qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 void Porto_Init()
  84 {
  85         porto = spawn();
  86         porto.classname = "porto";
  87         porto.draw = Porto_Draw;
  88         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  89 }
  90
  91 float drawtime;
  92 float avgspeed;
  93 vector GetCurrentFov(float fov)
  94 {
  95         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  96         float velocityzoom, curspeed;
  97
  98         zoomsensitivity = autocvar_cl_zoomsensitivity;
  99         zoomfactor = autocvar_cl_zoomfactor;
 100         if(zoomfactor < 1 || zoomfactor > 16)
 101                 zoomfactor = 2.5;
 102         zoomspeed = autocvar_cl_zoomspeed;
 103         if(zoomspeed >= 0)
 104                 if(zoomspeed < 0.5 || zoomspeed > 16)
 105                         zoomspeed = 3.5;
 106
 107         zoomdir = button_zoom;
 108         if(hud == HUD_NORMAL)
 109         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 110                 zoomdir += button_attack2;
 111         if(spectatee_status > 0 || isdemo())
 112         {
 113                 if(spectatorbutton_zoom)
 114                 {
 115                         if(zoomdir)
 116                                 zoomdir = 0;
 117                         else
 118                                 zoomdir = 1;
 119                 }
 120                 // fteqcc failed twice here already, don't optimize this
 121         }
 122
 123         if(zoomdir)
 124                 zoomin_effect = 0;
 125
 126         if(zoomin_effect || camera_active)
 127         {
 128                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 129         }
 130         else
 131         {
 132                 if(zoomspeed < 0) // instant zoom
 133                 {
 134                         if(zoomdir)
 135                                 current_viewzoom = 1 / zoomfactor;
 136                         else
 137                                 current_viewzoom = 1;
 138                 }
 139                 else
 140                 {
 141                         if(zoomdir)
 142                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 143                         else
 144                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 145                 }
 146         }
 147
 148         if(almost_equals(current_viewzoom, 1))
 149                 current_zoomfraction = 0;
 150         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 151                 current_zoomfraction = 1;
 152         else
 153                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 154
 155         if(zoomsensitivity < 1)
 156                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 157         else
 158                 setsensitivityscale(1);
 159
 160         makevectors(view_angles);
 161
 162         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 163         {
 164                 switch(autocvar_cl_velocityzoom_type)
 165                 {
 166                         case 3: curspeed = max(0, v_forward * pmove_vel); break;
 167                         case 2: curspeed = (v_forward * pmove_vel); break;
 168                         case 1: default: curspeed = vlen(pmove_vel); break;
 169                 }
 170
 171                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 172                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 173                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 174
 175                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 176         }
 177         else
 178                 velocityzoom = 1;
 179
 180         float frustumx, frustumy, fovx, fovy;
 181         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 182         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 183         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 184         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 185
 186         return '1 0 0' * fovx + '0 1 0' * fovy;
 187 }
 188
 189 // this function must match W_SetupShot!
 190 float zoomscript_caught;
 191
 192 vector wcross_origin;
 193 float wcross_scale_prev, wcross_alpha_prev;
 194 vector wcross_color_prev;
 195 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 196 vector wcross_color_goal_prev;
 197 float wcross_changedonetime;
 198
 199 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 200 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 201 float wcross_name_changestarttime, wcross_name_changedonetime;
 202 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 203 entity trueaim;
 204 entity trueaim_rifle;
 205
 206 #define SHOTTYPE_HITTEAM 1
 207 #define SHOTTYPE_HITOBSTRUCTION 2
 208 #define SHOTTYPE_HITWORLD 3
 209 #define SHOTTYPE_HITENEMY 4
 210
 211 void TrueAim_Init()
 212 {
 213         trueaim = spawn();
 214         trueaim.classname = "trueaim";
 215         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 216         trueaim_rifle = spawn();
 217         trueaim_rifle.classname = "trueaim_rifle";
 218         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 219 }
 220
 221 float EnemyHitCheck()
 222 {
 223         float t, n;
 224         wcross_origin = project_3d_to_2d(trace_endpos);
 225         wcross_origin_z = 0;
 226         if(trace_ent)
 227                 n = trace_ent.entnum;
 228         else
 229                 n = trace_networkentity;
 230         if(n < 1)
 231                 return SHOTTYPE_HITWORLD;
 232         if(n > maxclients)
 233                 return SHOTTYPE_HITWORLD;
 234         t = GetPlayerColor(n - 1);
 235         if(teamplay)
 236                 if(t == myteam)
 237                         return SHOTTYPE_HITTEAM;
 238         if(t == COLOR_SPECTATOR)
 239                 return SHOTTYPE_HITWORLD;
 240         return SHOTTYPE_HITENEMY;
 241 }
 242
 243 float TrueAimCheck()
 244 {
 245         float nudge = 1; // added to traceline target and subtracted from result
 246         vector vecs, trueaimpoint, w_shotorg;
 247         vector mi, ma, dv;
 248         float shottype;
 249         entity ta;
 250         float mv;
 251
 252         mi = ma = '0 0 0';
 253         ta = trueaim;
 254         mv = MOVE_NOMONSTERS;
 255
 256         switch(activeweapon)
 257         {
 258                 case WEP_TUBA: // no aim
 259                 case WEP_PORTO: // shoots from eye
 260                 case WEP_HOOK: // no trueaim
 261                 case WEP_GRENADE_LAUNCHER: // toss curve
 262                         return SHOTTYPE_HITWORLD;
 263                 case WEP_NEX:
 264                 case WEP_MINSTANEX:
 265                         mv = MOVE_NORMAL;
 266                         break;
 267                 case WEP_RIFLE:
 268                         ta = trueaim_rifle;
 269                         mv = MOVE_NORMAL;
 270                         if(zoomscript_caught)
 271                         {
 272                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 273                                 return EnemyHitCheck();
 274                         }
 275                         break;
 276                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 277                         mi = '-3 -3 -3';
 278                         ma = '3 3 3';
 279                         break;
 280                 case WEP_FIREBALL: // projectile has a size!
 281                         mi = '-16 -16 -16';
 282                         ma = '16 16 16';
 283                         break;
 284                 case WEP_SEEKER: // projectile has a size!
 285                         mi = '-2 -2 -2';
 286                         ma = '2 2 2';
 287                         break;
 288                 case WEP_ELECTRO: // projectile has a size!
 289                         mi = '0 0 -3';
 290                         ma = '0 0 -3';
 291                         break;
 292         }
 293
 294         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 295
 296         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 297         trueaimpoint = trace_endpos;
 298
 299         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 300                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 301
 302         if(vecs_x > 0)
 303                 vecs_y = -vecs_y;
 304         else
 305                 vecs = '0 0 0';
 306
 307         dv = view_right * vecs_y + view_up * vecs_z;
 308         w_shotorg = view_origin + dv;
 309
 310         // now move the vecs forward as much as requested if possible
 311         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 312         w_shotorg = trace_endpos - view_forward * nudge;
 313
 314         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 315         shottype = EnemyHitCheck();
 316         if(shottype != SHOTTYPE_HITWORLD)
 317                 return shottype;
 318
 319 #if 0
 320         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 321         // or rather, I know why, but see no fix
 322         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 323                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 324                 return SHOTTYPE_HITOBSTRUCTION;
 325 #endif
 326
 327         return SHOTTYPE_HITWORLD;
 328 }
 329
 330 void CSQC_common_hud(void);
 331
 332 void PostInit(void);
 333 void CSQC_Demo_Camera();
 334 float HUD_WouldDrawScoreboard();
 335 float camera_mode;
 336 float CAMERA_FREE = 1;
 337 float CAMERA_CHASE = 2;
 338 float reticle_type;
 339 string NextFrameCommand;
 340 void CSQC_SPIDER_HUD();
 341 void CSQC_RAPTOR_HUD();
 342
 343 vector freeze_org, freeze_ang;
 344 entity nightvision_noise, nightvision_noise2;
 345
 346 #define MAX_TIME_DIFF 5
 347 float pickup_crosshair_time, pickup_crosshair_size;
 348 float hit_time, typehit_time;
 349 float nextsound_hit_time, nextsound_typehit_time;
 350 float hitindication_crosshair_time, hitindication_crosshair_size;
 351 float use_nex_chargepool;
 352
 353 float myhealth, myhealth_prev;
 354 float myhealth_flash;
 355
 356 float old_blurradius, old_bluralpha;
 357 float old_sharpen_intensity;
 358
 359 vector myhealth_gentlergb;
 360
 361 float contentavgalpha, liquidalpha_prev;
 362 vector liquidcolor_prev;
 363
 364 float eventchase_current_distance;
 365
 366 vector damage_blurpostprocess, content_blurpostprocess;
 367
 368 float checkfail[16];
 369
 370 #define BUTTON_3 4
 371 #define BUTTON_4 8
 372 void CSQC_UpdateView(float w, float h)
 373 {
 374         entity e;
 375         float fov;
 376         float f, i, j;
 377         vector v;
 378         vector vf_size, vf_min;
 379         float a;
 380
 381         execute_next_frame();
 382
 383         ++framecount;
 384
 385         hud = getstati(STAT_HUD);
 386
 387         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 388                 view_quality = getproperty(VF_MINFPS_QUALITY);
 389         else
 390                 view_quality = 1;
 391
 392         button_attack2 = (input_buttons & BUTTON_3);
 393         button_zoom = (input_buttons & BUTTON_4);
 394
 395         // FIXME do we need this hack?
 396         if(isdemo())
 397         {
 398                 // in demos, input_buttons do not work
 399                 button_zoom = (autocvar__togglezoom == "-");
 400         }
 401
 402 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 403         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 404         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 405         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 406         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 407         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 408         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 409         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 410
 411         vf_size = getpropertyvec(VF_SIZE);
 412         vf_min = getpropertyvec(VF_MIN);
 413         vid_width = vf_size_x;
 414         vid_height = vf_size_y;
 415
 416         vector reticle_pos, reticle_size;
 417         vector splash_pos, splash_size;
 418
 419         WaypointSprite_Load();
 420
 421         CSQCPlayer_SetCamera();
 422
 423 #ifdef COMPAT_XON050_ENGINE
 424         if(spectatee_status)
 425                 myteam = GetPlayerColor(spectatee_status - 1);
 426         else
 427 #endif
 428                 myteam = GetPlayerColor(player_localentnum - 1);
 429
 430         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 431
 432         // event chase camera
 433         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 434         {
 435                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 436                 {
 437                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 438                         vector current_view_origin = getpropertyvec(VF_ORIGIN);
 439
 440                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 441                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 442                         if(!autocvar_chase_active)
 443                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 444
 445                         // make the camera smooth back
 446                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 447                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 448                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 449                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 450
 451                         vector eventchase_target_origin;
 452                         makevectors(view_angles);
 453                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 454                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 455                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 456                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 457                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 458                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 459                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 460
 461                         setproperty(VF_ORIGIN, trace_endpos);
 462                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 463                 }
 464                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 465                 {
 466                         cvar_set("chase_active", "0");
 467                         eventchase_current_distance = 0; // start from 0 next time
 468                 }
 469         }
 470
 471         // do lockview after event chase camera so that it still applies whenever necessary.
 472         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 473         {
 474                 setproperty(VF_ORIGIN, freeze_org);
 475                 setproperty(VF_ANGLES, freeze_ang);
 476         }
 477         else
 478         {
 479                 freeze_org = getpropertyvec(VF_ORIGIN);
 480                 freeze_ang = getpropertyvec(VF_ANGLES);
 481         }
 482
 483         WarpZone_FixView();
 484         //WarpZone_FixPMove();
 485
 486         // Render the Scene
 487         view_origin = getpropertyvec(VF_ORIGIN);
 488         view_angles = getpropertyvec(VF_ANGLES);
 489         makevectors(view_angles);
 490         view_forward = v_forward;
 491         view_right = v_right;
 492         view_up = v_up;
 493
 494 #ifdef BLURTEST
 495         if(time > blurtest_time0 && time < blurtest_time1)
 496         {
 497                 float r, t;
 498
 499                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 500                 r = t * blurtest_radius;
 501                 f = 1 / pow(t, blurtest_power) - 1;
 502
 503                 cvar_set("r_glsl_postprocess", "1");
 504                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 505         }
 506         else
 507         {
 508                 cvar_set("r_glsl_postprocess", "0");
 509                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 510         }
 511 #endif
 512
 513         TargetMusic_Advance();
 514         Fog_Force();
 515
 516         if(drawtime == 0)
 517                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 518         else
 519                 drawframetime = bound(0.000001, time - drawtime, 1);
 520         drawtime = time;
 521
 522         // watch for gametype changes here...
 523         // in ParseStuffCMD the cmd isn't executed yet :/
 524         // might even be better to add the gametype to TE_CSQC_INIT...?
 525         if(!postinit)
 526                 PostInit();
 527
 528         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 529         {
 530                 if(calledhooks & HOOK_START)
 531                 {
 532                         localcmd("\ncl_hook_gameend\n");
 533                         calledhooks |= HOOK_END;
 534                 }
 535         }
 536
 537   Announcer();
 538
 539         fov = autocvar_fov;
 540         if(fov <= 59.5)
 541         {
 542                 if(!zoomscript_caught)
 543                 {
 544                         localcmd("+button9\n");
 545                         zoomscript_caught = 1;
 546                 }
 547         }
 548         else
 549         {
 550                 if(zoomscript_caught)
 551                 {
 552                         localcmd("-button9\n");
 553                         zoomscript_caught = 0;
 554                 }
 555         }
 556
 557         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 558
 559         // next WANTED weapon (for HUD)
 560         switchweapon = getstati(STAT_SWITCHWEAPON);
 561
 562         // currently switching-to weapon (for crosshair)
 563         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 564
 565         // actually active weapon (for zoom)
 566         activeweapon = getstati(STAT_ACTIVEWEAPON);
 567
 568         f = (serverflags & SERVERFLAG_TEAMPLAY);
 569         if(f != teamplay)
 570         {
 571                 teamplay = f;
 572                 HUD_InitScores();
 573         }
 574
 575         if(last_switchweapon != switchweapon) {
 576                 weapontime = time;
 577                 last_switchweapon = switchweapon;
 578         }
 579         if(last_activeweapon != activeweapon) {
 580                 last_activeweapon = activeweapon;
 581
 582                 e = get_weaponinfo(activeweapon);
 583                 if(e.netname != "")
 584                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 585                 else
 586                         localcmd("\ncl_hook_activeweapon none\n");
 587         }
 588
 589         // ALWAYS Clear Current Scene First
 590         clearscene();
 591 #ifdef WORKAROUND_XON010
 592         if(checkextension("DP_CSQC_ROTATEMOVES"))
 593         {
 594 #endif
 595         setproperty(VF_ORIGIN, view_origin);
 596         setproperty(VF_ANGLES, view_angles);
 597 #ifdef WORKAROUND_XON010
 598         }
 599 #endif
 600
 601         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 602         setproperty(VF_SIZE, vf_size);
 603         setproperty(VF_MIN, vf_min);
 604
 605         // Assign Standard Viewflags
 606         // Draw the World (and sky)
 607         setproperty(VF_DRAWWORLD, 1);
 608
 609         // Set the console size vars
 610         vid_conwidth = autocvar_vid_conwidth;
 611         vid_conheight = autocvar_vid_conheight;
 612         vid_pixelheight = autocvar_vid_pixelheight;
 613
 614         setproperty(VF_FOV, GetCurrentFov(fov));
 615
 616         // Camera for demo playback
 617         if(camera_active)
 618         {
 619                 if(autocvar_camera_enable)
 620                         CSQC_Demo_Camera();
 621                 else
 622                 {
 623                         cvar_set("chase_active", ftos(chase_active_backup));
 624                         cvar_set("cl_demo_mousegrab", "0");
 625                         camera_active = FALSE;
 626                 }
 627         }
 628 #ifdef CAMERATEST
 629         else if(autocvar_camera_enable)
 630 #else
 631         else if(autocvar_camera_enable && isdemo())
 632 #endif
 633         {
 634                 // Enable required Darkplaces cvars
 635                 chase_active_backup = autocvar_chase_active;
 636                 cvar_set("chase_active", "2");
 637                 cvar_set("cl_demo_mousegrab", "1");
 638                 camera_active = TRUE;
 639                 camera_mode = FALSE;
 640         }
 641
 642         // Draw the Crosshair
 643         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 644
 645         // Draw the Engine Status Bar (the default Quake HUD)
 646         setproperty(VF_DRAWENGINESBAR, 0);
 647
 648         // Update the mouse position
 649         /*
 650            mousepos_x = vid_conwidth;
 651            mousepos_y = vid_conheight;
 652            mousepos = mousepos*0.5 + getmousepos();
 653          */
 654
 655         e = self;
 656         for(self = world; (self = nextent(self)); )
 657                 if(self.draw)
 658                         self.draw();
 659         self = e;
 660
 661         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 662         renderscene();
 663
 664         // now switch to 2D drawing mode by calling a 2D drawing function
 665         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 666         // next R_RenderScene call
 667         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 668
 669         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 670         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 671         {
 672                 // apply night vision effect
 673                 vector tc_00, tc_01, tc_10, tc_11;
 674                 vector rgb;
 675                 rgb_x = 0; // fteqcc sucks
 676                 rgb_y = 0; // fteqcc sucks
 677                 rgb_z = 0; // fteqcc sucks
 678
 679                 if(!nightvision_noise)
 680                 {
 681                         nightvision_noise = spawn();
 682                         nightvision_noise.classname = "nightvision_noise";
 683                 }
 684                 if(!nightvision_noise2)
 685                 {
 686                         nightvision_noise2 = spawn();
 687                         nightvision_noise2.classname = "nightvision_noise2";
 688                 }
 689
 690                 // color tint in yellow
 691                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 692
 693                 // draw BG
 694                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 695                 rgb = '1 1 1';
 696                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 697                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 698                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 699                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 700                 tc_11 = tc_01 + tc_10 - tc_00;
 701                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 702                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 703                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 704                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 705                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 706                 R_EndPolygon();
 707
 708                 // draw FG
 709                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 710                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 711                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 712                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 713                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 714                 tc_11 = tc_01 + tc_10 - tc_00;
 715                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 716                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 717                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 718                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 719                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 720                 R_EndPolygon();
 721         }
 722
 723         // Draw the aiming reticle for weapons that use it
 724         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 725         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 726         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 727         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 728                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 729         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 730                 reticle_type = 2; // nex zoom
 731         else if(button_zoom || zoomscript_caught)
 732                 reticle_type = 1; // normal zoom
 733         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 734                 reticle_type = 2; // nex zoom
 735
 736         if(reticle_type && autocvar_cl_reticle)
 737         {
 738                 if(autocvar_cl_reticle_stretch)
 739                 {
 740                         reticle_size_x = vid_conwidth;
 741                         reticle_size_y = vid_conheight;
 742                         reticle_pos_x = 0;
 743                         reticle_pos_y = 0;
 744                 }
 745                 else
 746                 {
 747                         reticle_size_x = max(vid_conwidth, vid_conheight);
 748                         reticle_size_y = max(vid_conwidth, vid_conheight);
 749                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 750                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 751                 }
 752
 753                 f = current_zoomfraction;
 754                 if(zoomscript_caught)
 755                         f = 1;
 756                 if(autocvar_cl_reticle_item_normal)
 757                 {
 758                         if(reticle_type == 1 && f)
 759                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 760                 }
 761                 if(autocvar_cl_reticle_item_nex)
 762                 {
 763                         if(reticle_type == 2 && f)
 764                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 765                 }
 766         }
 767
 768
 769         // improved polyblend
 770         vector rgb;
 771         if(autocvar_hud_contents)
 772         {
 773                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 774                 vector liquidcolor;
 775
 776                 switch(pointcontents(view_origin))
 777                 {
 778                         case CONTENT_WATER:
 779                                 liquidalpha = autocvar_hud_contents_water_alpha;
 780                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 781                                 incontent = 1;
 782                                 break;
 783
 784                         case CONTENT_LAVA:
 785                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 786                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 787                                 incontent = 1;
 788                                 break;
 789
 790                         case CONTENT_SLIME:
 791                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 792                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 793                                 incontent = 1;
 794                                 break;
 795
 796                         default:
 797                                 liquidalpha = 0;
 798                                 liquidcolor = '0 0 0';
 799                                 incontent = 0;
 800                                 break;
 801                 }
 802
 803                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 804                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 805                         contentfadetime = autocvar_hud_contents_fadeintime;
 806                         liquidalpha_prev = liquidalpha;
 807                         liquidcolor_prev = liquidcolor;
 808                 }
 809                 else
 810                         contentfadetime = autocvar_hud_contents_fadeouttime;
 811
 812                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 813                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 814
 815                 if(contentavgalpha)
 816                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 817
 818                 if(autocvar_hud_postprocessing)
 819                 {
 820                         if(autocvar_hud_contents_blur && contentavgalpha)
 821                         {
 822                                 content_blurpostprocess_x = 1;
 823                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 824                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 825                         }
 826                         else
 827                         {
 828                                 content_blurpostprocess_x = 0;
 829                                 content_blurpostprocess_y = 0;
 830                                 content_blurpostprocess_z = 0;
 831                         }
 832                 }
 833         }
 834
 835         if(autocvar_hud_damage)
 836         {
 837                 splash_size_x = max(vid_conwidth, vid_conheight);
 838                 splash_size_y = max(vid_conwidth, vid_conheight);
 839                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 840                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 841
 842                 float myhealth_flash_temp;
 843                 myhealth = getstati(STAT_HEALTH);
 844
 845                 // fade out
 846                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 847                 // add new damage
 848                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 849
 850                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 851                 pain_threshold = autocvar_hud_damage_pain_threshold;
 852                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 853                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 854
 855                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 856                 {
 857                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 858                 }
 859
 860                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 861
 862                 if(myhealth_prev < 1)
 863                 {
 864                         if(myhealth >= 1)
 865                         {
 866                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 867                                 myhealth_flash_temp = 0;
 868                         }
 869                         else
 870                         {
 871                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 872                         }
 873                 }
 874
 875                 if(spectatee_status == -1 || intermission)
 876                 {
 877                         myhealth_flash = 0; // observing, or match ended
 878                         myhealth_flash_temp = 0;
 879                 }
 880
 881                 myhealth_prev = myhealth;
 882
 883                 // IDEA: change damage color/picture based on player model for robot/alien species?
 884                 // pro: matches model better
 885                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 886                 // maybe different reddish pics?
 887                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 888                 {
 889                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 890                         {
 891                                 if(autocvar_cl_gentle_damage == 2)
 892                                 {
 893                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 894                                         {
 895                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 896                                         }
 897                                 }
 898                                 else
 899                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 900
 901                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 902                         }
 903                         else
 904                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 905                 }
 906
 907                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 908                 {
 909                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 910                         {
 911                                 damage_blurpostprocess_x = 1;
 912                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 913                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 914                         }
 915                         else
 916                         {
 917                                 damage_blurpostprocess_x = 0;
 918                                 damage_blurpostprocess_y = 0;
 919                                 damage_blurpostprocess_z = 0;
 920                         }
 921                 }
 922         }
 923
 924         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 925         {
 926                 // enable or disable rendering types if they are used or not
 927                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 928                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 929
 930                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 931                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 932                 {
 933                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 934                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 935                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 936                         {
 937                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 938                                 old_blurradius = blurradius;
 939                                 old_bluralpha = bluralpha;
 940                         }
 941                 }
 942                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 943                 {
 944                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 945                         old_blurradius = 0;
 946                         old_bluralpha = 0;
 947                 }
 948
 949                 // edge detection postprocess handling done second (used by hud_powerup)
 950                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 951                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 952                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 953
 954                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 955
 956                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 957                 {
 958                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 959                         {
 960                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 961                                 old_sharpen_intensity = sharpen_intensity;
 962                         }
 963                 }
 964                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 965                 {
 966                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 967                         old_sharpen_intensity = 0;
 968                 }
 969         }
 970
 971         if(menu_visible)
 972                 menu_show();
 973
 974         /*if(gametype == MAPINFO_TYPE_CTF)
 975           {
 976           ctf_view();
 977           } else */
 978
 979         // draw 2D entities
 980         e = self;
 981         for(self = world; (self = nextent(self)); )
 982                 if(self.draw2d)
 983                         self.draw2d();
 984         self = e;
 985         Draw_ShowNames_All();
 986
 987         scoreboard_active = HUD_WouldDrawScoreboard();
 988
 989         hit_time = getstatf(STAT_HIT_TIME);
 990         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 991         {
 992                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 993                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 994
 995                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 996         }
 997         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 998         if(typehit_time > nextsound_typehit_time)
 999         {
1000                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1001                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1002
1003                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1004         }
1005
1006         //else
1007         {
1008                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1009                 {
1010                         if(getstati(STAT_FROZEN))
1011                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1012                         if(getstatf(STAT_REVIVE_PROGRESS))
1013                         {
1014                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1015                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1016                         }
1017                 }
1018
1019                 if(autocvar_r_letterbox == 0)
1020                         if(autocvar_viewsize < 120)
1021                                 CSQC_common_hud();
1022
1023                 // crosshair goes VERY LAST
1024                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1025                 {
1026                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1027                                 return;
1028
1029                         string wcross_style;
1030                         float wcross_alpha, wcross_resolution;
1031                         wcross_style = autocvar_crosshair;
1032                         if (wcross_style == "0")
1033                                 return;
1034                         wcross_resolution = autocvar_crosshair_size;
1035                         if (wcross_resolution == 0)
1036                                 return;
1037                         wcross_alpha = autocvar_crosshair_alpha;
1038                         if (wcross_alpha == 0)
1039                                 return;
1040
1041                         // TrueAim check
1042                         float shottype;
1043
1044                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1045                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1046                         wcross_origin_z = 0;
1047                         if(autocvar_crosshair_hittest)
1048                         {
1049                                 vector wcross_oldorigin;
1050                                 wcross_oldorigin = wcross_origin;
1051                                 shottype = TrueAimCheck();
1052                                 if(shottype == SHOTTYPE_HITWORLD)
1053                                 {
1054                                         v = wcross_origin - wcross_oldorigin;
1055                                         v_x /= vid_conwidth;
1056                                         v_y /= vid_conheight;
1057                                         if(vlen(v) > 0.01)
1058                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1059                                 }
1060                                 if(!autocvar_crosshair_hittest_showimpact)
1061                                         wcross_origin = wcross_oldorigin;
1062                         }
1063                         else
1064                                 shottype = SHOTTYPE_HITWORLD;
1065
1066                         vector wcross_color, wcross_size;
1067                         string wcross_wep, wcross_name;
1068                         float wcross_scale, wcross_blur;
1069
1070                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1071                                 e = get_weaponinfo(switchingweapon);
1072                                 if (e && e.netname != "")
1073                                 {
1074                                         wcross_wep = e.netname;
1075                                         if(autocvar_crosshair_per_weapon)
1076                                         {
1077                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1078                                                 if (wcross_resolution == 0)
1079                                                         return;
1080                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1081                                                 if (wcross_alpha == 0)
1082                                                         return;
1083
1084                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1085                                                 if(wcross_style == "" || wcross_style == "0")
1086                                                         wcross_style = wcross_wep;
1087                                         }
1088                                 }
1089                         }
1090                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1091                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1092                         else if(autocvar_crosshair_color_by_health)
1093                         {
1094                                 float x = getstati(STAT_HEALTH);
1095
1096                                 //x = red
1097                                 //y = green
1098                                 //z = blue
1099
1100                                 wcross_color_z = 0;
1101
1102                                 if(x > 200)
1103                                 {
1104                                         wcross_color_x = 0;
1105                                         wcross_color_y = 1;
1106                                 }
1107                                 else if(x > 150)
1108                                 {
1109                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1110                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1111                                 }
1112                                 else if(x > 100)
1113                                 {
1114                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1115                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1116                                         wcross_color_z = 1 - (x-100)*0.02;
1117                                 }
1118                                 else if(x > 50)
1119                                 {
1120                                         wcross_color_x = 1;
1121                                         wcross_color_y = 1;
1122                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1123                                 }
1124                                 else if(x > 20)
1125                                 {
1126                                         wcross_color_x = 1;
1127                                         wcross_color_y = (x-20)*90/27/100;
1128                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1129                                 }
1130                                 else
1131                                 {
1132                                         wcross_color_x = 1;
1133                                         wcross_color_y = 0;
1134                                 }
1135                         }
1136                         else
1137                                 wcross_color = stov(autocvar_crosshair_color);
1138
1139                         wcross_name = strcat("gfx/crosshair", wcross_style);
1140
1141                         if(autocvar_crosshair_effect_scalefade)
1142                         {
1143                                 wcross_scale = wcross_resolution;
1144                                 wcross_resolution = 1;
1145                         }
1146                         else
1147                         {
1148                                 wcross_scale = 1;
1149                         }
1150
1151                         if(autocvar_crosshair_pickup)
1152                         {
1153                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1154
1155                                 if(pickup_crosshair_time < stat_pickup_time)
1156                                 {
1157                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1158                                                 pickup_crosshair_size = 1;
1159
1160                                         pickup_crosshair_time = stat_pickup_time;
1161                                 }
1162
1163                                 if(pickup_crosshair_size > 0)
1164                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1165                                 else
1166                                         pickup_crosshair_size = 0;
1167
1168                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1169                         }
1170
1171                         if(autocvar_crosshair_hitindication)
1172                         {
1173                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1174                                 if(hitindication_crosshair_time < hit_time)
1175                                 {
1176                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1177                                                 hitindication_crosshair_size = 1;
1178
1179                                         hitindication_crosshair_time = hit_time;
1180                                 }
1181
1182                                 if(hitindication_crosshair_size > 0)
1183                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1184                                 else
1185                                         hitindication_crosshair_size = 0;
1186
1187                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1188                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1189                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1190                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1191                         }
1192
1193                         if(shottype == SHOTTYPE_HITENEMY)
1194                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1195                         if(shottype == SHOTTYPE_HITTEAM)
1196                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1197
1198                         f = autocvar_crosshair_effect_speed;
1199                         if(f < 0)
1200                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1201                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1202                         {
1203                                 wcross_changedonetime = time + f;
1204                         }
1205                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1206                         {
1207                                 wcross_name_changestarttime = time;
1208                                 wcross_name_changedonetime = time + f;
1209                                 if(wcross_name_goal_prev_prev)
1210                                         strunzone(wcross_name_goal_prev_prev);
1211                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1212                                 wcross_name_goal_prev = strzone(wcross_name);
1213                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1214                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1215                                 wcross_resolution_goal_prev = wcross_resolution;
1216                         }
1217
1218                         wcross_scale_goal_prev = wcross_scale;
1219                         wcross_alpha_goal_prev = wcross_alpha;
1220                         wcross_color_goal_prev = wcross_color;
1221
1222                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1223                         {
1224                                 wcross_blur = 1;
1225                                 wcross_alpha *= 0.75;
1226                         }
1227                         else
1228                                 wcross_blur = 0;
1229                         // *_prev is at time-frametime
1230                         // * is at wcross_changedonetime+f
1231                         // what do we have at time?
1232                         if(time < wcross_changedonetime)
1233                         {
1234                                 f = frametime / (wcross_changedonetime - time + frametime);
1235                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1236                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1237                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1238                         }
1239
1240                         wcross_scale_prev = wcross_scale;
1241                         wcross_alpha_prev = wcross_alpha;
1242                         wcross_color_prev = wcross_color;
1243
1244                         wcross_scale *= 1 - autocvar__menu_alpha;
1245                         wcross_alpha *= 1 - autocvar__menu_alpha;
1246                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1247
1248                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1249                         {
1250                                 // crosshair rings for weapon stats
1251                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1252                                 {
1253                                         // declarations and stats
1254                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1255                                         string ring_image, ring_inner_image;
1256                                         vector ring_rgb, ring_inner_rgb;
1257
1258                                         ring_scale = autocvar_crosshair_ring_size;
1259
1260                                         float weapon_clipload, weapon_clipsize;
1261                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1262                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1263
1264                                         float nex_charge, nex_chargepool;
1265                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1266                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1267
1268                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1269                                                 nex_charge_movingavg = nex_charge;
1270
1271
1272                                         // handle the values
1273                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1274                                         {
1275                                                 if (nex_chargepool || use_nex_chargepool) {
1276                                                         use_nex_chargepool = 1;
1277                                                         ring_inner_value = nex_chargepool;
1278                                                 } else {
1279                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1280                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1281                                                 }
1282
1283                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1284                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1285                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1286
1287                                                 // draw the outer ring to show the current charge of the weapon
1288                                                 ring_value = nex_charge;
1289                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1290                                                 ring_rgb = wcross_color;
1291                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1292                                         }
1293                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1294                                         {
1295                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1296                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1297                                                 ring_rgb = wcross_color;
1298                                                 ring_image = "gfx/crosshair_ring.tga";
1299                                         }
1300                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1301                                         {
1302                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1303                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1304                                                 ring_rgb = wcross_color;
1305                                                 ring_image = "gfx/crosshair_ring.tga";
1306                                         }
1307
1308                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1309                                         {
1310                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1311                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1312                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1313                                                 ring_rgb = wcross_color;
1314
1315                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1316                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1317                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1318                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1319                                                 else
1320                                                         ring_image = "gfx/crosshair_ring.tga";
1321                                         }
1322
1323                                         // if in weapon switch animation, fade ring out/in
1324                                         if(g_weaponswitchdelay > 0)
1325                                         {
1326                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1327                                                 if(f > 0 && f < 2)
1328                                                         ring_alpha *= fabs(1 - f);
1329                                         }
1330
1331                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1332                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1333
1334                                         if (ring_value)
1335                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1336                                 }
1337
1338 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1339                                 do \
1340                                 { \
1341                                         if(wcross_blur > 0) \
1342                                         { \
1343                                                 for(i = -2; i <= 2; ++i) \
1344                                                 for(j = -2; j <= 2; ++j) \
1345                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1346                                         } \
1347                                         else \
1348                                         { \
1349                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1350                                         } \
1351                                 } \
1352                                 while(0)
1353
1354 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1355                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1356
1357 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1358                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1359
1360                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1361                                 {
1362                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1363                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1364                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1365                                         f = 1 - f;
1366                                 }
1367                                 else
1368                                 {
1369                                         f = 1;
1370                                 }
1371                                 wcross_name_alpha_goal_prev = f;
1372
1373                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1374                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1375
1376                                 if(autocvar_crosshair_dot)
1377                                 {
1378                                         vector wcross_color_old;
1379                                         wcross_color_old = wcross_color;
1380
1381                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1382                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1383
1384                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1385                                         // FIXME why don't we use wcross_alpha here?
1386                                         wcross_color = wcross_color_old;
1387                                 }
1388                         }
1389                 }
1390                 else
1391                 {
1392                         wcross_scale_prev = 0;
1393                         wcross_alpha_prev = 0;
1394                         wcross_scale_goal_prev = 0;
1395                         wcross_alpha_goal_prev = 0;
1396                         wcross_changedonetime = 0;
1397                         if(wcross_name_goal_prev)
1398                                 strunzone(wcross_name_goal_prev);
1399                         wcross_name_goal_prev = string_null;
1400                         if(wcross_name_goal_prev_prev)
1401                                 strunzone(wcross_name_goal_prev_prev);
1402                         wcross_name_goal_prev_prev = string_null;
1403                         wcross_name_changestarttime = 0;
1404                         wcross_name_changedonetime = 0;
1405                         wcross_name_alpha_goal_prev = 0;
1406                         wcross_name_alpha_goal_prev_prev = 0;
1407                         wcross_resolution_goal_prev = 0;
1408                         wcross_resolution_goal_prev_prev = 0;
1409                 }
1410         }
1411
1412         if(NextFrameCommand)
1413         {
1414                 localcmd("\n", NextFrameCommand, "\n");
1415                 NextFrameCommand = string_null;
1416         }
1417
1418         // we must do this check AFTER a frame was rendered, or it won't work
1419         if(cs_project_is_b0rked == 0)
1420         {
1421                 string w0, h0;
1422                 w0 = ftos(autocvar_vid_conwidth);
1423                 h0 = ftos(autocvar_vid_conheight);
1424                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1425                 //setproperty(VF_FOV, '90 90 0');
1426                 setproperty(VF_ORIGIN, '0 0 0');
1427                 setproperty(VF_ANGLES, '0 0 0');
1428                 setproperty(VF_PERSPECTIVE, 1);
1429                 makevectors('0 0 0');
1430                 vector v1, v2;
1431                 cvar_set("vid_conwidth", "800");
1432                 cvar_set("vid_conheight", "600");
1433                 v1 = cs_project(v_forward);
1434                 cvar_set("vid_conwidth", "640");
1435                 cvar_set("vid_conheight", "480");
1436                 v2 = cs_project(v_forward);
1437                 if(v1 == v2)
1438                         cs_project_is_b0rked = 1;
1439                 else
1440                         cs_project_is_b0rked = -1;
1441                 cvar_set("vid_conwidth", w0);
1442                 cvar_set("vid_conheight", h0);
1443         }
1444
1445         if(autocvar__hud_configure)
1446                 HUD_Panel_Mouse();
1447
1448     if(hud && !intermission)
1449     {
1450         if(hud == HUD_SPIDERBOT)
1451             CSQC_SPIDER_HUD();
1452         else if(hud == HUD_WAKIZASHI)
1453             CSQC_WAKIZASHI_HUD();
1454         else if(hud == HUD_RAPTOR)
1455             CSQC_RAPTOR_HUD();
1456         else if(hud == HUD_BUMBLEBEE)
1457             CSQC_BUMBLE_HUD();
1458     }
1459         // let's reset the view back to normal for the end
1460         setproperty(VF_MIN, '0 0 0');
1461         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1462 }
1463
1464
1465 void CSQC_common_hud(void)
1466 {
1467     // do some accuracy var caching
1468     float i;
1469     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1470     {
1471         if(autocvar_accuracy_color_levels != acc_color_levels)
1472         {
1473             if(acc_color_levels)
1474                 strunzone(acc_color_levels);
1475             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1476             acc_levels = tokenize_console(acc_color_levels);
1477             if (acc_levels > MAX_ACCURACY_LEVELS)
1478                 acc_levels = MAX_ACCURACY_LEVELS;
1479
1480             for (i = 0; i < acc_levels; ++i)
1481                 acc_lev[i] = stof(argv(i)) / 100.0;
1482         }
1483         // let know that acc_col[] needs to be loaded
1484         acc_col_x[0] = -1;
1485     }
1486
1487     HUD_Main(); // always run these functions for alpha checks
1488     HUD_DrawScoreboard();
1489
1490     if (scoreboard_active) // scoreboard/accuracy
1491         HUD_Reset();
1492     else if (intermission == 2) // map voting screen
1493     {
1494         HUD_FinaleOverlay();
1495         HUD_Reset();
1496     }
1497         /*
1498         switch(hud)
1499         {
1500                 case HUD_SPIDERBOT:
1501                         CSQC_SPIDER_HUD();
1502                         break;
1503
1504                 case HUD_WAKIZASHI:
1505                         CSQC_WAKIZASHI_HUD();
1506                         break;
1507
1508         case HUD_BUMBLEBEE:
1509             CSQC_BUMBLE_HUD();
1510             break;
1511         }
1512         */
1513 }
1514
1515
1516 // following vectors must be global to allow seamless switching between camera modes
1517 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1518 void CSQC_Demo_Camera()
1519 {
1520         float speed, attenuation, dimensions;
1521         vector tmp, delta;
1522
1523         if( autocvar_camera_reset || !camera_mode )
1524         {
1525                 camera_offset = '0 0 0';
1526                 current_angles = '0 0 0';
1527                 camera_direction = '0 0 0';
1528                 camera_offset_z += 30;
1529                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1530                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1531                 current_origin = view_origin;
1532                 current_camera_offset  = camera_offset;
1533                 cvar_set("camera_reset", "0");
1534                 camera_mode = CAMERA_CHASE;
1535         }
1536
1537         // Camera angles
1538         if( camera_roll )
1539                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1540
1541         if(autocvar_camera_look_player)
1542         {
1543                 vector dir;
1544                 float n;
1545
1546                 dir = normalize(view_origin - current_position);
1547                 n = mouse_angles_z;
1548                 mouse_angles = vectoangles(dir);
1549                 mouse_angles_x = mouse_angles_x * -1;
1550                 mouse_angles_z = n;
1551         }
1552         else
1553         {
1554                 tmp = getmousepos() * 0.1;
1555                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1556                 {
1557                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1558                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1559                 }
1560         }
1561
1562         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1563         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1564         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1565         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1566
1567         // Fix difference when angles don't have the same sign
1568         delta = '0 0 0';
1569         if(mouse_angles_y < -60 && current_angles_y > 60)
1570                 delta = '0 360 0';
1571         if(mouse_angles_y > 60 && current_angles_y < -60)
1572                 delta = '0 -360 0';
1573
1574         if(autocvar_camera_look_player)
1575                 attenuation = autocvar_camera_look_attenuation;
1576         else
1577                 attenuation = autocvar_camera_speed_attenuation;
1578
1579         attenuation = 1 / max(1, attenuation);
1580         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1581
1582         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1583         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1584         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1585         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1586
1587         // Camera position
1588         tmp = '0 0 0';
1589         dimensions = 0;
1590
1591         if( camera_direction_x )
1592         {
1593                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1594                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1595                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1596                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1597                 ++dimensions;
1598         }
1599
1600         if( camera_direction_y )
1601         {
1602                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1603                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1604                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1605                 ++dimensions;
1606         }
1607
1608         if( camera_direction_z )
1609         {
1610                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1611                 ++dimensions;
1612         }
1613
1614         if(autocvar_camera_free)
1615                 speed = autocvar_camera_speed_free;
1616         else
1617                 speed = autocvar_camera_speed_chase;
1618
1619         if(dimensions)
1620         {
1621                 speed = speed * sqrt(1 / dimensions);
1622                 camera_offset += tmp * speed;
1623         }
1624
1625         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1626
1627         // Camera modes
1628         if( autocvar_camera_free )
1629         {
1630                 if ( camera_mode == CAMERA_CHASE )
1631                 {
1632                         current_camera_offset = current_origin + current_camera_offset;
1633                         camera_offset = current_origin + camera_offset;
1634                 }
1635
1636                 camera_mode = CAMERA_FREE;
1637                 current_position = current_camera_offset;
1638         }
1639         else
1640         {
1641                 if ( camera_mode == CAMERA_FREE )
1642                 {
1643                         current_origin = view_origin;
1644                         camera_offset = camera_offset - current_origin;
1645                         current_camera_offset = current_camera_offset - current_origin;
1646                 }
1647
1648                 camera_mode = CAMERA_CHASE;
1649
1650                 if(autocvar_camera_chase_smoothly)
1651                         current_origin += (view_origin - current_origin) * attenuation;
1652                 else
1653                         current_origin = view_origin;
1654
1655                 current_position = current_origin + current_camera_offset;
1656         }
1657
1658         setproperty(VF_ANGLES, current_angles);
1659         setproperty(VF_ORIGIN, current_position);
1660 }