qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw(float isplayer);
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 void CSQCPlayer_ForceModel_PreUpdate(void)
  96 {
  97         self.model = self.forceplayermodels_savemodel;
  98         self.modelindex = self.forceplayermodels_savemodelindex;
  99         self.skin = self.forceplayermodels_saveskin;
 100         self.colormap = self.forceplayermodels_savecolormap;
 101 }
 102 void CSQCPlayer_ForceModel_PostUpdate(void)
 103 {
 104         self.forceplayermodels_savemodel = self.model;
 105         self.forceplayermodels_savemodelindex = self.modelindex;
 106         self.forceplayermodels_saveskin = self.skin;
 107         self.forceplayermodels_savecolormap = self.colormap;
 108
 109         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 110         {
 111                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 112                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 113                 if(!self.forceplayermodels_isgoodmodel)
 114                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 115         }
 116 }
 117 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 118 {
 119         // which one is ALWAYS good?
 120         if not(forceplayermodels_goodmodel)
 121         {
 122                 entity e;
 123                 e = spawn();
 124                 precache_model(cvar_defstring("_cl_playermodel"));
 125                 setmodel(e, cvar_defstring("_cl_playermodel"));
 126                 forceplayermodels_goodmodel = e.model;
 127                 forceplayermodels_goodmodelindex = e.modelindex;
 128                 remove(e);
 129         }
 130
 131         // first, try finding it from the server
 132         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 133         {
 134                 if(islocalplayer)
 135                 {
 136                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 137                         {
 138                                 // trust server's idea of "own player model"
 139                                 forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 140                                 forceplayermodels_model = self.forceplayermodels_savemodel;
 141                                 forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 142                                 forceplayermodels_skin = self.forceplayermodels_saveskin;
 143                                 forceplayermodels_attempted = 1;
 144                         }
 145                 }
 146         }
 147
 148         // forcemodel finding
 149         if(!forceplayermodels_attempted)
 150         {
 151                 forceplayermodels_attempted = 1;
 152
 153                 // only if this failed, find it out on our own
 154                 entity e;
 155                 e = spawn();
 156                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 157                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 158                 forceplayermodels_model = e.model;
 159                 forceplayermodels_modelindex = e.modelindex;
 160                 forceplayermodels_skin = autocvar__cl_playerskin;
 161                 remove(e);
 162         }
 163
 164         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 165         {
 166                 entity e;
 167                 e = spawn();
 168                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 169                 forceplayermodels_myisgoodmodel = fexists(e.model);
 170                 forceplayermodels_mymodel = e.model;
 171                 forceplayermodels_mymodelindex = e.modelindex;
 172                 remove(e);
 173         }
 174
 175         // apply it
 176         float isfriend;
 177         float cm;
 178         cm = self.forceplayermodels_savecolormap;
 179         cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(self.colormap - 1, "colors")) + 1024);
 180
 181         if(teamplay)
 182                 isfriend = (cm == 1024 + 17 * myteam);
 183         else
 184                 isfriend = islocalplayer;
 185
 186         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 187         {
 188                 self.model = forceplayermodels_mymodel;
 189                 self.modelindex = forceplayermodels_mymodelindex;
 190                 self.skin = autocvar_cl_forcemyplayerskin;
 191         }
 192         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 193         {
 194                 self.model = forceplayermodels_model;
 195                 self.modelindex = forceplayermodels_modelindex;
 196                 self.skin = forceplayermodels_skin;
 197         }
 198         else if(self.forceplayermodels_isgoodmodel)
 199         {
 200                 self.model = self.forceplayermodels_savemodel;
 201                 self.modelindex = self.forceplayermodels_savemodelindex;
 202                 self.skin = self.forceplayermodels_saveskin;
 203         }
 204         else
 205         {
 206                 self.model = forceplayermodels_goodmodel;
 207                 self.modelindex = forceplayermodels_goodmodelindex;
 208                 self.skin = self.forceplayermodels_saveskin;
 209         }
 210
 211         // forceplayercolors too
 212         if(teamplay)
 213         {
 214                 // own team's color is never forced
 215                 float forcecolor_friend = 0;
 216                 float forcecolor_enemy = 0;
 217                 float teams_count = 0;
 218                 entity tm;
 219
 220                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 221                         if(tm.team != NUM_SPECTATOR)
 222                                 ++teams_count;
 223
 224                 if(autocvar_cl_forcemyplayercolors)
 225                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 226                 if(autocvar_cl_forceplayercolors && teams_count == 2)
 227                         forcecolor_enemy = 1024 + autocvar__cl_color;
 228
 229                 if(forcecolor_enemy && !forcecolor_friend)
 230                 {
 231                         // only enemy color is forced?
 232                         // verify it is not equal to the friend color
 233                         if(forcecolor_enemy == 1024 + 17 * myteam)
 234                                 forcecolor_enemy = 0;
 235                 }
 236
 237                 if(forcecolor_friend && !forcecolor_enemy)
 238                 {
 239                         // only friend color is forced?
 240                         // verify it is not equal to the enemy color
 241                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 242                                 // note: we even compare against our own team.
 243                                 // if we rejected because we matched our OWN team color,
 244                                 // this is not bad; we then simply keep our color as is
 245                                 // anyway.
 246                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 247                                         forcecolor_friend = 0;
 248                 }
 249
 250                 if(cm == 1024 + 17 * myteam)
 251                 {
 252                         if(forcecolor_friend)
 253                                 self.colormap = forcecolor_friend;
 254                 }
 255                 else
 256                 {
 257                         if(forcecolor_enemy)
 258                                 self.colormap = forcecolor_enemy;
 259                 }
 260         }
 261         else
 262         {
 263                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 264                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 265                 else if(autocvar_cl_forceplayercolors)
 266                         self.colormap = player_localnum + 1;
 267         }
 268 }
 269
 270 // FEATURE: fallback frames
 271 .float csqcmodel_saveframe;
 272 .float csqcmodel_saveframe2;
 273 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 274 .float csqcmodel_saveframe3;
 275 .float csqcmodel_saveframe4;
 276 #endif
 277 .float csqcmodel_framecount;
 278
 279 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 280 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 281 {
 282         self.frame = self.csqcmodel_saveframe;
 283         self.frame2 = self.csqcmodel_saveframe2;
 284 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 285         self.frame3 = self.csqcmodel_saveframe3;
 286         self.frame4 = self.csqcmodel_saveframe4;
 287 #endif
 288 }
 289 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 290 {
 291         self.csqcmodel_saveframe = self.frame;
 292         self.csqcmodel_saveframe2 = self.frame2;
 293 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 294         self.csqcmodel_saveframe3 = self.frame3;
 295         self.csqcmodel_saveframe4 = self.frame4;
 296 #endif
 297
 298         // hack for death animations: set their frametime to zero in case a
 299         // player "pops in"
 300         if(isnew)
 301         {
 302 #define FIX_FRAMETIME(f,ft) \
 303                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 304                 { \
 305                         self.ft = self.death_time; \
 306                 }
 307                 FIX_FRAMETIME(frame, frame1time)
 308                 FIX_FRAMETIME(frame2, frame2time)
 309 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 310                 FIX_FRAMETIME(frame3, frame3time)
 311                 FIX_FRAMETIME(frame4, frame4time)
 312 #endif
 313         }
 314         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 315 }
 316 void CSQCPlayer_AnimDecide_PostUpdate(float isnew)
 317 {
 318         self.csqcmodel_isdead = !!(self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 319 }
 320 float CSQCPlayer_FallbackFrame(float f)
 321 {
 322         if(frameduration(self.modelindex, f) > 0)
 323                 return f; // goooooood
 324         if(frameduration(self.modelindex, 1) <= 0)
 325                 return f; // this is a static model. We can't fix it if we wanted to
 326         switch(f)
 327         {
 328                 case 23: return 11; // anim_melee -> anim_shoot
 329                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 330                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 331                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 332                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 333                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 334                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 335                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 336         }
 337         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 338         return f;
 339 }
 340 void CSQCPlayer_FallbackFrame_Apply(void)
 341 {
 342         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 343         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 344 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 345         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 346         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 347 #endif
 348 }
 349
 350 // FEATURE: auto tag_index
 351 .entity tag_entity;
 352 .float tag_entity_lastmodelindex;
 353 .float tag_index;
 354 void CSQCModel_AutoTagIndex_Apply(void)
 355 {
 356         if(self.tag_entity && wasfreed(self.tag_entity))
 357                 self.tag_entity = world;
 358
 359         if(self.tag_networkentity)
 360         {
 361                 // we are ATTACHED!
 362                 float changed = 0;
 363                 if(self.tag_entity.entnum != self.tag_networkentity)
 364                 {
 365                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 366                         changed = 1;
 367                 }
 368
 369                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 370                 if(self.tag_entity.classname == "csqcmodel")
 371                 {
 372                         entity oldself = self;
 373                         self = self.tag_entity;
 374                         CSQCModel_Hook_PreDraw((self.entnum >= 1 && self.entnum <= maxclients));
 375                         self = oldself;
 376                 }
 377
 378                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 379                 {
 380                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 381                         changed = 1;
 382                 }
 383                 if(changed)
 384                 {
 385                         if(self.tag_entity)
 386                         {
 387                                 // the best part is: IT EXISTS
 388                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 389                                 {
 390                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 391                                         {
 392                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 393                                                 if(!self.tag_index)
 394                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 395                                                 if(!self.tag_index)
 396                                                 {
 397                                                         // we need to prevent this from 'appening
 398                                                         self.tag_entity = world;
 399                                                         self.drawmask = 0;
 400                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 401                                                 }
 402                                         }
 403                                         else if(self.tag_entity.isplayermodel)
 404                                         {
 405                                                 skeleton_loadinfo(self.tag_entity);
 406                                                 self.tag_index = self.tag_entity.bone_weapon;
 407                                         }
 408                                 }
 409
 410                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 411                                 {
 412                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 413                                         if(!self.tag_index)
 414                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 415                                 }
 416                         }
 417                         else
 418                         {
 419                                 // damn, see you next frame
 420                                 self.drawmask = 0;
 421                         }
 422                 }
 423         }
 424 }
 425
 426 // FEATURE: EF_NODRAW workalike
 427 float EF_BRIGHTFIELD    = 1;
 428 float EF_BRIGHTLIGHT    = 4;
 429 float EF_DIMLIGHT       = 8;
 430 float EF_DOUBLESIDED = 32768;
 431 float EF_NOSELFSHADOW = 65536;
 432 float EF_DYNAMICMODELLIGHT = 131072;
 433 float EF_RESTARTANIM_BIT = 1048576;
 434 float EF_TELEPORT_BIT = 2097152;
 435 float MF_ROCKET  =   1; // leave a trail
 436 float MF_GRENADE =   2; // leave a trail
 437 float MF_GIB     =   4; // leave a trail
 438 float MF_ROTATE  =   8; // rotate (bonus items)
 439 float MF_TRACER  =  16; // green split trail
 440 float MF_ZOMGIB  =  32; // small blood trail
 441 float MF_TRACER2 =  64; // orange split trail
 442 float MF_TRACER3 = 128; // purple trail
 443 .float csqcmodel_effects;
 444 .float csqcmodel_modelflags;
 445 void CSQCModel_Effects_PreUpdate(void)
 446 {
 447         self.effects = self.csqcmodel_effects;
 448         self.modelflags = self.csqcmodel_modelflags;
 449 }
 450 void CSQCModel_Effects_PostUpdate(void)
 451 {
 452         self.csqcmodel_effects = self.effects;
 453         self.csqcmodel_modelflags = self.modelflags;
 454         self.effects = 0;
 455         self.modelflags = 0;
 456         if(self.csqcmodel_teleported)
 457                 Projectile_ResetTrail(self.origin);
 458 }
 459 .float snd_looping;
 460 void CSQCModel_Effects_Apply(void)
 461 {
 462         float eff = self.csqcmodel_effects;
 463         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 464
 465         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 466         self.effects = 0;
 467         self.traileffect = 0;
 468
 469         if(eff & EF_BRIGHTFIELD)
 470                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 471         // ignoring EF_MUZZLEFLASH
 472         if(eff & EF_BRIGHTLIGHT)
 473                 adddynamiclight(self.origin, 400, '3 3 3');
 474         if(eff & EF_DIMLIGHT)
 475                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 476         if((eff & EF_NODRAW) || (self.alpha < 0))
 477                 self.drawmask = 0;
 478         if(eff & EF_ADDITIVE)
 479                 self.renderflags |= RF_ADDITIVE;
 480         if(eff & EF_BLUE)
 481                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 482         if(eff & EF_RED)
 483                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 484         // ignoring EF_NOGUNBOB
 485         if(eff & EF_FULLBRIGHT)
 486                 self.renderflags |= RF_FULLBRIGHT;
 487         if(eff & EF_FLAME)
 488                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 489         if(eff & EF_STARDUST)
 490                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 491         if(eff & EF_NOSHADOW)
 492                 self.renderflags |= RF_NOSHADOW;
 493         if(eff & EF_NODEPTHTEST)
 494                 self.renderflags |= RF_DEPTHHACK;
 495         // ignoring EF_SELECTABLE
 496         if(eff & EF_DOUBLESIDED)
 497                 self.effects |= EF_DOUBLESIDED;
 498         if(eff & EF_NOSELFSHADOW)
 499                 self.effects |= EF_NOSELFSHADOW;
 500         if(eff & EF_DYNAMICMODELLIGHT)
 501                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 502         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 503         if(self.csqcmodel_modelflags & MF_ROCKET)
 504                 self.traileffect = particleeffectnum("TR_ROCKET");
 505         if(self.csqcmodel_modelflags & MF_GRENADE)
 506                 self.traileffect = particleeffectnum("TR_GRENADE");
 507         if(self.csqcmodel_modelflags & MF_GIB)
 508                 self.traileffect = particleeffectnum("TR_BLOOD");
 509         if(self.csqcmodel_modelflags & MF_ROTATE)
 510         {
 511                 self.renderflags |= RF_USEAXIS;
 512                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 513         }
 514         if(self.csqcmodel_modelflags & MF_TRACER)
 515                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 516         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 517                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 518         if(self.csqcmodel_modelflags & MF_TRACER2)
 519                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 520         if(self.csqcmodel_modelflags & MF_TRACER3)
 521                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 522
 523         if(self.drawmask)
 524                 Projectile_DrawTrail(self.origin);
 525         else
 526                 Projectile_ResetTrail(self.origin);
 527
 528         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 529                 self.renderflags |= RF_ADDITIVE;
 530                 // also special in CSQCPlayer_GlowMod_Apply
 531
 532         if(self.csqcmodel_modelflags & MF_ROCKET)
 533         {
 534                 if(!self.snd_looping)
 535                 {
 536                         sound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 537                         self.snd_looping = CH_TRIGGER_SINGLE;
 538                 }
 539         }
 540         else
 541         {
 542                 if(self.snd_looping)
 543                 {
 544                         sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 545                         self.snd_looping = 0;
 546                 }
 547         }
 548 }
 549
 550 void CSQCPlayer_Precache()
 551 {
 552         precache_sound("misc/jetpack_fly.wav");
 553 }
 554
 555 // FEATURE: auto glowmod
 556 .vector glowmod;
 557 void CSQCPlayer_GlowMod_Apply(void)
 558 {
 559         float cm = self.colormap;
 560
 561         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 562                 cm = 1024;
 563
 564         if(self.colormap > 0)
 565                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 566         else
 567                 self.glowmod = '1 1 1';
 568
 569         if(autocvar_cl_deathglow > 0)
 570                 if(self.csqcmodel_isdead)
 571                 {
 572                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 573                         // prevent the zero vector
 574                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 575                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 576                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 577                 }
 578 }
 579
 580 // general functions
 581 .float csqcmodel_predraw_run;
 582 .float anim_frame;
 583 .float anim_frame1time;
 584 .float anim_frame2;
 585 .float anim_frame2time;
 586 .float anim_saveframe;
 587 .float anim_saveframe1time;
 588 .float anim_saveframe2;
 589 .float anim_saveframe2time;
 590 .float anim_prev_pmove_flags;
 591 void CSQCModel_Hook_PreDraw(float isplayer)
 592 {
 593         if(self.csqcmodel_predraw_run == framecount)
 594                 return;
 595         self.csqcmodel_predraw_run = framecount;
 596
 597         if(!self.modelindex || self.model == "null")
 598         {
 599                 self.drawmask = 0;
 600                 return;
 601         }
 602         else
 603                 self.drawmask = MASK_NORMAL;
 604
 605         if(self.isplayermodel) // this checks if it's a player MODEL!
 606         {
 607                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 608                 CSQCPlayer_GlowMod_Apply();
 609                 CSQCPlayer_LOD_Apply();
 610                 if(!isplayer)
 611                         CSQCPlayer_FallbackFrame_Apply();
 612                 else
 613                 {
 614                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 615                         skeleton_loadinfo(self);
 616                         float doblend = (self.bone_upperbody >= 0);
 617                         float onground = 0;
 618                         if(self == csqcplayer)
 619                         {
 620                                 if(self.pmove_flags & PMF_ONGROUND)
 621                                         onground = 1;
 622                                 self.anim_prev_pmove_flags = self.pmove_flags;
 623                                 if(self.pmove_flags & PMF_DUCKED)
 624                                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DUCK, FALSE);
 625                                 else if(self.anim_state & ANIMSTATE_DUCK)
 626                                         animdecide_setstate(self, self.anim_state - ANIMSTATE_DUCK, FALSE);
 627                         }
 628                         else
 629                         {
 630                                 tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
 631                                 if(trace_startsolid || trace_fraction < 1)
 632                                         onground = 1;
 633                         }
 634                         animdecide_init(self);
 635                         animdecide_setimplicitstate(self, onground);
 636                         animdecide_setframes(self, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 637                         float sf = 0;
 638                         if(self.anim_saveframe != self.anim_frame || self.anim_saveframe1time != self.anim_frame1time)
 639                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 640                         if(self.anim_saveframe2 != self.anim_frame2 || self.anim_saveframe2time != self.anim_frame2time)
 641                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 642                         self.anim_saveframe = self.anim_frame;
 643                         self.anim_saveframe1time = self.anim_frame1time;
 644                         self.anim_saveframe2 = self.anim_frame2;
 645                         self.anim_saveframe2time = self.anim_frame2time;
 646                         if(sf)
 647                         {
 648                                 CSQCModel_InterpolateAnimation_2To4_PreNote(sf | CSQCMODEL_PROPERTY_LERPFRAC);
 649                                 self.lerpfrac = (doblend ? 0.5 : 0);
 650                                 self.frame = self.anim_frame;
 651                                 self.frame1time = self.anim_frame1time;
 652                                 self.frame2 = self.anim_frame2;
 653                                 self.frame2time = self.anim_frame2time;
 654                                 CSQCModel_InterpolateAnimation_2To4_Note(sf | CSQCMODEL_PROPERTY_LERPFRAC, FALSE);
 655                         }
 656                         CSQCModel_InterpolateAnimation_2To4_Do();
 657                         if(doblend)
 658                         {
 659                                 skeleton_from_frames(self, self.csqcmodel_isdead);
 660                         }
 661                         else
 662                         {
 663                                 free_skeleton_from_frames(self);
 664                                 // just in case, clear these (we're animating in frame and frame3)
 665                                 self.lerpfrac = 0;
 666                                 self.lerpfrac4 = 0;
 667                         }
 668                 }
 669         }
 670
 671         CSQCModel_AutoTagIndex_Apply();
 672
 673         CSQCModel_Effects_Apply();
 674 }
 675
 676 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 677 {
 678         // interpolate v_angle
 679         self.iflags |= IFLAG_V_ANGLE_X;
 680         // revert to values from server
 681         CSQCModel_Effects_PreUpdate();
 682         if(self.isplayermodel)
 683         {
 684                 if(!isplayer)
 685                         CSQCPlayer_FallbackFrame_PreUpdate();
 686                 CSQCPlayer_ForceModel_PreUpdate();
 687         }
 688 }
 689
 690 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 691 {
 692         // is it a player model? (shared state)
 693         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 694
 695         // save values set by server
 696         if(self.isplayermodel)
 697         {
 698                 CSQCPlayer_ForceModel_PostUpdate();
 699                 if(isplayer)
 700                         CSQCPlayer_AnimDecide_PostUpdate(isnew);
 701                 else
 702                         CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 703         }
 704         CSQCModel_Effects_PostUpdate();
 705 }