qcsrc/client/command/cl_cmd.qc

   1 // ==============================================
   2 //  CSQC client commands code, written by Samual
   3 //  Last updated: December 28th, 2011
   4 // ==============================================
   5
   6 void DrawDebugModel()
   7 {
   8         if(time - floor(time) > 0.5)
   9         {
  10                 PolyDrawModel(self);
  11                 self.drawmask = 0;
  12         }
  13         else
  14         {
  15                 self.renderflags = 0;
  16                 self.drawmask = MASK_NORMAL;
  17         }
  18 }
  19
  20
  21 // =======================
  22 //  Command Sub-Functions
  23 // =======================
  24
  25 void LocalCommand_blurtest(float request)
  26 {
  27         // Simple command to work with postprocessing temporarily... possibly completely pointless, the glsl shader is used for a real feature now...
  28         // Anyway, to enable it, just compile the client with -DBLURTEST and then you can use the command.
  29
  30         #ifdef BLURTEST
  31         switch(request)
  32         {
  33                 case CMD_REQUEST_COMMAND:
  34                 {
  35                         blurtest_time0 = time;
  36                         blurtest_time1 = time + stof(argv(1));
  37                         blurtest_radius = stof(argv(2));
  38                         blurtest_power = stof(argv(3));
  39                         print("Enabled blurtest\n");
  40                         return;
  41                 }
  42
  43                 default:
  44                 case CMD_REQUEST_USAGE:
  45                 {
  46                         print("\nUsage:^3 cl_cmd blurtest\n");
  47                         print("  No arguments required.\n");
  48                         return;
  49                 }
  50         }
  51         #else
  52         if(request)
  53         {
  54                 print("Blurtest is not enabled on this client.\n");
  55                 return;
  56         }
  57         #endif
  58 }
  59
  60 void LocalCommand_boxparticles(float request, float argc)
  61 {
  62         switch(request)
  63         {
  64                 case CMD_REQUEST_COMMAND:
  65                 {
  66                         if (argc == 9)
  67                         {
  68                                 float effect = particleeffectnum(argv(1));
  69                                 if (effect >= 0)
  70                                 {
  71                                         float index = stof(argv(2));
  72                                         entity own;
  73                                         if(index <= 0)
  74                                                 own = entitybyindex(-index);
  75                                         else
  76                                                 own = findfloat(world, entnum, index);
  77                                         vector org_from = stov(argv(3));
  78                                         vector org_to = stov(argv(4));
  79                                         vector dir_from = stov(argv(5));
  80                                         vector dir_to = stov(argv(6));
  81                                         float countmultiplier = stof(argv(7));
  82                                         float flags = stof(argv(8));
  83                                         boxparticles(effect, own, org_from, org_to, dir_from, dir_to, countmultiplier, flags);
  84                                         return;
  85                                 }
  86                         }
  87                 }
  88
  89                 default:
  90                         print("Incorrect parameters for ^2boxparticles^7\n");
  91                 case CMD_REQUEST_USAGE:
  92                 {
  93                         print("\nUsage:^3 lv_cmd boxparticles effectname own org_from org_to, dir_from, dir_to, countmultiplier, flags\n");
  94                         print("  'effectname' is the name of a particle effect in effectinfo.txt\n");
  95                         print("  'own' is the entity number of the owner (negative for csqc ent, positive for svqc ent)\n");
  96                         print("  'org_from' is the starting origin of the box\n");
  97                         print("  'org_to' is the ending origin of the box\n");
  98                         print("  'dir_from' is the minimum velocity\n");
  99                         print("  'dir_to' is the maximum velocity\n");
 100                         print("  'countmultiplier' defines a multiplier for the particle count (affects count only, not countabsolute or trailspacing)\n");
 101                         print("  'flags' can contain:\n");
 102                         print("    1 to respect globals particles_alphamin, particles_alphamax (set right before via prvm_globalset client)\n");
 103                         print("    2 to respect globals particles_colormin, particles_colormax (set right before via prvm_globalset client)\n");
 104                         print("    4 to respect globals particles_fade (set right before via prvm_globalset client)\n");
 105                         print("    128 to draw a trail, not a box\n");
 106                         return;
 107                 }
 108         }
 109 }
 110
 111 void LocalCommand_create_scrshot_ent(float request)
 112 {
 113         switch(request)
 114         {
 115                 case CMD_REQUEST_COMMAND:
 116                 {
 117                         float fh;
 118                         string filename = strcat(MapInfo_Map_bspname, "_scrshot_ent.txt");
 119                         fh = fopen(filename, FILE_WRITE);
 120
 121                         if(fh >= 0)
 122                         {
 123                                 fputs(fh, "{\n");
 124                                 fputs(fh, strcat("\"classname\" \"info_autoscreenshot\"\n"));
 125                                 fputs(fh, strcat("\"origin\" \"", strcat(ftos(view_origin_x), " ", ftos(view_origin_y), " ", ftos(view_origin_z)), "\"\n"));
 126                                 fputs(fh, strcat("\"angles\" \"", strcat(ftos(view_angles_x), " ", ftos(view_angles_y), " ", ftos(view_angles_z)), "\"\n"));
 127                                 fputs(fh, "}\n");
 128
 129                                 print("Completed screenshot entity dump in ^2data/data/", MapInfo_Map_bspname, "_scrshot_ent.txt^7.\n");
 130
 131                                 fclose(fh);
 132                         }
 133                         else
 134                         {
 135                                 print("^1Error: ^7Could not dump to file!\n");
 136                         }
 137                         return;
 138                 }
 139
 140                 default:
 141                 case CMD_REQUEST_USAGE:
 142                 {
 143                         print("\nUsage:^3 cl_cmd create_scrshot_ent\n");
 144                         print("  No arguments required.\n");
 145                         return;
 146                 }
 147         }
 148 }
 149
 150 void LocalCommand_debugmodel(float request, float argc)
 151 {
 152         switch(request)
 153         {
 154                 case CMD_REQUEST_COMMAND:
 155                 {
 156                         string modelname = argv(1);
 157                         entity debugmodel_entity;
 158
 159                         debugmodel_entity = spawn();
 160                         precache_model(modelname);
 161                         setmodel(debugmodel_entity, modelname);
 162                         setorigin(debugmodel_entity, view_origin);
 163                         debugmodel_entity.angles = view_angles;
 164                         debugmodel_entity.draw = DrawDebugModel;
 165                         debugmodel_entity.classname = "debugmodel";
 166
 167                         return;
 168                 }
 169
 170                 default:
 171                 case CMD_REQUEST_USAGE:
 172                 {
 173                         print("\nUsage:^3 cl_cmd debugmodel model\n");
 174                         print("  Where 'model' is a string of the model name to use for the debug model.\n");
 175                         return;
 176                 }
 177         }
 178 }
 179
 180 void LocalCommand_handlevote(float request, float argc)
 181 {
 182         switch(request)
 183         {
 184                 case CMD_REQUEST_COMMAND:
 185                 {
 186                         float vote_selection;
 187                         string vote_string;
 188
 189                         if(InterpretBoolean(argv(1)))
 190                         {
 191                                 vote_selection = 2;
 192                                 vote_string = "yes";
 193                         }
 194                         else
 195                         {
 196                                 vote_selection = 1;
 197                                 vote_string = "no";
 198                         }
 199
 200                         if(vote_selection)
 201                         {
 202                                 if(uid2name_dialog) // handled by "uid2name" option
 203                                 {
 204                                         vote_active = 0;
 205                                         vote_prev = 0;
 206                                         vote_change = -9999;
 207                                         localcmd(strcat("setreport cl_allow_uid2name ", ftos(vote_selection - 1), "\n"));
 208                                         uid2name_dialog = 0;
 209                                 }
 210                                 else { localcmd(strcat("cmd vote ", vote_string, "\n")); }
 211
 212                                 return;
 213                         }
 214                 }
 215
 216                 default:
 217                         print("Incorrect parameters for ^2handlevote^7\n");
 218                 case CMD_REQUEST_USAGE:
 219                 {
 220                         print("\nUsage:^3 cl_cmd handlevote vote\n");
 221                         print("  Where 'vote' is the selection for either the current poll or uid2name.\n");
 222                         return;
 223                 }
 224         }
 225 }
 226
 227 void LocalCommand_hud(float request, float argc)
 228 {
 229         switch(request)
 230         {
 231                 case CMD_REQUEST_COMMAND:
 232                 {
 233                         switch(argv(1))
 234                         {
 235                                 case "configure":
 236                                 {
 237                                         cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 238                                         return;
 239                                 }
 240
 241                                 case "save":
 242                                 {
 243                                         if(argv(2))
 244                                         {
 245                                                 HUD_Panel_ExportCfg(argv(2));
 246                                                 return;
 247                                         }
 248                                         else
 249                                         {
 250                                                 break; // go to usage, we're missing the paramater needed here.
 251                                         }
 252                                 }
 253
 254                                 case "scoreboard_columns_set":
 255                                 {
 256                                         Cmd_HUD_SetFields(argc);
 257                                         return;
 258                                 }
 259
 260                                 case "scoreboard_columns_help":
 261                                 {
 262                                         Cmd_HUD_Help();
 263                                         return;
 264                                 }
 265
 266                                 case "radar":
 267                                 {
 268                                         if(argv(2))
 269                                                 HUD_Radar_Show_Maximized(InterpretBoolean(argv(2)),0);
 270                                         else
 271                                                 HUD_Radar_Show_Maximized(!hud_panel_radar_maximized,0);
 272                                         return;
 273                                 }
 274
 275                                 case "clickradar":
 276                                 {
 277                                         HUD_Radar_Show_Maximized(!hud_panel_radar_mouse,1);
 278                                         return;
 279                                 }
 280                         }
 281                 }
 282
 283                 default:
 284                         print("Incorrect parameters for ^2hud^7\n");
 285                 case CMD_REQUEST_USAGE:
 286                 {
 287                         print("\nUsage:^3 cl_cmd hud action [configname | radartoggle | layout]\n");
 288                         print("  Where 'action' is the command to complete,\n");
 289                         print("  'configname' is the name to save to for \"save\" action,\n");
 290                         print("  'radartoggle' is to control hud_panel_radar_maximized for \"radar\" action,\n");
 291                         print("  and 'layout' is how to organize the scoreboard columns for the set action.\n");
 292                         print("  Full list of commands here: \"configure, save, scoreboard_columns_help, scoreboard_columns_set, radar.\"\n");
 293                         return;
 294                 }
 295         }
 296 }
 297
 298 void LocalCommand_localprint(float request, float argc)
 299 {
 300         switch(request)
 301         {
 302                 case CMD_REQUEST_COMMAND:
 303                 {
 304                         if(argv(1))
 305                         {
 306                                 centerprint_hud(argv(1));
 307                                 return;
 308                         }
 309                 }
 310
 311                 default:
 312                         print("Incorrect parameters for ^2localprint^7\n");
 313                 case CMD_REQUEST_USAGE:
 314                 {
 315                         print("\nUsage:^3 cl_cmd localprint \"message\"\n");
 316                         print("  'message' is the centerprint message to send to yourself.\n");
 317                         return;
 318                 }
 319         }
 320 }
 321
 322 void LocalCommand_mv_download(float request, float argc)
 323 {
 324         switch(request)
 325         {
 326                 case CMD_REQUEST_COMMAND:
 327                 {
 328                         if(argv(1))
 329                         {
 330                                 Cmd_MapVote_MapDownload(argc);
 331                                 return;
 332                         }
 333                 }
 334
 335                 default:
 336                         print("Incorrect parameters for ^2mv_download^7\n");
 337                 case CMD_REQUEST_USAGE:
 338                 {
 339                         print("\nUsage:^3 cl_cmd mv_download mapid\n");
 340                         print("  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 341                         return;
 342                 }
 343         }
 344 }
 345
 346 void LocalCommand_sendcvar(float request, float argc)
 347 {
 348         switch(request)
 349         {
 350                 case CMD_REQUEST_COMMAND:
 351                 {
 352                         if(argv(1))
 353                         {
 354                                 // W_FixWeaponOrder will trash argv, so save what we need.
 355                                 string thiscvar = strzone(argv(1));
 356                                 string s = cvar_string(thiscvar);
 357
 358                                 if(thiscvar == "cl_weaponpriority")
 359                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 360                                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 361                                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 362
 363                                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 364                                 strunzone(thiscvar);
 365                                 return;
 366                         }
 367                 }
 368
 369                 default:
 370                         print("Incorrect parameters for ^2sendcvar^7\n");
 371                 case CMD_REQUEST_USAGE:
 372                 {
 373                         print("\nUsage:^3 cl_cmd sendcvar <cvar>\n");
 374                         print("  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 375                         return;
 376                 }
 377         }
 378 }
 379
 380 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 381 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 382 void LocalCommand_(float request)
 383 {
 384         switch(request)
 385         {
 386                 case CMD_REQUEST_COMMAND:
 387                 {
 388
 389                         return;
 390                 }
 391
 392                 default:
 393                 case CMD_REQUEST_USAGE:
 394                 {
 395                         print("\nUsage:^3 cl_cmd \n");
 396                         print("  No arguments required.\n");
 397                         return;
 398                 }
 399         }
 400 }
 401 */
 402
 403
 404 // ==================================
 405 //  Macro system for client commands
 406 // ==================================
 407
 408 // Normally do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 409 #define CLIENT_COMMANDS(request,arguments) \
 410         CLIENT_COMMAND("blurtest", LocalCommand_blurtest(request), "Feature for testing blur postprocessing") \
 411         CLIENT_COMMAND("boxparticles", LocalCommand_boxparticles(request, arguments), "Spawn particles manually") \
 412         CLIENT_COMMAND("create_scrshot_ent", LocalCommand_create_scrshot_ent(request), "Create an entity at this location for automatic screenshots") \
 413         CLIENT_COMMAND("debugmodel", LocalCommand_debugmodel(request, arguments), "Spawn a debug model manually") \
 414         CLIENT_COMMAND("handlevote", LocalCommand_handlevote(request, arguments), "System to handle selecting a vote or option") \
 415         CLIENT_COMMAND("hud", LocalCommand_hud(request, arguments), "Commands regarding/controlling the HUD system") \
 416         CLIENT_COMMAND("localprint", LocalCommand_localprint(request, arguments), "Create your own centerprint sent to yourself") \
 417         CLIENT_COMMAND("mv_download", LocalCommand_mv_download(request, arguments), "Retrieve mapshot picture from the server") \
 418         CLIENT_COMMAND("sendcvar", LocalCommand_sendcvar(request, arguments), "Send a cvar to the server (like weaponpriority)") \
 419         /* nothing */
 420
 421 void LocalCommand_macro_help()
 422 {
 423         #define CLIENT_COMMAND(name,function,description) \
 424                 { if(strtolower(description) != "") { print("  ^2", name, "^7: ", description, "\n"); } }
 425
 426         CLIENT_COMMANDS(0, 0)
 427         #undef CLIENT_COMMAND
 428
 429         return;
 430 }
 431
 432 float LocalCommand_macro_command(float argc)
 433 {
 434         #define CLIENT_COMMAND(name,function,description) \
 435                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 436
 437         CLIENT_COMMANDS(CMD_REQUEST_COMMAND, argc)
 438         #undef CLIENT_COMMAND
 439
 440         return FALSE;
 441 }
 442
 443 float LocalCommand_macro_usage(float argc)
 444 {
 445         #define CLIENT_COMMAND(name,function,description) \
 446                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 447
 448         CLIENT_COMMANDS(CMD_REQUEST_USAGE, argc)
 449         #undef CLIENT_COMMAND
 450
 451         return FALSE;
 452 }
 453
 454 void LocalCommand_macro_write_aliases(float fh)
 455 {
 456         #define CLIENT_COMMAND(name,function,description) \
 457                 { if(strtolower(description) != "") { CMD_Write_Alias("qc_cmd_cl", name, description); } }
 458
 459         CLIENT_COMMANDS(0, 0)
 460         #undef CLIENT_COMMAND
 461
 462         return;
 463 }
 464
 465
 466 // =========================================
 467 //  Main Function Called By Engine (cl_cmd)
 468 // =========================================
 469 // If this function exists, client code handles gamecommand instead of the engine code.
 470
 471 void GameCommand(string command)
 472 {
 473         float argc = tokenize_console(command);
 474
 475         // Guide for working with argc arguments by example:
 476         // argc:   1    - 2      - 3     - 4
 477         // argv:   0    - 1      - 2     - 3
 478         // cmd     vote - master - login - password
 479
 480         if(strtolower(argv(0)) == "help")
 481         {
 482                 if(argc == 1)
 483                 {
 484                         print("\nClient console commands:\n");
 485                         LocalCommand_macro_help();
 486
 487                         print("\nGeneric commands shared by all programs:\n");
 488                         GenericCommand_macro_help();
 489
 490                         print("\nUsage:^3 cl_cmd COMMAND...^7, where possible commands are listed above.\n");
 491                         print("For help about a specific command, type cl_cmd help COMMAND\n");
 492
 493                         return;
 494                 }
 495                 else if(GenericCommand_macro_usage(argc)) // Instead of trying to call a command, we're going to see detailed information about it
 496                 {
 497                         return;
 498                 }
 499                 else if(LocalCommand_macro_usage(argc)) // now try for normal commands too
 500                 {
 501                         return;
 502                 }
 503         }
 504         else if(GenericCommand(command))
 505         {
 506                 return; // handled by common/command/generic.qc
 507         }
 508         else if(LocalCommand_macro_command(argc)) // continue as usual and scan for normal commands
 509         {
 510                 return; // handled by one of the above LocalCommand_* functions
 511         }
 512
 513         // nothing above caught the command, must be invalid
 514         print(((command != "") ? strcat("Unknown client command \"", command, "\"") : "No command provided"), ". For a list of supported commands, try cl_cmd help.\n");
 515
 516         return;
 517 }
 518
 519
 520 // ===================================
 521 //  Macro system for console commands
 522 // ===================================
 523
 524 // These functions are here specifically to add special + - commands to the game, and are not really normal commands.
 525 // Please add client commands to the function above this, as this is only for special reasons.
 526 #define CONSOLE_COMMANDS_NORMAL \
 527         CONSOLE_COMMAND("+showscores", { scoreboard_showscores = TRUE; }) \
 528         CONSOLE_COMMAND("-showscores", { scoreboard_showscores = FALSE; }) \
 529         CONSOLE_COMMAND("+showaccuracy", { scoreboard_showaccuracy = TRUE; }) \
 530         CONSOLE_COMMAND("-showaccuracy", { scoreboard_showaccuracy = FALSE; }) \
 531         /* nothing */
 532
 533 #define CONSOLE_COMMANDS_MOVEMENT \
 534         CONSOLE_COMMAND("+forward", { ++camera_direction_x; }) \
 535         CONSOLE_COMMAND("-forward", { --camera_direction_x; }) \
 536         CONSOLE_COMMAND("+back", { --camera_direction_x; }) \
 537         CONSOLE_COMMAND("-back", { ++camera_direction_x; }) \
 538         CONSOLE_COMMAND("+moveup", { ++camera_direction_z; }) \
 539         CONSOLE_COMMAND("-moveup", { --camera_direction_z; }) \
 540         CONSOLE_COMMAND("+movedown", { --camera_direction_z; }) \
 541         CONSOLE_COMMAND("-movedown", { ++camera_direction_z; }) \
 542         CONSOLE_COMMAND("+moveright", { --camera_direction_y; }) \
 543         CONSOLE_COMMAND("-moveright", { ++camera_direction_y; }) \
 544         CONSOLE_COMMAND("+moveleft", { ++camera_direction_y; }) \
 545         CONSOLE_COMMAND("-moveleft", { --camera_direction_y; }) \
 546         CONSOLE_COMMAND("+roll_right", { ++camera_roll; }) \
 547         CONSOLE_COMMAND("-roll_right", { --camera_roll; }) \
 548         CONSOLE_COMMAND("+roll_left", { --camera_roll; }) \
 549         CONSOLE_COMMAND("-roll_left", { ++camera_roll; }) \
 550         /* nothing */
 551
 552 void ConsoleCommand_macro_init()
 553 {
 554         // first init normal commands
 555         #define CONSOLE_COMMAND(name,execution) \
 556                 { registercommand(name); }
 557
 558         CONSOLE_COMMANDS_NORMAL
 559         #undef CONSOLE_COMMAND
 560
 561         // then init movement commands
 562         #ifndef CAMERATEST
 563         if(isdemo())
 564         {
 565         #endif
 566                 #define CONSOLE_COMMAND(name,execution) \
 567                         { registercommand(name); }
 568
 569                 CONSOLE_COMMANDS_MOVEMENT
 570                 #undef CONSOLE_COMMAND
 571         #ifndef CAMERATEST
 572         }
 573         #endif
 574
 575         return;
 576 }
 577
 578 float ConsoleCommand_macro_normal(float argc)
 579 {
 580         #define CONSOLE_COMMAND(name,execution) \
 581                 { if(name == strtolower(argv(0))) { { execution } return TRUE; } }
 582
 583         CONSOLE_COMMANDS_NORMAL
 584         #undef CONSOLE_COMMAND
 585
 586         return FALSE;
 587 }
 588
 589 float ConsoleCommand_macro_movement(float argc)
 590 {
 591         if(camera_active)
 592         {
 593                 #define CONSOLE_COMMAND(name,execution) \
 594                         { if(name == strtolower(argv(0))) { { execution } return TRUE; } }
 595
 596                 CONSOLE_COMMANDS_MOVEMENT
 597                 #undef CONSOLE_COMMAND
 598         }
 599
 600         return FALSE;
 601 }
 602
 603
 604 // ======================================================
 605 //  Main Function Called By Engine (registered commands)
 606 // ======================================================
 607 // Used to parse commands in the console that have been registered with the "registercommand" function
 608
 609 float CSQC_ConsoleCommand(string command)
 610 {
 611         float argc = tokenize_console(command);
 612
 613         if(ConsoleCommand_macro_normal(argc))
 614         {
 615                 return TRUE;
 616         }
 617         else if(ConsoleCommand_macro_movement(argc))
 618         {
 619                 return TRUE;
 620         }
 621
 622         // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 623
 624         return FALSE;
 625 }