qcsrc/client/damage.qc

   1 void Ent_DamageInfo(float isNew)
   2 {
   3         float dmg, rad, edge, thisdmg, forcemul;
   4         vector force, thisforce;
   5         entity oldself;
   6
   7         oldself = self;
   8
   9         w_deathtype = ReadShort();
  10         w_issilent = (w_deathtype & 0x8000);
  11         w_deathtype = (w_deathtype & 0x7FFF);
  12
  13         w_org_x = ReadCoord();
  14         w_org_y = ReadCoord();
  15         w_org_z = ReadCoord();
  16
  17         dmg = ReadByte();
  18         rad = ReadByte();
  19         edge = ReadByte();
  20         force = decompressShortVector(ReadShort());
  21
  22         if not(isNew)
  23                 return;
  24
  25         if(rad < 0)
  26         {
  27                 rad = -rad;
  28                 forcemul = -1;
  29         }
  30         else
  31                 forcemul = 1;
  32
  33         for(self = findradius(w_org, rad + MAX_DAMAGEEXTRARADIUS); self; self = self.chain)
  34         {
  35                 vector nearest = NearestPointOnBox(self, w_org);
  36                 if(rad)
  37                 {
  38                         thisdmg = ((vlen (nearest - w_org) - bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
  39                         if(thisdmg >= 1)
  40                                 continue;
  41                         if(dmg)
  42                         {
  43                                 thisdmg = dmg + (edge - dmg) * thisdmg;
  44                                 thisforce = forcemul * vlen(force) * (thisdmg / dmg) * normalize(self.origin - w_org);
  45                         }
  46                         else
  47                         {
  48                                 thisdmg = 0;
  49                                 thisforce = forcemul * vlen(force) * normalize(self.origin - w_org);
  50                         }
  51                 }
  52                 else
  53                 {
  54                         if(vlen(nearest - w_org) > bound(MIN_DAMAGEEXTRARADIUS, self.damageextraradius, MAX_DAMAGEEXTRARADIUS))
  55                                 continue;
  56
  57                         thisdmg = dmg;
  58                         thisforce = forcemul * force;
  59                 }
  60
  61                 if(self.damageforcescale)
  62                         if(vlen(thisforce))
  63                         {
  64                                 self.move_velocity = self.move_velocity + damage_explosion_calcpush(self.damageforcescale * thisforce, self.move_velocity, autocvar_g_balance_damagepush_speedfactor);
  65                                 self.move_flags &~= FL_ONGROUND;
  66                         }
  67
  68                 if(w_issilent)
  69                         self.silent = 1;
  70
  71                 if(self.event_damage)
  72                         self.event_damage(thisdmg, w_deathtype, w_org, thisforce);
  73         }
  74
  75         self = oldself;
  76
  77         if(DEATH_ISVEHICLE(w_deathtype))
  78         {
  79             traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
  80             if(trace_plane_normal != '0 0 0')
  81             w_backoff = trace_plane_normal;
  82         else
  83             w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
  84
  85             setorigin(self, w_org + w_backoff * 2); // for sound() calls
  86
  87             switch(w_deathtype)
  88             {
  89             case DEATH_VHCRUSH:
  90                 break;
  91
  92             case DEATH_SBMINIGUN:
  93                 string _snd;
  94                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
  95                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
  96                 pointparticles(particleeffectnum("spiderbot_minigun_impact"), self.origin, w_backoff * 1000, 1);
  97                 break;
  98             case DEATH_SBROCKET:
  99                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 100                 pointparticles(particleeffectnum("spiderbot_rocket_explode"), self.origin, w_backoff * 1000, 1);
 101                 break;
 102             case DEATH_SBBLOWUP:
 103                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 104                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 105                 break;
 106
 107             case DEATH_WAKIGUN:
 108                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 109                 pointparticles(particleeffectnum("wakizashi_gun_impact"), self.origin, w_backoff * 1000, 1);
 110                 break;
 111             case DEATH_WAKIROCKET:
 112                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 113                 pointparticles(particleeffectnum("wakizashi_rocket_explode"), self.origin, w_backoff * 1000, 1);
 114                 break;
 115             case DEATH_WAKIBLOWUP:
 116                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 117                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 118                 break;
 119
 120             case DEATH_RAPTOR_CANNON:
 121                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 122                 pointparticles(particleeffectnum("raptor_cannon_impact"), self.origin, w_backoff * 1000, 1);
 123                 break;
 124             case DEATH_RAPTOR_BOMB_SPLIT:
 125                 float i;
 126                 vector ang, vel;
 127                 for(i = 1; i < 4; ++i)
 128                 {
 129                     vel = normalize(w_org - (w_org + normalize(force) * 16)) + randomvec() * 128;
 130                     ang = vectoangles(vel);
 131                     RaptorCBShellfragToss(w_org, vel, ang + '0 0 1' * (120 * i));
 132                 }
 133
 134
 135                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 136                 pointparticles(particleeffectnum("raptor_bomb_spread"), self.origin, w_backoff * 1000, 1);
 137                 break;
 138             case DEATH_RAPTOR_BOMB:
 139                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 140                 pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, w_backoff * 1000, 1);
 141                 break;
 142             case DEATH_RAPTOR_DEATH:
 143                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_MIN);
 144                 pointparticles(particleeffectnum("explosion_big"), self.origin, w_backoff * 1000, 1);
 145                 break;
 146             }
 147         }
 148
 149
 150         if(DEATH_ISTURRET(w_deathtype))
 151         {
 152             string _snd;
 153             traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
 154             if(trace_plane_normal != '0 0 0')
 155             w_backoff = trace_plane_normal;
 156         else
 157             w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
 158
 159             setorigin(self, w_org + w_backoff * 2); // for sound() calls
 160
 161             switch(w_deathtype)
 162             {
 163              case DEATH_TURRET_EWHEEL:
 164                 sound(self, CH_SHOTS, "weapons/laserimpact.wav", VOL_BASE, ATTN_MIN);
 165                 pointparticles(particleeffectnum("laser_impact"), self.origin, w_backoff * 1000, 1);
 166                 break;
 167
 168              case DEATH_TURRET_FLAC:
 169                 pointparticles(particleeffectnum("hagar_explode"), w_org, '0 0 0', 1);
 170                 _snd = strcat("weapons/hagexp", ftos(1 + rint(random() * 2)), ".waw");
 171                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
 172                 break;
 173
 174              case DEATH_TURRET_MLRS:
 175              case DEATH_TURRET_HK:
 176              case DEATH_TURRET_WALKER_ROCKET:
 177              case DEATH_TURRET_HELLION:
 178                 sound(self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_MIN);
 179                 pointparticles(particleeffectnum("rocket_explode"), self.origin, w_backoff * 1000, 1);
 180                 break;
 181
 182              case DEATH_TURRET_MACHINEGUN:
 183              case DEATH_TURRET_WALKER_GUN:
 184                 _snd = strcat("weapons/ric", ftos(1 + rint(random() * 2)), ".waw");
 185                 sound(self, CH_SHOTS, _snd, VOL_BASE, ATTN_NORM);
 186                 pointparticles(particleeffectnum("machinegun_impact"), self.origin, w_backoff * 1000, 1);
 187                 break;
 188
 189              case DEATH_TURRET_PLASMA:
 190                 sound(self, CH_SHOTS, "weapons/electro_impact.wav", VOL_BASE, ATTN_MIN);
 191                 pointparticles(particleeffectnum("electro_impact"), self.origin, w_backoff * 1000, 1);
 192                 break;
 193
 194              case DEATH_TURRET_WALKER_MEELE:
 195                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_MIN);
 196                 pointparticles(particleeffectnum("TE_SPARK"), self.origin, w_backoff * 1000, 1);
 197                 break;
 198
 199              case DEATH_TURRET_PHASER:
 200                 break;
 201
 202              case DEATH_TURRET_TESLA:
 203                 te_smallflash(self.origin);
 204                 break;
 205
 206         }
 207         }
 208
 209         // TODO spawn particle effects and sounds based on w_deathtype
 210         if(!DEATH_ISSPECIAL(w_deathtype))
 211         {
 212                 float hitwep;
 213
 214                 hitwep = DEATH_WEAPONOFWEAPONDEATH(w_deathtype);
 215                 w_random = prandom();
 216
 217                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, world);
 218                 if(trace_fraction < 1 && hitwep != WEP_NEX && hitwep != WEP_MINSTANEX)
 219                         w_backoff = trace_plane_normal;
 220                 else
 221                         w_backoff = -1 * normalize(force);
 222                 setorigin(self, w_org + w_backoff * 2); // for sound() calls
 223
 224                 (get_weaponinfo(hitwep)).weapon_func(WR_IMPACTEFFECT);
 225         }
 226 }
 227
 228 void DamageInfo_Precache()
 229 {
 230         float i;
 231         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 232                 (get_weaponinfo(i)).weapon_func(WR_PRECACHE);
 233 }