qcsrc/client/gibs.qc

   1 .float silent;
   2
   3 void Gib_Delete()
   4 {
   5         remove(self);
   6 }
   7
   8 string species_prefix(float specnum)
   9 {
  10         switch(specnum)
  11         {
  12                 case SPECIES_HUMAN:       return "";
  13                 case SPECIES_ALIEN:       return "alien_";
  14                 case SPECIES_ROBOT_SHINY: return "robot_";
  15                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  16                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
  17                 case SPECIES_ANIMAL:      return "animal_";
  18                 case SPECIES_RESERVED:    return "reserved_";
  19                 default:         return "";
  20         }
  21 }
  22
  23 void Gib_setmodel(entity gib, string mdlname, float specnum)
  24 {
  25         switch(specnum)
  26         {
  27                 case SPECIES_ROBOT_RUSTY:
  28                 case SPECIES_ROBOT_SHINY:
  29                 case SPECIES_ROBOT_SOLID:
  30                         if(specnum != SPECIES_ROBOT_SOLID || mdlname == "models/gibs/chunk.mdl")
  31                         {
  32                                 if(mdlname == "models/gibs/bloodyskull.md3")
  33                                         setmodel(gib, "models/gibs/robo.md3");
  34                                 else
  35                                         setmodel(gib, strcat("models/gibs/robo", ftos(floor(random() * 8) + 1), ".md3"));
  36                                 if(specnum == SPECIES_ROBOT_SHINY)
  37                                 {
  38                                         gib.skin = 1;
  39                                         gib.colormod = '2 2 2';
  40                                 }
  41                                 gib.scale = 1;
  42                                 break;
  43                         }
  44                 default:
  45                         setmodel(gib, mdlname);
  46                         gib.skin = specnum;
  47                         break;
  48         }
  49 }
  50
  51 void new_te_bloodshower (float ef, vector org, float explosionspeed, float howmany)
  52 {
  53         float i, pmod;
  54         pmod = autocvar_cl_particles_quality;
  55         for (i = 0; i < 250 * pmod; ++i)
  56                 pointparticles(ef, org, randomvec() * explosionspeed, howmany / 250);
  57 }
  58
  59 void SUB_RemoveOnNoImpact()
  60 {
  61         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  62                 Gib_Delete();
  63 }
  64
  65 void Gib_Touch()
  66 {
  67         // TODO maybe bounce of walls, make more gibs, etc.
  68
  69         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  70         {
  71                 Gib_Delete();
  72                 return;
  73         }
  74
  75         if(!self.silent)
  76                 sound(self, CHAN_PAIN, strcat("misc/gib_splat0", ftos(floor(prandom() * 4 + 1)), ".wav"), VOL_BASE, ATTN_NORM);
  77         pointparticles(particleeffectnum(strcat(species_prefix(self.cnt), "blood")), self.origin + '0 0 1', '0 0 30', 10);
  78
  79         Gib_Delete();
  80 }
  81
  82 void Gib_Draw()
  83 {
  84         vector oldorg;
  85         oldorg = self.origin;
  86
  87         Movetype_Physics_MatchTicrate(autocvar_cl_gibs_ticrate, autocvar_cl_gibs_sloppy);
  88         if(wasfreed(self))
  89                 return;
  90
  91         if(self.touch == Gib_Touch) // don't do this for the "chunk" thingie...
  92                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_SLIGHTBLOOD")), oldorg, self.origin);
  93         else
  94                 trailparticles(self, particleeffectnum(strcat(species_prefix(self.cnt), "TR_BLOOD")), oldorg, self.origin);
  95
  96         self.renderflags = 0;
  97         self.alpha = bound(0, self.nextthink - time, 1);
  98
  99         if(self.alpha < ALPHA_MIN_VISIBLE)
 100         {
 101                 self.drawmask = 0;
 102                 Gib_Delete();
 103         }
 104 }
 105
 106 void TossGib (string mdlname, vector org, vector vconst, vector vrand, float specnum, float destroyontouch, float issilent)
 107 {
 108         entity gib;
 109
 110         // TODO remove some gibs according to cl_nogibs
 111         gib = RubbleNew("gib");
 112         gib.move_movetype = MOVETYPE_BOUNCE;
 113         gib.gravity = 1;
 114         gib.solid = SOLID_CORPSE;
 115         gib.cnt = specnum;
 116         gib.silent = issilent;
 117         Gib_setmodel(gib, mdlname, specnum);
 118
 119         setsize (gib, '-8 -8 -8', '8 8 8');
 120
 121         gib.draw = Gib_Draw;
 122         if(destroyontouch)
 123                 gib.move_touch = Gib_Touch;
 124         else
 125                 gib.move_touch = SUB_RemoveOnNoImpact;
 126
 127         gib.move_origin = gib.origin = org;
 128         gib.move_velocity = vconst * autocvar_cl_gibs_velocity_scale + vrand * autocvar_cl_gibs_velocity_random + '0 0 1' * autocvar_cl_gibs_velocity_up;
 129         gib.move_avelocity = prandomvec() * vlen(gib.move_velocity);
 130         gib.move_time = time;
 131         gib.damageforcescale = autocvar_cl_gibs_damageforcescale;
 132
 133         gib.nextthink = time + autocvar_cl_gibs_lifetime * (1 + prandom() * 0.15);
 134         gib.drawmask = MASK_NORMAL;
 135
 136         RubbleLimit("gib", autocvar_cl_gibs_maxcount, Gib_Delete);
 137 }
 138
 139 void Ent_GibSplash(float isNew)
 140 {
 141         float amount, type, specnum;
 142         vector org, vel;
 143         string specstr;
 144         float issilent;
 145         string gentle_prefix;
 146
 147         float c, randomvalue;
 148
 149         type = ReadByte(); // gibbage type
 150         amount = ReadByte() / 16.0; // gibbage amount
 151         org_x = ReadShort() * 4 + 2;
 152         org_y = ReadShort() * 4 + 2;
 153         org_z = ReadShort() * 4 + 2;
 154         vel = decompressShortVector(ReadShort());
 155
 156         float cl_gentle_gibs = autocvar_cl_gentle_gibs;
 157         if(cl_gentle_gibs || autocvar_cl_gentle)
 158                 type |= 0x80; // set gentle bit
 159
 160         if(type & 0x80)
 161         {
 162                 if(cl_gentle_gibs == 2)
 163                         gentle_prefix = "";
 164                 else if(cl_gentle_gibs == 3)
 165                         gentle_prefix = "happy_";
 166                 else
 167                         gentle_prefix = "morphed_";
 168         }
 169         else if(autocvar_cl_particlegibs)
 170         {
 171                 type |= 0x80;
 172                 gentle_prefix = "particlegibs_";
 173         }
 174
 175         if not(cl_gentle_gibs || autocvar_cl_gentle)
 176                 amount *= 1 - autocvar_cl_nogibs;
 177
 178         if(autocvar_ekg)
 179                 amount *= 5;
 180
 181         if(amount <= 0 || !isNew)
 182                 return;
 183
 184         self.origin = org; // for the sounds
 185
 186         specnum = (type & 0x78) / 8; // blood/gibmodel type: using four bits (0..7, bit indexes 3,4,5)
 187         issilent = (type & 0x40);
 188         type = type & 0x87; // remove the species bits: bit 7 = gentle, bit 0,1,2 = kind of gib
 189         specstr = species_prefix(specnum);
 190
 191         switch(type)
 192         {
 193                 case 0x01:
 194                         if(!issilent)
 195                                 sound (self, CHAN_PAIN, "misc/gib.wav", VOL_BASE, ATTN_NORM);
 196
 197                         if(prandom() < amount)
 198                                 TossGib ("models/gibs/eye.md3", org, vel, prandomvec() * 150, specnum, 0, issilent);
 199                         new_te_bloodshower(particleeffectnum(strcat(specstr, "bloodshower")), org, 1200, amount);
 200                         if(prandom() < amount)
 201                                 TossGib ("models/gibs/bloodyskull.md3", org + 16 * prandomvec(), vel, prandomvec() * 100, specnum, 0, issilent);
 202
 203                         for(c = 0; c < amount; ++c)
 204                         {
 205                                 randomvalue = amount - c;
 206
 207                                 if(prandom() < randomvalue)
 208                                         TossGib ("models/gibs/arm.md3", org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 209                                 if(prandom() < randomvalue)
 210                                         TossGib ("models/gibs/arm.md3", org + 16 * prandomvec() + '0 0 8', vel, prandomvec() * (prandom() * 120 + 90), specnum,0, issilent);
 211                                 if(prandom() < randomvalue)
 212                                         TossGib ("models/gibs/chest.md3", org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 213                                 if(prandom() < randomvalue)
 214                                         TossGib ("models/gibs/smallchest.md3", org + 16 * prandomvec(), vel, prandomvec() * (prandom() * 120 + 80), specnum,0, issilent);
 215                                 if(prandom() < randomvalue)
 216                                         TossGib ("models/gibs/leg1.md3", org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 217                                 if(prandom() < randomvalue)
 218                                         TossGib ("models/gibs/leg2.md3", org + 16 * prandomvec() + '0 0 -5', vel, prandomvec() * (prandom() * 120 + 85), specnum,0, issilent);
 219
 220                                 // these splat on impact
 221                                 if(prandom() < randomvalue)
 222                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 223                                 if(prandom() < randomvalue)
 224                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 225                                 if(prandom() < randomvalue)
 226                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 227                                 if(prandom() < randomvalue)
 228                                         TossGib ("models/gibs/chunk.mdl", org + 16 * prandomvec(), vel, prandomvec() * 450, specnum,1, issilent);
 229                         }
 230                         break;
 231                 case 0x02:
 232                         pointparticles(particleeffectnum(strcat(specstr, "blood")), org, vel, amount * 16);
 233                         break;
 234                 case 0x03:
 235                         if(prandom() < amount)
 236                                 TossGib ("models/gibs/chunk.mdl", org, vel, prandomvec() * (prandom() * 30 + 20), specnum, 1, issilent); // TODO maybe adjust to more randomization?
 237                         break;
 238                 case 0x81:
 239                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_dissolve")), org, vel, amount);
 240                         break;
 241                 case 0x82:
 242                         pointparticles(particleeffectnum(strcat(gentle_prefix, "damage_hit")), org, vel, amount * 16);
 243                         break;
 244                 case 0x83:
 245                         // no gibs in gentle mode, sorry
 246                         break;
 247         }
 248 }
 249
 250 void GibSplash_Precache()
 251 {
 252         precache_model("models/gibs/chunk.mdl");
 253         precache_model("models/gibs/leg1.md3");
 254         precache_model("models/gibs/leg2.md3");
 255         precache_model("models/gibs/chest.md3");
 256         precache_model("models/gibs/smallchest.md3");
 257         precache_model("models/gibs/arm.md3");
 258         precache_model("models/gibs/bloodyskull.md3");
 259         precache_model("models/gibs/eye.md3");
 260
 261         precache_model("models/gibs/robo.md3");
 262         precache_model("models/gibs/robo1.md3");
 263         precache_model("models/gibs/robo2.md3");
 264         precache_model("models/gibs/robo3.md3");
 265         precache_model("models/gibs/robo4.md3");
 266         precache_model("models/gibs/robo5.md3");
 267         precache_model("models/gibs/robo6.md3");
 268         precache_model("models/gibs/robo7.md3");
 269         precache_model("models/gibs/robo8.md3");
 270
 271         precache_sound ("misc/gib.wav");
 272     precache_sound ("misc/gib_splat01.wav");
 273     precache_sound ("misc/gib_splat02.wav");
 274     precache_sound ("misc/gib_splat03.wav");
 275     precache_sound ("misc/gib_splat04.wav");
 276 }