qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float trace_dphitcontents;
   4 float trace_networkentity;
   5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   6 float DPCONTENTS_SOLID = 1; // blocks player movement
   7 float DPCONTENTS_BODY = 32; // blocks player movement
   8 float DPCONTENTS_CORPSE = 64; // blocks player movement
   9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  10 void Porto_Draw()
  11 {
  12         vector p, dir, ang, q, nextdir;
  13         float idx, portal_number, portal1_idx;
  14
  15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 /**
  84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  85  *
  86  * TODO: Use a better solution where a common shared entitiy is used that contains
  87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  88  * and STAT_FRAGLIMIT to be auto-sent)
  89  */
  90 void CheckForGamestartChange() {
  91         float startTime;
  92         startTime = getstatf(STAT_GAMESTARTTIME);
  93         if (previous_game_starttime != startTime) {
  94                 if ((time + 5.0) < startTime) {
  95                         //if connecting to server while restart was active don't always play prepareforbattle
  96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  97                 }
  98                 if (time < startTime) {
  99                         restartAnnouncer = spawn();
 100                         restartAnnouncer.think = restartAnnouncer_Think;
 101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 102                 }
 103         }
 104         previous_game_starttime = startTime;
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 120
 121         zoomsensitivity = autocvar_cl_zoomsensitivity;
 122         zoomfactor = autocvar_cl_zoomfactor;
 123         if(zoomfactor < 1 || zoomfactor > 16)
 124                 zoomfactor = 2.5;
 125         zoomspeed = autocvar_cl_zoomspeed;
 126         if(zoomspeed >= 0)
 127                 if(zoomspeed < 0.5 || zoomspeed > 16)
 128                         zoomspeed = 3.5;
 129
 130         zoomdir = button_zoom;
 131         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 132                 zoomdir += button_attack2;
 133         if(spectatee_status > 0 || isdemo())
 134         {
 135                 if(spectatorbutton_zoom)
 136                         zoomdir = 0 + !zoomdir;
 137                 // do not even THINK about removing this 0
 138                 // _I_ know what I am doing
 139                 // fteqcc does not
 140         }
 141
 142         if(zoomdir)
 143                 zoomin_effect = 0;
 144
 145         if(zoomin_effect || camera_active)
 146         {
 147                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 148         }
 149         else
 150         {
 151                 if(zoomspeed < 0) // instant zoom
 152                 {
 153                         if(zoomdir)
 154                                 current_viewzoom = 1 / zoomfactor;
 155                         else
 156                                 current_viewzoom = 1;
 157                 }
 158                 else
 159                 {
 160                         if(zoomdir)
 161                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 162                         else
 163                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 164                 }
 165         }
 166
 167         if(almost_equals(current_viewzoom, 1))
 168                 current_zoomfraction = 0;
 169         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 170                 current_zoomfraction = 1;
 171         else
 172                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 173
 174         if(zoomsensitivity < 1)
 175                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 176         else
 177                 setsensitivityscale(1);
 178
 179         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 180         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 181         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 182
 183         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 184
 185         float frustumx, frustumy, fovx, fovy;
 186         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 187         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 188         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 189         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 190
 191         return '1 0 0' * fovx + '0 1 0' * fovy;
 192 }
 193
 194 // this function must match W_SetupShot!
 195 float zoomscript_caught;
 196
 197 vector wcross_origin;
 198 float wcross_scale_prev, wcross_alpha_prev;
 199 vector wcross_color_prev;
 200 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 201 vector wcross_color_goal_prev;
 202 float wcross_changedonetime;
 203
 204 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 205 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 206 float wcross_name_changestarttime, wcross_name_changedonetime;
 207 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 208 entity trueaim;
 209 entity trueaim_rifle;
 210
 211 #define SHOTTYPE_HITTEAM 1
 212 #define SHOTTYPE_HITOBSTRUCTION 2
 213 #define SHOTTYPE_HITWORLD 3
 214 #define SHOTTYPE_HITENEMY 4
 215
 216 void TrueAim_Init()
 217 {
 218         trueaim = spawn();
 219         trueaim.classname = "trueaim";
 220         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 221         trueaim_rifle = spawn();
 222         trueaim_rifle.classname = "trueaim_rifle";
 223         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 224 }
 225
 226 float EnemyHitCheck()
 227 {
 228         float t;
 229         wcross_origin = project_3d_to_2d(trace_endpos);
 230         wcross_origin_z = 0;
 231         if(trace_networkentity < 1)
 232                 return SHOTTYPE_HITWORLD;
 233         if(trace_networkentity > maxclients)
 234                 return SHOTTYPE_HITWORLD;
 235         t = GetPlayerColor(trace_networkentity - 1);
 236         if(teamplay)
 237                 if(t == myteam)
 238                         return SHOTTYPE_HITTEAM;
 239         if(t == COLOR_SPECTATOR)
 240                 return SHOTTYPE_HITWORLD;
 241         return SHOTTYPE_HITENEMY;
 242 }
 243
 244 float TrueAimCheck()
 245 {
 246         float nudge = 1; // added to traceline target and subtracted from result
 247         vector vecs, trueaimpoint, w_shotorg;
 248         vector mi, ma, dv;
 249         float shottype;
 250         entity ta;
 251         float mv;
 252
 253         mi = ma = '0 0 0';
 254         ta = trueaim;
 255         mv = MOVE_NOMONSTERS;
 256
 257         switch(activeweapon)
 258         {
 259                 case WEP_TUBA: // no aim
 260                 case WEP_PORTO: // shoots from eye
 261                 case WEP_HOOK: // no trueaim
 262                 case WEP_GRENADE_LAUNCHER: // toss curve
 263                         return SHOTTYPE_HITWORLD;
 264                 case WEP_NEX:
 265                 case WEP_MINSTANEX:
 266                         mv = MOVE_NORMAL;
 267                         break;
 268                 case WEP_RIFLE:
 269                         ta = trueaim_rifle;
 270                         mv = MOVE_NORMAL;
 271                         if(zoomscript_caught)
 272                         {
 273                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 274                                 return EnemyHitCheck();
 275                         }
 276                         break;
 277                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 278                         mi = '-3 -3 -3';
 279                         ma = '3 3 3';
 280                         break;
 281                 case WEP_FIREBALL: // projectile has a size!
 282                         mi = '-16 -16 -16';
 283                         ma = '16 16 16';
 284                         break;
 285                 case WEP_SEEKER: // projectile has a size!
 286                         mi = '-2 -2 -2';
 287                         ma = '2 2 2';
 288                         break;
 289                 case WEP_ELECTRO: // projectile has a size!
 290                         mi = '0 0 -3';
 291                         ma = '0 0 -3';
 292                         break;
 293         }
 294
 295         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 296
 297         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 298         trueaimpoint = trace_endpos;
 299
 300         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 301                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 302
 303         if(vecs_x > 0)
 304                 vecs_y = -vecs_y;
 305         else
 306                 vecs = '0 0 0';
 307
 308         dv = view_right * vecs_y + view_up * vecs_z;
 309         w_shotorg = view_origin + dv;
 310
 311         // now move the vecs forward as much as requested if possible
 312         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 313         w_shotorg = trace_endpos - view_forward * nudge;
 314
 315         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 316         shottype = EnemyHitCheck();
 317         if(shottype != SHOTTYPE_HITWORLD)
 318                 return shottype;
 319
 320 #if 0
 321         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 322         // or rather, I know why, but see no fix
 323         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 324                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 325                 return SHOTTYPE_HITOBSTRUCTION;
 326 #endif
 327
 328         return SHOTTYPE_HITWORLD;
 329 }
 330
 331 void CSQC_common_hud(void);
 332
 333 void PostInit(void);
 334 void CSQC_Demo_Camera();
 335 float HUD_WouldDrawScoreboard();
 336 float camera_mode;
 337 float reticle_type;
 338 string NextFrameCommand;
 339 void CSQC_SPIDER_HUD();
 340 void CSQC_RAPTOR_HUD();
 341
 342 vector freeze_org, freeze_ang;
 343 entity nightvision_noise, nightvision_noise2;
 344
 345 float pickup_crosshair_time, pickup_crosshair_size;
 346 float hit_time, typehit_time;
 347 float nextsound_hit_time, nextsound_typehit_time;
 348 float hitindication_crosshair_time, hitindication_crosshair_size;
 349 float use_nex_chargepool;
 350
 351 float myhealth, myhealth_prev;
 352 float myhealth_flash;
 353
 354 vector myhealth_gentlergb;
 355
 356 float contentavgalpha, liquidalpha_prev;
 357 vector liquidcolor_prev;
 358
 359 float eventchase_current_distance;
 360
 361 float checkfail[16];
 362
 363 void CSQC_UpdateView(float w, float h)
 364 {
 365         entity e;
 366         float fov;
 367         float f, i, j;
 368         vector v, vo;
 369         vector vf_size, vf_min;
 370         float a;
 371         hud = getstati(STAT_HUD);
 372
 373         button_attack2 = (input_buttons & BUTTON_3);
 374         button_zoom = (input_buttons & BUTTON_4);
 375
 376 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 377         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 378         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 379         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 380         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 381         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 382         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 383
 384         vf_size = R_SetView3fv(VF_SIZE);
 385         vf_min = R_SetView3fv(VF_MIN);
 386         vid_width = vf_size_x;
 387         vid_height = vf_size_y;
 388
 389         vector reticle_pos, reticle_size;
 390         vector splash_pos, splash_size;
 391
 392         WaypointSprite_Load();
 393
 394         if(spectatee_status)
 395                 myteam = GetPlayerColor(spectatee_status - 1);
 396         else
 397                 myteam = GetPlayerColor(player_localentnum - 1);
 398
 399         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 400         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 401
 402         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 403         {
 404                 R_SetView(VF_ORIGIN, freeze_org);
 405                 R_SetView(VF_ANGLES, freeze_ang);
 406         }
 407         else
 408         {
 409                 freeze_org = R_SetView3fv(VF_ORIGIN);
 410                 freeze_ang = R_SetView3fv(VF_ANGLES);
 411         }
 412
 413         // event chase camera
 414         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 415         {
 416                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 417                 {
 418                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 419                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 420                         if(!autocvar_chase_active)
 421                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 422
 423                         // make the camera smooth back
 424                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 425                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 426                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 427                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 428
 429                         vector eventchase_target_origin;
 430                         makevectors(view_angles);
 431                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 432                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 433
 434                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 435                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 436                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 437                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 438                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 439
 440                         R_SetView(VF_ORIGIN, trace_endpos);
 441                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 442                 }
 443                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 444                 {
 445                         cvar_set("chase_active", "0");
 446                         eventchase_current_distance = 0; // start from 0 next time
 447                 }
 448         }
 449
 450         WarpZone_FixView();
 451         //WarpZone_FixPMove();
 452
 453         // Render the Scene
 454         view_origin = R_SetView3fv(VF_ORIGIN);
 455         view_angles = R_SetView3fv(VF_ANGLES);
 456         makevectors(view_angles);
 457         view_forward = v_forward;
 458         view_right = v_right;
 459         view_up = v_up;
 460
 461 #ifdef BLURTEST
 462         if(time > blurtest_time0 && time < blurtest_time1)
 463         {
 464                 float r, t;
 465
 466                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 467                 r = t * blurtest_radius;
 468                 f = 1 / pow(t, blurtest_power) - 1;
 469
 470                 cvar_set("r_glsl_postprocess", "1");
 471                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 472         }
 473         else
 474         {
 475                 cvar_set("r_glsl_postprocess", "0");
 476                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 477         }
 478 #endif
 479
 480         TargetMusic_Advance();
 481         Fog_Force();
 482
 483         if(drawtime == 0)
 484                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 485         else
 486                 drawframetime = bound(0.000001, time - drawtime, 1);
 487         drawtime = time;
 488
 489         // watch for gametype changes here...
 490         // in ParseStuffCMD the cmd isn't executed yet :/
 491         // might even be better to add the gametype to TE_CSQC_INIT...?
 492         if(!postinit)
 493                 PostInit();
 494
 495         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 496                 if(calledhooks & HOOK_START)
 497                 {
 498                         localcmd("\ncl_hook_gameend\n");
 499                         calledhooks |= HOOK_END;
 500                 }
 501
 502         CheckForGamestartChange();
 503         serverAnnouncer();
 504         maptimeAnnouncer();
 505         carrierAnnouncer();
 506
 507         fov = autocvar_fov;
 508         if(fov <= 59.5)
 509         {
 510                 if(!zoomscript_caught)
 511                 {
 512                         localcmd("+button9\n");
 513                         zoomscript_caught = 1;
 514                 }
 515         }
 516         else
 517         {
 518                 if(zoomscript_caught)
 519                 {
 520                         localcmd("-button9\n");
 521                         zoomscript_caught = 0;
 522                 }
 523         }
 524
 525         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 526         activeweapon = getstati(STAT_SWITCHWEAPON);
 527         f = (serverflags & SERVERFLAG_TEAMPLAY);
 528         if(f != teamplay)
 529         {
 530                 teamplay = f;
 531                 HUD_InitScores();
 532         }
 533
 534         if(last_weapon != activeweapon) {
 535                 weapontime = time;
 536                 last_weapon = activeweapon;
 537
 538                 e = get_weaponinfo(activeweapon);
 539                 if(e.netname != "")
 540                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 541                 else
 542                         localcmd("\ncl_hook_activeweapon none\n");
 543         }
 544
 545         // ALWAYS Clear Current Scene First
 546         R_ClearScene();
 547         R_SetView(VF_ORIGIN, view_origin);
 548         R_SetView(VF_ANGLES, view_angles);
 549
 550         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 551         R_SetView(VF_SIZE, vf_size);
 552         R_SetView(VF_MIN, vf_min);
 553
 554         // Assign Standard Viewflags
 555         // Draw the World (and sky)
 556         R_SetView(VF_DRAWWORLD, 1);
 557
 558         // Set the console size vars
 559         vid_conwidth = autocvar_vid_conwidth;
 560         vid_conheight = autocvar_vid_conheight;
 561         vid_pixelheight = autocvar_vid_pixelheight;
 562
 563         R_SetView(VF_FOV, GetCurrentFov(fov));
 564
 565         // Camera for demo playback
 566         if(camera_active)
 567         {
 568                 if(autocvar_camera_enable)
 569                         CSQC_Demo_Camera();
 570                 else
 571                 {
 572                         cvar_set("chase_active", ftos(chase_active_backup));
 573                         cvar_set("cl_demo_mousegrab", "0");
 574                         camera_active = FALSE;
 575                 }
 576         }
 577 #ifdef CAMERATEST
 578         else if(autocvar_camera_enable)
 579 #else
 580         else if(autocvar_camera_enable && isdemo())
 581 #endif
 582         {
 583                 // Enable required Darkplaces cvars
 584                 chase_active_backup = autocvar_chase_active;
 585                 cvar_set("chase_active", "2");
 586                 cvar_set("cl_demo_mousegrab", "1");
 587                 camera_active = TRUE;
 588                 camera_mode = FALSE;
 589         }
 590
 591         // Draw the Crosshair
 592         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 593
 594         // Draw the Engine Status Bar (the default Quake HUD)
 595         R_SetView(VF_DRAWENGINEHUD, 0);
 596
 597         // Update the mouse position
 598         /*
 599            mousepos_x = vid_conwidth;
 600            mousepos_y = vid_conheight;
 601            mousepos = mousepos*0.5 + getmousepos();
 602          */
 603
 604         e = self;
 605         for(self = world; (self = nextent(self)); )
 606                 if(self.draw)
 607                         self.draw();
 608         self = e;
 609
 610         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 611         R_RenderScene();
 612
 613         // now switch to 2D drawing mode by calling a 2D drawing function
 614         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 615         // next R_RenderScene call
 616         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 617
 618         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 619         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 620         {
 621                 // apply night vision effect
 622                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 623
 624                 if(!nightvision_noise)
 625                 {
 626                         nightvision_noise = spawn();
 627                         nightvision_noise.classname = "nightvision_noise";
 628                 }
 629                 if(!nightvision_noise2)
 630                 {
 631                         nightvision_noise2 = spawn();
 632                         nightvision_noise2.classname = "nightvision_noise2";
 633                 }
 634
 635                 // color tint in yellow
 636                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 637
 638                 // draw BG
 639                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 640                 rgb = '1 1 1';
 641                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 642                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 643                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 644                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 645                 tc_11 = tc_01 + tc_10 - tc_00;
 646                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 647                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 648                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 649                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 650                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 651                 R_EndPolygon();
 652
 653                 // draw FG
 654                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 655                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 656                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 657                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 658                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 659                 tc_11 = tc_01 + tc_10 - tc_00;
 660                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 661                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 662                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 663                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 664                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 665                 R_EndPolygon();
 666         }
 667
 668         // Draw the aiming reticle for weapons that use it
 669         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 670         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 671         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 672         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 673                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 674         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 675                 reticle_type = 2; // nex zoom
 676         else if(button_zoom || zoomscript_caught)
 677                 reticle_type = 1; // normal zoom
 678         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 679                 reticle_type = 2; // nex zoom
 680
 681         if (reticle_type)
 682         {
 683                 if(autocvar_cl_reticle_stretch)
 684                 {
 685                         reticle_size_x = vid_conwidth;
 686                         reticle_size_y = vid_conheight;
 687                         reticle_pos_x = 0;
 688                         reticle_pos_y = 0;
 689                 }
 690                 else
 691                 {
 692                         reticle_size_x = max(vid_conwidth, vid_conheight);
 693                         reticle_size_y = max(vid_conwidth, vid_conheight);
 694                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 695                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 696                 }
 697
 698                 f = current_zoomfraction;
 699                 if(zoomscript_caught)
 700                         f = 1;
 701                 if(autocvar_cl_reticle_item_normal)
 702                 {
 703                         if(reticle_type == 1 && f)
 704                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 705                 }
 706                 if(autocvar_cl_reticle_item_nex)
 707                 {
 708                         if(reticle_type == 2 && f)
 709                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 710                 }
 711         }
 712
 713
 714         // improved polyblend
 715         vector rgb;
 716         if(autocvar_hud_contents)
 717         {
 718                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 719                 vector liquidcolor;
 720
 721                 switch(pointcontents(view_origin))
 722                 {
 723                         case CONTENT_WATER:
 724                                 liquidalpha = autocvar_hud_contents_water_alpha;
 725                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 726                                 incontent = 1;
 727                                 break;
 728
 729                         case CONTENT_LAVA:
 730                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 731                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 732                                 incontent = 1;
 733                                 break;
 734
 735                         case CONTENT_SLIME:
 736                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 737                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 738                                 incontent = 1;
 739                                 break;
 740
 741                         default:
 742                                 liquidalpha = 0;
 743                                 liquidcolor = '0 0 0';
 744                                 incontent = 0;
 745                                 break;
 746                 }
 747
 748                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 749                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 750                         contentfadetime = autocvar_hud_contents_fadeintime;
 751                         liquidalpha_prev = liquidalpha;
 752                         liquidcolor_prev = liquidcolor;
 753                 }
 754                 else
 755                         contentfadetime = autocvar_hud_contents_fadeouttime;
 756
 757                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 758                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 759
 760                 if(contentavgalpha)
 761                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 762         }
 763
 764         if(autocvar_hud_damage && !autocvar_chase_active)
 765
 766         {
 767                 splash_size_x = max(vid_conwidth, vid_conheight);
 768                 splash_size_y = max(vid_conwidth, vid_conheight);
 769                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 770                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 771
 772                 float myhealth_flash_temp;
 773                 myhealth = getstati(STAT_HEALTH);
 774
 775                 // fade out
 776                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 777                 // add new damage
 778                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 779
 780                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 781                 pain_threshold = autocvar_hud_damage_pain_threshold;
 782                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 783                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 784
 785                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 786                 {
 787                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 788                 }
 789
 790                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 791
 792                 if(myhealth_prev < 1)
 793                 {
 794                         if(myhealth >= 1)
 795                         {
 796                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 797                                 myhealth_flash_temp = 0;
 798                         }
 799                         else
 800                         {
 801                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 802                         }
 803                 }
 804
 805                 if(spectatee_status == -1 || intermission)
 806                 {
 807                         myhealth_flash = 0; // observing, or match ended
 808                         myhealth_flash_temp = 0;
 809                 }
 810
 811                 myhealth_prev = myhealth;
 812
 813                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 814                 {
 815                         if(autocvar_cl_gentle_damage == 2)
 816                         {
 817                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 818                                 {
 819                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 820                                 }
 821                         }
 822                         else
 823                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 824
 825                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 826                 }
 827                 else
 828                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 829         }
 830
 831         if(menu_visible)
 832                 menu_show();
 833
 834         /*if(gametype == GAME_CTF)
 835           {
 836           ctf_view();
 837           } else */
 838
 839         // draw 2D entities
 840         e = self;
 841         for(self = world; (self = nextent(self)); )
 842                 if(self.draw2d)
 843                         self.draw2d();
 844         self = e;
 845         Draw_ShowNames_All();
 846
 847         scoreboard_active = HUD_WouldDrawScoreboard();
 848
 849         hit_time = getstatf(STAT_HIT_TIME);
 850         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 851         {
 852                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 853                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 854         }
 855         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 856         if(typehit_time > nextsound_typehit_time)
 857         {
 858                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 859                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 860         }
 861
 862         //else
 863         {
 864                 if(gametype == GAME_FREEZETAG)
 865                 {
 866                         if(getstati(STAT_FROZEN))
 867                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 868                         if(getstatf(STAT_REVIVE_PROGRESS))
 869                         {
 870                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 871                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 872                         }
 873                 }
 874
 875                 if(autocvar_r_letterbox == 0)
 876                         if(autocvar_viewsize < 120)
 877                                 CSQC_common_hud();
 878
 879                 // crosshair goes VERY LAST
 880                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 881                         string wcross_style;
 882                         float wcross_alpha, wcross_resolution;
 883                         wcross_style = autocvar_crosshair;
 884                         if (wcross_style == "0")
 885                                 return;
 886                         wcross_resolution = autocvar_crosshair_size;
 887                         if (wcross_resolution == 0)
 888                                 return;
 889                         wcross_alpha = autocvar_crosshair_alpha;
 890                         if (wcross_alpha == 0)
 891                                 return;
 892
 893                         // TrueAim check
 894                         float shottype;
 895
 896                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 897                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 898                         wcross_origin_z = 0;
 899                         if(autocvar_crosshair_hittest)
 900                         {
 901                                 vector wcross_oldorigin;
 902                                 wcross_oldorigin = wcross_origin;
 903                                 shottype = TrueAimCheck();
 904                                 if(shottype == SHOTTYPE_HITWORLD)
 905                                 {
 906                                         v = wcross_origin - wcross_oldorigin;
 907                                         v_x /= vid_conwidth;
 908                                         v_y /= vid_conheight;
 909                                         if(vlen(v) > 0.01)
 910                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 911                                 }
 912                                 if(!autocvar_crosshair_hittest_showimpact)
 913                                         wcross_origin = wcross_oldorigin;
 914                         }
 915                         else
 916                                 shottype = SHOTTYPE_HITWORLD;
 917
 918                         vector wcross_color, wcross_size;
 919                         string wcross_wep, wcross_name;
 920                         float wcross_scale, wcross_blur;
 921
 922                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 923                                 e = get_weaponinfo(activeweapon);
 924                                 if (e && e.netname != "")
 925                                 {
 926                                         wcross_wep = e.netname;
 927                                         if(autocvar_crosshair_per_weapon)
 928                                         {
 929                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 930                                                 if (wcross_resolution == 0)
 931                                                         return;
 932                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 933                                                 if (wcross_alpha == 0)
 934                                                         return;
 935
 936                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 937                                                 if(wcross_style == "" || wcross_style == "0")
 938                                                         wcross_style = wcross_wep;
 939                                         }
 940                                 }
 941                         }
 942                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 943                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 944                         else if(autocvar_crosshair_color_by_health)
 945                         {
 946                                 local float x = getstati(STAT_HEALTH);
 947
 948                                 //x = red
 949                                 //y = green
 950                                 //z = blue
 951
 952                                 wcross_color_z = 0;
 953
 954                                 if(x > 200)
 955                                 {
 956                                         wcross_color_x = 0;
 957                                         wcross_color_y = 1;
 958                                 }
 959                                 else if(x > 150)
 960                                 {
 961                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 962                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 963                                 }
 964                                 else if(x > 100)
 965                                 {
 966                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 967                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 968                                         wcross_color_z = 1 - (x-100)*0.02;
 969                                 }
 970                                 else if(x > 50)
 971                                 {
 972                                         wcross_color_x = 1;
 973                                         wcross_color_y = 1;
 974                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
 975                                 }
 976                                 else if(x > 20)
 977                                 {
 978                                         wcross_color_x = 1;
 979                                         wcross_color_y = (x-20)*90/27/100;
 980                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
 981                                 }
 982                                 else
 983                                 {
 984                                         wcross_color_x = 1;
 985                                         wcross_color_y = 0;
 986                                 }
 987                         }
 988                         else
 989                                 wcross_color = stov(autocvar_crosshair_color);
 990
 991                         wcross_name = strcat("gfx/crosshair", wcross_style);
 992
 993                         if(autocvar_crosshair_effect_scalefade)
 994                         {
 995                                 wcross_scale = wcross_resolution;
 996                                 wcross_resolution = 1;
 997                         }
 998                         else
 999                         {
1000                                 wcross_scale = 1;
1001                         }
1002
1003                         if(autocvar_crosshair_pickup)
1004                         {
1005                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1006                                 {
1007                                         pickup_crosshair_size = 1;
1008                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1009                                 }
1010
1011                                 if(pickup_crosshair_size > 0)
1012                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1013                                 else
1014                                         pickup_crosshair_size = 0;
1015
1016                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1017                         }
1018
1019                         vector hitindication_color;
1020                         if(autocvar_crosshair_hitindication)
1021                         {
1022                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1023                                 if(hitindication_crosshair_time < hit_time)
1024                                 {
1025                                         hitindication_crosshair_size = 1;
1026                                         hitindication_crosshair_time = hit_time;
1027                                 }
1028
1029                                 if(hitindication_crosshair_size > 0)
1030                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1031                                 else
1032                                         hitindication_crosshair_size = 0;
1033
1034                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1035                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1036                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1037                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1038                         }
1039
1040                         if(shottype == SHOTTYPE_HITENEMY)
1041                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1042                         if(shottype == SHOTTYPE_HITTEAM)
1043                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1044
1045                         f = autocvar_crosshair_effect_speed;
1046                         if(f < 0)
1047                                 f *= -2 * g_weaponswitchdelay;
1048                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1049                         {
1050                                 wcross_changedonetime = time + f;
1051                         }
1052                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1053                         {
1054                                 wcross_name_changestarttime = time;
1055                                 wcross_name_changedonetime = time + f;
1056                                 if(wcross_name_goal_prev_prev)
1057                                         strunzone(wcross_name_goal_prev_prev);
1058                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1059                                 wcross_name_goal_prev = strzone(wcross_name);
1060                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1061                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1062                                 wcross_resolution_goal_prev = wcross_resolution;
1063                         }
1064
1065                         wcross_scale_goal_prev = wcross_scale;
1066                         wcross_alpha_goal_prev = wcross_alpha;
1067                         wcross_color_goal_prev = wcross_color;
1068
1069                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1070                         {
1071                                 wcross_blur = 1;
1072                                 wcross_alpha *= 0.75;
1073                         }
1074                         else
1075                                 wcross_blur = 0;
1076                         // *_prev is at time-frametime
1077                         // * is at wcross_changedonetime+f
1078                         // what do we have at time?
1079                         if(time < wcross_changedonetime)
1080                         {
1081                                 f = frametime / (wcross_changedonetime - time + frametime);
1082                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1083                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1084                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1085                         }
1086
1087                         wcross_scale_prev = wcross_scale;
1088                         wcross_alpha_prev = wcross_alpha;
1089                         wcross_color_prev = wcross_color;
1090
1091                         wcross_scale *= 1 - autocvar__menu_alpha;
1092                         wcross_alpha *= 1 - autocvar__menu_alpha;
1093                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1094
1095                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1096                         {
1097                                 // crosshair rings for weapon stats
1098                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1099                                 {
1100                                         // declarations and stats
1101                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1102                                         string ring_image, ring_inner_image;
1103                                         vector ring_rgb, ring_inner_rgb;
1104
1105                                         ring_scale = autocvar_crosshair_ring_size;
1106
1107                                         float weapon_clipload, weapon_clipsize;
1108                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1109                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1110
1111                                         float nex_charge, nex_chargepool;
1112                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1113                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1114
1115                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1116                                                 nex_charge_movingavg = nex_charge;
1117
1118
1119                                         // handle the values
1120                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1121                                         {
1122                                                 if (nex_chargepool || use_nex_chargepool) {
1123                                                         use_nex_chargepool = 1;
1124                                                         ring_inner_value = nex_chargepool;
1125                                                 } else {
1126                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1127                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1128                                                 }
1129
1130                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1131                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1132                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1133
1134                                                 // draw the outer ring to show the current charge of the weapon
1135                                                 ring_value = nex_charge;
1136                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1137                                                 ring_rgb = wcross_color;
1138                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1139                                         }
1140                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1141                                         {
1142                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1143                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1144                                                 ring_rgb = wcross_color;
1145                                                 ring_image = "gfx/crosshair_ring.tga";
1146                                         }
1147                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1148                                         {
1149                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1150                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1151                                                 ring_rgb = wcross_color;
1152                                                 ring_image = "gfx/crosshair_ring.tga";
1153                                         }
1154
1155                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1156                                         {
1157                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1158                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1159                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1160                                                 ring_rgb = wcross_color;
1161
1162                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1163                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1164                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1165                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1166                                                 else
1167                                                         ring_image = "gfx/crosshair_ring.tga";
1168                                         }
1169
1170                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1171                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1172
1173                                         if (ring_value)
1174                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1175                                 }
1176
1177 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1178                                 do \
1179                                 { \
1180                                         if(wcross_blur > 0) \
1181                                         { \
1182                                                 for(i = -2; i <= 2; ++i) \
1183                                                 for(j = -2; j <= 2; ++j) \
1184                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1185                                         } \
1186                                         else \
1187                                         { \
1188                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1189                                         } \
1190                                 } \
1191                                 while(0)
1192
1193 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1194                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1195
1196 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1197                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1198
1199                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1200                                 {
1201                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1202                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1203                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1204                                         f = 1 - f;
1205                                 }
1206                                 else
1207                                 {
1208                                         f = 1;
1209                                 }
1210                                 wcross_name_alpha_goal_prev = f;
1211
1212                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1213                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1214
1215                                 if(autocvar_crosshair_dot)
1216                                 {
1217                                         vector wcross_color_old;
1218                                         wcross_color_old = wcross_color;
1219                                         if(autocvar_crosshair_dot_color != "0")
1220                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1221                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1222                                         // FIXME why don't we use wcross_alpha here?
1223                                         wcross_color = wcross_color_old;
1224                                 }
1225                         }
1226                 }
1227                 else
1228                 {
1229                         wcross_scale_prev = 0;
1230                         wcross_alpha_prev = 0;
1231                         wcross_scale_goal_prev = 0;
1232                         wcross_alpha_goal_prev = 0;
1233                         wcross_changedonetime = 0;
1234                         if(wcross_name_goal_prev)
1235                                 strunzone(wcross_name_goal_prev);
1236                         wcross_name_goal_prev = string_null;
1237                         if(wcross_name_goal_prev_prev)
1238                                 strunzone(wcross_name_goal_prev_prev);
1239                         wcross_name_goal_prev_prev = string_null;
1240                         wcross_name_changestarttime = 0;
1241                         wcross_name_changedonetime = 0;
1242                         wcross_name_alpha_goal_prev = 0;
1243                         wcross_name_alpha_goal_prev_prev = 0;
1244                         wcross_resolution_goal_prev = 0;
1245                         wcross_resolution_goal_prev_prev = 0;
1246                 }
1247         }
1248
1249         if(NextFrameCommand)
1250         {
1251                 localcmd("\n", NextFrameCommand, "\n");
1252                 NextFrameCommand = string_null;
1253         }
1254
1255         // we must do this check AFTER a frame was rendered, or it won't work
1256         if(cs_project_is_b0rked == 0)
1257         {
1258                 string w0, h0;
1259                 w0 = ftos(autocvar_vid_conwidth);
1260                 h0 = ftos(autocvar_vid_conheight);
1261                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1262                 //R_SetView(VF_FOV, '90 90 0');
1263                 R_SetView(VF_ORIGIN, '0 0 0');
1264                 R_SetView(VF_ANGLES, '0 0 0');
1265                 R_SetView(VF_PERSPECTIVE, 1);
1266                 makevectors('0 0 0');
1267                 vector v1, v2;
1268                 cvar_set("vid_conwidth", "800");
1269                 cvar_set("vid_conheight", "600");
1270                 v1 = cs_project(v_forward);
1271                 cvar_set("vid_conwidth", "640");
1272                 cvar_set("vid_conheight", "480");
1273                 v2 = cs_project(v_forward);
1274                 if(v1 == v2)
1275                         cs_project_is_b0rked = 1;
1276                 else
1277                         cs_project_is_b0rked = -1;
1278                 cvar_set("vid_conwidth", w0);
1279                 cvar_set("vid_conheight", h0);
1280         }
1281
1282         if(autocvar__hud_configure)
1283                 HUD_Panel_Mouse();
1284
1285     if(hud && !intermission)
1286     {
1287         if(hud == HUD_SPIDERBOT)
1288             CSQC_SPIDER_HUD();
1289         else if(hud == HUD_WAKIZASHI)
1290             CSQC_WAKIZASHI_HUD();
1291         else if(hud == HUD_RAPTOR)
1292             CSQC_RAPTOR_HUD();
1293         else if(hud == HUD_BUMBLEBEE)
1294             CSQC_BUMBLE_HUD();
1295     }
1296         // let's reset the view back to normal for the end
1297         R_SetView(VF_MIN, '0 0 0');
1298         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1299 }
1300
1301
1302 void CSQC_common_hud(void)
1303 {
1304     // do some accuracy var caching
1305     float i;
1306     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1307     {
1308         if(autocvar_accuracy_color_levels != acc_color_levels)
1309         {
1310             if(acc_color_levels)
1311                 strunzone(acc_color_levels);
1312             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1313             acc_levels = tokenize(acc_color_levels);
1314             if (acc_levels > MAX_ACCURACY_LEVELS)
1315                 acc_levels = MAX_ACCURACY_LEVELS;
1316
1317             for (i = 0; i < acc_levels; ++i)
1318                 acc_lev[i] = stof(argv(i)) / 100.0;
1319         }
1320         // let know that acc_col[] needs to be loaded
1321         acc_col_x[0] = -1;
1322     }
1323
1324     HUD_Main(); // always run these functions for alpha checks
1325     HUD_DrawScoreboard();
1326
1327     if (scoreboard_active) // scoreboard/accuracy
1328     {
1329         HUD_Reset();
1330         // HUD_DrawScoreboard takes care of centerprint_start
1331     }
1332     else if (intermission == 2) // map voting screen
1333     {
1334         HUD_FinaleOverlay();
1335         HUD_Reset();
1336
1337         centerprint_start_x = 0;
1338         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1339     }
1340     else // hud
1341     {
1342         centerprint_start_x = 0;
1343         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1344     }
1345
1346         /*
1347         switch(hud)
1348         {
1349                 case HUD_SPIDERBOT:
1350                         CSQC_SPIDER_HUD();
1351                         break;
1352
1353                 case HUD_WAKIZASHI:
1354                         CSQC_WAKIZASHI_HUD();
1355                         break;
1356
1357         case HUD_BUMBLEBEE:
1358             CSQC_BUMBLE_HUD();
1359             break;
1360         }
1361         */
1362
1363     HUD_DrawCenterPrint();
1364
1365 }
1366
1367
1368 // following vectors must be global to allow seamless switching between camera modes
1369 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1370 void CSQC_Demo_Camera()
1371 {
1372         float speed, attenuation, dimensions;
1373         vector tmp, delta;
1374
1375         if( autocvar_camera_reset || !camera_mode )
1376         {
1377                 camera_offset = '0 0 0';
1378                 current_angles = '0 0 0';
1379                 camera_direction = '0 0 0';
1380                 camera_offset_z += 30;
1381                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1382                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1383                 current_origin = view_origin;
1384                 current_camera_offset  = camera_offset;
1385                 cvar_set("camera_reset", "0");
1386                 camera_mode = CAMERA_CHASE;
1387         }
1388
1389         // Camera angles
1390         if( camera_roll )
1391                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1392
1393         if(autocvar_camera_look_player)
1394         {
1395                 local vector dir;
1396                 local float n;
1397
1398                 dir = normalize(view_origin - current_position);
1399                 n = mouse_angles_z;
1400                 mouse_angles = vectoangles(dir);
1401                 mouse_angles_x = mouse_angles_x * -1;
1402                 mouse_angles_z = n;
1403         }
1404         else
1405         {
1406                 tmp = getmousepos() * 0.1;
1407                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1408                 {
1409                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1410                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1411                 }
1412         }
1413
1414         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1415         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1416         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1417         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1418
1419         // Fix difference when angles don't have the same sign
1420         delta = '0 0 0';
1421         if(mouse_angles_y < -60 && current_angles_y > 60)
1422                 delta = '0 360 0';
1423         if(mouse_angles_y > 60 && current_angles_y < -60)
1424                 delta = '0 -360 0';
1425
1426         if(autocvar_camera_look_player)
1427                 attenuation = autocvar_camera_look_attenuation;
1428         else
1429                 attenuation = autocvar_camera_speed_attenuation;
1430
1431         attenuation = 1 / max(1, attenuation);
1432         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1433
1434         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1435         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1436         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1437         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1438
1439         // Camera position
1440         tmp = '0 0 0';
1441         dimensions = 0;
1442
1443         if( camera_direction_x )
1444         {
1445                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1446                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1447                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1448                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1449                 ++dimensions;
1450         }
1451
1452         if( camera_direction_y )
1453         {
1454                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1455                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1456                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1457                 ++dimensions;
1458         }
1459
1460         if( camera_direction_z )
1461         {
1462                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1463                 ++dimensions;
1464         }
1465
1466         if(autocvar_camera_free)
1467                 speed = autocvar_camera_speed_free;
1468         else
1469                 speed = autocvar_camera_speed_chase;
1470
1471         if(dimensions)
1472         {
1473                 speed = speed * sqrt(1 / dimensions);
1474                 camera_offset += tmp * speed;
1475         }
1476
1477         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1478
1479         // Camera modes
1480         if( autocvar_camera_free )
1481         {
1482                 if ( camera_mode == CAMERA_CHASE )
1483                 {
1484                         current_camera_offset = current_origin + current_camera_offset;
1485                         camera_offset = current_origin + camera_offset;
1486                 }
1487
1488                 camera_mode = CAMERA_FREE;
1489                 current_position = current_camera_offset;
1490         }
1491         else
1492         {
1493                 if ( camera_mode == CAMERA_FREE )
1494                 {
1495                         current_origin = view_origin;
1496                         camera_offset = camera_offset - current_origin;
1497                         current_camera_offset = current_camera_offset - current_origin;
1498                 }
1499
1500                 camera_mode = CAMERA_CHASE;
1501
1502                 if(autocvar_camera_chase_smoothly)
1503                         current_origin += (view_origin - current_origin) * attenuation;
1504                 else
1505                         current_origin = view_origin;
1506
1507                 current_position = current_origin + current_camera_offset;
1508         }
1509
1510         R_SetView(VF_ANGLES, current_angles);
1511         R_SetView(VF_ORIGIN, current_position);
1512 }