qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_SNIPERRIFLE && sniperrifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_SNIPERRIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 float old_blurradius, old_bluralpha;
 365 float old_sharpen_intensity;
 366
 367 vector myhealth_gentlergb;
 368
 369 float contentavgalpha, liquidalpha_prev;
 370 vector liquidcolor_prev;
 371
 372 float eventchase_current_distance;
 373
 374 vector damage_blurpostprocess, content_blurpostprocess;
 375
 376 float checkfail[16];
 377
 378 void CSQC_UpdateView(float w, float h)
 379 {
 380         entity e;
 381         float fov;
 382         float f, i, j;
 383         vector v, vo;
 384         vector vf_size, vf_min;
 385         float a;
 386
 387 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 388         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 389         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 390         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 391         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 392         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 393         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 394
 395         vf_size = R_SetView3fv(VF_SIZE);
 396         vf_min = R_SetView3fv(VF_MIN);
 397         vid_width = vf_size_x;
 398         vid_height = vf_size_y;
 399
 400         vector reticle_pos, reticle_size;
 401         vector splash_pos, splash_size;
 402
 403         WaypointSprite_Load();
 404
 405         if(spectatee_status)
 406                 myteam = GetPlayerColor(spectatee_status - 1);
 407         else
 408                 myteam = GetPlayerColor(player_localentnum - 1);
 409
 410         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 411         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 412
 413         warpzone_fixview_origin = pmove_org + vo;
 414         warpzone_fixview_cl_viewangles = input_angles;
 415         warpzone_fixview_angles = view_angles;
 416         WarpZone_FixView();
 417         pmove_org = warpzone_fixview_origin - vo;
 418         input_angles = warpzone_fixview_cl_viewangles;
 419         view_angles = warpzone_fixview_angles;
 420
 421         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 422         {
 423                 pmove_org = freeze_pmove_org;
 424                 input_angles = view_angles = freeze_input_angles;
 425                 R_SetView(VF_ORIGIN, pmove_org + vo);
 426                 R_SetView(VF_ANGLES, view_angles);
 427                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 428         }
 429         freeze_pmove_org = pmove_org;
 430         freeze_input_angles = input_angles;
 431
 432         // event chase camera
 433         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 434         {
 435                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || (autocvar_cl_eventchase_intermission && intermission))
 436                 {
 437                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 438                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 439                         if(!autocvar_chase_active)
 440                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 441
 442                         // make the camera smooth back
 443                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 444                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 445                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 446                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 447
 448                         vector eventchase_target_origin;
 449                         makevectors(view_angles);
 450                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 451                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance;
 452
 453                         traceline(pmove_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 454                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 455                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 456                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 457
 458                         R_SetView(VF_ORIGIN, eventchase_target_origin);
 459                 }
 460                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 461                 {
 462                         cvar_set("chase_active", "0");
 463                         eventchase_current_distance = 0; // start from 0 next time
 464                 }
 465         }
 466
 467         // Render the Scene
 468         if(!intermission || !view_set || (intermission && autocvar_cl_eventchase_intermission))
 469         {
 470                 view_origin = pmove_org + vo;
 471                 view_angles = input_angles;
 472                 makevectors(view_angles);
 473                 view_forward = v_forward;
 474                 view_right = v_right;
 475                 view_up = v_up;
 476                 view_set = 1;
 477         }
 478
 479 #ifdef BLURTEST
 480         if(time > blurtest_time0 && time < blurtest_time1)
 481         {
 482                 float r, t;
 483
 484                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 485                 r = t * blurtest_radius;
 486                 f = 1 / pow(t, blurtest_power) - 1;
 487
 488                 cvar_set("r_glsl_postprocess", "1");
 489                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 490         }
 491         else
 492         {
 493                 cvar_set("r_glsl_postprocess", "0");
 494                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 495         }
 496 #endif
 497
 498         TargetMusic_Advance();
 499         Fog_Force();
 500
 501         drawframetime = max(0.000001, time - drawtime);
 502         drawtime = time;
 503
 504         // watch for gametype changes here...
 505         // in ParseStuffCMD the cmd isn't executed yet :/
 506         // might even be better to add the gametype to TE_CSQC_INIT...?
 507         if(!postinit)
 508                 PostInit();
 509
 510         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 511                 if(calledhooks & HOOK_START)
 512                 {
 513                         localcmd("\ncl_hook_gameend\n");
 514                         calledhooks |= HOOK_END;
 515                 }
 516
 517         CheckForGamestartChange();
 518         serverAnnouncer();
 519         maptimeAnnouncer();
 520         carrierAnnouncer();
 521
 522         fov = autocvar_fov;
 523         if(button_zoom || fov <= 59.5)
 524         {
 525                 if(!zoomscript_caught)
 526                 {
 527                         localcmd("+button4\n");
 528                         zoomscript_caught = 1;
 529                         ignore_plus_zoom += 1;
 530                 }
 531         }
 532         else
 533         {
 534                 if(zoomscript_caught)
 535                 {
 536                         localcmd("-button4\n");
 537                         zoomscript_caught = 0;
 538                         ignore_minus_zoom += 1;
 539                 }
 540         }
 541
 542         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 543         activeweapon = getstati(STAT_SWITCHWEAPON);
 544         f = (serverflags & SERVERFLAG_TEAMPLAY);
 545         if(f != teamplay)
 546         {
 547                 teamplay = f;
 548                 HUD_InitScores();
 549         }
 550
 551         if(last_weapon != activeweapon) {
 552                 weapontime = time;
 553                 last_weapon = activeweapon;
 554
 555                 e = get_weaponinfo(activeweapon);
 556                 if(e.netname != "")
 557                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 558                 else
 559                         localcmd("\ncl_hook_activeweapon none\n");
 560         }
 561
 562         // ALWAYS Clear Current Scene First
 563         R_ClearScene();
 564
 565         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 566         R_SetView(VF_SIZE, vf_size);
 567         R_SetView(VF_MIN, vf_min);
 568
 569         // Assign Standard Viewflags
 570         // Draw the World (and sky)
 571         R_SetView(VF_DRAWWORLD, 1);
 572
 573         // Set the console size vars
 574         vid_conwidth = autocvar_vid_conwidth;
 575         vid_conheight = autocvar_vid_conheight;
 576         vid_pixelheight = autocvar_vid_pixelheight;
 577
 578         R_SetView(VF_FOV, GetCurrentFov(fov));
 579
 580         // Camera for demo playback
 581         if(camera_active)
 582         {
 583                 if(autocvar_camera_enable)
 584                         CSQC_Demo_Camera();
 585                 else
 586                 {
 587                         cvar_set("chase_active", ftos(chase_active_backup));
 588                         cvar_set("cl_demo_mousegrab", "0");
 589                         camera_active = FALSE;
 590                 }
 591         }
 592 #ifdef CAMERATEST
 593         else if(autocvar_camera_enable)
 594 #else
 595         else if(autocvar_camera_enable && isdemo())
 596 #endif
 597         {
 598                 // Enable required Darkplaces cvars
 599                 chase_active_backup = autocvar_chase_active;
 600                 cvar_set("chase_active", "2");
 601                 cvar_set("cl_demo_mousegrab", "1");
 602                 camera_active = TRUE;
 603                 camera_mode = FALSE;
 604         }
 605
 606         // Draw the Crosshair
 607         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 608
 609         // Draw the Engine Status Bar (the default Quake HUD)
 610         R_SetView(VF_DRAWENGINEHUD, 0);
 611
 612         // fetch this one only once per frame
 613         hud_showbinds = autocvar_hud_showbinds;
 614         hud_showbinds_limit = autocvar_hud_showbinds_limit;
 615
 616         // Update the mouse position
 617         /*
 618            mousepos_x = vid_conwidth;
 619            mousepos_y = vid_conheight;
 620            mousepos = mousepos*0.5 + getmousepos();
 621          */
 622
 623         e = self;
 624         for(self = world; (self = nextent(self)); )
 625                 if(self.draw)
 626                         self.draw();
 627         self = e;
 628
 629         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 630         R_RenderScene();
 631
 632         // now switch to 2D drawing mode by calling a 2D drawing function
 633         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 634         // next R_RenderScene call
 635         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 636
 637         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 638         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 639         {
 640                 // apply night vision effect
 641                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 642
 643                 if(!nightvision_noise)
 644                 {
 645                         nightvision_noise = spawn();
 646                         nightvision_noise.classname = "nightvision_noise";
 647                 }
 648                 if(!nightvision_noise2)
 649                 {
 650                         nightvision_noise2 = spawn();
 651                         nightvision_noise2.classname = "nightvision_noise2";
 652                 }
 653
 654                 // color tint in yellow
 655                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 656
 657                 // draw BG
 658                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 659                 rgb = '1 1 1';
 660                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 661                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 662                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 663                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 664                 tc_11 = tc_01 + tc_10 - tc_00;
 665                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 666                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 667                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 668                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 669                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 670                 R_EndPolygon();
 671
 672                 // draw FG
 673                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 674                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 675                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 676                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 677                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 678                 tc_11 = tc_01 + tc_10 - tc_00;
 679                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 680                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 681                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 682                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 683                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 684                 R_EndPolygon();
 685         }
 686
 687         // Draw the aiming reticle for weapons that use it
 688         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 689         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 690         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 691         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 692                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 693         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_SNIPERRIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 694                 reticle_type = 2; // nex zoom
 695         else if(button_zoom || zoomscript_caught)
 696                 reticle_type = 1; // normal zoom
 697         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_SNIPERRIFLE && button_attack2)
 698                 reticle_type = 2; // nex zoom
 699
 700         if (reticle_type)
 701         {
 702                 if(autocvar_cl_reticle_stretch)
 703                 {
 704                         reticle_size_x = vid_conwidth;
 705                         reticle_size_y = vid_conheight;
 706                         reticle_pos_x = 0;
 707                         reticle_pos_y = 0;
 708                 }
 709                 else
 710                 {
 711                         reticle_size_x = max(vid_conwidth, vid_conheight);
 712                         reticle_size_y = max(vid_conwidth, vid_conheight);
 713                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 714                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 715                 }
 716
 717                 f = current_zoomfraction;
 718                 if(zoomscript_caught)
 719                         f = 1;
 720                 if(autocvar_cl_reticle_item_normal)
 721                 {
 722                         if(reticle_type == 1 && f)
 723                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 724                 }
 725                 if(autocvar_cl_reticle_item_nex)
 726                 {
 727                         if(reticle_type == 2 && f)
 728                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 729                 }
 730         }
 731
 732
 733         // improved polyblend
 734         vector rgb;
 735         if(autocvar_hud_contents)
 736         {
 737                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 738                 vector liquidcolor;
 739
 740                 switch(pointcontents(view_origin))
 741                 {
 742                         case CONTENT_WATER:
 743                                 liquidalpha = autocvar_hud_contents_water_alpha;
 744                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 745                                 incontent = 1;
 746                                 break;
 747
 748                         case CONTENT_LAVA:
 749                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 750                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 751                                 incontent = 1;
 752                                 break;
 753
 754                         case CONTENT_SLIME:
 755                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 756                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 757                                 incontent = 1;
 758                                 break;
 759
 760                         default:
 761                                 liquidalpha = 0;
 762                                 liquidcolor = '0 0 0';
 763                                 incontent = 0;
 764                                 break;
 765                 }
 766
 767                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 768                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 769                         contentfadetime = autocvar_hud_contents_fadeintime;
 770                         liquidalpha_prev = liquidalpha;
 771                         liquidcolor_prev = liquidcolor;
 772                 }
 773                 else
 774                         contentfadetime = autocvar_hud_contents_fadeouttime;
 775
 776                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 777                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 778
 779                 if(contentavgalpha)
 780                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 781
 782                 if(autocvar_hud_postprocessing)
 783                 {
 784                         if(autocvar_hud_contents_blur && contentavgalpha)
 785                         {
 786                                 content_blurpostprocess_x = 1;
 787                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 788                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 789                         }
 790                         else
 791                         {
 792                                 content_blurpostprocess_x = 0;
 793                                 content_blurpostprocess_y = 0;
 794                                 content_blurpostprocess_z = 0;
 795                         }
 796                 }
 797         }
 798
 799         if(autocvar_hud_damage)
 800         {
 801                 splash_size_x = max(vid_conwidth, vid_conheight);
 802                 splash_size_y = max(vid_conwidth, vid_conheight);
 803                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 804                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 805
 806                 float myhealth_flash_temp;
 807                 myhealth = getstati(STAT_HEALTH);
 808
 809                 // fade out
 810                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 811                 // add new damage
 812                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 813
 814                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 815                 pain_threshold = autocvar_hud_damage_pain_threshold;
 816                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 817                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 818
 819                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 820                 {
 821                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 822                 }
 823
 824                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 825
 826                 if(myhealth_prev < 1)
 827                 {
 828                         if(myhealth >= 1)
 829                         {
 830                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 831                                 myhealth_flash_temp = 0;
 832                         }
 833                         else
 834                         {
 835                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 836                         }
 837                 }
 838
 839                 if(spectatee_status == -1 || intermission)
 840                 {
 841                         myhealth_flash = 0; // observing, or match ended
 842                         myhealth_flash_temp = 0;
 843                 }
 844
 845                 myhealth_prev = myhealth;
 846
 847                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 848                 {
 849                         if(autocvar_cl_gentle_damage == 2)
 850                         {
 851                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 852                                 {
 853                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 854                                 }
 855                         }
 856                         else
 857                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 858
 859                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 860                 }
 861                 else
 862                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 863
 864                 if(autocvar_hud_postprocessing)
 865                 {
 866                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 867                         {
 868                                 damage_blurpostprocess_x = 1;
 869                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 870                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 871                         }
 872                         else
 873                         {
 874                                 damage_blurpostprocess_x = 0;
 875                                 damage_blurpostprocess_y = 0;
 876                                 damage_blurpostprocess_z = 0;
 877                         }
 878                 }
 879         }
 880
 881         if(autocvar_hud_postprocessing)
 882         {
 883                 // all of this should be done in the engine eventually
 884
 885                 // enable or disable rendering types if they are used or not
 886                 if(cvar("r_glsl_postprocess_uservec1_enable") != (cvar("hud_postprocessing_maxbluralpha") != 0))
 887                         cvar_set("r_glsl_postprocess_uservec1_enable", ftos(cvar("hud_postprocessing_maxbluralpha") != 0));
 888                 if(cvar("r_glsl_postprocess_uservec2_enable") != (cvar("hud_powerup") != 0))
 889                         cvar_set("r_glsl_postprocess_uservec2_enable", ftos(cvar("hud_powerup") != 0));
 890
 891                 // lets apply the postprocess effects from the previous two functions if needed
 892                 if(damage_blurpostprocess_x || content_blurpostprocess_x)
 893                 {
 894                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 895                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 896                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 897                         {
 898                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 899                                 old_blurradius = blurradius;
 900                                 old_bluralpha = bluralpha;
 901                         }
 902                 }
 903                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 904                 {
 905                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 906                         old_blurradius = 0;
 907                         old_bluralpha = 0;
 908                 }
 909
 910                 float sharpen_intensity;
 911                 if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
 912                         sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
 913                 if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
 914                         sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
 915
 916                 if(autocvar_hud_powerup && sharpen_intensity > 0)
 917                 {
 918                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
 919
 920                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 921                         {
 922                                 cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
 923                                 old_sharpen_intensity = sharpen_intensity;
 924                         }
 925                 }
 926                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 927                 {
 928                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 929                         old_sharpen_intensity = 0;
 930                 }
 931         }
 932
 933         // Draw the mouse cursor
 934         // NOTE: drawpic must happen after R_RenderScene for some reason
 935         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 936         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 937         //self = edict_num(player_localnum);
 938         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 939         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 940         // as long as the ctf part isn't in, this is useless
 941         if(menu_visible)
 942                 menu_show();
 943
 944         /*if(gametype == GAME_CTF)
 945           {
 946           ctf_view();
 947           } else */
 948
 949         // draw 2D entities
 950         e = self;
 951         for(self = world; (self = nextent(self)); )
 952                 if(self.draw2d)
 953                         self.draw2d();
 954         self = e;
 955
 956         scoreboard_active = HUD_WouldDrawScoreboard();
 957
 958         hit_time = getstatf(STAT_HIT_TIME);
 959         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 960         {
 961                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 962                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 963         }
 964         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 965         if(typehit_time > nextsound_typehit_time)
 966         {
 967                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 968                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 969         }
 970
 971         float hud;
 972         hud = getstati(STAT_HUD);
 973         if(hud == HUD_SPIDERBOT)
 974                 CSQC_SPIDER_HUD();
 975         else if(hud == HUD_WAKIZASHI)
 976         CSQC_WAKIZASHI_HUD();
 977     else if(hud == HUD_RAPTOR)
 978         CSQC_RAPTOR_HUD();
 979         else
 980         {
 981                 if(gametype == GAME_FREEZETAG)
 982                 {
 983                         if(getstati(STAT_FROZEN))
 984                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 985                         if(getstatf(STAT_REVIVE_PROGRESS))
 986                         {
 987                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 988                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 989                         }
 990                 }
 991
 992                 if(autocvar_r_letterbox == 0)
 993                         if(autocvar_viewsize < 120)
 994                                 CSQC_common_hud();
 995
 996                 // crosshair goes VERY LAST
 997                 if(!scoreboard_active && !camera_active && intermission != 2) {
 998                         string wcross_style;
 999                         float wcross_alpha, wcross_resolution;
1000                         wcross_style = autocvar_crosshair;
1001                         if (wcross_style == "0")
1002                                 return;
1003                         wcross_resolution = autocvar_crosshair_size;
1004                         if (wcross_resolution == 0)
1005                                 return;
1006                         wcross_alpha = autocvar_crosshair_alpha;
1007                         if (wcross_alpha == 0)
1008                                 return;
1009
1010                         // TrueAim check
1011                         float shottype;
1012
1013                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1014                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1015                         wcross_origin_z = 0;
1016                         if(autocvar_crosshair_hittest)
1017                         {
1018                                 vector wcross_oldorigin;
1019                                 wcross_oldorigin = wcross_origin;
1020                                 shottype = TrueAimCheck();
1021                                 if(shottype == SHOTTYPE_HITWORLD)
1022                                 {
1023                                         v = wcross_origin - wcross_oldorigin;
1024                                         v_x /= vid_conwidth;
1025                                         v_y /= vid_conheight;
1026                                         if(vlen(v) > 0.01)
1027                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1028                                 }
1029                                 if(!autocvar_crosshair_hittest_showimpact)
1030                                         wcross_origin = wcross_oldorigin;
1031                         }
1032                         else
1033                                 shottype = SHOTTYPE_HITWORLD;
1034
1035                         vector wcross_color, wcross_size;
1036                         string wcross_wep, wcross_name;
1037                         float wcross_scale, wcross_blur;
1038
1039                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1040                                 e = get_weaponinfo(activeweapon);
1041                                 if (e && e.netname != "")
1042                                 {
1043                                         wcross_wep = e.netname;
1044                                         if(autocvar_crosshair_per_weapon)
1045                                         {
1046                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1047                                                 if (wcross_resolution == 0)
1048                                                         return;
1049                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1050                                                 if (wcross_alpha == 0)
1051                                                         return;
1052
1053                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1054                                                 if(wcross_style == "" || wcross_style == "0")
1055                                                         wcross_style = wcross_wep;
1056                                         }
1057                                 }
1058                         }
1059                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1060                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1061                         else if(autocvar_crosshair_color_by_health)
1062                         {
1063                                 local float x = getstati(STAT_HEALTH);
1064
1065                                 //x = red
1066                                 //y = green
1067                                 //z = blue
1068
1069                                 wcross_color_z = 0;
1070
1071                                 if(x > 200)
1072                                 {
1073                                         wcross_color_x = 0;
1074                                         wcross_color_y = 1;
1075                                 }
1076                                 else if(x > 150)
1077                                 {
1078                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1079                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1080                                 }
1081                                 else if(x > 100)
1082                                 {
1083                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1084                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1085                                         wcross_color_z = 1 - (x-100)*0.02;
1086                                 }
1087                                 else if(x > 50)
1088                                 {
1089                                         wcross_color_x = 1;
1090                                         wcross_color_y = 1;
1091                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1092                                 }
1093                                 else if(x > 20)
1094                                 {
1095                                         wcross_color_x = 1;
1096                                         wcross_color_y = (x-20)*90/27/100;
1097                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1098                                 }
1099                                 else
1100                                 {
1101                                         wcross_color_x = 1;
1102                                         wcross_color_y = 0;
1103                                 }
1104                         }
1105                         else
1106                                 wcross_color = stov(autocvar_crosshair_color);
1107
1108                         wcross_name = strcat("gfx/crosshair", wcross_style);
1109
1110                         if(autocvar_crosshair_effect_scalefade)
1111                         {
1112                                 wcross_scale = wcross_resolution;
1113                                 wcross_resolution = 1;
1114                         }
1115                         else
1116                         {
1117                                 wcross_scale = 1;
1118                         }
1119
1120                         if(autocvar_crosshair_pickup)
1121                         {
1122                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1123                                 {
1124                                         pickup_crosshair_size = 1;
1125                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1126                                 }
1127
1128                                 if(pickup_crosshair_size > 0)
1129                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1130                                 else
1131                                         pickup_crosshair_size = 0;
1132
1133                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1134                         }
1135
1136                         vector hitindication_color;
1137                         if(autocvar_crosshair_hitindication)
1138                         {
1139                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1140                                 if(hitindication_crosshair_time < hit_time)
1141                                 {
1142                                         hitindication_crosshair_size = 1;
1143                                         hitindication_crosshair_time = hit_time;
1144                                 }
1145
1146                                 if(hitindication_crosshair_size > 0)
1147                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1148                                 else
1149                                         hitindication_crosshair_size = 0;
1150
1151                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1152                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1153                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1154                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1155                         }
1156
1157                         if(shottype == SHOTTYPE_HITENEMY)
1158                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1159                         if(shottype == SHOTTYPE_HITTEAM)
1160                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1161
1162                         f = autocvar_crosshair_effect_speed;
1163                         if(f < 0)
1164                                 f *= -2 * g_weaponswitchdelay;
1165                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1166                         {
1167                                 wcross_changedonetime = time + f;
1168                         }
1169                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1170                         {
1171                                 wcross_name_changestarttime = time;
1172                                 wcross_name_changedonetime = time + f;
1173                                 if(wcross_name_goal_prev_prev)
1174                                         strunzone(wcross_name_goal_prev_prev);
1175                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1176                                 wcross_name_goal_prev = strzone(wcross_name);
1177                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1178                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1179                                 wcross_resolution_goal_prev = wcross_resolution;
1180                         }
1181
1182                         wcross_scale_goal_prev = wcross_scale;
1183                         wcross_alpha_goal_prev = wcross_alpha;
1184                         wcross_color_goal_prev = wcross_color;
1185
1186                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1187                         {
1188                                 wcross_blur = 1;
1189                                 wcross_alpha *= 0.75;
1190                         }
1191                         else
1192                                 wcross_blur = 0;
1193                         // *_prev is at time-frametime
1194                         // * is at wcross_changedonetime+f
1195                         // what do we have at time?
1196                         if(time < wcross_changedonetime)
1197                         {
1198                                 f = frametime / (wcross_changedonetime - time + frametime);
1199                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1200                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1201                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1202                         }
1203
1204                         wcross_scale_prev = wcross_scale;
1205                         wcross_alpha_prev = wcross_alpha;
1206                         wcross_color_prev = wcross_color;
1207
1208                         wcross_scale *= 1 - autocvar__menu_alpha;
1209                         wcross_alpha *= 1 - autocvar__menu_alpha;
1210                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1211
1212                         // crosshair rings for weapon stats
1213                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1214                         {
1215                                 // declarations and stats
1216                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1217                                 string ring_image, ring_inner_image;
1218                                 vector ring_rgb, ring_inner_rgb;
1219
1220                                 ring_scale = autocvar_crosshair_ring_size;
1221
1222                                 float weapon_clipload, weapon_clipsize;
1223                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1224                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1225
1226                                 float nex_charge, nex_chargepool;
1227                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1228                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1229
1230                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1231                                         nex_charge_movingavg = nex_charge;
1232
1233
1234                                 // handle the values
1235                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1236                                 {
1237                                         if (nex_chargepool || use_nex_chargepool) {
1238                                                 use_nex_chargepool = 1;
1239                                                 ring_inner_value = nex_chargepool;
1240                                         } else {
1241                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1242                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1243                                         }
1244
1245                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1246                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1247                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1248
1249                                         // draw the outer ring to show the current charge of the weapon
1250                                         ring_value = nex_charge;
1251                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1252                                         ring_rgb = wcross_color;
1253                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1254                                 }
1255                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1256                                 {
1257                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1258                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1259                                         ring_rgb = wcross_color;
1260                                         ring_image = "gfx/crosshair_ring.tga";
1261                                 }
1262
1263                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1264                                 {
1265                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1266                                         ring_scale = autocvar_crosshair_ring_reload_size;
1267                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1268                                         ring_rgb = wcross_color;
1269
1270                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1271                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1272                                         if ((activeweapon == WEP_SNIPERRIFLE) && (weapon_clipsize == 80))
1273                                                 ring_image = "gfx/crosshair_ring_sniperrifle.tga";
1274                                         else
1275                                                 ring_image = "gfx/crosshair_ring.tga";
1276                                 }
1277
1278                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1279                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1280
1281                                 if (ring_value)
1282                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1283                         }
1284
1285 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1286                         do \
1287                         { \
1288                                 if(wcross_blur > 0) \
1289                                 { \
1290                                         for(i = -2; i <= 2; ++i) \
1291                                                 for(j = -2; j <= 2; ++j) \
1292                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1293                                 } \
1294                                 else \
1295                                 { \
1296                                         M(0,0,sz,wcross_name,wcross_alpha); \
1297                                 } \
1298                         } \
1299                         while(0)
1300
1301 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1302                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1303
1304 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1305                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1306
1307                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1308                         {
1309                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1310                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1311                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1312                                 f = 1 - f;
1313                         }
1314                         else
1315                         {
1316                                 f = 1;
1317                         }
1318
1319                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1320                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1321
1322                         if(autocvar_crosshair_dot)
1323             {
1324                 vector wcross_color_old;
1325                 wcross_color_old = wcross_color;
1326                 if(autocvar_crosshair_dot_color != "0")
1327                     wcross_color = stov(autocvar_crosshair_dot_color);
1328                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1329                 wcross_color = wcross_color_old;
1330             }
1331
1332                         wcross_name_alpha_goal_prev = f;
1333                 }
1334                 else
1335                 {
1336                         wcross_scale_prev = 0;
1337                         wcross_alpha_prev = 0;
1338                         wcross_scale_goal_prev = 0;
1339                         wcross_alpha_goal_prev = 0;
1340                         wcross_changedonetime = 0;
1341                         if(wcross_name_goal_prev)
1342                                 strunzone(wcross_name_goal_prev);
1343                         wcross_name_goal_prev = string_null;
1344                         if(wcross_name_goal_prev_prev)
1345                                 strunzone(wcross_name_goal_prev_prev);
1346                         wcross_name_goal_prev_prev = string_null;
1347                         wcross_name_changestarttime = 0;
1348                         wcross_name_changedonetime = 0;
1349                         wcross_name_alpha_goal_prev = 0;
1350                         wcross_name_alpha_goal_prev_prev = 0;
1351                         wcross_resolution_goal_prev = 0;
1352                         wcross_resolution_goal_prev_prev = 0;
1353                 }
1354         }
1355
1356         if(NextFrameCommand)
1357         {
1358                 localcmd("\n", NextFrameCommand, "\n");
1359                 NextFrameCommand = string_null;
1360         }
1361
1362         // we must do this check AFTER a frame was rendered, or it won't work
1363         if(cs_project_is_b0rked == 0)
1364         {
1365                 string w0, h0;
1366                 w0 = ftos(autocvar_vid_conwidth);
1367                 h0 = ftos(autocvar_vid_conheight);
1368                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1369                 //R_SetView(VF_FOV, '90 90 0');
1370                 R_SetView(VF_ORIGIN, '0 0 0');
1371                 R_SetView(VF_ANGLES, '0 0 0');
1372                 R_SetView(VF_PERSPECTIVE, 1);
1373                 makevectors('0 0 0');
1374                 vector v1, v2;
1375                 cvar_set("vid_conwidth", "800");
1376                 cvar_set("vid_conheight", "600");
1377                 v1 = cs_project(v_forward);
1378                 cvar_set("vid_conwidth", "640");
1379                 cvar_set("vid_conheight", "480");
1380                 v2 = cs_project(v_forward);
1381                 if(v1 == v2)
1382                         cs_project_is_b0rked = 1;
1383                 else
1384                         cs_project_is_b0rked = -1;
1385                 cvar_set("vid_conwidth", w0);
1386                 cvar_set("vid_conheight", h0);
1387         }
1388
1389         if(autocvar__hud_configure)
1390                 HUD_Panel_Mouse();
1391
1392         // let's reset the view back to normal for the end
1393         R_SetView(VF_MIN, '0 0 0');
1394         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1395 }
1396
1397 #define spider_h "gfx/vehicles/hud_bg.tga"
1398 #define spider_b "gfx/vehicles/sbot.tga"
1399 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1400 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1401 #define spider_s "gfx/vehicles/shiled.tga"
1402 #define spider_a1 "gfx/hud/sb_rocket.tga"
1403 #define spider_a2 "gfx/sb_bullets.tga"
1404
1405 void CSQC_SPIDER_HUD()
1406 {
1407         float rockets, reload, heat, hp, shield;
1408         vector picsize, hudloc;
1409
1410     // Fetch health & ammo stats
1411     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1412         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1413         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1414         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1415         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1416
1417     // Draw the crosshairs
1418     picsize = drawgetimagesize(SPIDER_CROSS);
1419     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1420     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1421     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1422
1423     hudloc_y =  4;
1424     hudloc_x = 4;
1425
1426     picsize = drawgetimagesize(spider_h) * 0.5;
1427     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1428
1429     picsize = drawgetimagesize(spider_a2) * 0.5;
1430     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1431
1432     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1433     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1434     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1435
1436     picsize = drawgetimagesize(spider_a1) * 0.85;
1437     if(rockets == 9)
1438     {
1439         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1440         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1441     }
1442     else
1443     {
1444         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1445         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1446     }
1447
1448     picsize = drawgetimagesize(spider_b) * 0.5;
1449     hudloc_y = 10.5;
1450     hudloc_x = 10.5;
1451
1452     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1453     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1454     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1455     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1456
1457
1458         /*
1459         // Draw health bar
1460         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1461         p = p + '0 1 0' * vid_conheight - '0 32 0';
1462         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1463         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1464         p_y += 8;
1465         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1466         p_x += 256 * hp;
1467         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1468
1469         // Draw minigun heat indicator
1470         p = '0.5 0 0' * (vid_conwidth - 256);
1471         p = p + '0 1 0' * vid_conheight - '0 34  0';
1472         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1473         p_x += 256 * (1-heat);
1474         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1475
1476
1477         // Draw rocket icons for loaded/empty tubes.
1478         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1479         pp += '0 1 0' * vid_conheight - '0 64 0';
1480         for(i = 0; i < 8; ++i)
1481         {
1482                 p = pp + '1 0 0' * (rkt_size * i);
1483                 if(rockets == 8)
1484                 {
1485                         if(floor(reload * 8) == i)
1486                         {
1487                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1488                         }
1489                         else if(i < reload * 8)
1490                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1491                         else
1492                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1493                 }
1494                 else
1495                 {
1496                         if(i < rockets)
1497                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1498                         else
1499                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1500                 }
1501         }
1502         */
1503
1504         if (scoreboard_showscores)
1505         {
1506                 HUD_DrawScoreboard();
1507                 HUD_DrawCenterPrint();
1508         }
1509
1510 }
1511
1512 #define raptor_h "gfx/vehicles/hud_bg.tga"
1513 #define raptor_b "gfx/vehicles/raptor.tga"
1514 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1515 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1516 #define raptor_s "gfx/vehicles/shiled.tga"
1517
1518 void CSQC_RAPTOR_HUD()
1519 {
1520         float reload, hp, shield, energy;
1521         vector picsize, hudloc;
1522
1523     // Fetch health & ammo stats
1524     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1525         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1526         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1527         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1528
1529     // Draw the crosshairs
1530     picsize = drawgetimagesize(SPIDER_CROSS);
1531     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1532     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1533     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1534
1535     hudloc_y =  4;
1536     hudloc_x = 4;
1537
1538     picsize = drawgetimagesize(raptor_h) * 0.5;
1539     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1540
1541     picsize = drawgetimagesize(spider_a2) * 0.5;
1542     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1543
1544     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1545     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1546     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1547
1548
1549     picsize = drawgetimagesize(spider_a1) * 0.85;
1550     if(reload == 1)
1551     {
1552         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1553         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1554     }
1555     else
1556     {
1557         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1558         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1559     }
1560
1561     picsize = drawgetimagesize(raptor_b) * 0.5;
1562     hudloc_y = 10.5;
1563     hudloc_x = 10.5;
1564
1565     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1566     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1567     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1568     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1569
1570
1571         if (scoreboard_showscores)
1572         {
1573                 HUD_DrawScoreboard();
1574                 HUD_DrawCenterPrint();
1575         }
1576
1577 }
1578
1579 #define waki_h "gfx/vehicles/hud_bg.tga"
1580 #define waki_b "gfx/vehicles/waki.tga"
1581 #define waki_e "gfx/vehicles/waki_e.tga"
1582 #define waki_g "gfx/vehicles/waki_guns.tga"
1583 #define waki_r "gfx/vehicles/waki_rockets.tga"
1584 #define waki_s "gfx/vehicles/shiled.tga"
1585
1586 #define waki_a1 "gfx/hud/sb_rocket.tga"
1587 #define waki_a2 "gfx/sb_cells.tga"
1588
1589 void CSQC_WAKIZASHI_HUD()
1590 {
1591         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1592         float health, shield, energy, rockets;
1593         vector picsize, hudloc;
1594
1595     picsize = drawgetimagesize(SPIDER_CROSS);
1596     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1597     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1598     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1599
1600 /*
1601 const float STAT_VEHICLESTAT_HEALTH  = 60;
1602 const float STAT_VEHICLESTAT_SHIELD  = 61;
1603 const float STAT_VEHICLESTAT_ENERGY  = 62;
1604 const float STAT_VEHICLESTAT_AMMO1   = 63;
1605 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1606 const float STAT_VEHICLESTAT_AMMO2   = 65;
1607 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1608 */
1609     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1610         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1611         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1612         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1613
1614     hudloc_y =  4;
1615     hudloc_x = 4;
1616
1617     picsize = drawgetimagesize(waki_h) * 0.5;
1618     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1619
1620     picsize = drawgetimagesize(waki_a2) * 0.7;
1621     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1622
1623
1624     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1625     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1626
1627     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1628
1629     picsize = drawgetimagesize(waki_a1) * 0.75;
1630     if(rockets == 1)
1631     {
1632         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1633         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1634     }
1635     else
1636     {
1637         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1638         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1639         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1640     }
1641
1642     picsize = drawgetimagesize(waki_b) * 0.5;
1643     hudloc_y = 10.5;
1644     hudloc_x = 10.5;
1645
1646     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1647     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1648     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1649     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1650
1651
1652
1653         /*
1654         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1655         p = p + '0 1 0' * vid_conheight - '0 32 0';
1656
1657         // Draw health bar
1658         p_y += 8;
1659         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1660         p_x += 256 * health;
1661         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1662
1663         // Draw shiled bar
1664         p_x -= 256 * health;
1665         p_y += 4;
1666         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1667
1668         // Draw energy
1669         //p_x -= 256 * health;
1670         p_y -= 8;
1671         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1672
1673         // Draw rockets bar
1674         p_y += 12;
1675         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1676         */
1677
1678
1679
1680
1681         if (scoreboard_showscores)
1682         {
1683                 HUD_DrawScoreboard();
1684                 HUD_DrawCenterPrint();
1685         }
1686
1687 }
1688
1689
1690 void CSQC_common_hud(void)
1691 {
1692         // HUD_SortFrags(); done in HUD_Draw
1693         float hud;
1694         hud = getstati(STAT_HUD);
1695
1696         //hud = 10;
1697         switch(hud)
1698         {
1699                 case HUD_NORMAL:
1700                         // do some accuracy var caching
1701                         float i;
1702                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1703                         {
1704                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1705                                 {
1706                                         if(acc_color_levels)
1707                                                 strunzone(acc_color_levels);
1708                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1709                                         acc_levels = tokenize(acc_color_levels);
1710                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1711                                                 acc_levels = MAX_ACCURACY_LEVELS;
1712
1713                                         for (i = 0; i < acc_levels; ++i)
1714                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1715                                 }
1716                                 // let know that acc_col[] needs to be loaded
1717                                 acc_col_x[0] = -1;
1718                         }
1719
1720                         HUD_Main(); // always run these functions for alpha checks
1721                         HUD_DrawScoreboard();
1722
1723                         if (scoreboard_active) // scoreboard/accuracy
1724                         {
1725                                 HUD_Reset();
1726                                 // HUD_DrawScoreboard takes care of centerprint_start
1727                         }
1728                         else if (intermission == 2) // map voting screen
1729                         {
1730                                 HUD_FinaleOverlay();
1731                                 HUD_Reset();
1732
1733                                 centerprint_start_x = 0;
1734                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1735                         }
1736                         else // hud
1737                         {
1738                                 centerprint_start_x = 0;
1739                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1740                         }
1741
1742                         HUD_DrawCenterPrint();
1743                         break;
1744
1745                 case HUD_SPIDERBOT:
1746                         CSQC_SPIDER_HUD();
1747                         break;
1748
1749                 case HUD_WAKIZASHI:
1750                         CSQC_WAKIZASHI_HUD();
1751                         break;
1752         }
1753 }
1754
1755
1756 // following vectors must be global to allow seamless switching between camera modes
1757 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1758 void CSQC_Demo_Camera()
1759 {
1760         float speed, attenuation, dimensions;
1761         vector tmp, delta;
1762
1763         if( autocvar_camera_reset || !camera_mode )
1764         {
1765                 camera_offset = '0 0 0';
1766                 current_angles = '0 0 0';
1767                 camera_direction = '0 0 0';
1768                 camera_offset_z += 30;
1769                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1770                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1771                 current_origin = view_origin;
1772                 current_camera_offset  = camera_offset;
1773                 cvar_set("camera_reset", "0");
1774                 camera_mode = CAMERA_CHASE;
1775         }
1776
1777         // Camera angles
1778         if( camera_roll )
1779                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1780
1781         if(autocvar_camera_look_player)
1782         {
1783                 local vector dir;
1784                 local float n;
1785
1786                 dir = normalize(view_origin - current_position);
1787                 n = mouse_angles_z;
1788                 mouse_angles = vectoangles(dir);
1789                 mouse_angles_x = mouse_angles_x * -1;
1790                 mouse_angles_z = n;
1791         }
1792         else
1793         {
1794                 tmp = getmousepos() * 0.1;
1795                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1796                 {
1797                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1798                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1799                 }
1800         }
1801
1802         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1803         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1804         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1805         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1806
1807         // Fix difference when angles don't have the same sign
1808         delta = '0 0 0';
1809         if(mouse_angles_y < -60 && current_angles_y > 60)
1810                 delta = '0 360 0';
1811         if(mouse_angles_y > 60 && current_angles_y < -60)
1812                 delta = '0 -360 0';
1813
1814         if(autocvar_camera_look_player)
1815                 attenuation = autocvar_camera_look_attenuation;
1816         else
1817                 attenuation = autocvar_camera_speed_attenuation;
1818
1819         attenuation = 1 / max(1, attenuation);
1820         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1821
1822         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1823         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1824         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1825         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1826
1827         // Camera position
1828         tmp = '0 0 0';
1829         dimensions = 0;
1830
1831         if( camera_direction_x )
1832         {
1833                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1834                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1835                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1836                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1837                 ++dimensions;
1838         }
1839
1840         if( camera_direction_y )
1841         {
1842                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1843                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1844                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1845                 ++dimensions;
1846         }
1847
1848         if( camera_direction_z )
1849         {
1850                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1851                 ++dimensions;
1852         }
1853
1854         if(autocvar_camera_free)
1855                 speed = autocvar_camera_speed_free;
1856         else
1857                 speed = autocvar_camera_speed_chase;
1858
1859         if(dimensions)
1860         {
1861                 speed = speed * sqrt(1 / dimensions);
1862                 camera_offset += tmp * speed;
1863         }
1864
1865         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1866
1867         // Camera modes
1868         if( autocvar_camera_free )
1869         {
1870                 if ( camera_mode == CAMERA_CHASE )
1871                 {
1872                         current_camera_offset = current_origin + current_camera_offset;
1873                         camera_offset = current_origin + camera_offset;
1874                 }
1875
1876                 camera_mode = CAMERA_FREE;
1877                 current_position = current_camera_offset;
1878         }
1879         else
1880         {
1881                 if ( camera_mode == CAMERA_FREE )
1882                 {
1883                         current_origin = view_origin;
1884                         camera_offset = camera_offset - current_origin;
1885                         current_camera_offset = current_camera_offset - current_origin;
1886                 }
1887
1888                 camera_mode = CAMERA_CHASE;
1889
1890                 if(autocvar_camera_chase_smoothly)
1891                         current_origin += (view_origin - current_origin) * attenuation;
1892                 else
1893                         current_origin = view_origin;
1894
1895                 current_position = current_origin + current_camera_offset;
1896         }
1897
1898         R_SetView(VF_ANGLES, current_angles);
1899         R_SetView(VF_ORIGIN, current_position);
1900 }