qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/autocvars.qh>
   6 #include <client/miscfunctions.qh>
   7 #include <common/animdecide.qh>
   8 #include <common/ent_cs.qh>
   9 #include <common/mapinfo.qh>
  10 #include <common/physics/movetypes/movetypes.qh>
  11 #include <common/physics/player.qh>
  12 #include <lib/csqcmodel/cl_player.qh>
  13
  14 // StrafeHUD (#25)
  15
  16 void HUD_StrafeHUD_Export(int fh)
  17 {
  18     // allow saving cvars that aesthetically change the panel into hud skin files
  19 }
  20
  21 float hidden_width;
  22 int direction;
  23 float demo_angle = -37;
  24 float demo_direction = 1;
  25 float demo_time = 0;
  26 bool state_onground = false;
  27 float state_onground_time = 0;
  28 bool state_strafekeys = false;
  29 float state_strafekeys_time = 0;
  30 bool turn = false;
  31 float turnangle;
  32 bool fwd = true;
  33 bool state_fwd = true;
  34 bool state_fwd_prev = true;
  35 float state_fwd_time = 0;
  36 float starttime = 0;
  37 float startspeed = -1;
  38 float jumptime = 0;
  39 float jumpheight = -1;
  40 float jumpheight_persistent = -1;
  41 float jumpheight_prev = 0;
  42 float jumpspeed_prev = 0;
  43 bool  jumprestart = true;
  44
  45 // provide basic panel cvars to old clients
  46 // TODO remove them after a future release (0.8.2+)
  47 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  48 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  49 noref string autocvar_hud_panel_strafehud_bg = "0";
  50 noref string autocvar_hud_panel_strafehud_bg_color = "";
  51 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  52 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  53 noref string autocvar_hud_panel_strafehud_bg_border = "";
  54 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  55
  56 void HUD_StrafeHUD()
  57 {
  58     entity strafeplayer;
  59     bool islocal;
  60
  61     // generic hud routines
  62     if(!autocvar__hud_configure)
  63     {
  64         if(!autocvar_hud_panel_strafehud ||
  65            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  66            (autocvar_hud_panel_strafehud == 3 && !(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))) return;
  67     }
  68
  69     HUD_Panel_LoadCvars();
  70
  71     if(autocvar_hud_panel_strafehud_dynamichud)
  72     {
  73         HUD_Scale_Enable();
  74     }
  75     else
  76     {
  77         HUD_Scale_Disable();
  78     }
  79
  80     HUD_Panel_DrawBg();
  81
  82     if(panel_bg_padding)
  83     {
  84         panel_pos  += '1 1 0' * panel_bg_padding;
  85         panel_size -= '2 2 0' * panel_bg_padding;
  86     }
  87
  88     // find out whether the local csqcmodel entity is valid
  89     if(spectatee_status > 0 || isdemo())
  90     {
  91         islocal = false;
  92         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  93     }
  94     else
  95     {
  96         islocal = true;
  97         strafeplayer = csqcplayer;
  98     }
  99
 100     // draw strafehud
 101     if(csqcplayer && strafeplayer)
 102     {
 103         // physics
 104         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 105         bool   strafekeys;
 106         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 107         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 108         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 109         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 110         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 111         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 112         float  vel_angle                     = vectoangles(strafeplayer.velocity).y;
 113         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y + 180;
 114         float  angle;
 115         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 116         int    keys                          = STAT(PRESSED_KEYS);
 117         int    keys_fwd;
 118         float  wishangle                     = 0;
 119
 120         // HUD
 121         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 122         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 123         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 124         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 125         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 126         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 127         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 128         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 129         float  minspeed;
 130         float  shift_offset                  = 0;
 131         bool   straight_overturn             = false;
 132         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 133         float  hudangle;
 134         float  neutral_offset;
 135         float  neutral_width;
 136         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 137         float  currentangle_offset;
 138         vector currentangle_size             = '0 0 0';
 139         float  bestangle;
 140         float  odd_bestangle;
 141         bool   bestangle_anywhere            = false;
 142         float  bestangle_offset;
 143         float  switch_bestangle_offset;
 144         bool   odd_angles                    = false;
 145         float  odd_bestangle_offset          = 0;
 146         float  switch_odd_bestangle_offset   = 0;
 147         float  bestangle_width;
 148         float  accelzone_left_offset;
 149         float  accelzone_right_offset;
 150         float  accelzone_width;
 151         float  overturn_offset;
 152         float  overturn_width;
 153         float  slickdetector_height;
 154         vector direction_size_vertical       = '0 0 0';
 155         vector direction_size_horizontal     = '0 0 0';
 156         float  range_minangle;
 157
 158         // determine whether the player is pressing forwards or backwards keys
 159         if(islocal) // if entity is local player
 160         {
 161             if(movement.x > 0)
 162             {
 163                 keys_fwd = 1;
 164             }
 165             else if(movement.x < 0)
 166             {
 167                 keys_fwd = -1;
 168             }
 169             else
 170             {
 171                 keys_fwd = 0;
 172             }
 173         }
 174         else // alternatively determine direction by querying pressed keys
 175         {
 176             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 177             {
 178                 keys_fwd = 1;
 179             }
 180             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 181             {
 182                 keys_fwd = -1;
 183             }
 184             else
 185             {
 186                 keys_fwd = 0;
 187             }
 188         }
 189
 190         // determine player wishdir
 191         if(islocal) // if entity is local player
 192         {
 193             if(movement.x == 0)
 194             {
 195                 if(movement.y < 0)
 196                 {
 197                     wishangle = -90;
 198                 }
 199                 else if(movement.y > 0)
 200                 {
 201                     wishangle = 90;
 202                 }
 203                 else
 204                 {
 205                     wishangle = 0;
 206                 }
 207             }
 208             else
 209             {
 210                 if(movement.y == 0)
 211                 {
 212                     wishangle = 0;
 213                 }
 214                 else
 215                 {
 216                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 217                     // wrap the wish angle if it exceeds ±90°
 218                     if(fabs(wishangle) > 90)
 219                     {
 220                         if(wishangle < 0) wishangle += 180;
 221                         else wishangle -= 180;
 222                         wishangle = -wishangle;
 223                     }
 224                 }
 225             }
 226         }
 227         else // alternatively calculate wishdir by querying pressed keys
 228         {
 229             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 230             {
 231                 wishangle = 45;
 232             }
 233             else
 234             {
 235                 wishangle = 90;
 236             }
 237             if(keys & KEY_LEFT)
 238             {
 239                 wishangle *= -1;
 240             }
 241             else if(!(keys & KEY_RIGHT))
 242             {
 243                 wishangle = 0; // wraps at 180°
 244             }
 245         }
 246
 247         strafekeys = fabs(wishangle) == 90;
 248
 249         // determine minimum required angle to display full strafe range
 250         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 251         if(range_minangle > 45) // minimum angle range is 45
 252         {
 253             range_minangle = 45 - fabs(wishangle) % 45;
 254         }
 255         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 256         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 257
 258         if(autocvar_hud_panel_strafehud_range == 0)
 259         {
 260             if(autocvar__hud_configure)
 261             {
 262                 hudangle = 90;
 263             }
 264             else
 265             {
 266                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 267             }
 268         }
 269         else
 270         {
 271             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 272         }
 273
 274         // detect air strafe turning
 275         if(onground != state_onground)
 276         {
 277             state_onground_time = time;
 278         }
 279         state_onground = onground;
 280
 281         if(strafekeys != state_strafekeys)
 282         {
 283             state_strafekeys_time = time;
 284         }
 285         state_strafekeys = strafekeys;
 286
 287         if((keys & KEY_FORWARD) || (keys & KEY_BACKWARD) || swimming || autocvar__hud_configure)
 288         {
 289             turn = false;
 290         }
 291         else if(onground)
 292         {
 293             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 294             {
 295                 turn = false;
 296             }
 297         }
 298         else // air strafe only
 299         {
 300             if(strafekeys)
 301             {
 302                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 303                 {
 304                     turn = true; // CPMA turning
 305                     turnangle = wishangle;
 306                 }
 307             }
 308             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 309             {
 310                 turn = false;
 311             }
 312         }
 313         if(turn)
 314         {
 315             maxspeed = PHYS_MAXAIRSTRAFESPEED(strafeplayer); // no modifiers here because they don't affect air strafing
 316             wishangle = turnangle;
 317         }
 318
 319         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? maxspeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 320
 321         // get current strafing angle ranging from -180° to +180°
 322         if(!autocvar__hud_configure)
 323         {
 324             if(speed > 0)
 325             {
 326                 // calculate view angle relative to the players current velocity direction
 327                 angle = vel_angle - view_angle;
 328
 329                 // if the angle goes above 180° or below -180° wrap it to the opposite side
 330                 if (angle > 180) angle -= 360;
 331                 else if(angle < -180) angle += 360;
 332
 333                 // shift the strafe angle by 180° for hud calculations
 334                 if(angle < 0) angle += 180;
 335                 else angle -= 180;
 336
 337                 // determine whether the player is strafing forwards or backwards
 338                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 339                 if(!strafekeys)
 340                 {
 341                     if(keys_fwd > 0)
 342                     {
 343                         state_fwd = true;
 344                     }
 345                     else if(keys_fwd < 0)
 346                     {
 347                         state_fwd = false;
 348                     }
 349                     else
 350                     {
 351                         state_fwd = fabs(angle) <= 90;
 352                     }
 353                 }
 354                 // otherwise determine by examining the strafe angle
 355                 else
 356                 {
 357                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 358                     {
 359                         state_fwd = angle <= -wishangle;
 360                     }
 361                     else
 362                     {
 363                         state_fwd = angle >= -wishangle;
 364                     }
 365                 }
 366
 367                 if(state_fwd_prev != state_fwd)
 368                 {
 369                     state_fwd_time = time;
 370                 }
 371                 state_fwd_prev = state_fwd;
 372
 373                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < maxspeed || (strafekeys && mode == 0)) // timeout when changing between forwards and backwards movement
 374                 {
 375                     fwd = state_fwd;
 376                 }
 377
 378                 // shift the strafe angle by 180° when strafing backwards
 379                 if(!fwd)
 380                 {
 381                     if(angle < 0) angle += 180;
 382                     else angle -= 180;
 383                 }
 384
 385                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 386                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 387                 {
 388                     straight_overturn = true;
 389                 }
 390             }
 391             else
 392             {
 393                 angle = 0;
 394             }
 395         }
 396         else // simulate turning for HUD setup
 397         {
 398             fwd = true;
 399             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 400             {
 401                 demo_time = time;
 402                 demo_angle += demo_direction;
 403                 if(fabs(demo_angle) >= 55)
 404                 {
 405                     demo_direction = -demo_direction;
 406                 }
 407             }
 408             angle = demo_angle;
 409             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 410         }
 411
 412         // invert the wish angle when strafing backwards
 413         if(!fwd)
 414         {
 415             wishangle = -wishangle;
 416         }
 417
 418         // flip angles if v_flipped is enabled
 419         if(autocvar_v_flipped)
 420         {
 421             angle = -angle;
 422             wishangle = -wishangle;
 423         }
 424
 425         // determine whether the player is strafing left or right
 426         if(wishangle != 0)
 427         {
 428             direction = wishangle > 0 ? 1 : -1;
 429         }
 430         else
 431         {
 432             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 433         }
 434
 435         // best angle to strafe at
 436         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 437         odd_bestangle = -bestangle - wishangle;
 438         bestangle -= wishangle;
 439
 440         // various offsets and size calculations of hud indicator elements
 441         // how much is hidden by the current hud angle
 442         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 443         // current angle
 444         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 445         if(mode == 0)
 446         {
 447             currentangle_offset = angle/hudangle * panel_size.x;
 448         }
 449         else
 450         {
 451             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 452         }
 453         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 454         // best strafe acceleration angle
 455         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 456         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 457         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 458
 459         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 460         {
 461             odd_angles = true;
 462             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 463             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 464         }
 465         // direction indicator
 466         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 467         direction_size_vertical.y = panel_size.y;
 468         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 469         direction_size_horizontal.y = direction_size_vertical.x;
 470         // overturn
 471         overturn_width = 180/hudangle * panel_size.x;
 472
 473         // the neutral zone fills the whole strafe bar
 474         if(immobile)
 475         {
 476             // draw neutral zone
 477             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 478             {
 479                 switch(autocvar_hud_panel_strafehud_style)
 480                 {
 481                     default:
 482                     case 0:
 483                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 484                         break;
 485
 486                     case 1:
 487                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 488                 }
 489             }
 490         }
 491         else
 492         {
 493             // calculate various zones of the strafe-o-meter
 494             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 495             accelzone_right_offset = 0;
 496             accelzone_left_offset = overturn_offset + overturn_width;
 497             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 498             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 499
 500             // remove switch indicator width from offset
 501             if(direction < 0)
 502             {
 503                 bestangle_offset -= bestangle_width;
 504                 switch_odd_bestangle_offset -= bestangle_width;
 505             }
 506             else
 507             {
 508                 switch_bestangle_offset -= bestangle_width;
 509                 odd_bestangle_offset -= bestangle_width;
 510             }
 511
 512             // shift hud if operating in view angle centered mode
 513             if(mode == 0)
 514             {
 515                 shift_offset = -currentangle_offset;
 516                 bestangle_offset += shift_offset;
 517                 switch_bestangle_offset += shift_offset;
 518                 odd_bestangle_offset += shift_offset;
 519                 switch_odd_bestangle_offset += shift_offset;
 520             }
 521             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 522             // calculate how far off-center the strafe zones currently are
 523             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 524             // shift strafe zones into correct place
 525             neutral_offset += shift_offset;
 526             accelzone_left_offset += shift_offset;
 527             accelzone_right_offset += shift_offset;
 528             overturn_offset += shift_offset;
 529
 530             // draw left acceleration zone
 531             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 532
 533             // draw right acceleration zone
 534             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 535
 536             // draw overturn zone
 537             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 538
 539             // draw neutral zone
 540             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 541
 542             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 543             {
 544                 bool indicator_direction = direction < 0;
 545                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 546                 // if both conditions are true then it's inverted twice hence not inverted at all
 547                 if(!fwd != odd_angles)
 548                 {
 549                     indicator_direction = !indicator_direction;
 550                 }
 551                 // draw the direction indicator caps at the sides of the hud
 552                 // vertical line
 553                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 554                 // top horizontal line
 555                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 556                 // bottom horizontal line
 557                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 558             }
 559
 560             if(speed >= minspeed) // only draw indicators if minspeed is reached
 561             {
 562                 // draw best angles for acceleration
 563                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 564                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 565                 // both indicators are inactive if no direction can be determined
 566                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 567                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 568                 // draw the switch indicators
 569                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 570                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 571             }
 572         }
 573
 574         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 575         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 576         {
 577             float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 578             bool slickdetected = false;
 579
 580             slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 581
 582             // traceline into every direction
 583             trace_dphitq3surfaceflags = 0;
 584             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 585             {
 586                 vector slickoffset;
 587                 float slickrotate;
 588                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 589                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 590                 if(i != 0 && i != 180)
 591                 {
 592                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 593                     {
 594                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 595                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 596
 597                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 598                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 599                     }
 600                 }
 601                 else
 602                 {
 603                     slickoffset.x = slickoffset.y = 0;
 604                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 605                     if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 606                 }
 607             }
 608
 609             // if a traceline hit a slick surface
 610             if(slickdetected)
 611             {
 612                 vector slickdetector_size = panel_size;
 613                 slickdetector_size.y = slickdetector_height;
 614                 // top horizontal line
 615                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 616                 // bottom horizontal line
 617                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 618             }
 619         }
 620
 621         draw_beginBoldFont();
 622         // show speed when crossing the start trigger
 623         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 624         {
 625             float text_alpha = 0;
 626             if(race_checkpoint == 254) // checkpoint 254 is the start trigger
 627             {
 628                 if(starttime != race_checkpointtime)
 629                 {
 630                     starttime = race_checkpointtime;
 631                     startspeed = speed;
 632                 }
 633             }
 634             if(startspeed >= 0)
 635             {
 636                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 637                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 638                 {
 639                     startspeed = -1;
 640                 }
 641             }
 642             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 643             {
 644                 vector startspeed_size = panel_size;
 645                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 5);
 646                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 647             }
 648         }
 649         else
 650         {
 651             starttime = 0;
 652             startspeed = -1;
 653         }
 654
 655         // show height achieved by a single jump
 656         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 657         {
 658             float text_alpha = 0;
 659             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min * length_conversion_factor, 0);
 660             float jumpheight_current = strafeplayer.origin.z;
 661             float jumpspeed_current = strafeplayer.velocity.z;
 662             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || IS_ONGROUND(strafeplayer) || swimming || IS_DEAD(strafeplayer))
 663             {
 664                 jumprestart = true;
 665             }
 666             else
 667             {
 668                 if(jumpheight < 0 || jumprestart)
 669                 {
 670                     jumprestart = false;
 671                     jumpheight = 0;
 672                     // this reduces accuracy a little bit but prevents all kind of bugs from carryover values at connect or when dying
 673                     jumpheight_prev = jumpheight_current;
 674                     jumpspeed_prev = jumpspeed_current;
 675                 }
 676                 else
 677                 {
 678                     jumpheight += jumpheight_current - jumpheight_prev;
 679                 }
 680                 if(jumpheight > jumpheight_min && jumpheight > jumpheight_persistent)
 681                 {
 682                     jumptime = time;
 683                     jumpheight_persistent = jumpheight;
 684                 }
 685             }
 686             jumpheight_prev = jumpheight_current;
 687             jumpspeed_prev = jumpspeed_current;
 688             if(jumpheight_persistent > 0)
 689             {
 690                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 691                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 692                 {
 693                     jumpheight_persistent = -1;
 694                 }
 695             }
 696             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 697             {
 698                 vector jumpheight_size = panel_size;
 699                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 5);
 700                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 701             }
 702         }
 703         else
 704         {
 705             jumpheight_prev = jumpspeed_prev = 0;
 706             jumpheight = jumpheight_persistent = -1;
 707         }
 708         draw_endBoldFont();
 709
 710         if(speed < (maxspeed + antiflicker_speed) && !immobile)
 711         {
 712             bestangle_anywhere = true; // moving forward should suffice to gain speed
 713         }
 714
 715         // draw the actual strafe angle
 716         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 717         {
 718             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 719                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 720             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 721         }
 722
 723         if(fabs(angle + wishangle) > 90) // player is overturning
 724         {
 725             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 726         }
 727         else if(bestangle_anywhere) // player gains speed without strafing
 728         {
 729             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 730         }
 731
 732         if(mode == 0 || straight_overturn)
 733         {
 734             currentangle_offset = panel_size.x/2;
 735         }
 736
 737         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 738         {
 739             float moveangle = angle + wishangle;
 740             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 741             float strafe_ratio = 0;
 742             if(fabs(moveangle) > 90)
 743             {
 744                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 745                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 746             }
 747             else
 748             {
 749                 if(moveangle >= strafeangle)
 750                 {
 751                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 752                 }
 753                 else if(moveangle <= -strafeangle)
 754                 {
 755                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 756                 }
 757             }
 758             if(strafe_ratio < 0)
 759             {
 760                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 761             }
 762             else
 763             {
 764                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 765             }
 766         }
 767
 768         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 769         {
 770             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 771         }
 772     }
 773 }
 774
 775 // functions to make hud elements align perfectly in the hud area
 776 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 777 {
 778     float mirror_offset, mirror_width;
 779     vector size = panel_size;
 780     vector mirror_size = panel_size;
 781
 782     float original_width = width;
 783     float hiddencolor_width;
 784
 785     if(alpha <= 0 && type != 2 || width <= 0) return;
 786
 787     if(type == 2 && gradientType == 0) type = 0;
 788
 789     if(offset < 0)
 790     {
 791         mirror_width = min(fabs(offset), width);
 792         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 793         width += offset;
 794         offset = 0;
 795     }
 796     else
 797     {
 798         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 799         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 800     }
 801     if((offset + width) > panel_size.x)
 802     {
 803         width = panel_size.x - offset;
 804     }
 805     if(mirror_offset < 0)
 806     {
 807         mirror_width += mirror_offset;
 808         mirror_offset = 0;
 809     }
 810     if((mirror_offset + mirror_width) > panel_size.x)
 811     {
 812         mirror_width = panel_size.x - mirror_offset;
 813     }
 814
 815     if(width < 0) width = 0;
 816     if(mirror_width < 0) mirror_width = 0;
 817     hiddencolor_width = original_width - width - mirror_width;
 818
 819     if(direction < 0) // swap mirror and non-mirror values if direction points left
 820     {
 821         offset += mirror_offset;
 822         mirror_offset = offset - mirror_offset;
 823         offset -= mirror_offset;
 824
 825         width += mirror_width;
 826         mirror_width = width - mirror_width;
 827         width -= mirror_width;
 828     }
 829
 830     size.x = width;
 831     mirror_size.x = mirror_width;
 832
 833     switch(type)
 834     {
 835         default:
 836         case 0: // no styling (drawfill)
 837             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 838             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 839             break;
 840
 841         case 1: // progress bar style
 842             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 843             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 844             break;
 845
 846         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 847             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, width + (mirror_offset == 0 ? hiddencolor_width : 0), gradientType);
 848             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, (offset == 0 ? hiddencolor_width : 0), gradientType);
 849     }
 850 }
 851
 852 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 853 {
 854     vector mixedColor;
 855     if(ratio <= 0) return color1;
 856     if(ratio >= 1) return color2;
 857     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 858     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 859     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 860     return mixedColor;
 861 }
 862
 863 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 864 {
 865     float color_ratio, alpha1, alpha2;
 866     vector gradient_size = size;
 867     alpha1 = bound(0, alpha, 1);
 868     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 869     if((alpha1+alpha2) == 0) return;
 870     color_ratio = alpha1/(alpha1+alpha2);
 871     for(int i = 0; i < size.x; ++i)
 872     {
 873         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 874         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 875         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 876         if(ratio > 1) ratio = 2 - ratio;
 877         if(gradientType != 2) ratio = 1 - ratio;
 878         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 879         combine_ratio1 = ratio*(1-color_ratio);
 880         combine_ratio2 = (1-ratio)*color_ratio;
 881         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 882         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 883     }
 884 }
 885
 886 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 887 float GetLengthUnitFactor(int length_unit)
 888 {
 889         switch(length_unit)
 890         {
 891                 default:
 892                 case 1: return 1.0;
 893                 case 2: return 0.0254;
 894                 case 3: return 0.0254 * 0.001;
 895                 case 4: return 0.0254 * 0.001 * 0.6213711922;
 896                 case 5: return 0.0254 * 0.001 * 0.5399568035;
 897         }
 898 }
 899
 900 string GetLengthUnit(int length_unit)
 901 {
 902         switch(length_unit)
 903         {
 904                 // translator-friendly strings without the initial space
 905                 default:
 906                 case 1: return strcat(" ", _("qu"));
 907                 case 2: return strcat(" ", _("m"));
 908                 case 3: return strcat(" ", _("km"));
 909                 case 4: return strcat(" ", _("mi"));
 910                 case 5: return strcat(" ", _("nmi"));
 911         }
 912 }