qcsrc/client/csqcmodel_hooks.qc

   1 void CSQCModel_Hook_PreDraw();
   2
   3 .float isplayermodel;
   4
   5 // FEATURE: LOD
   6 .float lodmodelindex0;
   7 .float lodmodelindex1;
   8 .float lodmodelindex2;
   9 void CSQCPlayer_LOD_Apply(void)
  10 {
  11         // LOD model loading
  12         if(self.lodmodelindex0 != self.modelindex)
  13         {
  14                 string modelname = self.model;
  15                 string s;
  16
  17                 vector mi = self.mins;
  18                 vector ma = self.maxs;
  19
  20                 // set modelindex
  21                 self.lodmodelindex0 = self.modelindex;
  22                 self.lodmodelindex1 = self.modelindex;
  23                 self.lodmodelindex2 = self.modelindex;
  24
  25                 // FIXME: this only supports 3-letter extensions
  26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  27                 if(fexists(s))
  28                 {
  29                         precache_model(s);
  30                         setmodel(self, s);
  31                         if(self.modelindex)
  32                                 self.lodmodelindex1 = self.modelindex;
  33                 }
  34
  35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  36                 if(fexists(s))
  37                 {
  38                         precache_model(s);
  39                         setmodel(self, s);
  40                         if(self.modelindex)
  41                                 self.lodmodelindex2 = self.modelindex;
  42                 }
  43
  44                 setmodel(self, modelname); // make everything normal again
  45                 setsize(self, mi, ma);
  46         }
  47
  48         // apply LOD
  49         if(autocvar_cl_playerdetailreduction <= 0)
  50         {
  51                 if(autocvar_cl_playerdetailreduction <= -2)
  52                         self.modelindex = self.lodmodelindex2;
  53                 else if(autocvar_cl_playerdetailreduction <= -1)
  54                         self.modelindex = self.lodmodelindex1;
  55                 else
  56                         self.modelindex = self.lodmodelindex0;
  57         }
  58         else
  59         {
  60                 float distance = vlen(self.origin - view_origin);
  61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
  62                 f *= 1.0 / bound(0.01, view_quality, 1);
  63                 if(f > autocvar_cl_loddistance2)
  64                         self.modelindex = self.lodmodelindex2;
  65                 else if(f > autocvar_cl_loddistance1)
  66                         self.modelindex = self.lodmodelindex1;
  67                 else
  68                         self.modelindex = self.lodmodelindex0;
  69         }
  70 }
  71
  72 // FEATURE: forcemodel (MUST be called BEFORE LOD!)
  73 string forceplayermodels_model;
  74 float forceplayermodels_modelisgoodmodel;
  75 float forceplayermodels_modelindex;
  76 float forceplayermodels_skin;
  77
  78 string forceplayermodels_mymodel;
  79 float forceplayermodels_myisgoodmodel;
  80 float forceplayermodels_mymodelindex;
  81
  82 float forceplayermodels_attempted;
  83
  84 .string forceplayermodels_savemodel;
  85 .float forceplayermodels_savemodelindex;
  86 .float forceplayermodels_saveskin;
  87 .float forceplayermodels_savecolormap;
  88
  89 .string forceplayermodels_isgoodmodel_mdl;
  90 .float forceplayermodels_isgoodmodel;
  91
  92 string forceplayermodels_goodmodel;
  93 float forceplayermodels_goodmodelindex;
  94
  95 void CSQCPlayer_ForceModel_PreUpdate(void)
  96 {
  97         self.model = self.forceplayermodels_savemodel;
  98         self.modelindex = self.forceplayermodels_savemodelindex;
  99         self.skin = self.forceplayermodels_saveskin;
 100         self.colormap = self.forceplayermodels_savecolormap;
 101 }
 102 void CSQCPlayer_ForceModel_PostUpdate(void)
 103 {
 104         self.forceplayermodels_savemodel = self.model;
 105         self.forceplayermodels_savemodelindex = self.modelindex;
 106         self.forceplayermodels_saveskin = self.skin;
 107         self.forceplayermodels_savecolormap = self.colormap;
 108
 109         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
 110         {
 111                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
 112                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
 113                 if(!self.forceplayermodels_isgoodmodel)
 114                         print(sprintf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel));
 115         }
 116 }
 117 void CSQCPlayer_ForceModel_Apply(float islocalplayer)
 118 {
 119         // which one is ALWAYS good?
 120         if not(forceplayermodels_goodmodel)
 121         {
 122                 entity e;
 123                 e = spawn();
 124                 precache_model(cvar_defstring("_cl_playermodel"));
 125                 setmodel(e, cvar_defstring("_cl_playermodel"));
 126                 forceplayermodels_goodmodel = e.model;
 127                 forceplayermodels_goodmodelindex = e.modelindex;
 128                 remove(e);
 129         }
 130
 131         // first, try finding it from the server
 132         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
 133         {
 134                 if(islocalplayer)
 135                 {
 136                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 137                         {
 138                                 // trust server's idea of "own player model"
 139                                 forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
 140                                 forceplayermodels_model = self.forceplayermodels_savemodel;
 141                                 forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
 142                                 forceplayermodels_skin = self.forceplayermodels_saveskin;
 143                                 forceplayermodels_attempted = 1;
 144                         }
 145                 }
 146         }
 147
 148         // forcemodel finding
 149         if(!forceplayermodels_attempted)
 150         {
 151                 forceplayermodels_attempted = 1;
 152
 153                 // only if this failed, find it out on our own
 154                 entity e;
 155                 e = spawn();
 156                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 157                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 158                 forceplayermodels_model = e.model;
 159                 forceplayermodels_modelindex = e.modelindex;
 160                 forceplayermodels_skin = autocvar__cl_playerskin;
 161                 remove(e);
 162         }
 163
 164         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 165         {
 166                 entity e;
 167                 e = spawn();
 168                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 169                 forceplayermodels_myisgoodmodel = fexists(e.model);
 170                 forceplayermodels_mymodel = e.model;
 171                 forceplayermodels_mymodelindex = e.modelindex;
 172                 remove(e);
 173         }
 174
 175         // apply it
 176         float isfriend;
 177         if(teamplay)
 178         {
 179                 cm = self.forceplayermodels_savecolormap;
 180                 cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(self.colormap - 1, "colors")) + 1024);
 181
 182                 isfriend = (cm == 1024 + 17 * myteam);
 183         }
 184         else
 185                 isfriend = islocalplayer;
 186
 187         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 188         {
 189                 self.model = forceplayermodels_mymodel;
 190                 self.modelindex = forceplayermodels_mymodelindex;
 191                 self.skin = autocvar_cl_forcemyplayerskin;
 192         }
 193         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 194         {
 195                 self.model = forceplayermodels_model;
 196                 self.modelindex = forceplayermodels_modelindex;
 197                 self.skin = forceplayermodels_skin;
 198         }
 199         else if(self.forceplayermodels_isgoodmodel)
 200         {
 201                 self.model = self.forceplayermodels_savemodel;
 202                 self.modelindex = self.forceplayermodels_savemodelindex;
 203                 self.skin = self.forceplayermodels_saveskin;
 204         }
 205         else
 206         {
 207                 self.model = forceplayermodels_goodmodel;
 208                 self.modelindex = forceplayermodels_goodmodelindex;
 209                 self.skin = self.forceplayermodels_saveskin;
 210         }
 211
 212         // forceplayercolors too
 213         if(teamplay)
 214         {
 215                 // own team's color is never forced
 216                 float forcecolor_friend = 0;
 217                 float forcecolor_enemy = 0;
 218                 float teams_count = 0;
 219                 entity tm;
 220
 221                 for(tm = teams.sort_next; tm; tm = tm.sort_next)
 222                         if(tm.team != COLOR_SPECTATOR)
 223                                 ++teams_count;
 224
 225                 if(autocvar_cl_forcemyplayercolors)
 226                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 227                 if(autocvar_cl_forceplayercolors && teams_count == 2)
 228                         forcecolor_enemy = 1024 + autocvar__cl_color;
 229
 230                 if(forcecolor_enemy && !forcecolor_friend)
 231                 {
 232                         // only enemy color is forced?
 233                         // verify it is not equal to the friend color
 234                         if(forcecolor_enemy == 1024 + 17 * myteam)
 235                                 forcecolor_enemy = 0;
 236                 }
 237
 238                 if(forcecolor_friend && !forcecolor_enemy)
 239                 {
 240                         // only friend color is forced?
 241                         // verify it is not equal to the enemy color
 242                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 243                                 // note: we even compare against our own team.
 244                                 // if we rejected because we matched our OWN team color,
 245                                 // this is not bad; we then simply keep our color as is
 246                                 // anyway.
 247                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 248                                         forcecolor_friend = 0;
 249                 }
 250
 251                 float cm;
 252                 cm = self.forceplayermodels_savecolormap;
 253                 cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(self.colormap - 1, "colors")) + 1024);
 254
 255                 if(cm == 1024 + 17 * myteam)
 256                 {
 257                         if(forcecolor_friend)
 258                                 self.colormap = forcecolor_friend;
 259                 }
 260                 else
 261                 {
 262                         if(forcecolor_enemy)
 263                                 self.colormap = forcecolor_enemy;
 264                 }
 265         }
 266         else
 267         {
 268                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 269                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 270                 else if(autocvar_cl_forceplayercolors)
 271                         self.colormap = player_localnum + 1;
 272         }
 273 }
 274
 275 // FEATURE: fallback frames
 276 .float csqcmodel_saveframe;
 277 .float csqcmodel_saveframe2;
 278 .float csqcmodel_saveframe3;
 279 .float csqcmodel_saveframe4;
 280 .float csqcmodel_framecount;
 281
 282 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 283 void CSQCPlayer_FallbackFrame_PreUpdate(void)
 284 {
 285         self.frame = self.csqcmodel_saveframe;
 286         self.frame2 = self.csqcmodel_saveframe2;
 287         self.frame3 = self.csqcmodel_saveframe3;
 288         self.frame4 = self.csqcmodel_saveframe4;
 289 }
 290 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
 291 {
 292         self.csqcmodel_saveframe = self.frame;
 293         self.csqcmodel_saveframe2 = self.frame2;
 294         self.csqcmodel_saveframe3 = self.frame3;
 295         self.csqcmodel_saveframe4 = self.frame4;
 296
 297         // hack for death animations: set their frametime to zero in case a
 298         // player "pops in"
 299         if(isnew)
 300         {
 301 #define FIX_FRAMETIME(f,ft) \
 302                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
 303                 { \
 304                         self.ft = self.death_time; \
 305                 }
 306                 FIX_FRAMETIME(frame, frame1time)
 307                 FIX_FRAMETIME(frame2, frame2time)
 308                 FIX_FRAMETIME(frame3, frame3time)
 309                 FIX_FRAMETIME(frame4, frame4time)
 310         }
 311         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
 312 }
 313 float CSQCPlayer_FallbackFrame(float f)
 314 {
 315         if(frameduration(self.modelindex, f) > 0)
 316                 return f; // goooooood
 317         if(frameduration(self.modelindex, 1) <= 0)
 318                 return f; // this is a static model. We can't fix it if we wanted to
 319         switch(f)
 320         {
 321                 case 23: return 11; // anim_melee -> anim_shoot
 322                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 323                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 324                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 325                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 326                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 327                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 328                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 329         }
 330         print(sprintf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model));
 331         return f;
 332 }
 333 void CSQCPlayer_FallbackFrame_Apply(void)
 334 {
 335         self.frame = CSQCPlayer_FallbackFrame(self.frame);
 336         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
 337         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
 338         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
 339 }
 340
 341 // FEATURE: auto tag_index
 342 .entity tag_entity;
 343 .float tag_entity_lastmodelindex;
 344 .float tag_index;
 345 void CSQCModel_AutoTagIndex_Apply(void)
 346 {
 347         if(self.tag_entity && wasfreed(self.tag_entity))
 348                 self.tag_entity = world;
 349
 350         if(self.tag_networkentity)
 351         {
 352                 // we are ATTACHED!
 353                 float changed = 0;
 354                 if(self.tag_entity.entnum != self.tag_networkentity)
 355                 {
 356                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
 357                         changed = 1;
 358                 }
 359
 360                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 361                 if(self.tag_entity.classname == "csqcmodel")
 362                 {
 363                         entity oldself = self;
 364                         self = self.tag_entity;
 365                         CSQCModel_Hook_PreDraw();
 366                         self = oldself;
 367                 }
 368
 369                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
 370                 {
 371                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
 372                         changed = 1;
 373                 }
 374                 if(changed)
 375                 {
 376                         if(self.tag_entity)
 377                         {
 378                                 // the best part is: IT EXISTS
 379                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
 380                                 {
 381                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
 382                                         {
 383                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 384                                                 if(!self.tag_index)
 385                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 386                                                 if(!self.tag_index)
 387                                                 {
 388                                                         // we need to prevent this from 'appening
 389                                                         self.tag_entity = world;
 390                                                         self.drawmask = 0;
 391                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
 392                                                 }
 393                                         }
 394                                         else if(self.tag_entity.isplayermodel)
 395                                         {
 396                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
 397                                                 if(!self.tag_index)
 398                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
 399                                                 if(!self.tag_index)
 400                                                         self.tag_index = gettagindex(self.tag_entity, "bip01 r hand");
 401                                         }
 402                                 }
 403
 404                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
 405                                 {
 406                                         self.tag_index = gettagindex(self.tag_entity, "shot");
 407                                         if(!self.tag_index)
 408                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
 409                                 }
 410                         }
 411                         else
 412                         {
 413                                 // damn, see you next frame
 414                                 self.drawmask = 0;
 415                         }
 416                 }
 417         }
 418 }
 419
 420 // FEATURE: EF_NODRAW workalike
 421 float EF_BRIGHTFIELD    = 1;
 422 float EF_BRIGHTLIGHT    = 4;
 423 float EF_DIMLIGHT       = 8;
 424 float EF_DOUBLESIDED = 32768;
 425 float EF_NOSELFSHADOW = 65536;
 426 float EF_DYNAMICMODELLIGHT = 131072;
 427 float MF_ROCKET  =   1; // leave a trail
 428 float MF_GRENADE =   2; // leave a trail
 429 float MF_GIB     =   4; // leave a trail
 430 float MF_ROTATE  =   8; // rotate (bonus items)
 431 float MF_TRACER  =  16; // green split trail
 432 float MF_ZOMGIB  =  32; // small blood trail
 433 float MF_TRACER2 =  64; // orange split trail
 434 float MF_TRACER3 = 128; // purple trail
 435 .float csqcmodel_effects;
 436 .float csqcmodel_modelflags;
 437 void CSQCModel_Effects_PreUpdate(void)
 438 {
 439         self.effects = self.csqcmodel_effects;
 440         self.modelflags = self.csqcmodel_modelflags;
 441 }
 442 void CSQCModel_Effects_PostUpdate(void)
 443 {
 444         self.csqcmodel_effects = self.effects;
 445         self.csqcmodel_modelflags = self.modelflags;
 446         self.effects = 0;
 447         self.modelflags = 0;
 448         if(self.csqcmodel_teleported)
 449                 Projectile_ResetTrail(self.origin);
 450 }
 451 void CSQCModel_Effects_Apply(void)
 452 {
 453         float eff = self.csqcmodel_effects;
 454         eff &~= CSQCMODEL_EF_RESPAWNGHOST;
 455
 456         self.renderflags &~= (RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 457         self.effects = 0;
 458         self.traileffect = 0;
 459
 460         if(eff & EF_BRIGHTFIELD)
 461                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
 462         // ignoring EF_MUZZLEFLASH
 463         if(eff & EF_BRIGHTLIGHT)
 464                 adddynamiclight(self.origin, 400, '3 3 3');
 465         if(eff & EF_DIMLIGHT)
 466                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
 467         if((eff & EF_NODRAW) || (self.alpha < 0))
 468                 self.drawmask = 0;
 469         if(eff & EF_ADDITIVE)
 470                 self.renderflags |= RF_ADDITIVE;
 471         if(eff & EF_BLUE)
 472                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
 473         if(eff & EF_RED)
 474                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
 475         // ignoring EF_NOGUNBOB
 476         if(eff & EF_FULLBRIGHT)
 477                 self.renderflags |= RF_FULLBRIGHT;
 478         if(eff & EF_FLAME)
 479                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 480         if(eff & EF_STARDUST)
 481                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
 482         if(eff & EF_NOSHADOW)
 483                 self.renderflags |= RF_NOSHADOW;
 484         if(eff & EF_NODEPTHTEST)
 485                 self.renderflags |= RF_DEPTHHACK;
 486         // ignoring EF_SELECTABLE
 487         if(eff & EF_DOUBLESIDED)
 488                 self.effects |= EF_DOUBLESIDED;
 489         if(eff & EF_NOSELFSHADOW)
 490                 self.effects |= EF_NOSELFSHADOW;
 491         if(eff & EF_DYNAMICMODELLIGHT)
 492                 self.renderflags |= RF_DYNAMICMODELLIGHT;
 493         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 494         if(self.csqcmodel_modelflags & MF_ROCKET)
 495                 self.traileffect = particleeffectnum("TR_ROCKET");
 496         if(self.csqcmodel_modelflags & MF_GRENADE)
 497                 self.traileffect = particleeffectnum("TR_GRENADE");
 498         if(self.csqcmodel_modelflags & MF_GIB)
 499                 self.traileffect = particleeffectnum("TR_BLOOD");
 500         if(self.csqcmodel_modelflags & MF_ROTATE)
 501         {
 502                 self.renderflags |= RF_USEAXIS;
 503                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
 504         }
 505         if(self.csqcmodel_modelflags & MF_TRACER)
 506                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
 507         if(self.csqcmodel_modelflags & MF_ZOMGIB)
 508                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
 509         if(self.csqcmodel_modelflags & MF_TRACER2)
 510                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
 511         if(self.csqcmodel_modelflags & MF_TRACER3)
 512                 self.traileffect = particleeffectnum("TR_VORESPIKE");
 513
 514         if(self.drawmask)
 515                 Projectile_DrawTrail(self.origin);
 516         else
 517                 Projectile_ResetTrail(self.origin);
 518
 519         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 520                 self.renderflags |= RF_ADDITIVE;
 521                 // also special in CSQCPlayer_GlowMod_Apply
 522 }
 523
 524 // FEATURE: auto glowmod
 525 .vector glowmod;
 526 void CSQCPlayer_GlowMod_Apply(void)
 527 {
 528         float cm = self.colormap;
 529
 530         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 531                 cm = 1024;
 532
 533         if(self.colormap > 0)
 534                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
 535         else
 536                 self.glowmod = '1 1 1';
 537
 538         if(autocvar_cl_deathglow > 0)
 539                 if(self.csqcmodel_isdead)
 540                 {
 541                         self.glowmod = self.glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
 542                         // prevent the zero vector
 543                         self.glowmod_x = max(self.glowmod_x, 0.0001);
 544                         self.glowmod_y = max(self.glowmod_y, 0.0001);
 545                         self.glowmod_z = max(self.glowmod_z, 0.0001);
 546                 }
 547 }
 548
 549 // general functions
 550 .float csqcmodel_predraw_run;
 551 void CSQCModel_Hook_PreDraw()
 552 {
 553         if(self.csqcmodel_predraw_run == framecount)
 554                 return;
 555         self.csqcmodel_predraw_run = framecount;
 556
 557         if(!self.modelindex || self.model == "null")
 558         {
 559                 self.drawmask = 0;
 560                 return;
 561         }
 562         else
 563                 self.drawmask = MASK_NORMAL;
 564
 565         if(self.isplayermodel) // this checks if it's a player MODEL!
 566         {
 567                 CSQCPlayer_ForceModel_Apply(self.entnum == player_localnum + 1);
 568                 CSQCPlayer_GlowMod_Apply();
 569                 CSQCPlayer_LOD_Apply();
 570                 CSQCPlayer_FallbackFrame_Apply();
 571         }
 572
 573         CSQCModel_AutoTagIndex_Apply();
 574
 575         CSQCModel_Effects_Apply();
 576 }
 577
 578 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
 579 {
 580         // revert to values from server
 581         CSQCModel_Effects_PreUpdate();
 582         if(self.isplayermodel)
 583         {
 584                 CSQCPlayer_FallbackFrame_PreUpdate();
 585                 CSQCPlayer_ForceModel_PreUpdate();
 586         }
 587 }
 588
 589 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
 590 {
 591         // is it a player model? (shared state)
 592         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
 593
 594         // save values set by server
 595         if(self.isplayermodel)
 596         {
 597                 CSQCPlayer_ForceModel_PostUpdate();
 598                 CSQCPlayer_FallbackFrame_PostUpdate(isnew);
 599         }
 600         CSQCModel_Effects_PostUpdate();
 601 }