qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  14                 return;
  15         if(g_balance_porto_secondary)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                 {
  61                         portal1_idx = idx;
  62                         if(portal_number >= 2)
  63                                 break;
  64                 }
  65         }
  66
  67         while(idx >= 2)
  68         {
  69                 p = polyline[idx-2];
  70                 q = polyline[idx-1];
  71                 if(idx == 2)
  72                         p = p - view_up * 16;
  73                 if(idx-1 >= portal1_idx)
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 else
  78                 {
  79                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  80                 }
  81                 --idx;
  82         }
  83 }
  84
  85 void Porto_Init()
  86 {
  87         porto = spawn();
  88         porto.classname = "porto";
  89         porto.draw = Porto_Draw;
  90         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  91 }
  92
  93 float drawtime;
  94 float avgspeed;
  95 vector GetCurrentFov(float fov)
  96 {
  97         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  98         float velocityzoom, curspeed;
  99         vector v;
 100
 101         zoomsensitivity = autocvar_cl_zoomsensitivity;
 102         zoomfactor = autocvar_cl_zoomfactor;
 103         if(zoomfactor < 1 || zoomfactor > 16)
 104                 zoomfactor = 2.5;
 105         zoomspeed = autocvar_cl_zoomspeed;
 106         if(zoomspeed >= 0)
 107                 if(zoomspeed < 0.5 || zoomspeed > 16)
 108                         zoomspeed = 3.5;
 109
 110         zoomdir = button_zoom;
 111         if(hud == HUD_NORMAL)
 112         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 113                 zoomdir += button_attack2;
 114         if(spectatee_status > 0 || isdemo())
 115         {
 116                 if(spectatorbutton_zoom)
 117                 {
 118                         if(zoomdir)
 119                                 zoomdir = 0;
 120                         else
 121                                 zoomdir = 1;
 122                 }
 123                 // fteqcc failed twice here already, don't optimize this
 124         }
 125
 126         if(zoomdir)
 127                 zoomin_effect = 0;
 128
 129         if(zoomin_effect || camera_active)
 130         {
 131                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 132         }
 133         else
 134         {
 135                 if(zoomspeed < 0) // instant zoom
 136                 {
 137                         if(zoomdir)
 138                                 current_viewzoom = 1 / zoomfactor;
 139                         else
 140                                 current_viewzoom = 1;
 141                 }
 142                 else
 143                 {
 144                         if(zoomdir)
 145                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 146                         else
 147                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 148                 }
 149         }
 150
 151         if(almost_equals(current_viewzoom, 1))
 152                 current_zoomfraction = 0;
 153         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 154                 current_zoomfraction = 1;
 155         else
 156                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 157
 158         if(zoomsensitivity < 1)
 159                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 160         else
 161                 setsensitivityscale(1);
 162
 163         makevectors(view_angles);
 164
 165         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 166         {
 167                 v = pmove_vel;
 168                 if(csqcplayer)
 169                         v = csqcplayer.velocity;
 170
 171                 switch(autocvar_cl_velocityzoom_type)
 172                 {
 173                         case 3: curspeed = max(0, v_forward * v); break;
 174                         case 2: curspeed = (v_forward * v); break;
 175                         case 1: default: curspeed = vlen(v); break;
 176                 }
 177
 178                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 179                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 180                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 181
 182                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 183         }
 184         else
 185                 velocityzoom = 1;
 186
 187         float frustumx, frustumy, fovx, fovy;
 188         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 189         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 190         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 191         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 192
 193         return '1 0 0' * fovx + '0 1 0' * fovy;
 194 }
 195
 196 // this function must match W_SetupShot!
 197 float zoomscript_caught;
 198
 199 vector wcross_origin;
 200 float wcross_scale_prev, wcross_alpha_prev;
 201 vector wcross_color_prev;
 202 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 203 vector wcross_color_goal_prev;
 204 float wcross_changedonetime;
 205
 206 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 207 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 208 float wcross_name_changestarttime, wcross_name_changedonetime;
 209 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 210 entity trueaim;
 211 entity trueaim_rifle;
 212
 213 #define SHOTTYPE_HITTEAM 1
 214 #define SHOTTYPE_HITOBSTRUCTION 2
 215 #define SHOTTYPE_HITWORLD 3
 216 #define SHOTTYPE_HITENEMY 4
 217
 218 void TrueAim_Init()
 219 {
 220         trueaim = spawn();
 221         trueaim.classname = "trueaim";
 222         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 223         trueaim_rifle = spawn();
 224         trueaim_rifle.classname = "trueaim_rifle";
 225         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 226 }
 227
 228 float EnemyHitCheck()
 229 {
 230         float t, n;
 231         wcross_origin = project_3d_to_2d(trace_endpos);
 232         wcross_origin_z = 0;
 233         if(trace_ent)
 234                 n = trace_ent.entnum;
 235         else
 236                 n = trace_networkentity;
 237         if(n < 1)
 238                 return SHOTTYPE_HITWORLD;
 239         if(n > maxclients)
 240                 return SHOTTYPE_HITWORLD;
 241         t = GetPlayerColor(n - 1);
 242         if(teamplay)
 243                 if(t == myteam)
 244                         return SHOTTYPE_HITTEAM;
 245         if(t == COLOR_SPECTATOR)
 246                 return SHOTTYPE_HITWORLD;
 247         return SHOTTYPE_HITENEMY;
 248 }
 249
 250 float TrueAimCheck()
 251 {
 252         float nudge = 1; // added to traceline target and subtracted from result
 253         vector vecs, trueaimpoint, w_shotorg;
 254         vector mi, ma, dv;
 255         float shottype;
 256         entity ta;
 257         float mv;
 258
 259         mi = ma = '0 0 0';
 260         ta = trueaim;
 261         mv = MOVE_NOMONSTERS;
 262
 263         switch(activeweapon)
 264         {
 265                 case WEP_TUBA: // no aim
 266                 case WEP_PORTO: // shoots from eye
 267                 case WEP_HOOK: // no trueaim
 268                 case WEP_GRENADE_LAUNCHER: // toss curve
 269                         return SHOTTYPE_HITWORLD;
 270                 case WEP_NEX:
 271                 case WEP_MINSTANEX:
 272                         mv = MOVE_NORMAL;
 273                         break;
 274                 case WEP_RIFLE:
 275                         ta = trueaim_rifle;
 276                         mv = MOVE_NORMAL;
 277                         if(zoomscript_caught)
 278                         {
 279                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280                                 return EnemyHitCheck();
 281                         }
 282                         break;
 283                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 284                         mi = '-3 -3 -3';
 285                         ma = '3 3 3';
 286                         break;
 287                 case WEP_FIREBALL: // projectile has a size!
 288                         mi = '-16 -16 -16';
 289                         ma = '16 16 16';
 290                         break;
 291                 case WEP_SEEKER: // projectile has a size!
 292                         mi = '-2 -2 -2';
 293                         ma = '2 2 2';
 294                         break;
 295                 case WEP_ELECTRO: // projectile has a size!
 296                         mi = '0 0 -3';
 297                         ma = '0 0 -3';
 298                         break;
 299         }
 300
 301         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 302
 303         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 304         trueaimpoint = trace_endpos;
 305
 306         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 307                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 308
 309         if(vecs_x > 0)
 310                 vecs_y = -vecs_y;
 311         else
 312                 vecs = '0 0 0';
 313
 314         dv = view_right * vecs_y + view_up * vecs_z;
 315         w_shotorg = view_origin + dv;
 316
 317         // now move the vecs forward as much as requested if possible
 318         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 319         w_shotorg = trace_endpos - view_forward * nudge;
 320
 321         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 322         shottype = EnemyHitCheck();
 323         if(shottype != SHOTTYPE_HITWORLD)
 324                 return shottype;
 325
 326 #if 0
 327         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 328         // or rather, I know why, but see no fix
 329         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 330                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 331                 return SHOTTYPE_HITOBSTRUCTION;
 332 #endif
 333
 334         return SHOTTYPE_HITWORLD;
 335 }
 336
 337 void CSQC_common_hud(void);
 338
 339 void PostInit(void);
 340 void CSQC_Demo_Camera();
 341 float HUD_WouldDrawScoreboard();
 342 float camera_mode;
 343 float CAMERA_FREE = 1;
 344 float CAMERA_CHASE = 2;
 345 float reticle_type;
 346 string NextFrameCommand;
 347 void CSQC_SPIDER_HUD();
 348 void CSQC_RAPTOR_HUD();
 349
 350 vector freeze_org, freeze_ang;
 351 entity nightvision_noise, nightvision_noise2;
 352
 353 #define MAX_TIME_DIFF 5
 354 float pickup_crosshair_time, pickup_crosshair_size;
 355 float hit_time, typehit_time;
 356 float nextsound_hit_time, nextsound_typehit_time;
 357 float hitindication_crosshair_time, hitindication_crosshair_size;
 358 float use_nex_chargepool;
 359
 360 float myhealth, myhealth_prev;
 361 float myhealth_flash;
 362
 363 float old_blurradius, old_bluralpha;
 364 float old_sharpen_intensity;
 365
 366 vector myhealth_gentlergb;
 367
 368 float contentavgalpha, liquidalpha_prev;
 369 vector liquidcolor_prev;
 370
 371 float eventchase_current_distance;
 372
 373 vector damage_blurpostprocess, content_blurpostprocess;
 374
 375 float checkfail[16];
 376
 377 #define BUTTON_3 4
 378 #define BUTTON_4 8
 379 float cl_notice_run();
 380 void CSQC_UpdateView(float w, float h)
 381 {
 382         entity e;
 383         float fov;
 384         float f, i, j;
 385         vector v;
 386         vector vf_size, vf_min;
 387         float a;
 388
 389         execute_next_frame();
 390
 391         ++framecount;
 392
 393         hud = getstati(STAT_HUD);
 394
 395         if(autocvar__hud_showbinds_reload) // menu can set this one
 396         {
 397                 db_close(binddb);
 398                 binddb = db_create();
 399                 cvar_set("_hud_showbinds_reload", "0");
 400         }
 401
 402         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 403                 view_quality = getproperty(VF_MINFPS_QUALITY);
 404         else
 405                 view_quality = 1;
 406
 407         button_attack2 = (input_buttons & BUTTON_3);
 408         button_zoom = (input_buttons & BUTTON_4);
 409
 410         // FIXME do we need this hack?
 411         if(isdemo())
 412         {
 413                 // in demos, input_buttons do not work
 414                 button_zoom = (autocvar__togglezoom == "-");
 415         }
 416
 417 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 418         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 419         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 420         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 421         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 422         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 423         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 424         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 425
 426         vf_size = getpropertyvec(VF_SIZE);
 427         vf_min = getpropertyvec(VF_MIN);
 428         vid_width = vf_size_x;
 429         vid_height = vf_size_y;
 430
 431         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 432         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 433
 434         WaypointSprite_Load();
 435
 436         CSQCPlayer_SetCamera();
 437
 438 #ifdef COMPAT_XON050_ENGINE
 439         if(spectatee_status)
 440                 myteam = GetPlayerColor(spectatee_status - 1);
 441         else
 442 #endif
 443                 myteam = GetPlayerColor(player_localentnum - 1);
 444
 445         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 446
 447         // event chase camera
 448         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 449         {
 450                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 451                 {
 452                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 453                         vector current_view_origin = ((csqcplayer ? csqcplayer.origin : pmove_org) + autocvar_sv_spectator_viewoffset);
 454
 455                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 456                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 457                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 458                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 459
 460                         // make the camera smooth back
 461                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 462                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 463                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 464                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 465
 466                         makevectors(view_angles);
 467
 468                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 469                         WarpZone_TraceBox(current_view_origin, autocvar_sv_spectator_mins, autocvar_sv_spectator_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 470
 471                         setproperty(VF_ORIGIN, ((trace_startsolid) ? current_view_origin : trace_endpos));
 472                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 473                 }
 474                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 475                 {
 476                         cvar_set("chase_active", "0");
 477                         eventchase_current_distance = 0; // start from 0 next time
 478                 }
 479         }
 480         // workaround for camera stuck between player's legs when using chase_active 1
 481         // because the engine stops updating the chase_active camera when the game ends
 482         else if(intermission)
 483         {
 484                 cvar_settemp("chase_active", "-1");
 485                 eventchase_current_distance = 0;
 486         }
 487
 488         // do lockview after event chase camera so that it still applies whenever necessary.
 489         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 490         {
 491                 setproperty(VF_ORIGIN, freeze_org);
 492                 setproperty(VF_ANGLES, freeze_ang);
 493         }
 494         else
 495         {
 496                 freeze_org = getpropertyvec(VF_ORIGIN);
 497                 freeze_ang = getpropertyvec(VF_ANGLES);
 498         }
 499
 500         WarpZone_FixView();
 501         //WarpZone_FixPMove();
 502
 503         // Render the Scene
 504         view_origin = getpropertyvec(VF_ORIGIN);
 505         view_angles = getpropertyvec(VF_ANGLES);
 506         makevectors(view_angles);
 507         view_forward = v_forward;
 508         view_right = v_right;
 509         view_up = v_up;
 510
 511 #ifdef BLURTEST
 512         if(time > blurtest_time0 && time < blurtest_time1)
 513         {
 514                 float r, t;
 515
 516                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 517                 r = t * blurtest_radius;
 518                 f = 1 / pow(t, blurtest_power) - 1;
 519
 520                 cvar_set("r_glsl_postprocess", "1");
 521                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 522         }
 523         else
 524         {
 525                 cvar_set("r_glsl_postprocess", "0");
 526                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 527         }
 528 #endif
 529
 530         TargetMusic_Advance();
 531         Fog_Force();
 532
 533         if(drawtime == 0)
 534                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 535         else
 536                 drawframetime = bound(0.000001, time - drawtime, 1);
 537         drawtime = time;
 538
 539         // watch for gametype changes here...
 540         // in ParseStuffCMD the cmd isn't executed yet :/
 541         // might even be better to add the gametype to TE_CSQC_INIT...?
 542         if(!postinit)
 543                 PostInit();
 544
 545         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 546         {
 547                 if(calledhooks & HOOK_START)
 548                 {
 549                         localcmd("\ncl_hook_gameend\n");
 550                         calledhooks |= HOOK_END;
 551                 }
 552         }
 553
 554         Announcer();
 555
 556         fov = autocvar_fov;
 557         if(fov <= 59.5)
 558         {
 559                 if(!zoomscript_caught)
 560                 {
 561                         localcmd("+button9\n");
 562                         zoomscript_caught = 1;
 563                 }
 564         }
 565         else
 566         {
 567                 if(zoomscript_caught)
 568                 {
 569                         localcmd("-button9\n");
 570                         zoomscript_caught = 0;
 571                 }
 572         }
 573
 574         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 575
 576         // next WANTED weapon (for HUD)
 577         switchweapon = getstati(STAT_SWITCHWEAPON);
 578
 579         // currently switching-to weapon (for crosshair)
 580         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 581
 582         // actually active weapon (for zoom)
 583         activeweapon = getstati(STAT_ACTIVEWEAPON);
 584
 585         f = (serverflags & SERVERFLAG_TEAMPLAY);
 586         if(f != teamplay)
 587         {
 588                 teamplay = f;
 589                 HUD_InitScores();
 590         }
 591
 592         if(last_switchweapon != switchweapon) {
 593                 weapontime = time;
 594                 last_switchweapon = switchweapon;
 595         }
 596         if(last_activeweapon != activeweapon) {
 597                 last_activeweapon = activeweapon;
 598
 599                 e = get_weaponinfo(activeweapon);
 600                 if(e.netname != "")
 601                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 602                 else
 603                         localcmd("\ncl_hook_activeweapon none\n");
 604         }
 605
 606         // ALWAYS Clear Current Scene First
 607         clearscene();
 608 #ifdef WORKAROUND_XON010
 609         if(checkextension("DP_CSQC_ROTATEMOVES"))
 610         {
 611 #endif
 612         setproperty(VF_ORIGIN, view_origin);
 613         setproperty(VF_ANGLES, view_angles);
 614 #ifdef WORKAROUND_XON010
 615         }
 616 #endif
 617
 618         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 619         setproperty(VF_SIZE, vf_size);
 620         setproperty(VF_MIN, vf_min);
 621
 622         // Assign Standard Viewflags
 623         // Draw the World (and sky)
 624         setproperty(VF_DRAWWORLD, 1);
 625
 626         // Set the console size vars
 627         vid_conwidth = autocvar_vid_conwidth;
 628         vid_conheight = autocvar_vid_conheight;
 629         vid_pixelheight = autocvar_vid_pixelheight;
 630
 631         setproperty(VF_FOV, GetCurrentFov(fov));
 632
 633         // Camera for demo playback
 634         if(camera_active)
 635         {
 636                 if(autocvar_camera_enable)
 637                         CSQC_Demo_Camera();
 638                 else
 639                 {
 640                         cvar_set("chase_active", ftos(chase_active_backup));
 641                         cvar_set("cl_demo_mousegrab", "0");
 642                         camera_active = FALSE;
 643                 }
 644         }
 645 #ifdef CAMERATEST
 646         else if(autocvar_camera_enable)
 647 #else
 648         else if(autocvar_camera_enable && isdemo())
 649 #endif
 650         {
 651                 // Enable required Darkplaces cvars
 652                 chase_active_backup = autocvar_chase_active;
 653                 cvar_set("chase_active", "2");
 654                 cvar_set("cl_demo_mousegrab", "1");
 655                 camera_active = TRUE;
 656                 camera_mode = FALSE;
 657         }
 658
 659         // Draw the Crosshair
 660         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 661
 662         // Draw the Engine Status Bar (the default Quake HUD)
 663         setproperty(VF_DRAWENGINESBAR, 0);
 664
 665         // Update the mouse position
 666         /*
 667            mousepos_x = vid_conwidth;
 668            mousepos_y = vid_conheight;
 669            mousepos = mousepos*0.5 + getmousepos();
 670          */
 671
 672         e = self;
 673         for(self = world; (self = nextent(self)); )
 674                 if(self.draw)
 675                         self.draw();
 676         self = e;
 677
 678         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 679         renderscene();
 680
 681         // now switch to 2D drawing mode by calling a 2D drawing function
 682         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 683         // next R_RenderScene call
 684         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 685
 686         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 687         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 688         {
 689                 // apply night vision effect
 690                 vector tc_00, tc_01, tc_10, tc_11;
 691                 vector rgb;
 692                 rgb_x = 0; // fteqcc sucks
 693                 rgb_y = 0; // fteqcc sucks
 694                 rgb_z = 0; // fteqcc sucks
 695
 696                 if(!nightvision_noise)
 697                 {
 698                         nightvision_noise = spawn();
 699                         nightvision_noise.classname = "nightvision_noise";
 700                 }
 701                 if(!nightvision_noise2)
 702                 {
 703                         nightvision_noise2 = spawn();
 704                         nightvision_noise2.classname = "nightvision_noise2";
 705                 }
 706
 707                 // color tint in yellow
 708                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 709
 710                 // draw BG
 711                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 712                 rgb = '1 1 1';
 713                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 714                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 715                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 716                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 717                 tc_11 = tc_01 + tc_10 - tc_00;
 718                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 719                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 720                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 721                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 722                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 723                 R_EndPolygon();
 724
 725                 // draw FG
 726                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 727                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 728                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 729                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 730                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 731                 tc_11 = tc_01 + tc_10 - tc_00;
 732                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 733                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 734                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 735                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 736                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 737                 R_EndPolygon();
 738         }
 739
 740         // Draw the aiming reticle for weapons that use it
 741         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 742         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 743         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 744         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 745                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 746         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 747                 reticle_type = 2; // nex zoom
 748         else if(button_zoom || zoomscript_caught)
 749                 reticle_type = 1; // normal zoom
 750         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 751                 reticle_type = 2; // nex zoom
 752
 753         if(reticle_type && autocvar_cl_reticle)
 754         {
 755                 if(autocvar_cl_reticle_stretch)
 756                 {
 757                         reticle_size_x = vid_conwidth;
 758                         reticle_size_y = vid_conheight;
 759                         reticle_pos_x = 0;
 760                         reticle_pos_y = 0;
 761                 }
 762                 else
 763                 {
 764                         reticle_size_x = max(vid_conwidth, vid_conheight);
 765                         reticle_size_y = max(vid_conwidth, vid_conheight);
 766                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 767                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 768                 }
 769
 770                 f = current_zoomfraction;
 771                 if(zoomscript_caught)
 772                         f = 1;
 773                 if(autocvar_cl_reticle_item_normal)
 774                 {
 775                         if(reticle_type == 1 && f)
 776                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 777                 }
 778                 if(autocvar_cl_reticle_item_nex)
 779                 {
 780                         if(reticle_type == 2 && f)
 781                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 782                 }
 783         }
 784
 785
 786         // improved polyblend
 787         if(autocvar_hud_contents)
 788         {
 789                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 790                 vector liquidcolor;
 791
 792                 switch(pointcontents(view_origin))
 793                 {
 794                         case CONTENT_WATER:
 795                                 liquidalpha = autocvar_hud_contents_water_alpha;
 796                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 797                                 incontent = 1;
 798                                 break;
 799
 800                         case CONTENT_LAVA:
 801                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 802                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 803                                 incontent = 1;
 804                                 break;
 805
 806                         case CONTENT_SLIME:
 807                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 808                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 809                                 incontent = 1;
 810                                 break;
 811
 812                         default:
 813                                 liquidalpha = 0;
 814                                 liquidcolor = '0 0 0';
 815                                 incontent = 0;
 816                                 break;
 817                 }
 818
 819                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 820                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 821                         contentfadetime = autocvar_hud_contents_fadeintime;
 822                         liquidalpha_prev = liquidalpha;
 823                         liquidcolor_prev = liquidcolor;
 824                 }
 825                 else
 826                         contentfadetime = autocvar_hud_contents_fadeouttime;
 827
 828                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 829                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 830
 831                 if(contentavgalpha)
 832                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 833
 834                 if(autocvar_hud_postprocessing)
 835                 {
 836                         if(autocvar_hud_contents_blur && contentavgalpha)
 837                         {
 838                                 content_blurpostprocess_x = 1;
 839                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 840                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 841                         }
 842                         else
 843                         {
 844                                 content_blurpostprocess_x = 0;
 845                                 content_blurpostprocess_y = 0;
 846                                 content_blurpostprocess_z = 0;
 847                         }
 848                 }
 849         }
 850
 851         if(autocvar_hud_damage)
 852         {
 853                 splash_size_x = max(vid_conwidth, vid_conheight);
 854                 splash_size_y = max(vid_conwidth, vid_conheight);
 855                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 856                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 857
 858                 float myhealth_flash_temp;
 859                 myhealth = getstati(STAT_HEALTH);
 860
 861                 // fade out
 862                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 863                 // add new damage
 864                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 865
 866                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 867                 pain_threshold = autocvar_hud_damage_pain_threshold;
 868                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 869                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 870
 871                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 872                 {
 873                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 874                 }
 875
 876                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 877
 878                 if(myhealth_prev < 1)
 879                 {
 880                         if(myhealth >= 1)
 881                         {
 882                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 883                                 myhealth_flash_temp = 0;
 884                         }
 885                         else
 886                         {
 887                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 888                         }
 889                 }
 890
 891                 if(spectatee_status == -1 || intermission)
 892                 {
 893                         myhealth_flash = 0; // observing, or match ended
 894                         myhealth_flash_temp = 0;
 895                 }
 896
 897                 myhealth_prev = myhealth;
 898
 899                 // IDEA: change damage color/picture based on player model for robot/alien species?
 900                 // pro: matches model better
 901                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 902                 // maybe different reddish pics?
 903                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 904                 {
 905                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 906                         {
 907                                 if(autocvar_cl_gentle_damage == 2)
 908                                 {
 909                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 910                                         {
 911                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 912                                         }
 913                                 }
 914                                 else
 915                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 916
 917                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 918                         }
 919                         else
 920                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 921                 }
 922
 923                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 924                 {
 925                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 926                         {
 927                                 damage_blurpostprocess_x = 1;
 928                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 929                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 930                         }
 931                         else
 932                         {
 933                                 damage_blurpostprocess_x = 0;
 934                                 damage_blurpostprocess_y = 0;
 935                                 damage_blurpostprocess_z = 0;
 936                         }
 937                 }
 938         }
 939
 940         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
 941         float e2 = (autocvar_hud_powerup != 0);
 942         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 943         {
 944                 // enable or disable rendering types if they are used or not
 945                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
 946                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
 947
 948                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 949                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 950                 {
 951                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 952                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 953                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 954                         {
 955                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 956                                 old_blurradius = blurradius;
 957                                 old_bluralpha = bluralpha;
 958                         }
 959                 }
 960                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 961                 {
 962                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 963                         old_blurradius = 0;
 964                         old_bluralpha = 0;
 965                 }
 966
 967                 // edge detection postprocess handling done second (used by hud_powerup)
 968                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 969                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 970                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 971
 972                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 973
 974                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 975                 {
 976                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 977                         {
 978                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 979                                 old_sharpen_intensity = sharpen_intensity;
 980                         }
 981                 }
 982                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 983                 {
 984                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 985                         old_sharpen_intensity = 0;
 986                 }
 987
 988                 if(cvar("r_glsl_postprocess") == 0)
 989                         cvar_set("r_glsl_postprocess", "2");
 990         }
 991         else if(cvar("r_glsl_postprocess") == 2)
 992                 cvar_set("r_glsl_postprocess", "0");
 993
 994         if(menu_visible)
 995                 menu_show();
 996
 997         /*if(gametype == MAPINFO_TYPE_CTF)
 998           {
 999           ctf_view();
1000           } else */
1001
1002         // draw 2D entities
1003         e = self;
1004         for(self = world; (self = nextent(self)); )
1005                 if(self.draw2d)
1006                         self.draw2d();
1007         self = e;
1008         Draw_ShowNames_All();
1009
1010         scoreboard_active = HUD_WouldDrawScoreboard();
1011
1012         hit_time = getstatf(STAT_HIT_TIME);
1013         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1014         {
1015                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1016                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
1017
1018                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1019         }
1020         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1021         if(typehit_time > nextsound_typehit_time)
1022         {
1023                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1024                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
1025
1026                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1027         }
1028
1029         //else
1030         {
1031                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1032                 {
1033                         if(getstati(STAT_FROZEN))
1034                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1035                         if(getstatf(STAT_REVIVE_PROGRESS))
1036                         {
1037                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1038                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1039                         }
1040                 }
1041
1042                 if(autocvar_r_letterbox == 0)
1043                         if(autocvar_viewsize < 120)
1044                                 CSQC_common_hud();
1045
1046                 // crosshair goes VERY LAST
1047                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1048                 {
1049                         if not(autocvar_crosshair_enabled) // main toggle for crosshair rendering
1050                                 return;
1051
1052                         string wcross_style;
1053                         float wcross_alpha, wcross_resolution;
1054                         wcross_style = autocvar_crosshair;
1055                         if (wcross_style == "0")
1056                                 return;
1057                         wcross_resolution = autocvar_crosshair_size;
1058                         if (wcross_resolution == 0)
1059                                 return;
1060                         wcross_alpha = autocvar_crosshair_alpha;
1061                         if (wcross_alpha == 0)
1062                                 return;
1063
1064                         // TrueAim check
1065                         float shottype;
1066
1067                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1068                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1069                         wcross_origin_z = 0;
1070                         if(autocvar_crosshair_hittest)
1071                         {
1072                                 vector wcross_oldorigin;
1073                                 wcross_oldorigin = wcross_origin;
1074                                 shottype = TrueAimCheck();
1075                                 if(shottype == SHOTTYPE_HITWORLD)
1076                                 {
1077                                         v = wcross_origin - wcross_oldorigin;
1078                                         v_x /= vid_conwidth;
1079                                         v_y /= vid_conheight;
1080                                         if(vlen(v) > 0.01)
1081                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1082                                 }
1083                                 if(!autocvar_crosshair_hittest_showimpact)
1084                                         wcross_origin = wcross_oldorigin;
1085                         }
1086                         else
1087                                 shottype = SHOTTYPE_HITWORLD;
1088
1089                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1090                         string wcross_wep = "", wcross_name;
1091                         float wcross_scale, wcross_blur;
1092
1093                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1094                                 e = get_weaponinfo(switchingweapon);
1095                                 if (e && e.netname != "")
1096                                 {
1097                                         wcross_wep = e.netname;
1098                                         if(autocvar_crosshair_per_weapon)
1099                                         {
1100                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1101                                                 if (wcross_resolution == 0)
1102                                                         return;
1103                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1104                                                 if (wcross_alpha == 0)
1105                                                         return;
1106
1107                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1108                                                 if(wcross_style == "" || wcross_style == "0")
1109                                                         wcross_style = wcross_wep;
1110                                         }
1111                                 }
1112                         }
1113                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1114                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1115                         else if(autocvar_crosshair_color_by_health)
1116                         {
1117                                 float x = getstati(STAT_HEALTH);
1118
1119                                 //x = red
1120                                 //y = green
1121                                 //z = blue
1122
1123                                 wcross_color_z = 0;
1124
1125                                 if(x > 200)
1126                                 {
1127                                         wcross_color_x = 0;
1128                                         wcross_color_y = 1;
1129                                 }
1130                                 else if(x > 150)
1131                                 {
1132                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1133                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1134                                 }
1135                                 else if(x > 100)
1136                                 {
1137                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1138                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1139                                         wcross_color_z = 1 - (x-100)*0.02;
1140                                 }
1141                                 else if(x > 50)
1142                                 {
1143                                         wcross_color_x = 1;
1144                                         wcross_color_y = 1;
1145                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1146                                 }
1147                                 else if(x > 20)
1148                                 {
1149                                         wcross_color_x = 1;
1150                                         wcross_color_y = (x-20)*90/27/100;
1151                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1152                                 }
1153                                 else
1154                                 {
1155                                         wcross_color_x = 1;
1156                                         wcross_color_y = 0;
1157                                 }
1158                         }
1159                         else
1160                                 wcross_color = stov(autocvar_crosshair_color);
1161
1162                         wcross_name = strcat("gfx/crosshair", wcross_style);
1163
1164                         if(autocvar_crosshair_effect_scalefade)
1165                         {
1166                                 wcross_scale = wcross_resolution;
1167                                 wcross_resolution = 1;
1168                         }
1169                         else
1170                         {
1171                                 wcross_scale = 1;
1172                         }
1173
1174                         if(autocvar_crosshair_pickup)
1175                         {
1176                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1177
1178                                 if(pickup_crosshair_time < stat_pickup_time)
1179                                 {
1180                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1181                                                 pickup_crosshair_size = 1;
1182
1183                                         pickup_crosshair_time = stat_pickup_time;
1184                                 }
1185
1186                                 if(pickup_crosshair_size > 0)
1187                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1188                                 else
1189                                         pickup_crosshair_size = 0;
1190
1191                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1192                         }
1193
1194                         if(autocvar_crosshair_hitindication)
1195                         {
1196                                 vector hitindication_color = ((autocvar_crosshair_color_per_weapon) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1197
1198                                 if(hitindication_crosshair_time < hit_time)
1199                                 {
1200                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1201                                                 hitindication_crosshair_size = 1;
1202
1203                                         hitindication_crosshair_time = hit_time;
1204                                 }
1205
1206                                 if(hitindication_crosshair_size > 0)
1207                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1208                                 else
1209                                         hitindication_crosshair_size = 0;
1210
1211                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1212                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1213                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1214                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1215                         }
1216
1217                         if(shottype == SHOTTYPE_HITENEMY)
1218                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1219                         if(shottype == SHOTTYPE_HITTEAM)
1220                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1221
1222                         f = autocvar_crosshair_effect_speed;
1223                         if(f < 0)
1224                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1225                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1226                         {
1227                                 wcross_changedonetime = time + f;
1228                         }
1229                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1230                         {
1231                                 wcross_name_changestarttime = time;
1232                                 wcross_name_changedonetime = time + f;
1233                                 if(wcross_name_goal_prev_prev)
1234                                         strunzone(wcross_name_goal_prev_prev);
1235                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1236                                 wcross_name_goal_prev = strzone(wcross_name);
1237                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1238                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1239                                 wcross_resolution_goal_prev = wcross_resolution;
1240                         }
1241
1242                         wcross_scale_goal_prev = wcross_scale;
1243                         wcross_alpha_goal_prev = wcross_alpha;
1244                         wcross_color_goal_prev = wcross_color;
1245
1246                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1247                         {
1248                                 wcross_blur = 1;
1249                                 wcross_alpha *= 0.75;
1250                         }
1251                         else
1252                                 wcross_blur = 0;
1253                         // *_prev is at time-frametime
1254                         // * is at wcross_changedonetime+f
1255                         // what do we have at time?
1256                         if(time < wcross_changedonetime)
1257                         {
1258                                 f = frametime / (wcross_changedonetime - time + frametime);
1259                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1260                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1261                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1262                         }
1263
1264                         wcross_scale_prev = wcross_scale;
1265                         wcross_alpha_prev = wcross_alpha;
1266                         wcross_color_prev = wcross_color;
1267
1268                         wcross_scale *= 1 - autocvar__menu_alpha;
1269                         wcross_alpha *= 1 - autocvar__menu_alpha;
1270                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1271
1272                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1273                         {
1274                                 // crosshair rings for weapon stats
1275                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1276                                 {
1277                                         // declarations and stats
1278                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1279                                         string ring_image = string_null, ring_inner_image = string_null;
1280                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1281
1282                                         ring_scale = autocvar_crosshair_ring_size;
1283
1284                                         float weapon_clipload, weapon_clipsize;
1285                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1286                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1287
1288                                         float nex_charge, nex_chargepool;
1289                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1290                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1291
1292                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1293                                                 nex_charge_movingavg = nex_charge;
1294
1295
1296                                         // handle the values
1297                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1298                                         {
1299                                                 if (nex_chargepool || use_nex_chargepool) {
1300                                                         use_nex_chargepool = 1;
1301                                                         ring_inner_value = nex_chargepool;
1302                                                 } else {
1303                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1304                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1305                                                 }
1306
1307                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1308                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1309                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1310
1311                                                 // draw the outer ring to show the current charge of the weapon
1312                                                 ring_value = nex_charge;
1313                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1314                                                 ring_rgb = wcross_color;
1315                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1316                                         }
1317                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1318                                         {
1319                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1320                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1321                                                 ring_rgb = wcross_color;
1322                                                 ring_image = "gfx/crosshair_ring.tga";
1323                                         }
1324                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1325                                         {
1326                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1327                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1328                                                 ring_rgb = wcross_color;
1329                                                 ring_image = "gfx/crosshair_ring.tga";
1330                                         }
1331
1332                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1333                                         {
1334                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1335                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1336                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1337                                                 ring_rgb = wcross_color;
1338
1339                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1340                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1341                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1342                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1343                                                 else
1344                                                         ring_image = "gfx/crosshair_ring.tga";
1345                                         }
1346
1347                                         // if in weapon switch animation, fade ring out/in
1348                                         if(g_weaponswitchdelay > 0)
1349                                         {
1350                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1351                                                 if(f > 0 && f < 2)
1352                                                         ring_alpha *= fabs(1 - f);
1353                                         }
1354
1355                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1356                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1357
1358                                         if (ring_value)
1359                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1360                                 }
1361
1362 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1363                                 do \
1364                                 { \
1365                                         if(wcross_blur > 0) \
1366                                         { \
1367                                                 for(i = -2; i <= 2; ++i) \
1368                                                 for(j = -2; j <= 2; ++j) \
1369                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1370                                         } \
1371                                         else \
1372                                         { \
1373                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1374                                         } \
1375                                 } \
1376                                 while(0)
1377
1378 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1379                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1380
1381 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1382                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1383
1384                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1385                                 {
1386                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1387                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1388                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1389                                         f = 1 - f;
1390                                 }
1391                                 else
1392                                 {
1393                                         f = 1;
1394                                 }
1395                                 wcross_name_alpha_goal_prev = f;
1396
1397                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1398                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1399
1400                                 if(autocvar_crosshair_dot)
1401                                 {
1402                                         vector wcross_color_old;
1403                                         wcross_color_old = wcross_color;
1404
1405                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1406                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1407
1408                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1409                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1410                                         wcross_color = wcross_color_old;
1411                                 }
1412                         }
1413                 }
1414                 else
1415                 {
1416                         wcross_scale_prev = 0;
1417                         wcross_alpha_prev = 0;
1418                         wcross_scale_goal_prev = 0;
1419                         wcross_alpha_goal_prev = 0;
1420                         wcross_changedonetime = 0;
1421                         if(wcross_name_goal_prev)
1422                                 strunzone(wcross_name_goal_prev);
1423                         wcross_name_goal_prev = string_null;
1424                         if(wcross_name_goal_prev_prev)
1425                                 strunzone(wcross_name_goal_prev_prev);
1426                         wcross_name_goal_prev_prev = string_null;
1427                         wcross_name_changestarttime = 0;
1428                         wcross_name_changedonetime = 0;
1429                         wcross_name_alpha_goal_prev = 0;
1430                         wcross_name_alpha_goal_prev_prev = 0;
1431                         wcross_resolution_goal_prev = 0;
1432                         wcross_resolution_goal_prev_prev = 0;
1433                 }
1434         }
1435
1436         if(NextFrameCommand)
1437         {
1438                 localcmd("\n", NextFrameCommand, "\n");
1439                 NextFrameCommand = string_null;
1440         }
1441
1442         // we must do this check AFTER a frame was rendered, or it won't work
1443         if(cs_project_is_b0rked == 0)
1444         {
1445                 string w0, h0;
1446                 w0 = ftos(autocvar_vid_conwidth);
1447                 h0 = ftos(autocvar_vid_conheight);
1448                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1449                 //setproperty(VF_FOV, '90 90 0');
1450                 setproperty(VF_ORIGIN, '0 0 0');
1451                 setproperty(VF_ANGLES, '0 0 0');
1452                 setproperty(VF_PERSPECTIVE, 1);
1453                 makevectors('0 0 0');
1454                 vector v1, v2;
1455                 cvar_set("vid_conwidth", "800");
1456                 cvar_set("vid_conheight", "600");
1457                 v1 = cs_project(v_forward);
1458                 cvar_set("vid_conwidth", "640");
1459                 cvar_set("vid_conheight", "480");
1460                 v2 = cs_project(v_forward);
1461                 if(v1 == v2)
1462                         cs_project_is_b0rked = 1;
1463                 else
1464                         cs_project_is_b0rked = -1;
1465                 cvar_set("vid_conwidth", w0);
1466                 cvar_set("vid_conheight", h0);
1467         }
1468
1469         if(autocvar__hud_configure)
1470                 HUD_Panel_Mouse();
1471
1472     if(hud && !intermission)
1473     {
1474         if(hud == HUD_SPIDERBOT)
1475             CSQC_SPIDER_HUD();
1476         else if(hud == HUD_WAKIZASHI)
1477             CSQC_WAKIZASHI_HUD();
1478         else if(hud == HUD_RAPTOR)
1479             CSQC_RAPTOR_HUD();
1480         else if(hud == HUD_BUMBLEBEE)
1481             CSQC_BUMBLE_HUD();
1482         else if(hud == HUD_BUMBLEBEE_GUN)
1483             CSQC_BUMBLE_GUN_HUD();
1484     }
1485
1486         cl_notice_run();
1487
1488         // let's reset the view back to normal for the end
1489         setproperty(VF_MIN, '0 0 0');
1490         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1491 }
1492
1493
1494 void CSQC_common_hud(void)
1495 {
1496     // do some accuracy var caching
1497     float i;
1498     if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1499     {
1500         if(autocvar_accuracy_color_levels != acc_color_levels)
1501         {
1502             if(acc_color_levels)
1503                 strunzone(acc_color_levels);
1504             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1505             acc_levels = tokenize_console(acc_color_levels);
1506             if (acc_levels > MAX_ACCURACY_LEVELS)
1507                 acc_levels = MAX_ACCURACY_LEVELS;
1508
1509             for (i = 0; i < acc_levels; ++i)
1510                 acc_lev[i] = stof(argv(i)) / 100.0;
1511         }
1512         // let know that acc_col[] needs to be loaded
1513         acc_col[0] = '-1 0 0';
1514     }
1515
1516     HUD_Main(); // always run these functions for alpha checks
1517     HUD_DrawScoreboard();
1518
1519     if (scoreboard_active) // scoreboard/accuracy
1520         HUD_Reset();
1521     else if (intermission == 2) // map voting screen
1522     {
1523         HUD_FinaleOverlay();
1524         HUD_Reset();
1525     }
1526         /*
1527         switch(hud)
1528         {
1529                 case HUD_SPIDERBOT:
1530                         CSQC_SPIDER_HUD();
1531                         break;
1532
1533                 case HUD_WAKIZASHI:
1534                         CSQC_WAKIZASHI_HUD();
1535                         break;
1536
1537         case HUD_BUMBLEBEE:
1538             CSQC_BUMBLE_HUD();
1539             break;
1540         }
1541         */
1542 }
1543
1544
1545 // following vectors must be global to allow seamless switching between camera modes
1546 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1547 void CSQC_Demo_Camera()
1548 {
1549         float speed, attenuation, dimensions;
1550         vector tmp, delta;
1551
1552         if( autocvar_camera_reset || !camera_mode )
1553         {
1554                 camera_offset = '0 0 0';
1555                 current_angles = '0 0 0';
1556                 camera_direction = '0 0 0';
1557                 camera_offset_z += 30;
1558                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1559                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1560                 current_origin = view_origin;
1561                 current_camera_offset  = camera_offset;
1562                 cvar_set("camera_reset", "0");
1563                 camera_mode = CAMERA_CHASE;
1564         }
1565
1566         // Camera angles
1567         if( camera_roll )
1568                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1569
1570         if(autocvar_camera_look_player)
1571         {
1572                 vector dir;
1573                 float n;
1574
1575                 dir = normalize(view_origin - current_position);
1576                 n = mouse_angles_z;
1577                 mouse_angles = vectoangles(dir);
1578                 mouse_angles_x = mouse_angles_x * -1;
1579                 mouse_angles_z = n;
1580         }
1581         else
1582         {
1583                 tmp = getmousepos() * 0.1;
1584                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1585                 {
1586                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1587                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1588                 }
1589         }
1590
1591         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1592         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1593         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1594         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1595
1596         // Fix difference when angles don't have the same sign
1597         delta = '0 0 0';
1598         if(mouse_angles_y < -60 && current_angles_y > 60)
1599                 delta = '0 360 0';
1600         if(mouse_angles_y > 60 && current_angles_y < -60)
1601                 delta = '0 -360 0';
1602
1603         if(autocvar_camera_look_player)
1604                 attenuation = autocvar_camera_look_attenuation;
1605         else
1606                 attenuation = autocvar_camera_speed_attenuation;
1607
1608         attenuation = 1 / max(1, attenuation);
1609         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1610
1611         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1612         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1613         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1614         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1615
1616         // Camera position
1617         tmp = '0 0 0';
1618         dimensions = 0;
1619
1620         if( camera_direction_x )
1621         {
1622                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1623                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1624                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1625                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1626                 ++dimensions;
1627         }
1628
1629         if( camera_direction_y )
1630         {
1631                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1632                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1633                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1634                 ++dimensions;
1635         }
1636
1637         if( camera_direction_z )
1638         {
1639                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1640                 ++dimensions;
1641         }
1642
1643         if(autocvar_camera_free)
1644                 speed = autocvar_camera_speed_free;
1645         else
1646                 speed = autocvar_camera_speed_chase;
1647
1648         if(dimensions)
1649         {
1650                 speed = speed * sqrt(1 / dimensions);
1651                 camera_offset += tmp * speed;
1652         }
1653
1654         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1655
1656         // Camera modes
1657         if( autocvar_camera_free )
1658         {
1659                 if ( camera_mode == CAMERA_CHASE )
1660                 {
1661                         current_camera_offset = current_origin + current_camera_offset;
1662                         camera_offset = current_origin + camera_offset;
1663                 }
1664
1665                 camera_mode = CAMERA_FREE;
1666                 current_position = current_camera_offset;
1667         }
1668         else
1669         {
1670                 if ( camera_mode == CAMERA_FREE )
1671                 {
1672                         current_origin = view_origin;
1673                         camera_offset = camera_offset - current_origin;
1674                         current_camera_offset = current_camera_offset - current_origin;
1675                 }
1676
1677                 camera_mode = CAMERA_CHASE;
1678
1679                 if(autocvar_camera_chase_smoothly)
1680                         current_origin += (view_origin - current_origin) * attenuation;
1681                 else
1682                         current_origin = view_origin;
1683
1684                 current_position = current_origin + current_camera_offset;
1685         }
1686
1687         setproperty(VF_ANGLES, current_angles);
1688         setproperty(VF_ORIGIN, current_position);
1689 }