qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/draw.qh>
   6 #include <client/hud/panel/racetimer.qh>
   7 #include <client/resources.qh>
   8 #include <client/view.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 float turnspeed;
  35 bool fwd = true;
  36 bool state_fwd = true;
  37 bool state_fwd_prev = true;
  38 float state_fwd_time = 0;
  39 float starttime = 0;
  40 float startspeed = -1;
  41 float jumptime = 0;
  42 float jumpheight = -1;
  43 float jumpheight_persistent = -1;
  44 float jumpheight_prev = 0;
  45 float jumpspeed_prev = 0;
  46 bool  jumprestart = true;
  47
  48 // provide basic panel cvars to old clients
  49 // TODO remove them after a future release (0.8.2+)
  50 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  51 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  52 noref string autocvar_hud_panel_strafehud_bg = "0";
  53 noref string autocvar_hud_panel_strafehud_bg_color = "";
  54 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  55 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  56 noref string autocvar_hud_panel_strafehud_bg_border = "";
  57 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  58
  59 void HUD_StrafeHUD()
  60 {
  61     entity strafeplayer;
  62     bool islocal;
  63
  64     // generic hud routines
  65     if(!autocvar__hud_configure)
  66     {
  67         if(!autocvar_hud_panel_strafehud ||
  68            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  69            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  70     }
  71
  72     HUD_Panel_LoadCvars();
  73
  74     if(autocvar_hud_panel_strafehud_dynamichud)
  75     {
  76         HUD_Scale_Enable();
  77     }
  78     else
  79     {
  80         HUD_Scale_Disable();
  81     }
  82
  83     HUD_Panel_DrawBg();
  84
  85     if(panel_bg_padding)
  86     {
  87         panel_pos  += '1 1 0' * panel_bg_padding;
  88         panel_size -= '2 2 0' * panel_bg_padding;
  89     }
  90
  91     // find out whether the local csqcmodel entity is valid
  92     if(spectatee_status > 0 || isdemo())
  93     {
  94         islocal = false;
  95         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  96     }
  97     else
  98     {
  99         islocal = true;
 100         strafeplayer = csqcplayer;
 101     }
 102
 103     // draw strafehud
 104     if(csqcplayer && strafeplayer)
 105     {
 106         // physics
 107         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 108         bool   strafekeys;
 109         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 110         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 111         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 112         float  maxspeed_crouch_mod           = IS_DUCKED(strafeplayer) && !swimming ? .5 : 1;
 113         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 114         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 115         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 116         float  movespeed;
 117         float  vel_angle                     = vectoangles(strafeplayer.velocity).y - (vectoangles(strafeplayer.velocity).y > 180 ? 360 : 0); // change the range from 0° - 360° to -180° - 180° to match how view_angle represents angles
 118         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y;
 119         float  angle;
 120         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 121         int    keys                          = STAT(PRESSED_KEYS);
 122         int    keys_fwd;
 123         float  wishangle                     = 0;
 124
 125         // HUD
 126         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 127         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 128         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 129         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 130         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 131         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 132         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 133         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 134         float  minspeed;
 135         float  shift_offset                  = 0;
 136         bool   straight_overturn             = false;
 137         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 138         float  hudangle;
 139         float  neutral_offset;
 140         float  neutral_width;
 141         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 142         float  currentangle_offset;
 143         vector currentangle_size             = '0 0 0';
 144         float  bestangle;
 145         float  odd_bestangle;
 146         bool   bestangle_anywhere            = false;
 147         float  bestangle_offset;
 148         float  switch_bestangle_offset;
 149         bool   odd_angles                    = false;
 150         float  odd_bestangle_offset          = 0;
 151         float  switch_odd_bestangle_offset   = 0;
 152         float  bestangle_width;
 153         float  accelzone_left_offset;
 154         float  accelzone_right_offset;
 155         float  accelzone_width;
 156         float  overturn_offset;
 157         float  overturn_width;
 158         float  slickdetector_height;
 159         vector direction_size_vertical       = '0 0 0';
 160         vector direction_size_horizontal     = '0 0 0';
 161         float  range_minangle;
 162
 163         // determine whether the player is pressing forwards or backwards keys
 164         if(islocal) // if entity is local player
 165         {
 166             if(movement.x > 0)
 167             {
 168                 keys_fwd = 1;
 169             }
 170             else if(movement.x < 0)
 171             {
 172                 keys_fwd = -1;
 173             }
 174             else
 175             {
 176                 keys_fwd = 0;
 177             }
 178         }
 179         else // alternatively determine direction by querying pressed keys
 180         {
 181             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 182             {
 183                 keys_fwd = 1;
 184             }
 185             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 186             {
 187                 keys_fwd = -1;
 188             }
 189             else
 190             {
 191                 keys_fwd = 0;
 192             }
 193         }
 194
 195         // determine player wishdir
 196         if(islocal) // if entity is local player
 197         {
 198             if(movement.x == 0)
 199             {
 200                 if(movement.y < 0)
 201                 {
 202                     wishangle = -90;
 203                 }
 204                 else if(movement.y > 0)
 205                 {
 206                     wishangle = 90;
 207                 }
 208                 else
 209                 {
 210                     wishangle = 0;
 211                 }
 212             }
 213             else
 214             {
 215                 if(movement.y == 0)
 216                 {
 217                     wishangle = 0;
 218                 }
 219                 else
 220                 {
 221                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 222                     // wrap the wish angle if it exceeds ±90°
 223                     if(fabs(wishangle) > 90)
 224                     {
 225                         if(wishangle < 0) wishangle += 180;
 226                         else wishangle -= 180;
 227                         wishangle = -wishangle;
 228                     }
 229                 }
 230             }
 231         }
 232         else // alternatively calculate wishdir by querying pressed keys
 233         {
 234             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 235             {
 236                 wishangle = 45;
 237             }
 238             else
 239             {
 240                 wishangle = 90;
 241             }
 242             if(keys & KEY_LEFT)
 243             {
 244                 wishangle *= -1;
 245             }
 246             else if(!(keys & KEY_RIGHT))
 247             {
 248                 wishangle = 0; // wraps at 180°
 249             }
 250         }
 251
 252         strafekeys = fabs(wishangle) > 45;
 253
 254         // determine minimum required angle to display full strafe range
 255         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 256         if(range_minangle > 45) // minimum angle range is 45
 257         {
 258             range_minangle = 45 - fabs(wishangle) % 45;
 259         }
 260         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 261         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 262
 263         if(autocvar_hud_panel_strafehud_range == 0)
 264         {
 265             if(autocvar__hud_configure)
 266             {
 267                 hudangle = 90;
 268             }
 269             else
 270             {
 271                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 272             }
 273         }
 274         else
 275         {
 276             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 277         }
 278
 279         // detect air strafe turning
 280         if(onground != state_onground)
 281         {
 282             state_onground_time = time;
 283         }
 284         state_onground = onground;
 285
 286         if(strafekeys != state_strafekeys)
 287         {
 288             state_strafekeys_time = time;
 289         }
 290         state_strafekeys = strafekeys;
 291
 292         if((!strafekeys && vlen(vec2(movement)) > 0) || swimming || autocvar__hud_configure)
 293         {
 294             turn = false;
 295         }
 296         else if(onground)
 297         {
 298             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 299             {
 300                 turn = false;
 301             }
 302         }
 303         else // air strafe only
 304         {
 305             if(strafekeys)
 306             {
 307                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 308                 {
 309                     turn = true; // CPMA turning
 310                     turnangle = wishangle;
 311
 312                     // calculate the maximum air strafe speed
 313                     if(PHYS_MAXAIRSPEED(strafeplayer) == 0){
 314                         maxspeed = 0;
 315                     }
 316                     else if(PHYS_MAXAIRSTRAFESPEED(strafeplayer) == 0 || PHYS_MAXAIRSPEED(strafeplayer) <= PHYS_MAXAIRSTRAFESPEED(strafeplayer)){
 317                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer);
 318                     }
 319                     else{
 320                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer) * pow(fabs(PHYS_MAXAIRSTRAFESPEED(strafeplayer) / PHYS_MAXAIRSPEED(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 321                     }
 322
 323                     turnspeed = vlen(vec2(movement));
 324                     if(turnspeed == 0) turnspeed = maxspeed;
 325                     else turnspeed = min(turnspeed, maxspeed);
 326                 }
 327             }
 328             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 329             {
 330                 turn = false;
 331             }
 332         }
 333         if(turn && (onground || !strafekeys)) // retain last state until strafe turning times out
 334         {
 335             wishangle = turnangle;
 336             movespeed = turnspeed;
 337         }
 338         else{
 339             movespeed = vlen(vec2(movement));
 340             if(movespeed == 0) movespeed = maxspeed;
 341             else movespeed = min(movespeed, maxspeed);
 342         }
 343
 344         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? movespeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 345
 346         // get current strafing angle ranging from -180° to +180°
 347         if(!autocvar__hud_configure)
 348         {
 349             if(speed > 0)
 350             {
 351                 // calculate view angle relative to the players current velocity direction
 352                 angle = vel_angle - view_angle;
 353
 354                 // if the angle goes above 180° or below -180° wrap it to the opposite side since we want the interior angle
 355                 if (angle > 180) angle -= 360;
 356                 else if(angle < -180) angle += 360;
 357
 358                 // determine whether the player is strafing forwards or backwards
 359                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 360                 if(fabs(wishangle) != 90)
 361                 {
 362                     if(keys_fwd > 0)
 363                     {
 364                         state_fwd = true;
 365                     }
 366                     else if(keys_fwd < 0)
 367                     {
 368                         state_fwd = false;
 369                     }
 370                     else
 371                     {
 372                         state_fwd = fabs(angle) <= 90;
 373                     }
 374                 }
 375                 // otherwise determine by examining the strafe angle
 376                 else
 377                 {
 378                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 379                     {
 380                         state_fwd = angle <= -wishangle;
 381                     }
 382                     else
 383                     {
 384                         state_fwd = angle >= -wishangle;
 385                     }
 386                 }
 387
 388                 if(state_fwd_prev != state_fwd)
 389                 {
 390                     state_fwd_time = time;
 391                 }
 392                 state_fwd_prev = state_fwd;
 393
 394                 if((time - state_fwd_time) >= autocvar_hud_panel_strafehud_timeout_direction || speed < movespeed || ((fabs(wishangle) == 90) && mode == 0)) // timeout when changing between forwards and backwards movement
 395                 {
 396                     fwd = state_fwd;
 397                 }
 398
 399                 // shift the strafe angle by 180° when strafing backwards
 400                 if(!fwd)
 401                 {
 402                     if(angle < 0) angle += 180;
 403                     else angle -= 180;
 404                 }
 405
 406                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 407                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 408                 {
 409                     straight_overturn = true;
 410                 }
 411             }
 412             else
 413             {
 414                 angle = 0;
 415             }
 416         }
 417         else // simulate turning for HUD setup
 418         {
 419             fwd = true;
 420             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 421             {
 422                 demo_time = time;
 423                 demo_angle += demo_direction;
 424                 if(fabs(demo_angle) >= 55)
 425                 {
 426                     demo_direction = -demo_direction;
 427                 }
 428             }
 429             angle = demo_angle;
 430             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 431         }
 432
 433         // invert the wish angle when strafing backwards
 434         if(!fwd)
 435         {
 436             wishangle = -wishangle;
 437         }
 438
 439         // flip angles if v_flipped is enabled
 440         if(autocvar_v_flipped)
 441         {
 442             angle = -angle;
 443             wishangle = -wishangle;
 444         }
 445
 446         // determine whether the player is strafing left or right
 447         if(wishangle != 0)
 448         {
 449             direction = wishangle > 0 ? 1 : -1;
 450         }
 451         else
 452         {
 453             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 454         }
 455
 456         // best angle to strafe at
 457         bestangle = (speed > movespeed ? acos(movespeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 458         odd_bestangle = -bestangle - wishangle;
 459         bestangle -= wishangle;
 460
 461         // various offsets and size calculations of hud indicator elements
 462         // how much is hidden by the current hud angle
 463         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 464         // current angle
 465         currentangle_size.x = max(panel_size.x * autocvar_hud_panel_strafehud_angle_width, 1);
 466         if(mode == 0)
 467         {
 468             currentangle_offset = angle/hudangle * panel_size.x;
 469         }
 470         else
 471         {
 472             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 473         }
 474         currentangle_size.y = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_height, 2), 1);
 475         // best strafe acceleration angle
 476         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 477         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 478         bestangle_width = max(panel_size.x * autocvar_hud_panel_strafehud_switch_width, 1);
 479
 480         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 481         {
 482             odd_angles = true;
 483             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 484             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 485         }
 486         // direction indicator
 487         direction_size_vertical.x = max(panel_size.y * min(autocvar_hud_panel_strafehud_direction_width, .5), 1);
 488         direction_size_vertical.y = panel_size.y;
 489         direction_size_horizontal.x = max(panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5), direction_size_vertical.x);
 490         direction_size_horizontal.y = direction_size_vertical.x;
 491         // overturn
 492         overturn_width = 180/hudangle * panel_size.x;
 493
 494         // the neutral zone fills the whole strafe bar
 495         if(immobile)
 496         {
 497             // draw neutral zone
 498             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 499             {
 500                 switch(autocvar_hud_panel_strafehud_style)
 501                 {
 502                     default:
 503                     case 0:
 504                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 505                         break;
 506
 507                     case 1:
 508                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 509                 }
 510             }
 511         }
 512         else
 513         {
 514             // calculate various zones of the strafe-o-meter
 515             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 516             accelzone_right_offset = 0;
 517             accelzone_left_offset = overturn_offset + overturn_width;
 518             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 519             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 520
 521             // remove switch indicator width from offset
 522             if(direction < 0)
 523             {
 524                 bestangle_offset -= bestangle_width;
 525                 switch_odd_bestangle_offset -= bestangle_width;
 526             }
 527             else
 528             {
 529                 switch_bestangle_offset -= bestangle_width;
 530                 odd_bestangle_offset -= bestangle_width;
 531             }
 532
 533             // shift hud if operating in view angle centered mode
 534             if(mode == 0)
 535             {
 536                 shift_offset = -currentangle_offset;
 537                 bestangle_offset += shift_offset;
 538                 switch_bestangle_offset += shift_offset;
 539                 odd_bestangle_offset += shift_offset;
 540                 switch_odd_bestangle_offset += shift_offset;
 541             }
 542             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 543             // calculate how far off-center the strafe zones currently are
 544             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 545             // shift strafe zones into correct place
 546             neutral_offset += shift_offset;
 547             accelzone_left_offset += shift_offset;
 548             accelzone_right_offset += shift_offset;
 549             overturn_offset += shift_offset;
 550
 551             // draw left acceleration zone
 552             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 553
 554             // draw right acceleration zone
 555             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 556
 557             // draw overturn zone
 558             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 559
 560             // draw neutral zone
 561             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 562
 563             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 564             {
 565                 bool indicator_direction = direction < 0;
 566                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 567                 // if both conditions are true then it's inverted twice hence not inverted at all
 568                 if(!fwd != odd_angles)
 569                 {
 570                     indicator_direction = !indicator_direction;
 571                 }
 572                 // draw the direction indicator caps at the sides of the hud
 573                 // vertical line
 574                 if(direction_size_vertical.y > 0) drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 575                 // top horizontal line
 576                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 577                 // bottom horizontal line
 578                 drawfill(panel_pos + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x - direction_size_horizontal.x + direction_size_vertical.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 579             }
 580
 581             if(speed >= minspeed) // only draw indicators if minspeed is reached
 582             {
 583                 // draw best angles for acceleration
 584                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 585                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 586                 // both indicators are inactive if no direction can be determined
 587                 vector switch_color = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_color : autocvar_hud_panel_strafehud_switch_inactive_color;
 588                 float switch_alpha = direction != 0 ? autocvar_hud_panel_strafehud_switch_active_alpha : autocvar_hud_panel_strafehud_switch_inactive_alpha;
 589                 // draw the switch indicators
 590                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_inactive_color, autocvar_hud_panel_strafehud_switch_inactive_alpha * panel_fg_alpha, 0, 0);
 591                 HUD_Panel_DrawStrafeHUD(offset, bestangle_width, switch_color, switch_alpha * panel_fg_alpha, 0, 0);
 592             }
 593         }
 594
 595         // experimental: slick detector
 596         slickdetector_height = panel_size.y * bound(0, autocvar_hud_panel_strafehud_slickdetector_height, 0.5);
 597         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 598         {
 599             bool slickdetected = false;
 600             if(PHYS_FRICTION(strafeplayer) != 0)
 601             {
 602                 float slicksteps = 90 / pow(2, bound(0, autocvar_hud_panel_strafehud_slickdetector_granularity, 4));
 603
 604                 slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 605
 606                 // traceline into every direction
 607                 trace_dphitq3surfaceflags = 0;
 608                 for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 609                 {
 610                     vector slickoffset;
 611                     float slickrotate;
 612                     slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 613                     slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 614                     if(i != 0 && i != 180)
 615                     {
 616                         for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 617                         {
 618                             slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 619                             slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 620
 621                             traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 622                             if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 623                         }
 624                     }
 625                     else
 626                     {
 627                         slickoffset.x = slickoffset.y = 0;
 628                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 629                         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 630                     }
 631                 }
 632             }
 633             else
 634             {
 635                 slickdetected = true;
 636             }
 637
 638             // if a traceline hit a slick surface
 639             if(slickdetected)
 640             {
 641                 vector slickdetector_size = panel_size;
 642                 slickdetector_size.y = slickdetector_height;
 643                 // top horizontal line
 644                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 645                 // bottom horizontal line
 646                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 647             }
 648         }
 649
 650         draw_beginBoldFont();
 651         // show speed when crossing the start trigger
 652         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 653         {
 654             float text_alpha = 0;
 655             if((race_nextcheckpoint == 1) || (race_checkpoint == 254 && race_nextcheckpoint == 255)) // check if the start trigger was hit (will also trigger if the finish trigger was hit if those have the same ID)
 656             {
 657                 if(starttime != race_checkpointtime)
 658                 {
 659                     starttime = race_checkpointtime;
 660                     startspeed = speed;
 661                 }
 662             }
 663             if(startspeed >= 0)
 664             {
 665                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 666                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 667                 {
 668                     startspeed = -1;
 669                 }
 670             }
 671             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 672             {
 673                 vector startspeed_size = panel_size;
 674                 startspeed_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_startspeed_size, 5);
 675                 drawstring_aspect(panel_pos + eY * panel_size.y, strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 676             }
 677         }
 678         else
 679         {
 680             starttime = 0;
 681             startspeed = -1;
 682         }
 683
 684         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 685         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 686         {
 687             float text_alpha = 0;
 688             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 689             float jumpheight_current = strafeplayer.origin.z;
 690             float jumpspeed_current = strafeplayer.velocity.z;
 691             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || IS_ONGROUND(strafeplayer) || swimming || IS_DEAD(strafeplayer) || spectating)
 692             {
 693                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 694                 jumprestart = true;
 695             }
 696             else
 697             {
 698                 if(jumpheight < 0 || jumprestart)
 699                 {
 700                     jumprestart = false;
 701                     jumpheight = 0;
 702                 }
 703                 else
 704                 {
 705                     jumpheight += jumpheight_current - jumpheight_prev;
 706                 }
 707                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 708                 {
 709                     jumptime = time;
 710                     jumpheight_persistent = jumpheight;
 711                 }
 712             }
 713             jumpheight_prev = jumpheight_current;
 714             jumpspeed_prev = jumpspeed_current;
 715             if(jumpheight_persistent > 0)
 716             {
 717                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 718                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 719                 {
 720                     jumpheight_persistent = -1;
 721                 }
 722             }
 723             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 724             {
 725                 vector jumpheight_size = panel_size;
 726                 jumpheight_size.y = panel_size.y * min(autocvar_hud_panel_strafehud_jumpheight_size, 5);
 727                 drawstring_aspect(panel_pos - eY * jumpheight_size.y, strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 728             }
 729         }
 730         else
 731         {
 732             jumpheight_prev = jumpspeed_prev = 0;
 733             jumpheight = jumpheight_persistent = -1;
 734         }
 735         draw_endBoldFont();
 736
 737         if(speed < (movespeed + antiflicker_speed) && !immobile)
 738         {
 739             bestangle_anywhere = true; // moving forward should suffice to gain speed
 740         }
 741
 742         // draw the actual strafe angle
 743         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 744         {
 745             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 746                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 747             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 748         }
 749
 750         if(fabs(angle + wishangle) > 90) // player is overturning
 751         {
 752             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 753         }
 754         else if(bestangle_anywhere) // player gains speed without strafing
 755         {
 756             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 757         }
 758
 759         if(mode == 0 || straight_overturn)
 760         {
 761             currentangle_offset = panel_size.x/2;
 762         }
 763
 764         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 765         {
 766             float moveangle = angle + wishangle;
 767             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 768             float strafe_ratio = 0;
 769             if(fabs(moveangle) > 90)
 770             {
 771                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 772                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 773             }
 774             else
 775             {
 776                 if(moveangle >= strafeangle)
 777                 {
 778                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 779                 }
 780                 else if(moveangle <= -strafeangle)
 781                 {
 782                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 783                 }
 784             }
 785             if(strafe_ratio < 0)
 786             {
 787                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 788             }
 789             else
 790             {
 791                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 792             }
 793         }
 794
 795         if(currentangle_size.x > 0 && currentangle_size.y > 0 && autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 796         {
 797             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 798         }
 799     }
 800 }
 801
 802 // functions to make hud elements align perfectly in the hud area
 803 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 804 {
 805     float mirror_offset, mirror_width;
 806     vector size = panel_size;
 807     vector mirror_size = panel_size;
 808     int gradient_start;
 809     float gradient_offset, gradient_mirror_offset;
 810     float overflow_width = 0, overflow_mirror_width = 0;
 811
 812     float original_width = width;
 813
 814     if(alpha <= 0 && type != 2 || width <= 0) return;
 815
 816     if(type == 2 && gradientType == 0) type = 0;
 817
 818     if(offset < 0)
 819     {
 820         mirror_width = min(fabs(offset), width);
 821         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 822         width += offset;
 823         offset = 0;
 824     }
 825     else
 826     {
 827         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 828         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 829     }
 830
 831     if(width < 0) width = 0;
 832     if((offset + width) > panel_size.x)
 833     {
 834         overflow_width = (offset + width) - panel_size.x;
 835         width = panel_size.x - offset;
 836     }
 837     if(mirror_offset < 0)
 838     {
 839         mirror_width += mirror_offset;
 840         mirror_offset = 0;
 841     }
 842
 843     if(mirror_width < 0) mirror_width = 0;
 844     if((mirror_offset + mirror_width) > panel_size.x)
 845     {
 846         overflow_mirror_width = (mirror_offset + mirror_width) - panel_size.x;
 847         mirror_width = panel_size.x - mirror_offset;
 848     }
 849
 850     if(direction < 0) // swap mirror and non-mirror values if direction points left
 851     {
 852         offset += mirror_offset;
 853         mirror_offset = offset - mirror_offset;
 854         offset -= mirror_offset;
 855
 856         width += mirror_width;
 857         mirror_width = width - mirror_width;
 858         width -= mirror_width;
 859
 860         overflow_width += overflow_mirror_width;
 861         overflow_mirror_width = overflow_width - overflow_mirror_width;
 862         overflow_width -= overflow_mirror_width;
 863     }
 864
 865     size.x = width;
 866     mirror_size.x = mirror_width;
 867
 868     switch(type)
 869     {
 870         default:
 871         case 0: // no styling (drawfill)
 872             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 873             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 874             break;
 875
 876         case 1: // progress bar style
 877             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 878             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 879             break;
 880
 881         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 882             // determine whether the gradient starts in the mirrored or the non-mirrored area
 883             if(offset == 0 && mirror_offset == 0) gradient_start = width > mirror_width ? 2 : 1;
 884             else if(offset == 0) gradient_start = 2;
 885             else if(mirror_offset == 0) gradient_start = 1;
 886             else gradient_start = 0;
 887
 888             switch(gradient_start){
 889                 default:
 890                 case 0: // no offset required
 891                     gradient_offset = gradient_mirror_offset = 0;
 892                     break;
 893                 case 1: // offset starts in non-mirrored area, mirrored area requires offset
 894                     gradient_offset = 0;
 895                     gradient_mirror_offset = original_width - (mirror_width + overflow_mirror_width);
 896                     break;
 897                 case 2: // offset starts in mirrored area, non-mirrored area requires offset
 898                     gradient_offset = original_width - (width + overflow_width);
 899                     gradient_mirror_offset = 0;
 900             }
 901
 902             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, gradient_mirror_offset, gradientType);
 903             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, gradient_offset, gradientType);
 904     }
 905 }
 906
 907 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 908 {
 909     vector mixedColor;
 910     if(ratio <= 0) return color1;
 911     if(ratio >= 1) return color2;
 912     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 913     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 914     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 915     return mixedColor;
 916 }
 917
 918 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 919 {
 920     float color_ratio, alpha1, alpha2;
 921     vector gradient_size = size;
 922     alpha1 = bound(0, alpha, 1);
 923     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 924     if((alpha1+alpha2) == 0) return;
 925     color_ratio = alpha1/(alpha1+alpha2);
 926     for(int i = 0; i < size.x; ++i)
 927     {
 928         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 929         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 930         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 931         if(ratio > 1) ratio = 2 - ratio;
 932         if(gradientType != 2) ratio = 1 - ratio;
 933         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 934         combine_ratio1 = ratio*(1-color_ratio);
 935         combine_ratio2 = (1-ratio)*color_ratio;
 936         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 937         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 938     }
 939 }
 940
 941 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
 942 float GetLengthUnitFactor(int length_unit)
 943 {
 944         switch(length_unit)
 945         {
 946                 default:
 947                 case 1: return 1.0;
 948                 case 2: return 0.0254;
 949                 case 3: return 0.0254 * 0.001;
 950                 case 4: return 0.0254 * 0.001 * 0.6213711922;
 951                 case 5: return 0.0254 * 0.001 * 0.5399568035;
 952         }
 953 }
 954
 955 string GetLengthUnit(int length_unit)
 956 {
 957         switch(length_unit)
 958         {
 959                 // translator-friendly strings without the initial space
 960                 default:
 961                 case 1: return strcat(" ", _("qu"));
 962                 case 2: return strcat(" ", _("m"));
 963                 case 3: return strcat(" ", _("km"));
 964                 case 4: return strcat(" ", _("mi"));
 965                 case 5: return strcat(" ", _("nmi"));
 966         }
 967 }