qcsrc/client/View.qc

   1 #define spider_rocket_icon "gfx/vehicles/rocket_ico.tga"
   2 #define spider_rocket_targ "gfx/vehicles/target.tga"
   3 #define SPIDER_CROSS "textures/spiderbot/cross.tga"
   4 #define rkt_size 32
   5 #define rld_size_x 256
   6 #define rld_size_y 16
   7
   8 void CSQC_WAKIZASHI_HUD();
   9
  10 entity porto;
  11 vector polyline[16];
  12 float trace_dphitcontents;
  13 float trace_networkentity;
  14 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
  15 float DPCONTENTS_SOLID = 1; // blocks player movement
  16 float DPCONTENTS_BODY = 32; // blocks player movement
  17 float DPCONTENTS_CORPSE = 64; // blocks player movement
  18 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  19 void Porto_Draw()
  20 {
  21         vector p, dir, ang, q, nextdir;
  22         float idx, portal_number, portal1_idx;
  23
  24         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  25                 return;
  26         if(intermission == 1)
  27                 return;
  28         if(intermission == 2)
  29                 return;
  30         if (getstati(STAT_HEALTH) <= 0)
  31                 return;
  32
  33         dir = view_forward;
  34
  35         if(angles_held_status)
  36         {
  37                 makevectors(angles_held);
  38                 dir = v_forward;
  39         }
  40
  41         p = view_origin;
  42
  43         polyline[0] = p;
  44         idx = 1;
  45         portal_number = 0;
  46         nextdir = dir;
  47
  48         for(;;)
  49         {
  50                 dir = nextdir;
  51                 traceline(p, p + 65536 * dir, TRUE, porto);
  52                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  53                         return;
  54                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  55                 p = trace_endpos;
  56                 polyline[idx] = p;
  57                 ++idx;
  58                 if(idx >= 16)
  59                         return;
  60                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  61                         continue;
  62                 ++portal_number;
  63                 ang = vectoangles2(trace_plane_normal, dir);
  64                 ang_x = -ang_x;
  65                 makevectors(ang);
  66                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  67                         return;
  68                 if(portal_number == 1)
  69                         portal1_idx = idx;
  70                 if(portal_number >= 2)
  71                         break;
  72         }
  73
  74         while(idx >= 2)
  75         {
  76                 p = polyline[idx-2];
  77                 q = polyline[idx-1];
  78                 if(idx == 2)
  79                         p = p - view_up * 16;
  80                 if(idx-1 >= portal1_idx)
  81                 {
  82                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  83                 }
  84                 else
  85                 {
  86                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  87                 }
  88                 --idx;
  89         }
  90 }
  91
  92 /**
  93  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  94  *
  95  * TODO: Use a better solution where a common shared entitiy is used that contains
  96  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  97  * and STAT_FRAGLIMIT to be auto-sent)
  98  */
  99 void CheckForGamestartChange() {
 100         float startTime;
 101         startTime = getstatf(STAT_GAMESTARTTIME);
 102         if (previous_game_starttime != startTime) {
 103                 if ((time + 5.0) < startTime) {
 104                         //if connecting to server while restart was active don't always play prepareforbattle
 105                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
 106                 }
 107                 if (time < startTime) {
 108                         restartAnnouncer = spawn();
 109                         restartAnnouncer.think = restartAnnouncer_Think;
 110                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 111                 }
 112         }
 113         previous_game_starttime = startTime;
 114 }
 115
 116 void Porto_Init()
 117 {
 118         porto = spawn();
 119         porto.classname = "porto";
 120         porto.draw = Porto_Draw;
 121         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 122 }
 123
 124 float drawtime;
 125 float avgspeed;
 126 vector GetCurrentFov(float fov)
 127 {
 128         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 129
 130         zoomsensitivity = autocvar_cl_zoomsensitivity;
 131         zoomfactor = autocvar_cl_zoomfactor;
 132         if(zoomfactor < 1 || zoomfactor > 16)
 133                 zoomfactor = 2.5;
 134         zoomspeed = autocvar_cl_zoomspeed;
 135         if(zoomspeed >= 0)
 136                 if(zoomspeed < 0.5 || zoomspeed > 16)
 137                         zoomspeed = 3.5;
 138
 139         zoomdir = button_zoom;
 140         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 141                 zoomdir += button_attack2;
 142         if(spectatee_status > 0 || isdemo())
 143         {
 144                 if(spectatorbutton_zoom)
 145                         zoomdir = 0 + !zoomdir;
 146                 // do not even THINK about removing this 0
 147                 // _I_ know what I am doing
 148                 // fteqcc does not
 149         }
 150
 151         if(zoomdir)
 152                 zoomin_effect = 0;
 153
 154         if(zoomin_effect || camera_active)
 155         {
 156                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 189         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 190         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 191
 192         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 193
 194         float frustumx, frustumy, fovx, fovy;
 195         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 196         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 197         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 198         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 199
 200         return '1 0 0' * fovx + '0 1 0' * fovy;
 201 }
 202
 203 // this function must match W_SetupShot!
 204 float zoomscript_caught;
 205
 206 vector wcross_origin;
 207 float wcross_scale_prev, wcross_alpha_prev;
 208 vector wcross_color_prev;
 209 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 210 vector wcross_color_goal_prev;
 211 float wcross_changedonetime;
 212
 213 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 214 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 215 float wcross_name_changestarttime, wcross_name_changedonetime;
 216 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 217 entity trueaim;
 218 entity trueaim_rifle;
 219
 220 #define SHOTTYPE_HITTEAM 1
 221 #define SHOTTYPE_HITOBSTRUCTION 2
 222 #define SHOTTYPE_HITWORLD 3
 223 #define SHOTTYPE_HITENEMY 4
 224
 225 void TrueAim_Init()
 226 {
 227         trueaim = spawn();
 228         trueaim.classname = "trueaim";
 229         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 230         trueaim_rifle = spawn();
 231         trueaim_rifle.classname = "trueaim_rifle";
 232         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 233 }
 234
 235 float EnemyHitCheck()
 236 {
 237         float t;
 238         wcross_origin = project_3d_to_2d(trace_endpos);
 239         wcross_origin_z = 0;
 240         if(trace_networkentity < 1)
 241                 return SHOTTYPE_HITWORLD;
 242         if(trace_networkentity > maxclients)
 243                 return SHOTTYPE_HITWORLD;
 244         t = GetPlayerColor(trace_networkentity - 1);
 245         if(teamplay)
 246                 if(t == myteam)
 247                         return SHOTTYPE_HITTEAM;
 248         if(t == COLOR_SPECTATOR)
 249                 return SHOTTYPE_HITWORLD;
 250         return SHOTTYPE_HITENEMY;
 251 }
 252
 253 float TrueAimCheck()
 254 {
 255         float nudge = 1; // added to traceline target and subtracted from result
 256         vector vecs, trueaimpoint, w_shotorg;
 257         vector mi, ma, dv;
 258         float shottype;
 259         entity ta;
 260         float mv;
 261
 262         mi = ma = '0 0 0';
 263         ta = trueaim;
 264         mv = MOVE_NOMONSTERS;
 265
 266         switch(activeweapon)
 267         {
 268                 case WEP_TUBA: // no aim
 269                 case WEP_PORTO: // shoots from eye
 270                 case WEP_HOOK: // no trueaim
 271                 case WEP_GRENADE_LAUNCHER: // toss curve
 272                         return SHOTTYPE_HITWORLD;
 273                 case WEP_NEX:
 274                 case WEP_MINSTANEX:
 275                         mv = MOVE_NORMAL;
 276                         break;
 277                 case WEP_RIFLE:
 278                         ta = trueaim_rifle;
 279                         mv = MOVE_NORMAL;
 280                         if(zoomscript_caught)
 281                         {
 282                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 283                                 return EnemyHitCheck();
 284                         }
 285                         break;
 286                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 287                         mi = '-3 -3 -3';
 288                         ma = '3 3 3';
 289                         break;
 290                 case WEP_FIREBALL: // projectile has a size!
 291                         mi = '-16 -16 -16';
 292                         ma = '16 16 16';
 293                         break;
 294                 case WEP_SEEKER: // projectile has a size!
 295                         mi = '-2 -2 -2';
 296                         ma = '2 2 2';
 297                         break;
 298                 case WEP_ELECTRO: // projectile has a size!
 299                         mi = '0 0 -3';
 300                         ma = '0 0 -3';
 301                         break;
 302         }
 303
 304         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 305
 306         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 307         trueaimpoint = trace_endpos;
 308
 309         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 310                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 311
 312         if(vecs_x > 0)
 313                 vecs_y = -vecs_y;
 314         else
 315                 vecs = '0 0 0';
 316
 317         dv = view_right * vecs_y + view_up * vecs_z;
 318         w_shotorg = view_origin + dv;
 319
 320         // now move the vecs forward as much as requested if possible
 321         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 322         w_shotorg = trace_endpos - view_forward * nudge;
 323
 324         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 325         shottype = EnemyHitCheck();
 326         if(shottype != SHOTTYPE_HITWORLD)
 327                 return shottype;
 328
 329 #if 0
 330         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 331         // or rather, I know why, but see no fix
 332         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 333                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 334                 return SHOTTYPE_HITOBSTRUCTION;
 335 #endif
 336
 337         return SHOTTYPE_HITWORLD;
 338 }
 339
 340 void CSQC_common_hud(void);
 341
 342 void PostInit(void);
 343 void CSQC_Demo_Camera();
 344 float HUD_WouldDrawScoreboard();
 345 float view_set;
 346 float camera_mode;
 347 float reticle_type;
 348 string NextFrameCommand;
 349 void CSQC_SPIDER_HUD();
 350 void CSQC_RAPTOR_HUD();
 351
 352 vector freeze_pmove_org, freeze_input_angles;
 353 entity nightvision_noise, nightvision_noise2;
 354
 355 float pickup_crosshair_time, pickup_crosshair_size;
 356 float hit_time, typehit_time;
 357 float nextsound_hit_time, nextsound_typehit_time;
 358 float hitindication_crosshair_time, hitindication_crosshair_size;
 359 float use_nex_chargepool;
 360
 361 float myhealth, myhealth_prev;
 362 float myhealth_flash;
 363
 364 vector myhealth_gentlergb;
 365
 366 float contentavgalpha, liquidalpha_prev;
 367 vector liquidcolor_prev;
 368
 369 float eventchase_current_distance;
 370
 371 float checkfail[16];
 372
 373 void CSQC_UpdateView(float w, float h)
 374 {
 375         entity e;
 376         float fov;
 377         float f, i, j;
 378         vector v, vo;
 379         vector vf_size, vf_min;
 380         float a;
 381
 382         button_attack2 = (input_buttons & BUTTON_3);
 383         button_zoom = (input_buttons & BUTTON_4);
 384
 385 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 386         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 387         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 388         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 389         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 390         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 391         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 392
 393         vf_size = R_SetView3fv(VF_SIZE);
 394         vf_min = R_SetView3fv(VF_MIN);
 395         vid_width = vf_size_x;
 396         vid_height = vf_size_y;
 397
 398         vector reticle_pos, reticle_size;
 399         vector splash_pos, splash_size;
 400
 401         WaypointSprite_Load();
 402
 403         if(spectatee_status)
 404                 myteam = GetPlayerColor(spectatee_status - 1);
 405         else
 406                 myteam = GetPlayerColor(player_localentnum - 1);
 407
 408         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 409         vo = '0 0 1' * getstati(STAT_VIEWHEIGHT);
 410
 411         warpzone_fixview_origin = pmove_org + vo;
 412         warpzone_fixview_cl_viewangles = input_angles;
 413         warpzone_fixview_angles = view_angles;
 414         WarpZone_FixView();
 415         pmove_org = warpzone_fixview_origin - vo;
 416         input_angles = warpzone_fixview_cl_viewangles;
 417         view_angles = warpzone_fixview_angles;
 418
 419         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 420         {
 421                 pmove_org = freeze_pmove_org;
 422                 input_angles = view_angles = freeze_input_angles;
 423                 R_SetView(VF_ORIGIN, pmove_org + vo);
 424                 R_SetView(VF_ANGLES, view_angles);
 425                 //R_SetView(VF_CL_VIEWANGLES, input_angles);
 426         }
 427         freeze_pmove_org = pmove_org;
 428         freeze_input_angles = input_angles;
 429
 430         // event chase camera
 431         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 432         {
 433                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || (autocvar_cl_eventchase_intermission && intermission))
 434                 {
 435                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 436                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 437                         if(!autocvar_chase_active)
 438                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 439
 440                         // make the camera smooth back
 441                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 442                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 443                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 444                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 445
 446                         vector eventchase_target_origin;
 447                         makevectors(view_angles);
 448                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 449                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance;
 450
 451                         traceline(pmove_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 452                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 453                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 454                         eventchase_target_origin = pmove_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 455
 456                         R_SetView(VF_ORIGIN, eventchase_target_origin);
 457                         R_SetView(VF_ANGLES, view_angles);
 458                 }
 459                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 460                 {
 461                         cvar_set("chase_active", "0");
 462                         eventchase_current_distance = 0; // start from 0 next time
 463                 }
 464         }
 465
 466         // Render the Scene
 467         if(!intermission || !view_set || (intermission && autocvar_cl_eventchase_intermission))
 468         {
 469                 view_origin = pmove_org + vo;
 470                 view_angles = input_angles;
 471                 makevectors(view_angles);
 472                 view_forward = v_forward;
 473                 view_right = v_right;
 474                 view_up = v_up;
 475                 view_set = 1;
 476         }
 477
 478 #ifdef BLURTEST
 479         if(time > blurtest_time0 && time < blurtest_time1)
 480         {
 481                 float r, t;
 482
 483                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 484                 r = t * blurtest_radius;
 485                 f = 1 / pow(t, blurtest_power) - 1;
 486
 487                 cvar_set("r_glsl_postprocess", "1");
 488                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 489         }
 490         else
 491         {
 492                 cvar_set("r_glsl_postprocess", "0");
 493                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 494         }
 495 #endif
 496
 497         TargetMusic_Advance();
 498         Fog_Force();
 499
 500         drawframetime = max(0.000001, time - drawtime);
 501         drawtime = time;
 502
 503         // watch for gametype changes here...
 504         // in ParseStuffCMD the cmd isn't executed yet :/
 505         // might even be better to add the gametype to TE_CSQC_INIT...?
 506         if(!postinit)
 507                 PostInit();
 508
 509         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 510                 if(calledhooks & HOOK_START)
 511                 {
 512                         localcmd("\ncl_hook_gameend\n");
 513                         calledhooks |= HOOK_END;
 514                 }
 515
 516         CheckForGamestartChange();
 517         serverAnnouncer();
 518         maptimeAnnouncer();
 519         carrierAnnouncer();
 520
 521         fov = autocvar_fov;
 522         if(fov <= 59.5)
 523         {
 524                 if(!zoomscript_caught)
 525                 {
 526                         localcmd("+button9\n");
 527                         zoomscript_caught = 1;
 528                 }
 529         }
 530         else
 531         {
 532                 if(zoomscript_caught)
 533                 {
 534                         localcmd("-button9\n");
 535                         zoomscript_caught = 0;
 536                 }
 537         }
 538
 539         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 540         activeweapon = getstati(STAT_SWITCHWEAPON);
 541         f = (serverflags & SERVERFLAG_TEAMPLAY);
 542         if(f != teamplay)
 543         {
 544                 teamplay = f;
 545                 HUD_InitScores();
 546         }
 547
 548         if(last_weapon != activeweapon) {
 549                 weapontime = time;
 550                 last_weapon = activeweapon;
 551
 552                 e = get_weaponinfo(activeweapon);
 553                 if(e.netname != "")
 554                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 555                 else
 556                         localcmd("\ncl_hook_activeweapon none\n");
 557         }
 558
 559         // ALWAYS Clear Current Scene First
 560         R_ClearScene();
 561
 562         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 563         R_SetView(VF_SIZE, vf_size);
 564         R_SetView(VF_MIN, vf_min);
 565
 566         // Assign Standard Viewflags
 567         // Draw the World (and sky)
 568         R_SetView(VF_DRAWWORLD, 1);
 569
 570         // Set the console size vars
 571         vid_conwidth = autocvar_vid_conwidth;
 572         vid_conheight = autocvar_vid_conheight;
 573         vid_pixelheight = autocvar_vid_pixelheight;
 574
 575         R_SetView(VF_FOV, GetCurrentFov(fov));
 576
 577         // Camera for demo playback
 578         if(camera_active)
 579         {
 580                 if(autocvar_camera_enable)
 581                         CSQC_Demo_Camera();
 582                 else
 583                 {
 584                         cvar_set("chase_active", ftos(chase_active_backup));
 585                         cvar_set("cl_demo_mousegrab", "0");
 586                         camera_active = FALSE;
 587                 }
 588         }
 589 #ifdef CAMERATEST
 590         else if(autocvar_camera_enable)
 591 #else
 592         else if(autocvar_camera_enable && isdemo())
 593 #endif
 594         {
 595                 // Enable required Darkplaces cvars
 596                 chase_active_backup = autocvar_chase_active;
 597                 cvar_set("chase_active", "2");
 598                 cvar_set("cl_demo_mousegrab", "1");
 599                 camera_active = TRUE;
 600                 camera_mode = FALSE;
 601         }
 602
 603         // Draw the Crosshair
 604         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 605
 606         // Draw the Engine Status Bar (the default Quake HUD)
 607         R_SetView(VF_DRAWENGINEHUD, 0);
 608
 609         // Update the mouse position
 610         /*
 611            mousepos_x = vid_conwidth;
 612            mousepos_y = vid_conheight;
 613            mousepos = mousepos*0.5 + getmousepos();
 614          */
 615
 616         e = self;
 617         for(self = world; (self = nextent(self)); )
 618                 if(self.draw)
 619                         self.draw();
 620         self = e;
 621
 622         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 623         R_RenderScene();
 624
 625         // now switch to 2D drawing mode by calling a 2D drawing function
 626         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 627         // next R_RenderScene call
 628         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 629
 630         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 631         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 632         {
 633                 // apply night vision effect
 634                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 635
 636                 if(!nightvision_noise)
 637                 {
 638                         nightvision_noise = spawn();
 639                         nightvision_noise.classname = "nightvision_noise";
 640                 }
 641                 if(!nightvision_noise2)
 642                 {
 643                         nightvision_noise2 = spawn();
 644                         nightvision_noise2.classname = "nightvision_noise2";
 645                 }
 646
 647                 // color tint in yellow
 648                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 649
 650                 // draw BG
 651                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 652                 rgb = '1 1 1';
 653                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 654                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 655                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 656                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 657                 tc_11 = tc_01 + tc_10 - tc_00;
 658                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 659                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 660                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 661                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 662                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 663                 R_EndPolygon();
 664
 665                 // draw FG
 666                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 667                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 668                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 669                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 670                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 671                 tc_11 = tc_01 + tc_10 - tc_00;
 672                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 673                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 674                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 675                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 676                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 677                 R_EndPolygon();
 678         }
 679
 680         // Draw the aiming reticle for weapons that use it
 681         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 682         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 683         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 684         if(spectatee_status || getstati(STAT_HEALTH) <= 0)
 685                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 686         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 687                 reticle_type = 2; // nex zoom
 688         else if(button_zoom || zoomscript_caught)
 689                 reticle_type = 1; // normal zoom
 690         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 691                 reticle_type = 2; // nex zoom
 692
 693         if (reticle_type)
 694         {
 695                 if(autocvar_cl_reticle_stretch)
 696                 {
 697                         reticle_size_x = vid_conwidth;
 698                         reticle_size_y = vid_conheight;
 699                         reticle_pos_x = 0;
 700                         reticle_pos_y = 0;
 701                 }
 702                 else
 703                 {
 704                         reticle_size_x = max(vid_conwidth, vid_conheight);
 705                         reticle_size_y = max(vid_conwidth, vid_conheight);
 706                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 707                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 708                 }
 709
 710                 f = current_zoomfraction;
 711                 if(zoomscript_caught)
 712                         f = 1;
 713                 if(autocvar_cl_reticle_item_normal)
 714                 {
 715                         if(reticle_type == 1 && f)
 716                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 717                 }
 718                 if(autocvar_cl_reticle_item_nex)
 719                 {
 720                         if(reticle_type == 2 && f)
 721                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 722                 }
 723         }
 724
 725
 726         // improved polyblend
 727         vector rgb;
 728         if(autocvar_hud_contents)
 729         {
 730                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 731                 vector liquidcolor;
 732
 733                 switch(pointcontents(view_origin))
 734                 {
 735                         case CONTENT_WATER:
 736                                 liquidalpha = autocvar_hud_contents_water_alpha;
 737                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 738                                 incontent = 1;
 739                                 break;
 740
 741                         case CONTENT_LAVA:
 742                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 743                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 744                                 incontent = 1;
 745                                 break;
 746
 747                         case CONTENT_SLIME:
 748                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 749                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 750                                 incontent = 1;
 751                                 break;
 752
 753                         default:
 754                                 liquidalpha = 0;
 755                                 liquidcolor = '0 0 0';
 756                                 incontent = 0;
 757                                 break;
 758                 }
 759
 760                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 761                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 762                         contentfadetime = autocvar_hud_contents_fadeintime;
 763                         liquidalpha_prev = liquidalpha;
 764                         liquidcolor_prev = liquidcolor;
 765                 }
 766                 else
 767                         contentfadetime = autocvar_hud_contents_fadeouttime;
 768
 769                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 770                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 771
 772                 if(contentavgalpha)
 773                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 774         }
 775
 776         if(autocvar_hud_damage && !autocvar_chase_active)
 777         {
 778                 splash_size_x = max(vid_conwidth, vid_conheight);
 779                 splash_size_y = max(vid_conwidth, vid_conheight);
 780                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 781                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 782
 783                 float myhealth_flash_temp;
 784                 myhealth = getstati(STAT_HEALTH);
 785
 786                 // fade out
 787                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 788                 // add new damage
 789                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 790
 791                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 792                 pain_threshold = autocvar_hud_damage_pain_threshold;
 793                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 794                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 795
 796                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 797                 {
 798                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 799                 }
 800
 801                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 802
 803                 if(myhealth_prev < 1)
 804                 {
 805                         if(myhealth >= 1)
 806                         {
 807                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 808                                 myhealth_flash_temp = 0;
 809                         }
 810                         else
 811                         {
 812                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 813                         }
 814                 }
 815
 816                 if(spectatee_status == -1 || intermission)
 817                 {
 818                         myhealth_flash = 0; // observing, or match ended
 819                         myhealth_flash_temp = 0;
 820                 }
 821
 822                 myhealth_prev = myhealth;
 823
 824                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 825                 {
 826                         if(autocvar_cl_gentle_damage == 2)
 827                         {
 828                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 829                                 {
 830                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 831                                 }
 832                         }
 833                         else
 834                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 835
 836                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 837                 }
 838                 else
 839                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 840         }
 841
 842         // Draw the mouse cursor
 843         // NOTE: drawpic must happen after R_RenderScene for some reason
 844         //drawpic(getmousepos(), "gfx/cursor.tga", '11 14 0', '1 1 1', 1, 0);
 845         //drawstring('50 50', ftos(game), '10 10 0', '1 1 1', 1, 0);
 846         //self = edict_num(player_localnum);
 847         //drawstring('0 0', vtos(pmove_org), '8 8 0', '1 1 1', 1, 0);
 848         //drawstring('0 8', strcat("ORG: ", vtos(self.origin), " state: ", ftos(self.ctf_state), " HP: ", ftos(self.health)), '8 8 0', '1 1 1', 1, 0);
 849         // as long as the ctf part isn't in, this is useless
 850         if(menu_visible)
 851                 menu_show();
 852
 853         /*if(gametype == GAME_CTF)
 854           {
 855           ctf_view();
 856           } else */
 857
 858         // draw 2D entities
 859         e = self;
 860         for(self = world; (self = nextent(self)); )
 861                 if(self.draw2d)
 862                         self.draw2d();
 863         self = e;
 864         Draw_ShowNames_All();
 865
 866         scoreboard_active = HUD_WouldDrawScoreboard();
 867
 868         hit_time = getstatf(STAT_HIT_TIME);
 869         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 870         {
 871                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 872                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 873         }
 874         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 875         if(typehit_time > nextsound_typehit_time)
 876         {
 877                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 878                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 879         }
 880
 881         float hud;
 882         hud = getstati(STAT_HUD);
 883         if(hud == HUD_SPIDERBOT)
 884                 CSQC_SPIDER_HUD();
 885         else if(hud == HUD_WAKIZASHI)
 886         CSQC_WAKIZASHI_HUD();
 887     else if(hud == HUD_RAPTOR)
 888         CSQC_RAPTOR_HUD();
 889         else
 890         {
 891                 if(gametype == GAME_FREEZETAG)
 892                 {
 893                         if(getstati(STAT_FROZEN))
 894                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 895                         if(getstatf(STAT_REVIVE_PROGRESS))
 896                         {
 897                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 898                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 899                         }
 900                 }
 901
 902                 if(autocvar_r_letterbox == 0)
 903                         if(autocvar_viewsize < 120)
 904                                 CSQC_common_hud();
 905
 906                 // crosshair goes VERY LAST
 907                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1) {
 908                         string wcross_style;
 909                         float wcross_alpha, wcross_resolution;
 910                         wcross_style = autocvar_crosshair;
 911                         if (wcross_style == "0")
 912                                 return;
 913                         wcross_resolution = autocvar_crosshair_size;
 914                         if (wcross_resolution == 0)
 915                                 return;
 916                         wcross_alpha = autocvar_crosshair_alpha;
 917                         if (wcross_alpha == 0)
 918                                 return;
 919
 920                         // TrueAim check
 921                         float shottype;
 922
 923                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 924                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 925                         wcross_origin_z = 0;
 926                         if(autocvar_crosshair_hittest)
 927                         {
 928                                 vector wcross_oldorigin;
 929                                 wcross_oldorigin = wcross_origin;
 930                                 shottype = TrueAimCheck();
 931                                 if(shottype == SHOTTYPE_HITWORLD)
 932                                 {
 933                                         v = wcross_origin - wcross_oldorigin;
 934                                         v_x /= vid_conwidth;
 935                                         v_y /= vid_conheight;
 936                                         if(vlen(v) > 0.01)
 937                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
 938                                 }
 939                                 if(!autocvar_crosshair_hittest_showimpact)
 940                                         wcross_origin = wcross_oldorigin;
 941                         }
 942                         else
 943                                 shottype = SHOTTYPE_HITWORLD;
 944
 945                         vector wcross_color, wcross_size;
 946                         string wcross_wep, wcross_name;
 947                         float wcross_scale, wcross_blur;
 948
 949                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
 950                                 e = get_weaponinfo(activeweapon);
 951                                 if (e && e.netname != "")
 952                                 {
 953                                         wcross_wep = e.netname;
 954                                         if(autocvar_crosshair_per_weapon)
 955                                         {
 956                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 957                                                 if (wcross_resolution == 0)
 958                                                         return;
 959                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
 960                                                 if (wcross_alpha == 0)
 961                                                         return;
 962
 963                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 964                                                 if(wcross_style == "" || wcross_style == "0")
 965                                                         wcross_style = wcross_wep;
 966                                         }
 967                                 }
 968                         }
 969                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
 970                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
 971                         else if(autocvar_crosshair_color_by_health)
 972                         {
 973                                 local float x = getstati(STAT_HEALTH);
 974
 975                                 //x = red
 976                                 //y = green
 977                                 //z = blue
 978
 979                                 wcross_color_z = 0;
 980
 981                                 if(x > 200)
 982                                 {
 983                                         wcross_color_x = 0;
 984                                         wcross_color_y = 1;
 985                                 }
 986                                 else if(x > 150)
 987                                 {
 988                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
 989                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
 990                                 }
 991                                 else if(x > 100)
 992                                 {
 993                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
 994                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
 995                                         wcross_color_z = 1 - (x-100)*0.02;
 996                                 }
 997                                 else if(x > 50)
 998                                 {
 999                                         wcross_color_x = 1;
1000                                         wcross_color_y = 1;
1001                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1002                                 }
1003                                 else if(x > 20)
1004                                 {
1005                                         wcross_color_x = 1;
1006                                         wcross_color_y = (x-20)*90/27/100;
1007                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1008                                 }
1009                                 else
1010                                 {
1011                                         wcross_color_x = 1;
1012                                         wcross_color_y = 0;
1013                                 }
1014                         }
1015                         else
1016                                 wcross_color = stov(autocvar_crosshair_color);
1017
1018                         wcross_name = strcat("gfx/crosshair", wcross_style);
1019
1020                         if(autocvar_crosshair_effect_scalefade)
1021                         {
1022                                 wcross_scale = wcross_resolution;
1023                                 wcross_resolution = 1;
1024                         }
1025                         else
1026                         {
1027                                 wcross_scale = 1;
1028                         }
1029
1030                         if(autocvar_crosshair_pickup)
1031                         {
1032                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1033                                 {
1034                                         pickup_crosshair_size = 1;
1035                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1036                                 }
1037
1038                                 if(pickup_crosshair_size > 0)
1039                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1040                                 else
1041                                         pickup_crosshair_size = 0;
1042
1043                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1044                         }
1045
1046                         vector hitindication_color;
1047                         if(autocvar_crosshair_hitindication)
1048                         {
1049                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1050                                 if(hitindication_crosshair_time < hit_time)
1051                                 {
1052                                         hitindication_crosshair_size = 1;
1053                                         hitindication_crosshair_time = hit_time;
1054                                 }
1055
1056                                 if(hitindication_crosshair_size > 0)
1057                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1058                                 else
1059                                         hitindication_crosshair_size = 0;
1060
1061                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1062                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1063                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1064                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1065                         }
1066
1067                         if(shottype == SHOTTYPE_HITENEMY)
1068                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1069                         if(shottype == SHOTTYPE_HITTEAM)
1070                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1071
1072                         f = autocvar_crosshair_effect_speed;
1073                         if(f < 0)
1074                                 f *= -2 * g_weaponswitchdelay;
1075                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1076                         {
1077                                 wcross_changedonetime = time + f;
1078                         }
1079                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1080                         {
1081                                 wcross_name_changestarttime = time;
1082                                 wcross_name_changedonetime = time + f;
1083                                 if(wcross_name_goal_prev_prev)
1084                                         strunzone(wcross_name_goal_prev_prev);
1085                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1086                                 wcross_name_goal_prev = strzone(wcross_name);
1087                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1088                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1089                                 wcross_resolution_goal_prev = wcross_resolution;
1090                         }
1091
1092                         wcross_scale_goal_prev = wcross_scale;
1093                         wcross_alpha_goal_prev = wcross_alpha;
1094                         wcross_color_goal_prev = wcross_color;
1095
1096                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1097                         {
1098                                 wcross_blur = 1;
1099                                 wcross_alpha *= 0.75;
1100                         }
1101                         else
1102                                 wcross_blur = 0;
1103                         // *_prev is at time-frametime
1104                         // * is at wcross_changedonetime+f
1105                         // what do we have at time?
1106                         if(time < wcross_changedonetime)
1107                         {
1108                                 f = frametime / (wcross_changedonetime - time + frametime);
1109                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1110                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1111                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1112                         }
1113
1114                         wcross_scale_prev = wcross_scale;
1115                         wcross_alpha_prev = wcross_alpha;
1116                         wcross_color_prev = wcross_color;
1117
1118                         wcross_scale *= 1 - autocvar__menu_alpha;
1119                         wcross_alpha *= 1 - autocvar__menu_alpha;
1120                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1121
1122                         // crosshair rings for weapon stats
1123                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1124                         {
1125                                 // declarations and stats
1126                                 float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1127                                 string ring_image, ring_inner_image;
1128                                 vector ring_rgb, ring_inner_rgb;
1129
1130                                 ring_scale = autocvar_crosshair_ring_size;
1131
1132                                 float weapon_clipload, weapon_clipsize;
1133                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1134                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1135
1136                                 float nex_charge, nex_chargepool;
1137                                 nex_charge = getstatf(STAT_NEX_CHARGE);
1138                                 nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1139
1140                                 if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1141                                         nex_charge_movingavg = nex_charge;
1142
1143
1144                                 // handle the values
1145                                 if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1146                                 {
1147                                         if (nex_chargepool || use_nex_chargepool) {
1148                                                 use_nex_chargepool = 1;
1149                                                 ring_inner_value = nex_chargepool;
1150                                         } else {
1151                                                 nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1152                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1153                                         }
1154
1155                                         ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1156                                         ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1157                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1158
1159                                         // draw the outer ring to show the current charge of the weapon
1160                                         ring_value = nex_charge;
1161                                         ring_alpha = autocvar_crosshair_ring_nex_alpha;
1162                                         ring_rgb = wcross_color;
1163                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1164                                 }
1165                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1166                                 {
1167                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1168                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1169                                         ring_rgb = wcross_color;
1170                                         ring_image = "gfx/crosshair_ring.tga";
1171                                 }
1172                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1173                                 {
1174                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1175                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1176                                         ring_rgb = wcross_color;
1177                                         ring_image = "gfx/crosshair_ring.tga";
1178                                 }
1179
1180                                 if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1181                                 {
1182                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1183                                         ring_scale = autocvar_crosshair_ring_reload_size;
1184                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1185                                         ring_rgb = wcross_color;
1186
1187                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1188                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1189                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1190                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1191                                         else
1192                                                 ring_image = "gfx/crosshair_ring.tga";
1193                                 }
1194
1195                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1196                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1197
1198                                 if (ring_value)
1199                                         DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1200                         }
1201
1202 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1203                         do \
1204                         { \
1205                                 if(wcross_blur > 0) \
1206                                 { \
1207                                         for(i = -2; i <= 2; ++i) \
1208                                                 for(j = -2; j <= 2; ++j) \
1209                                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1210                                 } \
1211                                 else \
1212                                 { \
1213                                         M(0,0,sz,wcross_name,wcross_alpha); \
1214                                 } \
1215                         } \
1216                         while(0)
1217
1218 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1219                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1220
1221 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1222                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1223
1224                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1225                         {
1226                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1227                                 wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1228                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1229                                 f = 1 - f;
1230                         }
1231                         else
1232                         {
1233                                 f = 1;
1234                         }
1235
1236                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1237                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1238
1239                         if(autocvar_crosshair_dot)
1240             {
1241                 vector wcross_color_old;
1242                 wcross_color_old = wcross_color;
1243                 if(autocvar_crosshair_dot_color != "0")
1244                     wcross_color = stov(autocvar_crosshair_dot_color);
1245                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1246                 wcross_color = wcross_color_old;
1247             }
1248
1249                         wcross_name_alpha_goal_prev = f;
1250                 }
1251                 else
1252                 {
1253                         wcross_scale_prev = 0;
1254                         wcross_alpha_prev = 0;
1255                         wcross_scale_goal_prev = 0;
1256                         wcross_alpha_goal_prev = 0;
1257                         wcross_changedonetime = 0;
1258                         if(wcross_name_goal_prev)
1259                                 strunzone(wcross_name_goal_prev);
1260                         wcross_name_goal_prev = string_null;
1261                         if(wcross_name_goal_prev_prev)
1262                                 strunzone(wcross_name_goal_prev_prev);
1263                         wcross_name_goal_prev_prev = string_null;
1264                         wcross_name_changestarttime = 0;
1265                         wcross_name_changedonetime = 0;
1266                         wcross_name_alpha_goal_prev = 0;
1267                         wcross_name_alpha_goal_prev_prev = 0;
1268                         wcross_resolution_goal_prev = 0;
1269                         wcross_resolution_goal_prev_prev = 0;
1270                 }
1271         }
1272
1273         if(NextFrameCommand)
1274         {
1275                 localcmd("\n", NextFrameCommand, "\n");
1276                 NextFrameCommand = string_null;
1277         }
1278
1279         // we must do this check AFTER a frame was rendered, or it won't work
1280         if(cs_project_is_b0rked == 0)
1281         {
1282                 string w0, h0;
1283                 w0 = ftos(autocvar_vid_conwidth);
1284                 h0 = ftos(autocvar_vid_conheight);
1285                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1286                 //R_SetView(VF_FOV, '90 90 0');
1287                 R_SetView(VF_ORIGIN, '0 0 0');
1288                 R_SetView(VF_ANGLES, '0 0 0');
1289                 R_SetView(VF_PERSPECTIVE, 1);
1290                 makevectors('0 0 0');
1291                 vector v1, v2;
1292                 cvar_set("vid_conwidth", "800");
1293                 cvar_set("vid_conheight", "600");
1294                 v1 = cs_project(v_forward);
1295                 cvar_set("vid_conwidth", "640");
1296                 cvar_set("vid_conheight", "480");
1297                 v2 = cs_project(v_forward);
1298                 if(v1 == v2)
1299                         cs_project_is_b0rked = 1;
1300                 else
1301                         cs_project_is_b0rked = -1;
1302                 cvar_set("vid_conwidth", w0);
1303                 cvar_set("vid_conheight", h0);
1304         }
1305
1306         if(autocvar__hud_configure)
1307                 HUD_Panel_Mouse();
1308
1309         // let's reset the view back to normal for the end
1310         R_SetView(VF_MIN, '0 0 0');
1311         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1312 }
1313
1314 #define spider_h "gfx/vehicles/hud_bg.tga"
1315 #define spider_b "gfx/vehicles/sbot.tga"
1316 #define spider_r "gfx/vehicles/sbot_rpods.tga"
1317 #define spider_g "gfx/vehicles/sbot_mguns.tga"
1318 #define spider_s "gfx/vehicles/shiled.tga"
1319 #define spider_a1 "gfx/hud/sb_rocket.tga"
1320 #define spider_a2 "gfx/sb_bullets.tga"
1321
1322 void CSQC_SPIDER_HUD()
1323 {
1324         float rockets, reload, heat, hp, shield;
1325         vector picsize, hudloc;
1326
1327     // Fetch health & ammo stats
1328     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1329         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1330         heat    = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 2);
1331         rockets =     getstati(STAT_VEHICLESTAT_AMMO2);
1332         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD2), 1);
1333
1334     // Draw the crosshairs
1335     picsize = drawgetimagesize(SPIDER_CROSS);
1336     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1337     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1338     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1339
1340     hudloc_y =  4;
1341     hudloc_x = 4;
1342
1343     picsize = drawgetimagesize(spider_h) * 0.5;
1344     drawpic(hudloc, spider_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1345
1346     picsize = drawgetimagesize(spider_a2) * 0.5;
1347     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1348
1349     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1350     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1351     drawstring(hudloc + '136 102  0', strcat(ftos(100 - rint(heat * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1352
1353     picsize = drawgetimagesize(spider_a1) * 0.85;
1354     if(rockets == 9)
1355     {
1356         drawpic(hudloc + '132 54  0', spider_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1357         drawstring(hudloc + '179 69 0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1358     }
1359     else
1360     {
1361         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1362         drawstring(hudloc + '179 69  0', strcat(ftos(9 - rockets), "/8"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1363     }
1364
1365     picsize = drawgetimagesize(spider_b) * 0.5;
1366     hudloc_y = 10.5;
1367     hudloc_x = 10.5;
1368
1369     drawpic(hudloc, spider_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1370     drawpic(hudloc, spider_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1371     drawpic(hudloc, spider_r, picsize, '1 1 1' * reload + '1 0 0' * (1 - reload), 1, DRAWFLAG_NORMAL);
1372     drawpic(hudloc, spider_g, picsize, '1 1 1' * (1 - heat) + '1 0 0' *  heat, 1, DRAWFLAG_NORMAL);
1373
1374
1375         /*
1376         // Draw health bar
1377         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1378         p = p + '0 1 0' * vid_conheight - '0 32 0';
1379         //pp = ('0 1 0' * hp) + ('1 0 0' * (1-hp));
1380         drawfill(p, '256 0 0' * shield + '0 8 0' , '0.5 0.5 1', 0.75, DRAWFLAG_NORMAL);
1381         p_y += 8;
1382         drawfill(p, '256 0 0' * hp + '0 8 0' , '0 1 0', 0.75, DRAWFLAG_NORMAL);
1383         p_x += 256 * hp;
1384         drawfill(p, '256 0 0' * (1-hp) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1385
1386         // Draw minigun heat indicator
1387         p = '0.5 0 0' * (vid_conwidth - 256);
1388         p = p + '0 1 0' * vid_conheight - '0 34  0';
1389         drawfill(p, '256 0 0' * (1-heat) + '0 2 0' ,'0 0 1', 0.5, DRAWFLAG_NORMAL);
1390         p_x += 256 * (1-heat);
1391         drawfill(p, '256 0 0' * heat  + '0 2 0' , '1 0 0', 0.5, DRAWFLAG_NORMAL);
1392
1393
1394         // Draw rocket icons for loaded/empty tubes.
1395         pp = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1396         pp += '0 1 0' * vid_conheight - '0 64 0';
1397         for(i = 0; i < 8; ++i)
1398         {
1399                 p = pp + '1 0 0' * (rkt_size * i);
1400                 if(rockets == 8)
1401                 {
1402                         if(floor(reload * 8) == i)
1403                         {
1404                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 0 0' + '0 1 0' * ((reload*8)-i), 0.75 , DRAWFLAG_NORMAL);
1405                         }
1406                         else if(i < reload * 8)
1407                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '1 1 0', 0.75 , DRAWFLAG_NORMAL);
1408                         else
1409                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0.5 0.5 0.5', 0.75, DRAWFLAG_NORMAL);
1410                 }
1411                 else
1412                 {
1413                         if(i < rockets)
1414                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 0 0', 0.25, DRAWFLAG_NORMAL);
1415                         else
1416                                 drawpic(p, spider_rocket_icon, '1 1 0' * rkt_size, '0 1 0' * reload, 0.75, DRAWFLAG_NORMAL);
1417                 }
1418         }
1419         */
1420
1421         if (scoreboard_showscores)
1422         {
1423                 HUD_DrawScoreboard();
1424                 HUD_DrawCenterPrint();
1425         }
1426
1427 }
1428
1429 #define raptor_h "gfx/vehicles/hud_bg.tga"
1430 #define raptor_b "gfx/vehicles/raptor.tga"
1431 #define raptor_g1 "gfx/vehicles/raptor_guns.tga"
1432 #define raptor_g2 "gfx/vehicles/raptor_bombs.tga"
1433 #define raptor_s "gfx/vehicles/shiled.tga"
1434
1435 void CSQC_RAPTOR_HUD()
1436 {
1437         float reload, hp, shield, energy;
1438         vector picsize, hudloc;
1439
1440     // Fetch health & ammo stats
1441     hp      = bound(0,getstatf(STAT_VEHICLESTAT_HEALTH), 1);
1442         shield  = bound(0,getstatf(STAT_VEHICLESTAT_SHIELD), 1);
1443         reload  = min(getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1444         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1445
1446     // Draw the crosshairs
1447     picsize = drawgetimagesize(SPIDER_CROSS);
1448     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1449     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1450     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1451
1452     hudloc_y =  4;
1453     hudloc_x = 4;
1454
1455     picsize = drawgetimagesize(raptor_h) * 0.5;
1456     drawpic(hudloc, raptor_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1457
1458     picsize = drawgetimagesize(spider_a2) * 0.5;
1459     drawpic(hudloc + '120 96  0', spider_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1460
1461     drawstring(hudloc + '145 19  0', strcat(ftos(rint(hp * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1462     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1463     drawstring(hudloc + '136 102 0', strcat(ftos(rint(energy * 100)), "%"),'15 15 0','0.5 0.5 1', 1, DRAWFLAG_NORMAL);
1464
1465
1466     picsize = drawgetimagesize(spider_a1) * 0.85;
1467     if(reload == 1)
1468     {
1469         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1470         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 1 0', 0.5, DRAWFLAG_NORMAL);
1471     }
1472     else
1473     {
1474         drawpic(hudloc + '132 54  0', spider_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1475         drawstring(hudloc + '179 69  0', strcat(ftos(rint(reload * 100)), "%"),'14 14 0','0 0 1', 1, DRAWFLAG_NORMAL);
1476     }
1477
1478     picsize = drawgetimagesize(raptor_b) * 0.5;
1479     hudloc_y = 10.5;
1480     hudloc_x = 10.5;
1481
1482     drawpic(hudloc, raptor_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1483     drawpic(hudloc, raptor_b, picsize, '0 1 0' * hp + '1 0 0' * (1 - hp), 1, DRAWFLAG_NORMAL);
1484     drawpic(hudloc, raptor_g1, picsize, '1 1 1' * energy + '1 0 0' * (1 - energy), 1, DRAWFLAG_NORMAL);
1485     drawpic(hudloc, raptor_g2, picsize, '1 1 1' * reload + '1 0 0' *  (1 - reload), 1, DRAWFLAG_NORMAL);
1486
1487
1488         if (scoreboard_showscores)
1489         {
1490                 HUD_DrawScoreboard();
1491                 HUD_DrawCenterPrint();
1492         }
1493
1494 }
1495
1496 #define waki_h "gfx/vehicles/hud_bg.tga"
1497 #define waki_b "gfx/vehicles/waki.tga"
1498 #define waki_e "gfx/vehicles/waki_e.tga"
1499 #define waki_g "gfx/vehicles/waki_guns.tga"
1500 #define waki_r "gfx/vehicles/waki_rockets.tga"
1501 #define waki_s "gfx/vehicles/shiled.tga"
1502
1503 #define waki_a1 "gfx/hud/sb_rocket.tga"
1504 #define waki_a2 "gfx/sb_cells.tga"
1505
1506 void CSQC_WAKIZASHI_HUD()
1507 {
1508         // 0--1 floats. 1 = 100%, 0.6 = 50%.
1509         float health, shield, energy, rockets;
1510         vector picsize, hudloc;
1511
1512     picsize = drawgetimagesize(SPIDER_CROSS);
1513     picsize_x *= autocvar_cl_vehicle_spiderbot_cross_size;
1514     picsize_y *= autocvar_cl_vehicle_spiderbot_cross_size;
1515     drawpic('0.5 0 0' * (vid_conwidth - picsize_x) + '0 0.5 0' * (vid_conheight - picsize_y), SPIDER_CROSS, picsize, '1 1 1', autocvar_cl_vehicle_spiderbot_cross_alpha, DRAWFLAG_NORMAL);
1516
1517 /*
1518 const float STAT_VEHICLESTAT_HEALTH  = 60;
1519 const float STAT_VEHICLESTAT_SHIELD  = 61;
1520 const float STAT_VEHICLESTAT_ENERGY  = 62;
1521 const float STAT_VEHICLESTAT_AMMO1   = 63;
1522 const float STAT_VEHICLESTAT_RELAOD1 = 64;
1523 const float STAT_VEHICLESTAT_AMMO2   = 65;
1524 const float STAT_VEHICLESTAT_RELOAD2 = 66;
1525 */
1526     health  = min(getstatf(STAT_VEHICLESTAT_HEALTH),  1);
1527         shield  = min(getstatf(STAT_VEHICLESTAT_SHIELD),  1);
1528         energy  = min(getstatf(STAT_VEHICLESTAT_ENERGY),  1);
1529         rockets = bound(0,getstatf(STAT_VEHICLESTAT_RELOAD1), 1);
1530
1531     hudloc_y =  4;
1532     hudloc_x = 4;
1533
1534     picsize = drawgetimagesize(waki_h) * 0.5;
1535     drawpic(hudloc, waki_h, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1536
1537     picsize = drawgetimagesize(waki_a2) * 0.7;
1538     drawpic(hudloc + '116 92  0', waki_a2, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1539
1540
1541     drawstring(hudloc + '145 19  0', strcat(ftos(rint(health * 100)), "%"),'15 15 0','0 1 0', 1, DRAWFLAG_NORMAL);
1542     drawstring(hudloc + '175 34  0', strcat(ftos(rint(shield * 100)), "%"),'15 15 0','0 0 1', 1, DRAWFLAG_NORMAL);
1543
1544     drawstring(hudloc + '136 102  0', strcat(ftos(rint(energy * 100)), "%"),'14 14 0','1 1 1', 1, DRAWFLAG_NORMAL);
1545
1546     picsize = drawgetimagesize(waki_a1) * 0.75;
1547     if(rockets == 1)
1548     {
1549         drawpic(hudloc + '140 55  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1550         drawpic(hudloc + '144 59  0', waki_a1, picsize, '1 1 1', 1, DRAWFLAG_NORMAL);
1551     }
1552     else
1553     {
1554         drawpic(hudloc + '140 55  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1555         drawpic(hudloc + '144 59  0', waki_a1, picsize, '-1 -1 -1', 1, DRAWFLAG_NORMAL);
1556         drawstring(hudloc + '165 69 0', strcat(ftos(rint(rockets * 100)), "%"),'14 14 0','1 1 0', 1, DRAWFLAG_NORMAL);
1557     }
1558
1559     picsize = drawgetimagesize(waki_b) * 0.5;
1560     hudloc_y = 10.5;
1561     hudloc_x = 10.5;
1562
1563     drawpic(hudloc, waki_s, picsize, '1 1 1', shield, DRAWFLAG_NORMAL);
1564     drawpic(hudloc, waki_b, picsize, '0 1 0' * health + '1 0 0' * (1 - health), 1, DRAWFLAG_NORMAL);
1565     drawpic(hudloc, waki_r, picsize, '1 1 1' * rockets + '1 0 0' * (1 - rockets), 1, DRAWFLAG_NORMAL);
1566     drawpic(hudloc, waki_e, picsize, '1 1 1' * energy + '1 0 0' *  (1 - energy), 1, DRAWFLAG_NORMAL);
1567
1568
1569
1570         /*
1571         p = '0.5 0 0' * (vid_conwidth - (rkt_size * 8));
1572         p = p + '0 1 0' * vid_conheight - '0 32 0';
1573
1574         // Draw health bar
1575         p_y += 8;
1576         drawfill(p, '256 0 0' * health + '0 8 0' , '0 0.7 0', 0.75, DRAWFLAG_NORMAL);
1577         p_x += 256 * health;
1578         drawfill(p, '256 0 0' * (1 - health) + '0 8 0' , '0 0 0', 0.75, DRAWFLAG_NORMAL);
1579
1580         // Draw shiled bar
1581         p_x -= 256 * health;
1582         p_y += 4;
1583         drawfill(p, '256 0 0' * shield + '0 4 0' , '0.25 0.25 1', 0.5, DRAWFLAG_NORMAL);
1584
1585         // Draw energy
1586         //p_x -= 256 * health;
1587         p_y -= 8;
1588         drawfill(p, '256 0 0' * energy + '0 4 0' , '1 1 1', 0.75, DRAWFLAG_NORMAL);
1589
1590         // Draw rockets bar
1591         p_y += 12;
1592         drawfill(p, '256 0 0' * rockets + '0 4 0' , '1 0 0', 0.75, DRAWFLAG_NORMAL);
1593         */
1594
1595
1596
1597
1598         if (scoreboard_showscores)
1599         {
1600                 HUD_DrawScoreboard();
1601                 HUD_DrawCenterPrint();
1602         }
1603
1604 }
1605
1606 void CSQC_common_hud(void)
1607 {
1608         // HUD_SortFrags(); done in HUD_Draw
1609         float hud;
1610         hud = getstati(STAT_HUD);
1611
1612         //hud = 10;
1613         switch(hud)
1614         {
1615                 case HUD_NORMAL:
1616                         // do some accuracy var caching
1617                         float i;
1618                         if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1619                         {
1620                                 if(autocvar_accuracy_color_levels != acc_color_levels)
1621                                 {
1622                                         if(acc_color_levels)
1623                                                 strunzone(acc_color_levels);
1624                                         acc_color_levels = strzone(autocvar_accuracy_color_levels);
1625                                         acc_levels = tokenize(acc_color_levels);
1626                                         if (acc_levels > MAX_ACCURACY_LEVELS)
1627                                                 acc_levels = MAX_ACCURACY_LEVELS;
1628
1629                                         for (i = 0; i < acc_levels; ++i)
1630                                                 acc_lev[i] = stof(argv(i)) / 100.0;
1631                                 }
1632                                 // let know that acc_col[] needs to be loaded
1633                                 acc_col_x[0] = -1;
1634                         }
1635
1636                         HUD_Main(); // always run these functions for alpha checks
1637                         HUD_DrawScoreboard();
1638
1639                         if (scoreboard_active) // scoreboard/accuracy
1640                         {
1641                                 HUD_Reset();
1642                                 // HUD_DrawScoreboard takes care of centerprint_start
1643                         }
1644                         else if (intermission == 2) // map voting screen
1645                         {
1646                                 HUD_FinaleOverlay();
1647                                 HUD_Reset();
1648
1649                                 centerprint_start_x = 0;
1650                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1651                         }
1652                         else // hud
1653                         {
1654                                 centerprint_start_x = 0;
1655                                 centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1656                         }
1657
1658                         HUD_DrawCenterPrint();
1659                         break;
1660
1661                 case HUD_SPIDERBOT:
1662                         CSQC_SPIDER_HUD();
1663                         break;
1664
1665                 case HUD_WAKIZASHI:
1666                         CSQC_WAKIZASHI_HUD();
1667                         break;
1668         }
1669 }
1670
1671
1672 // following vectors must be global to allow seamless switching between camera modes
1673 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1674 void CSQC_Demo_Camera()
1675 {
1676         float speed, attenuation, dimensions;
1677         vector tmp, delta;
1678
1679         if( autocvar_camera_reset || !camera_mode )
1680         {
1681                 camera_offset = '0 0 0';
1682                 current_angles = '0 0 0';
1683                 camera_direction = '0 0 0';
1684                 camera_offset_z += 30;
1685                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1686                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1687                 current_origin = view_origin;
1688                 current_camera_offset  = camera_offset;
1689                 cvar_set("camera_reset", "0");
1690                 camera_mode = CAMERA_CHASE;
1691         }
1692
1693         // Camera angles
1694         if( camera_roll )
1695                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1696
1697         if(autocvar_camera_look_player)
1698         {
1699                 local vector dir;
1700                 local float n;
1701
1702                 dir = normalize(view_origin - current_position);
1703                 n = mouse_angles_z;
1704                 mouse_angles = vectoangles(dir);
1705                 mouse_angles_x = mouse_angles_x * -1;
1706                 mouse_angles_z = n;
1707         }
1708         else
1709         {
1710                 tmp = getmousepos() * 0.1;
1711                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1712                 {
1713                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1714                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1715                 }
1716         }
1717
1718         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1719         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1720         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1721         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1722
1723         // Fix difference when angles don't have the same sign
1724         delta = '0 0 0';
1725         if(mouse_angles_y < -60 && current_angles_y > 60)
1726                 delta = '0 360 0';
1727         if(mouse_angles_y > 60 && current_angles_y < -60)
1728                 delta = '0 -360 0';
1729
1730         if(autocvar_camera_look_player)
1731                 attenuation = autocvar_camera_look_attenuation;
1732         else
1733                 attenuation = autocvar_camera_speed_attenuation;
1734
1735         attenuation = 1 / max(1, attenuation);
1736         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1737
1738         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1739         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1740         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1741         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1742
1743         // Camera position
1744         tmp = '0 0 0';
1745         dimensions = 0;
1746
1747         if( camera_direction_x )
1748         {
1749                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1750                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1751                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1752                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1753                 ++dimensions;
1754         }
1755
1756         if( camera_direction_y )
1757         {
1758                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1759                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1760                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1761                 ++dimensions;
1762         }
1763
1764         if( camera_direction_z )
1765         {
1766                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1767                 ++dimensions;
1768         }
1769
1770         if(autocvar_camera_free)
1771                 speed = autocvar_camera_speed_free;
1772         else
1773                 speed = autocvar_camera_speed_chase;
1774
1775         if(dimensions)
1776         {
1777                 speed = speed * sqrt(1 / dimensions);
1778                 camera_offset += tmp * speed;
1779         }
1780
1781         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1782
1783         // Camera modes
1784         if( autocvar_camera_free )
1785         {
1786                 if ( camera_mode == CAMERA_CHASE )
1787                 {
1788                         current_camera_offset = current_origin + current_camera_offset;
1789                         camera_offset = current_origin + camera_offset;
1790                 }
1791
1792                 camera_mode = CAMERA_FREE;
1793                 current_position = current_camera_offset;
1794         }
1795         else
1796         {
1797                 if ( camera_mode == CAMERA_FREE )
1798                 {
1799                         current_origin = view_origin;
1800                         camera_offset = camera_offset - current_origin;
1801                         current_camera_offset = current_camera_offset - current_origin;
1802                 }
1803
1804                 camera_mode = CAMERA_CHASE;
1805
1806                 if(autocvar_camera_chase_smoothly)
1807                         current_origin += (view_origin - current_origin) * attenuation;
1808                 else
1809                         current_origin = view_origin;
1810
1811                 current_position = current_origin + current_camera_offset;
1812         }
1813
1814         R_SetView(VF_ANGLES, current_angles);
1815         R_SetView(VF_ORIGIN, current_position);
1816 }