qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float trace_dphitcontents;
   4 float trace_networkentity;
   5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   6 float DPCONTENTS_SOLID = 1; // blocks player movement
   7 float DPCONTENTS_BODY = 32; // blocks player movement
   8 float DPCONTENTS_CORPSE = 64; // blocks player movement
   9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  10 void Porto_Draw()
  11 {
  12         vector p, dir, ang, q, nextdir;
  13         float idx, portal_number, portal1_idx;
  14
  15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 /**
  84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  85  *
  86  * TODO: Use a better solution where a common shared entitiy is used that contains
  87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  88  * and STAT_FRAGLIMIT to be auto-sent)
  89  */
  90 void CheckForGamestartChange() {
  91         float startTime;
  92         startTime = getstatf(STAT_GAMESTARTTIME);
  93         if (previous_game_starttime != startTime) {
  94                 if ((time + 5.0) < startTime) {
  95                         //if connecting to server while restart was active don't always play prepareforbattle
  96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  97                 }
  98                 if (time < startTime) {
  99                         restartAnnouncer = spawn();
 100                         restartAnnouncer.think = restartAnnouncer_Think;
 101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 102                 }
 103         }
 104         previous_game_starttime = startTime;
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 120
 121         zoomsensitivity = autocvar_cl_zoomsensitivity;
 122         zoomfactor = autocvar_cl_zoomfactor;
 123         if(zoomfactor < 1 || zoomfactor > 16)
 124                 zoomfactor = 2.5;
 125         zoomspeed = autocvar_cl_zoomspeed;
 126         if(zoomspeed >= 0)
 127                 if(zoomspeed < 0.5 || zoomspeed > 16)
 128                         zoomspeed = 3.5;
 129
 130         zoomdir = button_zoom;
 131         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 132                 zoomdir += button_attack2;
 133         if(spectatee_status > 0 || isdemo())
 134         {
 135                 if(spectatorbutton_zoom)
 136                         zoomdir = 0 + !zoomdir;
 137                 // do not even THINK about removing this 0
 138                 // _I_ know what I am doing
 139                 // fteqcc does not
 140         }
 141
 142         if(zoomdir)
 143                 zoomin_effect = 0;
 144
 145         if(zoomin_effect || camera_active)
 146         {
 147                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 148         }
 149         else
 150         {
 151                 if(zoomspeed < 0) // instant zoom
 152                 {
 153                         if(zoomdir)
 154                                 current_viewzoom = 1 / zoomfactor;
 155                         else
 156                                 current_viewzoom = 1;
 157                 }
 158                 else
 159                 {
 160                         if(zoomdir)
 161                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 162                         else
 163                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 164                 }
 165         }
 166
 167         if(almost_equals(current_viewzoom, 1))
 168                 current_zoomfraction = 0;
 169         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 170                 current_zoomfraction = 1;
 171         else
 172                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 173
 174         if(zoomsensitivity < 1)
 175                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 176         else
 177                 setsensitivityscale(1);
 178
 179         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 180         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 181         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 182
 183         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_networkentity < 1)
 232                 return SHOTTYPE_HITWORLD;
 233         if(trace_networkentity > maxclients)
 234                 return SHOTTYPE_HITWORLD;
 235         t = GetPlayerColor(trace_networkentity - 1);
 236         if(teamplay)
 237                 if(t == myteam)
 238                         return SHOTTYPE_HITTEAM;
 239         if(t == COLOR_SPECTATOR)
 240                 return SHOTTYPE_HITWORLD;
 241         return SHOTTYPE_HITENEMY;
 242 }
 243
 244 float TrueAimCheck()
 245 {
 246         float nudge = 1; // added to traceline target and subtracted from result
 247         vector vecs, trueaimpoint, w_shotorg;
 248         vector mi, ma, dv;
 249         float shottype;
 250         entity ta;
 251         float mv;
 252
 253         mi = ma = '0 0 0';
 254         ta = trueaim;
 255         mv = MOVE_NOMONSTERS;
 256
 257         switch(activeweapon)
 258         {
 259                 case WEP_TUBA: // no aim
 260                 case WEP_PORTO: // shoots from eye
 261                 case WEP_HOOK: // no trueaim
 262                 case WEP_GRENADE_LAUNCHER: // toss curve
 263                         return SHOTTYPE_HITWORLD;
 264                 case WEP_NEX:
 265                 case WEP_MINSTANEX:
 266                         mv = MOVE_NORMAL;
 267                         break;
 268                 case WEP_SNIPERRIFLE:
 269                         ta = trueaim_rifle;
 270                         mv = MOVE_NORMAL;
 271                         if(zoomscript_caught)
 272                         {
 273                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 274                                 return EnemyHitCheck();
 275                         }
 276                         break;
 277                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 278                         mi = '-3 -3 -3';
 279                         ma = '3 3 3';
 280                         break;
 281                 case WEP_FIREBALL: // projectile has a size!
 282                         mi = '-16 -16 -16';
 283                         ma = '16 16 16';
 284                         break;
 285                 case WEP_SEEKER: // projectile has a size!
 286                         mi = '-2 -2 -2';
 287                         ma = '2 2 2';
 288                         break;
 289                 case WEP_ELECTRO: // projectile has a size!
 290                         mi = '0 0 -3';
 291                         ma = '0 0 -3';
 292                         break;
 293         }
 294
 295         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 296
 297         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 298         trueaimpoint = trace_endpos;
 299
 300         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 301                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 302
 303         if(vecs_x > 0)
 304                 vecs_y = -vecs_y;
 305         else
 306                 vecs = '0 0 0';
 307
 308         dv = view_right * vecs_y + view_up * vecs_z;
 309         w_shotorg = view_origin + dv;
 310
 311         // now move the vecs forward as much as requested if possible
 312         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 313         w_shotorg = trace_endpos - view_forward * nudge;
 314
 315         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 316         shottype = EnemyHitCheck();
 317         if(shottype != SHOTTYPE_HITWORLD)
 318                 return shottype;
 319
 320 #if 0
 321         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 322         // or rather, I know why, but see no fix
 323         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 324                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 325                 return SHOTTYPE_HITOBSTRUCTION;
 326 #endif
 327
 328         return SHOTTYPE_HITWORLD;
 329 }
 330
 331 void CSQC_common_hud(void);
 332
 333 void PostInit(void);
 334 void CSQC_Demo_Camera();
 335 float HUD_WouldDrawScoreboard();
 336 float view_set;
 337 float camera_mode;
 338 float reticle_type;
 339 string NextFrameCommand;
 340 void CSQC_SPIDER_HUD();
 341 void CSQC_RAPTOR_HUD();
 342
 343 vector freeze_pmove_org, freeze_input_angles;
 344 entity nightvision_noise, nightvision_noise2;
 345
 346 float pickup_crosshair_time, pickup_crosshair_size;
 347 float hit_time, typehit_time;
 348 float nextsound_hit_time, nextsound_typehit_time;
 349 float hitindication_crosshair_time, hitindication_crosshair_size;
 350 float use_nex_chargepool;
 351
 352 float myhealth, myhealth_prev;
 353 float myhealth_flash;
 354
 355 vector myhealth_gentlergb;
 356
 357 float contentavgalpha, liquidalpha_prev;
 358 vector liquidcolor_prev;
 359
 360 float checkfail[16];
 361
 362 void CSQC_UpdateView(float w, float h)
 363 {
 364         entity e;
 365         float fov;
 366         float f, i, j;
 367         vector v, vo;
 368         vector vf_size, vf_min;
 369         float a;
 370         float hud;
 371         hud = getstati(STAT_HUD);
 372
 373 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 374         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 375         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 376         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 377         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 378         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 379         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 380
 381         vf_size = R_SetView3fv(VF_SIZE);
 382         vf_min = R_SetView3fv(VF_MIN);
 383         vid_width = vf_size_x;
 384         vid_height = vf_size_y;
 385
 386         vector reticle_pos, reticle_size;
 387         vector splash_pos, splash_size;
 388
 389         WaypointSprite_Load();
 390
 391         if(spectatee_status)
 392                 myteam = GetPlayerColor(spectatee_status - 1);
 393         else
 394                 myteam = GetPlayerColor(player_localentnum - 1);
 395
 396         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 397         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 398
 399         warpzone_fixview_origin = pmove_org + vo;
 400         warpzone_fixview_cl_viewangles = input_angles;
 401         warpzone_fixview_angles = view_angles;
 402         WarpZone_FixView();
 403         pmove_org = warpzone_fixview_origin - vo;
 404         input_angles = warpzone_fixview_cl_viewangles;
 405         view_angles = warpzone_fixview_angles;
 406
 407
 408
 409         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0))
 410         {
 411                 pmove_org = freeze_pmove_org;
 412                 input_angles = view_angles = freeze_input_angles;
 413                 R_SetView(VF_ORIGIN, pmove_org + vo);
 414                 R_SetView(VF_ANGLES, view_angles);
 415                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 416         }
 417         freeze_pmove_org = pmove_org;
 418         freeze_input_angles = input_angles;
 419
 420         // Render the Scene
 421         if(!intermission || !view_set)
 422         {
 423             #ifdef VEHICLES_CSQC
 424             if(hud)
 425             {
 426             view_origin = vehicle_hudmodel.origin; //pmove_org + vo + randomvec() * 20;
 427             view_angles = input_angles;
 428             R_SetView(VF_ORIGIN, view_origin);
 429             makevectors(view_angles);
 430             view_forward = v_forward;
 431             view_right = v_right;
 432             view_up = v_up;
 433             view_set = 1;
 434             }
 435             else
 436             {
 437         #endif
 438             view_origin = pmove_org + vo;
 439             view_angles = input_angles;
 440             makevectors(view_angles);
 441             view_forward = v_forward;
 442             view_right = v_right;
 443             view_up = v_up;
 444             view_set = 1;
 445             #ifdef VEHICLES_CSQC
 446             }
 447         #endif
 448         }
 449
 450 #ifdef BLURTEST
 451         if(time > blurtest_time0 && time < blurtest_time1)
 452         {
 453                 float r, t;
 454
 455                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 456                 r = t * blurtest_radius;
 457                 f = 1 / pow(t, blurtest_power) - 1;
 458
 459                 cvar_set("r_glsl_postprocess", "1");
 460                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 461         }
 462         else
 463         {
 464                 cvar_set("r_glsl_postprocess", "0");
 465                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 466         }
 467 #endif
 468
 469         TargetMusic_Advance();
 470         Fog_Force();
 471
 472         drawframetime = max(0.000001, time - drawtime);
 473         drawtime = time;
 474
 475         // watch for gametype changes here...
 476         // in ParseStuffCMD the cmd isn't executed yet :/
 477         // might even be better to add the gametype to TE_CSQC_INIT...?
 478         if(!postinit)
 479                 PostInit();
 480
 481         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 482                 if(calledhooks & HOOK_START)
 483                 {
 484                         localcmd("\ncl_hook_gameend\n");
 485                         calledhooks |= HOOK_END;
 486                 }
 487
 488         CheckForGamestartChange();
 489         serverAnnouncer();
 490         maptimeAnnouncer();
 491         carrierAnnouncer();
 492
 493         fov = autocvar_fov;
 494         if(button_zoom || fov <= 59.5)
 495         {
 496                 if(!zoomscript_caught)
 497                 {
 498                         localcmd("+button4\n");
 499                         zoomscript_caught = 1;
 500                         ignore_plus_zoom += 1;
 501                 }
 502         }
 503         else
 504         {
 505                 if(zoomscript_caught)
 506                 {
 507                         localcmd("-button4\n");
 508                         zoomscript_caught = 0;
 509                         ignore_minus_zoom += 1;
 510                 }
 511         }
 512
 513         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 514         activeweapon = getstati(STAT_SWITCHWEAPON);
 515         f = (serverflags & SERVERFLAG_TEAMPLAY);
 516         if(f != teamplay)
 517         {
 518                 teamplay = f;
 519                 HUD_InitScores();
 520         }
 521
 522         if(last_weapon != activeweapon) {
 523                 weapontime = time;
 524                 last_weapon = activeweapon;
 525
 526                 e = get_weaponinfo(activeweapon);
 527                 if(e.netname != "")
 528                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 529                 else
 530                         localcmd("\ncl_hook_activeweapon none\n");
 531         }
 532
 533         // ALWAYS Clear Current Scene First
 534         R_ClearScene();
 535
 536         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 537         R_SetView(VF_SIZE, vf_size);
 538         R_SetView(VF_MIN, vf_min);
 539
 540         // Assign Standard Viewflags
 541         // Draw the World (and sky)
 542         R_SetView(VF_DRAWWORLD, 1);
 543
 544         // Set the console size vars
 545         vid_conwidth = autocvar_vid_conwidth;
 546         vid_conheight = autocvar_vid_conheight;
 547         vid_pixelheight = autocvar_vid_pixelheight;
 548
 549         R_SetView(VF_FOV, GetCurrentFov(fov));
 550
 551         // Camera for demo playback
 552         if(camera_active)
 553         {
 554                 if(autocvar_camera_enable)
 555                         CSQC_Demo_Camera();
 556                 else
 557                 {
 558                         cvar_set("chase_active", ftos(chase_active_backup));
 559                         cvar_set("cl_demo_mousegrab", "0");
 560                         camera_active = FALSE;
 561                 }
 562         }
 563 #ifdef CAMERATEST
 564         else if(autocvar_camera_enable)
 565 #else
 566         else if(autocvar_camera_enable && isdemo())
 567 #endif
 568         {
 569                 // Enable required Darkplaces cvars
 570                 chase_active_backup = autocvar_chase_active;
 571                 cvar_set("chase_active", "2");
 572                 cvar_set("cl_demo_mousegrab", "1");
 573                 camera_active = TRUE;
 574                 camera_mode = FALSE;
 575         }
 576
 577         // Draw the Crosshair
 578         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 579
 580         // Draw the Engine Status Bar (the default Quake HUD)
 581         R_SetView(VF_DRAWENGINEHUD, 0);
 582
 583         // fetch this one only once per frame
 584         hud_showbinds = autocvar_hud_showbinds;
 585         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 586
 587         // Update the mouse position
 588         /*
 589            mousepos_x = vid_conwidth;
 590            mousepos_y = vid_conheight;
 591            mousepos = mousepos*0.5 + getmousepos();
 592          */
 593
 594         e = self;
 595         for(self = world; (self = nextent(self)); )
 596                 if(self.draw)
 597                         self.draw();
 598         self = e;
 599
 600         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 601         R_RenderScene();
 602
 603         // now switch to 2D drawing mode by calling a 2D drawing function
 604         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 605         // next R_RenderScene call
 606         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 607
 608         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 609         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 610         {
 611                 // apply night vision effect
 612                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 613
 614                 if(!nightvision_noise)
 615                 {
 616                         nightvision_noise = spawn();
 617                         nightvision_noise.classname = "nightvision_noise";
 618                 }
 619                 if(!nightvision_noise2)
 620                 {
 621                         nightvision_noise2 = spawn();
 622                         nightvision_noise2.classname = "nightvision_noise2";
 623                 }
 624
 625                 // color tint in yellow
 626                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 627
 628                 // draw BG
 629                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 630                 rgb = '1 1 1';
 631                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 632                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 633                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 634                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 635                 tc_11 = tc_01 + tc_10 - tc_00;
 636                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 637                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 638                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 639                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 640                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 641                 R_EndPolygon();
 642
 643                 // draw FG
 644                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 645                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 646                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 647                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 648                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 649                 tc_11 = tc_01 + tc_10 - tc_00;
 650                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 651                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 652                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 653                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 654                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 655                 R_EndPolygon();
 656         }
 657
 658         // Draw the aiming reticle for weapons that use it
 659         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 660         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 661         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 662         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 663                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 664         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 665                 reticle_type = 2; // nex zoom
 666         else if(button_zoom || zoomscript_caught)
 667                 reticle_type = 1; // normal zoom
 668         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 669                 reticle_type = 2; // nex zoom
 670
 671         if (reticle_type)
 672         {
 673                 if(autocvar_cl_reticle_stretch)
 674                 {
 675                         reticle_size_x = vid_conwidth;
 676                         reticle_size_y = vid_conheight;
 677                         reticle_pos_x = 0;
 678                         reticle_pos_y = 0;
 679                 }
 680                 else
 681                 {
 682                         reticle_size_x = max(vid_conwidth, vid_conheight);
 683                         reticle_size_y = max(vid_conwidth, vid_conheight);
 684                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 685                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 686                 }
 687
 688                 f = current_zoomfraction;
 689                 if(zoomscript_caught)
 690                         f = 1;
 691                 if(autocvar_cl_reticle_item_normal)
 692                 {
 693                         if(reticle_type == 1 && f)
 694                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 695                 }
 696                 if(autocvar_cl_reticle_item_nex)
 697                 {
 698                         if(reticle_type == 2 && f)
 699                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 700                 }
 701         }
 702
 703
 704         // improved polyblend
 705         vector rgb;
 706         if(autocvar_hud_contents)
 707         {
 708                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 709                 vector liquidcolor;
 710
 711                 switch(pointcontents(view_origin))
 712                 {
 713                         case CONTENT_WATER:
 714                                 liquidalpha = autocvar_hud_contents_water_alpha;
 715                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 716                                 incontent = 1;
 717                                 break;
 718
 719                         case CONTENT_LAVA:
 720                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 721                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 722                                 incontent = 1;
 723                                 break;
 724
 725                         case CONTENT_SLIME:
 726                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 727                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 728                                 incontent = 1;
 729                                 break;
 730
 731                         default:
 732                                 liquidalpha = 0;
 733                                 liquidcolor = '0 0 0';
 734                                 incontent = 0;
 735                                 break;
 736                 }
 737
 738                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 739                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 740                         contentfadetime = autocvar_hud_contents_fadeintime;
 741                         liquidalpha_prev = liquidalpha;
 742                         liquidcolor_prev = liquidcolor;
 743                 }
 744                 else
 745                         contentfadetime = autocvar_hud_contents_fadeouttime;
 746
 747                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 748                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 749
 750                 if(contentavgalpha)
 751                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 752         }
 753
 754         if(autocvar_hud_damage)
 755         {
 756                 splash_size_x = max(vid_conwidth, vid_conheight);
 757                 splash_size_y = max(vid_conwidth, vid_conheight);
 758                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 759                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 760
 761                 float myhealth_flash_temp;
 762                 myhealth = getstati(STAT_HEALTH);
 763
 764                 // fade out
 765                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 766                 // add new damage
 767                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 768
 769                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 770                 pain_threshold = autocvar_hud_damage_pain_threshold;
 771                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 772                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 773
 774                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 775                 {
 776                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 777                 }
 778
 779                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 780
 781                 if(myhealth_prev < 1)
 782                 {
 783                         if(myhealth >= 1)
 784                         {
 785                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 786                                 myhealth_flash_temp = 0;
 787                         }
 788                         else
 789                         {
 790                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 791                         }
 792                 }
 793
 794                 if(spectatee_status == -1 || intermission)
 795                 {
 796                         myhealth_flash = 0; // observing, or match ended
 797                         myhealth_flash_temp = 0;
 798                 }
 799
 800                 myhealth_prev = myhealth;
 801
 802                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 803                 {
 804                         if(autocvar_cl_gentle_damage == 2)
 805                         {
 806                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 807                                 {
 808                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 809                                 }
 810                         }
 811                         else
 812                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 813
 814                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 815                 }
 816                 else
 817                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 818         }
 819
 820         // Draw the mouse cursor
 821         // NOTE: drawpic must happen after R_RenderScene for some reason
 822         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 823         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 824         //self = edict_num(player_localnum);
 825         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 826         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 827         // as long as the ctf part isn't in, this is useless
 828         if(menu_visible)
 829                 menu_show();
 830
 831         /*if(gametype == GAME_CTF)
 832           {
 833           ctf_view();
 834           } else */
 835
 836         // draw 2D entities
 837         e = self;
 838         for(self = world; (self = nextent(self)); )
 839                 if(self.draw2d)
 840                         self.draw2d();
 841         self = e;
 842
 843         scoreboard_active = HUD_WouldDrawScoreboard();
 844
 845         hit_time = getstatf(STAT_HIT_TIME);
 846         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 847         {
 848                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 849                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 850         }
 851         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 852         if(typehit_time > nextsound_typehit_time)
 853         {
 854                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 855                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 856         }
 857
 858         if(hud == HUD_SPIDERBOT)
 859                 CSQC_SPIDER_HUD();
 860         else if(hud == HUD_WAKIZASHI)
 861         CSQC_WAKIZASHI_HUD();
 862     else if(hud == HUD_RAPTOR)
 863         CSQC_RAPTOR_HUD();
 864     else if(hud == HUD_BUMBLEBEE)
 865         CSQC_BUMBLE_HUD();
 866         else
 867         {
 868                 if(gametype == GAME_FREEZETAG)
 869                 {
 870                         if(getstati(STAT_FROZEN))
 871                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 872                         if(getstatf(STAT_REVIVE_PROGRESS))
 873                         {
 874                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 875                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 876                         }
 877                 }
 878
 879                 if(autocvar_r_letterbox == 0)
 880                         if(autocvar_viewsize < 120)
 881                                 CSQC_common_hud();
 882
 883                 // crosshair goes VERY LAST
 884                 if(!scoreboard_active && !camera_active && intermission != 2) {
 885                         string wcross_style;
 886                         float wcross_alpha, wcross_resolution;
 887                         wcross_style = autocvar_crosshair;
 888                         if (wcross_style == "0")
 889                                 return;
 890                         wcross_resolution = autocvar_crosshair_size;
 891                         if (wcross_resolution == 0)
 892                                 return;
 893                         wcross_alpha = autocvar_crosshair_alpha;
 894                         if (wcross_alpha == 0)
 895                                 return;
 896
 897                         // TrueAim check
 898                         float shottype;
 899
 900                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 901                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 902                         wcross_origin_z = 0;
 903                         if(autocvar_crosshair_hittest)
 904                         {
 905                                 vector wcross_oldorigin;
 906                                 wcross_oldorigin = wcross_origin;
 907                                 shottype = TrueAimCheck();
 908                                 if(shottype == SHOTTYPE_HITWORLD)
 909                                 {
 910                                         v = wcross_origin - wcross_oldorigin;
 911                                         v_x /= vid_conwidth;
 912                                         v_y /= vid_conheight;
 913                                         if(vlen(v) > 0.01)
 914                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 915                                 }
 916                                 if(!autocvar_crosshair_hittest_showimpact)
 917                                         wcross_origin = wcross_oldorigin;
 918                         }
 919                         else
 920                                 shottype = SHOTTYPE_HITWORLD;
 921
 922                         vector wcross_color, wcross_size;
 923                         string wcross_wep, wcross_name;
 924                         float wcross_scale, wcross_blur;
 925
 926                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 927                                 e = get_weaponinfo(activeweapon);
 928                                 if (e && e.netname != "")
 929                                 {
 930                                         wcross_wep = e.netname;
 931                                         if(autocvar_crosshair_per_weapon)
 932                                         {
 933                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 934                                                 if (wcross_resolution == 0)
 935                                                         return;
 936                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 937                                                 if (wcross_alpha == 0)
 938                                                         return;
 939
 940                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 941                                                 if(wcross_style == "" || wcross_style == "0")
 942                                                         wcross_style = wcross_wep;
 943                                         }
 944                                 }
 945                         }
 946                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 947                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 948                         else if(autocvar_crosshair_color_by_health)
 949                         {
 950                                 local float x = getstati(STAT_HEALTH);
 951
 952                                 //x = red
 953                                 //y = green
 954                                 //z = blue
 955
 956                                 wcross_color_z = 0;
 957
 958                                 if(x > 200)
 959                                 {
 960                                         wcross_color_x = 0;
 961                                         wcross_color_y = 1;
 962                                 }
 963                                 else if(x > 150)
 964                                 {
 965                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 966                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 967                                 }
 968                                 else if(x > 100)
 969                                 {
 970                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 971                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 972                                         wcross_color_z = 1 - (x-100)*0.02;
 973                                 }
 974                                 else if(x > 50)
 975                                 {
 976                                         wcross_color_x = 1;
 977                                         wcross_color_y = 1;
 978                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 979                                 }
 980                                 else if(x > 20)
 981                                 {
 982                                         wcross_color_x = 1;
 983                                         wcross_color_y = (x-20)*90/27/100;
 984                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 985                                 }
 986                                 else
 987                                 {
 988                                         wcross_color_x = 1;
 989                                         wcross_color_y = 0;
 990                                 }
 991                         }
 992                         else
 993                                 wcross_color = stov(autocvar_crosshair_color);
 994
 995                         wcross_name = strcat("gfx/crosshair", wcross_style);
 996
 997                         if(autocvar_crosshair_effect_scalefade)
 998                         {
 999                                 wcross_scale = wcross_resolution;
1000                                 wcross_resolution = 1;
1001                         }
1002                         else
1003                         {
1004                                 wcross_scale = 1;
1005                         }
1006
1007                         if(autocvar_crosshair_pickup)
1008                         {
1009                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1010                                 {
1011                                         pickup_crosshair_size = 1;
1012                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1013                                 }
1014
1015                                 if(pickup_crosshair_size > 0)
1016                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1017                                 else
1018                                         pickup_crosshair_size = 0;
1019
1020                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1021                         }
1022
1023                         vector hitindication_color;
1024                         if(autocvar_crosshair_hitindication)
1025                         {
1026                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1027                                 if(hitindication_crosshair_time < hit_time)
1028                                 {
1029                                         hitindication_crosshair_size = 1;
1030                                         hitindication_crosshair_time = hit_time;
1031                                 }
1032
1033                                 if(hitindication_crosshair_size > 0)
1034                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1035                                 else
1036                                         hitindication_crosshair_size = 0;
1037
1038                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1039                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1040                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1041                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1042                         }
1043
1044                         if(shottype == SHOTTYPE_HITENEMY)
1045                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1046                         if(shottype == SHOTTYPE_HITTEAM)
1047                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1048
1049                         f = autocvar_crosshair_effect_speed;
1050                         if(f < 0)
1051                                 f *= -2 * g_weaponswitchdelay;
1052                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1053                         {
1054                                 wcross_changedonetime = time + f;
1055                         }
1056                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1057                         {
1058                                 wcross_name_changestarttime = time;
1059                                 wcross_name_changedonetime = time + f;
1060                                 if(wcross_name_goal_prev_prev)
1061                                         strunzone(wcross_name_goal_prev_prev);
1062                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1063                                 wcross_name_goal_prev = strzone(wcross_name);
1064                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1065                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1066                                 wcross_resolution_goal_prev = wcross_resolution;
1067                         }
1068
1069                         wcross_scale_goal_prev = wcross_scale;
1070                         wcross_alpha_goal_prev = wcross_alpha;
1071                         wcross_color_goal_prev = wcross_color;
1072
1073                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1074                         {
1075                                 wcross_blur = 1;
1076                                 wcross_alpha *= 0.75;
1077                         }
1078                         else
1079                                 wcross_blur = 0;
1080                         // *_prev is at time-frametime
1081                         // * is at wcross_changedonetime+f
1082                         // what do we have at time?
1083                         if(time < wcross_changedonetime)
1084                         {
1085                                 f = frametime / (wcross_changedonetime - time + frametime);
1086                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1087                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1088                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1089                         }
1090
1091                         wcross_scale_prev = wcross_scale;
1092                         wcross_alpha_prev = wcross_alpha;
1093                         wcross_color_prev = wcross_color;
1094
1095                         wcross_scale *= 1 - autocvar__menu_alpha;
1096                         wcross_alpha *= 1 - autocvar__menu_alpha;
1097                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1098
1099                         // crosshair rings for weapon stats
1100                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1101                         {
1102                                 // declarations and stats
1103                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1104                                 string ring_image, ring_inner_image;
1105                                 vector ring_rgb, ring_inner_rgb;
1106
1107                                 ring_scale = autocvar_crosshair_ring_size;
1108
1109                                 float weapon_clipload, weapon_clipsize;
1110                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1111                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1112
1113                                 float nex_charge, nex_chargepool;
1114                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1115                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1116
1117                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1118                                         nex_charge_movingavg = nex_charge;
1119
1120
1121                                 // handle the values
1122                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1123                                 {
1124                                         if (nex_chargepool || use_nex_chargepool) {
1125                                                 use_nex_chargepool = 1;
1126                                                 ring_inner_value = nex_chargepool;
1127                                         } else {
1128                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1129                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1130                                         }
1131
1132                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1133                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1134                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1135
1136                                         // draw the outer ring to show the current charge of the weapon
1137                                         ring_value = nex_charge;
1138                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1139                                         ring_rgb = wcross_color;
1140                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1141                                 }
1142                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1143                                 {
1144                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1145                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1146                                         ring_rgb = wcross_color;
1147                                         ring_image = "gfx/crosshair_ring.tga";
1148                                 }
1149
1150                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1151                                 {
1152                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1153                                         ring_scale = autocvar_crosshair_ring_reload_size;
1154                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1155                                         ring_rgb = wcross_color;
1156
1157                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1158                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1159                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1160                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1161                                         else
1162                                                 ring_image = "gfx/crosshair_ring.tga";
1163                                 }
1164
1165                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1166                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1167
1168                                 if (ring_value)
1169                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1170                         }
1171
1172 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1173                         do \
1174                         { \
1175                                 if(wcross_blur > 0) \
1176                                 { \
1177                                         for(i = -2; i <= 2; ++i) \
1178                                                 for(j = -2; j <= 2; ++j) \
1179                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1180                                 } \
1181                                 else \
1182                                 { \
1183                                         M(0,0,sz,wcross_name,wcross_alpha); \
1184                                 } \
1185                         } \
1186                         while(0)
1187
1188 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1189                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1190
1191 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1192                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1193
1194                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1195                         {
1196                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1197                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1198                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1199                                 f = 1 - f;
1200                         }
1201                         else
1202                         {
1203                                 f = 1;
1204                         }
1205
1206                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1207                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1208
1209                         if(autocvar_crosshair_dot)
1210             {
1211                 vector wcross_color_old;
1212                 wcross_color_old = wcross_color;
1213                 if(autocvar_crosshair_dot_color != "0")
1214                     wcross_color = stov(autocvar_crosshair_dot_color);
1215                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1216                 wcross_color = wcross_color_old;
1217             }
1218
1219                         wcross_name_alpha_goal_prev = f;
1220                 }
1221                 else
1222                 {
1223                         wcross_scale_prev = 0;
1224                         wcross_alpha_prev = 0;
1225                         wcross_scale_goal_prev = 0;
1226                         wcross_alpha_goal_prev = 0;
1227                         wcross_changedonetime = 0;
1228                         if(wcross_name_goal_prev)
1229                                 strunzone(wcross_name_goal_prev);
1230                         wcross_name_goal_prev = string_null;
1231                         if(wcross_name_goal_prev_prev)
1232                                 strunzone(wcross_name_goal_prev_prev);
1233                         wcross_name_goal_prev_prev = string_null;
1234                         wcross_name_changestarttime = 0;
1235                         wcross_name_changedonetime = 0;
1236                         wcross_name_alpha_goal_prev = 0;
1237                         wcross_name_alpha_goal_prev_prev = 0;
1238                         wcross_resolution_goal_prev = 0;
1239                         wcross_resolution_goal_prev_prev = 0;
1240                 }
1241         }
1242
1243         if(NextFrameCommand)
1244         {
1245                 localcmd("\n", NextFrameCommand, "\n");
1246                 NextFrameCommand = string_null;
1247         }
1248
1249         // we must do this check AFTER a frame was rendered, or it won't work
1250         if(cs_project_is_b0rked == 0)
1251         {
1252                 string w0, h0;
1253                 w0 = ftos(autocvar_vid_conwidth);
1254                 h0 = ftos(autocvar_vid_conheight);
1255                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1256                 //R_SetView(VF_FOV, '90 90 0');
1257                 R_SetView(VF_ORIGIN, '0 0 0');
1258                 R_SetView(VF_ANGLES, '0 0 0');
1259                 R_SetView(VF_PERSPECTIVE, 1);
1260                 makevectors('0 0 0');
1261                 vector v1, v2;
1262                 cvar_set("vid_conwidth", "800");
1263                 cvar_set("vid_conheight", "600");
1264                 v1 = cs_project(v_forward);
1265                 cvar_set("vid_conwidth", "640");
1266                 cvar_set("vid_conheight", "480");
1267                 v2 = cs_project(v_forward);
1268                 if(v1 == v2)
1269                         cs_project_is_b0rked = 1;
1270                 else
1271                         cs_project_is_b0rked = -1;
1272                 cvar_set("vid_conwidth", w0);
1273                 cvar_set("vid_conheight", h0);
1274         }
1275
1276         if(autocvar__hud_configure)
1277                 HUD_Panel_Mouse();
1278
1279         // let's reset the view back to normal for the end
1280         R_SetView(VF_MIN, '0 0 0');
1281         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1282 }
1283
1284 void CSQC_common_hud(void)
1285 {
1286         // HUD_SortFrags(); done in HUD_Draw
1287         float hud;
1288         hud = getstati(STAT_HUD);
1289
1290         //hud = 10;
1291         switch(hud)
1292         {
1293                 case HUD_NORMAL:
1294                         // do some accuracy var caching
1295                         float i;
1296                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1297                         {
1298                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1299                                 {
1300                                         if(acc_color_levels)
1301                                                 strunzone(acc_color_levels);
1302                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1303                                         acc_levels = tokenize(acc_color_levels);
1304                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1305                                                 acc_levels = MAX_ACCURACY_LEVELS;
1306
1307                                         for (i = 0; i < acc_levels; ++i)
1308                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1309                                 }
1310                                 // let know that acc_col[] needs to be loaded
1311                                 acc_col_x[0] = -1;
1312                         }
1313
1314                         HUD_Main(); // always run these functions for alpha checks
1315                         HUD_DrawScoreboard();
1316
1317                         if (scoreboard_active) // scoreboard/accuracy
1318                         {
1319                                 HUD_Reset();
1320                                 // HUD_DrawScoreboard takes care of centerprint_start
1321                         }
1322                         else if (intermission == 2) // map voting screen
1323                         {
1324                                 HUD_FinaleOverlay();
1325                                 HUD_Reset();
1326
1327                                 centerprint_start_x = 0;
1328                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1329                         }
1330                         else // hud
1331                         {
1332                                 centerprint_start_x = 0;
1333                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1334                         }
1335
1336                         HUD_DrawCenterPrint();
1337                         break;
1338
1339                 case HUD_SPIDERBOT:
1340                         CSQC_SPIDER_HUD();
1341                         break;
1342
1343                 case HUD_WAKIZASHI:
1344                         CSQC_WAKIZASHI_HUD();
1345                         break;
1346
1347         case HUD_BUMBLEBEE:
1348             CSQC_BUMBLE_HUD();
1349             break;
1350
1351         }
1352 }
1353
1354
1355 // following vectors must be global to allow seamless switching between camera modes
1356 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1357 void CSQC_Demo_Camera()
1358 {
1359         float speed, attenuation, dimensions;
1360         vector tmp, delta;
1361
1362         if( autocvar_camera_reset || !camera_mode )
1363         {
1364                 camera_offset = '0 0 0';
1365                 current_angles = '0 0 0';
1366                 camera_direction = '0 0 0';
1367                 camera_offset_z += 30;
1368                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1369                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1370                 current_origin = view_origin;
1371                 current_camera_offset  = camera_offset;
1372                 cvar_set("camera_reset", "0");
1373                 camera_mode = CAMERA_CHASE;
1374         }
1375
1376         // Camera angles
1377         if( camera_roll )
1378                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1379
1380         if(autocvar_camera_look_player)
1381         {
1382                 local vector dir;
1383                 local float n;
1384
1385                 dir = normalize(view_origin - current_position);
1386                 n = mouse_angles_z;
1387                 mouse_angles = vectoangles(dir);
1388                 mouse_angles_x = mouse_angles_x * -1;
1389                 mouse_angles_z = n;
1390         }
1391         else
1392         {
1393                 tmp = getmousepos() * 0.1;
1394                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1395                 {
1396                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1397                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1398                 }
1399         }
1400
1401         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1402         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1403         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1404         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1405
1406         // Fix difference when angles don't have the same sign
1407         delta = '0 0 0';
1408         if(mouse_angles_y < -60 && current_angles_y > 60)
1409                 delta = '0 360 0';
1410         if(mouse_angles_y > 60 && current_angles_y < -60)
1411                 delta = '0 -360 0';
1412
1413         if(autocvar_camera_look_player)
1414                 attenuation = autocvar_camera_look_attenuation;
1415         else
1416                 attenuation = autocvar_camera_speed_attenuation;
1417
1418         attenuation = 1 / max(1, attenuation);
1419         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1420
1421         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1422         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1423         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1424         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1425
1426         // Camera position
1427         tmp = '0 0 0';
1428         dimensions = 0;
1429
1430         if( camera_direction_x )
1431         {
1432                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1433                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1434                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1435                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1436                 ++dimensions;
1437         }
1438
1439         if( camera_direction_y )
1440         {
1441                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1442                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1443                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1444                 ++dimensions;
1445         }
1446
1447         if( camera_direction_z )
1448         {
1449                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1450                 ++dimensions;
1451         }
1452
1453         if(autocvar_camera_free)
1454                 speed = autocvar_camera_speed_free;
1455         else
1456                 speed = autocvar_camera_speed_chase;
1457
1458         if(dimensions)
1459         {
1460                 speed = speed * sqrt(1 / dimensions);
1461                 camera_offset += tmp * speed;
1462         }
1463
1464         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1465
1466         // Camera modes
1467         if( autocvar_camera_free )
1468         {
1469                 if ( camera_mode == CAMERA_CHASE )
1470                 {
1471                         current_camera_offset = current_origin + current_camera_offset;
1472                         camera_offset = current_origin + camera_offset;
1473                 }
1474
1475                 camera_mode = CAMERA_FREE;
1476                 current_position = current_camera_offset;
1477         }
1478         else
1479         {
1480                 if ( camera_mode == CAMERA_FREE )
1481                 {
1482                         current_origin = view_origin;
1483                         camera_offset = camera_offset - current_origin;
1484                         current_camera_offset = current_camera_offset - current_origin;
1485                 }
1486
1487                 camera_mode = CAMERA_CHASE;
1488
1489                 if(autocvar_camera_chase_smoothly)
1490                         current_origin += (view_origin - current_origin) * attenuation;
1491                 else
1492                         current_origin = view_origin;
1493
1494                 current_position = current_origin + current_camera_offset;
1495         }
1496
1497         R_SetView(VF_ANGLES, current_angles);
1498         R_SetView(VF_ORIGIN, current_position);
1499 }