qcsrc/client/announcer.qc

   1 float previous_announcement_time;
   2 float previous_game_starttime;
   3 string previous_announcement;
   4
   5 // remaining maptime announcer sounds, true when sound was already played
   6 float announcer_1min;
   7 float announcer_5min;
   8
   9 void Announcer_Play(string announcement)
  10 {
  11         if((announcement != previous_announcement) || (time >= (previous_announcement_time + autocvar_cl_announcer_antispam)))
  12         {
  13                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", announcement, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  14
  15                 if(previous_announcement) { strunzone(previous_announcement); }
  16
  17                 previous_announcement = strzone(announcement);
  18                 previous_announcement_time = time;
  19         }
  20 }
  21
  22 void Announcer_Countdown()
  23 {
  24         float starttime = getstatf(STAT_GAMESTARTTIME);
  25         float roundstarttime = getstatf(STAT_ROUNDSTARTTIME);
  26         if(roundstarttime == -1)
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if(roundstarttime >= starttime)
  32                 starttime = roundstarttime;
  33         if(starttime <= time && roundstarttime != starttime) // game start time has passed
  34                 announcer_5min = announcer_1min = FALSE; // reset maptime announcers now as well
  35
  36         float countdown = (starttime - time);
  37         float countdown_rounded = floor(0.5 + countdown);
  38
  39         if(countdown <= 0) // countdown has finished, starttime is now
  40         {
  41                 Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_BEGIN);
  42
  43                 Announcer_Play("begin");
  44                 remove(self);
  45                 return;
  46         }
  47         else // countdown is still going
  48         {
  49                 if(roundstarttime == starttime)
  50                         Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_ROUNDSTART, countdown_rounded);
  51                 else
  52                         Local_Notification(MSG_CENTER, CENTER_COUNTDOWN_GAMESTART, countdown_rounded);
  53
  54                 if(countdown_rounded <= 3 && countdown_rounded >= 1)
  55                         Announcer_Play(ftos(countdown_rounded));
  56
  57                 self.nextthink = (starttime - (countdown - 1));
  58         }
  59 }
  60
  61 /**
  62  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  63  *
  64  * TODO: Use a better solution where a common shared entitiy is used that contains
  65  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  66  * and STAT_FRAGLIMIT to be auto-sent)
  67  */
  68 void Announcer_Gamestart()
  69 {
  70         float startTime = getstatf(STAT_GAMESTARTTIME);
  71         float roundstarttime = getstatf(STAT_ROUNDSTARTTIME);
  72         if(roundstarttime > startTime)
  73                 startTime = roundstarttime;
  74
  75         if(previous_game_starttime != startTime)
  76         {
  77                 if((time + 5.0) < startTime) // if connecting to server while restart was active don't always play prepareforbattle
  78                         Announcer_Play("prepareforbattle");
  79
  80                 if(time < startTime)
  81                 {
  82                         entity e;
  83                         e = spawn();
  84                         e.think = Announcer_Countdown;
  85                         e.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
  86                 }
  87         }
  88
  89         previous_game_starttime = startTime;
  90 }
  91
  92
  93 // Plays the 1 minute or 5 minutes (of maptime) remaining sound, if client wants it
  94 void Announcer_Time()
  95 {
  96         float timelimit = getstatf(STAT_TIMELIMIT);
  97         float timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  98         float warmup_timeleft = 0;
  99
 100         if(warmup_stage)
 101                 if(autocvar_g_warmup_limit > 0)
 102                         warmup_timeleft = max(0, autocvar_g_warmup_limit + getstatf(STAT_GAMESTARTTIME) - time);
 103
 104         // 5 minute check
 105         if(autocvar_cl_announcer_maptime >= 2)
 106         {
 107                 // make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
 108                 if(announcer_5min)
 109                 {
 110                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 300)
 111                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 300))
 112                                         announcer_5min = FALSE;
 113                 }
 114                 else
 115                 {
 116                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299)
 117                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 300 && warmup_timeleft > 299))
 118                         {
 119                                 //if we're in warmup mode, check whether there's a warmup timelimit
 120                                 if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 121                                 {
 122                                         announcer_5min = TRUE;
 123                                         Announcer_Play("5minutesremain");
 124                                 }
 125                         }
 126                 }
 127         }
 128
 129         // 1 minute check
 130         if((autocvar_cl_announcer_maptime == 1) || (autocvar_cl_announcer_maptime == 3))
 131         {
 132                 if (announcer_1min)
 133                 {
 134                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 60)
 135                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 60))
 136                                         announcer_1min = FALSE;
 137                 }
 138                 else if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 60)
 139                         || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 60))
 140                 {
 141                         // if we're in warmup mode, check whether there's a warmup timelimit
 142                         if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 143                         {
 144                                 announcer_1min = TRUE;
 145                                 Announcer_Play("1minuteremains");
 146                         }
 147                 }
 148         }
 149 }
 150
 151 void Announcer()
 152 {
 153         Announcer_Gamestart();
 154         Announcer_Time();
 155 }
 156
 157 void Announcer_Precache ()
 158 {
 159         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 160         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 161
 162         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 163         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 164         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 165         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 166         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 167         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 168         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 169         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 170         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 171         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 172         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 173         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 174         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 175         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 176
 177         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 178         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 179         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 180         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 181         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 182         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 183         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 184
 185         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 186         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 187         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 188         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 189         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 190         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 191         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 192         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 193         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 194         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 195
 196         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 197         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 198
 199         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 200         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 201         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 202 }