qcsrc/client/csqcmodel_hooks.qc

   1 #include "csqcmodel_hooks.qh"
   2 #include "autocvars.qh"
   3 #include "miscfunctions.qh"
   4 #include <client/mutators/_mod.qh>
   5 #include "player_skeleton.qh"
   6 #include "weapons/projectile.qh"
   7 #include <common/animdecide.qh>
   8 #include <common/ent_cs.qh>
   9 #include <common/physics/movetypes/movetypes.qh>
  10 #include <common/viewloc.qh>
  11 #include <common/effects/all.qh>
  12 #include <common/effects/all.inc>
  13 #include <lib/csqcmodel/cl_model.qh>
  14 #include <lib/csqcmodel/cl_player.qh>
  15 #include <lib/csqcmodel/interpolate.qh>
  16
  17 .float death_time;
  18 .int modelflags;
  19
  20 // FEATURE: LOD
  21 .int lodmodelindex0;
  22 .int lodmodelindex1;
  23 .int lodmodelindex2;
  24 void CSQCPlayer_LOD_Apply(entity this, bool isplayer)
  25 {
  26         int detailreduction = ((isplayer) ? autocvar_cl_playerdetailreduction : autocvar_cl_modeldetailreduction);
  27
  28         // LOD model loading
  29         if(this.lodmodelindex0 != this.modelindex)
  30         {
  31                 string modelname = this.model;
  32                 string s;
  33
  34                 vector mi = this.mins;
  35                 vector ma = this.maxs;
  36
  37                 // set modelindex
  38                 this.lodmodelindex0 = this.modelindex;
  39                 this.lodmodelindex1 = this.modelindex;
  40                 this.lodmodelindex2 = this.modelindex;
  41
  42                 // FIXME: this only supports 3-letter extensions
  43                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
  44                 if(fexists(s))
  45                 {
  46                         precache_model(s);
  47                         _setmodel(this, s);
  48                         if(this.modelindex)
  49                                 this.lodmodelindex1 = this.modelindex;
  50                 }
  51
  52                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
  53                 if(fexists(s))
  54                 {
  55                         precache_model(s);
  56                         _setmodel(this, s);
  57                         if(this.modelindex)
  58                                 this.lodmodelindex2 = this.modelindex;
  59                 }
  60
  61                 _setmodel(this, modelname); // make everything normal again
  62                 setsize(this, mi, ma);
  63         }
  64
  65         // apply LOD
  66         if(detailreduction <= 0)
  67         {
  68                 if(detailreduction <= -2)
  69                         this.modelindex = this.lodmodelindex2;
  70                 else if(detailreduction <= -1)
  71                         this.modelindex = this.lodmodelindex1;
  72                 else
  73                         this.modelindex = this.lodmodelindex0;
  74         }
  75         else
  76         {
  77                 float distance = vlen(((isplayer) ? this.origin : NearestPointOnBox(this, view_origin)) - view_origin); // TODO: perhaps it should just use NearestPointOnBox all the time, player hitbox can potentially be huge
  78                 float f = (distance * current_viewzoom + 100.0) * detailreduction;
  79                 f *= 1.0 / bound(0.01, view_quality, 1);
  80                 if(f > autocvar_cl_loddistance2)
  81                         this.modelindex = this.lodmodelindex2;
  82                 else if(f > autocvar_cl_loddistance1)
  83                         this.modelindex = this.lodmodelindex1;
  84                 else
  85                         this.modelindex = this.lodmodelindex0;
  86         }
  87 }
  88
  89 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
  90 string forceplayermodels_model;
  91 bool forceplayermodels_modelisgoodmodel;
  92 int forceplayermodels_modelindex;
  93 int forceplayermodels_skin;
  94
  95 string forceplayermodels_mymodel;
  96 bool forceplayermodels_myisgoodmodel;
  97 int forceplayermodels_mymodelindex;
  98
  99 bool forceplayermodels_attempted;
 100
 101 .string forceplayermodels_savemodel;
 102 .int forceplayermodels_savemodelindex;
 103 .int forceplayermodels_saveskin;
 104 .int forceplayermodels_savecolormap;
 105
 106 .string forceplayermodels_isgoodmodel_mdl;
 107 .bool forceplayermodels_isgoodmodel;
 108
 109 string forceplayermodels_goodmodel;
 110 int forceplayermodels_goodmodelindex;
 111
 112 .vector glowmod;
 113
 114 void CSQCPlayer_ModelAppearance_PreUpdate(entity this)
 115 {
 116         this.model = this.forceplayermodels_savemodel;
 117         this.modelindex = this.forceplayermodels_savemodelindex;
 118         this.skin = this.forceplayermodels_saveskin;
 119         this.colormap = this.forceplayermodels_savecolormap;
 120 }
 121 void CSQCPlayer_ModelAppearance_PostUpdate(entity this)
 122 {
 123         this.forceplayermodels_savemodel = this.model;
 124         this.forceplayermodels_savemodelindex = this.modelindex;
 125         this.forceplayermodels_saveskin = this.skin;
 126         this.forceplayermodels_savecolormap = this.colormap;
 127
 128         if(this.forceplayermodels_savemodel != this.forceplayermodels_isgoodmodel_mdl)
 129         {
 130                 this.forceplayermodels_isgoodmodel = fexists(this.forceplayermodels_savemodel);
 131                 this.forceplayermodels_isgoodmodel_mdl = this.forceplayermodels_savemodel;
 132                 if(!this.forceplayermodels_isgoodmodel)
 133                         LOG_INFOF("Warning: missing model %s has been used", this.forceplayermodels_savemodel);
 134         }
 135 }
 136 void CSQCPlayer_ModelAppearance_Apply(entity this, bool islocalplayer)
 137 {
 138         if(MUTATOR_CALLHOOK(ForcePlayermodels_Skip, this, islocalplayer))
 139                 goto skipforcemodels;
 140
 141         // FORCEMODEL
 142         // which one is ALWAYS good?
 143         if (!forceplayermodels_goodmodel)
 144         {
 145                 entity e = spawn();
 146                 precache_model(cvar_defstring("_cl_playermodel"));
 147                 _setmodel(e, cvar_defstring("_cl_playermodel"));
 148                 forceplayermodels_goodmodel = e.model;
 149                 forceplayermodels_goodmodelindex = e.modelindex;
 150                 delete(e);
 151         }
 152
 153         // first, try finding it from the server
 154         if(this.forceplayermodels_savemodelindex && this.forceplayermodels_savemodel != "null")
 155         {
 156                 if(islocalplayer)
 157                 {
 158                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
 159                         {
 160                                 // trust server's idea of "own player model"
 161                                 forceplayermodels_modelisgoodmodel = this.forceplayermodels_isgoodmodel;
 162                                 forceplayermodels_model = this.forceplayermodels_savemodel;
 163                                 forceplayermodels_modelindex = this.forceplayermodels_savemodelindex;
 164                                 forceplayermodels_skin = this.forceplayermodels_saveskin;
 165                                 forceplayermodels_attempted = 1;
 166                         }
 167                 }
 168         }
 169
 170         // forcemodel finding
 171         if(!forceplayermodels_attempted)
 172         {
 173                 forceplayermodels_attempted = 1;
 174
 175                 // only if this failed, find it out on our own
 176                 entity e = spawn();
 177                 precache_model(autocvar__cl_playermodel);
 178                 _setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
 179                 forceplayermodels_modelisgoodmodel = fexists(e.model);
 180                 forceplayermodels_model = e.model;
 181                 forceplayermodels_modelindex = e.modelindex;
 182                 forceplayermodels_skin = autocvar__cl_playerskin;
 183                 delete(e);
 184         }
 185
 186         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
 187         {
 188                 entity e = spawn();
 189                 _setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
 190                 forceplayermodels_myisgoodmodel = fexists(e.model);
 191                 forceplayermodels_mymodel = e.model;
 192                 forceplayermodels_mymodelindex = e.modelindex;
 193                 delete(e);
 194         }
 195
 196         // apply it
 197         bool isfriend;
 198         int cm;
 199         cm = this.forceplayermodels_savecolormap;
 200         cm = (cm >= 1024) ? cm : (entcs_GetClientColors(cm - 1) + 1024);
 201
 202         if(teamplay)
 203                 isfriend = (cm == 1024 + 17 * myteam);
 204         else
 205                 isfriend = islocalplayer;
 206
 207         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
 208         {
 209                 this.model = forceplayermodels_mymodel;
 210                 this.modelindex = forceplayermodels_mymodelindex;
 211                 this.skin = autocvar_cl_forcemyplayerskin;
 212         }
 213         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
 214         {
 215                 this.model = forceplayermodels_model;
 216                 this.modelindex = forceplayermodels_modelindex;
 217                 this.skin = forceplayermodels_skin;
 218         }
 219         else if(this.forceplayermodels_isgoodmodel)
 220         {
 221                 this.model = this.forceplayermodels_savemodel;
 222                 this.modelindex = this.forceplayermodels_savemodelindex;
 223                 this.skin = this.forceplayermodels_saveskin;
 224         }
 225         else
 226         {
 227                 this.model = forceplayermodels_goodmodel;
 228                 this.modelindex = forceplayermodels_goodmodelindex;
 229                 this.skin = this.forceplayermodels_saveskin;
 230         }
 231
 232         // forceplayercolors too
 233         if(teamplay)
 234         {
 235                 // own team's color is never forced
 236                 int forcecolor_friend = 0;
 237                 int forcecolor_enemy = 0;
 238                 entity tm;
 239
 240                 if(autocvar_cl_forcemyplayercolors)
 241                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
 242                 if(autocvar_cl_forceplayercolors == 2 && team_count == 2)
 243                         forcecolor_enemy = 1024 + autocvar__cl_color;
 244
 245                 if(forcecolor_enemy && !forcecolor_friend)
 246                 {
 247                         // only enemy color is forced?
 248                         // verify it is not equal to the friend color
 249                         if(forcecolor_enemy == 1024 + 17 * myteam)
 250                                 forcecolor_enemy = 0;
 251                 }
 252
 253                 if(forcecolor_friend && !forcecolor_enemy)
 254                 {
 255                         // only friend color is forced?
 256                         // verify it is not equal to the enemy color
 257                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
 258                                 // note: we even compare against our own team.
 259                                 // if we rejected because we matched our OWN team color,
 260                                 // this is not bad; we then simply keep our color as is
 261                                 // anyway.
 262                                 if(forcecolor_friend == 1024 + 17 * tm.team)
 263                                         forcecolor_friend = 0;
 264                 }
 265
 266                 if(cm == 1024 + 17 * myteam)
 267                 {
 268                         if(forcecolor_friend)
 269                                 this.colormap = forcecolor_friend;
 270                 }
 271                 else
 272                 {
 273                         if(forcecolor_enemy)
 274                                 this.colormap = forcecolor_enemy;
 275                 }
 276         }
 277         else
 278         {
 279                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
 280                         this.colormap = 1024 + autocvar_cl_forcemyplayercolors;
 281                 else if(autocvar_cl_forceplayercolors)
 282                         this.colormap = player_localnum + 1;
 283         }
 284
 285         LABEL(skipforcemodels)
 286
 287         // GLOWMOD AND DEATH FADING
 288         if(this.colormap > 0)
 289                 this.glowmod = colormapPaletteColor(((this.colormap >= 1024) ? this.colormap : entcs_GetClientColors(this.colormap - 1)) & 0x0F, true) * 2;
 290         else
 291                 this.glowmod = '1 1 1';
 292
 293         if(autocvar_cl_deathglow > 0)
 294         {
 295                 if(this.csqcmodel_isdead)
 296                 {
 297                         float min_factor = bound(0, autocvar_cl_deathglow_min, 1);
 298                         if(this.colormap > 0)
 299                                 min_factor /= 2;
 300                         float glow_fade = bound(0, 1 - (time - this.death_time) / autocvar_cl_deathglow, 1);
 301                         this.glowmod *= (min_factor + glow_fade * (1 - min_factor));
 302                         if (this.glowmod == '0 0 0')
 303                                 this.glowmod.x = 0.000001;
 304                 }
 305         }
 306
 307         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (this.csqcmodel_isdead ? "DEAD" : "ALIVE"), this.colormap, vtos(this.glowmod));
 308 }
 309
 310 // FEATURE: fallback frames
 311 .int csqcmodel_saveframe;
 312 .int csqcmodel_saveframe2;
 313 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 314 .int csqcmodel_saveframe3;
 315 .int csqcmodel_saveframe4;
 316 #endif
 317 .int csqcmodel_framecount;
 318
 319 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
 320 void CSQCPlayer_FallbackFrame_PreUpdate(entity this)
 321 {
 322         this.frame = this.csqcmodel_saveframe;
 323         this.frame2 = this.csqcmodel_saveframe2;
 324 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 325         this.frame3 = this.csqcmodel_saveframe3;
 326         this.frame4 = this.csqcmodel_saveframe4;
 327 #endif
 328 }
 329 void CSQCPlayer_FallbackFrame_PostUpdate(entity this, bool isnew)
 330 {
 331         this.csqcmodel_saveframe = this.frame;
 332         this.csqcmodel_saveframe2 = this.frame2;
 333 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 334         this.csqcmodel_saveframe3 = this.frame3;
 335         this.csqcmodel_saveframe4 = this.frame4;
 336 #endif
 337
 338         // hack for death animations: set their frametime to zero in case a
 339         // player "pops in"
 340         if(isnew)
 341         {
 342 #define FIX_FRAMETIME(f,ft) MACRO_BEGIN \
 343                 if(IS_DEAD_FRAME(this.f) && this.ft != 0 && this.death_time != 0) \
 344                         this.ft = this.death_time; \
 345 MACRO_END
 346                 FIX_FRAMETIME(frame, frame1time);
 347                 FIX_FRAMETIME(frame2, frame2time);
 348 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 349                 FIX_FRAMETIME(frame3, frame3time);
 350                 FIX_FRAMETIME(frame4, frame4time);
 351 #endif
 352         }
 353         this.csqcmodel_isdead = IS_DEAD_FRAME(this.frame);
 354 }
 355 void CSQCPlayer_AnimDecide_PostUpdate(entity this, bool isnew)
 356 {
 357         this.csqcmodel_isdead = boolean(this.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 358 }
 359 int CSQCPlayer_FallbackFrame(entity this, int f)
 360 {
 361         TC(int, f);
 362         if(frameduration(this.modelindex, f) > 0)
 363                 return f; // goooooood
 364         if(frameduration(this.modelindex, 1) <= 0)
 365                 return f; // this is a static model. We can't fix it if we wanted to
 366         switch(f)
 367         {
 368                 case 23: return 11; // anim_melee -> anim_shoot
 369                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
 370                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
 371                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
 372                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
 373                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
 374                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
 375                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
 376         }
 377         LOG_DEBUGF("Frame %d missing in model %s, and we have no fallback - FAIL!", f, this.model);
 378         return f;
 379 }
 380 void CSQCPlayer_FallbackFrame_Apply(entity this)
 381 {
 382         this.frame = CSQCPlayer_FallbackFrame(this, this.frame);
 383         this.frame2 = CSQCPlayer_FallbackFrame(this, this.frame2);
 384 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
 385         this.frame3 = CSQCPlayer_FallbackFrame(this, this.frame3);
 386         this.frame4 = CSQCPlayer_FallbackFrame(this, this.frame4);
 387 #endif
 388 }
 389
 390 // FEATURE: auto tag_index
 391 .entity tag_entity;
 392 .int tag_entity_lastmodelindex;
 393 .int tag_index;
 394 void CSQCModel_AutoTagIndex_Apply(entity this)
 395 {
 396         if(this.tag_entity && wasfreed(this.tag_entity))
 397                 this.tag_entity = NULL;
 398
 399         MUTATOR_CALLHOOK(TagIndex_Update, this);
 400
 401         if(this.tag_networkentity)
 402         {
 403                 // we are ATTACHED!
 404                 bool changed = 0;
 405                 if(this.tag_entity.entnum != this.tag_networkentity)
 406                 {
 407                         this.tag_entity = findfloat(NULL, entnum, this.tag_networkentity);
 408                         changed = 1;
 409                 }
 410
 411                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
 412                 if(this.tag_entity.classname == "csqcmodel")
 413                 {
 414                         CSQCModel_Hook_PreDraw(this.tag_entity, (this.tag_entity.isplayermodel & ISPLAYER_CLIENT));
 415                 }
 416
 417                 if(this.tag_entity.modelindex != this.tag_entity_lastmodelindex)
 418                 {
 419                         this.tag_entity_lastmodelindex = this.tag_entity.modelindex;
 420                         changed = 1;
 421                 }
 422                 if(changed)
 423                 {
 424                         if(this.tag_entity)
 425                         {
 426                                 // the best part is: IT EXISTS
 427                                 if(substring(this.model, 0, 14) == "models/weapons")
 428                                 {
 429                                         if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 430                                         {
 431                                                 this.tag_index = gettagindex(this.tag_entity, "weapon");
 432                                                 if(!this.tag_index)
 433                                                         this.tag_index = gettagindex(this.tag_entity, "tag_weapon");
 434                                                 if(!this.tag_index)
 435                                                 {
 436                                                         // we need to prevent this from 'appening
 437                                                         this.tag_entity = NULL;
 438                                                         this.drawmask = 0;
 439                                                         LOG_TRACE("h_ model lacks weapon attachment, but v_ model is attached to it");
 440                                                 }
 441                                         }
 442                                         else if((this.tag_entity.isplayermodel & ISPLAYER_MODEL))
 443                                         {
 444                                                 skeleton_loadinfo(this.tag_entity);
 445                                                 this.tag_index = this.tag_entity.bone_weapon;
 446                                         }
 447                                 }
 448
 449                                 if(substring(this.tag_entity.model, 0, 14) == "models/weapons")
 450                                 {
 451                                         this.tag_index = gettagindex(this.tag_entity, "shot");
 452                                         if(!this.tag_index)
 453                                                 this.tag_index = gettagindex(this.tag_entity, "tag_shot");
 454                                 }
 455
 456                                 MUTATOR_CALLHOOK(TagIndex_Apply, this);
 457                         }
 458                         else
 459                         {
 460                                 // damn, see you next frame
 461                                 this.drawmask = 0;
 462                         }
 463                 }
 464         }
 465 }
 466
 467 void CSQCModel_Effects_PreUpdate(entity this)
 468 {
 469         this.effects = this.csqcmodel_effects;
 470         this.modelflags = this.csqcmodel_modelflags;
 471         this.traileffect = this.csqcmodel_traileffect;
 472 }
 473 void Reset_ArcBeam();
 474 void CSQCModel_Effects_PostUpdate(entity this)
 475 {
 476         if (this == csqcplayer) {
 477                 if (this.csqcmodel_teleported) {
 478                         Reset_ArcBeam();
 479                 }
 480         }
 481         this.csqcmodel_effects = this.effects;
 482         this.csqcmodel_modelflags = this.modelflags;
 483         this.csqcmodel_traileffect = this.traileffect;
 484         this.effects = 0;
 485         this.modelflags = 0;
 486         if(this.csqcmodel_teleported)
 487                 Projectile_ResetTrail(this, this.origin);
 488 }
 489 .int snd_looping;
 490 void CSQCModel_Effects_Apply(entity this)
 491 {
 492         int eff = this.csqcmodel_effects & ~CSQCMODEL_EF_RESPAWNGHOST;
 493         int tref = this.csqcmodel_traileffect;
 494
 495         this.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
 496         this.effects = 0;
 497         this.traileffect = 0;
 498
 499         if(eff & EF_BRIGHTFIELD)
 500                 tref = EFFECT_TR_NEXUIZPLASMA.m_id;
 501         // ignoring EF_MUZZLEFLASH
 502         if(eff & EF_BRIGHTLIGHT)
 503                 adddynamiclight(this.origin, 400, '3 3 3');
 504         if(eff & EF_DIMLIGHT)
 505                 adddynamiclight(this.origin, 200, '1.5 1.5 1.5');
 506         if((eff & EF_NODRAW) || (this.alpha < 0))
 507                 this.drawmask = 0;
 508         if(eff & EF_ADDITIVE)
 509                 this.renderflags |= RF_ADDITIVE;
 510         if(eff & EF_BLUE)
 511                 adddynamiclight(this.origin, 200, '0.15 0.15 1.5');
 512         if(eff & EF_RED)
 513                 adddynamiclight(this.origin, 200, '1.5 0.15 0.15');
 514         // ignoring EF_NOGUNBOB
 515         if(eff & EF_FULLBRIGHT)
 516                 this.renderflags |= RF_FULLBRIGHT;
 517         if(eff & EF_FLAME)
 518                 pointparticles(EFFECT_EF_FLAME, this.origin, '0 0 0', bound(0, frametime, 0.1));
 519         if(eff & EF_STARDUST)
 520                 pointparticles(EFFECT_EF_STARDUST, this.origin, '0 0 0', bound(0, frametime, 0.1));
 521         if(eff & EF_NOSHADOW)
 522                 this.renderflags |= RF_NOSHADOW;
 523         if(eff & EF_NODEPTHTEST)
 524                 this.renderflags |= RF_DEPTHHACK;
 525         // ignoring EF_SELECTABLE
 526         if(eff & EF_DOUBLESIDED)
 527                 this.effects |= EF_DOUBLESIDED;
 528         if(eff & EF_NOSELFSHADOW)
 529                 this.effects |= EF_NOSELFSHADOW;
 530         if(eff & EF_DYNAMICMODELLIGHT)
 531                 this.renderflags |= RF_DYNAMICMODELLIGHT;
 532         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
 533         if(this.csqcmodel_modelflags & MF_ROCKET)
 534                 tref = EFFECT_TR_ROCKET.m_id;
 535         if(this.csqcmodel_modelflags & MF_GRENADE)
 536                 tref = EFFECT_TR_GRENADE.m_id;
 537         if(this.csqcmodel_modelflags & MF_GIB)
 538                 tref = EFFECT_TR_BLOOD.m_id;
 539         if(this.csqcmodel_modelflags & MF_ROTATE)
 540         {
 541                 // This will be hard to replace with MAKE_VECTORS because it's called as part of the predraw function
 542                 // as documented in csprogs.h in the engine. The globals can then be read in many places in the engine.
 543                 // However MF_ROTATE is currently only used in one place - might be possible to get rid of it entirely.
 544                 this.renderflags |= RF_USEAXIS;
 545                 makevectors(this.angles + '0 100 0' * fmod(time, 3.6));
 546         }
 547         if(this.csqcmodel_modelflags & MF_TRACER)
 548                 tref = EFFECT_TR_WIZSPIKE.m_id;
 549         if(this.csqcmodel_modelflags & MF_ZOMGIB)
 550                 tref = EFFECT_TR_SLIGHTBLOOD.m_id;
 551         if(this.csqcmodel_modelflags & MF_TRACER2)
 552                 tref = EFFECT_TR_KNIGHTSPIKE.m_id;
 553         if(this.csqcmodel_modelflags & MF_TRACER3)
 554                 tref = EFFECT_TR_VORESPIKE.m_id;
 555
 556         this.traileffect = tref;
 557
 558         if(this.drawmask)
 559                 Projectile_DrawTrail(this, this.origin);
 560         else
 561                 Projectile_ResetTrail(this, this.origin);
 562
 563         if(this.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
 564                 this.renderflags |= RF_ADDITIVE;
 565                 // also special in CSQCPlayer_GlowMod_Apply
 566
 567         if(this.csqcmodel_modelflags & MF_ROCKET)
 568         {
 569                 if(!this.snd_looping)
 570                 {
 571                         sound(this, CH_TRIGGER_SINGLE, SND_JETPACK_FLY, VOL_BASE, autocvar_cl_jetpack_attenuation);
 572                         this.snd_looping = CH_TRIGGER_SINGLE;
 573                 }
 574         }
 575         else
 576         {
 577                 if(this.snd_looping)
 578                 {
 579                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 580                         this.snd_looping = 0;
 581                 }
 582         }
 583 }
 584
 585 // general functions
 586 .int csqcmodel_predraw_run;
 587 .int anim_frame;
 588 .int anim_frame1time;
 589 .int anim_frame2;
 590 .int anim_frame2time;
 591 .int anim_saveframe;
 592 .int anim_saveframe1time;
 593 .int anim_saveframe2;
 594 .int anim_saveframe2time;
 595 .int anim_prev_pmove_flags;
 596 void CSQCModel_Hook_PreDraw(entity this, bool isplayer)
 597 {
 598         if(this.csqcmodel_predraw_run == framecount)
 599                 return;
 600         this.csqcmodel_predraw_run = framecount;
 601
 602         if(!this.modelindex || this.model == "null" || this.alpha < 0)
 603         {
 604                 this.drawmask = 0;
 605                 if(this.snd_looping > 0)
 606                 {
 607                         sound(this, this.snd_looping, SND_Null, VOL_BASE, autocvar_cl_jetpack_attenuation);
 608                         this.snd_looping = 0;
 609                 }
 610                 return;
 611         }
 612         else
 613                 this.drawmask = MASK_NORMAL;
 614
 615         if((this.isplayermodel & ISPLAYER_MODEL) && this.drawmask) // this checks if it's a player MODEL!
 616         {
 617                 CSQCPlayer_ModelAppearance_Apply(this, (this.isplayermodel & ISPLAYER_LOCAL));
 618                 CSQCPlayer_LOD_Apply(this, true);
 619
 620                 if(!isplayer)
 621                 {
 622                         skeleton_loadinfo(this);
 623                         bool doblend = (this.bone_upperbody >= 0);
 624                         CSQCPlayer_FallbackFrame_Apply(this);
 625                         if(doblend)
 626                         {
 627                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 628                         }
 629                         else
 630                         {
 631                                 free_skeleton_from_frames(this);
 632                                 // just in case, clear these (we're animating in frame and frame3)
 633                                 this.lerpfrac = 0;
 634                                 this.lerpfrac4 = 0;
 635                         }
 636                 }
 637                 else
 638                 {
 639                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
 640                         skeleton_loadinfo(this);
 641                         bool doblend = (this.bone_upperbody >= 0);
 642                         bool onground = 0;
 643                         if(this == csqcplayer)
 644                         {
 645                                 if(IS_ONGROUND(this))
 646                                         onground = 1;
 647                                 this.anim_prev_pmove_flags = this.flags;
 648                                 if(this.flags & FL_DUCKED)
 649                                         animdecide_setstate(this, this.anim_state | ANIMSTATE_DUCK, false);
 650                                 else if(this.anim_state & ANIMSTATE_DUCK)
 651                                         animdecide_setstate(this, this.anim_state - ANIMSTATE_DUCK, false);
 652                         }
 653                         else
 654                         {
 655                                 tracebox(this.origin + '0 0 1', this.mins, this.maxs, this.origin - '0 0 4', MOVE_NORMAL, this);
 656                                 if(trace_startsolid || trace_fraction < 1)
 657                                         onground = 1;
 658                         }
 659                         animdecide_load_if_needed(this);
 660                         animdecide_setimplicitstate(this, onground);
 661                         animdecide_setframes(this, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
 662                         int sf = 0;
 663                         if(this.anim_saveframe != this.anim_frame || this.anim_saveframe1time != this.anim_frame1time)
 664                                 sf |= CSQCMODEL_PROPERTY_FRAME;
 665                         if(this.anim_saveframe2 != this.anim_frame2 || this.anim_saveframe2time != this.anim_frame2time)
 666                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
 667                         this.anim_saveframe = this.anim_frame;
 668                         this.anim_saveframe1time = this.anim_frame1time;
 669                         this.anim_saveframe2 = this.anim_frame2;
 670                         this.anim_saveframe2time = this.anim_frame2time;
 671                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
 672                         // This ensures that .frame etc. are always written.
 673                         CSQCModel_InterpolateAnimation_2To4_PreNote(this, sf | CSQCMODEL_PROPERTY_LERPFRAC);
 674                         this.lerpfrac = (doblend ? 0.5 : 0);
 675                         this.frame = this.anim_frame;
 676                         this.frame1time = this.anim_frame1time;
 677                         this.frame2 = this.anim_frame2;
 678                         this.frame2time = this.anim_frame2time;
 679                         CSQCModel_InterpolateAnimation_2To4_Note(this, sf | CSQCMODEL_PROPERTY_LERPFRAC, false);
 680                         CSQCModel_InterpolateAnimation_2To4_Do(this);
 681                         if(doblend)
 682                         {
 683                                 skeleton_from_frames(this, this.csqcmodel_isdead);
 684                         }
 685                         else
 686                         {
 687                                 free_skeleton_from_frames(this);
 688                                 // just in case, clear these (we're animating in frame and frame3)
 689                                 this.lerpfrac = 0;
 690                                 this.lerpfrac4 = 0;
 691                         }
 692                 }
 693         }
 694         else
 695                 CSQCPlayer_LOD_Apply(this, false);
 696
 697         CSQCModel_AutoTagIndex_Apply(this);
 698
 699         CSQCModel_Effects_Apply(this);
 700 }
 701
 702 void CSQCModel_Hook_PreUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 703 {
 704         // interpolate v_angle
 705         this.iflags |= IFLAG_V_ANGLE_X;
 706         // revert to values from server
 707         CSQCModel_Effects_PreUpdate(this);
 708         if((this.isplayermodel & ISPLAYER_MODEL))
 709         {
 710                 if(!isplayer)
 711                         CSQCPlayer_FallbackFrame_PreUpdate(this);
 712                 CSQCPlayer_ModelAppearance_PreUpdate(this);
 713         }
 714 }
 715
 716 void CSQCModel_Hook_PostUpdate(entity this, bool isnew, bool isplayer, bool islocalplayer)
 717 {
 718         // is it a player model? (shared state)
 719         bool is_playermodel = (substring(this.model, 0, 14) == "models/player/" || substring(this.model, 0, 17) == "models/ok_player/" ||
 720                                                         (substring(this.model, 0, 16) == "models/monsters/" && (this.isplayermodel & BIT(1))));
 721         this.isplayermodel = BITSET(this.isplayermodel, ISPLAYER_MODEL, is_playermodel);
 722
 723         // save values set by server
 724         if((this.isplayermodel & ISPLAYER_MODEL))
 725         {
 726                 CSQCPlayer_ModelAppearance_PostUpdate(this);
 727                 if(isplayer)
 728                         CSQCPlayer_AnimDecide_PostUpdate(this, isnew);
 729                 else
 730                         CSQCPlayer_FallbackFrame_PostUpdate(this, isnew);
 731         }
 732         CSQCModel_Effects_PostUpdate(this);
 733 }