qcsrc/client/hud/panel/strafehud.qc

   1 // Author: Juhu
   2
   3 #include "strafehud.qh"
   4
   5 #include <client/draw.qh>
   6 #include <client/hud/panel/racetimer.qh>
   7 #include <client/resources.qh>
   8 #include <client/view.qh>
   9 #include <common/animdecide.qh>
  10 #include <common/ent_cs.qh>
  11 #include <common/mapinfo.qh>
  12 #include <common/physics/movetypes/movetypes.qh>
  13 #include <common/physics/player.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15
  16 // StrafeHUD (#25)
  17
  18 void HUD_StrafeHUD_Export(int fh)
  19 {
  20     // allow saving cvars that aesthetically change the panel into hud skin files
  21 }
  22
  23 float hidden_width;
  24 int direction;
  25 float demo_angle = -37;
  26 float demo_direction = 1;
  27 float demo_time = 0;
  28 bool state_onground = false;
  29 float state_onground_time = 0;
  30 bool state_strafekeys = false;
  31 float state_strafekeys_time = 0;
  32 bool turn = false;
  33 float turnangle;
  34 float turnspeed;
  35 bool fwd = true;
  36 float starttime = 0;
  37 float startspeed = -1;
  38 float jumptime = 0;
  39 float jumpheight = -1;
  40 float jumpheight_persistent = -1;
  41 float jumpheight_prev = 0;
  42 float jumpspeed_prev = 0;
  43 bool  jumprestart = true;
  44
  45 // provide basic panel cvars to old clients
  46 // TODO remove them after a future release (0.8.2+)
  47 noref string autocvar_hud_panel_strafehud_pos = "0.320000 0.570000";
  48 noref string autocvar_hud_panel_strafehud_size = "0.360000 0.020000";
  49 noref string autocvar_hud_panel_strafehud_bg = "0";
  50 noref string autocvar_hud_panel_strafehud_bg_color = "";
  51 noref string autocvar_hud_panel_strafehud_bg_color_team = "";
  52 noref string autocvar_hud_panel_strafehud_bg_alpha = "0.7";
  53 noref string autocvar_hud_panel_strafehud_bg_border = "";
  54 noref string autocvar_hud_panel_strafehud_bg_padding = "";
  55
  56 void HUD_StrafeHUD()
  57 {
  58     entity strafeplayer;
  59     bool islocal;
  60
  61     // generic hud routines
  62     if(!autocvar__hud_configure)
  63     {
  64         if(!autocvar_hud_panel_strafehud ||
  65            (spectatee_status == -1 && (autocvar_hud_panel_strafehud == 1 || autocvar_hud_panel_strafehud == 3)) ||
  66            (autocvar_hud_panel_strafehud == 3 && !MUTATOR_CALLHOOK(HUD_StrafeHUD_showoptional))) return;
  67     }
  68
  69     HUD_Panel_LoadCvars();
  70
  71     if(autocvar_hud_panel_strafehud_dynamichud)
  72     {
  73         HUD_Scale_Enable();
  74     }
  75     else
  76     {
  77         HUD_Scale_Disable();
  78     }
  79
  80     HUD_Panel_DrawBg();
  81
  82     if(panel_bg_padding)
  83     {
  84         panel_pos  += '1 1 0' * panel_bg_padding;
  85         panel_size -= '2 2 0' * panel_bg_padding;
  86     }
  87
  88     // find out whether the local csqcmodel entity is valid
  89     if(spectatee_status > 0 || isdemo())
  90     {
  91         islocal = false;
  92         strafeplayer = CSQCModel_server2csqc(player_localentnum - 1);
  93     }
  94     else
  95     {
  96         islocal = true;
  97         strafeplayer = csqcplayer;
  98     }
  99
 100     // draw strafehud
 101     if(csqcplayer && strafeplayer)
 102     {
 103         // physics
 104         bool   onground                      = islocal ? IS_ONGROUND(strafeplayer) : !(strafeplayer.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 105         bool   strafekeys;
 106         bool   swimming                      = strafeplayer.waterlevel >= WATERLEVEL_SWIMMING;
 107         bool   spectating                    = entcs_GetSpecState(strafeplayer.sv_entnum) == ENTCS_SPEC_PURE;
 108         float  speed                         = !autocvar__hud_configure ? vlen(vec2(csqcplayer.velocity)) : 1337; // use local csqcmodel entity for this even when spectating, flickers too much otherwise
 109         float  maxspeed_crouch_mod           = IS_DUCKED(csqcplayer) && !swimming ? .5 : 1;
 110         float  maxspeed_water_mod            = swimming ? .7 : 1; // very simplified water physics, the hud will not work well (and is not supposed to) while swimming
 111         float  maxspeed_phys                 = onground ? PHYS_MAXSPEED(strafeplayer) : PHYS_MAXAIRSPEED(strafeplayer);
 112         float  maxspeed                      = !autocvar__hud_configure ? maxspeed_phys * maxspeed_crouch_mod * maxspeed_water_mod : 320;
 113         float  movespeed;
 114         float  vel_angle                     = vectoangles(strafeplayer.velocity).y - (vectoangles(strafeplayer.velocity).y > 180 ? 360 : 0); // change the range from 0° - 360° to -180° - 180° to match how view_angle represents angles
 115         float  view_angle                    = PHYS_INPUT_ANGLES(strafeplayer).y;
 116         float  angle;
 117         vector movement                      = PHYS_INPUT_MOVEVALUES(strafeplayer);
 118         int    keys                          = STAT(PRESSED_KEYS);
 119         int    keys_fwd;
 120         float  wishangle                     = 0;
 121
 122         // HUD
 123         int    mode                          = autocvar_hud_panel_strafehud_mode >= 0 && autocvar_hud_panel_strafehud_mode <= 1 ? autocvar_hud_panel_strafehud_mode : 0;
 124         float  speed_conversion_factor       = GetSpeedUnitFactor(autocvar_hud_panel_strafehud_unit);
 125         float  length_conversion_factor      = GetLengthUnitFactor(autocvar_hud_panel_strafehud_unit);
 126         string speed_unit                    = GetSpeedUnit(autocvar_hud_panel_strafehud_unit);
 127         string length_unit                   = GetLengthUnit(autocvar_hud_panel_strafehud_unit);
 128         int    length_decimals               = autocvar_hud_panel_strafehud_unit >= 3 && autocvar_hud_panel_strafehud_unit <= 5 ? 6 : 2; // use more decimals when displaying km or miles
 129         float  antiflicker_angle             = bound(0, autocvar_hud_panel_strafehud_antiflicker_angle, 180);
 130         float  antiflicker_speed             = max(0, autocvar_hud_panel_strafehud_antiflicker_speed);
 131         float  minspeed;
 132         float  shift_offset                  = 0;
 133         bool   straight_overturn             = false;
 134         bool   immobile                      = speed <= (swimming ? antiflicker_speed : 0);
 135         float  hudangle;
 136         float  neutral_offset;
 137         float  neutral_width;
 138         vector currentangle_color            = autocvar_hud_panel_strafehud_angle_neutral_color;
 139         float  currentangle_offset;
 140         vector currentangle_size             = '0 0 0';
 141         float  bestangle;
 142         float  odd_bestangle;
 143         bool   bestangle_anywhere            = false;
 144         float  bestangle_offset;
 145         float  switch_bestangle_offset;
 146         bool   odd_angles                    = false;
 147         float  odd_bestangle_offset          = 0;
 148         float  switch_odd_bestangle_offset   = 0;
 149         float  bestangle_width;
 150         float  accelzone_left_offset;
 151         float  accelzone_right_offset;
 152         float  accelzone_width;
 153         float  overturn_offset;
 154         float  overturn_width;
 155         float  slickdetector_height;
 156         vector direction_size_vertical       = '0 0 0';
 157         vector direction_size_horizontal     = '0 0 0';
 158         float  range_minangle;
 159         float  arrow_size = max(panel_size.y * min(autocvar_hud_panel_strafehud_angle_arrow_size, 10), 0); // there's only one size cvar for the arrows, they will always have a 45° angle to ensure proper rendering without antialiasing
 160
 161         if(!autocvar_hud_panel_strafehud_uncapped)
 162             arrow_size = max(arrow_size, 1);
 163
 164         // determine whether the player is pressing forwards or backwards keys
 165         if(islocal) // if entity is local player
 166         {
 167             if(movement.x > 0)
 168             {
 169                 keys_fwd = 1;
 170             }
 171             else if(movement.x < 0)
 172             {
 173                 keys_fwd = -1;
 174             }
 175             else
 176             {
 177                 keys_fwd = 0;
 178             }
 179         }
 180         else // alternatively determine direction by querying pressed keys
 181         {
 182             if((keys & KEY_FORWARD) && !(keys & KEY_BACKWARD))
 183             {
 184                 keys_fwd = 1;
 185             }
 186             else if(!(keys & KEY_FORWARD) && (keys & KEY_BACKWARD))
 187             {
 188                 keys_fwd = -1;
 189             }
 190             else
 191             {
 192                 keys_fwd = 0;
 193             }
 194         }
 195
 196         // determine player wishdir
 197         if(islocal) // if entity is local player
 198         {
 199             if(movement.x == 0)
 200             {
 201                 if(movement.y < 0)
 202                 {
 203                     wishangle = -90;
 204                 }
 205                 else if(movement.y > 0)
 206                 {
 207                     wishangle = 90;
 208                 }
 209                 else
 210                 {
 211                     wishangle = 0;
 212                 }
 213             }
 214             else
 215             {
 216                 if(movement.y == 0)
 217                 {
 218                     wishangle = 0;
 219                 }
 220                 else
 221                 {
 222                     wishangle = RAD2DEG * atan2(movement.y, movement.x);
 223                     // wrap the wish angle if it exceeds ±90°
 224                     if(fabs(wishangle) > 90)
 225                     {
 226                         if(wishangle < 0) wishangle += 180;
 227                         else wishangle -= 180;
 228                         wishangle = -wishangle;
 229                     }
 230                 }
 231             }
 232         }
 233         else // alternatively calculate wishdir by querying pressed keys
 234         {
 235             if(keys & KEY_FORWARD || keys & KEY_BACKWARD)
 236             {
 237                 wishangle = 45;
 238             }
 239             else
 240             {
 241                 wishangle = 90;
 242             }
 243             if(keys & KEY_LEFT)
 244             {
 245                 wishangle *= -1;
 246             }
 247             else if(!(keys & KEY_RIGHT))
 248             {
 249                 wishangle = 0; // wraps at 180°
 250             }
 251         }
 252
 253         strafekeys = fabs(wishangle) > 45;
 254
 255         // determine minimum required angle to display full strafe range
 256         range_minangle = fabs(wishangle) % 90; // maximum range is 90 degree
 257         if(range_minangle > 45) // minimum angle range is 45
 258         {
 259             range_minangle = 45 - fabs(wishangle) % 45;
 260         }
 261         range_minangle = 90 - range_minangle; // calculate value which is never >90 or <45
 262         range_minangle *= 2; // multiply to accommodate for both sides of the hud
 263
 264         if(autocvar_hud_panel_strafehud_range == 0)
 265         {
 266             if(autocvar__hud_configure)
 267             {
 268                 hudangle = 90;
 269             }
 270             else
 271             {
 272                 hudangle = range_minangle; // use minimum angle required if dynamically setting hud angle
 273             }
 274         }
 275         else
 276         {
 277             hudangle = bound(0, fabs(autocvar_hud_panel_strafehud_range), 360); // limit HUD range to 360 degrees, higher values don't make sense
 278         }
 279
 280         // detect air strafe turning
 281         if(onground != state_onground)
 282         {
 283             state_onground_time = time;
 284         }
 285         state_onground = onground;
 286
 287         if(strafekeys != state_strafekeys)
 288         {
 289             state_strafekeys_time = time;
 290         }
 291         state_strafekeys = strafekeys;
 292
 293         if((!strafekeys && vlen(vec2(movement)) > 0) || swimming || autocvar__hud_configure)
 294         {
 295             turn = false;
 296         }
 297         else if(onground)
 298         {
 299             if((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_ground) // timeout for strafe jumping in general
 300             {
 301                 turn = false;
 302             }
 303         }
 304         else // air strafe only
 305         {
 306             if(strafekeys)
 307             {
 308                 if(((time - state_onground_time) >= autocvar_hud_panel_strafehud_timeout_air) || (keys & KEY_JUMP)) // timeout for slick ramps
 309                 {
 310                     turn = true; // CPMA turning
 311                     turnangle = wishangle;
 312
 313                     // calculate the maximum air strafe speed
 314                     if(PHYS_MAXAIRSPEED(strafeplayer) == 0){
 315                         maxspeed = 0;
 316                     }
 317                     else if(PHYS_MAXAIRSTRAFESPEED(strafeplayer) == 0 || PHYS_MAXAIRSPEED(strafeplayer) <= PHYS_MAXAIRSTRAFESPEED(strafeplayer)){
 318                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer);
 319                     }
 320                     else{
 321                         maxspeed = PHYS_MAXAIRSPEED(strafeplayer) * pow(fabs(PHYS_MAXAIRSTRAFESPEED(strafeplayer) / PHYS_MAXAIRSPEED(strafeplayer)), 1 - (90 - fabs(wishangle)) / 45); // no modifiers here because they don't affect air strafing
 322                     }
 323
 324                     turnspeed = vlen(vec2(movement));
 325                     if(turnspeed == 0) turnspeed = maxspeed;
 326                     else turnspeed = min(turnspeed, maxspeed);
 327                 }
 328             }
 329             else if((time - state_strafekeys_time) >= autocvar_hud_panel_strafehud_timeout_turn) // timeout for jumping with strafe keys only
 330             {
 331                 turn = false;
 332             }
 333         }
 334         if(turn && (onground || !strafekeys)) // retain last state until strafe turning times out
 335         {
 336             wishangle = turnangle;
 337             movespeed = turnspeed;
 338         }
 339         else{
 340             movespeed = vlen(vec2(movement));
 341             if(movespeed == 0) movespeed = maxspeed;
 342             else movespeed = min(movespeed, maxspeed);
 343         }
 344
 345         minspeed = autocvar_hud_panel_strafehud_switch_minspeed < 0 ? movespeed + antiflicker_speed : autocvar_hud_panel_strafehud_switch_minspeed;
 346
 347         // get current strafing angle ranging from -180° to +180°
 348         if(!autocvar__hud_configure)
 349         {
 350             if(speed > 0)
 351             {
 352                 // calculate view angle relative to the players current velocity direction
 353                 angle = vel_angle - view_angle;
 354
 355                 // if the angle goes above 180° or below -180° wrap it to the opposite side since we want the interior angle
 356                 if (angle > 180) angle -= 360;
 357                 else if(angle < -180) angle += 360;
 358
 359                 // determine whether the player is strafing forwards or backwards
 360                 // if the player isn't strafe turning use forwards/backwards keys to determine direction
 361                 if(fabs(wishangle) != 90)
 362                 {
 363                     if(keys_fwd > 0)
 364                     {
 365                         fwd = true;
 366                     }
 367                     else if(keys_fwd < 0)
 368                     {
 369                         fwd = false;
 370                     }
 371                     else
 372                     {
 373                         fwd = fabs(angle) <= 90;
 374                     }
 375                 }
 376                 // otherwise determine by examining the strafe angle
 377                 else
 378                 {
 379                     if(wishangle < 0) // detect direction using wishangle since the direction is not yet set
 380                     {
 381                         fwd = angle <= -wishangle;
 382                     }
 383                     else
 384                     {
 385                         fwd = angle >= -wishangle;
 386                     }
 387                 }
 388
 389                 // shift the strafe angle by 180° when strafing backwards
 390                 if(!fwd)
 391                 {
 392                     if(angle < 0) angle += 180;
 393                     else angle -= 180;
 394                 }
 395
 396                 // don't make the angle indicator switch side too much at ±180° if anti flicker is turned on
 397                 if(angle > (180 - antiflicker_angle) || angle < (-180 + antiflicker_angle))
 398                 {
 399                     straight_overturn = true;
 400                 }
 401             }
 402             else
 403             {
 404                 angle = 0;
 405             }
 406         }
 407         else // simulate turning for HUD setup
 408         {
 409             fwd = true;
 410             if(autocvar__hud_panel_strafehud_demo && ((time - demo_time) >= .025))
 411             {
 412                 demo_time = time;
 413                 demo_angle += demo_direction;
 414                 if(fabs(demo_angle) >= 55)
 415                 {
 416                     demo_direction = -demo_direction;
 417                 }
 418             }
 419             angle = demo_angle;
 420             wishangle = 45 * (demo_angle > 0 ? 1 : -1);
 421         }
 422
 423         // invert the wish angle when strafing backwards
 424         if(!fwd)
 425         {
 426             wishangle = -wishangle;
 427         }
 428
 429         // flip angles if v_flipped is enabled
 430         if(autocvar_v_flipped)
 431         {
 432             angle = -angle;
 433             wishangle = -wishangle;
 434         }
 435
 436         // determine whether the player is strafing left or right
 437         if(wishangle != 0)
 438         {
 439             direction = wishangle > 0 ? 1 : -1;
 440         }
 441         else
 442         {
 443             direction = (angle > antiflicker_angle && angle < (180 - antiflicker_angle)) ? 1 : (angle < -antiflicker_angle && angle > (-180 + antiflicker_angle)) ? -1 : 0;
 444         }
 445
 446         // best angle to strafe at
 447         bestangle = (speed > movespeed ? acos(movespeed / speed) : 0) * RAD2DEG * (direction < 0 ? -1 : 1);
 448         odd_bestangle = -bestangle - wishangle;
 449         bestangle -= wishangle;
 450
 451         // various offsets and size calculations of hud indicator elements
 452         // how much is hidden by the current hud angle
 453         hidden_width = (360 - hudangle) / hudangle * panel_size.x;
 454         // current angle
 455         currentangle_size.x = autocvar_hud_panel_strafehud_angle_width;
 456         currentangle_size.y = autocvar_hud_panel_strafehud_angle_height;
 457         if(!autocvar_hud_panel_strafehud_uncapped)
 458         {
 459             currentangle_size.x = min(currentangle_size.x, 10);
 460             currentangle_size.y = min(currentangle_size.y, 10);
 461         }
 462         currentangle_size.x *= panel_size.x;
 463         currentangle_size.y *= panel_size.y;
 464         if(!autocvar_hud_panel_strafehud_uncapped)
 465         {
 466             currentangle_size.x = max(currentangle_size.x, 1);
 467             currentangle_size.y = max(currentangle_size.y, 1);
 468         }
 469         else
 470         {
 471             currentangle_size.y = max(currentangle_size.y, 0);
 472         }
 473         if(mode == 0)
 474         {
 475             currentangle_offset = angle/hudangle * panel_size.x;
 476         }
 477         else
 478         {
 479             currentangle_offset = bound(-hudangle/2, angle, hudangle/2)/hudangle * panel_size.x + panel_size.x/2;
 480         }
 481         // best strafe acceleration angle
 482         bestangle_offset        =  bestangle/hudangle * panel_size.x + panel_size.x/2;
 483         switch_bestangle_offset = -bestangle/hudangle * panel_size.x + panel_size.x/2;
 484         bestangle_width = panel_size.x * autocvar_hud_panel_strafehud_switch_width;
 485         if(!autocvar_hud_panel_strafehud_uncapped)
 486             bestangle_width = max(bestangle_width, 1);
 487
 488         if(((angle > -wishangle && direction < 0) || (angle < -wishangle && direction > 0)) && (direction != 0))
 489         {
 490             odd_angles = true;
 491             odd_bestangle_offset = odd_bestangle/hudangle * panel_size.x + panel_size.x/2;
 492             switch_odd_bestangle_offset = (odd_bestangle+bestangle*2)/hudangle * panel_size.x + panel_size.x/2;
 493         }
 494         // direction indicator
 495         direction_size_vertical.x = autocvar_hud_panel_strafehud_direction_width;
 496         if(!autocvar_hud_panel_strafehud_uncapped)
 497             direction_size_vertical.x = min(direction_size_vertical.x, 1);
 498         direction_size_vertical.x *= panel_size.y;
 499         if(!autocvar_hud_panel_strafehud_uncapped)
 500             direction_size_vertical.x = max(direction_size_vertical.x, 1);
 501         direction_size_vertical.y = panel_size.y + direction_size_vertical.x*2;
 502         direction_size_horizontal.x = panel_size.x * min(autocvar_hud_panel_strafehud_direction_length, .5);
 503         direction_size_horizontal.y = direction_size_vertical.x;
 504         // overturn
 505         overturn_width = 180/hudangle * panel_size.x;
 506
 507         // the neutral zone fills the whole strafe bar
 508         if(immobile)
 509         {
 510             // draw neutral zone
 511             if(panel_size.x > 0 && panel_size.y > 0 && autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha > 0)
 512             {
 513                 switch(autocvar_hud_panel_strafehud_style)
 514                 {
 515                     default:
 516                     case 0:
 517                         drawfill(panel_pos, panel_size, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 518                         break;
 519
 520                     case 1:
 521                         HUD_Panel_DrawProgressBar(panel_pos, panel_size, "progressbar", 1, 0, 0, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 522                 }
 523             }
 524         }
 525         else
 526         {
 527             // calculate various zones of the strafe-o-meter
 528             accelzone_width = overturn_offset = (90 - fabs(bestangle + wishangle))/hudangle * panel_size.x;
 529             accelzone_right_offset = 0;
 530             accelzone_left_offset = overturn_offset + overturn_width;
 531             neutral_width = 360/hudangle * panel_size.x - accelzone_width*2 - overturn_width;
 532             neutral_offset = direction < 0 ? accelzone_left_offset + accelzone_width : -neutral_width;
 533
 534             // remove switch indicator width from offset
 535             if(direction < 0)
 536             {
 537                 bestangle_offset -= bestangle_width;
 538                 switch_odd_bestangle_offset -= bestangle_width;
 539             }
 540             else
 541             {
 542                 switch_bestangle_offset -= bestangle_width;
 543                 odd_bestangle_offset -= bestangle_width;
 544             }
 545
 546             // shift hud if operating in view angle centered mode
 547             if(mode == 0)
 548             {
 549                 shift_offset = -currentangle_offset;
 550                 bestangle_offset += shift_offset;
 551                 switch_bestangle_offset += shift_offset;
 552                 odd_bestangle_offset += shift_offset;
 553                 switch_odd_bestangle_offset += shift_offset;
 554             }
 555             if(direction < 0) shift_offset += -360/hudangle * panel_size.x;
 556             // calculate how far off-center the strafe zones currently are
 557             shift_offset += (panel_size.x + neutral_width)/2 - wishangle/hudangle * panel_size.x;
 558             // shift strafe zones into correct place
 559             neutral_offset += shift_offset;
 560             accelzone_left_offset += shift_offset;
 561             accelzone_right_offset += shift_offset;
 562             overturn_offset += shift_offset;
 563
 564             // draw left acceleration zone
 565             HUD_Panel_DrawStrafeHUD(accelzone_left_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 1);
 566
 567             // draw right acceleration zone
 568             HUD_Panel_DrawStrafeHUD(accelzone_right_offset, accelzone_width, autocvar_hud_panel_strafehud_bar_accel_color, autocvar_hud_panel_strafehud_bar_accel_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 2);
 569
 570             // draw overturn zone
 571             HUD_Panel_DrawStrafeHUD(overturn_offset, overturn_width, autocvar_hud_panel_strafehud_bar_overturn_color, autocvar_hud_panel_strafehud_bar_overturn_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 3);
 572
 573             // draw neutral zone
 574             HUD_Panel_DrawStrafeHUD(neutral_offset, neutral_width, autocvar_hud_panel_strafehud_bar_neutral_color, autocvar_hud_panel_strafehud_bar_neutral_alpha * panel_fg_alpha, autocvar_hud_panel_strafehud_style, 0);
 575
 576             if(direction != 0 && direction_size_vertical.x > 0 && autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha > 0)
 577             {
 578                 bool indicator_direction = direction < 0;
 579                 // invert left/right when strafing backwards or when strafing towards the opposite side indicated by the direction variable
 580                 // if both conditions are true then it's inverted twice hence not inverted at all
 581                 if(!fwd != odd_angles)
 582                 {
 583                     indicator_direction = !indicator_direction;
 584                 }
 585                 // draw the direction indicator caps at the sides of the hud
 586                 // vertical line
 587                 if(direction_size_vertical.y > 0) drawfill(panel_pos - eY * direction_size_horizontal.y + eX * (indicator_direction ? -direction_size_vertical.x : panel_size.x), direction_size_vertical, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 588                 // top horizontal line
 589                 drawfill(panel_pos + eX * (indicator_direction ? 0 : panel_size.x - direction_size_horizontal.x) - eY * direction_size_horizontal.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 590                 // bottom horizontal line
 591                 drawfill(panel_pos + eX * (indicator_direction ? 0 : panel_size.x - direction_size_horizontal.x) + eY * panel_size.y, direction_size_horizontal, autocvar_hud_panel_strafehud_direction_color, autocvar_hud_panel_strafehud_direction_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 592             }
 593
 594             if(speed >= minspeed && bestangle_width > 0) // only draw indicators if minspeed is reached
 595             {
 596                 // draw the switch indicator(s)
 597                 float offset = !odd_angles ? bestangle_offset : odd_bestangle_offset;
 598                 float switch_offset = !odd_angles ? switch_bestangle_offset : switch_odd_bestangle_offset;
 599                 HUD_Panel_DrawStrafeHUD(switch_offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 600                 if(direction == 0) HUD_Panel_DrawStrafeHUD(offset, bestangle_width, autocvar_hud_panel_strafehud_switch_color, autocvar_hud_panel_strafehud_switch_alpha * panel_fg_alpha, 0, 0);
 601             }
 602         }
 603
 604         // experimental: slick detector
 605         slickdetector_height = max(autocvar_hud_panel_strafehud_slickdetector_height, 0);
 606         if(!autocvar_hud_panel_strafehud_uncapped)
 607              slickdetector_height = min(slickdetector_height, 1);
 608         slickdetector_height *= panel_size.y;
 609         if(autocvar_hud_panel_strafehud_slickdetector_range > 0 && autocvar_hud_panel_strafehud_slickdetector_alpha > 0 && slickdetector_height > 0 && panel_size.x > 0) // dunno if slick detection works in spectate
 610         {
 611             float slicksteps = max(autocvar_hud_panel_strafehud_slickdetector_granularity, 0);
 612             bool slickdetected = false;
 613
 614             if(!autocvar_hud_panel_strafehud_uncapped)
 615                 slicksteps = min(slicksteps, 4);
 616             slicksteps = 90 / pow(2, slicksteps);
 617
 618             if(islocal) slickdetected = IS_ONSLICK(strafeplayer); // don't need to traceline if already touching slick
 619
 620             // traceline into every direction
 621             trace_dphitq3surfaceflags = 0;
 622             for(float i = 0; i < 360 && !slickdetected; i += slicksteps)
 623             {
 624                 vector slickoffset;
 625                 float slickrotate;
 626                 slickoffset.z = -cos(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 627                 slickrotate = sin(i * DEG2RAD) * autocvar_hud_panel_strafehud_slickdetector_range;
 628                 if(i != 0 && i != 180)
 629                 {
 630                     for(float j = 0; j < 180 && !slickdetected; j += slicksteps)
 631                     {
 632                         slickoffset.x = sin(j * DEG2RAD) * slickrotate;
 633                         slickoffset.y = cos(j * DEG2RAD) * slickrotate;
 634
 635                         traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 636                         if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 637                     }
 638                 }
 639                 else
 640                 {
 641                     slickoffset.x = slickoffset.y = 0;
 642                     traceline(strafeplayer.origin, strafeplayer.origin + slickoffset, MOVE_WORLDONLY, NULL);
 643                     if((PHYS_FRICTION(strafeplayer) == 0 && trace_fraction < 1) || trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK) slickdetected = true;
 644                 }
 645             }
 646
 647             // if a traceline hit a slick surface
 648             if(slickdetected)
 649             {
 650                 vector slickdetector_size = panel_size;
 651                 slickdetector_size.y = slickdetector_height;
 652                 // top horizontal line
 653                 drawfill(panel_pos - eY * slickdetector_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 654                 // bottom horizontal line
 655                 drawfill(panel_pos + eY * panel_size.y, slickdetector_size, autocvar_hud_panel_strafehud_slickdetector_color, autocvar_hud_panel_strafehud_slickdetector_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 656             }
 657         }
 658
 659         if(speed < (movespeed + antiflicker_speed) && !immobile)
 660         {
 661             bestangle_anywhere = true; // moving forward should suffice to gain speed
 662         }
 663
 664         // draw the actual strafe angle
 665         if(!bestangle_anywhere && !immobile) // player gains speed with strafing
 666         {
 667             if((direction > 0 && (angle >= bestangle || angle <= -(bestangle + wishangle*2))) ||
 668                (direction < 0 && (angle <= bestangle || angle >= -(bestangle + wishangle*2))))
 669             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 670         }
 671
 672         if(fabs(angle + wishangle) > 90) // player is overturning
 673         {
 674             currentangle_color = autocvar_hud_panel_strafehud_angle_overturn_color;
 675         }
 676         else if(bestangle_anywhere) // player gains speed without strafing
 677         {
 678             currentangle_color = autocvar_hud_panel_strafehud_angle_accel_color;
 679         }
 680
 681         if(mode == 0 || straight_overturn)
 682         {
 683             currentangle_offset = panel_size.x/2;
 684         }
 685
 686         if(autocvar_hud_panel_strafehud_style == 2 && !immobile)
 687         {
 688             float moveangle = angle + wishangle;
 689             float strafeangle = (bestangle + wishangle) * (direction < 0 ? -1 : 1);
 690             float strafe_ratio = 0;
 691             if(fabs(moveangle) > 90)
 692             {
 693                 strafe_ratio = -((fabs(moveangle) - 90) / 90);
 694                 if(strafe_ratio < -1) strafe_ratio = -2 - strafe_ratio;
 695             }
 696             else
 697             {
 698                 if(moveangle >= strafeangle)
 699                 {
 700                     strafe_ratio = 1 - (moveangle - strafeangle) / (90 - strafeangle);
 701                 }
 702                 else if(moveangle <= -strafeangle)
 703                 {
 704                     strafe_ratio = 1 - (moveangle + strafeangle) / (-90 + strafeangle);
 705                 }
 706             }
 707             if(strafe_ratio < 0)
 708             {
 709                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_overturn_color, -strafe_ratio);
 710             }
 711             else
 712             {
 713                 currentangle_color = StrafeHUD_mixColors(autocvar_hud_panel_strafehud_angle_neutral_color, autocvar_hud_panel_strafehud_angle_accel_color, strafe_ratio);
 714             }
 715         }
 716
 717         if(autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha > 0)
 718         {
 719             switch(autocvar_hud_panel_strafehud_angle_style)
 720             {
 721                 case 1:
 722                     if(currentangle_size.x > 0 && currentangle_size.y > 0) drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2) + eX * (currentangle_offset - currentangle_size.x/2), currentangle_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 723                     break;
 724                 case 2:
 725                     if(currentangle_size.x > 0 && currentangle_size.y > 0)
 726                     {
 727                         vector line_size = currentangle_size;
 728                         line_size.y = currentangle_size.y / (bound(2, autocvar_hud_panel_strafehud_angle_dashes, currentangle_size.y)*2-1);
 729                         for(float i = 0; i < currentangle_size.y; i += line_size.y*2)
 730                         {
 731                             if(i + line_size.y*2 >= currentangle_size.y) line_size.y = currentangle_size.y - i;
 732                             drawfill(panel_pos - eY * ((currentangle_size.y - panel_size.y) / 2 - i) + eX * (currentangle_offset - line_size.x/2), line_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 733                         }
 734                     }
 735                     break;
 736                 case 0:
 737                 default:
 738             }
 739
 740             if(autocvar_hud_panel_strafehud_angle_arrow > 0)
 741             {
 742                 if(arrow_size > 0)
 743                 {
 744                     if(autocvar_hud_panel_strafehud_angle_arrow == 1 || autocvar_hud_panel_strafehud_angle_arrow >= 3)
 745                         StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - currentangle_size.y) / 2) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, true);
 746                     if(autocvar_hud_panel_strafehud_angle_arrow >= 2)
 747                         StrafeHUD_drawStrafeArrow(panel_pos + eY * ((panel_size.y - currentangle_size.y) / 2 + currentangle_size.y) + eX * currentangle_offset, arrow_size, currentangle_color, autocvar_hud_panel_strafehud_angle_alpha * panel_fg_alpha, false);
 748                 }
 749             }
 750         }
 751
 752         draw_beginBoldFont();
 753         // show speed when crossing the start trigger
 754         if(autocvar_hud_panel_strafehud_startspeed_fade > 0)
 755         {
 756             float text_alpha = 0;
 757             if((race_nextcheckpoint == 1) || (race_checkpoint == 254 && race_nextcheckpoint == 255)) // check if the start trigger was hit (will also trigger if the finish trigger was hit if those have the same ID)
 758             {
 759                 if(starttime != race_checkpointtime)
 760                 {
 761                     starttime = race_checkpointtime;
 762                     startspeed = speed;
 763                 }
 764             }
 765             if(startspeed >= 0)
 766             {
 767                 text_alpha = cos(((time - starttime) / autocvar_hud_panel_strafehud_startspeed_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 768                 if((time - starttime) > autocvar_hud_panel_strafehud_startspeed_fade)
 769                 {
 770                     startspeed = -1;
 771                 }
 772             }
 773             if(startspeed >= 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_startspeed_size > 0)
 774             {
 775                 vector startspeed_size = panel_size;
 776                 startspeed_size.y = autocvar_hud_panel_strafehud_startspeed_size;
 777                 if(!autocvar_hud_panel_strafehud_uncapped)
 778                     startspeed_size.y = min(startspeed_size.y, 10);
 779                 startspeed_size.y *= panel_size.y;
 780                 if(!autocvar_hud_panel_strafehud_uncapped)
 781                     startspeed_size.y = max(startspeed_size.y, 1);
 782                 drawstring_aspect(panel_pos + eY * (panel_size.y + arrow_size + ((currentangle_size.y - panel_size.y) / 2)), strcat(ftos_decimals(startspeed * speed_conversion_factor, 2), autocvar_hud_panel_strafehud_unit_show ? speed_unit : ""), startspeed_size, autocvar_hud_panel_strafehud_startspeed_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 783             }
 784         }
 785         else
 786         {
 787             starttime = 0;
 788             startspeed = -1;
 789         }
 790
 791         // experimental: show height achieved by a single jump (doesn't work in low gravity and may not be 100% accurate)
 792         if(autocvar_hud_panel_strafehud_jumpheight_fade > 0)
 793         {
 794             float text_alpha = 0;
 795             float jumpheight_min = max(autocvar_hud_panel_strafehud_jumpheight_min, 0);
 796             float jumpheight_current = strafeplayer.origin.z;
 797             float jumpspeed_current = strafeplayer.velocity.z;
 798             if(jumpspeed_prev <= jumpspeed_current || jumpheight_prev > jumpheight_current || onground || swimming || IS_DEAD(strafeplayer) || spectating)
 799             {
 800                 // tries to catch kill and spectate but those are not reliable, should just hook to kill/spectate/teleport and reset jump height there
 801                 jumprestart = true;
 802             }
 803             else
 804             {
 805                 if(jumpheight < 0 || jumprestart)
 806                 {
 807                     jumprestart = false;
 808                     jumpheight = 0;
 809                 }
 810                 else
 811                 {
 812                     jumpheight += jumpheight_current - jumpheight_prev;
 813                 }
 814                 if((jumpheight * length_conversion_factor) > jumpheight_min && jumpheight > jumpheight_persistent)
 815                 {
 816                     jumptime = time;
 817                     jumpheight_persistent = jumpheight;
 818                 }
 819             }
 820             jumpheight_prev = jumpheight_current;
 821             jumpspeed_prev = jumpspeed_current;
 822             if(jumpheight_persistent > 0)
 823             {
 824                 text_alpha = cos(((time - jumptime) / autocvar_hud_panel_strafehud_jumpheight_fade) * 90 * DEG2RAD); // fade non-linear like the physics panel does
 825                 if((time - jumptime) > autocvar_hud_panel_strafehud_jumpheight_fade)
 826                 {
 827                     jumpheight_persistent = -1;
 828                 }
 829             }
 830             if(jumpheight_persistent > 0 && text_alpha > 0 && autocvar_hud_panel_strafehud_jumpheight_size > 0)
 831             {
 832                 vector jumpheight_size = panel_size;
 833                 jumpheight_size.y = autocvar_hud_panel_strafehud_jumpheight_size;
 834                 if(!autocvar_hud_panel_strafehud_uncapped)
 835                     jumpheight_size.y = min(jumpheight_size.y, 10);
 836                 jumpheight_size.y *= panel_size.y;
 837                 if(!autocvar_hud_panel_strafehud_uncapped)
 838                     jumpheight_size.y = max(jumpheight_size.y, 1);
 839                 drawstring_aspect(panel_pos - eY * (jumpheight_size.y + arrow_size + ((currentangle_size.y - panel_size.y) / 2)), strcat(ftos_decimals(jumpheight_persistent * length_conversion_factor, length_decimals), autocvar_hud_panel_strafehud_unit_show ? length_unit : ""), jumpheight_size, autocvar_hud_panel_strafehud_jumpheight_color, text_alpha * panel_fg_alpha, DRAWFLAG_NORMAL);
 840             }
 841         }
 842         else
 843         {
 844             jumpheight_prev = jumpspeed_prev = 0;
 845             jumpheight = jumpheight_persistent = -1;
 846         }
 847         draw_endBoldFont();
 848     }
 849 }
 850
 851 // functions to make hud elements align perfectly in the hud area
 852 void HUD_Panel_DrawStrafeHUD(float offset, float width, vector color, float alpha, int type, int gradientType)
 853 {
 854     float mirror_offset, mirror_width;
 855     vector size = panel_size;
 856     vector mirror_size = panel_size;
 857     int gradient_start;
 858     float gradient_offset, gradient_mirror_offset;
 859     float overflow_width = 0, overflow_mirror_width = 0;
 860
 861     float original_width = width;
 862
 863     if(alpha <= 0 && type != 2 || width <= 0) return;
 864
 865     if(type == 2 && gradientType == 0) type = 0;
 866
 867     if(offset < 0)
 868     {
 869         mirror_width = min(fabs(offset), width);
 870         mirror_offset = panel_size.x + hidden_width - fabs(offset);
 871         width += offset;
 872         offset = 0;
 873     }
 874     else
 875     {
 876         mirror_width = min(offset + width - panel_size.x - hidden_width, width);
 877         mirror_offset = max(offset - panel_size.x - hidden_width, 0);
 878     }
 879
 880     if(width < 0) width = 0;
 881     if((offset + width) > panel_size.x)
 882     {
 883         overflow_width = (offset + width) - panel_size.x;
 884         width = panel_size.x - offset;
 885     }
 886     if(mirror_offset < 0)
 887     {
 888         mirror_width += mirror_offset;
 889         mirror_offset = 0;
 890     }
 891
 892     if(mirror_width < 0) mirror_width = 0;
 893     if((mirror_offset + mirror_width) > panel_size.x)
 894     {
 895         overflow_mirror_width = (mirror_offset + mirror_width) - panel_size.x;
 896         mirror_width = panel_size.x - mirror_offset;
 897     }
 898
 899     if(direction < 0) // swap mirror and non-mirror values if direction points left
 900     {
 901         offset += mirror_offset;
 902         mirror_offset = offset - mirror_offset;
 903         offset -= mirror_offset;
 904
 905         width += mirror_width;
 906         mirror_width = width - mirror_width;
 907         width -= mirror_width;
 908
 909         overflow_width += overflow_mirror_width;
 910         overflow_mirror_width = overflow_width - overflow_mirror_width;
 911         overflow_width -= overflow_mirror_width;
 912     }
 913
 914     size.x = width;
 915     mirror_size.x = mirror_width;
 916
 917     switch(type)
 918     {
 919         default:
 920         case 0: // no styling (drawfill)
 921             if(mirror_size.x > 0 && mirror_size.y > 0) drawfill(panel_pos + eX * mirror_offset, mirror_size, color, alpha, DRAWFLAG_NORMAL);
 922             if(size.x > 0 && size.y > 0) drawfill(panel_pos + eX * offset, size, color, alpha, DRAWFLAG_NORMAL);
 923             break;
 924
 925         case 1: // progress bar style
 926             if(mirror_size.x > 0 && mirror_size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * mirror_offset, mirror_size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 927             if(size.x > 0 && size.y > 0) HUD_Panel_DrawProgressBar(panel_pos + eX * offset, size, "progressbar", 1, 0, 0, color, alpha, DRAWFLAG_NORMAL);
 928             break;
 929
 930         case 2: // gradient style (types: 1 = left, 2 = right, 3 = both)
 931             // determine whether the gradient starts in the mirrored or the non-mirrored area
 932             if(offset == 0 && mirror_offset == 0) gradient_start = width > mirror_width ? 2 : 1;
 933             else if(offset == 0) gradient_start = 2;
 934             else if(mirror_offset == 0) gradient_start = 1;
 935             else gradient_start = 0;
 936
 937             switch(gradient_start){
 938                 default:
 939                 case 0: // no offset required
 940                     gradient_offset = gradient_mirror_offset = 0;
 941                     break;
 942                 case 1: // offset starts in non-mirrored area, mirrored area requires offset
 943                     gradient_offset = 0;
 944                     gradient_mirror_offset = original_width - (mirror_width + overflow_mirror_width);
 945                     break;
 946                 case 2: // offset starts in mirrored area, non-mirrored area requires offset
 947                     gradient_offset = original_width - (width + overflow_width);
 948                     gradient_mirror_offset = 0;
 949             }
 950
 951             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, mirror_size, original_width, mirror_offset, alpha, gradient_mirror_offset, gradientType);
 952             StrafeHUD_drawGradient(color, autocvar_hud_panel_strafehud_bar_neutral_color, size, original_width, offset, alpha, gradient_offset, gradientType);
 953     }
 954 }
 955
 956 vector StrafeHUD_mixColors(vector color1, vector color2, float ratio)
 957 {
 958     vector mixedColor;
 959     if(ratio <= 0) return color1;
 960     if(ratio >= 1) return color2;
 961     mixedColor.x = color1.x + (color2.x - color1.x) * ratio;
 962     mixedColor.y = color1.y + (color2.y - color1.y) * ratio;
 963     mixedColor.z = color1.z + (color2.z - color1.z) * ratio;
 964     return mixedColor;
 965 }
 966
 967 void StrafeHUD_drawGradient(vector color1, vector color2, vector size, float original_width, float offset, float alpha, float gradientOffset, int gradientType)
 968 {
 969     float color_ratio, alpha1, alpha2;
 970     vector gradient_size = size;
 971     alpha1 = bound(0, alpha, 1);
 972     alpha2 = bound(0, autocvar_hud_panel_strafehud_bar_neutral_alpha, 1);
 973     if((alpha1+alpha2) == 0) return;
 974     color_ratio = alpha1/(alpha1+alpha2);
 975     for(int i = 0; i < size.x; ++i)
 976     {
 977         float ratio, alpha_ratio, combine_ratio1, combine_ratio2;
 978         gradient_size.x = size.x - i < 1 ? size.x - i : 1;
 979         ratio = (i + gradientOffset) / original_width * (gradientType == 3 ? 2 : 1);
 980         if(ratio > 1) ratio = 2 - ratio;
 981         if(gradientType != 2) ratio = 1 - ratio;
 982         alpha_ratio = alpha1 - (alpha1 - alpha2) * ratio;
 983         combine_ratio1 = ratio*(1-color_ratio);
 984         combine_ratio2 = (1-ratio)*color_ratio;
 985         ratio = (combine_ratio1 + combine_ratio2) == 0 ? 1 : combine_ratio1/(combine_ratio1 + combine_ratio2);
 986         if(alpha_ratio > 0) drawfill(panel_pos + eX * (offset + i), gradient_size, StrafeHUD_mixColors(color1, color2, ratio), alpha_ratio, DRAWFLAG_NORMAL);
 987     }
 988 }
 989
 990 // draw the strafe arrows (inspired by drawspritearrow() in common/mutators/mutator/waypoints/waypointsprites.qc)
 991 void StrafeHUD_drawStrafeArrow(vector origin, float size, vector color, float alpha, bool flipped)
 992 {
 993     if(flipped) origin -= size*eY;
 994     R_BeginPolygon("", DRAWFLAG_NORMAL, true);
 995     R_PolygonVertex(origin + (flipped ? size*eY : '0 0 0')          , '0 0 0', color, alpha);
 996     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) - size*eX, '0 0 0', color, alpha);
 997     R_PolygonVertex(origin + (flipped ? '0 0 0' : size*eY) + size*eX, '0 0 0', color, alpha);
 998     R_EndPolygon();
 999 }
1000
1001 // length unit conversion (km and miles are only included to match the GetSpeedUnit* functions)
1002 float GetLengthUnitFactor(int length_unit)
1003 {
1004     switch(length_unit)
1005     {
1006         default:
1007         case 1: return 1.0;
1008         case 2: return 0.0254;
1009         case 3: return 0.0254 * 0.001;
1010         case 4: return 0.0254 * 0.001 * 0.6213711922;
1011         case 5: return 0.0254 * 0.001 * 0.5399568035;
1012     }
1013 }
1014
1015 string GetLengthUnit(int length_unit)
1016 {
1017     switch(length_unit)
1018     {
1019         // translator-friendly strings without the initial space
1020         default:
1021         case 1: return strcat(" ", _("qu"));
1022         case 2: return strcat(" ", _("m"));
1023         case 3: return strcat(" ", _("km"));
1024         case 4: return strcat(" ", _("mi"));
1025         case 5: return strcat(" ", _("nmi"));
1026     }
1027 }