qcsrc/client/announcer.qc

   1 float previous_announcement_time;
   2 float previous_game_starttime;
   3 string previous_announcement;
   4
   5 //remaining maptime announcer sounds, true when sound was already played
   6 float announcer_1min;
   7 float announcer_5min;
   8
   9 void Announcer_Play(string announcement)
  10 {
  11         if((announcement != previous_announcement) || (time >= (previous_announcement_time + autocvar_cl_announcer_antispam)))
  12         {
  13                 sound(world, CH_INFO, strcat("announcer/", autocvar_cl_announcer, "/", announcement, ".wav"), VOL_BASEVOICE, ATTN_NONE);
  14
  15                 previous_announcement = announcement;
  16                 previous_announcement_time = time;
  17         }
  18 }
  19
  20 void Announcer_Countdown()
  21 {
  22         float starttime = getstatf(STAT_GAMESTARTTIME);
  23         float countdown = (starttime - time);
  24         float countdown_rounded = floor(0.5 + countdown);
  25
  26         if(countdown <= 0) // countdown has finished, starttime is now
  27         {
  28                 if (!spectatee_status)
  29                         centerprint_generic(CPID_GAME_STARTING, _("^1Begin!"), 1, 0);
  30
  31                 Announcer_Play("begin");
  32                 announcer_5min = announcer_1min = FALSE; // reset maptime announcers now as well
  33                 remove(self);
  34                 return;
  35         }
  36         else // countdown is still going
  37         {
  38                 if (!spectatee_status)
  39                         centerprint_generic(CPID_GAME_STARTING, _("^1Game starts in %d seconds"), 1, countdown_rounded);
  40
  41                 if(countdown_rounded <= 3 && countdown_rounded >= 1)
  42                         Announcer_Play(ftos(countdown_rounded));
  43
  44                 self.nextthink = (starttime - (countdown - 1));
  45         }
  46 }
  47
  48 /**
  49  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  50  *
  51  * TODO: Use a better solution where a common shared entitiy is used that contains
  52  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  53  * and STAT_FRAGLIMIT to be auto-sent)
  54  */
  55 void Announcer_Gamestart()
  56 {
  57         float startTime = getstatf(STAT_GAMESTARTTIME);
  58
  59         if(previous_game_starttime != startTime)
  60         {
  61                 if((time + 5.0) < startTime) // if connecting to server while restart was active don't always play prepareforbattle
  62                         Announcer_Play("prepareforbattle");
  63
  64                 if(time < startTime)
  65                 {
  66                         entity e;
  67                         e = spawn();
  68                         e.think = Announcer_Countdown;
  69                         e.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
  70                 }
  71         }
  72
  73         previous_game_starttime = startTime;
  74 }
  75
  76 /**
  77  * Plays the 1minute or 5 minutes (of maptime) remaining sound, if client wants it
  78  */
  79 void Announcer_Time()
  80 {
  81         float timelimit = getstatf(STAT_TIMELIMIT);
  82         float timeleft = max(0, timelimit * 60 + getstatf(STAT_GAMESTARTTIME) - time);
  83         float warmup_timeleft;
  84
  85         if(warmup_stage)
  86                 if(autocvar_g_warmup_limit > 0)
  87                         warmup_timeleft = max(0, autocvar_g_warmup_limit + getstatf(STAT_GAMESTARTTIME) - time);
  88
  89         // 5 minute check
  90         if(autocvar_cl_announcer_maptime >= 2)
  91         {
  92                 // make sure that after connect (and e.g. 4 minutes left) we will not get a wrong sound
  93                 if(announcer_5min)
  94                 {
  95                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 300)
  96                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 300))
  97                                         announcer_5min = FALSE;
  98                 }
  99                 else
 100                 {
 101                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 300 && timeleft > 299)
 102                                 || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 300 && warmup_timeleft > 299))
 103                         {
 104                                 //if we're in warmup mode, check whether there's a warmup timelimit
 105                                 if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 106                                 {
 107                                         announcer_5min = TRUE;
 108                                         Announcer_Play("5minutesremain");
 109                                 }
 110                         }
 111                 }
 112         }
 113
 114         // 1 minute check
 115         if((autocvar_cl_announcer_maptime == 1) || (autocvar_cl_announcer_maptime == 3))
 116         {
 117                 if (announcer_1min)
 118                 {
 119                         if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timeleft > 60) || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft > 60))
 120                                 announcer_1min = FALSE;
 121                 }
 122                 else if(((!warmup_stage || autocvar_g_warmup_limit == 0) && timelimit > 0 && timeleft < 60) || (warmup_stage && autocvar_g_warmup_limit > 0 && warmup_timeleft < 60))
 123                 {
 124                         //if we're in warmup mode, check whether there's a warmup timelimit
 125                         if not(autocvar_g_warmup_limit == -1 && warmup_stage)
 126                         {
 127                                 announcer_1min = TRUE;
 128                                 Announcer_Play("1minuteremains");
 129                         }
 130                 }
 131         }
 132 }
 133
 134 /**
 135  * Announce carried items (e.g. flags in CTF).
 136  */
 137 float redflag_prev;
 138 float blueflag_prev;
 139 void carrierAnnouncer() {
 140         float stat_items, redflag, blueflag;
 141         float pickup;
 142         string item;
 143
 144         if not(autocvar_cl_notify_carried_items)
 145                 return;
 146
 147         stat_items = getstati(STAT_ITEMS);
 148
 149         redflag = (stat_items/IT_RED_FLAG_TAKEN) & 3;
 150         blueflag = (stat_items/IT_BLUE_FLAG_TAKEN) & 3;
 151
 152         if (redflag == 3 && redflag != redflag_prev) {
 153                 item = _("^1RED^7 flag");
 154                 pickup = (redflag_prev == 2);
 155         }
 156
 157         if (blueflag == 3 && blueflag != blueflag_prev) {
 158                 item = _("^4BLUE^7 flag");
 159                 pickup = (blueflag_prev == 2);
 160         }
 161
 162         if (item)
 163         {
 164                 if (pickup) {
 165                         if (autocvar_cl_notify_carried_items & 2)
 166                                 centerprint(sprintf(_("You picked up the %s!"), item));
 167                 }
 168                 else {
 169                         if (autocvar_cl_notify_carried_items & 1)
 170                                 centerprint(sprintf(_("You got the %s!"), item));
 171                 }
 172         }
 173
 174         blueflag_prev = blueflag;
 175         redflag_prev = redflag;
 176 }
 177
 178 void Announcer()
 179 {
 180         Announcer_Gamestart();
 181         Announcer_Time();
 182         carrierAnnouncer();
 183 }
 184
 185 /**
 186  * Add all future announcer sounds precaches here.
 187  * TODO: announcer queues
 188  */
 189 void Announcer_Precache () {
 190         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1minuteremains.wav"));
 191         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5minutesremain.wav"));
 192
 193         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/electrobitch.wav"));
 194         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/airshot.wav"));
 195         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/03kills.wav"));
 196         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/05kills.wav"));
 197         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10kills.wav"));
 198         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/15kills.wav"));
 199         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/20kills.wav"));
 200         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/25kills.wav"));
 201         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/30kills.wav"));
 202         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/botlike.wav"));
 203         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/yoda.wav"));
 204         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/amazing.wav"));
 205         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/awesome.wav"));
 206         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/headshot.wav"));
 207         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/impressive.wav"));
 208
 209         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"));
 210         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/begin.wav"));
 211         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/timeoutcalled.wav"));
 212         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1fragleft.wav"));
 213         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2fragsleft.wav"));
 214         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3fragsleft.wav"));
 215         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/terminated.wav"));
 216
 217         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/1.wav"));
 218         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/2.wav"));
 219         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/3.wav"));
 220         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/4.wav"));
 221         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/5.wav"));
 222         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/6.wav"));
 223         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/7.wav"));
 224         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/8.wav"));
 225         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/9.wav"));
 226         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/10.wav"));
 227
 228         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/lastsecond.wav"));
 229         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/narrowly.wav"));
 230
 231         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/voteaccept.wav"));
 232         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votecall.wav"));
 233         precache_sound (strcat("announcer/", autocvar_cl_announcer, "/votefail.wav"));
 234 }