qcsrc/client/hud.qc

   1 #include "hud.qh"
   2 #include "_all.qh"
   3
   4 #include "hud_config.qh"
   5 #include "scoreboard.qh"
   6 #include "sortlist.qh"
   7 #include "teamradar.qh"
   8 #include "t_items.qh"
   9
  10 #include "../common/buffs.qh"
  11 #include "../common/constants.qh"
  12 #include "../common/counting.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16
  17 #include "../server/mutators/gamemode_ctf.qh"
  18
  19 #include "../common/stats.qh"
  20
  21 #include "../csqcmodellib/cl_player.qh"
  22
  23 #include "../warpzonelib/mathlib.qh"
  24
  25 /*
  26 ==================
  27 Misc HUD functions
  28 ==================
  29 */
  30
  31 // a border picture is a texture containing nine parts:
  32 //   1/4 width: left part
  33 //   1/2 width: middle part (stretched)
  34 //   1/4 width: right part
  35 // divided into
  36 //   1/4 height: top part
  37 //   1/2 height: middle part (stretched)
  38 //   1/4 height: bottom part
  39 void draw_BorderPicture(vector theOrigin, string pic, vector theSize, vector theColor, float theAlpha, vector theBorderSize)
  40 {
  41     if (theBorderSize.x < 0 && theBorderSize.y < 0) // draw whole image as it is
  42     {
  43                 drawpic(theOrigin, pic, theSize, theColor, theAlpha, 0);
  44                 return;
  45     }
  46         if (theBorderSize.x == 0 && theBorderSize.y == 0) // no border
  47         {
  48                 // draw only the central part
  49                 drawsubpic(theOrigin, theSize, pic, '0.25 0.25 0', '0.5 0.5 0', theColor, theAlpha, 0);
  50                 return;
  51         }
  52
  53         vector dX, dY;
  54         vector width, height;
  55         vector bW, bH;
  56         //pic = draw_UseSkinFor(pic);
  57         width = eX * theSize.x;
  58         height = eY * theSize.y;
  59         if(theSize.x <= theBorderSize.x * 2)
  60         {
  61                 // not wide enough... draw just left and right then
  62                 bW = eX * (0.25 * theSize.x / (theBorderSize.x * 2));
  63                 if(theSize.y <= theBorderSize.y * 2)
  64                 {
  65                         // not high enough... draw just corners
  66                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  67                         drawsubpic(theOrigin,                 width * 0.5 + height * 0.5, pic, '0 0 0',           bW + bH, theColor, theAlpha, 0);
  68                         drawsubpic(theOrigin + width   * 0.5, width * 0.5 + height * 0.5, pic, eX - bW,           bW + bH, theColor, theAlpha, 0);
  69                         drawsubpic(theOrigin + height  * 0.5, width * 0.5 + height * 0.5, pic, eY - bH,           bW + bH, theColor, theAlpha, 0);
  70                         drawsubpic(theOrigin + theSize * 0.5, width * 0.5 + height * 0.5, pic, eX + eY - bW - bH, bW + bH, theColor, theAlpha, 0);
  71                 }
  72                 else
  73                 {
  74                         dY = theBorderSize.x * eY;
  75                         drawsubpic(theOrigin,                             width * 0.5          +     dY, pic, '0 0    0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  76                         drawsubpic(theOrigin + width * 0.5,               width * 0.5          +     dY, pic, '0 0    0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  77                         drawsubpic(theOrigin                        + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0',           '0 0.5  0' + bW, theColor, theAlpha, 0);
  78                         drawsubpic(theOrigin + width * 0.5          + dY, width * 0.5 + height - 2 * dY, pic, '0 0.25 0' + eX - bW, '0 0.5  0' + bW, theColor, theAlpha, 0);
  79                         drawsubpic(theOrigin               + height - dY, width * 0.5          +     dY, pic, '0 0.75 0',           '0 0.25 0' + bW, theColor, theAlpha, 0);
  80                         drawsubpic(theOrigin + width * 0.5 + height - dY, width * 0.5          +     dY, pic, '0 0.75 0' + eX - bW, '0 0.25 0' + bW, theColor, theAlpha, 0);
  81                 }
  82         }
  83         else
  84         {
  85                 if(theSize.y <= theBorderSize.y * 2)
  86                 {
  87                         // not high enough... draw just top and bottom then
  88                         bH = eY * (0.25 * theSize.y / (theBorderSize.y * 2));
  89                         dX = theBorderSize.x * eX;
  90                         drawsubpic(theOrigin,                                         dX + height * 0.5, pic, '0    0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  91                         drawsubpic(theOrigin + dX,                        width - 2 * dX + height * 0.5, pic, '0.25 0 0',           '0.5  0 0' + bH, theColor, theAlpha, 0);
  92                         drawsubpic(theOrigin + width - dX,                            dX + height * 0.5, pic, '0.75 0 0',           '0.25 0 0' + bH, theColor, theAlpha, 0);
  93                         drawsubpic(theOrigin              + height * 0.5,             dX + height * 0.5, pic, '0    0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  94                         drawsubpic(theOrigin + dX         + height * 0.5, width - 2 * dX + height * 0.5, pic, '0.25 0 0' + eY - bH, '0.5  0 0' + bH, theColor, theAlpha, 0);
  95                         drawsubpic(theOrigin + width - dX + height * 0.5,             dX + height * 0.5, pic, '0.75 0 0' + eY - bH, '0.25 0 0' + bH, theColor, theAlpha, 0);
  96                 }
  97                 else
  98                 {
  99                         dX = theBorderSize.x * eX;
 100                         dY = theBorderSize.x * eY;
 101                         drawsubpic(theOrigin,                                        dX          +     dY, pic, '0    0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 102                         drawsubpic(theOrigin                  + dX,      width - 2 * dX          +     dY, pic, '0.25 0    0', '0.5  0.25 0', theColor, theAlpha, 0);
 103                         drawsubpic(theOrigin          + width - dX,                  dX          +     dY, pic, '0.75 0    0', '0.25 0.25 0', theColor, theAlpha, 0);
 104                         drawsubpic(theOrigin          + dY,                          dX + height - 2 * dY, pic, '0    0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 105                         drawsubpic(theOrigin          + dY         + dX, width - 2 * dX + height - 2 * dY, pic, '0.25 0.25 0', '0.5  0.5  0', theColor, theAlpha, 0);
 106                         drawsubpic(theOrigin          + dY + width - dX,             dX + height - 2 * dY, pic, '0.75 0.25 0', '0.25 0.5  0', theColor, theAlpha, 0);
 107                         drawsubpic(theOrigin + height - dY,                          dX          +     dY, pic, '0    0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 108                         drawsubpic(theOrigin + height - dY         + dX, width - 2 * dX          +     dY, pic, '0.25 0.75 0', '0.5  0.25 0', theColor, theAlpha, 0);
 109                         drawsubpic(theOrigin + height - dY + width - dX,             dX          +     dY, pic, '0.75 0.75 0', '0.25 0.25 0', theColor, theAlpha, 0);
 110                 }
 111         }
 112 }
 113
 114 vector HUD_Get_Num_Color (float x, float maxvalue)
 115 {
 116         float blinkingamt;
 117         vector color;
 118         if(x >= maxvalue) {
 119                 color.x = sin(2*M_PI*time);
 120                 color.y = 1;
 121                 color.z = sin(2*M_PI*time);
 122         }
 123         else if(x > maxvalue * 0.75) {
 124                 color.x = 0.4 - (x-150)*0.02 * 0.4; //red value between 0.4 -> 0
 125                 color.y = 0.9 + (x-150)*0.02 * 0.1; // green value between 0.9 -> 1
 126                 color.z = 0;
 127         }
 128         else if(x > maxvalue * 0.5) {
 129                 color.x = 1 - (x-100)*0.02 * 0.6; //red value between 1 -> 0.4
 130                 color.y = 1 - (x-100)*0.02 * 0.1; // green value between 1 -> 0.9
 131                 color.z = 1 - (x-100)*0.02; // blue value between 1 -> 0
 132         }
 133         else if(x > maxvalue * 0.25) {
 134                 color.x = 1;
 135                 color.y = 1;
 136                 color.z = 0.2 + (x-50)*0.02 * 0.8; // blue value between 0.2 -> 1
 137         }
 138         else if(x > maxvalue * 0.1) {
 139                 color.x = 1;
 140                 color.y = (x-20)*90/27/100; // green value between 0 -> 1
 141                 color.z = (x-20)*90/27/100 * 0.2; // blue value between 0 -> 0.2
 142         }
 143         else {
 144                 color.x = 1;
 145                 color.y = 0;
 146                 color.z = 0;
 147         }
 148
 149         blinkingamt = (1 - x/maxvalue/0.25);
 150         if(blinkingamt > 0)
 151         {
 152                 color.x = color.x - color.x * blinkingamt * sin(2*M_PI*time);
 153                 color.y = color.y - color.y * blinkingamt * sin(2*M_PI*time);
 154                 color.z = color.z - color.z * blinkingamt * sin(2*M_PI*time);
 155         }
 156         return color;
 157 }
 158
 159 float HUD_GetRowCount(int item_count, vector size, float item_aspect)
 160 {
 161         float aspect = size_y / size_x;
 162         return bound(1, floor((sqrt(4 * item_aspect * aspect * item_count + aspect * aspect) + aspect + 0.5) / 2), item_count);
 163 }
 164
 165 vector HUD_GetTableSize(int item_count, vector psize, float item_aspect)
 166 {
 167         float columns, rows;
 168         float ratio, best_ratio = 0;
 169         float best_columns = 1, best_rows = 1;
 170         bool vertical = (psize.x / psize.y >= item_aspect);
 171         if(vertical)
 172         {
 173                 psize = eX * psize.y + eY * psize.x;
 174                 item_aspect = 1 / item_aspect;
 175         }
 176
 177         rows = ceil(sqrt(item_count));
 178         columns = ceil(item_count/rows);
 179         while(columns >= 1)
 180         {
 181                 ratio = (psize.x/columns) / (psize.y/rows);
 182                 if(ratio > item_aspect)
 183                         ratio = item_aspect * item_aspect / ratio;
 184
 185                 if(ratio <= best_ratio)
 186                         break; // ratio starts decreasing by now, skip next configurations
 187
 188                 best_columns = columns;
 189                 best_rows = rows;
 190                 best_ratio = ratio;
 191
 192                 if(columns == 1)
 193                         break;
 194
 195                 --columns;
 196                 rows = ceil(item_count/columns);
 197         }
 198
 199         if(vertical)
 200                 return eX * best_rows + eY * best_columns;
 201         else
 202                 return eX * best_columns + eY * best_rows;
 203 }
 204
 205 float stringwidth_colors(string s, vector theSize)
 206 {
 207         return stringwidth(s, true, theSize);
 208 }
 209
 210 float stringwidth_nocolors(string s, vector theSize)
 211 {
 212         return stringwidth(s, false, theSize);
 213 }
 214
 215 void drawstringright(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 216 {
 217         position.x -= 2 / 3 * strlen(text) * theScale.x;
 218         drawstring(position, text, theScale, rgb, theAlpha, flag);
 219 }
 220
 221 void drawstringcenter(vector position, string text, vector theScale, vector rgb, float theAlpha, int flag)
 222 {
 223         position.x = 0.5 * (vid_conwidth - 0.6025 * strlen(text) * theScale.x);
 224         drawstring(position, text, theScale, rgb, theAlpha, flag);
 225 }
 226
 227 // return the string of the onscreen race timer
 228 string MakeRaceString(int cp, float mytime, float theirtime, float lapdelta, string theirname)
 229 {
 230         string col;
 231         string timestr;
 232         string cpname;
 233         string lapstr;
 234         lapstr = "";
 235
 236         if(theirtime == 0) // goal hit
 237         {
 238                 if(mytime > 0)
 239                 {
 240                         timestr = strcat("+", ftos_decimals(+mytime, TIME_DECIMALS));
 241                         col = "^1";
 242                 }
 243                 else if(mytime == 0)
 244                 {
 245                         timestr = "+0.0";
 246                         col = "^3";
 247                 }
 248                 else
 249                 {
 250                         timestr = strcat("-", ftos_decimals(-mytime, TIME_DECIMALS));
 251                         col = "^2";
 252                 }
 253
 254                 if(lapdelta > 0)
 255                 {
 256                         lapstr = sprintf(_(" (-%dL)"), lapdelta);
 257                         col = "^2";
 258                 }
 259                 else if(lapdelta < 0)
 260                 {
 261                         lapstr = sprintf(_(" (+%dL)"), -lapdelta);
 262                         col = "^1";
 263                 }
 264         }
 265         else if(theirtime > 0) // anticipation
 266         {
 267                 if(mytime >= theirtime)
 268                         timestr = strcat("+", ftos_decimals(mytime - theirtime, TIME_DECIMALS));
 269                 else
 270                         timestr = TIME_ENCODED_TOSTRING(TIME_ENCODE(theirtime));
 271                 col = "^3";
 272         }
 273         else
 274         {
 275                 col = "^7";
 276                 timestr = "";
 277         }
 278
 279         if(cp == 254)
 280                 cpname = _("Start line");
 281         else if(cp == 255)
 282                 cpname = _("Finish line");
 283         else if(cp)
 284                 cpname = sprintf(_("Intermediate %d"), cp);
 285         else
 286                 cpname = _("Finish line");
 287
 288         if(theirtime < 0)
 289                 return strcat(col, cpname);
 290         else if(theirname == "")
 291                 return strcat(col, sprintf("%s (%s)", cpname, timestr));
 292         else
 293                 return strcat(col, sprintf("%s (%s %s)", cpname, timestr, strcat(theirname, col, lapstr)));
 294 }
 295
 296 // Check if the given name already exist in race rankings? In that case, where? (otherwise return 0)
 297 int race_CheckName(string net_name)
 298 {
 299         int i;
 300         for (i=RANKINGS_CNT-1;i>=0;--i)
 301                 if(grecordholder[i] == net_name)
 302                         return i+1;
 303         return 0;
 304 }
 305
 306 int GetPlayerColorForce(int i)
 307 {
 308         if(!teamplay)
 309                 return 0;
 310         else
 311                 return stof(getplayerkeyvalue(i, "colors")) & 15;
 312 }
 313
 314 int GetPlayerColor(int i)
 315 {
 316         if(!playerslots[i].gotscores) // unconnected
 317                 return NUM_SPECTATOR;
 318         else if(stof(getplayerkeyvalue(i, "frags")) == FRAGS_SPECTATOR)
 319                 return NUM_SPECTATOR;
 320         else
 321                 return GetPlayerColorForce(i);
 322 }
 323
 324 string GetPlayerName(int i)
 325 {
 326         return ColorTranslateRGB(getplayerkeyvalue(i, "name"));
 327 }
 328
 329
 330 /*
 331 ==================
 332 HUD panels
 333 ==================
 334 */
 335
 336 // draw the background/borders
 337 #define HUD_Panel_DrawBg(theAlpha) do {                                                                                                                                                         \
 338         if(panel.current_panel_bg != "0" && panel.current_panel_bg != "")                                                                                               \
 339                 draw_BorderPicture(panel_pos - '1 1 0' * panel_bg_border, panel.current_panel_bg, panel_size + '1 1 0' * 2 * panel_bg_border, panel_bg_color, panel_bg_alpha * theAlpha, '1 1 0' * (panel_bg_border/BORDER_MULTIPLIER));\
 340 } while(0)
 341
 342 //basically the same code of draw_ButtonPicture and draw_VertButtonPicture for the menu
 343 void HUD_Panel_DrawProgressBar(vector theOrigin, vector theSize, string pic, float length_ratio, bool vertical, float baralign, vector theColor, float theAlpha, int drawflag)
 344 {
 345         if(!length_ratio || !theAlpha)
 346                 return;
 347         if(length_ratio > 1)
 348                 length_ratio = 1;
 349         if (baralign == 3)
 350         {
 351                 if(length_ratio < -1)
 352                         length_ratio = -1;
 353         }
 354         else if(length_ratio < 0)
 355                 return;
 356
 357         vector square;
 358         vector width, height;
 359         if(vertical) {
 360                 pic = strcat(hud_skin_path, "/", pic, "_vertical");
 361                 if(precache_pic(pic) == "") {
 362                         pic = "gfx/hud/default/progressbar_vertical";
 363                 }
 364
 365         if (baralign == 1) // bottom align
 366                         theOrigin.y += (1 - length_ratio) * theSize.y;
 367         else if (baralign == 2) // center align
 368             theOrigin.y += 0.5 * (1 - length_ratio) * theSize.y;
 369         else if (baralign == 3) // center align, positive values down, negative up
 370                 {
 371                         theSize.y *= 0.5;
 372                         if (length_ratio > 0)
 373                                 theOrigin.y += theSize.y;
 374                         else
 375                         {
 376                                 theOrigin.y += (1 + length_ratio) * theSize.y;
 377                                 length_ratio = -length_ratio;
 378                         }
 379                 }
 380                 theSize.y *= length_ratio;
 381
 382                 vector bH;
 383                 width = eX * theSize.x;
 384                 height = eY * theSize.y;
 385                 if(theSize.y <= theSize.x * 2)
 386                 {
 387                         // button not high enough
 388                         // draw just upper and lower part then
 389                         square = eY * theSize.y * 0.5;
 390                         bH = eY * (0.25 * theSize.y / (theSize.x * 2));
 391                         drawsubpic(theOrigin,          square + width, pic, '0 0 0', eX + bH, theColor, theAlpha, drawflag);
 392                         drawsubpic(theOrigin + square, square + width, pic, eY - bH, eX + bH, theColor, theAlpha, drawflag);
 393                 }
 394                 else
 395                 {
 396                         square = eY * theSize.x;
 397                         drawsubpic(theOrigin,                   width   +     square, pic, '0 0    0', '1 0.25 0', theColor, theAlpha, drawflag);
 398                         drawsubpic(theOrigin +          square, theSize - 2 * square, pic, '0 0.25 0', '1 0.5  0', theColor, theAlpha, drawflag);
 399                         drawsubpic(theOrigin + height - square, width   +     square, pic, '0 0.75 0', '1 0.25 0', theColor, theAlpha, drawflag);
 400                 }
 401         } else {
 402                 pic = strcat(hud_skin_path, "/", pic);
 403                 if(precache_pic(pic) == "") {
 404                         pic = "gfx/hud/default/progressbar";
 405                 }
 406
 407                 if (baralign == 1) // right align
 408                         theOrigin.x += (1 - length_ratio) * theSize.x;
 409         else if (baralign == 2) // center align
 410             theOrigin.x += 0.5 * (1 - length_ratio) * theSize.x;
 411         else if (baralign == 3) // center align, positive values on the right, negative on the left
 412                 {
 413                         theSize.x *= 0.5;
 414                         if (length_ratio > 0)
 415                                 theOrigin.x += theSize.x;
 416                         else
 417                         {
 418                                 theOrigin.x += (1 + length_ratio) * theSize.x;
 419                                 length_ratio = -length_ratio;
 420                         }
 421                 }
 422                 theSize.x *= length_ratio;
 423
 424                 vector bW;
 425                 width = eX * theSize.x;
 426                 height = eY * theSize.y;
 427                 if(theSize.x <= theSize.y * 2)
 428                 {
 429                         // button not wide enough
 430                         // draw just left and right part then
 431                         square = eX * theSize.x * 0.5;
 432                         bW = eX * (0.25 * theSize.x / (theSize.y * 2));
 433                         drawsubpic(theOrigin,          square + height, pic, '0 0 0', eY + bW, theColor, theAlpha, drawflag);
 434                         drawsubpic(theOrigin + square, square + height, pic, eX - bW, eY + bW, theColor, theAlpha, drawflag);
 435                 }
 436                 else
 437                 {
 438                         square = eX * theSize.y;
 439                         drawsubpic(theOrigin,                  height  +     square, pic, '0    0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 440                         drawsubpic(theOrigin +         square, theSize - 2 * square, pic, '0.25 0 0', '0.5  1 0', theColor, theAlpha, drawflag);
 441                         drawsubpic(theOrigin + width - square, height  +     square, pic, '0.75 0 0', '0.25 1 0', theColor, theAlpha, drawflag);
 442                 }
 443         }
 444 }
 445
 446 void HUD_Panel_DrawHighlight(vector pos, vector mySize, vector color, float theAlpha, int drawflag)
 447 {
 448         if(!theAlpha)
 449                 return;
 450
 451         string pic;
 452         pic = strcat(hud_skin_path, "/num_leading");
 453         if(precache_pic(pic) == "") {
 454                 pic = "gfx/hud/default/num_leading";
 455         }
 456
 457         drawsubpic(pos, eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0 0 0', '0.25 1 0', color, theAlpha, drawflag);
 458         if(mySize.x/mySize.y > 2)
 459                 drawsubpic(pos + eX * mySize.y, eX * (mySize.x - 2 * mySize.y) + eY * mySize.y, pic, '0.25 0 0', '0.5 1 0', color, theAlpha, drawflag);
 460         drawsubpic(pos + eX * mySize.x - eX * min(mySize.x * 0.5, mySize.y), eX * min(mySize.x * 0.5, mySize.y) + eY * mySize.y, pic, '0.75 0 0', '0.25 1 0', color, theAlpha, drawflag);
 461 }
 462
 463 // Weapon icons (#0)
 464 //
 465 entity weaponorder[WEP_MAXCOUNT];
 466 void weaponorder_swap(int i, int j, entity pass)
 467 {
 468         entity h = weaponorder[i];
 469         weaponorder[i] = weaponorder[j];
 470         weaponorder[j] = h;
 471 }
 472
 473 string weaponorder_cmp_str;
 474 int weaponorder_cmp(int i, int j, entity pass)
 475 {
 476         int ai, aj;
 477         ai = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[i].weapon), 0);
 478         aj = strstrofs(weaponorder_cmp_str, sprintf(" %d ", weaponorder[j].weapon), 0);
 479         return aj - ai; // the string is in REVERSE order (higher prio at the right is what we want, but higher prio first is the string)
 480 }
 481
 482 void HUD_Weapons(void)
 483 {
 484         // declarations
 485         WepSet weapons_stat = WepSet_GetFromStat();
 486         int i;
 487         float f, a;
 488         float screen_ar;
 489         vector center = '0 0 0';
 490         int weapon_count, weapon_id;
 491         int row, column, rows = 0, columns = 0;
 492         bool vertical_order = true;
 493         float aspect = autocvar_hud_panel_weapons_aspect;
 494
 495         float timeout = autocvar_hud_panel_weapons_timeout;
 496         float timein_effect_length = autocvar_hud_panel_weapons_timeout_speed_in; //? 0.375 : 0);
 497         float timeout_effect_length = autocvar_hud_panel_weapons_timeout_speed_out; //? 0.75 : 0);
 498
 499         vector barsize = '0 0 0', baroffset = '0 0 0';
 500         vector ammo_color = '1 0 1';
 501         float ammo_alpha = 1;
 502
 503         float when = max(1, autocvar_hud_panel_weapons_complainbubble_time);
 504         float fadetime = max(0, autocvar_hud_panel_weapons_complainbubble_fadetime);
 505
 506         vector weapon_pos, weapon_size = '0 0 0';
 507         vector color;
 508
 509         // check to see if we want to continue
 510         if(hud != HUD_NORMAL) { return; }
 511
 512         if(!autocvar__hud_configure)
 513         {
 514                 if((!autocvar_hud_panel_weapons) || (spectatee_status == -1))
 515                         return;
 516                 if(timeout && time >= weapontime + timeout + timeout_effect_length)
 517                 if(autocvar_hud_panel_weapons_timeout_effect == 3 || (autocvar_hud_panel_weapons_timeout_effect == 1 && !(autocvar_hud_panel_weapons_timeout_fadebgmin + autocvar_hud_panel_weapons_timeout_fadefgmin)))
 518                 {
 519                         weaponprevtime = time;
 520                         return;
 521                 }
 522         }
 523
 524         // update generic hud functions
 525         HUD_Panel_UpdateCvars();
 526
 527         // figure out weapon order (how the weapons are sorted) // TODO make this configurable
 528         if(weaponorder_bypriority != autocvar_cl_weaponpriority || !weaponorder[0])
 529         {
 530                 int weapon_cnt;
 531                 if(weaponorder_bypriority)
 532                         strunzone(weaponorder_bypriority);
 533                 if(weaponorder_byimpulse)
 534                         strunzone(weaponorder_byimpulse);
 535
 536                 weaponorder_bypriority = strzone(autocvar_cl_weaponpriority);
 537                 weaponorder_byimpulse = strzone(W_FixWeaponOrder_BuildImpulseList(W_FixWeaponOrder_ForceComplete(W_NumberWeaponOrder(weaponorder_bypriority))));
 538                 weaponorder_cmp_str = strcat(" ", weaponorder_byimpulse, " ");
 539
 540                 weapon_cnt = 0;
 541                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 542                 {
 543                         self = get_weaponinfo(i);
 544                         if(self.impulse >= 0)
 545                         {
 546                                 weaponorder[weapon_cnt] = self;
 547                                 ++weapon_cnt;
 548                         }
 549                 }
 550                 for(i = weapon_cnt; i < WEP_MAXCOUNT; ++i)
 551                         weaponorder[i] = world;
 552                 heapsort(weapon_cnt, weaponorder_swap, weaponorder_cmp, world);
 553
 554                 weaponorder_cmp_str = string_null;
 555         }
 556
 557         if(!autocvar_hud_panel_weapons_complainbubble || autocvar__hud_configure || time - complain_weapon_time >= when + fadetime)
 558                 complain_weapon = 0;
 559
 560         if(autocvar__hud_configure)
 561         {
 562                 if(!weapons_stat)
 563                         for(i = WEP_FIRST; i <= WEP_LAST; i += floor((WEP_LAST-WEP_FIRST)/5))
 564                                 weapons_stat |= WepSet_FromWeapon(i);
 565
 566                 #if 0
 567                 /// debug code
 568                 if(cvar("wep_add"))
 569                 {
 570                         weapons_stat = '0 0 0';
 571                         float countw = 1 + floor((floor(time * cvar("wep_add"))) % WEP_COUNT);
 572                         for(i = WEP_FIRST; i <= countw; ++i)
 573                                 weapons_stat |= WepSet_FromWeapon(i);
 574                 }
 575                 #endif
 576         }
 577
 578         // determine which weapons are going to be shown
 579         if (autocvar_hud_panel_weapons_onlyowned)
 580         {
 581                 if(autocvar__hud_configure)
 582                 {
 583                         if(menu_enabled != 2)
 584                                 HUD_Panel_DrawBg(1); // also draw the bg of the entire panel
 585                 }
 586
 587                 // do we own this weapon?
 588                 weapon_count = 0;
 589                 for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 590                         if((weapons_stat & WepSet_FromWeapon(weaponorder[i].weapon)) || (weaponorder[i].weapon == complain_weapon))
 591                                 ++weapon_count;
 592
 593
 594                 // might as well commit suicide now, no reason to live ;)
 595                 if (weapon_count == 0)
 596                         return;
 597
 598                 vector old_panel_size = panel_size;
 599                 vector padded_panel_size = panel_size - '2 2 0' * panel_bg_padding;
 600
 601                 // get the all-weapons layout
 602                 vector table_size = HUD_GetTableSize(WEP_COUNT, padded_panel_size, aspect);
 603                 columns = table_size.x;
 604                 rows = table_size.y;
 605                 weapon_size.x = padded_panel_size.x / columns;
 606                 weapon_size.y = padded_panel_size.y / rows;
 607
 608                 // NOTE: although weapons should aways look the same even if onlyowned is enabled,
 609                 // we enlarge them a bit when possible to better match the desired aspect ratio
 610                 if(padded_panel_size.x / padded_panel_size.y < aspect)
 611                 {
 612                         // maximum number of rows that allows to display items with the desired aspect ratio
 613                         int max_rows = floor(padded_panel_size.y / (weapon_size.x / aspect));
 614                         columns = min(columns, ceil(weapon_count / max_rows));
 615                         rows = ceil(weapon_count / columns);
 616                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 617                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 618                         vertical_order = false;
 619                 }
 620                 else
 621                 {
 622                         int max_columns = floor(padded_panel_size.x / (weapon_size.y * aspect));
 623                         rows = min(rows, ceil(weapon_count / max_columns));
 624                         columns = ceil(weapon_count / rows);
 625                         weapon_size.x = min(padded_panel_size.x / columns, aspect * weapon_size.y);
 626                         weapon_size.y = min(padded_panel_size.y / rows, weapon_size.x / aspect);
 627                         vertical_order = true;
 628                 }
 629
 630                 // reduce size of the panel
 631                 panel_size.x = columns * weapon_size.x;
 632                 panel_size.y = rows * weapon_size.y;
 633                 panel_size += '2 2 0' * panel_bg_padding;
 634
 635                 // center the resized panel, or snap it to the screen edge when close enough
 636                 if(panel_pos.x > vid_conwidth * 0.001)
 637                 {
 638                         if(panel_pos.x + old_panel_size.x > vid_conwidth * 0.999)
 639                                 panel_pos.x += old_panel_size.x - panel_size.x;
 640                         else
 641                                 panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 642                 }
 643                 else if(old_panel_size.x > vid_conwidth * 0.999)
 644                         panel_pos.x += (old_panel_size.x - panel_size.x) / 2;
 645
 646                 if(panel_pos.y > vid_conheight * 0.001)
 647                 {
 648                         if(panel_pos.y + old_panel_size.y > vid_conheight * 0.999)
 649                                 panel_pos.y += old_panel_size.y - panel_size.y;
 650                         else
 651                                 panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 652                 }
 653                 else if(old_panel_size.y > vid_conheight * 0.999)
 654                         panel_pos.y += (old_panel_size.y - panel_size.y) / 2;
 655         }
 656         else
 657                 weapon_count = WEP_COUNT;
 658
 659         // animation for fading in/out the panel respectively when not in use
 660         if(!autocvar__hud_configure)
 661         {
 662                 if (timeout && time >= weapontime + timeout) // apply timeout effect if needed
 663                 {
 664                         f = bound(0, (time - (weapontime + timeout)) / timeout_effect_length, 1);
 665
 666                         // fade the panel alpha
 667                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 668                         {
 669                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * f + (1 - f));
 670                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * f + (1 - f));
 671                         }
 672                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 673                         {
 674                                 panel_bg_alpha *= (1 - f);
 675                                 panel_fg_alpha *= (1 - f);
 676                         }
 677
 678                         // move the panel off the screen
 679                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 680                         {
 681                                 f *= f; // for a cooler movement
 682                                 center.x = panel_pos.x + panel_size.x/2;
 683                                 center.y = panel_pos.y + panel_size.y/2;
 684                                 screen_ar = vid_conwidth/vid_conheight;
 685                                 if (center.x/center.y < screen_ar) //bottom left
 686                                 {
 687                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 688                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 689                                         else //left
 690                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 691                                 }
 692                                 else //top right
 693                                 {
 694                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 695                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 696                                         else //top
 697                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 698                                 }
 699                                 if(f == 1)
 700                                         center.x = -1; // mark the panel as off screen
 701                         }
 702                         weaponprevtime = time - (1 - f) * timein_effect_length;
 703                 }
 704                 else if (timeout && time < weaponprevtime + timein_effect_length) // apply timein effect if needed
 705                 {
 706                         f = bound(0, (time - weaponprevtime) / timein_effect_length, 1);
 707
 708                         // fade the panel alpha
 709                         if(autocvar_hud_panel_weapons_timeout_effect == 1)
 710                         {
 711                                 panel_bg_alpha *= (autocvar_hud_panel_weapons_timeout_fadebgmin * (1 - f) + f);
 712                                 panel_fg_alpha *= (autocvar_hud_panel_weapons_timeout_fadefgmin * (1 - f) + f);
 713                         }
 714                         else if(autocvar_hud_panel_weapons_timeout_effect == 3)
 715                         {
 716                                 panel_bg_alpha *= (f);
 717                                 panel_fg_alpha *= (f);
 718                         }
 719
 720                         // move the panel back on screen
 721                         if (autocvar_hud_panel_weapons_timeout_effect == 2 || autocvar_hud_panel_weapons_timeout_effect == 3)
 722                         {
 723                                 f *= f; // for a cooler movement
 724                                 f = 1 - f;
 725                                 center.x = panel_pos.x + panel_size.x/2;
 726                                 center.y = panel_pos.y + panel_size.y/2;
 727                                 screen_ar = vid_conwidth/vid_conheight;
 728                                 if (center.x/center.y < screen_ar) //bottom left
 729                                 {
 730                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //bottom
 731                                                 panel_pos.y += f * (vid_conheight - panel_pos.y);
 732                                         else //left
 733                                                 panel_pos.x -= f * (panel_pos.x + panel_size.x);
 734                                 }
 735                                 else //top right
 736                                 {
 737                                         if ((vid_conwidth - center.x)/center.y < screen_ar) //right
 738                                                 panel_pos.x += f * (vid_conwidth - panel_pos.x);
 739                                         else //top
 740                                                 panel_pos.y -= f * (panel_pos.y + panel_size.y);
 741                                 }
 742                         }
 743                 }
 744         }
 745
 746         // draw the background, then change the virtual size of it to better fit other items inside
 747         HUD_Panel_DrawBg(1);
 748
 749         if(center.x == -1)
 750                 return;
 751
 752         if(panel_bg_padding)
 753         {
 754                 panel_pos += '1 1 0' * panel_bg_padding;
 755                 panel_size -= '2 2 0' * panel_bg_padding;
 756         }
 757
 758         // after the sizing and animations are done, update the other values
 759
 760         if(!rows) // if rows is > 0 onlyowned code has already updated these vars
 761         {
 762                 vector table_size = HUD_GetTableSize(WEP_COUNT, panel_size, aspect);
 763                 columns = table_size.x;
 764                 rows = table_size.y;
 765                 weapon_size.x = panel_size.x / columns;
 766                 weapon_size.y = panel_size.y / rows;
 767                 vertical_order = (panel_size.x / panel_size.y >= aspect);
 768         }
 769
 770         // calculate position/size for visual bar displaying ammount of ammo status
 771         if (autocvar_hud_panel_weapons_ammo)
 772         {
 773                 ammo_color = stov(autocvar_hud_panel_weapons_ammo_color);
 774                 ammo_alpha = panel_fg_alpha * autocvar_hud_panel_weapons_ammo_alpha;
 775
 776                 if(weapon_size.x/weapon_size.y > aspect)
 777                 {
 778                         barsize.x = aspect * weapon_size.y;
 779                         barsize.y = weapon_size.y;
 780                         baroffset.x = (weapon_size.x - barsize.x) / 2;
 781                 }
 782                 else
 783                 {
 784                         barsize.y = 1/aspect * weapon_size.x;
 785                         barsize.x = weapon_size.x;
 786                         baroffset.y = (weapon_size.y - barsize.y) / 2;
 787                 }
 788         }
 789         if(autocvar_hud_panel_weapons_accuracy)
 790                 Accuracy_LoadColors();
 791
 792         // draw items
 793         row = column = 0;
 794         vector label_size = '1 1 0' * min(weapon_size.x, weapon_size.y) * bound(0, autocvar_hud_panel_weapons_label_scale, 1);
 795         for(i = 0; i <= WEP_LAST-WEP_FIRST; ++i)
 796         {
 797                 // retrieve information about the current weapon to be drawn
 798                 self = weaponorder[i];
 799                 weapon_id = self.impulse;
 800
 801                 // skip if this weapon doesn't exist
 802                 if(!self || weapon_id < 0) { continue; }
 803
 804                 // skip this weapon if we don't own it (and onlyowned is enabled)-- or if weapons_complainbubble is showing for this weapon
 805                 if(autocvar_hud_panel_weapons_onlyowned)
 806                 if (!((weapons_stat & WepSet_FromWeapon(self.weapon)) || (self.weapon == complain_weapon)))
 807                         continue;
 808
 809                 // figure out the drawing position of weapon
 810                 weapon_pos = (panel_pos
 811                         + eX * column * weapon_size.x
 812                         + eY * row * weapon_size.y);
 813
 814                 // draw background behind currently selected weapon
 815                 if(self.weapon == switchweapon)
 816                         drawpic_aspect_skin(weapon_pos, "weapon_current_bg", weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 817
 818                 // draw the weapon accuracy
 819                 if(autocvar_hud_panel_weapons_accuracy)
 820                 {
 821                         float panel_weapon_accuracy = weapon_accuracy[self.weapon-WEP_FIRST];
 822                         if(panel_weapon_accuracy >= 0)
 823                         {
 824                                 color = Accuracy_GetColor(panel_weapon_accuracy);
 825                                 drawpic_aspect_skin(weapon_pos, "weapon_accuracy", weapon_size, color, panel_fg_alpha, DRAWFLAG_NORMAL);
 826                         }
 827                 }
 828
 829                 // drawing all the weapon items
 830                 if(weapons_stat & WepSet_FromWeapon(self.weapon))
 831                 {
 832                         // draw the weapon image
 833                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 834
 835                         // draw weapon label string
 836                         switch(autocvar_hud_panel_weapons_label)
 837                         {
 838                                 case 1: // weapon number
 839                                         drawstring(weapon_pos, ftos(weapon_id), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 840                                         break;
 841
 842                                 case 2: // bind
 843                                         drawstring(weapon_pos, getcommandkey(ftos(weapon_id), strcat("weapon_group_", ftos(weapon_id))), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 844                                         break;
 845
 846                                 case 3: // weapon name
 847                                         drawstring(weapon_pos, strtolower(self.message), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 848                                         break;
 849
 850                                 default: // nothing
 851                                         break;
 852                         }
 853
 854                         // draw ammo status bar
 855                         if(autocvar_hud_panel_weapons_ammo && (self.ammo_field != ammo_none))
 856                         {
 857                                 float ammo_full;
 858                                 a = getstati(GetAmmoStat(self.ammo_field)); // how much ammo do we have?
 859
 860                                 if(a > 0)
 861                                 {
 862                                         switch(self.ammo_field)
 863                                         {
 864                                                 case ammo_shells:  ammo_full = autocvar_hud_panel_weapons_ammo_full_shells;  break;
 865                                                 case ammo_nails:   ammo_full = autocvar_hud_panel_weapons_ammo_full_nails;   break;
 866                                                 case ammo_rockets: ammo_full = autocvar_hud_panel_weapons_ammo_full_rockets; break;
 867                                                 case ammo_cells:   ammo_full = autocvar_hud_panel_weapons_ammo_full_cells;   break;
 868                                                 case ammo_plasma:  ammo_full = autocvar_hud_panel_weapons_ammo_full_plasma;  break;
 869                                                 case ammo_fuel:    ammo_full = autocvar_hud_panel_weapons_ammo_full_fuel;    break;
 870                                                 default: ammo_full = 60;
 871                                         }
 872
 873                                         drawsetcliparea(
 874                                                 weapon_pos.x + baroffset.x,
 875                                                 weapon_pos.y + baroffset.y,
 876                                                 barsize.x * bound(0, a/ammo_full, 1),
 877                                                 barsize.y
 878                                         );
 879
 880                                         drawpic_aspect_skin(
 881                                                 weapon_pos,
 882                                                 "weapon_ammo",
 883                                                 weapon_size,
 884                                                 ammo_color,
 885                                                 ammo_alpha,
 886                                                 DRAWFLAG_NORMAL
 887                                         );
 888
 889                                         drawresetcliparea();
 890                                 }
 891                         }
 892                 }
 893                 else // draw a "ghost weapon icon" if you don't have the weapon
 894                 {
 895                         drawpic_aspect_skin(weapon_pos, self.model2, weapon_size, '0 0 0', panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
 896                 }
 897
 898                 // draw the complain message
 899                 if(self.weapon == complain_weapon)
 900                 {
 901                         if(fadetime)
 902                                 a = ((complain_weapon_time + when > time) ? 1 : bound(0, (complain_weapon_time + when + fadetime - time) / fadetime, 1));
 903                         else
 904                                 a = ((complain_weapon_time + when > time) ? 1 : 0);
 905
 906                         string s;
 907                         if(complain_weapon_type == 0) {
 908                                 s = _("Out of ammo");
 909                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_outofammo);
 910                         }
 911                         else if(complain_weapon_type == 1) {
 912                                 s = _("Don't have");
 913                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_donthave);
 914                         }
 915                         else {
 916                                 s = _("Unavailable");
 917                                 color = stov(autocvar_hud_panel_weapons_complainbubble_color_unavailable);
 918                         }
 919                         float padding = autocvar_hud_panel_weapons_complainbubble_padding;
 920                         drawpic_aspect_skin(weapon_pos + '1 1 0' * padding, "weapon_complainbubble", weapon_size - '2 2 0' * padding, color, a * panel_fg_alpha, DRAWFLAG_NORMAL);
 921                         drawstring_aspect(weapon_pos + '1 1 0' * padding, s, weapon_size - '2 2 0' * padding, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
 922                 }
 923
 924                 #if 0
 925                 /// debug code
 926                 if(!autocvar_hud_panel_weapons_onlyowned)
 927                 {
 928                         drawfill(weapon_pos + '1 1 0', weapon_size - '2 2 0', '1 1 1', panel_fg_alpha * 0.2, DRAWFLAG_NORMAL);
 929                         drawstring(weapon_pos, ftos(i + 1), label_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 930                 }
 931                 #endif
 932
 933                 // continue with new position for the next weapon
 934                 if(vertical_order)
 935                 {
 936                         ++column;
 937                         if(column >= columns)
 938                         {
 939                                 column = 0;
 940                                 ++row;
 941                         }
 942                 }
 943                 else
 944                 {
 945                         ++row;
 946                         if(row >= rows)
 947                         {
 948                                 row = 0;
 949                                 ++column;
 950                         }
 951                 }
 952         }
 953 }
 954
 955 // Ammo (#1)
 956 void DrawNadeProgressBar(vector myPos, vector mySize, float progress, vector color)
 957 {
 958         HUD_Panel_DrawProgressBar(
 959                 myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 960                 mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x,
 961                 autocvar_hud_panel_ammo_progressbar_name,
 962                 progress, 0, 0, color,
 963                 autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 964 }
 965
 966 void DrawAmmoNades(vector myPos, vector mySize, bool draw_expanding, float expand_time)
 967 {
 968         float bonusNades    = getstatf(STAT_NADE_BONUS);
 969         float bonusProgress = getstatf(STAT_NADE_BONUS_SCORE);
 970         float bonusType     = getstati(STAT_NADE_BONUS_TYPE);
 971         vector nadeColor    = Nade_Color(bonusType);
 972         string nadeIcon     = Nade_Icon(bonusType);
 973
 974         vector iconPos, textPos;
 975
 976         if(autocvar_hud_panel_ammo_iconalign)
 977         {
 978                 iconPos = myPos + eX * 2 * mySize.y;
 979                 textPos = myPos;
 980         }
 981         else
 982         {
 983                 iconPos = myPos;
 984                 textPos = myPos + eX * mySize.y;
 985         }
 986
 987         if(bonusNades > 0 || bonusProgress > 0)
 988         {
 989                 DrawNadeProgressBar(myPos, mySize, bonusProgress, nadeColor);
 990
 991                 if(autocvar_hud_panel_ammo_text)
 992                         drawstring_aspect(textPos, ftos(bonusNades), eX * (2/3) * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 993
 994                 if(draw_expanding)
 995                         drawpic_aspect_skin_expanding(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, expand_time);
 996
 997                 drawpic_aspect_skin(iconPos, nadeIcon, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
 998         }
 999 }
1000
1001 void DrawAmmoItem(vector myPos, vector mySize, .int ammoType, bool isCurrent, bool isInfinite)
1002 {
1003         if(ammoType == ammo_none)
1004                 return;
1005
1006         // Initialize variables
1007
1008         int ammo;
1009         if(autocvar__hud_configure)
1010         {
1011                 isCurrent = (ammoType == ammo_rockets); // Rockets always current
1012                 ammo = 60;
1013         }
1014         else
1015                 ammo = getstati(GetAmmoStat(ammoType));
1016
1017         if(!isCurrent)
1018         {
1019                 float scale = bound(0, autocvar_hud_panel_ammo_noncurrent_scale, 1);
1020                 myPos = myPos + (mySize - mySize * scale) * 0.5;
1021                 mySize = mySize * scale;
1022         }
1023
1024         vector iconPos, textPos;
1025         if(autocvar_hud_panel_ammo_iconalign)
1026         {
1027                 iconPos = myPos + eX * 2 * mySize.y;
1028                 textPos = myPos;
1029         }
1030         else
1031         {
1032                 iconPos = myPos;
1033                 textPos = myPos + eX * mySize.y;
1034         }
1035
1036         bool isShadowed = (ammo <= 0 && !isCurrent && !isInfinite);
1037
1038         vector iconColor = isShadowed ? '0 0 0' : '1 1 1';
1039         vector textColor;
1040         if(isInfinite)
1041                 textColor = '0.2 0.95 0';
1042         else if(isShadowed)
1043                 textColor = '0 0 0';
1044         else if(ammo < 10)
1045                 textColor = '0.8 0.04 0';
1046         else
1047                 textColor = '1 1 1';
1048
1049         float alpha;
1050         if(isCurrent)
1051                 alpha = panel_fg_alpha;
1052         else if(isShadowed)
1053                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1) * 0.5;
1054         else
1055                 alpha = panel_fg_alpha * bound(0, autocvar_hud_panel_ammo_noncurrent_alpha, 1);
1056
1057         string text = isInfinite ? "\xE2\x88\x9E" : ftos(ammo); // Use infinity symbol (U+221E)
1058
1059         // Draw item
1060
1061         if(isCurrent)
1062                 drawpic_aspect_skin(myPos, "ammo_current_bg", mySize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1063
1064         if(ammo > 0 && autocvar_hud_panel_ammo_progressbar)
1065                 HUD_Panel_DrawProgressBar(myPos + eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, mySize - eX * autocvar_hud_panel_ammo_progressbar_xoffset * mySize.x, autocvar_hud_panel_ammo_progressbar_name, ammo/autocvar_hud_panel_ammo_maxammo, 0, 0, textColor, autocvar_hud_progressbar_alpha * alpha, DRAWFLAG_NORMAL);
1066
1067         if(autocvar_hud_panel_ammo_text)
1068                 drawstring_aspect(textPos, text, eX * (2/3) * mySize.x + eY * mySize.y, textColor, alpha, DRAWFLAG_NORMAL);
1069
1070         drawpic_aspect_skin(iconPos, GetAmmoPicture(ammoType), '1 1 0' * mySize.y, iconColor, alpha, DRAWFLAG_NORMAL);
1071 }
1072
1073 int nade_prevstatus;
1074 int nade_prevframe;
1075 float nade_statuschange_time;
1076 void HUD_Ammo(void)
1077 {
1078         if(hud != HUD_NORMAL) return;
1079         if(!autocvar__hud_configure)
1080         {
1081                 if(!autocvar_hud_panel_ammo) return;
1082                 if(spectatee_status == -1) return;
1083         }
1084
1085         HUD_Panel_UpdateCvars();
1086
1087         draw_beginBoldFont();
1088
1089         vector pos, mySize;
1090         pos = panel_pos;
1091         mySize = panel_size;
1092
1093         HUD_Panel_DrawBg(1);
1094         if(panel_bg_padding)
1095         {
1096                 pos += '1 1 0' * panel_bg_padding;
1097                 mySize -= '2 2 0' * panel_bg_padding;
1098         }
1099
1100         int rows = 0, columns, row, column;
1101         float nade_cnt = getstatf(STAT_NADE_BONUS), nade_score = getstatf(STAT_NADE_BONUS_SCORE);
1102         bool draw_nades = (nade_cnt > 0 || nade_score > 0);
1103         float nade_statuschange_elapsedtime;
1104         int total_ammo_count;
1105
1106         vector ammo_size;
1107         if (autocvar_hud_panel_ammo_onlycurrent)
1108                 total_ammo_count = 1;
1109         else
1110                 total_ammo_count = AMMO_COUNT;
1111
1112         if(draw_nades)
1113         {
1114                 ++total_ammo_count;
1115                 if (nade_cnt != nade_prevframe)
1116                 {
1117                         nade_statuschange_time = time;
1118                         nade_prevstatus = nade_prevframe;
1119                         nade_prevframe = nade_cnt;
1120                 }
1121         }
1122         else
1123                 nade_prevstatus = nade_prevframe = nade_statuschange_time = 0;
1124
1125         rows = HUD_GetRowCount(total_ammo_count, mySize, 3);
1126         columns = ceil((total_ammo_count)/rows);
1127         ammo_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
1128
1129         vector offset = '0 0 0'; // fteqcc sucks
1130         float newSize;
1131         if(ammo_size.x/ammo_size.y > 3)
1132         {
1133                 newSize = 3 * ammo_size.y;
1134                 offset.x = ammo_size.x - newSize;
1135                 pos.x += offset.x/2;
1136                 ammo_size.x = newSize;
1137         }
1138         else
1139         {
1140                 newSize = 1/3 * ammo_size.x;
1141                 offset.y = ammo_size.y - newSize;
1142                 pos.y += offset.y/2;
1143                 ammo_size.y = newSize;
1144         }
1145
1146         int i;
1147         bool infinite_ammo = (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_WEAPON_AMMO);
1148         row = column = 0;
1149         if(autocvar_hud_panel_ammo_onlycurrent)
1150         {
1151                 if(autocvar__hud_configure)
1152                 {
1153                         DrawAmmoItem(pos, ammo_size, ammo_rockets, true, false);
1154                 }
1155                 else
1156                 {
1157                         DrawAmmoItem(
1158                                 pos,
1159                                 ammo_size,
1160                                 (get_weaponinfo(switchweapon)).ammo_field,
1161                                 true,
1162                                 infinite_ammo
1163                         );
1164                 }
1165
1166                 ++row;
1167                 if(row >= rows)
1168                 {
1169                         row = 0;
1170                         column = column + 1;
1171                 }
1172         }
1173         else
1174         {
1175                 .int ammotype;
1176                 row = column = 0;
1177                 for(i = 0; i < AMMO_COUNT; ++i)
1178                 {
1179                         ammotype = GetAmmoFieldFromNum(i);
1180                         DrawAmmoItem(
1181                                 pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y),
1182                                 ammo_size,
1183                                 ammotype,
1184                                 ((get_weaponinfo(switchweapon)).ammo_field == ammotype),
1185                                 infinite_ammo
1186                         );
1187
1188                         ++row;
1189                         if(row >= rows)
1190                         {
1191                                 row = 0;
1192                                 column = column + 1;
1193                         }
1194                 }
1195         }
1196
1197         if (draw_nades)
1198         {
1199                 nade_statuschange_elapsedtime = time - nade_statuschange_time;
1200
1201                 float f = bound(0, nade_statuschange_elapsedtime*2, 1);
1202
1203                 DrawAmmoNades(pos + eX * column * (ammo_size.x + offset.x) + eY * row * (ammo_size.y + offset.y), ammo_size, nade_prevstatus < nade_cnt && nade_cnt != 0 && f < 1, f);
1204         }
1205
1206         draw_endBoldFont();
1207 }
1208
1209 void DrawNumIcon_expanding(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha, float fadelerp)
1210 {
1211         vector newPos = '0 0 0', newSize = '0 0 0';
1212         vector picpos, numpos;
1213
1214         if (vertical)
1215         {
1216                 if(mySize.y/mySize.x > 2)
1217                 {
1218                         newSize.y = 2 * mySize.x;
1219                         newSize.x = mySize.x;
1220
1221                         newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1222                         newPos.x = myPos.x;
1223                 }
1224                 else
1225                 {
1226                         newSize.x = 1/2 * mySize.y;
1227                         newSize.y = mySize.y;
1228
1229                         newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1230                         newPos.y = myPos.y;
1231                 }
1232
1233                 if(icon_right_align)
1234                 {
1235                         numpos = newPos;
1236                         picpos = newPos + eY * newSize.x;
1237                 }
1238                 else
1239                 {
1240                         picpos = newPos;
1241                         numpos = newPos + eY * newSize.x;
1242                 }
1243
1244                 newSize.y /= 2;
1245                 drawpic_aspect_skin(picpos, icon, newSize, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1246                 // make number smaller than icon, it looks better
1247                 // reduce only y to draw numbers with different number of digits with the same y size
1248                 numpos.y += newSize.y * ((1 - 0.7) / 2);
1249                 newSize.y *= 0.7;
1250                 drawstring_aspect(numpos, ftos(x), newSize, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL);
1251                 return;
1252         }
1253
1254         if(mySize.x/mySize.y > 3)
1255         {
1256                 newSize.x = 3 * mySize.y;
1257                 newSize.y = mySize.y;
1258
1259                 newPos.x = myPos.x + (mySize.x - newSize.x) / 2;
1260                 newPos.y = myPos.y;
1261         }
1262         else
1263         {
1264                 newSize.y = 1/3 * mySize.x;
1265                 newSize.x = mySize.x;
1266
1267                 newPos.y = myPos.y + (mySize.y - newSize.y) / 2;
1268                 newPos.x = myPos.x;
1269         }
1270
1271         if(icon_right_align) // right align
1272         {
1273                 numpos = newPos;
1274                 picpos = newPos + eX * 2 * newSize.y;
1275         }
1276         else // left align
1277         {
1278                 numpos = newPos + eX * newSize.y;
1279                 picpos = newPos;
1280         }
1281
1282         // NOTE: newSize_x is always equal to 3 * mySize_y so we can use
1283         // '2 1 0' * newSize_y instead of eX * (2/3) * newSize_x + eY * newSize_y
1284         drawstring_aspect_expanding(numpos, ftos(x), '2 1 0' * newSize.y, color, panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1285         drawpic_aspect_skin_expanding(picpos, icon, '1 1 0' * newSize.y, '1 1 1', panel_fg_alpha * theAlpha, DRAWFLAG_NORMAL, fadelerp);
1286 }
1287
1288 void DrawNumIcon(vector myPos, vector mySize, float x, string icon, bool vertical, bool icon_right_align, vector color, float theAlpha)
1289 {
1290         DrawNumIcon_expanding(myPos, mySize, x, icon, vertical, icon_right_align, color, theAlpha, 0);
1291 }
1292
1293 // Powerups (#2)
1294 //
1295 void HUD_Powerups(void)
1296 {
1297         float strength_time, shield_time, superweapons_time;
1298         if(!autocvar__hud_configure)
1299         {
1300                 if(!autocvar_hud_panel_powerups) return;
1301                 if(spectatee_status == -1) return;
1302                 if(!(getstati(STAT_ITEMS, 0, 24) & (IT_STRENGTH | IT_INVINCIBLE | IT_SUPERWEAPON))) return;
1303                 if (getstati(STAT_HEALTH) <= 0) return;
1304
1305                 strength_time = bound(0, getstatf(STAT_STRENGTH_FINISHED) - time, 99);
1306                 shield_time = bound(0, getstatf(STAT_INVINCIBLE_FINISHED) - time, 99);
1307                 superweapons_time = bound(0, getstatf(STAT_SUPERWEAPONS_FINISHED) - time, 99);
1308
1309                 if (getstati(STAT_ITEMS, 0, 24) & IT_UNLIMITED_SUPERWEAPONS)
1310                         superweapons_time = 99; // force max
1311
1312                 // prevent stuff to show up on mismatch that will be fixed next frame
1313                 if (!(getstati(STAT_ITEMS, 0, 24) & IT_SUPERWEAPON))
1314                         superweapons_time = 0;
1315         }
1316         else
1317         {
1318                 strength_time = 15;
1319                 shield_time = 27;
1320                 superweapons_time = 13;
1321         }
1322
1323         HUD_Panel_UpdateCvars();
1324
1325         draw_beginBoldFont();
1326
1327         vector pos, mySize;
1328         pos = panel_pos;
1329         mySize = panel_size;
1330
1331         HUD_Panel_DrawBg(bound(0, max(strength_time, shield_time, superweapons_time), 1));
1332         if(panel_bg_padding)
1333         {
1334                 pos += '1 1 0' * panel_bg_padding;
1335                 mySize -= '2 2 0' * panel_bg_padding;
1336         }
1337
1338         float panel_ar = mySize.x/mySize.y;
1339         bool is_vertical = (panel_ar < 1);
1340         vector shield_offset = '0 0 0', strength_offset = '0 0 0', superweapons_offset = '0 0 0';
1341
1342         int superweapons_is = -1;
1343
1344         if(superweapons_time)
1345         {
1346                 if(strength_time)
1347                 {
1348                         if(shield_time)
1349                                 superweapons_is = 0;
1350                         else
1351                                 superweapons_is = 2;
1352                 }
1353                 else
1354                 {
1355                         if(shield_time)
1356                                 superweapons_is = 1;
1357                         else
1358                                 superweapons_is = 2;
1359                 }
1360         }
1361
1362         // FIXME handle superweapons here
1363         if(superweapons_is == 0)
1364         {
1365                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1366                 {
1367                         mySize.x *= (1.0 / 3.0);
1368                         superweapons_offset.x = mySize.x;
1369                         if (autocvar_hud_panel_powerups_flip)
1370                                 shield_offset.x = 2*mySize.x;
1371                         else
1372                                 strength_offset.x = 2*mySize.x;
1373                 }
1374                 else
1375                 {
1376                         mySize.y *= (1.0 / 3.0);
1377                         superweapons_offset.y = mySize.y;
1378                         if (autocvar_hud_panel_powerups_flip)
1379                                 shield_offset.y = 2*mySize.y;
1380                         else
1381                                 strength_offset.y = 2*mySize.y;
1382                 }
1383         }
1384         else
1385         {
1386                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1387                 {
1388                         mySize.x *= 0.5;
1389                         if (autocvar_hud_panel_powerups_flip)
1390                                 shield_offset.x = mySize.x;
1391                         else
1392                                 strength_offset.x = mySize.x;
1393                 }
1394                 else
1395                 {
1396                         mySize.y *= 0.5;
1397                         if (autocvar_hud_panel_powerups_flip)
1398                                 shield_offset.y = mySize.y;
1399                         else
1400                                 strength_offset.y = mySize.y;
1401                 }
1402         }
1403
1404         bool shield_baralign, strength_baralign, superweapons_baralign;
1405         bool shield_iconalign, strength_iconalign, superweapons_iconalign;
1406
1407         if (autocvar_hud_panel_powerups_flip)
1408         {
1409                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1410                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1411                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1412                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1413         }
1414         else
1415         {
1416                 shield_baralign = (autocvar_hud_panel_powerups_baralign == 2 || autocvar_hud_panel_powerups_baralign == 1);
1417                 strength_baralign = (autocvar_hud_panel_powerups_baralign == 3 || autocvar_hud_panel_powerups_baralign == 1);
1418                 shield_iconalign = (autocvar_hud_panel_powerups_iconalign == 2 || autocvar_hud_panel_powerups_iconalign == 1);
1419                 strength_iconalign = (autocvar_hud_panel_powerups_iconalign == 3 || autocvar_hud_panel_powerups_iconalign == 1);
1420         }
1421
1422         if(superweapons_is == 0)
1423         {
1424                 superweapons_iconalign = strength_iconalign;
1425                 superweapons_baralign = 2;
1426         }
1427         else if(superweapons_is == 1)
1428         {
1429                 superweapons_offset = strength_offset;
1430                 superweapons_iconalign = strength_iconalign;
1431                 superweapons_baralign = strength_baralign;
1432         }
1433         else // if(superweapons_is == 2)
1434         {
1435                 superweapons_offset = shield_offset;
1436                 superweapons_iconalign = shield_iconalign;
1437                 superweapons_baralign = shield_baralign;
1438         }
1439
1440         if(shield_time)
1441         {
1442                 const float maxshield = 30;
1443                 float shield = ceil(shield_time);
1444                 if(autocvar_hud_panel_powerups_progressbar)
1445                         HUD_Panel_DrawProgressBar(pos + shield_offset, mySize, autocvar_hud_panel_powerups_progressbar_shield, shield/maxshield, is_vertical, shield_baralign, autocvar_hud_progressbar_shield_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1446                 if(autocvar_hud_panel_powerups_text)
1447                 {
1448                         if(shield > 1)
1449                                 DrawNumIcon(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1);
1450                         if(shield <= 5)
1451                                 DrawNumIcon_expanding(pos + shield_offset, mySize, shield, "shield", is_vertical, shield_iconalign, '1 1 1', 1, bound(0, (shield - shield_time) / 0.5, 1));
1452                 }
1453         }
1454
1455         if(strength_time)
1456         {
1457                 const float maxstrength = 30;
1458                 float strength = ceil(strength_time);
1459                 if(autocvar_hud_panel_powerups_progressbar)
1460                         HUD_Panel_DrawProgressBar(pos + strength_offset, mySize, autocvar_hud_panel_powerups_progressbar_strength, strength/maxstrength, is_vertical, strength_baralign, autocvar_hud_progressbar_strength_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1461                 if(autocvar_hud_panel_powerups_text)
1462                 {
1463                         if(strength > 1)
1464                                 DrawNumIcon(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1);
1465                         if(strength <= 5)
1466                                 DrawNumIcon_expanding(pos + strength_offset, mySize, strength, "strength", is_vertical, strength_iconalign, '1 1 1', 1, bound(0, (strength - strength_time) / 0.5, 1));
1467                 }
1468         }
1469
1470         if(superweapons_time)
1471         {
1472                 const float maxsuperweapons = 30;
1473                 float superweapons = ceil(superweapons_time);
1474                 if(autocvar_hud_panel_powerups_progressbar)
1475                         HUD_Panel_DrawProgressBar(pos + superweapons_offset, mySize, autocvar_hud_panel_powerups_progressbar_superweapons, superweapons/maxsuperweapons, is_vertical, superweapons_baralign, autocvar_hud_progressbar_superweapons_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1476                 if(autocvar_hud_panel_powerups_text)
1477                 {
1478                         if(superweapons > 1)
1479                                 DrawNumIcon(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1);
1480                         if(superweapons <= 5)
1481                                 DrawNumIcon_expanding(pos + superweapons_offset, mySize, superweapons, "superweapons", is_vertical, superweapons_iconalign, '1 1 1', 1, bound(0, (superweapons - superweapons_time) / 0.5, 1));
1482                 }
1483         }
1484
1485         draw_endBoldFont();
1486 }
1487
1488 // Health/armor (#3)
1489 //
1490
1491
1492 void HUD_HealthArmor(void)
1493 {
1494         int armor, health, fuel;
1495         if(!autocvar__hud_configure)
1496         {
1497                 if(!autocvar_hud_panel_healtharmor) return;
1498                 if(hud != HUD_NORMAL) return;
1499                 if(spectatee_status == -1) return;
1500
1501                 health = getstati(STAT_HEALTH);
1502                 if(health <= 0)
1503                 {
1504                         prev_health = -1;
1505                         return;
1506                 }
1507                 armor = getstati(STAT_ARMOR);
1508
1509                 // code to check for spectatee_status changes is in Ent_ClientData()
1510                 // prev_p_health and prev_health can be set to -1 there
1511
1512                 if (prev_p_health == -1)
1513                 {
1514                         // no effect
1515                         health_beforedamage = 0;
1516                         armor_beforedamage = 0;
1517                         health_damagetime = 0;
1518                         armor_damagetime = 0;
1519                         prev_health = health;
1520                         prev_armor = armor;
1521                         old_p_health = health;
1522                         old_p_armor = armor;
1523                         prev_p_health = health;
1524                         prev_p_armor = armor;
1525                 }
1526                 else if (prev_health == -1)
1527                 {
1528                         //start the load effect
1529                         health_damagetime = 0;
1530                         armor_damagetime = 0;
1531                         prev_health = 0;
1532                         prev_armor = 0;
1533                 }
1534                 fuel = getstati(STAT_FUEL);
1535         }
1536         else
1537         {
1538                 health = 150;
1539                 armor = 75;
1540                 fuel = 20;
1541         }
1542
1543         HUD_Panel_UpdateCvars();
1544
1545         draw_beginBoldFont();
1546
1547         vector pos, mySize;
1548         pos = panel_pos;
1549         mySize = panel_size;
1550
1551         HUD_Panel_DrawBg(1);
1552         if(panel_bg_padding)
1553         {
1554                 pos += '1 1 0' * panel_bg_padding;
1555                 mySize -= '2 2 0' * panel_bg_padding;
1556         }
1557
1558         int baralign = autocvar_hud_panel_healtharmor_baralign;
1559         int iconalign = autocvar_hud_panel_healtharmor_iconalign;
1560
1561     int maxhealth = autocvar_hud_panel_healtharmor_maxhealth;
1562     int maxarmor = autocvar_hud_panel_healtharmor_maxarmor;
1563         if(autocvar_hud_panel_healtharmor == 2) // combined health and armor display
1564         {
1565                 vector v;
1566                 v = healtharmor_maxdamage(health, armor, armorblockpercent, DEATH_WEAPON);
1567
1568                 float x;
1569                 x = floor(v.x + 1);
1570
1571         float maxtotal = maxhealth + maxarmor;
1572                 string biggercount;
1573                 if(v.z) // NOT fully armored
1574                 {
1575                         biggercount = "health";
1576                         if(autocvar_hud_panel_healtharmor_progressbar)
1577                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_health, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1578                         if(armor)
1579             if(autocvar_hud_panel_healtharmor_text)
1580                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "armor", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha * armor / health, DRAWFLAG_NORMAL);
1581                 }
1582                 else
1583                 {
1584                         biggercount = "armor";
1585                         if(autocvar_hud_panel_healtharmor_progressbar)
1586                                 HUD_Panel_DrawProgressBar(pos, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, x/maxtotal, 0, (baralign == 1 || baralign == 2), autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1587                         if(health)
1588             if(autocvar_hud_panel_healtharmor_text)
1589                                 drawpic_aspect_skin(pos + eX * mySize.x - eX * 0.5 * mySize.y, "health", '0.5 0.5 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
1590                 }
1591         if(autocvar_hud_panel_healtharmor_text)
1592                         DrawNumIcon(pos, mySize, x, biggercount, 0, iconalign, HUD_Get_Num_Color(x, maxtotal), 1);
1593
1594                 if(fuel)
1595                         HUD_Panel_DrawProgressBar(pos, eX * mySize.x + eY * 0.2 * mySize.y, "progressbar", fuel/100, 0, (baralign == 1 || baralign == 3), autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1596         }
1597         else
1598         {
1599                 float panel_ar = mySize.x/mySize.y;
1600                 bool is_vertical = (panel_ar < 1);
1601                 vector health_offset = '0 0 0', armor_offset = '0 0 0';
1602                 if (panel_ar >= 4 || (panel_ar >= 1/4 && panel_ar < 1))
1603                 {
1604                         mySize.x *= 0.5;
1605                         if (autocvar_hud_panel_healtharmor_flip)
1606                                 health_offset.x = mySize.x;
1607                         else
1608                                 armor_offset.x = mySize.x;
1609                 }
1610                 else
1611                 {
1612                         mySize.y *= 0.5;
1613                         if (autocvar_hud_panel_healtharmor_flip)
1614                                 health_offset.y = mySize.y;
1615                         else
1616                                 armor_offset.y = mySize.y;
1617                 }
1618
1619                 bool health_baralign, armor_baralign, fuel_baralign;
1620                 bool health_iconalign, armor_iconalign;
1621                 if (autocvar_hud_panel_healtharmor_flip)
1622                 {
1623                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1624                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1625                         fuel_baralign = health_baralign;
1626                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1627                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1628                 }
1629                 else
1630                 {
1631                         health_baralign = (autocvar_hud_panel_healtharmor_baralign == 2 || autocvar_hud_panel_healtharmor_baralign == 1);
1632                         armor_baralign = (autocvar_hud_panel_healtharmor_baralign == 3 || autocvar_hud_panel_healtharmor_baralign == 1);
1633                         fuel_baralign = armor_baralign;
1634                         health_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 2 || autocvar_hud_panel_healtharmor_iconalign == 1);
1635                         armor_iconalign = (autocvar_hud_panel_healtharmor_iconalign == 3 || autocvar_hud_panel_healtharmor_iconalign == 1);
1636                 }
1637
1638                 //if(health)
1639                 {
1640                         if(autocvar_hud_panel_healtharmor_progressbar)
1641                         {
1642                                 float p_health, pain_health_alpha;
1643                                 p_health = health;
1644                                 pain_health_alpha = 1;
1645                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1646                                 {
1647                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1648                                         {
1649                                                 if (fabs(prev_health - health) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1650                                                 {
1651                                                         if (time - old_p_healthtime < 1)
1652                                                                 old_p_health = prev_p_health;
1653                                                         else
1654                                                                 old_p_health = prev_health;
1655                                                         old_p_healthtime = time;
1656                                                 }
1657                                                 if (time - old_p_healthtime < 1)
1658                                                 {
1659                                                         p_health += (old_p_health - health) * (1 - (time - old_p_healthtime));
1660                                                         prev_p_health = p_health;
1661                                                 }
1662                                         }
1663                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1664                                         {
1665                                                 if (prev_health - health >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1666                                                 {
1667                                                         if (time - health_damagetime >= 1)
1668                                                                 health_beforedamage = prev_health;
1669                                                         health_damagetime = time;
1670                                                 }
1671                                                 if (time - health_damagetime < 1)
1672                                                 {
1673                                                         float health_damagealpha = 1 - (time - health_damagetime)*(time - health_damagetime);
1674                                                         HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, health_beforedamage/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * health_damagealpha, DRAWFLAG_NORMAL);
1675                                                 }
1676                                         }
1677                                         prev_health = health;
1678
1679                                         if (health <= autocvar_hud_panel_healtharmor_progressbar_gfx_lowhealth)
1680                                         {
1681                                                 float BLINK_FACTOR = 0.15;
1682                                                 float BLINK_BASE = 0.85;
1683                                                 float BLINK_FREQ = 9;
1684                                                 pain_health_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
1685                                         }
1686                                 }
1687                                 HUD_Panel_DrawProgressBar(pos + health_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_health, p_health/maxhealth, is_vertical, health_baralign, autocvar_hud_progressbar_health_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * pain_health_alpha, DRAWFLAG_NORMAL);
1688                         }
1689                         if(autocvar_hud_panel_healtharmor_text)
1690                                 DrawNumIcon(pos + health_offset, mySize, health, "health", is_vertical, health_iconalign, HUD_Get_Num_Color(health, maxhealth), 1);
1691                 }
1692
1693                 if(armor)
1694                 {
1695                         if(autocvar_hud_panel_healtharmor_progressbar)
1696                         {
1697                                 float p_armor;
1698                                 p_armor = armor;
1699                                 if (autocvar_hud_panel_healtharmor_progressbar_gfx)
1700                                 {
1701                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_smooth > 0)
1702                                         {
1703                                                 if (fabs(prev_armor - armor) >= autocvar_hud_panel_healtharmor_progressbar_gfx_smooth)
1704                                                 {
1705                                                         if (time - old_p_armortime < 1)
1706                                                                 old_p_armor = prev_p_armor;
1707                                                         else
1708                                                                 old_p_armor = prev_armor;
1709                                                         old_p_armortime = time;
1710                                                 }
1711                                                 if (time - old_p_armortime < 1)
1712                                                 {
1713                                                         p_armor += (old_p_armor - armor) * (1 - (time - old_p_armortime));
1714                                                         prev_p_armor = p_armor;
1715                                                 }
1716                                         }
1717                                         if (autocvar_hud_panel_healtharmor_progressbar_gfx_damage > 0)
1718                                         {
1719                                                 if (prev_armor - armor >= autocvar_hud_panel_healtharmor_progressbar_gfx_damage)
1720                                                 {
1721                                                         if (time - armor_damagetime >= 1)
1722                                                                 armor_beforedamage = prev_armor;
1723                                                         armor_damagetime = time;
1724                                                 }
1725                                                 if (time - armor_damagetime < 1)
1726                                                 {
1727                                                         float armor_damagealpha = 1 - (time - armor_damagetime)*(time - armor_damagetime);
1728                                                         HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, armor_beforedamage/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha * armor_damagealpha, DRAWFLAG_NORMAL);
1729                                                 }
1730                                         }
1731                                         prev_armor = armor;
1732                                 }
1733                                 HUD_Panel_DrawProgressBar(pos + armor_offset, mySize, autocvar_hud_panel_healtharmor_progressbar_armor, p_armor/maxarmor, is_vertical, armor_baralign, autocvar_hud_progressbar_armor_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
1734                         }
1735                         if(autocvar_hud_panel_healtharmor_text)
1736                                 DrawNumIcon(pos + armor_offset, mySize, armor, "armor", is_vertical, armor_iconalign, HUD_Get_Num_Color(armor, maxarmor), 1);
1737                 }
1738
1739                 if(fuel)
1740                 {
1741                         if (is_vertical)
1742                                 mySize.x *= 0.2 / 2; //if vertical always halve x to not cover too much numbers with 3 digits
1743                         else
1744                                 mySize.y *= 0.2;
1745                         if (panel_ar >= 4)
1746                                 mySize.x *= 2; //restore full panel size
1747                         else if (panel_ar < 1/4)
1748                                 mySize.y *= 2; //restore full panel size
1749                         HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", fuel/100, is_vertical, fuel_baralign, autocvar_hud_progressbar_fuel_color, panel_fg_alpha * 0.8, DRAWFLAG_NORMAL);
1750                 }
1751         }
1752
1753         draw_endBoldFont();
1754 }
1755
1756 // Notification area (#4)
1757 //
1758
1759 void HUD_Notify_Push(string icon, string attacker, string victim)
1760 {
1761         if (icon == "")
1762                 return;
1763
1764         ++notify_count;
1765         --notify_index;
1766
1767         if (notify_index == -1)
1768                 notify_index = NOTIFY_MAX_ENTRIES-1;
1769
1770         // Free old strings
1771         if (notify_attackers[notify_index])
1772                 strunzone(notify_attackers[notify_index]);
1773
1774         if (notify_victims[notify_index])
1775                 strunzone(notify_victims[notify_index]);
1776
1777         if (notify_icons[notify_index])
1778                 strunzone(notify_icons[notify_index]);
1779
1780         // Allocate new strings
1781         if (victim != "")
1782         {
1783                 notify_attackers[notify_index] = strzone(attacker);
1784                 notify_victims[notify_index] = strzone(victim);
1785         }
1786         else
1787         {
1788                 // In case of a notification without a victim, the attacker
1789                 // is displayed on the victim's side. Instead of special
1790                 // treatment later on, we can simply switch them here.
1791                 notify_attackers[notify_index] = string_null;
1792                 notify_victims[notify_index] = strzone(attacker);
1793         }
1794
1795         notify_icons[notify_index] = strzone(icon);
1796         notify_times[notify_index] = time;
1797 }
1798
1799 void HUD_Notify(void)
1800 {
1801         if (!autocvar__hud_configure)
1802                 if (!autocvar_hud_panel_notify)
1803                         return;
1804
1805         HUD_Panel_UpdateCvars();
1806         HUD_Panel_DrawBg(1);
1807
1808         if (!autocvar__hud_configure)
1809                 if (notify_count == 0)
1810                         return;
1811
1812         vector pos, size;
1813         pos  = panel_pos;
1814         size = panel_size;
1815
1816         if (panel_bg_padding)
1817         {
1818                 pos  += '1 1 0' * panel_bg_padding;
1819                 size -= '2 2 0' * panel_bg_padding;
1820         }
1821
1822         float fade_start = max(0, autocvar_hud_panel_notify_time);
1823         float fade_time = max(0, autocvar_hud_panel_notify_fadetime);
1824         float icon_aspect = max(1, autocvar_hud_panel_notify_icon_aspect);
1825
1826         int entry_count = bound(1, floor(NOTIFY_MAX_ENTRIES * size.y / size.x), NOTIFY_MAX_ENTRIES);
1827         float entry_height = size.y / entry_count;
1828
1829         float panel_width_half = size.x * 0.5;
1830         float icon_width_half = entry_height * icon_aspect / 2;
1831         float name_maxwidth = panel_width_half - icon_width_half - size.x * NOTIFY_ICON_MARGIN;
1832
1833         vector font_size = '0.5 0.5 0' * entry_height * autocvar_hud_panel_notify_fontsize;
1834         vector icon_size = (eX * icon_aspect + eY) * entry_height;
1835         vector icon_left = eX * (panel_width_half - icon_width_half);
1836         vector attacker_right = eX * name_maxwidth;
1837         vector victim_left = eX * (size.x - name_maxwidth);
1838
1839         vector attacker_pos, victim_pos, icon_pos;
1840         string attacker, victim, icon;
1841         int i, j, count, step, limit;
1842         float alpha;
1843
1844         if (autocvar_hud_panel_notify_flip)
1845         {
1846                 // Order items from the top down
1847                 i = 0;
1848                 step = +1;
1849                 limit = entry_count;
1850         }
1851         else
1852         {
1853                 // Order items from the bottom up
1854                 i = entry_count - 1;
1855                 step = -1;
1856                 limit = -1;
1857         }
1858
1859         for (j = notify_index, count = 0; i != limit; i += step, ++j, ++count)
1860         {
1861                 if(autocvar__hud_configure)
1862                 {
1863                         attacker = sprintf(_("Player %d"), count + 1);
1864                         victim = sprintf(_("Player %d"), count + 2);
1865                         icon = get_weaponinfo(min(WEP_FIRST + count * 2, WEP_LAST)).model2;
1866                         alpha = bound(0, 1.2 - count / entry_count, 1);
1867                 }
1868                 else
1869                 {
1870                         if (j == NOTIFY_MAX_ENTRIES)
1871                                 j = 0;
1872
1873                         if (notify_times[j] + fade_start > time)
1874                                 alpha = 1;
1875                         else if (fade_time != 0)
1876                         {
1877                                 alpha = bound(0, (notify_times[j] + fade_start + fade_time - time) / fade_time, 1);
1878                                 if (alpha == 0)
1879                                         break;
1880                         }
1881                         else
1882                                 break;
1883
1884                         attacker = notify_attackers[j];
1885                         victim = notify_victims[j];
1886                         icon = notify_icons[j];
1887                 }
1888
1889                 if (icon != "" && victim != "")
1890                 {
1891                         vector name_top = eY * (i * entry_height + 0.5 * (entry_height - font_size.y));
1892
1893                         icon_pos = pos + icon_left + eY * i * entry_height;
1894                         drawpic_aspect_skin(icon_pos, icon, icon_size, '1 1 1', panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1895
1896                         victim = textShortenToWidth(victim, name_maxwidth, font_size, stringwidth_colors);
1897                         victim_pos = pos + victim_left + name_top;
1898                         drawcolorcodedstring(victim_pos, victim, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1899
1900                         if (attacker != "")
1901                         {
1902                                 attacker = textShortenToWidth(attacker, name_maxwidth, font_size, stringwidth_colors);
1903                                 attacker_pos = pos + attacker_right - eX * stringwidth(attacker, true, font_size) + name_top;
1904                                 drawcolorcodedstring(attacker_pos, attacker, font_size, panel_fg_alpha * alpha, DRAWFLAG_NORMAL);
1905                         }
1906                 }
1907         }
1908
1909         notify_count = count;
1910 }
1911
1912 // Timer (#5)
1913 //
1914 // TODO: macro
1915 string seconds_tostring(float sec)
1916 {
1917         float minutes;
1918         minutes = floor(sec / 60);
1919
1920         sec -= minutes * 60;
1921         return sprintf("%d:%02d", minutes, sec);
1922 }
1923
1924 void HUD_Timer(void)
1925 {
1926         if(!autocvar__hud_configure)
1927         {
1928                 if(!autocvar_hud_panel_timer) return;
1929         }
1930
1931         HUD_Panel_UpdateCvars();
1932
1933         draw_beginBoldFont();
1934
1935         vector pos, mySize;
1936         pos = panel_pos;
1937         mySize = panel_size;
1938
1939         HUD_Panel_DrawBg(1);
1940         if(panel_bg_padding)
1941         {
1942                 pos += '1 1 0' * panel_bg_padding;
1943                 mySize -= '2 2 0' * panel_bg_padding;
1944         }
1945
1946         string timer;
1947         float timelimit, elapsedTime, timeleft, minutesLeft;
1948
1949         timelimit = getstatf(STAT_TIMELIMIT);
1950
1951         timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
1952         timeleft = ceil(timeleft);
1953
1954         minutesLeft = floor(timeleft / 60);
1955
1956         vector timer_color;
1957         if(minutesLeft >= 5 || warmup_stage || timelimit == 0) //don't use red or yellow in warmup or when there is no timelimit
1958                 timer_color = '1 1 1'; //white
1959         else if(minutesLeft >= 1)
1960                 timer_color = '1 1 0'; //yellow
1961         else
1962                 timer_color = '1 0 0'; //red
1963
1964         if (autocvar_hud_panel_timer_increment || timelimit == 0 || warmup_stage) {
1965                 if (time < getstatf(STAT_GAMESTARTTIME)) {
1966                         //while restart is still active, show 00:00
1967                         timer = seconds_tostring(0);
1968                 } else {
1969                         elapsedTime = floor(time - getstatf(STAT_GAMESTARTTIME)); //127
1970                         timer = seconds_tostring(elapsedTime);
1971                 }
1972         } else {
1973                 timer = seconds_tostring(timeleft);
1974         }
1975
1976         drawstring_aspect(pos, timer, mySize, timer_color, panel_fg_alpha, DRAWFLAG_NORMAL);
1977
1978         draw_endBoldFont();
1979 }
1980
1981 // Radar (#6)
1982 //
1983 void HUD_Radar(void)
1984 {
1985         if (!autocvar__hud_configure)
1986         {
1987                 if (hud_panel_radar_maximized)
1988                 {
1989                         if (!hud_draw_maximized) return;
1990                 }
1991                 else
1992                 {
1993                         if (autocvar_hud_panel_radar == 0) return;
1994                         if (autocvar_hud_panel_radar != 2 && !teamplay) return;
1995                         if(radar_panel_modified)
1996                         {
1997                                 panel.update_time = time; // forces reload of panel attributes
1998                                 radar_panel_modified = false;
1999                         }
2000                 }
2001         }
2002
2003         HUD_Panel_UpdateCvars();
2004
2005         float f = 0;
2006
2007         if (hud_panel_radar_maximized && !autocvar__hud_configure)
2008         {
2009                 panel_size = autocvar_hud_panel_radar_maximized_size;
2010                 panel_size.x = bound(0.2, panel_size.x, 1) * vid_conwidth;
2011                 panel_size.y = bound(0.2, panel_size.y, 1) * vid_conheight;
2012                 panel_pos.x = (vid_conwidth - panel_size.x) / 2;
2013                 panel_pos.y = (vid_conheight - panel_size.y) / 2;
2014
2015                 string panel_bg;
2016                 panel_bg = strcat(hud_skin_path, "/border_default"); // always use the default border when maximized
2017                 if(precache_pic(panel_bg) == "")
2018                         panel_bg = "gfx/hud/default/border_default"; // fallback
2019                 if(!radar_panel_modified && panel_bg != panel.current_panel_bg)
2020                         radar_panel_modified = true;
2021                 if(panel.current_panel_bg)
2022                         strunzone(panel.current_panel_bg);
2023                 panel.current_panel_bg = strzone(panel_bg);
2024
2025                 switch(hud_panel_radar_maximized_zoommode)
2026                 {
2027                         default:
2028                         case 0:
2029                                 f = current_zoomfraction;
2030                                 break;
2031                         case 1:
2032                                 f = 1 - current_zoomfraction;
2033                                 break;
2034                         case 2:
2035                                 f = 0;
2036                                 break;
2037                         case 3:
2038                                 f = 1;
2039                                 break;
2040                 }
2041
2042                 switch(hud_panel_radar_maximized_rotation)
2043                 {
2044                         case 0:
2045                                 teamradar_angle = view_angles.y - 90;
2046                                 break;
2047                         default:
2048                                 teamradar_angle = 90 * hud_panel_radar_maximized_rotation;
2049                                 break;
2050                 }
2051         }
2052         if (!hud_panel_radar_maximized && !autocvar__hud_configure)
2053         {
2054                 switch(hud_panel_radar_zoommode)
2055                 {
2056                         default:
2057                         case 0:
2058                                 f = current_zoomfraction;
2059                                 break;
2060                         case 1:
2061                                 f = 1 - current_zoomfraction;
2062                                 break;
2063                         case 2:
2064                                 f = 0;
2065                                 break;
2066                         case 3:
2067                                 f = 1;
2068                                 break;
2069                 }
2070
2071                 switch(hud_panel_radar_rotation)
2072                 {
2073                         case 0:
2074                                 teamradar_angle = view_angles.y - 90;
2075                                 break;
2076                         default:
2077                                 teamradar_angle = 90 * hud_panel_radar_rotation;
2078                                 break;
2079                 }
2080         }
2081
2082         vector pos, mySize;
2083         pos = panel_pos;
2084         mySize = panel_size;
2085
2086         HUD_Panel_DrawBg(1);
2087         if(panel_bg_padding)
2088         {
2089                 pos += '1 1 0' * panel_bg_padding;
2090                 mySize -= '2 2 0' * panel_bg_padding;
2091         }
2092
2093         int color2;
2094         entity tm;
2095         float scale2d, normalsize, bigsize;
2096
2097         teamradar_origin2d = pos + 0.5 * mySize;
2098         teamradar_size2d = mySize;
2099
2100         if(minimapname == "")
2101                 return;
2102
2103         teamradar_loadcvars();
2104
2105         scale2d = vlen_maxnorm2d(mi_picmax - mi_picmin);
2106         teamradar_size2d = mySize;
2107
2108         teamradar_extraclip_mins = teamradar_extraclip_maxs = '0 0 0'; // we always center
2109
2110         // pixels per world qu to match the teamradar_size2d_x range in the longest dimension
2111         if((hud_panel_radar_rotation == 0 && !hud_panel_radar_maximized) || (hud_panel_radar_maximized_rotation == 0 && hud_panel_radar_maximized))
2112         {
2113                 // max-min distance must fit the radar in any rotation
2114                 bigsize = vlen_minnorm2d(teamradar_size2d) * scale2d / (1.05 * vlen2d(mi_scale));
2115         }
2116         else
2117         {
2118                 vector c0, c1, c2, c3, span;
2119                 c0 = rotate(mi_min, teamradar_angle * DEG2RAD);
2120                 c1 = rotate(mi_max, teamradar_angle * DEG2RAD);
2121                 c2 = rotate('1 0 0' * mi_min.x + '0 1 0' * mi_max.y, teamradar_angle * DEG2RAD);
2122                 c3 = rotate('1 0 0' * mi_max.x + '0 1 0' * mi_min.y, teamradar_angle * DEG2RAD);
2123                 span = '0 0 0';
2124                 span.x = max(c0_x, c1_x, c2_x, c3_x) - min(c0_x, c1_x, c2_x, c3_x);
2125                 span.y = max(c0_y, c1_y, c2_y, c3_y) - min(c0_y, c1_y, c2_y, c3_y);
2126
2127                 // max-min distance must fit the radar in x=x, y=y
2128                 bigsize = min(
2129                         teamradar_size2d.x * scale2d / (1.05 * span.x),
2130                         teamradar_size2d.y * scale2d / (1.05 * span.y)
2131                 );
2132         }
2133
2134         normalsize = vlen_maxnorm2d(teamradar_size2d) * scale2d / hud_panel_radar_scale;
2135         if(bigsize > normalsize)
2136                 normalsize = bigsize;
2137
2138         teamradar_size =
2139                   f * bigsize
2140                 + (1 - f) * normalsize;
2141         teamradar_origin3d_in_texcoord = teamradar_3dcoord_to_texcoord(
2142                   f * mi_center
2143                 + (1 - f) * view_origin);
2144
2145         drawsetcliparea(
2146                 pos.x,
2147                 pos.y,
2148                 mySize.x,
2149                 mySize.y
2150         );
2151
2152         draw_teamradar_background(hud_panel_radar_foreground_alpha);
2153
2154         for(tm = world; (tm = find(tm, classname, "radarlink")); )
2155                 draw_teamradar_link(tm.origin, tm.velocity, tm.team);
2156         for(tm = world; (tm = findflags(tm, teamradar_icon, 0xFFFFFF)); )
2157                 draw_teamradar_icon(tm.origin, tm.teamradar_icon, tm, tm.teamradar_color, panel_fg_alpha);
2158         for(tm = world; (tm = find(tm, classname, "entcs_receiver")); )
2159         {
2160                 color2 = GetPlayerColor(tm.sv_entnum);
2161                 //if(color == NUM_SPECTATOR || color == color2)
2162                         draw_teamradar_player(tm.origin, tm.angles, Team_ColorRGB(color2));
2163         }
2164         draw_teamradar_player(view_origin, view_angles, '1 1 1');
2165
2166         drawresetcliparea();
2167 }
2168
2169 // Score (#7)
2170 //
2171 void HUD_UpdatePlayerTeams();
2172 void HUD_Score_Rankings(vector pos, vector mySize, entity me)
2173 {
2174         float score;
2175         entity tm = world, pl;
2176         int SCOREPANEL_MAX_ENTRIES = 6;
2177         float SCOREPANEL_ASPECTRATIO = 2;
2178         int entries = bound(1, floor(SCOREPANEL_MAX_ENTRIES * mySize.y/mySize.x * SCOREPANEL_ASPECTRATIO), SCOREPANEL_MAX_ENTRIES);
2179         vector fontsize = '1 1 0' * (mySize.y/entries);
2180
2181         vector rgb, score_color;
2182         rgb = '1 1 1';
2183         score_color = '1 1 1';
2184
2185         float name_size = mySize.x*0.75;
2186         float spacing_size = mySize.x*0.04;
2187         const float highlight_alpha = 0.2;
2188         int i = 0, first_pl = 0;
2189         bool me_printed = false;
2190         string s;
2191         if (autocvar__hud_configure)
2192         {
2193                 float players_per_team = 0;
2194                 if (team_count)
2195                 {
2196                         // show team scores in the first line
2197                         float score_size = mySize.x / team_count;
2198                         players_per_team = max(2, ceil((entries - 1) / team_count));
2199                         for(i=0; i<team_count; ++i) {
2200                                 if (i == floor((entries - 2) / players_per_team) || (entries == 1 && i == 0))
2201                                         HUD_Panel_DrawHighlight(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2202                                 drawstring_aspect(pos + eX * score_size * i, ftos(175 - 23*i), eX * score_size + eY * fontsize.y, Team_ColorRGB(ColorByTeam(i)) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2203                         }
2204                         first_pl = 1;
2205                         pos.y += fontsize.y;
2206                 }
2207                 score = 10 + SCOREPANEL_MAX_ENTRIES * 3;
2208                 for (i=first_pl; i<entries; ++i)
2209                 {
2210                         //simulate my score is lower than all displayed players,
2211                         //so that I don't appear at all showing pure rankings.
2212                         //This is to better show the difference between the 2 ranking views
2213                         if (i == entries-1 && autocvar_hud_panel_score_rankings == 1)
2214                         {
2215                                 rgb = '1 1 0';
2216                                 drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2217                                 s = GetPlayerName(player_localnum);
2218                                 score = 7;
2219                         }
2220                         else
2221                         {
2222                                 s = sprintf(_("Player %d"), i + 1 - first_pl);
2223                                 score -= 3;
2224                         }
2225
2226                         if (team_count)
2227                                 score_color = Team_ColorRGB(ColorByTeam(floor((i - first_pl) / players_per_team))) * 0.8;
2228                         s = textShortenToWidth(s, name_size, fontsize, stringwidth_colors);
2229                         drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2230                         drawstring(pos + eX * (name_size + spacing_size), ftos(score), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2231                         pos.y += fontsize.y;
2232                 }
2233                 return;
2234         }
2235
2236         if (!scoreboard_fade_alpha) // the scoreboard too calls HUD_UpdatePlayerTeams
2237                 HUD_UpdatePlayerTeams();
2238         if (team_count)
2239         {
2240                 // show team scores in the first line
2241                 float score_size = mySize.x / team_count;
2242                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2243                         if(tm.team == NUM_SPECTATOR)
2244                                 continue;
2245                         if (tm.team == myteam)
2246                                 drawfill(pos + eX * score_size * i, eX * score_size + eY * fontsize.y, '1 1 1', highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2247                         drawstring_aspect(pos + eX * score_size * i, ftos(tm.(teamscores[ts_primary])), eX * score_size + eY * fontsize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2248                         ++i;
2249                 }
2250                 first_pl = 1;
2251                 pos.y += fontsize.y;
2252                 tm = teams.sort_next;
2253         }
2254         i = first_pl;
2255
2256         do
2257         for (pl = players.sort_next; pl && i<entries; pl = pl.sort_next)
2258         {
2259                 if ((team_count && pl.team != tm.team) || pl.team == NUM_SPECTATOR)
2260                         continue;
2261
2262                 if (i == entries-1 && !me_printed && pl != me)
2263                 if (autocvar_hud_panel_score_rankings == 1 && spectatee_status != -1)
2264                 {
2265                         for (pl = me.sort_next; pl; pl = pl.sort_next)
2266                                 if (pl.team != NUM_SPECTATOR)
2267                                         break;
2268
2269                         if (pl)
2270                                 rgb = '1 1 0'; //not last but not among the leading players: yellow
2271                         else
2272                                 rgb = '1 0 0'; //last: red
2273                         pl = me;
2274                 }
2275
2276                 if (pl == me)
2277                 {
2278                         if (i == first_pl)
2279                                 rgb = '0 1 0'; //first: green
2280                         me_printed = true;
2281                         drawfill(pos, eX * mySize.x + eY * fontsize.y, rgb, highlight_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
2282                 }
2283                 if (team_count)
2284                         score_color = Team_ColorRGB(pl.team) * 0.8;
2285                 s = textShortenToWidth(GetPlayerName(pl.sv_entnum), name_size, fontsize, stringwidth_colors);
2286                 drawcolorcodedstring(pos + eX * (name_size - stringwidth(s, true, fontsize)), s, fontsize, panel_fg_alpha, DRAWFLAG_NORMAL);
2287                 drawstring(pos + eX * (name_size + spacing_size), ftos(pl.(scores[ps_primary])), fontsize, score_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2288                 pos.y += fontsize.y;
2289                 ++i;
2290         }
2291         while (i<entries && team_count && (tm = tm.sort_next) && (tm.team != NUM_SPECTATOR || (tm = tm.sort_next)));
2292 }
2293
2294 void HUD_Score(void)
2295 {
2296         if(!autocvar__hud_configure)
2297         {
2298                 if(!autocvar_hud_panel_score) return;
2299                 if(spectatee_status == -1 && (gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2300         }
2301
2302         HUD_Panel_UpdateCvars();
2303         vector pos, mySize;
2304         pos = panel_pos;
2305         mySize = panel_size;
2306
2307         HUD_Panel_DrawBg(1);
2308         if(panel_bg_padding)
2309         {
2310                 pos += '1 1 0' * panel_bg_padding;
2311                 mySize -= '2 2 0' * panel_bg_padding;
2312         }
2313
2314         float score, distribution = 0;
2315         string sign;
2316         vector distribution_color;
2317         entity tm, pl, me;
2318
2319         me = playerslots[current_player];
2320
2321         if((scores_flags[ps_primary] & SFL_TIME) && !teamplay) { // race/cts record display on HUD
2322                 string timer, distrtimer;
2323
2324                 pl = players.sort_next;
2325                 if(pl == me)
2326                         pl = pl.sort_next;
2327                 if(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)
2328                         if(pl.scores[ps_primary] == 0)
2329                                 pl = world;
2330
2331                 score = me.(scores[ps_primary]);
2332                 timer = TIME_ENCODED_TOSTRING(score);
2333
2334                 draw_beginBoldFont();
2335                 if (pl && ((!(scores_flags[ps_primary] & SFL_ZERO_IS_WORST)) || score)) {
2336                         // distribution display
2337                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2338
2339                         distrtimer = ftos_decimals(fabs(distribution/pow(10, TIME_DECIMALS)), TIME_DECIMALS);
2340
2341                         if (distribution <= 0) {
2342                                 distribution_color = '0 1 0';
2343                                 sign = "-";
2344                         }
2345                         else {
2346                                 distribution_color = '1 0 0';
2347                                 sign = "+";
2348                         }
2349                         drawstring_aspect(pos + eX * 0.75 * mySize.x, strcat(sign, distrtimer), eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2350                 }
2351                 // race record display
2352                 if (distribution <= 0)
2353                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2354                 drawstring_aspect(pos, timer, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2355                 draw_endBoldFont();
2356         } else if (!teamplay) { // non-teamgames
2357                 if ((spectatee_status == -1 && !autocvar__hud_configure) || autocvar_hud_panel_score_rankings)
2358                 {
2359                         HUD_Score_Rankings(pos, mySize, me);
2360                         return;
2361                 }
2362                 // me vector := [team/connected frags id]
2363                 pl = players.sort_next;
2364                 if(pl == me)
2365                         pl = pl.sort_next;
2366
2367                 if(autocvar__hud_configure)
2368                         distribution = 42;
2369                 else if(pl)
2370                         distribution = me.(scores[ps_primary]) - pl.(scores[ps_primary]);
2371                 else
2372                         distribution = 0;
2373
2374                 score = me.(scores[ps_primary]);
2375                 if(autocvar__hud_configure)
2376                         score = 123;
2377
2378                 if(distribution >= 5)
2379                         distribution_color = eY;
2380                 else if(distribution >= 0)
2381                         distribution_color = '1 1 1';
2382                 else if(distribution >= -5)
2383                         distribution_color = '1 1 0';
2384                 else
2385                         distribution_color = eX;
2386
2387                 string distribution_str;
2388                 distribution_str = ftos(distribution);
2389                 draw_beginBoldFont();
2390                 if (distribution >= 0)
2391                 {
2392                         if (distribution > 0)
2393                                 distribution_str = strcat("+", distribution_str);
2394                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2395                 }
2396                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2397                 drawstring_aspect(pos + eX * 0.75 * mySize.x, distribution_str, eX * 0.25 * mySize.x + eY * (1/3) * mySize.y, distribution_color, panel_fg_alpha, DRAWFLAG_NORMAL);
2398                 draw_endBoldFont();
2399         } else { // teamgames
2400                 float row, column, rows = 0, columns = 0;
2401                 vector offset = '0 0 0';
2402                 vector score_pos, score_size; //for scores other than myteam
2403                 if(autocvar_hud_panel_score_rankings)
2404                 {
2405                         HUD_Score_Rankings(pos, mySize, me);
2406                         return;
2407                 }
2408                 if(spectatee_status == -1)
2409                 {
2410                         rows = HUD_GetRowCount(team_count, mySize, 3);
2411                         columns = ceil(team_count/rows);
2412                         score_size = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2413
2414                         float newSize;
2415                         if(score_size.x/score_size.y > 3)
2416                         {
2417                                 newSize = 3 * score_size.y;
2418                                 offset.x = score_size.x - newSize;
2419                                 pos.x += offset.x/2;
2420                                 score_size.x = newSize;
2421                         }
2422                         else
2423                         {
2424                                 newSize = 1/3 * score_size.x;
2425                                 offset.y = score_size.y - newSize;
2426                                 pos.y += offset.y/2;
2427                                 score_size.y = newSize;
2428                         }
2429                 }
2430                 else
2431                         score_size = eX * mySize.x*(1/4) + eY * mySize.y*(1/3);
2432
2433                 float max_fragcount;
2434                 max_fragcount = -99;
2435                 draw_beginBoldFont();
2436                 row = column = 0;
2437                 for(tm = teams.sort_next; tm; tm = tm.sort_next) {
2438                         if(tm.team == NUM_SPECTATOR)
2439                                 continue;
2440                         score = tm.(teamscores[ts_primary]);
2441                         if(autocvar__hud_configure)
2442                                 score = 123;
2443
2444                         if (score > max_fragcount)
2445                                 max_fragcount = score;
2446
2447                         if (spectatee_status == -1)
2448                         {
2449                                 score_pos = pos + eX * column * (score_size.x + offset.x) + eY * row * (score_size.y + offset.y);
2450                                 if (max_fragcount == score)
2451                                         HUD_Panel_DrawHighlight(score_pos, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2452                                 drawstring_aspect(score_pos, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2453                                 ++row;
2454                                 if(row >= rows)
2455                                 {
2456                                         row = 0;
2457                                         ++column;
2458                                 }
2459                         }
2460                         else if(tm.team == myteam) {
2461                                 if (max_fragcount == score)
2462                                         HUD_Panel_DrawHighlight(pos, eX * 0.75 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2463                                 drawstring_aspect(pos, ftos(score), eX * 0.75 * mySize.x + eY * mySize.y, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2464                         } else {
2465                                 if (max_fragcount == score)
2466                                         HUD_Panel_DrawHighlight(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, score_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2467                                 drawstring_aspect(pos + eX * 0.75 * mySize.x + eY * (1/3) * rows * mySize.y, ftos(score), score_size, Team_ColorRGB(tm.team) * 0.8, panel_fg_alpha, DRAWFLAG_NORMAL);
2468                                 ++rows;
2469                         }
2470                 }
2471                 draw_endBoldFont();
2472         }
2473 }
2474
2475 // Race timer (#8)
2476 //
2477 void HUD_RaceTimer (void)
2478 {
2479         if(!autocvar__hud_configure)
2480         {
2481                 if(!autocvar_hud_panel_racetimer) return;
2482                 if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
2483                 if(spectatee_status == -1) return;
2484         }
2485
2486         HUD_Panel_UpdateCvars();
2487
2488         vector pos, mySize;
2489         pos = panel_pos;
2490         mySize = panel_size;
2491
2492         HUD_Panel_DrawBg(1);
2493         if(panel_bg_padding)
2494         {
2495                 pos += '1 1 0' * panel_bg_padding;
2496                 mySize -= '2 2 0' * panel_bg_padding;
2497         }
2498
2499         // always force 4:1 aspect
2500         vector newSize = '0 0 0';
2501         if(mySize.x/mySize.y > 4)
2502         {
2503                 newSize.x = 4 * mySize.y;
2504                 newSize.y = mySize.y;
2505
2506                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2507         }
2508         else
2509         {
2510                 newSize.y = 1/4 * mySize.x;
2511                 newSize.x = mySize.x;
2512
2513                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2514         }
2515         mySize = newSize;
2516
2517         float a, t;
2518         string s, forcetime;
2519
2520         if(autocvar__hud_configure)
2521         {
2522                 s = "0:13:37";
2523                 draw_beginBoldFont();
2524                 drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.60 0.60 0' * mySize.y), s, '0.60 0.60 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2525                 draw_endBoldFont();
2526                 s = _("^1Intermediate 1 (+15.42)");
2527                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.60 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2528                 s = sprintf(_("^1PENALTY: %.1f (%s)"), 2, "missing a checkpoint");
2529                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.20 * mySize.y) + eY * 0.80 * mySize.y, s, '1 1 0' * 0.20 * mySize.y, panel_fg_alpha, DRAWFLAG_NORMAL);
2530         }
2531         else if(race_checkpointtime)
2532         {
2533                 a = bound(0, 2 - (time - race_checkpointtime), 1);
2534                 s = "";
2535                 forcetime = "";
2536                 if(a > 0) // just hit a checkpoint?
2537                 {
2538                         if(race_checkpoint != 254)
2539                         {
2540                                 if(race_time && race_previousbesttime)
2541                                         s = MakeRaceString(race_checkpoint, TIME_DECODE(race_time) - TIME_DECODE(race_previousbesttime), 0, 0, race_previousbestname);
2542                                 else
2543                                         s = MakeRaceString(race_checkpoint, 0, -1, 0, race_previousbestname);
2544                                 if(race_time)
2545                                         forcetime = TIME_ENCODED_TOSTRING(race_time);
2546                         }
2547                 }
2548                 else
2549                 {
2550                         if(race_laptime && race_nextbesttime && race_nextcheckpoint != 254)
2551                         {
2552                                 a = bound(0, 2 - ((race_laptime + TIME_DECODE(race_nextbesttime)) - (time + TIME_DECODE(race_penaltyaccumulator))), 1);
2553                                 if(a > 0) // next one?
2554                                 {
2555                                         s = MakeRaceString(race_nextcheckpoint, (time + TIME_DECODE(race_penaltyaccumulator)) - race_laptime, TIME_DECODE(race_nextbesttime), 0, race_nextbestname);
2556                                 }
2557                         }
2558                 }
2559
2560                 if(s != "" && a > 0)
2561                 {
2562                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2563                 }
2564
2565                 if(race_penaltytime)
2566                 {
2567                         a = bound(0, 2 - (time - race_penaltyeventtime), 1);
2568                         if(a > 0)
2569                         {
2570                                 s = sprintf(_("^1PENALTY: %.1f (%s)"), race_penaltytime * 0.1, race_penaltyreason);
2571                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.8 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2572                         }
2573                 }
2574
2575                 draw_beginBoldFont();
2576
2577                 if(forcetime != "")
2578                 {
2579                         a = bound(0, (time - race_checkpointtime) / 0.5, 1);
2580                         drawstring_expanding(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(forcetime, false, '1 1 0' * 0.6 * mySize.y), forcetime, '1 1 0' * 0.6 * mySize.y, '1 1 1', panel_fg_alpha, 0, a);
2581                 }
2582                 else
2583                         a = 1;
2584
2585                 if(race_laptime && race_checkpoint != 255)
2586                 {
2587                         s = TIME_ENCODED_TOSTRING(TIME_ENCODE(time + TIME_DECODE(race_penaltyaccumulator) - race_laptime));
2588                         drawstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, false, '0.6 0.6 0' * mySize.y), s, '0.6 0.6 0' * mySize.y, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
2589                 }
2590
2591                 draw_endBoldFont();
2592         }
2593         else
2594         {
2595                 if(race_mycheckpointtime)
2596                 {
2597                         a = bound(0, 2 - (time - race_mycheckpointtime), 1);
2598                         s = MakeRaceString(race_mycheckpoint, TIME_DECODE(race_mycheckpointdelta), -(race_mycheckpointenemy == ""), race_mycheckpointlapsdelta, race_mycheckpointenemy);
2599                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2600                 }
2601                 if(race_othercheckpointtime && race_othercheckpointenemy != "")
2602                 {
2603                         a = bound(0, 2 - (time - race_othercheckpointtime), 1);
2604                         s = MakeRaceString(race_othercheckpoint, -TIME_DECODE(race_othercheckpointdelta), -(race_othercheckpointenemy == ""), race_othercheckpointlapsdelta, race_othercheckpointenemy);
2605                         drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2606                 }
2607
2608                 if(race_penaltytime && !race_penaltyaccumulator)
2609                 {
2610                         t = race_penaltytime * 0.1 + race_penaltyeventtime;
2611                         a = bound(0, (1 + t - time), 1);
2612                         if(a > 0)
2613                         {
2614                                 if(time < t)
2615                                         s = sprintf(_("^1PENALTY: %.1f (%s)"), (t - time) * 0.1, race_penaltyreason);
2616                                 else
2617                                         s = sprintf(_("^2PENALTY: %.1f (%s)"), 0, race_penaltyreason);
2618                                 drawcolorcodedstring(pos + eX * 0.5 * mySize.x - '0.5 0 0' * stringwidth(s, true, '1 1 0' * 0.2 * mySize.y) + eY * 0.6 * mySize.y, s, '1 1 0' * 0.2 * mySize.y, panel_fg_alpha * a, DRAWFLAG_NORMAL);
2619                         }
2620                 }
2621         }
2622 }
2623
2624 // Vote window (#9)
2625 //
2626
2627 void HUD_Vote(void)
2628 {
2629         if(autocvar_cl_allow_uid2name == -1 && (gametype == MAPINFO_TYPE_CTS || gametype == MAPINFO_TYPE_RACE || (serverflags & SERVERFLAG_PLAYERSTATS)))
2630         {
2631                 vote_active = 1;
2632                 if (autocvar__hud_configure)
2633                 {
2634                         vote_yescount = 0;
2635                         vote_nocount = 0;
2636                         print(_("^1You must answer before entering hud configure mode\n"));
2637                         cvar_set("_hud_configure", "0");
2638                 }
2639                 if(vote_called_vote)
2640                         strunzone(vote_called_vote);
2641                 vote_called_vote = strzone(_("^2Name ^7instead of \"^1Anonymous player^7\" in stats"));
2642                 uid2name_dialog = 1;
2643         }
2644
2645         if(!autocvar__hud_configure)
2646         {
2647                 if(!autocvar_hud_panel_vote) return;
2648
2649                 panel_fg_alpha = autocvar_hud_panel_fg_alpha;
2650                 panel_bg_alpha_str = autocvar_hud_panel_vote_bg_alpha;
2651
2652                 if(panel_bg_alpha_str == "") {
2653                         panel_bg_alpha_str = ftos(autocvar_hud_panel_bg_alpha);
2654                 }
2655                 panel_bg_alpha = stof(panel_bg_alpha_str);
2656         }
2657         else
2658         {
2659                 vote_yescount = 3;
2660                 vote_nocount = 2;
2661                 vote_needed = 4;
2662         }
2663
2664         string s;
2665         float a;
2666         if(vote_active != vote_prev) {
2667                 vote_change = time;
2668                 vote_prev = vote_active;
2669         }
2670
2671         if(vote_active || autocvar__hud_configure)
2672                 vote_alpha = bound(0, (time - vote_change) * 2, 1);
2673         else
2674                 vote_alpha = bound(0, 1 - (time - vote_change) * 2, 1);
2675
2676         if(!vote_alpha)
2677                 return;
2678
2679         HUD_Panel_UpdateCvars();
2680
2681         if(uid2name_dialog)
2682         {
2683                 panel_pos = eX * 0.3 * vid_conwidth + eY * 0.1 * vid_conheight;
2684                 panel_size = eX * 0.4 * vid_conwidth + eY * 0.3 * vid_conheight;
2685         }
2686
2687     // these must be below above block
2688         vector pos, mySize;
2689         pos = panel_pos;
2690         mySize = panel_size;
2691
2692         a = vote_alpha * (vote_highlighted ? autocvar_hud_panel_vote_alreadyvoted_alpha : 1);
2693         HUD_Panel_DrawBg(a);
2694         a = panel_fg_alpha * a;
2695
2696         if(panel_bg_padding)
2697         {
2698                 pos += '1 1 0' * panel_bg_padding;
2699                 mySize -= '2 2 0' * panel_bg_padding;
2700         }
2701
2702         // always force 3:1 aspect
2703         vector newSize = '0 0 0';
2704         if(mySize.x/mySize.y > 3)
2705         {
2706                 newSize.x = 3 * mySize.y;
2707                 newSize.y = mySize.y;
2708
2709                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
2710         }
2711         else
2712         {
2713                 newSize.y = 1/3 * mySize.x;
2714                 newSize.x = mySize.x;
2715
2716                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
2717         }
2718         mySize = newSize;
2719
2720         s = _("A vote has been called for:");
2721         if(uid2name_dialog)
2722                 s = _("Allow servers to store and display your name?");
2723         drawstring_aspect(pos, s, eX * mySize.x + eY * (2/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2724         s = textShortenToWidth(vote_called_vote, mySize.x, '1 1 0' * mySize.y * (1/8), stringwidth_colors);
2725         if(autocvar__hud_configure)
2726                 s = _("^1Configure the HUD");
2727         drawcolorcodedstring_aspect(pos + eY * (2/8) * mySize.y, s, eX * mySize.x + eY * (1.75/8) * mySize.y, a, DRAWFLAG_NORMAL);
2728
2729         // print the yes/no counts
2730     s = sprintf(_("Yes (%s): %d"), getcommandkey("vyes", "vyes"), vote_yescount);
2731         drawstring_aspect(pos + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '0 1 0', a, DRAWFLAG_NORMAL);
2732     s = sprintf(_("No (%s): %d"), getcommandkey("vno", "vno"), vote_nocount);
2733         drawstring_aspect(pos + eX * 0.5 * mySize.x + eY * (4/8) * mySize.y, s, eX * 0.5 * mySize.x + eY * (1.5/8) * mySize.y, '1 0 0', a, DRAWFLAG_NORMAL);
2734
2735         // draw the progress bar backgrounds
2736         drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_back", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2737
2738         // draw the highlights
2739         if(vote_highlighted == 1) {
2740                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5, mySize.y);
2741                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2742         }
2743         else if(vote_highlighted == -1) {
2744                 drawsetcliparea(pos.x + 0.5 * mySize.x, pos.y, mySize.x * 0.5, mySize.y);
2745                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_voted", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2746         }
2747
2748         // draw the progress bars
2749         if(vote_yescount && vote_needed)
2750         {
2751                 drawsetcliparea(pos.x, pos.y, mySize.x * 0.5 * (vote_yescount/vote_needed), mySize.y);
2752                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2753         }
2754
2755         if(vote_nocount && vote_needed)
2756         {
2757                 drawsetcliparea(pos.x + mySize.x - mySize.x * 0.5 * (vote_nocount/vote_needed), pos.y, mySize.x * 0.5, mySize.y);
2758                 drawpic_skin(pos + eY * (5/8) * mySize.y, "voteprogress_prog", eX * mySize.x + eY * (3/8) * mySize.y, '1 1 1', a, DRAWFLAG_NORMAL);
2759         }
2760
2761         drawresetcliparea();
2762 }
2763
2764 // Mod icons panel (#10)
2765 //
2766
2767 bool mod_active; // is there any active mod icon?
2768
2769 void DrawCAItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
2770 {
2771         int stat = -1;
2772         string pic = "";
2773         vector color = '0 0 0';
2774         switch(i)
2775         {
2776                 case 0:
2777                         stat = getstati(STAT_REDALIVE);
2778                         pic = "player_red.tga";
2779                         color = '1 0 0';
2780                         break;
2781                 case 1:
2782                         stat = getstati(STAT_BLUEALIVE);
2783                         pic = "player_blue.tga";
2784                         color = '0 0 1';
2785                         break;
2786                 case 2:
2787                         stat = getstati(STAT_YELLOWALIVE);
2788                         pic = "player_yellow.tga";
2789                         color = '1 1 0';
2790                         break;
2791                 default:
2792                 case 3:
2793                         stat = getstati(STAT_PINKALIVE);
2794                         pic = "player_pink.tga";
2795                         color = '1 0 1';
2796                         break;
2797         }
2798
2799         if(mySize.x/mySize.y > aspect_ratio)
2800         {
2801                 i = aspect_ratio * mySize.y;
2802                 myPos.x = myPos.x + (mySize.x - i) / 2;
2803                 mySize.x = i;
2804         }
2805         else
2806         {
2807                 i = 1/aspect_ratio * mySize.x;
2808                 myPos.y = myPos.y + (mySize.y - i) / 2;
2809                 mySize.y = i;
2810         }
2811
2812         if(layout)
2813         {
2814                 drawpic_aspect_skin(myPos, pic, eX * 0.7 * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
2815                 drawstring_aspect(myPos + eX * 0.7 * mySize.x, ftos(stat), eX * 0.3 * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2816         }
2817         else
2818                 drawstring_aspect(myPos, ftos(stat), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
2819 }
2820
2821 // Clan Arena and Freeze Tag HUD modicons
2822 void HUD_Mod_CA(vector myPos, vector mySize)
2823 {
2824         mod_active = 1; // required in each mod function that always shows something
2825
2826         int layout;
2827         if(gametype == MAPINFO_TYPE_CA)
2828                 layout = autocvar_hud_panel_modicons_ca_layout;
2829         else //if(gametype == MAPINFO_TYPE_FREEZETAG)
2830                 layout = autocvar_hud_panel_modicons_freezetag_layout;
2831         int rows, columns;
2832         float aspect_ratio;
2833         aspect_ratio = (layout) ? 2 : 1;
2834         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
2835         columns = ceil(team_count/rows);
2836
2837         int i;
2838         float row = 0, column = 0;
2839         vector pos, itemSize;
2840         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
2841         for(i=0; i<team_count; ++i)
2842         {
2843                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
2844
2845                 DrawCAItem(pos, itemSize, aspect_ratio, layout, i);
2846
2847                 ++row;
2848                 if(row >= rows)
2849                 {
2850                         row = 0;
2851                         ++column;
2852                 }
2853         }
2854 }
2855
2856 // CTF HUD modicon section
2857 int redflag_prevframe, blueflag_prevframe, yellowflag_prevframe, pinkflag_prevframe, neutralflag_prevframe; // status during previous frame
2858 int redflag_prevstatus, blueflag_prevstatus, yellowflag_prevstatus, pinkflag_prevstatus, neutralflag_prevstatus; // last remembered status
2859 float redflag_statuschange_time, blueflag_statuschange_time, yellowflag_statuschange_time, pinkflag_statuschange_time, neutralflag_statuschange_time; // time when the status changed
2860
2861 void HUD_Mod_CTF_Reset(void)
2862 {
2863         redflag_prevstatus = blueflag_prevstatus = yellowflag_prevstatus = pinkflag_prevstatus = neutralflag_prevstatus = 0;
2864         redflag_prevframe = blueflag_prevframe = yellowflag_prevframe = pinkflag_prevframe = neutralflag_prevframe = 0;
2865         redflag_statuschange_time = blueflag_statuschange_time = yellowflag_statuschange_time = pinkflag_statuschange_time = neutralflag_statuschange_time = 0;
2866 }
2867
2868 void HUD_Mod_CTF(vector pos, vector mySize)
2869 {
2870         vector redflag_pos, blueflag_pos, yellowflag_pos, pinkflag_pos, neutralflag_pos;
2871         vector flag_size;
2872         float f; // every function should have that
2873
2874         int redflag, blueflag, yellowflag, pinkflag, neutralflag; // current status
2875         float redflag_statuschange_elapsedtime, blueflag_statuschange_elapsedtime, yellowflag_statuschange_elapsedtime, pinkflag_statuschange_elapsedtime, neutralflag_statuschange_elapsedtime; // time since the status changed
2876         bool ctf_oneflag; // one-flag CTF mode enabled/disabled
2877         int stat_items = getstati(STAT_CTF_FLAGSTATUS, 0, 24);
2878         float fs, fs2, fs3, size1, size2;
2879         vector e1, e2;
2880
2881         redflag = (stat_items/CTF_RED_FLAG_TAKEN) & 3;
2882         blueflag = (stat_items/CTF_BLUE_FLAG_TAKEN) & 3;
2883         yellowflag = (stat_items/CTF_YELLOW_FLAG_TAKEN) & 3;
2884         pinkflag = (stat_items/CTF_PINK_FLAG_TAKEN) & 3;
2885         neutralflag = (stat_items/CTF_NEUTRAL_FLAG_TAKEN) & 3;
2886
2887         ctf_oneflag = (stat_items & CTF_FLAG_NEUTRAL);
2888
2889         mod_active = (redflag || blueflag || yellowflag || pinkflag || neutralflag);
2890
2891         if (autocvar__hud_configure) {
2892                 redflag = 1;
2893                 blueflag = 2;
2894                 if (team_count >= 3)
2895                         yellowflag = 2;
2896                 if (team_count >= 4)
2897                         pinkflag = 3;
2898                 ctf_oneflag = neutralflag = 0; // disable neutral flag in hud editor?
2899         }
2900
2901         // when status CHANGES, set old status into prevstatus and current status into status
2902         #define X(team) do {                                                                                                                    \
2903                 if (team##flag != team##flag_prevframe) {                                                                       \
2904                 team##flag_statuschange_time = time;                                                                    \
2905                 team##flag_prevstatus = team##flag_prevframe;                                                   \
2906                 team##flag_prevframe = team##flag;                                                                              \
2907         }                                                                                                                                                       \
2908         team##flag_statuschange_elapsedtime = time - team##flag_statuschange_time;      \
2909     } while (0)
2910         X(red);
2911         X(blue);
2912         X(yellow);
2913         X(pink);
2914         X(neutral);
2915         #undef X
2916
2917         const float BLINK_FACTOR = 0.15;
2918         const float BLINK_BASE = 0.85;
2919         // note:
2920         //   RMS = sqrt(BLINK_BASE^2 + 0.5 * BLINK_FACTOR^2)
2921         // thus
2922         //   BLINK_BASE = sqrt(RMS^2 - 0.5 * BLINK_FACTOR^2)
2923         // ensure RMS == 1
2924         const float BLINK_FREQ = 5; // circle frequency, = 2*pi*frequency in hertz
2925
2926         #define X(team, cond) \
2927         string team##_icon, team##_icon_prevstatus; \
2928         int team##_alpha, team##_alpha_prevstatus; \
2929         team##_alpha = team##_alpha_prevstatus = 1; \
2930         do { \
2931                 switch (team##flag) { \
2932                         case 1: team##_icon = "flag_" #team "_taken"; break; \
2933                         case 2: team##_icon = "flag_" #team "_lost"; break; \
2934                         case 3: team##_icon = "flag_" #team "_carrying"; team##_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2935                         default: \
2936                                 if ((stat_items & CTF_SHIELDED) && (cond)) { \
2937                                         team##_icon = "flag_" #team "_shielded"; \
2938                                 } else { \
2939                                         team##_icon = string_null; \
2940                                 } \
2941                                 break; \
2942                 } \
2943                 switch (team##flag_prevstatus) { \
2944                         case 1: team##_icon_prevstatus = "flag_" #team "_taken"; break; \
2945                         case 2: team##_icon_prevstatus = "flag_" #team "_lost"; break; \
2946                         case 3: team##_icon_prevstatus = "flag_" #team "_carrying"; team##_alpha_prevstatus = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ); break; \
2947                         default: \
2948                                 if (team##flag == 3) { \
2949                                         team##_icon_prevstatus = "flag_" #team "_carrying"; /* make it more visible */\
2950                                 } else if((stat_items & CTF_SHIELDED) && (cond)) { \
2951                                         team##_icon_prevstatus = "flag_" #team "_shielded"; \
2952                                 } else { \
2953                                         team##_icon_prevstatus = string_null; \
2954                                 } \
2955                                 break; \
2956                 } \
2957         } while (0)
2958         X(red, myteam != NUM_TEAM_1);
2959         X(blue, myteam != NUM_TEAM_2);
2960         X(yellow, myteam != NUM_TEAM_3);
2961         X(pink, myteam != NUM_TEAM_4);
2962         X(neutral, true);
2963         #undef X
2964
2965         if (ctf_oneflag) {
2966                 // hacky, but these aren't needed
2967                 red_icon = red_icon_prevstatus = blue_icon = blue_icon_prevstatus = yellow_icon = yellow_icon_prevstatus = pink_icon = pink_icon_prevstatus = string_null;
2968                 fs = fs2 = fs3 = 1;
2969         } else switch (team_count) {
2970                 default:
2971                 case 2: fs = 0.5; fs2 = 0.5; fs3 = 0.5; break;
2972                 case 3: fs = 1; fs2 = 0.35; fs3 = 0.35; break;
2973                 case 4: fs = 0.75; fs2 = 0.25; fs3 = 0.5; break;
2974         }
2975
2976         if (mySize_x > mySize_y) {
2977                 size1 = mySize_x;
2978                 size2 = mySize_y;
2979                 e1 = eX;
2980                 e2 = eY;
2981         } else {
2982                 size1 = mySize_y;
2983                 size2 = mySize_x;
2984                 e1 = eY;
2985                 e2 = eX;
2986         }
2987
2988         switch (myteam) {
2989                 default:
2990                 case NUM_TEAM_1: {
2991                         redflag_pos = pos;
2992                         blueflag_pos = pos + eX * fs2 * size1;
2993                         yellowflag_pos = pos - eX * fs2 * size1;
2994                         pinkflag_pos = pos + eX * fs3 * size1;
2995                         break;
2996                 }
2997                 case NUM_TEAM_2: {
2998                         redflag_pos = pos + eX * fs2 * size1;
2999                         blueflag_pos = pos;
3000                         yellowflag_pos = pos - eX * fs2 * size1;
3001                         pinkflag_pos = pos + eX * fs3 * size1;
3002                         break;
3003                 }
3004                 case NUM_TEAM_3: {
3005                         redflag_pos = pos + eX * fs3 * size1;
3006                         blueflag_pos = pos - eX * fs2 * size1;
3007                         yellowflag_pos = pos;
3008                         pinkflag_pos = pos + eX * fs2 * size1;
3009                         break;
3010                 }
3011                 case NUM_TEAM_4: {
3012                         redflag_pos = pos - eX * fs2 * size1;
3013                         blueflag_pos = pos + eX * fs3 * size1;
3014                         yellowflag_pos = pos + eX * fs2 * size1;
3015                         pinkflag_pos = pos;
3016                         break;
3017                 }
3018         }
3019         neutralflag_pos = pos;
3020         flag_size = e1 * fs * size1 + e2 * size2;
3021
3022         #define X(team) do { \
3023                 f = bound(0, team##flag_statuschange_elapsedtime * 2, 1); \
3024                 if (team##_icon_prevstatus && f < 1) \
3025                         drawpic_aspect_skin_expanding(team##flag_pos, team##_icon_prevstatus, flag_size, '1 1 1', panel_fg_alpha * team##_alpha_prevstatus, DRAWFLAG_NORMAL, f); \
3026                 if (team##_icon) \
3027                         drawpic_aspect_skin(team##flag_pos, team##_icon, flag_size, '1 1 1', panel_fg_alpha * team##_alpha * f, DRAWFLAG_NORMAL); \
3028         } while (0)
3029         X(red);
3030         X(blue);
3031         X(yellow);
3032         X(pink);
3033         X(neutral);
3034         #undef X
3035 }
3036
3037 // Keyhunt HUD modicon section
3038 vector KH_SLOTS[4];
3039
3040 void HUD_Mod_KH(vector pos, vector mySize)
3041 {
3042         mod_active = 1; // keyhunt should never hide the mod icons panel
3043
3044         // Read current state
3045
3046         int state = getstati(STAT_KH_KEYS);
3047         int i, key_state;
3048         int all_keys, team1_keys, team2_keys, team3_keys, team4_keys, dropped_keys, carrying_keys;
3049         all_keys = team1_keys = team2_keys = team3_keys = team4_keys = dropped_keys = carrying_keys = 0;
3050
3051         for(i = 0; i < 4; ++i)
3052         {
3053                 key_state = (bitshift(state, i * -5) & 31) - 1;
3054
3055                 if(key_state == -1)
3056                         continue;
3057
3058                 if(key_state == 30)
3059                 {
3060                         ++carrying_keys;
3061                         key_state = myteam;
3062                 }
3063
3064                 switch(key_state)
3065                 {
3066                         case NUM_TEAM_1: ++team1_keys; break;
3067                         case NUM_TEAM_2: ++team2_keys; break;
3068                         case NUM_TEAM_3: ++team3_keys; break;
3069                         case NUM_TEAM_4: ++team4_keys; break;
3070                         case 29: ++dropped_keys; break;
3071                 }
3072
3073                 ++all_keys;
3074         }
3075
3076         // Calculate slot measurements
3077
3078         vector slot_size;
3079
3080         if(all_keys == 4 && mySize.x * 0.5 < mySize.y && mySize.y * 0.5 < mySize.x)
3081         {
3082                 // Quadratic arrangement
3083                 slot_size = eX * mySize.x * 0.5 + eY * mySize.y * 0.5;
3084                 KH_SLOTS[0] = pos;
3085                 KH_SLOTS[1] = pos + eX * slot_size.x;
3086                 KH_SLOTS[2] = pos + eY * slot_size.y;
3087                 KH_SLOTS[3] = pos + eX * slot_size.x + eY * slot_size.y;
3088         }
3089         else
3090         {
3091                 if(mySize.x > mySize.y)
3092                 {
3093                         // Horizontal arrangement
3094                         slot_size = eX * mySize.x / all_keys + eY * mySize.y;
3095                         for(i = 0; i < all_keys; ++i)
3096                                 KH_SLOTS[i] = pos + eX * slot_size.x * i;
3097                 }
3098                 else
3099                 {
3100                         // Vertical arrangement
3101                         slot_size = eX * mySize.x + eY * mySize.y / all_keys;
3102                         for(i = 0; i < all_keys; ++i)
3103                                 KH_SLOTS[i] = pos + eY * slot_size.y * i;
3104                 }
3105         }
3106
3107         // Make icons blink in case of RUN HERE
3108
3109         float blink = 0.6 + sin(2*M_PI*time) / 2.5; // Oscillate between 0.2 and 1
3110         float alpha;
3111         alpha = 1;
3112
3113         if(carrying_keys)
3114                 switch(myteam)
3115                 {
3116                         case NUM_TEAM_1: if(team1_keys == all_keys) alpha = blink; break;
3117                         case NUM_TEAM_2: if(team2_keys == all_keys) alpha = blink; break;
3118                         case NUM_TEAM_3: if(team3_keys == all_keys) alpha = blink; break;
3119                         case NUM_TEAM_4: if(team4_keys == all_keys) alpha = blink; break;
3120                 }
3121
3122         // Draw icons
3123
3124         i = 0;
3125
3126         while(team1_keys--)
3127                 if(myteam == NUM_TEAM_1 && carrying_keys)
3128                 {
3129                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3130                         --carrying_keys;
3131                 }
3132                 else
3133                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_red_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3134
3135         while(team2_keys--)
3136                 if(myteam == NUM_TEAM_2 && carrying_keys)
3137                 {
3138                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3139                         --carrying_keys;
3140                 }
3141                 else
3142                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_blue_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3143
3144         while(team3_keys--)
3145                 if(myteam == NUM_TEAM_3 && carrying_keys)
3146                 {
3147                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3148                         --carrying_keys;
3149                 }
3150                 else
3151                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_yellow_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3152
3153         while(team4_keys--)
3154                 if(myteam == NUM_TEAM_4 && carrying_keys)
3155                 {
3156                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_carrying", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3157                         --carrying_keys;
3158                 }
3159                 else
3160                         drawpic_aspect_skin(KH_SLOTS[i++], "kh_pink_taken", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3161
3162         while(dropped_keys--)
3163                 drawpic_aspect_skin(KH_SLOTS[i++], "kh_dropped", slot_size, '1 1 1', alpha, DRAWFLAG_NORMAL);
3164 }
3165
3166 // Keepaway HUD mod icon
3167 int kaball_prevstatus; // last remembered status
3168 float kaball_statuschange_time; // time when the status changed
3169
3170 // we don't need to reset for keepaway since it immediately
3171 // autocorrects prevstatus as to if the player has the ball or not
3172
3173 void HUD_Mod_Keepaway(vector pos, vector mySize)
3174 {
3175         mod_active = 1; // keepaway should always show the mod HUD
3176
3177         float BLINK_FACTOR = 0.15;
3178         float BLINK_BASE = 0.85;
3179         float BLINK_FREQ = 5;
3180         float kaball_alpha = BLINK_BASE + BLINK_FACTOR * cos(time * BLINK_FREQ);
3181
3182         int stat_items = getstati(STAT_ITEMS, 0, 24);
3183         int kaball = (stat_items/IT_KEY1) & 1;
3184
3185         if(kaball != kaball_prevstatus)
3186         {
3187                 kaball_statuschange_time = time;
3188                 kaball_prevstatus = kaball;
3189         }
3190
3191         vector kaball_pos, kaball_size;
3192
3193         if(mySize.x > mySize.y) {
3194                 kaball_pos = pos + eX * 0.25 * mySize.x;
3195                 kaball_size = eX * 0.5 * mySize.x + eY * mySize.y;
3196         } else {
3197                 kaball_pos = pos + eY * 0.25 * mySize.y;
3198                 kaball_size = eY * 0.5 * mySize.y + eX * mySize.x;
3199         }
3200
3201         float kaball_statuschange_elapsedtime = time - kaball_statuschange_time;
3202         float f = bound(0, kaball_statuschange_elapsedtime*2, 1);
3203
3204         if(kaball_prevstatus && f < 1)
3205                 drawpic_aspect_skin_expanding(kaball_pos, "keepawayball_carrying", kaball_size, '1 1 1', panel_fg_alpha * kaball_alpha, DRAWFLAG_NORMAL, f);
3206
3207         if(kaball)
3208                 drawpic_aspect_skin(pos, "keepawayball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha * kaball_alpha * f, DRAWFLAG_NORMAL);
3209 }
3210
3211
3212 // Nexball HUD mod icon
3213 void HUD_Mod_NexBall(vector pos, vector mySize)
3214 {
3215         float nb_pb_starttime, dt, p;
3216         int stat_items;
3217
3218         stat_items = getstati(STAT_ITEMS, 0, 24);
3219         nb_pb_starttime = getstatf(STAT_NB_METERSTART);
3220
3221         if (stat_items & IT_KEY1)
3222                 mod_active = 1;
3223         else
3224                 mod_active = 0;
3225
3226         //Manage the progress bar if any
3227         if (nb_pb_starttime > 0)
3228         {
3229                 dt = (time - nb_pb_starttime) % nb_pb_period;
3230                 // one period of positive triangle
3231                 p = 2 * dt / nb_pb_period;
3232                 if (p > 1)
3233                         p = 2 - p;
3234
3235                 HUD_Panel_DrawProgressBar(pos, mySize, "progressbar", p, (mySize.x <= mySize.y), 0, autocvar_hud_progressbar_nexball_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
3236         }
3237
3238         if (stat_items & IT_KEY1)
3239                 drawpic_aspect_skin(pos, "nexball_carrying", eX * mySize.x + eY * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3240 }
3241
3242 // Race/CTS HUD mod icons
3243 float crecordtime_prev; // last remembered crecordtime
3244 float crecordtime_change_time; // time when crecordtime last changed
3245 float srecordtime_prev; // last remembered srecordtime
3246 float srecordtime_change_time; // time when srecordtime last changed
3247
3248 float race_status_time;
3249 int race_status_prev;
3250 string race_status_name_prev;
3251 void HUD_Mod_Race(vector pos, vector mySize)
3252 {
3253         mod_active = 1; // race should never hide the mod icons panel
3254         entity me;
3255         me = playerslots[player_localnum];
3256         float t, score;
3257         float f; // yet another function has this
3258         score = me.(scores[ps_primary]);
3259
3260         if(!(scores_flags[ps_primary] & SFL_TIME) || teamplay) // race/cts record display on HUD
3261                 return; // no records in the actual race
3262
3263         // clientside personal record
3264         string rr;
3265         if(gametype == MAPINFO_TYPE_CTS)
3266                 rr = CTS_RECORD;
3267         else
3268                 rr = RACE_RECORD;
3269         t = stof(db_get(ClientProgsDB, strcat(shortmapname, rr, "time")));
3270
3271         if(score && (score < t || !t)) {
3272                 db_put(ClientProgsDB, strcat(shortmapname, rr, "time"), ftos(score));
3273                 if(autocvar_cl_autodemo_delete_keeprecords)
3274                 {
3275                         f = autocvar_cl_autodemo_delete;
3276                         f &= ~1;
3277                         cvar_set("cl_autodemo_delete", ftos(f)); // don't delete demo with new record!
3278                 }
3279         }
3280
3281         if(t != crecordtime_prev) {
3282                 crecordtime_prev = t;
3283                 crecordtime_change_time = time;
3284         }
3285
3286         vector textPos, medalPos;
3287         float squareSize;
3288         if(mySize.x > mySize.y) {
3289                 // text on left side
3290                 squareSize = min(mySize.y, mySize.x/2);
3291                 textPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eY * 0.5 * (mySize.y - squareSize);
3292                 medalPos = pos + eX * 0.5 * max(0, mySize.x/2 - squareSize) + eX * 0.5 * mySize.x + eY * 0.5 * (mySize.y - squareSize);
3293         } else {
3294                 // text on top
3295                 squareSize = min(mySize.x, mySize.y/2);
3296                 textPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eX * 0.5 * (mySize.x - squareSize);
3297                 medalPos = pos + eY * 0.5 * max(0, mySize.y/2 - squareSize) + eY * 0.5 * mySize.y + eX * 0.5 * (mySize.x - squareSize);
3298         }
3299
3300         f = time - crecordtime_change_time;
3301
3302         if (f > 1) {
3303                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3304                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3305         } else {
3306                 drawstring_aspect(textPos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3307                 drawstring_aspect(textPos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3308                 drawstring_aspect_expanding(pos, _("Personal best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3309                 drawstring_aspect_expanding(pos + eY * 0.25 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3310         }
3311
3312         // server record
3313         t = race_server_record;
3314         if(t != srecordtime_prev) {
3315                 srecordtime_prev = t;
3316                 srecordtime_change_time = time;
3317         }
3318         f = time - srecordtime_change_time;
3319
3320         if (f > 1) {
3321                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3322                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3323         } else {
3324                 drawstring_aspect(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3325                 drawstring_aspect(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3326                 drawstring_aspect_expanding(textPos + eY * 0.5 * squareSize, _("Server best"), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3327                 drawstring_aspect_expanding(textPos + eY * 0.75 * squareSize, TIME_ENCODED_TOSTRING(t), eX * squareSize + eY * 0.25 * squareSize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL, f);
3328         }
3329
3330         if (race_status != race_status_prev || race_status_name != race_status_name_prev) {
3331                 race_status_time = time + 5;
3332                 race_status_prev = race_status;
3333                 if (race_status_name_prev)
3334                         strunzone(race_status_name_prev);
3335                 race_status_name_prev = strzone(race_status_name);
3336         }
3337
3338         // race "awards"
3339         float a;
3340         a = bound(0, race_status_time - time, 1);
3341
3342         string s;
3343         s = textShortenToWidth(race_status_name, squareSize, '1 1 0' * 0.1 * squareSize, stringwidth_colors);
3344
3345         float rank;
3346         if(race_status > 0)
3347                 rank = race_CheckName(race_status_name);
3348         else
3349                 rank = 0;
3350         string rankname;
3351         rankname = count_ordinal(rank);
3352
3353         vector namepos;
3354         namepos = medalPos + '0 0.8 0' * squareSize;
3355         vector rankpos;
3356         rankpos = medalPos + '0 0.15 0' * squareSize;
3357
3358         if(race_status == 0)
3359                 drawpic_aspect_skin(medalPos, "race_newfail", '1 1 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3360         else if(race_status == 1) {
3361                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newtime", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3362                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3363                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3364         } else if(race_status == 2) {
3365                 if(race_status_name == GetPlayerName(player_localnum) || !race_myrank || race_myrank < rank)
3366                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankgreen", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3367                 else
3368                         drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrankyellow", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3369                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3370                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3371         } else if(race_status == 3) {
3372                 drawpic_aspect_skin(medalPos + '0.1 0 0' * squareSize, "race_newrecordserver", '1 1 0' * 0.8 * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3373                 drawcolorcodedstring_aspect(namepos, s, '1 0.2 0' * squareSize, panel_fg_alpha * a, DRAWFLAG_NORMAL);
3374                 drawstring_aspect(rankpos, rankname, '1 0.15 0' * squareSize, '1 1 1', panel_fg_alpha * a, DRAWFLAG_NORMAL);
3375         }
3376
3377         if (race_status_time - time <= 0) {
3378                 race_status_prev = -1;
3379                 race_status = -1;
3380                 if(race_status_name)
3381                         strunzone(race_status_name);
3382                 race_status_name = string_null;
3383                 if(race_status_name_prev)
3384                         strunzone(race_status_name_prev);
3385                 race_status_name_prev = string_null;
3386         }
3387 }
3388
3389 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
3390 {
3391         float stat = -1;
3392         string pic = "";
3393         vector color = '0 0 0';
3394         switch(i)
3395         {
3396                 case 0:
3397                         stat = getstatf(STAT_DOM_PPS_RED);
3398                         pic = "dom_icon_red";
3399                         color = '1 0 0';
3400                         break;
3401                 case 1:
3402                         stat = getstatf(STAT_DOM_PPS_BLUE);
3403                         pic = "dom_icon_blue";
3404                         color = '0 0 1';
3405                         break;
3406                 case 2:
3407                         stat = getstatf(STAT_DOM_PPS_YELLOW);
3408                         pic = "dom_icon_yellow";
3409                         color = '1 1 0';
3410                         break;
3411                 default:
3412                 case 3:
3413                         stat = getstatf(STAT_DOM_PPS_PINK);
3414                         pic = "dom_icon_pink";
3415                         color = '1 0 1';
3416                         break;
3417         }
3418         float pps_ratio = stat / getstatf(STAT_DOM_TOTAL_PPS);
3419
3420         if(mySize.x/mySize.y > aspect_ratio)
3421         {
3422                 i = aspect_ratio * mySize.y;
3423                 myPos.x = myPos.x + (mySize.x - i) / 2;
3424                 mySize.x = i;
3425         }
3426         else
3427         {
3428                 i = 1/aspect_ratio * mySize.x;
3429                 myPos.y = myPos.y + (mySize.y - i) / 2;
3430                 mySize.y = i;
3431         }
3432
3433         if (layout) // show text too
3434         {
3435                 //draw the text
3436                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
3437                 if (layout == 2) // average pps
3438                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3439                 else // percentage of average pps
3440                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), eX * (2/3) * mySize.x + eY * mySize.y, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3441         }
3442
3443         //draw the icon
3444         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3445         if (stat > 0)
3446         {
3447                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
3448                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3449                 drawresetcliparea();
3450         }
3451 }
3452
3453 void HUD_Mod_Dom(vector myPos, vector mySize)
3454 {
3455         mod_active = 1; // required in each mod function that always shows something
3456
3457         int layout = autocvar_hud_panel_modicons_dom_layout;
3458         int rows, columns;
3459         float aspect_ratio;
3460         aspect_ratio = (layout) ? 3 : 1;
3461         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
3462         columns = ceil(team_count/rows);
3463
3464         int i;
3465         float row = 0, column = 0;
3466         vector pos, itemSize;
3467         itemSize = eX * mySize.x*(1/columns) + eY * mySize.y*(1/rows);
3468         for(i=0; i<team_count; ++i)
3469         {
3470                 pos = myPos + eX * column * itemSize.x + eY * row * itemSize.y;
3471
3472                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
3473
3474                 ++row;
3475                 if(row >= rows)
3476                 {
3477                         row = 0;
3478                         ++column;
3479                 }
3480         }
3481 }
3482
3483 void HUD_ModIcons_SetFunc()
3484 {
3485         switch(gametype)
3486         {
3487                 case MAPINFO_TYPE_KEYHUNT:              HUD_ModIcons_GameType = HUD_Mod_KH; break;
3488                 case MAPINFO_TYPE_CTF:                  HUD_ModIcons_GameType = HUD_Mod_CTF; break;
3489                 case MAPINFO_TYPE_NEXBALL:              HUD_ModIcons_GameType = HUD_Mod_NexBall; break;
3490                 case MAPINFO_TYPE_CTS:
3491                 case MAPINFO_TYPE_RACE:         HUD_ModIcons_GameType = HUD_Mod_Race; break;
3492                 case MAPINFO_TYPE_CA:
3493                 case MAPINFO_TYPE_FREEZETAG:    HUD_ModIcons_GameType = HUD_Mod_CA; break;
3494                 case MAPINFO_TYPE_DOMINATION:   HUD_ModIcons_GameType = HUD_Mod_Dom; break;
3495                 case MAPINFO_TYPE_KEEPAWAY:     HUD_ModIcons_GameType = HUD_Mod_Keepaway; break;
3496         }
3497 }
3498
3499 int mod_prev; // previous state of mod_active to check for a change
3500 float mod_alpha;
3501 float mod_change; // "time" when mod_active changed
3502
3503 void HUD_ModIcons(void)
3504 {
3505         if(!autocvar__hud_configure)
3506         {
3507                 if(!autocvar_hud_panel_modicons) return;
3508                 if(!HUD_ModIcons_GameType) return;
3509         }
3510
3511         HUD_Panel_UpdateCvars();
3512
3513         draw_beginBoldFont();
3514
3515         if(mod_active != mod_prev) {
3516                 mod_change = time;
3517                 mod_prev = mod_active;
3518         }
3519
3520         if(mod_active || autocvar__hud_configure)
3521                 mod_alpha = bound(0, (time - mod_change) * 2, 1);
3522         else
3523                 mod_alpha = bound(0, 1 - (time - mod_change) * 2, 1);
3524
3525         if(mod_alpha)
3526                 HUD_Panel_DrawBg(mod_alpha);
3527
3528         if(panel_bg_padding)
3529         {
3530                 panel_pos += '1 1 0' * panel_bg_padding;
3531                 panel_size -= '2 2 0' * panel_bg_padding;
3532         }
3533
3534         if(autocvar__hud_configure)
3535                 HUD_Mod_CTF(panel_pos, panel_size);
3536         else
3537                 HUD_ModIcons_GameType(panel_pos, panel_size);
3538
3539         draw_endBoldFont();
3540 }
3541
3542 // Draw pressed keys (#11)
3543 //
3544 void HUD_PressedKeys(void)
3545 {
3546         if(!autocvar__hud_configure)
3547         {
3548                 if(!autocvar_hud_panel_pressedkeys) return;
3549                 if(spectatee_status <= 0 && autocvar_hud_panel_pressedkeys < 2) return;
3550         }
3551
3552         HUD_Panel_UpdateCvars();
3553         vector pos, mySize;
3554         pos = panel_pos;
3555         mySize = panel_size;
3556
3557         HUD_Panel_DrawBg(1);
3558         if(panel_bg_padding)
3559         {
3560                 pos += '1 1 0' * panel_bg_padding;
3561                 mySize -= '2 2 0' * panel_bg_padding;
3562         }
3563
3564         // force custom aspect
3565         float aspect = autocvar_hud_panel_pressedkeys_aspect;
3566         if(aspect)
3567         {
3568                 vector newSize = '0 0 0';
3569                 if(mySize.x/mySize.y > aspect)
3570                 {
3571                         newSize.x = aspect * mySize.y;
3572                         newSize.y = mySize.y;
3573
3574                         pos.x = pos.x + (mySize.x - newSize.x) / 2;
3575                 }
3576                 else
3577                 {
3578                         newSize.y = 1/aspect * mySize.x;
3579                         newSize.x = mySize.x;
3580
3581                         pos.y = pos.y + (mySize.y - newSize.y) / 2;
3582                 }
3583                 mySize = newSize;
3584         }
3585
3586         vector keysize;
3587         keysize = eX * mySize.x * (1/3.0) + eY * mySize.y * (1/(3.0 - !autocvar_hud_panel_pressedkeys_attack));
3588         float pressedkeys;
3589         pressedkeys = getstatf(STAT_PRESSED_KEYS);
3590
3591         if(autocvar_hud_panel_pressedkeys_attack)
3592         {
3593                 drawpic_aspect_skin(pos + eX * keysize.x * 0.5, ((pressedkeys & KEY_ATCK) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3594                 drawpic_aspect_skin(pos + eX * keysize.x * 1.5, ((pressedkeys & KEY_ATCK2) ? "key_atck_inv.tga" : "key_atck.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3595                 pos.y += keysize.y;
3596         }
3597
3598         drawpic_aspect_skin(pos, ((pressedkeys & KEY_CROUCH) ? "key_crouch_inv.tga" : "key_crouch.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3599         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_FORWARD) ? "key_forward_inv.tga" : "key_forward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3600         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_JUMP) ? "key_jump_inv.tga" : "key_jump.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3601         pos.y += keysize.y;
3602         drawpic_aspect_skin(pos, ((pressedkeys & KEY_LEFT) ? "key_left_inv.tga" : "key_left.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3603         drawpic_aspect_skin(pos + eX * keysize.x, ((pressedkeys & KEY_BACKWARD) ? "key_backward_inv.tga" : "key_backward.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3604         drawpic_aspect_skin(pos + eX * keysize.x * 2, ((pressedkeys & KEY_RIGHT) ? "key_right_inv.tga" : "key_right.tga"), keysize, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
3605 }
3606
3607 // Handle chat as a panel (#12)
3608 //
3609 void HUD_Chat(void)
3610 {
3611         if(!autocvar__hud_configure)
3612         {
3613                 if (!autocvar_hud_panel_chat)
3614                 {
3615                         if (!autocvar_con_chatrect)
3616                                 cvar_set("con_chatrect", "0");
3617                         return;
3618                 }
3619                 if(autocvar__con_chat_maximized)
3620                 {
3621                         if(!hud_draw_maximized) return;
3622                 }
3623                 else if(chat_panel_modified)
3624                 {
3625                         panel.update_time = time; // forces reload of panel attributes
3626                         chat_panel_modified = false;
3627                 }
3628         }
3629
3630         HUD_Panel_UpdateCvars();
3631
3632         if(autocvar__con_chat_maximized && !autocvar__hud_configure) // draw at full screen height if maximized
3633         {
3634                 panel_pos.y = panel_bg_border;
3635                 panel_size.y = vid_conheight - panel_bg_border * 2;
3636                 if(panel.current_panel_bg == "0") // force a border when maximized
3637                 {
3638                         string panel_bg;
3639                         panel_bg = strcat(hud_skin_path, "/border_default");
3640                         if(precache_pic(panel_bg) == "")
3641                                 panel_bg = "gfx/hud/default/border_default";
3642                         if(panel.current_panel_bg)
3643                                 strunzone(panel.current_panel_bg);
3644                         panel.current_panel_bg = strzone(panel_bg);
3645                         chat_panel_modified = true;
3646                 }
3647                 panel_bg_alpha = max(0.75, panel_bg_alpha); // force an theAlpha of at least 0.75
3648         }
3649
3650         vector pos, mySize;
3651         pos = panel_pos;
3652         mySize = panel_size;
3653
3654         HUD_Panel_DrawBg(1);
3655
3656         if(panel_bg_padding)
3657         {
3658                 pos += '1 1 0' * panel_bg_padding;
3659                 mySize -= '2 2 0' * panel_bg_padding;
3660         }
3661
3662         if (!autocvar_con_chatrect)
3663                 cvar_set("con_chatrect", "1");
3664
3665         cvar_set("con_chatrect_x", ftos(pos.x/vid_conwidth));
3666         cvar_set("con_chatrect_y", ftos(pos.y/vid_conheight));
3667
3668         cvar_set("con_chatwidth", ftos(mySize.x/vid_conwidth));
3669         cvar_set("con_chat", ftos(floor(mySize.y/autocvar_con_chatsize - 0.5)));
3670
3671         if(autocvar__hud_configure)
3672         {
3673                 vector chatsize;
3674                 chatsize = '1 1 0' * autocvar_con_chatsize;
3675                 cvar_set("con_chatrect_x", "9001"); // over 9000, we'll fake it instead for more control over theAlpha and such
3676                 float i, a;
3677                 for(i = 0; i < autocvar_con_chat; ++i)
3678                 {
3679                         if(i == autocvar_con_chat - 1)
3680                                 a = panel_fg_alpha;
3681                         else
3682                                 a = panel_fg_alpha * floor(((i + 1) * 7 + autocvar_con_chattime)/45);
3683                         drawcolorcodedstring(pos, textShortenToWidth(_("^3Player^7: This is the chat area."), mySize.x, chatsize, stringwidth_colors), chatsize, a, DRAWFLAG_NORMAL);
3684                         pos.y += chatsize.y;
3685                 }
3686         }
3687 }
3688
3689 // Engine info panel (#13)
3690 //
3691 float prevfps;
3692 float prevfps_time;
3693 int framecounter;
3694
3695 float frametimeavg;
3696 float frametimeavg1; // 1 frame ago
3697 float frametimeavg2; // 2 frames ago
3698 void HUD_EngineInfo(void)
3699 {
3700         if(!autocvar__hud_configure)
3701         {
3702                 if(!autocvar_hud_panel_engineinfo) return;
3703         }
3704
3705         HUD_Panel_UpdateCvars();
3706         vector pos, mySize;
3707         pos = panel_pos;
3708         mySize = panel_size;
3709
3710         HUD_Panel_DrawBg(1);
3711         if(panel_bg_padding)
3712         {
3713                 pos += '1 1 0' * panel_bg_padding;
3714                 mySize -= '2 2 0' * panel_bg_padding;
3715         }
3716
3717         float currentTime = gettime(GETTIME_REALTIME);
3718         if(cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage"))
3719         {
3720                 float currentframetime = currentTime - prevfps_time;
3721                 frametimeavg = (frametimeavg + frametimeavg1 + frametimeavg2 + currentframetime)/4; // average three frametimes into framecounter for slightly more stable fps readings :P
3722                 frametimeavg2 = frametimeavg1;
3723                 frametimeavg1 = frametimeavg;
3724
3725                 float weight;
3726                 weight = cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_new_weight");
3727                 if(currentframetime > 0.0001) // filter out insane values which sometimes seem to occur and throw off the average? If you are getting 10,000 fps or more, then you don't need a framerate counter.
3728                 {
3729                         if(fabs(prevfps - (1/frametimeavg)) > prevfps * cvar("hud_panel_engineinfo_framecounter_exponentialmovingaverage_instantupdate_change_threshold")) // if there was a big jump in fps, just force prevfps at current (1/currentframetime) to make big updates instant
3730                                 prevfps = (1/currentframetime);
3731                         prevfps = (1 - weight) * prevfps + weight * (1/frametimeavg); // framecounter just used so there's no need for a new variable, think of it as "frametime average"
3732                 }
3733                 prevfps_time = currentTime;
3734         }
3735         else
3736         {
3737                 framecounter += 1;
3738                 if(currentTime - prevfps_time > autocvar_hud_panel_engineinfo_framecounter_time)
3739                 {
3740                         prevfps = framecounter/(currentTime - prevfps_time);
3741                         framecounter = 0;
3742                         prevfps_time = currentTime;
3743                 }
3744         }
3745
3746         vector color;
3747         color = HUD_Get_Num_Color (prevfps, 100);
3748         drawstring_aspect(pos, sprintf(_("FPS: %.*f"), autocvar_hud_panel_engineinfo_framecounter_decimals, prevfps), mySize, color, panel_fg_alpha, DRAWFLAG_NORMAL);
3749 }
3750
3751 // Info messages panel (#14)
3752 //
3753 #define drawInfoMessage(s) do {                                                                                                                                                                         \
3754         if(autocvar_hud_panel_infomessages_flip)                                                                                                                                                \
3755                 o.x = pos.x + mySize.x - stringwidth(s, true, fontsize);                                                                                                        \
3756         drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);                                                                                                               \
3757         o.y += fontsize.y;                                                                                                                                                                                              \
3758 } while(0)
3759 void HUD_InfoMessages(void)
3760 {
3761         if(!autocvar__hud_configure)
3762         {
3763                 if(!autocvar_hud_panel_infomessages) return;
3764         }
3765
3766         HUD_Panel_UpdateCvars();
3767         vector pos, mySize;
3768         pos = panel_pos;
3769         mySize = panel_size;
3770
3771         HUD_Panel_DrawBg(1);
3772         if(panel_bg_padding)
3773         {
3774                 pos += '1 1 0' * panel_bg_padding;
3775                 mySize -= '2 2 0' * panel_bg_padding;
3776         }
3777
3778         // always force 5:1 aspect
3779         vector newSize = '0 0 0';
3780         if(mySize.x/mySize.y > 5)
3781         {
3782                 newSize.x = 5 * mySize.y;
3783                 newSize.y = mySize.y;
3784
3785                 pos.x = pos.x + (mySize.x - newSize.x) / 2;
3786         }
3787         else
3788         {
3789                 newSize.y = 1/5 * mySize.x;
3790                 newSize.x = mySize.x;
3791
3792                 pos.y = pos.y + (mySize.y - newSize.y) / 2;
3793         }
3794
3795         mySize = newSize;
3796         entity tm;
3797         vector o;
3798         o = pos;
3799
3800         vector fontsize;
3801         fontsize = '0.20 0.20 0' * mySize.y;
3802
3803         float a;
3804         a = panel_fg_alpha;
3805
3806         string s;
3807         if(!autocvar__hud_configure)
3808         {
3809                 if(spectatee_status && !intermission)
3810                 {
3811                         a = 1;
3812                         if(spectatee_status == -1)
3813                                 s = _("^1Observing");
3814                         else
3815                                 s = sprintf(_("^1Spectating: ^7%s"), GetPlayerName(current_player));
3816                         drawInfoMessage(s);
3817
3818                         if(spectatee_status == -1)
3819                                 s = sprintf(_("^1Press ^3%s^1 to spectate"), getcommandkey("primary fire", "+fire"));
3820                         else
3821                                 s = sprintf(_("^1Press ^3%s^1 or ^3%s^1 for next or previous player"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3822                         drawInfoMessage(s);
3823
3824                         if(spectatee_status == -1)
3825                                 s = sprintf(_("^1Use ^3%s^1 or ^3%s^1 to change the speed"), getcommandkey("next weapon", "weapnext"), getcommandkey("previous weapon", "weapprev"));
3826                         else
3827                                 s = sprintf(_("^1Press ^3%s^1 to observe"), getcommandkey("secondary fire", "+fire2"));
3828                         drawInfoMessage(s);
3829
3830                         s = sprintf(_("^1Press ^3%s^1 for gamemode info"), getcommandkey("server info", "+show_info"));
3831                         drawInfoMessage(s);
3832
3833                         if(gametype == MAPINFO_TYPE_LMS)
3834                         {
3835                                 entity sk;
3836                                 sk = playerslots[player_localnum];
3837                                 if(sk.(scores[ps_primary]) >= 666)
3838                                         s = _("^1Match has already begun");
3839                                 else if(sk.(scores[ps_primary]) > 0)
3840                                         s = _("^1You have no more lives left");
3841                                 else
3842                                         s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3843                         }
3844                         else
3845                                 s = sprintf(_("^1Press ^3%s^1 to join"), getcommandkey("jump", "+jump"));
3846                         drawInfoMessage(s);
3847
3848                         //show restart countdown:
3849                         if (time < getstatf(STAT_GAMESTARTTIME)) {
3850                                 float countdown;
3851                                 //we need to ceil, otherwise the countdown would be off by .5 when using round()
3852                                 countdown = ceil(getstatf(STAT_GAMESTARTTIME) - time);
3853                                 s = sprintf(_("^1Game starts in ^3%d^1 seconds"), countdown);
3854                                 drawcolorcodedstring(o, s, fontsize, a, DRAWFLAG_NORMAL);
3855                                 o.y += fontsize.y;
3856                         }
3857                 }
3858                 if(warmup_stage && !intermission)
3859                 {
3860                         s = _("^2Currently in ^1warmup^2 stage!");
3861                         drawInfoMessage(s);
3862                 }
3863
3864                 string blinkcolor;
3865                 if(time % 1 >= 0.5)
3866                         blinkcolor = "^1";
3867                 else
3868                         blinkcolor = "^3";
3869
3870                 if(ready_waiting && !intermission && !spectatee_status)
3871                 {
3872                         if(ready_waiting_for_me)
3873                         {
3874                                 if(warmup_stage)
3875                                         s = sprintf(_("%sPress ^3%s%s to end warmup"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3876                                 else
3877                                         s = sprintf(_("%sPress ^3%s%s once you are ready"), blinkcolor, getcommandkey("ready", "ready"), blinkcolor);
3878                         }
3879                         else
3880                         {
3881                                 if(warmup_stage)
3882                                         s = _("^2Waiting for others to ready up to end warmup...");
3883                                 else
3884                                         s = _("^2Waiting for others to ready up...");
3885                         }
3886                         drawInfoMessage(s);
3887                 }
3888                 else if(warmup_stage && !intermission && !spectatee_status)
3889                 {
3890                         s = sprintf(_("^2Press ^3%s^2 to end warmup"), getcommandkey("ready", "ready"));
3891                         drawInfoMessage(s);
3892                 }
3893
3894                 if(teamplay && !intermission && !spectatee_status && gametype != MAPINFO_TYPE_CA && teamnagger)
3895                 {
3896                         float ts_min = 0, ts_max = 0;
3897                         tm = teams.sort_next;
3898                         if (tm)
3899                         {
3900                                 for (; tm.sort_next; tm = tm.sort_next)
3901                                 {
3902                                         if(!tm.team_size || tm.team == NUM_SPECTATOR)
3903                                                 continue;
3904                                         if(!ts_min) ts_min = tm.team_size;
3905                                         else ts_min = min(ts_min, tm.team_size);
3906                                         if(!ts_max) ts_max = tm.team_size;
3907                                         else ts_max = max(ts_max, tm.team_size);
3908                                 }
3909                                 if ((ts_max - ts_min) > 1)
3910                                 {
3911                                         s = strcat(blinkcolor, _("Teamnumbers are unbalanced!"));
3912                                         tm = GetTeam(myteam, false);
3913                                         if (tm)
3914                                         if (tm.team != NUM_SPECTATOR)
3915                                         if (tm.team_size == ts_max)
3916                                                 s = strcat(s, sprintf(_(" Press ^3%s%s to adjust"), getcommandkey("team menu", "menu_showteamselect"), blinkcolor));
3917                                         drawInfoMessage(s);
3918                                 }
3919                         }
3920                 }
3921         }
3922         else
3923         {
3924                 s = _("^7Press ^3ESC ^7to show HUD options.");
3925                 drawInfoMessage(s);
3926                 s = _("^3Doubleclick ^7a panel for panel-specific options.");
3927                 drawInfoMessage(s);
3928                 s = _("^3CTRL ^7to disable collision testing, ^3SHIFT ^7and");
3929                 drawInfoMessage(s);
3930                 s = _("^3ALT ^7+ ^3ARROW KEYS ^7for fine adjustments.");
3931                 drawInfoMessage(s);
3932         }
3933 }
3934
3935 // Physics panel (#15)
3936 //
3937 vector acc_prevspeed;
3938 float acc_prevtime, acc_avg, top_speed, top_speed_time;
3939 float physics_update_time, discrete_speed, discrete_acceleration;
3940 void HUD_Physics(void)
3941 {
3942         if(!autocvar__hud_configure)
3943         {
3944                 if(!autocvar_hud_panel_physics) return;
3945                 if(spectatee_status == -1 && (autocvar_hud_panel_physics == 1 || autocvar_hud_panel_physics == 3)) return;
3946                 if(autocvar_hud_panel_physics == 3 && !(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS)) return;
3947         }
3948
3949         HUD_Panel_UpdateCvars();
3950
3951         draw_beginBoldFont();
3952
3953         HUD_Panel_DrawBg(1);
3954         if(panel_bg_padding)
3955         {
3956                 panel_pos += '1 1 0' * panel_bg_padding;
3957                 panel_size -= '2 2 0' * panel_bg_padding;
3958         }
3959
3960         float acceleration_progressbar_scale = 0;
3961         if(autocvar_hud_panel_physics_progressbar && autocvar_hud_panel_physics_acceleration_progressbar_scale > 1)
3962                 acceleration_progressbar_scale = autocvar_hud_panel_physics_acceleration_progressbar_scale;
3963
3964         float text_scale;
3965         if (autocvar_hud_panel_physics_text_scale <= 0)
3966                 text_scale = 1;
3967         else
3968                 text_scale = min(autocvar_hud_panel_physics_text_scale, 1);
3969
3970         //compute speed
3971         float speed, conversion_factor;
3972         string unit;
3973
3974         switch(autocvar_hud_panel_physics_speed_unit)
3975         {
3976                 default:
3977                 case 1:
3978                         unit = _(" qu/s");
3979                         conversion_factor = 1.0;
3980                         break;
3981                 case 2:
3982                         unit = _(" m/s");
3983                         conversion_factor = 0.0254;
3984                         break;
3985                 case 3:
3986                         unit = _(" km/h");
3987                         conversion_factor = 0.0254 * 3.6;
3988                         break;
3989                 case 4:
3990                         unit = _(" mph");
3991                         conversion_factor = 0.0254 * 3.6 * 0.6213711922;
3992                         break;
3993                 case 5:
3994                         unit = _(" knots");
3995                         conversion_factor = 0.0254 * 1.943844492; // 1 m/s = 1.943844492 knots, because 1 knot = 1.852 km/h
3996                         break;
3997         }
3998
3999         vector vel = (csqcplayer ? csqcplayer.velocity : pmove_vel);
4000
4001         float max_speed = floor( autocvar_hud_panel_physics_speed_max * conversion_factor + 0.5 );
4002         if (autocvar__hud_configure)
4003                 speed = floor( max_speed * 0.65 + 0.5 );
4004         else if(autocvar_hud_panel_physics_speed_vertical)
4005                 speed = floor( vlen(vel) * conversion_factor + 0.5 );
4006         else
4007                 speed = floor( vlen(vel - vel.z * '0 0 1') * conversion_factor + 0.5 );
4008
4009         //compute acceleration
4010         float acceleration, f;
4011         if (autocvar__hud_configure)
4012                 acceleration = autocvar_hud_panel_physics_acceleration_max * 0.3;
4013         else
4014         {
4015                 // 1 m/s = 0.0254 qu/s; 1 g = 9.80665 m/s^2
4016                 f = time - acc_prevtime;
4017                 if(autocvar_hud_panel_physics_acceleration_vertical)
4018                         acceleration = (vlen(vel) - vlen(acc_prevspeed));
4019                 else
4020                         acceleration = (vlen(vel - '0 0 1' * vel.z) - vlen(acc_prevspeed - '0 0 1' * acc_prevspeed.z));
4021
4022                 acceleration = acceleration * (1 / max(0.0001, f)) * (0.0254 / 9.80665);
4023
4024                 acc_prevspeed = vel;
4025                 acc_prevtime = time;
4026
4027                 if(autocvar_hud_panel_physics_acceleration_movingaverage)
4028                 {
4029                         f = bound(0, f * 10, 1);
4030                         acc_avg = acc_avg * (1 - f) + acceleration * f;
4031                         acceleration = acc_avg;
4032                 }
4033         }
4034
4035         int acc_decimals = 2;
4036         if(time > physics_update_time)
4037         {
4038                 // workaround for ftos_decimals returning a negative 0
4039                 if(discrete_acceleration > -1 / pow(10, acc_decimals) && discrete_acceleration < 0)
4040                         discrete_acceleration = 0;
4041                 discrete_acceleration = acceleration;
4042                 discrete_speed = speed;
4043                 physics_update_time += autocvar_hud_panel_physics_update_interval;
4044         }
4045
4046         //compute layout
4047         float panel_ar = panel_size.x/panel_size.y;
4048         vector speed_offset = '0 0 0', acceleration_offset = '0 0 0';
4049         if (panel_ar >= 5 && !acceleration_progressbar_scale)
4050         {
4051                 panel_size.x *= 0.5;
4052                 if (autocvar_hud_panel_physics_flip)
4053                         speed_offset.x = panel_size.x;
4054                 else
4055                         acceleration_offset.x = panel_size.x;
4056         }
4057         else
4058         {
4059                 panel_size.y *= 0.5;
4060                 if (autocvar_hud_panel_physics_flip)
4061                         speed_offset.y = panel_size.y;
4062                 else
4063                         acceleration_offset.y = panel_size.y;
4064         }
4065         int speed_baralign, acceleration_baralign;
4066         if (autocvar_hud_panel_physics_baralign == 1)
4067                 acceleration_baralign = speed_baralign = 1;
4068     else if(autocvar_hud_panel_physics_baralign == 4)
4069                 acceleration_baralign = speed_baralign = 2;
4070         else if (autocvar_hud_panel_physics_flip)
4071         {
4072                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 2);
4073                 speed_baralign = (autocvar_hud_panel_physics_baralign == 3);
4074         }
4075         else
4076         {
4077                 speed_baralign = (autocvar_hud_panel_physics_baralign == 2);
4078                 acceleration_baralign = (autocvar_hud_panel_physics_baralign == 3);
4079         }
4080         if (autocvar_hud_panel_physics_acceleration_progressbar_mode == 0)
4081                 acceleration_baralign = 3; //override hud_panel_physics_baralign value for acceleration
4082
4083         //draw speed
4084         if(speed)
4085         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4086                 HUD_Panel_DrawProgressBar(panel_pos + speed_offset, panel_size, "progressbar", speed/max_speed, 0, speed_baralign, autocvar_hud_progressbar_speed_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4087         vector tmp_offset = '0 0 0', tmp_size = '0 0 0';
4088         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4089         {
4090                 tmp_size.x = panel_size.x * 0.75;
4091                 tmp_size.y = panel_size.y * text_scale;
4092                 if (speed_baralign)
4093                         tmp_offset.x = panel_size.x - tmp_size.x;
4094                 //else
4095                         //tmp_offset_x = 0;
4096                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4097                 drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(discrete_speed), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4098
4099                 //draw speed unit
4100                 if (speed_baralign)
4101                         tmp_offset.x = 0;
4102                 else
4103                         tmp_offset.x = tmp_size.x;
4104                 if (autocvar_hud_panel_physics_speed_unit_show)
4105                 {
4106                         //tmp_offset_y = 0;
4107                         tmp_size.x = panel_size.x * (1 - 0.75);
4108                         tmp_size.y = panel_size.y * 0.4 * text_scale;
4109                         tmp_offset.y = (panel_size.y * 0.4 - tmp_size.y) / 2;
4110                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, unit, tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4111                 }
4112         }
4113
4114         //compute and draw top speed
4115         if (autocvar_hud_panel_physics_topspeed)
4116         if (autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 2)
4117         {
4118                 if (autocvar__hud_configure)
4119                 {
4120                         top_speed = floor( max_speed * 0.75 + 0.5 );
4121                         f = 1;
4122                 }
4123                 else
4124                 {
4125                         if (speed >= top_speed)
4126                         {
4127                                 top_speed = speed;
4128                                 top_speed_time = time;
4129                         }
4130                         if (top_speed != 0)
4131                         {
4132                                 f = max(1, autocvar_hud_panel_physics_topspeed_time);
4133                                 // divide by f to make it start from 1
4134                                 f = cos( ((time - top_speed_time) / f) * PI/2 );
4135                         }
4136             else //hide top speed 0, it would be stupid
4137                                 f = 0;
4138                 }
4139                 if (f > 0)
4140                 {
4141                         //top speed progressbar peak
4142                         if(speed < top_speed)
4143                         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 2)
4144                         {
4145                                 float peak_offsetX;
4146                                 vector peak_size = '0 0 0';
4147                                 if (speed_baralign == 0)
4148                                         peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x;
4149                 else if (speed_baralign == 1)
4150                                         peak_offsetX = (1 - min(top_speed, max_speed)/max_speed) * panel_size.x;
4151                 else // if (speed_baralign == 2)
4152                     peak_offsetX = min(top_speed, max_speed)/max_speed * panel_size.x * 0.5;
4153                                 peak_size.x = floor(panel_size.x * 0.01 + 1.5);
4154                 peak_size.y = panel_size.y;
4155                 if (speed_baralign == 2) // draw two peaks, on both sides
4156                 {
4157                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x + peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4158                     drawfill(panel_pos + speed_offset + eX * (0.5 * panel_size.x - peak_offsetX + peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4159                 }
4160                 else
4161                     drawfill(panel_pos + speed_offset + eX * (peak_offsetX - peak_size.x), peak_size, autocvar_hud_progressbar_speed_color, f * autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4162                         }
4163
4164                         //top speed
4165                         tmp_offset.y = panel_size.y * 0.4;
4166                         tmp_size.x = panel_size.x * (1 - 0.75);
4167                         tmp_size.y = (panel_size.y - tmp_offset.y) * text_scale;
4168                         tmp_offset.y += (panel_size.y - tmp_offset.y - tmp_size.y) / 2;
4169                         drawstring_aspect(panel_pos + speed_offset + tmp_offset, ftos(top_speed), tmp_size, '1 0 0', f * panel_fg_alpha, DRAWFLAG_NORMAL);
4170                 }
4171                 else
4172                         top_speed = 0;
4173         }
4174
4175         //draw acceleration
4176         if(acceleration)
4177         if(autocvar_hud_panel_physics_progressbar == 1 || autocvar_hud_panel_physics_progressbar == 3)
4178         {
4179                 vector progressbar_color;
4180                 if(acceleration < 0)
4181                         progressbar_color = autocvar_hud_progressbar_acceleration_neg_color;
4182                 else
4183                         progressbar_color = autocvar_hud_progressbar_acceleration_color;
4184
4185                 f = acceleration/autocvar_hud_panel_physics_acceleration_max;
4186                 if (autocvar_hud_panel_physics_acceleration_progressbar_nonlinear)
4187                         f = (f >= 0 ? sqrt(f) : -sqrt(-f));
4188
4189                 if (acceleration_progressbar_scale) // allow progressbar to go out of panel bounds
4190                 {
4191                         tmp_size = acceleration_progressbar_scale * panel_size.x * eX + panel_size.y * eY;
4192
4193                         if (acceleration_baralign == 1)
4194                                 tmp_offset.x = panel_size.x - tmp_size.x;
4195                         else if (acceleration_baralign == 2 || acceleration_baralign == 3)
4196                                 tmp_offset.x = (panel_size.x - tmp_size.x) / 2;
4197                         else
4198                                 tmp_offset.x = 0;
4199                         tmp_offset.y = 0;
4200                 }
4201                 else
4202                 {
4203                         tmp_size = panel_size;
4204                         tmp_offset = '0 0 0';
4205                 }
4206
4207                 HUD_Panel_DrawProgressBar(panel_pos + acceleration_offset + tmp_offset, tmp_size, "accelbar", f, 0, acceleration_baralign, progressbar_color, autocvar_hud_progressbar_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
4208         }
4209
4210         if(autocvar_hud_panel_physics_text == 1 || autocvar_hud_panel_physics_text == 3)
4211         {
4212                 tmp_size.x = panel_size.x;
4213                 tmp_size.y = panel_size.y * text_scale;
4214                 tmp_offset.x = 0;
4215                 tmp_offset.y = (panel_size.y - tmp_size.y) / 2;
4216
4217                 drawstring_aspect(panel_pos + acceleration_offset + tmp_offset, strcat(ftos_decimals(discrete_acceleration, acc_decimals), "g"), tmp_size, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
4218         }
4219
4220         draw_endBoldFont();
4221 }
4222
4223 // CenterPrint (#16)
4224 //
4225 const int CENTERPRINT_MAX_MSGS = 10;
4226 const int CENTERPRINT_MAX_ENTRIES = 50;
4227 const float CENTERPRINT_SPACING = 0.7;
4228 int cpm_index;
4229 string centerprint_messages[CENTERPRINT_MAX_MSGS];
4230 int centerprint_msgID[CENTERPRINT_MAX_MSGS];
4231 float centerprint_time[CENTERPRINT_MAX_MSGS];
4232 float centerprint_expire_time[CENTERPRINT_MAX_MSGS];
4233 int centerprint_countdown_num[CENTERPRINT_MAX_MSGS];
4234 bool centerprint_showing;
4235
4236 void centerprint_generic(int new_id, string strMessage, float duration, int countdown_num)
4237 {
4238         //printf("centerprint_generic(%d, '%s^7', %d, %d);\n", new_id, strMessage, duration, countdown_num);
4239         int i, j;
4240
4241         if(strMessage == "" && new_id == 0)
4242                 return;
4243
4244         // strip trailing newlines
4245         j = strlen(strMessage) - 1;
4246         while(substring(strMessage, j, 1) == "\n" && j >= 0)
4247                 --j;
4248         if (j < strlen(strMessage) - 1)
4249                 strMessage = substring(strMessage, 0, j + 1);
4250
4251         if(strMessage == "" && new_id == 0)
4252                 return;
4253
4254         // strip leading newlines
4255         j = 0;
4256         while(substring(strMessage, j, 1) == "\n" && j < strlen(strMessage))
4257                 ++j;
4258         if (j > 0)
4259                 strMessage = substring(strMessage, j, strlen(strMessage) - j);
4260
4261         if(strMessage == "" && new_id == 0)
4262                 return;
4263
4264         if (!centerprint_showing)
4265                 centerprint_showing = true;
4266
4267         for (i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4268         {
4269                 if (j == CENTERPRINT_MAX_MSGS)
4270                         j = 0;
4271                 if (new_id && new_id == centerprint_msgID[j])
4272                 {
4273                         if (strMessage == "" && centerprint_messages[j] != "" && centerprint_countdown_num[j] == 0)
4274                         {
4275                                 // fade out the current msg (duration and countdown_num are ignored)
4276                                 centerprint_time[j] = min(5, autocvar_hud_panel_centerprint_fade_out);
4277                                 if (centerprint_expire_time[j] > time + min(5, autocvar_hud_panel_centerprint_fade_out) || centerprint_expire_time[j] < time)
4278                                         centerprint_expire_time[j] = time + min(5, autocvar_hud_panel_centerprint_fade_out);
4279                                 return;
4280                         }
4281                         break; // found a msg with the same id, at position j
4282                 }
4283         }
4284
4285         if (i == CENTERPRINT_MAX_MSGS)
4286         {
4287                 // a msg with the same id was not found, add the msg at the next position
4288                 --cpm_index;
4289                 if (cpm_index == -1)
4290                         cpm_index = CENTERPRINT_MAX_MSGS - 1;
4291                 j = cpm_index;
4292         }
4293         if(centerprint_messages[j])
4294                 strunzone(centerprint_messages[j]);
4295         centerprint_messages[j] = strzone(strMessage);
4296         centerprint_msgID[j] = new_id;
4297         if (duration < 0)
4298         {
4299                 centerprint_time[j] = -1;
4300                 centerprint_expire_time[j] = time;
4301         }
4302         else
4303         {
4304                 if(duration == 0)
4305                         duration = max(1, autocvar_hud_panel_centerprint_time);
4306                 centerprint_time[j] = duration;
4307                 centerprint_expire_time[j] = time + duration;
4308         }
4309         centerprint_countdown_num[j] = countdown_num;
4310 }
4311
4312 void centerprint_hud(string strMessage)
4313 {
4314         centerprint_generic(0, strMessage, autocvar_hud_panel_centerprint_time, 0);
4315 }
4316
4317 void reset_centerprint_messages(void)
4318 {
4319         int i;
4320         for (i=0; i<CENTERPRINT_MAX_MSGS; ++i)
4321         {
4322                 centerprint_expire_time[i] = 0;
4323                 centerprint_time[i] = 1;
4324                 centerprint_msgID[i] = 0;
4325                 if(centerprint_messages[i])
4326                         strunzone(centerprint_messages[i]);
4327                 centerprint_messages[i] = string_null;
4328         }
4329 }
4330 float hud_configure_cp_generation_time;
4331 void HUD_CenterPrint (void)
4332 {
4333         if(!autocvar__hud_configure)
4334         {
4335                 if(!autocvar_hud_panel_centerprint) return;
4336
4337                 if(hud_configure_prev)
4338                         reset_centerprint_messages();
4339         }
4340         else
4341         {
4342                 if(!hud_configure_prev)
4343                         reset_centerprint_messages();
4344                 if (time > hud_configure_cp_generation_time)
4345                 {
4346                         if(HUD_PANEL(CENTERPRINT) == highlightedPanel)
4347                         {
4348                                 float r;
4349                                 r = random();
4350                                 if (r > 0.8)
4351                                         centerprint_generic(floor(r*1000), strcat(sprintf("^3Countdown message at time %s", seconds_tostring(time)), ", seconds left: ^COUNT"), 1, 10);
4352                                 else if (r > 0.55)
4353                                         centerprint_generic(0, sprintf("^1Multiline message at time %s that\n^1lasts longer than normal", seconds_tostring(time)), 20, 0);
4354                                 else
4355                                         centerprint_hud(sprintf("Message at time %s", seconds_tostring(time)));
4356                                 hud_configure_cp_generation_time = time + 1 + random()*4;
4357                         }
4358                         else
4359                         {
4360                                 centerprint_generic(0, sprintf("Centerprint message", seconds_tostring(time)), 10, 0);
4361                                 hud_configure_cp_generation_time = time + 10 - random()*3;
4362                         }
4363                 }
4364         }
4365
4366         // this panel fades only when the menu does
4367         float hud_fade_alpha_save = 0;
4368         if(scoreboard_fade_alpha)
4369         {
4370                 hud_fade_alpha_save = hud_fade_alpha;
4371                 hud_fade_alpha = 1 - autocvar__menu_alpha;
4372         }
4373         HUD_Panel_UpdateCvars();
4374
4375         if(scoreboard_fade_alpha)
4376         {
4377                 hud_fade_alpha = hud_fade_alpha_save;
4378
4379                 // move the panel below the scoreboard
4380                 if (scoreboard_bottom >= 0.96 * vid_conheight)
4381                         return;
4382                 vector target_pos;
4383
4384                 target_pos = eY * scoreboard_bottom + eX * 0.5 * (vid_conwidth - panel_size.x);
4385
4386                 if(target_pos.y > panel_pos.y)
4387                 {
4388                         panel_pos = panel_pos + (target_pos - panel_pos) * sqrt(scoreboard_fade_alpha);
4389                         panel_size.y = min(panel_size.y, vid_conheight - scoreboard_bottom);
4390                 }
4391         }
4392
4393         HUD_Panel_DrawBg(1);
4394
4395         if (!centerprint_showing)
4396                 return;
4397
4398         if(panel_bg_padding)
4399         {
4400                 panel_pos += '1 1 0' * panel_bg_padding;
4401                 panel_size -= '2 2 0' * panel_bg_padding;
4402         }
4403
4404         int entries;
4405         float height;
4406         vector fontsize;
4407         // entries = bound(1, floor(CENTERPRINT_MAX_ENTRIES * 4 * panel_size_y/panel_size_x), CENTERPRINT_MAX_ENTRIES);
4408         // height = panel_size_y/entries;
4409         // fontsize = '1 1 0' * height;
4410         height = vid_conheight/50 * autocvar_hud_panel_centerprint_fontscale;
4411         fontsize = '1 1 0' * height;
4412         entries = bound(1, floor(panel_size.y/height), CENTERPRINT_MAX_ENTRIES);
4413
4414         int i, j, k, n, g;
4415         float a, sz, align, current_msg_posY = 0, msg_size;
4416         vector pos;
4417         string ts;
4418         bool all_messages_expired = true;
4419
4420         pos = panel_pos;
4421         if (autocvar_hud_panel_centerprint_flip)
4422                 pos.y += panel_size.y;
4423         align = bound(0, autocvar_hud_panel_centerprint_align, 1);
4424         for (g=0, i=0, j=cpm_index; i<CENTERPRINT_MAX_MSGS; ++i, ++j)
4425         {
4426                 if (j == CENTERPRINT_MAX_MSGS)
4427                         j = 0;
4428                 if (centerprint_expire_time[j] <= time)
4429                 {
4430                         if (centerprint_countdown_num[j] && centerprint_time[j] > 0)
4431                         {
4432                                 centerprint_countdown_num[j] = centerprint_countdown_num[j] - 1;
4433                                 if (centerprint_countdown_num[j] == 0)
4434                                         continue;
4435                                 centerprint_expire_time[j] = centerprint_expire_time[j] + centerprint_time[j];
4436                         }
4437                         else if(centerprint_time[j] != -1)
4438                                 continue;
4439                 }
4440
4441                 all_messages_expired = false;
4442
4443                 // fade the centerprint_hud in/out
4444                 if(centerprint_time[j] < 0)  // Expired but forced. Expire time is the fade-in time.
4445                         a = (time - centerprint_expire_time[j]) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4446                 else if(centerprint_expire_time[j] - autocvar_hud_panel_centerprint_fade_out > time)  // Regularily printed. Not fading out yet.
4447                         a = (time - (centerprint_expire_time[j] - centerprint_time[j])) / max(0.0001, autocvar_hud_panel_centerprint_fade_in);
4448                 else // Expiring soon, so fade it out.
4449                         a = (centerprint_expire_time[j] - time) / max(0.0001, autocvar_hud_panel_centerprint_fade_out);
4450
4451                 // while counting down show it anyway in order to hold the current message position
4452                 if (a <= 0.5/255.0 && centerprint_countdown_num[j] == 0)  // Guaranteed invisible - don't show.
4453                         continue;
4454                 if (a > 1)
4455                         a = 1;
4456
4457                 // set the size from fading in/out before subsequent fading
4458                 sz = autocvar_hud_panel_centerprint_fade_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_minfontsize);
4459
4460                 // also fade it based on positioning
4461                 if(autocvar_hud_panel_centerprint_fade_subsequent)
4462                 {
4463                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passone_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passone))), 1); // pass one: all messages after the first have half theAlpha
4464                         a = a * bound(autocvar_hud_panel_centerprint_fade_subsequent_passtwo_minalpha, (1 - (g / max(1, autocvar_hud_panel_centerprint_fade_subsequent_passtwo))), 1); // pass two: after that, gradually lower theAlpha even more for each message
4465                 }
4466                 a *= panel_fg_alpha;
4467
4468                 // finally set the size based on the new theAlpha from subsequent fading
4469                 sz = sz * (autocvar_hud_panel_centerprint_fade_subsequent_minfontsize + a * (1 - autocvar_hud_panel_centerprint_fade_subsequent_minfontsize));
4470                 drawfontscale = sz * '1 1 0';
4471
4472                 if (centerprint_countdown_num[j])
4473                         n = tokenizebyseparator(strreplace("^COUNT", count_seconds(centerprint_countdown_num[j]), centerprint_messages[j]), "\n");
4474                 else
4475                         n = tokenizebyseparator(centerprint_messages[j], "\n");
4476
4477                 if (autocvar_hud_panel_centerprint_flip)
4478                 {
4479                         // check if the message can be entirely shown
4480                         for(k = 0; k < n; ++k)
4481                         {
4482                                 getWrappedLine_remaining = argv(k);
4483                                 while(getWrappedLine_remaining)
4484                                 {
4485                                         ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4486                                         if (ts != "")
4487                                                 pos.y -= fontsize.y;
4488                                         else
4489                                                 pos.y -= fontsize.y * CENTERPRINT_SPACING/2;
4490                                 }
4491                         }
4492                         current_msg_posY = pos.y; // save starting pos (first line) of the current message
4493                 }
4494
4495                 msg_size = pos.y;
4496                 for(k = 0; k < n; ++k)
4497                 {
4498                         getWrappedLine_remaining = argv(k);
4499                         while(getWrappedLine_remaining)
4500                         {
4501                                 ts = getWrappedLine(panel_size.x * sz, fontsize, stringwidth_colors);
4502                                 if (ts != "")
4503                                 {
4504                                         if (align)
4505                                                 pos.x = panel_pos.x + (panel_size.x - stringwidth(ts, true, fontsize)) * align;
4506                                         if (a > 0.5/255.0)  // Otherwise guaranteed invisible - don't show. This is checked a second time after some multiplications with other factors were done so temporary changes of these cannot cause flicker.
4507                                                 drawcolorcodedstring(pos + eY * 0.5 * (1 - sz) * fontsize.y, ts, fontsize, a, DRAWFLAG_NORMAL);
4508                                         pos.y += fontsize.y;
4509                                 }
4510                                 else
4511                                         pos.y += fontsize.y * CENTERPRINT_SPACING/2;
4512                         }
4513                 }
4514
4515                 ++g; // move next position number up
4516
4517                 msg_size = pos.y - msg_size;
4518                 if (autocvar_hud_panel_centerprint_flip)
4519                 {
4520                         pos.y = current_msg_posY - CENTERPRINT_SPACING * fontsize.y;
4521                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4522                                 pos.y += (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4523
4524                         if (pos.y < panel_pos.y) // check if the next message can be shown
4525                         {
4526                                 drawfontscale = '1 1 0';
4527                                 return;
4528                         }
4529                 }
4530                 else
4531                 {
4532                         pos.y += CENTERPRINT_SPACING * fontsize.y;
4533                         if (a < 1 && centerprint_msgID[j] == 0) // messages with id can be replaced just after they are faded out, so never move over them the next messages
4534                                 pos.y -= (msg_size + CENTERPRINT_SPACING * fontsize.y) * (1 - sqrt(sz));
4535
4536                         if(pos.y > panel_pos.y + panel_size.y - fontsize.y) // check if the next message can be shown
4537                         {
4538                                 drawfontscale = '1 1 0';
4539                                 return;
4540                         }
4541                 }
4542         }
4543         drawfontscale = '1 1 0';
4544         if (all_messages_expired)
4545         {
4546                 centerprint_showing = false;
4547                 reset_centerprint_messages();
4548         }
4549 }
4550
4551 // Buffs (#18)
4552 //
4553 void HUD_Buffs(void)
4554 {
4555         int buffs = getstati(STAT_BUFFS, 0, 24);
4556         if(!autocvar__hud_configure)
4557         {
4558                 if(!autocvar_hud_panel_buffs) return;
4559                 if(spectatee_status == -1) return;
4560                 if(getstati(STAT_HEALTH) <= 0) return;
4561                 if(!buffs) return;
4562         }
4563         else
4564         {
4565                 buffs = Buff_Type_first.items; // force first buff
4566         }
4567
4568         int b = 0; // counter to tell other functions that we have buffs
4569         entity e;
4570         string s = "";
4571         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4572         {
4573                 ++b;
4574                 string o = strcat(rgb_to_hexcolor(Buff_Color(e.items)), Buff_PrettyName(e.items));
4575                 if(s == "")
4576                         s = o;
4577                 else
4578                         s = strcat(s, " ", o);
4579         }
4580
4581         HUD_Panel_UpdateCvars();
4582
4583         draw_beginBoldFont();
4584
4585         vector pos, mySize;
4586         pos = panel_pos;
4587         mySize = panel_size;
4588
4589         HUD_Panel_DrawBg(bound(0, b, 1));
4590         if(panel_bg_padding)
4591         {
4592                 pos += '1 1 0' * panel_bg_padding;
4593                 mySize -= '2 2 0' * panel_bg_padding;
4594         }
4595
4596         //float panel_ar = mySize_x/mySize_y;
4597         //bool is_vertical = (panel_ar < 1);
4598         //float buff_iconalign = autocvar_hud_panel_buffs_iconalign;
4599         vector buff_offset = '0 0 0';
4600
4601         for(e = Buff_Type_first; e; e = e.enemy) if(buffs & e.items)
4602         {
4603                 //DrawNumIcon(pos + buff_offset, mySize, shield, "shield", is_vertical, buff_iconalign, '1 1 1', 1);
4604                 drawcolorcodedstring_aspect(pos + buff_offset, s, mySize, panel_fg_alpha * 0.5, DRAWFLAG_NORMAL);
4605         }
4606
4607         draw_endBoldFont();
4608 }
4609
4610
4611 /*
4612 ==================
4613 Main HUD system
4614 ==================
4615 */
4616
4617 void HUD_Reset (void)
4618 {
4619         // reset gametype specific icons
4620         if(gametype == MAPINFO_TYPE_CTF)
4621                 HUD_Mod_CTF_Reset();
4622 }
4623
4624 void HUD_Main (void)
4625 {
4626         int i;
4627         // global hud theAlpha fade
4628         if(menu_enabled == 1)
4629                 hud_fade_alpha = 1;
4630         else
4631                 hud_fade_alpha = (1 - autocvar__menu_alpha);
4632
4633         if(scoreboard_fade_alpha)
4634                 hud_fade_alpha = (1 - scoreboard_fade_alpha);
4635
4636         HUD_Configure_Frame();
4637
4638         if(intermission == 2) // no hud during mapvote
4639                 hud_fade_alpha = 0;
4640
4641         // panels that we want to be active together with the scoreboard
4642         // they must fade only when the menu does
4643         if(scoreboard_fade_alpha == 1)
4644         {
4645                 (panel = HUD_PANEL(CENTERPRINT)).panel_draw();
4646                 return;
4647         }
4648
4649         if(!autocvar__hud_configure && !hud_fade_alpha)
4650                 return;
4651
4652         // Drawing stuff
4653         if (hud_skin_prev != autocvar_hud_skin)
4654         {
4655                 if (hud_skin_path)
4656                         strunzone(hud_skin_path);
4657                 hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
4658                 if (hud_skin_prev)
4659                         strunzone(hud_skin_prev);
4660                 hud_skin_prev = strzone(autocvar_hud_skin);
4661         }
4662
4663         // draw the dock
4664         if(autocvar_hud_dock != "" && autocvar_hud_dock != "0")
4665         {
4666                 int f;
4667                 vector color;
4668                 float hud_dock_color_team = autocvar_hud_dock_color_team;
4669                 if((teamplay) && hud_dock_color_team) {
4670                         if(autocvar__hud_configure && myteam == NUM_SPECTATOR)
4671                                 color = '1 0 0' * hud_dock_color_team;
4672                         else
4673                                 color = myteamcolors * hud_dock_color_team;
4674                 }
4675                 else if(autocvar_hud_configure_teamcolorforced && autocvar__hud_configure && hud_dock_color_team) {
4676                         color = '1 0 0' * hud_dock_color_team;
4677                 }
4678                 else
4679                 {
4680                         string hud_dock_color = autocvar_hud_dock_color;
4681                         if(hud_dock_color == "shirt") {
4682                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4683                                 color = colormapPaletteColor(floor(f / 16), 0);
4684                         }
4685                         else if(hud_dock_color == "pants") {
4686                                 f = stof(getplayerkeyvalue(current_player, "colors"));
4687                                 color = colormapPaletteColor(f % 16, 1);
4688                         }
4689                         else
4690                                 color = stov(hud_dock_color);
4691                 }
4692
4693                 string pic;
4694                 pic = strcat(hud_skin_path, "/", autocvar_hud_dock);
4695                 if(precache_pic(pic) == "") {
4696                         pic = strcat(hud_skin_path, "/dock_medium");
4697                         if(precache_pic(pic) == "") {
4698                                 pic = "gfx/hud/default/dock_medium";
4699                         }
4700                 }
4701                 drawpic('0 0 0', pic, eX * vid_conwidth + eY * vid_conheight, color, autocvar_hud_dock_alpha * hud_fade_alpha, DRAWFLAG_NORMAL); // no aspect ratio forcing on dock...
4702         }
4703
4704         // cache the panel order into the panel_order array
4705         if(autocvar__hud_panelorder != hud_panelorder_prev) {
4706                 for(i = 0; i < HUD_PANEL_NUM; ++i)
4707                         panel_order[i] = -1;
4708                 string s = "";
4709                 int p_num;
4710                 bool warning = false;
4711                 int argc = tokenize_console(autocvar__hud_panelorder);
4712                 if (argc > HUD_PANEL_NUM)
4713                         warning = true;
4714                 //first detect wrong/missing panel numbers
4715                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4716                         p_num = stoi(argv(i));
4717                         if (p_num >= 0 && p_num < HUD_PANEL_NUM) { //correct panel number?
4718                                 if (panel_order[p_num] == -1) //found for the first time?
4719                                         s = strcat(s, ftos(p_num), " ");
4720                                 panel_order[p_num] = 1; //mark as found
4721                         }
4722                         else
4723                                 warning = true;
4724                 }
4725                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4726                         if (panel_order[i] == -1) {
4727                                 warning = true;
4728                                 s = strcat(s, ftos(i), " "); //add missing panel number
4729                         }
4730                 }
4731                 if (warning)
4732                         dprint("Automatically fixed wrong/missing panel numbers in _hud_panelorder\n");
4733
4734                 cvar_set("_hud_panelorder", s);
4735                 if(hud_panelorder_prev)
4736                         strunzone(hud_panelorder_prev);
4737                 hud_panelorder_prev = strzone(s);
4738
4739                 //now properly set panel_order
4740                 tokenize_console(s);
4741                 for(i = 0; i < HUD_PANEL_NUM; ++i) {
4742                         panel_order[i] = stof(argv(i));
4743                 }
4744         }
4745
4746         hud_draw_maximized = 0;
4747         // draw panels in order specified by panel_order array
4748         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
4749                 (panel = hud_panel[panel_order[i]]).panel_draw();
4750
4751         hud_draw_maximized = 1; // panels that may be maximized must check this var
4752         // draw maximized panels on top
4753         if(hud_panel_radar_maximized)
4754                 (panel = HUD_PANEL(RADAR)).panel_draw();
4755         if(autocvar__con_chat_maximized)
4756                 (panel = HUD_PANEL(CHAT)).panel_draw();
4757
4758         HUD_Configure_PostDraw();
4759
4760         hud_configure_prev = autocvar__hud_configure;
4761 }