qcsrc/client/hud/crosshair.qc

   1 #include "crosshair.qh"
   2
   3 #include <client/autocvars.qh>
   4 #include <client/draw.qh>
   5 #include <client/hud/panel/scoreboard.qh>
   6 #include <client/view.qh>
   7 #include <common/deathtypes/all.qh>
   8 #include <common/ent_cs.qh>
   9 #include <common/mapobjects/trigger/viewloc.qh>
  10 #include <common/minigames/cl_minigames.qh>
  11 #include <common/minigames/cl_minigames_hud.qh>
  12 #include <common/mutators/mutator/overkill/oknex.qh>
  13 #include <common/vehicles/all.qh>
  14 #include <common/viewloc.qh>
  15 #include <common/wepent.qh>
  16 #include <lib/csqcmodel/cl_player.qh>
  17
  18 float pickup_crosshair_time, pickup_crosshair_size;
  19 float hitindication_crosshair_size;
  20 float use_vortex_chargepool;
  21
  22 float reticle_type;
  23
  24 vector wcross_origin;
  25 float wcross_scale_prev, wcross_alpha_prev;
  26 vector wcross_color_prev;
  27 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
  28 vector wcross_color_goal_prev;
  29 float wcross_changedonetime;
  30
  31 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
  32 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
  33 float wcross_name_changestarttime, wcross_name_changedonetime;
  34 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
  35
  36 float wcross_ring_prev;
  37
  38 entity trueaim;
  39 entity trueaim_rifle;
  40
  41 const float SHOTTYPE_HITTEAM = 1;
  42 const float SHOTTYPE_HITOBSTRUCTION = 2;
  43 const float SHOTTYPE_HITWORLD = 3;
  44 const float SHOTTYPE_HITENEMY = 4;
  45
  46 void TrueAim_Init()
  47 {
  48         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  49         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  50 }
  51
  52 float EnemyHitCheck()
  53 {
  54         float t, n;
  55         wcross_origin = project_3d_to_2d(trace_endpos);
  56         wcross_origin.z = 0;
  57         if(trace_ent)
  58                 n = trace_ent.entnum;
  59         else
  60                 n = trace_networkentity;
  61         if(n < 1)
  62                 return SHOTTYPE_HITWORLD;
  63         if(n > maxclients)
  64                 return SHOTTYPE_HITWORLD;
  65         t = entcs_GetTeam(n - 1);
  66         if(teamplay)
  67                 if(t == myteam)
  68                         return SHOTTYPE_HITTEAM;
  69         if(t == NUM_SPECTATOR)
  70                 return SHOTTYPE_HITWORLD;
  71         return SHOTTYPE_HITENEMY;
  72 }
  73
  74 float TrueAimCheck(entity wepent)
  75 {
  76         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
  77                 return SHOTTYPE_HITWORLD;
  78
  79         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  80         vector vecs, trueaimpoint, w_shotorg;
  81         vector mi, ma, dv;
  82         float shottype;
  83         entity ta;
  84         float mv;
  85
  86         mi = ma = '0 0 0';
  87         ta = trueaim;
  88         mv = MOVE_NOMONSTERS;
  89
  90         switch(wepent.activeweapon) // WEAPONTODO
  91         {
  92                 case WEP_VORTEX:
  93                 case WEP_OVERKILL_NEX:
  94                 case WEP_VAPORIZER:
  95                         mv = MOVE_NORMAL;
  96                         break;
  97                 case WEP_RIFLE:
  98                         ta = trueaim_rifle;
  99                         mv = MOVE_NORMAL;
 100                         if(zoomscript_caught)
 101                         {
 102                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 103                                 return EnemyHitCheck();
 104                         }
 105                         break;
 106                 case WEP_DEVASTATOR: // projectile has a size!
 107                         mi = '-3 -3 -3';
 108                         ma = '3 3 3';
 109                         break;
 110                 case WEP_FIREBALL: // projectile has a size!
 111                         mi = '-16 -16 -16';
 112                         ma = '16 16 16';
 113                         break;
 114                 case WEP_SEEKER: // projectile has a size!
 115                         mi = '-2 -2 -2';
 116                         ma = '2 2 2';
 117                         break;
 118                 case WEP_ELECTRO: // projectile has a size!
 119                         mi = '0 0 -3';
 120                         ma = '0 0 -3';
 121                         break;
 122         }
 123
 124         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 125
 126         vecs = decompressShotOrigin(STAT(SHOTORG));
 127
 128         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 129         trueaimpoint = trace_endpos;
 130         // move trueaimpoint a little bit forward to make the final tracebox reliable
 131         // since it sometimes doesn't reach a teammate by a hair
 132         trueaimpoint += view_forward;
 133
 134         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 135                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 136
 137         if(vecs.x > 0)
 138                 vecs.y = -vecs.y;
 139         else
 140                 vecs = '0 0 0';
 141
 142         dv = view_right * vecs.y + view_up * vecs.z;
 143         w_shotorg = traceorigin + dv;
 144
 145         // now move the vecs forward as much as requested if possible
 146         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 147         w_shotorg = trace_endpos - view_forward * nudge;
 148
 149         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 150         shottype = EnemyHitCheck();
 151         if(shottype != SHOTTYPE_HITWORLD)
 152                 return shottype;
 153
 154 #if 0
 155         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 156         // or rather, I know why, but see no fix
 157         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 158                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 159                 return SHOTTYPE_HITOBSTRUCTION;
 160 #endif
 161
 162         return SHOTTYPE_HITWORLD;
 163 }
 164
 165 void HUD_Crosshair_Vehicle(entity this)
 166 {
 167         if(hud != HUD_BUMBLEBEE_GUN)
 168         {
 169                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 170                 info.vr_crosshair(info, this);
 171         }
 172 }
 173
 174 vector crosshair_getcolor(entity this, float health_stat)
 175 {
 176         static float rainbow_last_flicker;
 177         static vector rainbow_prev_color;
 178         vector wcross_color = '0 0 0';
 179         switch(autocvar_crosshair_color_special)
 180         {
 181                 case 1: // weapon color
 182                 {
 183                         if(this != WEP_Null && hud == HUD_NORMAL)
 184                         {
 185                                 wcross_color = this.wpcolor;
 186                                 break;
 187                         }
 188                         else { goto normalcolor; }
 189                 }
 190
 191                 case 2: // color based on health and armor
 192                 {
 193                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 194                         float health_and_armor = floor(v.x + 1);
 195                         wcross_color = HUD_Get_Num_Color(health_and_armor, 200, false);
 196                         break;
 197                 }
 198
 199                 case 3: // rainbow/random color
 200                 {
 201                         if(time >= rainbow_last_flicker)
 202                         {
 203                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 204                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 205                         }
 206                         wcross_color = rainbow_prev_color;
 207                         break;
 208                 }
 209 LABEL(normalcolor)
 210                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 211         }
 212
 213         return wcross_color;
 214 }
 215
 216 void HUD_Crosshair(entity this)
 217 {
 218         // reset player's alpha here upon death since forced scoreboard prevents running the crosshair_chase code
 219         if(autocvar_chase_active > 0 && autocvar_crosshair_chase && STAT(HEALTH) <= 0 && csqcplayer)
 220                 csqcplayer.alpha = csqcplayer.m_alpha;
 221
 222         float f, i, j;
 223         vector v;
 224         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) && !autocvar_cl_lockview
 225                 && spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair)
 226                 && !HUD_MinigameMenu_IsOpened())
 227         {
 228                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 229                         return;
 230
 231                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 232                         return;
 233
 234                 if (hud != HUD_NORMAL)
 235                 {
 236                         HUD_Crosshair_Vehicle(this);
 237                         return;
 238                 }
 239
 240                 string wcross_style;
 241                 float wcross_alpha, wcross_resolution;
 242                 wcross_style = autocvar_crosshair;
 243                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 244                         wcross_style = autocvar_crosshair_2d;
 245                 if (wcross_style == "0")
 246                         return;
 247                 wcross_resolution = autocvar_crosshair_size;
 248                 if (wcross_resolution == 0)
 249                         return;
 250                 wcross_alpha = autocvar_crosshair_alpha;
 251                 if (wcross_alpha == 0)
 252                         return;
 253
 254                 // TrueAim check
 255                 float shottype;
 256
 257                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 258                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 259                         wcross_origin = viewloc_mousepos;
 260                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 261                 {
 262                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 263                         if(csqcplayer && autocvar_crosshair_chase_playeralpha && autocvar_crosshair_chase_playeralpha < 1)
 264                         {
 265                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 266                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 267                                 if(trace_ent == csqcplayer)
 268                                         csqcplayer.alpha = min(autocvar_crosshair_chase_playeralpha, myalpha);
 269                                 else
 270                                         csqcplayer.alpha = csqcplayer.m_alpha;
 271                         }
 272                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 273                         wcross_origin = project_3d_to_2d(trace_endpos);
 274                 }
 275                 else
 276                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 277                 wcross_origin.z = 0;
 278                 if(autocvar_crosshair_hittest)
 279                 {
 280                         vector wcross_oldorigin;
 281                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 282                         wcross_oldorigin = wcross_origin;
 283                         shottype = TrueAimCheck(thiswep);
 284                         if(shottype == SHOTTYPE_HITWORLD)
 285                         {
 286                                 v = wcross_origin - wcross_oldorigin;
 287                                 v.x /= vid_conwidth;
 288                                 v.y /= vid_conheight;
 289                                 if(vdist(v, >, 0.01))
 290                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 291                         }
 292                         if(!autocvar_crosshair_hittest_showimpact)
 293                                 wcross_origin = wcross_oldorigin;
 294                 }
 295                 else
 296                         shottype = SHOTTYPE_HITWORLD;
 297
 298                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 299                 string wcross_name = "";
 300                 float wcross_scale, wcross_blur;
 301
 302                 entity e = WEP_Null;
 303                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 304                 {
 305                         entity wepent = viewmodels[0]; // TODO: unhardcode
 306                         e = wepent.switchingweapon;
 307                         if(e)
 308                         {
 309                                 if(autocvar_crosshair_per_weapon)
 310                                 {
 311                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 312                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 313                                         //if (wcross_resolution == 0)
 314                                                 //return;
 315
 316                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 317                                         wcross_resolution *= e.w_crosshair_size;
 318                                         wcross_name = e.w_crosshair;
 319                                 }
 320                         }
 321                 }
 322
 323                 if(wcross_name == "")
 324                         wcross_name = strcat("gfx/crosshair", wcross_style);
 325
 326                 // MAIN CROSSHAIR COLOR DECISION
 327                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
 328
 329                 if(autocvar_crosshair_effect_scalefade)
 330                 {
 331                         wcross_scale = wcross_resolution;
 332                         wcross_resolution = 1;
 333                 }
 334                 else
 335                 {
 336                         wcross_scale = 1;
 337                 }
 338
 339                 if(autocvar_crosshair_pickup)
 340                 {
 341                         float stat_pickup_time = STAT(LAST_PICKUP);
 342
 343                         if(pickup_crosshair_time < stat_pickup_time)
 344                         {
 345                                 if(time - stat_pickup_time < 5) // don't trigger the animation if it's too old
 346                                         pickup_crosshair_size = 1;
 347
 348                                 pickup_crosshair_time = stat_pickup_time;
 349                         }
 350
 351                         if(pickup_crosshair_size > 0)
 352                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 353                         else
 354                                 pickup_crosshair_size = 0;
 355
 356                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 357                 }
 358
 359                 // todo: make crosshair hit indication dependent on damage dealt
 360                 if(autocvar_crosshair_hitindication)
 361                 {
 362                         vector col = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 363
 364                         if(unaccounted_damage)
 365                         {
 366                                 hitindication_crosshair_size = 1;
 367                         }
 368
 369                         if(hitindication_crosshair_size > 0)
 370                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 371                         else
 372                                 hitindication_crosshair_size = 0;
 373
 374                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 375                         wcross_color.x += sin(hitindication_crosshair_size) * col.x;
 376                         wcross_color.y += sin(hitindication_crosshair_size) * col.y;
 377                         wcross_color.z += sin(hitindication_crosshair_size) * col.z;
 378                 }
 379
 380                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
 381                 // just show for teammates to give a sign that they're an invalid target
 382                 //if(shottype == SHOTTYPE_HITENEMY)
 383                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 384                 if(shottype == SHOTTYPE_HITTEAM)
 385                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 386
 387                 f = fabs(autocvar_crosshair_effect_time);
 388                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 389                 {
 390                         wcross_changedonetime = time + f;
 391                 }
 392                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 393                 {
 394                         wcross_name_changestarttime = time;
 395                         wcross_name_changedonetime = time + f;
 396                         if(wcross_name_goal_prev_prev)
 397                                 strunzone(wcross_name_goal_prev_prev);
 398                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 399                         wcross_name_goal_prev = strzone(wcross_name);
 400                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 401                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 402                         wcross_resolution_goal_prev = wcross_resolution;
 403                 }
 404
 405                 wcross_scale_goal_prev = wcross_scale;
 406                 wcross_alpha_goal_prev = wcross_alpha;
 407                 wcross_color_goal_prev = wcross_color;
 408
 409                 if((shottype == SHOTTYPE_HITTEAM && autocvar_crosshair_hittest_blur_teammate)
 410                         || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur_wall && !autocvar_chase_active))
 411                 {
 412                         wcross_blur = 1;
 413                         wcross_alpha *= 0.75;
 414                 }
 415                 else
 416                         wcross_blur = 0;
 417                 // *_prev is at time-frametime
 418                 // * is at wcross_changedonetime+f
 419                 // what do we have at time?
 420                 if(time < wcross_changedonetime)
 421                 {
 422                         f = frametime / (wcross_changedonetime - time + frametime);
 423                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 424                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 425                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 426                 }
 427
 428                 wcross_scale_prev = wcross_scale;
 429                 wcross_alpha_prev = wcross_alpha;
 430                 wcross_color_prev = wcross_color;
 431
 432                 MUTATOR_CALLHOOK(UpdateCrosshair);
 433
 434                 wcross_scale *= 1 - autocvar__menu_alpha;
 435                 wcross_alpha *= 1 - autocvar__menu_alpha;
 436                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 437
 438                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 439                 {
 440                         // crosshair rings for weapon stats
 441                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 442                         {
 443                                 // declarations and stats
 444                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 445                                 string ring_image = string_null, ring_inner_image = string_null;
 446                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 447
 448                                 ring_scale = autocvar_crosshair_ring_size;
 449
 450                                 entity wepent = viewmodels[0]; // TODO: unhardcode
 451
 452                                 int weapon_clipload = wepent.clip_load;
 453                                 int weapon_clipsize = wepent.clip_size;
 454
 455                                 float arc_heat = wepent.arc_heat_percent;
 456
 457                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 458                                         vortex_charge_movingavg = wepent.vortex_charge;
 459
 460                                 float charge = 0;
 461                                 float chargepool = 0;
 462                                 bool ring_vortex_enabled = false;
 463                                 if (autocvar_crosshair_ring && autocvar_crosshair_ring_vortex)
 464                                 {
 465                                         if (wepent.activeweapon == WEP_VORTEX)
 466                                         {
 467                                                 charge = wepent.vortex_charge;
 468                                                 chargepool = wepent.vortex_chargepool_ammo;
 469                                         }
 470                                         else if (wepent.activeweapon == WEP_OVERKILL_NEX)
 471                                         {
 472                                                 charge = wepent.oknex_charge;
 473                                                 chargepool = wepent.oknex_chargepool_ammo;
 474                                         }
 475                                         if (charge)
 476                                                 ring_vortex_enabled = true;
 477                                 }
 478
 479                                 if (ring_vortex_enabled)
 480                                 {
 481                                         if (chargepool || use_vortex_chargepool) {
 482                                                 use_vortex_chargepool = 1;
 483                                                 ring_inner_value = chargepool;
 484                                         } else {
 485                                                 float rate = autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate;
 486                                                 vortex_charge_movingavg = (1 - rate) * vortex_charge_movingavg + rate * charge;
 487                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (charge - vortex_charge_movingavg), 1);
 488                                         }
 489
 490                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 491                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
 492                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 493
 494                                         // draw the outer ring to show the current charge of the weapon
 495                                         ring_value = charge;
 496                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 497                                         ring_rgb = wcross_color;
 498                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 499                                 }
 500                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
 501                                 {
 502                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1);
 503                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 504                                         ring_rgb = wcross_color;
 505                                         ring_image = "gfx/crosshair_ring.tga";
 506                                 }
 507                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
 508                                 {
 509                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
 510                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 511                                         ring_rgb = wcross_color;
 512                                         ring_image = "gfx/crosshair_ring.tga";
 513                                 }
 514                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 515                                 {
 516                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 517                                         ring_scale = autocvar_crosshair_ring_reload_size;
 518                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 519                                         ring_rgb = wcross_color;
 520
 521                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 522                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 523                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 524                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 525                                         else
 526                                                 ring_image = "gfx/crosshair_ring.tga";
 527                                 }
 528                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
 529                                 {
 530                                         ring_value = arc_heat;
 531                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 532                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 533                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 534                                         ring_image = "gfx/crosshair_ring.tga";
 535                                 }
 536
 537                                 // if in weapon switch animation, fade ring out/in
 538                                 if(autocvar_crosshair_effect_time > 0)
 539                                 {
 540                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 541                                         if (f >= 1)
 542                                         {
 543                                                 wcross_ring_prev = ((ring_image) ? true : false);
 544                                         }
 545
 546                                         if(wcross_ring_prev)
 547                                         {
 548                                                 if(f < 1)
 549                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 550                                         }
 551                                         else
 552                                         {
 553                                                 if(f < 1)
 554                                                         ring_alpha *= bound(0, f, 1);
 555                                         }
 556                                 }
 557
 558                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 559                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 560
 561                                 if (ring_value)
 562                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * wcross_resolution * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 563                         }
 564
 565 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 566                         MACRO_BEGIN \
 567                                 vector scaled_sz = sz * wcross_size; \
 568                                 if(wcross_blur > 0) \
 569                                 { \
 570                                         for(i = -2; i <= 2; ++i) \
 571                                         for(j = -2; j <= 2; ++j) \
 572                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
 573                                 } \
 574                                 else \
 575                                 { \
 576                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
 577                                 } \
 578                         MACRO_END
 579
 580 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
 581                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 582
 583 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 584                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 585
 586                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 587                         {
 588                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 589                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 590                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 591                                 f = 1 - f;
 592                         }
 593                         else
 594                         {
 595                                 f = 1;
 596                         }
 597                         wcross_name_alpha_goal_prev = f;
 598
 599                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 600                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 601
 602                         if(autocvar_crosshair_dot)
 603                         {
 604                                 vector wcross_color_old;
 605                                 wcross_color_old = wcross_color;
 606
 607                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 608                                         wcross_color = stov(autocvar_crosshair_dot_color);
 609
 610                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 611                                 // FIXME why don't we use wcross_alpha here?
 612                                 wcross_color = wcross_color_old;
 613                         }
 614                 }
 615         }
 616         else
 617         {
 618                 wcross_scale_prev = 0;
 619                 wcross_alpha_prev = 0;
 620                 wcross_scale_goal_prev = 0;
 621                 wcross_alpha_goal_prev = 0;
 622                 wcross_changedonetime = 0;
 623                 strfree(wcross_name_goal_prev);
 624                 strfree(wcross_name_goal_prev_prev);
 625                 wcross_name_changestarttime = 0;
 626                 wcross_name_changedonetime = 0;
 627                 wcross_name_alpha_goal_prev = 0;
 628                 wcross_name_alpha_goal_prev_prev = 0;
 629                 wcross_resolution_goal_prev = 0;
 630                 wcross_resolution_goal_prev_prev = 0;
 631         }
 632 }
 633
 634 void DrawReticle(entity this)
 635 {
 636         if(!autocvar_cl_reticle || MUTATOR_CALLHOOK(DrawReticle))
 637         {
 638                 reticle_type = 0;
 639                 return;
 640         }
 641
 642         float is_dead = (STAT(HEALTH) <= 0);
 643         string reticle_image = string_null;
 644         bool wep_zoomed = false;
 645         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 646         {
 647                 entity wepe = viewmodels[slot];
 648                 Weapon wep = wepe.activeweapon;
 649                 if(wep != WEP_Null && wep.wr_zoom)
 650                 {
 651                         bool do_zoom = wep.wr_zoom(wep, NULL);
 652                         if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
 653                                 reticle_image = wep.w_reticle;
 654                         wep_zoomed += do_zoom;
 655                 }
 656         }
 657         // Draw the aiming reticle for weapons that use it
 658         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 659         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 660         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 661         if(spectatee_status || is_dead || hud != HUD_NORMAL || this.viewloc)
 662         {
 663                 // no zoom reticle while dead
 664                 reticle_type = 0;
 665         }
 666         else if(wep_zoomed && autocvar_cl_reticle_weapon)
 667         {
 668                 if(reticle_image) { reticle_type = 2; }
 669                 else { reticle_type = 0; }
 670         }
 671         else if(button_zoom || zoomscript_caught)
 672         {
 673                 // normal zoom
 674                 reticle_type = 1;
 675         }
 676
 677         if(reticle_type)
 678         {
 679                 vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 680                 if(autocvar_cl_reticle_stretch)
 681                 {
 682                         reticle_size.x = vid_conwidth;
 683                         reticle_size.y = vid_conheight;
 684                         reticle_pos.x = 0;
 685                         reticle_pos.y = 0;
 686                 }
 687                 else
 688                 {
 689                         reticle_size.x = max(vid_conwidth, vid_conheight);
 690                         reticle_size.y = max(vid_conwidth, vid_conheight);
 691                         reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
 692                         reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
 693                 }
 694
 695                 float f = (zoomscript_caught) ? 1 : current_zoomfraction;
 696
 697                 if(f)
 698                 {
 699                         switch(reticle_type)
 700                         {
 701                                 case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 702                                 case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 703                         }
 704                 }
 705         }
 706 }