qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/draw.qh>
   6 #include <client/hud/panel/racetimer.qh>
   7 #include <client/resources.qh>
   8 #include <client/view.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 bool fwd = true;
  35 bool state_fwd = true;
  36 bool state_fwd_prev = true;
  37 float state_fwd_time = 0;
  38 float starttime = 0;
  39 float startspeed = -1;
  40 float jumptime = 0;
  41 float jumpheight = -1;
  42 float jumpheight_persistent = -1;
  43 float jumpheight_prev = 0;
  44 float jumpspeed_prev = 0;
  45 bool  jumprestart = true;
  46
  47 // provide basic panel cvars to old clients
  48 // TODO remove them after a future release (0.8.2+)
  49 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  50 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  51 noref string autocvar_hud_panel_strafehud_bg = "0";
  52 noref string autocvar_hud_panel_strafehud_bg_color = "";
  53 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  54 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  55 noref string autocvar_hud_panel_strafehud_bg_border = "";
  56 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  57
  58 void HUD_StrafeHUD()
  59 {
  60     entity strafeplayer;
  61     bool islocal;
  62
  63     // generic hud routines
  64     if(!autocvar__hud_configure)
  65     {
  66         if(!autocvar_hud_panel_strafehud ||
  67            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  68            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  69     }
  70
  71     HUD_Panel_LoadCvars();
  72
  73     if(autocvar_hud_panel_strafehud_dynamichud)
  74     {
  75         HUD_Scale_Enable();
  76     }
  77     else
  78     {
  79         HUD_Scale_Disable();
  80     }
  81
  82     HUD_Panel_DrawBg();
  83
  84     if(panel_bg_padding)
  85     {
  86         panel_pos  += '1 1 0' * panel_bg_padding;
  87         panel_size -= '2 2 0' * panel_bg_padding;
  88     }
  89
  90     // find out whether the local csqcmodel entity is valid
  91     if(spectatee_status > 0 || isdemo())
  92     {
  93         islocal = false;
  94         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  95     }
  96     else
  97     {
  98         islocal = true;
  99         strafeplayer = csqcplayer;
 100     }
 101
 102     // draw strafehud
 103     if(csqcplayer && strafeplayer)
 104     {
 105         // physics
 106         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 107         bool   strafekeys;
 108         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 109         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 110         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 111         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 112         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 113         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 114         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 115         float  vel_angle                     = vectoangles(strafeplayer.velocity).y;
 116         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y + 180;
 117         float  angle;
 118         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 119         int    keys                          = STAT(PRESSED_KEYS);
 120         int    keys_fwd;
 121         float  wishangle                     = 0;
 122
 123         // HUD
 124         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 125         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 126         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 127         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 128         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 129         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 130         float  minspeed;
 131         float  shift_offset                  = 0;
 132         bool   straight_overturn             = false;
 133         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 134         float  hudangle;
 135         float  neutral_offset;
 136         float  neutral_width;
 137         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 138         float  currentangle_offset;
 139         vector currentangle_size             = '0 0 0';
 140         float  bestangle;
 141         float  odd_bestangle;
 142         bool   bestangle_anywhere            = false;
 143         float  bestangle_offset;
 144         float  switch_bestangle_offset;
 145         bool   odd_angles                    = false;
 146         float  odd_bestangle_offset          = 0;
 147         float  switch_odd_bestangle_offset   = 0;
 148         float  bestangle_width;
 149         float  accelzone_left_offset;
 150         float  accelzone_right_offset;
 151         float  accelzone_width;
 152         float  overturn_offset;
 153         float  overturn_width;
 154         float  slickdetector_height;
 155         vector direction_size_vertical       = '0 0 0';
 156         vector direction_size_horizontal     = '0 0 0';
 157         float  range_minangle;
 158
 159         // determine whether the player is pressing forwards or backwards keys
 160         if(islocal) // if entity is local player
 161         {
 162             if(movement.x > 0)
 163             {
 164                 keys_fwd = 1;
 165             }
 166             else if(movement.x < 0)
 167             {
 168                 keys_fwd = -1;
 169             }
 170             else
 171             {
 172                 keys_fwd = 0;
 173             }
 174         }
 175         else // alternatively determine direction by querying pressed keys
 176         {
 177             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 178             {
 179                 keys_fwd = 1;
 180             }
 181             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 182             {
 183                 keys_fwd = -1;
 184             }
 185             else
 186             {
 187                 keys_fwd = 0;
 188             }
 189         }
 190
 191         // determine player wishdir
 192         if(islocal) // if entity is local player
 193         {
 194             if(movement.x == 0)
 195             {
 196                 if(movement.y < 0)
 197                 {
 198                     wishangle = -90;
 199                 }
 200                 else if(movement.y > 0)
 201                 {
 202                     wishangle = 90;
 203                 }
 204                 else
 205                 {
 206                     wishangle = 0;
 207                 }
 208             }
 209             else
 210             {
 211                 if(movement.y == 0)
 212                 {
 213                     wishangle = 0;
 214                 }
 215                 else
 216                 {
 217                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 218                     // wrap the wish angle if it exceeds ±90°
 219                     if(fabs(wishangle) > 90)
 220                     {
 221                         if(wishangle < 0) wishangle += 180;
 222                         else wishangle -= 180;
 223                         wishangle = -wishangle;
 224                     }
 225                 }
 226             }
 227         }
 228         else // alternatively calculate wishdir by querying pressed keys
 229         {
 230             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 231             {
 232                 wishangle = 45;
 233             }
 234             else
 235             {
 236                 wishangle = 90;
 237             }
 238             if(keys & KEY_LEFT)
 239             {
 240                 wishangle *= -1;
 241             }
 242             else if(!(keys & KEY_RIGHT))
 243             {
 244                 wishangle = 0; // wraps at 180°
 245             }
 246         }
 247
 248         strafekeys = fabs(wishangle) == 90;
 249
 250         // determine minimum required angle to display full strafe range
 251         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 252         if(range_minangle > 45) // minimum angle range is 45
 253         {
 254             range_minangle = 45 - fabs(wishangle) % 45;
 255         }
 256         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 257         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 258
 259         if(autocvar_hud_panel_strafehud_range == 0)
 260         {
 261             if(autocvar__hud_configure)
 262             {
 263                 hudangle = 90;
 264             }
 265             else
 266             {
 267                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 268             }
 269         }
 270         else
 271         {
 272             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 273         }
 274
 275         // detect air strafe turning
 276         if(onground != state_onground)
 277         {
 278             state_onground_time = time;
 279         }
 280         state_onground = onground;
 281
 282         if(strafekeys != state_strafekeys)
 283         {
 284             state_strafekeys_time = time;
 285         }
 286         state_strafekeys = strafekeys;
 287
 288         if((keys & KEY_FORWARD) || (keys & KEY_BACKWARD) || swimming || autocvar__hud_configure)
 289         {
 290             turn = false;
 291         }
 292         else if(onground)
 293         {
 294             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 295             {
 296                 turn = false;
 297             }
 298         }
 299         else // air strafe only
 300         {
 301             if(strafekeys)
 302             {
 303                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 304                 {
 305                     turn = true; // CPMA turning
 306                     turnangle = wishangle;
 307                 }
 308             }
 309             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 310             {
 311                 turn = false;
 312             }
 313         }
 314         if(turn)
 315         {
 316             maxspeed = PHYS_MAXAIRSTRAFESPEED(strafeplayer); // no modifiers here because they don't affect air strafing
 317             wishangle = turnangle;
 318         }
 319
 320         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? maxspeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 321
 322         // get current strafing angle ranging from -180° to +180°
 323         if(!autocvar__hud_configure)
 324         {
 325             if(speed > 0)
 326             {
 327                 // calculate view angle relative to the players current velocity direction
 328                 angle = vel_angle - view_angle;
 329
 330                 // if the angle goes above 180° or below -180° wrap it to the opposite side
 331                 if (angle > 180) angle -= 360;
 332                 else if(angle < -180) angle += 360;
 333
 334                 // shift the strafe angle by 180° for hud calculations
 335                 if(angle < 0) angle += 180;
 336                 else angle -= 180;
 337
 338                 // determine whether the player is strafing forwards or backwards
 339                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 340                 if(!strafekeys)
 341                 {
 342                     if(keys_fwd > 0)
 343                     {
 344                         state_fwd = true;
 345                     }
 346                     else if(keys_fwd < 0)
 347                     {
 348                         state_fwd = false;
 349                     }
 350                     else
 351                     {
 352                         state_fwd = fabs(angle) <= 90;
 353                     }
 354                 }
 355                 // otherwise determine by examining the strafe angle
 356                 else
 357                 {
 358                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 359                     {
 360                         state_fwd = angle <= -wishangle;
 361                     }
 362                     else
 363                     {
 364                         state_fwd = angle >= -wishangle;
 365                     }
 366                 }
 367
 368                 if(state_fwd_prev != state_fwd)
 369                 {
 370                     state_fwd_time = time;
 371                 }
 372                 state_fwd_prev = state_fwd;
 373
 374                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < maxspeed || (strafekeys && mode == 0)) // timeout when changing between forwards and backwards movement
 375                 {
 376                     fwd = state_fwd;
 377                 }
 378
 379                 // shift the strafe angle by 180° when strafing backwards
 380                 if(!fwd)
 381                 {
 382                     if(angle < 0) angle += 180;
 383                     else angle -= 180;
 384                 }
 385
 386                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 387                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 388                 {
 389                     straight_overturn = true;
 390                 }
 391             }
 392             else
 393             {
 394                 angle = 0;
 395             }
 396         }
 397         else // simulate turning for HUD setup
 398         {
 399             fwd = true;
 400             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 401             {
 402                 demo_time = time;
 403                 demo_angle += demo_direction;
 404                 if(fabs(demo_angle) >= 55)
 405                 {
 406                     demo_direction = -demo_direction;
 407                 }
 408             }
 409             angle = demo_angle;
 410             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 411         }
 412
 413         // invert the wish angle when strafing backwards
 414         if(!fwd)
 415         {
 416             wishangle = -wishangle;
 417         }
 418
 419         // flip angles if v_flipped is enabled
 420         if(autocvar_v_flipped)
 421         {
 422             angle = -angle;
 423             wishangle = -wishangle;
 424         }
 425
 426         // determine whether the player is strafing left or right
 427         if(wishangle != 0)
 428         {
 429             direction = wishangle > 0 ? 1 : -1;
 430         }
 431         else
 432         {
 433             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 434         }
 435
 436         // best angle to strafe at
 437         bestangle = (speed > maxspeed ? acos(maxspeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 438         odd_bestangle = -bestangle - wishangle;
 439         bestangle -= wishangle;
 440
 441         // various offsets and size calculations of hud indicator elements
 442         // how much is hidden by the current hud angle
 443         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 444         // current angle
 445         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 446         if(mode == 0)
 447         {
 448             currentangle_offset = angle/hudangle * panel_size.x;
 449         }
 450         else
 451         {
 452             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 453         }
 454         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 455         // best strafe acceleration angle
 456         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 457         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 458         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 459
 460         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 461         {
 462             odd_angles = true;
 463             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 464             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 465         }
 466         // direction indicator
 467         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 468         direction_size_vertical.y = panel_size.y;
 469         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 470         direction_size_horizontal.y = direction_size_vertical.x;
 471         // overturn
 472         overturn_width = 180/hudangle * panel_size.x;
 473
 474         // the neutral zone fills the whole strafe bar
 475         if(immobile)
 476         {
 477             // draw neutral zone
 478             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 479             {
 480                 switch(autocvar_hud_panel_strafehud_style)
 481                 {
 482                     default:
 483                     case 0:
 484                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 485                         break;
 486
 487                     case 1:
 488                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 489                 }
 490             }
 491         }
 492         else
 493         {
 494             // calculate various zones of the strafe-o-meter
 495             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 496             accelzone_right_offset = 0;
 497             accelzone_left_offset = overturn_offset + overturn_width;
 498             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 499             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 500
 501             // remove switch indicator width from offset
 502             if(direction < 0)
 503             {
 504                 bestangle_offset -= bestangle_width;
 505                 switch_odd_bestangle_offset -= bestangle_width;
 506             }
 507             else
 508             {
 509                 switch_bestangle_offset -= bestangle_width;
 510                 odd_bestangle_offset -= bestangle_width;
 511             }
 512
 513             // shift hud if operating in view angle centered mode
 514             if(mode == 0)
 515             {
 516                 shift_offset = -currentangle_offset;
 517                 bestangle_offset += shift_offset;
 518                 switch_bestangle_offset += shift_offset;
 519                 odd_bestangle_offset += shift_offset;
 520                 switch_odd_bestangle_offset += shift_offset;
 521             }
 522             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 523             // calculate how far off-center the strafe zones currently are
 524             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 525             // shift strafe zones into correct place
 526             neutral_offset += shift_offset;
 527             accelzone_left_offset += shift_offset;
 528             accelzone_right_offset += shift_offset;
 529             overturn_offset += shift_offset;
 530
 531             // draw left acceleration zone
 532             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 533
 534             // draw right acceleration zone
 535             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 536
 537             // draw overturn zone
 538             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 539
 540             // draw neutral zone
 541             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 542
 543             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 544             {
 545                 bool indicator_direction = direction < 0;
 546                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 547                 // if both conditions are true then it's inverted twice hence not inverted at all
 548                 if(!fwd != odd_angles)
 549                 {
 550                     indicator_direction = !indicator_direction;
 551                 }
 552                 // draw the direction indicator caps at the sides of the hud
 553                 // vertical line
 554                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 555                 // top horizontal line
 556                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 557                 // bottom horizontal line
 558                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 559             }
 560
 561             if(speed >= minspeed) // only draw indicators if minspeed is reached
 562             {
 563                 // draw best angles for acceleration
 564                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 565                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 566                 // both indicators are inactive if no direction can be determined
 567                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 568                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 569                 // draw the switch indicators
 570                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 571                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 572             }
 573         }
 574
 575         // experimental: slick detector
 576         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 577         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 578         {
 579             float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 580             bool slickdetected = false;
 581
 582             slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 583
 584             // traceline into every direction
 585             trace_dphitq3surfaceflags = 0;
 586             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 587             {
 588                 vector slickoffset;
 589                 float slickrotate;
 590                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 591                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 592                 if(i != 0 && i != 180)
 593                 {
 594                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 595                     {
 596                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 597                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 598
 599                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 600                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 601                     }
 602                 }
 603                 else
 604                 {
 605                     slickoffset.x = slickoffset.y = 0;
 606                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 607                     if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 608                 }
 609             }
 610
 611             // if a traceline hit a slick surface
 612             if(slickdetected)
 613             {
 614                 vector slickdetector_size = panel_size;
 615                 slickdetector_size.y = slickdetector_height;
 616                 // top horizontal line
 617                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 618                 // bottom horizontal line
 619                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 620             }
 621         }
 622
 623         draw_beginBoldFont();
 624         // show speed when crossing the start trigger
 625         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 626         {
 627             float text_alpha = 0;
 628             if(race_checkpoint == 254) // checkpoint 254 is the start trigger
 629             {
 630                 if(starttime != race_checkpointtime)
 631                 {
 632                     starttime = race_checkpointtime;
 633                     startspeed = speed;
 634                 }
 635             }
 636             if(startspeed >= 0)
 637             {
 638                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 639                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 640                 {
 641                     startspeed = -1;
 642                 }
 643             }
 644             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 645             {
 646                 vector startspeed_size = panel_size;
 647                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 5);
 648                 string speed_unit = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 649                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 650             }
 651         }
 652         else
 653         {
 654             starttime = 0;
 655             startspeed = -1;
 656         }
 657
 658         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 659         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 660         {
 661             float text_alpha = 0;
 662             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 663             float jumpheight_current = strafeplayer.origin.z;
 664             float jumpspeed_current = strafeplayer.velocity.z;
 665             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || IS_ONGROUND(strafeplayer) || swimming || IS_DEAD(strafeplayer) || spectating)
 666             {
 667                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 668                 jumprestart = true;
 669             }
 670             else
 671             {
 672                 if(jumpheight < 0 || jumprestart)
 673                 {
 674                     jumprestart = false;
 675                     jumpheight = 0;
 676                 }
 677                 else
 678                 {
 679                     jumpheight += jumpheight_current - jumpheight_prev;
 680                 }
 681                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 682                 {
 683                     jumptime = time;
 684                     jumpheight_persistent = jumpheight;
 685                 }
 686             }
 687             jumpheight_prev = jumpheight_current;
 688             jumpspeed_prev = jumpspeed_current;
 689             if(jumpheight_persistent > 0)
 690             {
 691                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 692                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 693                 {
 694                     jumpheight_persistent = -1;
 695                 }
 696             }
 697             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 698             {
 699                 vector jumpheight_size = panel_size;
 700                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 5);
 701                 string length_unit = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 702                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 703             }
 704         }
 705         else
 706         {
 707             jumpheight_prev = jumpspeed_prev = 0;
 708             jumpheight = jumpheight_persistent = -1;
 709         }
 710         draw_endBoldFont();
 711
 712         if(speed < (maxspeed + antiflicker_speed) && !immobile)
 713         {
 714             bestangle_anywhere = true; // moving forward should suffice to gain speed
 715         }
 716
 717         // draw the actual strafe angle
 718         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 719         {
 720             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 721                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 722             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 723         }
 724
 725         if(fabs(angle + wishangle) > 90) // player is overturning
 726         {
 727             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 728         }
 729         else if(bestangle_anywhere) // player gains speed without strafing
 730         {
 731             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 732         }
 733
 734         if(mode == 0 || straight_overturn)
 735         {
 736             currentangle_offset = panel_size.x/2;
 737         }
 738
 739         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 740         {
 741             float moveangle = angle + wishangle;
 742             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 743             float strafe_ratio = 0;
 744             if(fabs(moveangle) > 90)
 745             {
 746                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 747                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 748             }
 749             else
 750             {
 751                 if(moveangle >= strafeangle)
 752                 {
 753                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 754                 }
 755                 else if(moveangle <= -strafeangle)
 756                 {
 757                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 758                 }
 759             }
 760             if(strafe_ratio < 0)
 761             {
 762                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 763             }
 764             else
 765             {
 766                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 767             }
 768         }
 769
 770         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 771         {
 772             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 773         }
 774     }
 775 }
 776
 777 // functions to make hud elements align perfectly in the hud area
 778 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 779 {
 780     float mirror_offset, mirror_width;
 781     vector size = panel_size;
 782     vector mirror_size = panel_size;
 783
 784     float original_width = width;
 785     float hiddencolor_width;
 786
 787     if(alpha <= 0 && type != 2 || width <= 0) return;
 788
 789     if(type == 2 && gradientType == 0) type = 0;
 790
 791     if(offset < 0)
 792     {
 793         mirror_width = min(fabs(offset), width);
 794         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 795         width += offset;
 796         offset = 0;
 797     }
 798     else
 799     {
 800         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 801         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 802     }
 803     if((offset + width) > panel_size.x)
 804     {
 805         width = panel_size.x - offset;
 806     }
 807     if(mirror_offset < 0)
 808     {
 809         mirror_width += mirror_offset;
 810         mirror_offset = 0;
 811     }
 812     if((mirror_offset + mirror_width) > panel_size.x)
 813     {
 814         mirror_width = panel_size.x - mirror_offset;
 815     }
 816
 817     if(width < 0) width = 0;
 818     if(mirror_width < 0) mirror_width = 0;
 819     hiddencolor_width = original_width - width - mirror_width;
 820
 821     if(direction < 0) // swap mirror and non-mirror values if direction points left
 822     {
 823         offset += mirror_offset;
 824         mirror_offset = offset - mirror_offset;
 825         offset -= mirror_offset;
 826
 827         width += mirror_width;
 828         mirror_width = width - mirror_width;
 829         width -= mirror_width;
 830     }
 831
 832     size.x = width;
 833     mirror_size.x = mirror_width;
 834
 835     switch(type)
 836     {
 837         default:
 838         case 0: // no styling (drawfill)
 839             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 840             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 841             break;
 842
 843         case 1: // progress bar style
 844             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 845             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 846             break;
 847
 848         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 849             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, width + (mirror_offset == 0 ? hiddencolor_width : 0), gradientType);
 850             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, (offset == 0 ? hiddencolor_width : 0), gradientType);
 851     }
 852 }
 853
 854 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 855 {
 856     vector mixedColor;
 857     if(ratio <= 0) return color1;
 858     if(ratio >= 1) return color2;
 859     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 860     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 861     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 862     return mixedColor;
 863 }
 864
 865 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 866 {
 867     float color_ratio, alpha1, alpha2;
 868     vector gradient_size = size;
 869     alpha1 = bound(0, alpha, 1);
 870     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 871     if((alpha1+alpha2) == 0) return;
 872     color_ratio = alpha1/(alpha1+alpha2);
 873     for(int i = 0; i < size.x; ++i)
 874     {
 875         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 876         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 877         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 878         if(ratio > 1) ratio = 2 - ratio;
 879         if(gradientType != 2) ratio = 1 - ratio;
 880         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 881         combine_ratio1 = ratio*(1-color_ratio);
 882         combine_ratio2 = (1-ratio)*color_ratio;
 883         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 884         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 885     }
 886 }
 887
 888 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 889 float GetLengthUnitFactor(int length_unit)
 890 {
 891         switch(length_unit)
 892         {
 893                 default:
 894                 case 1: return 1.0;
 895                 case 2: return 0.0254;
 896                 case 3: return 0.0254 * 0.001;
 897                 case 4: return 0.0254 * 0.001 * 0.6213711922;
 898                 case 5: return 0.0254 * 0.001 * 0.5399568035;
 899         }
 900 }
 901
 902 string GetLengthUnit(int length_unit)
 903 {
 904         switch(length_unit)
 905         {
 906                 // translator-friendly strings without the initial space
 907                 default:
 908                 case 1: return strcat(" ", _("qu"));
 909                 case 2: return strcat(" ", _("m"));
 910                 case 3: return strcat(" ", _("km"));
 911                 case 4: return strcat(" ", _("mi"));
 912                 case 5: return strcat(" ", _("nmi"));
 913         }
 914 }