qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float trace_dphitcontents;
   4 float trace_networkentity;
   5 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   6 float DPCONTENTS_SOLID = 1; // blocks player movement
   7 float DPCONTENTS_BODY = 32; // blocks player movement
   8 float DPCONTENTS_CORPSE = 64; // blocks player movement
   9 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
  10 void Porto_Draw()
  11 {
  12         vector p, dir, ang, q, nextdir;
  13         float idx, portal_number, portal1_idx;
  14
  15         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  16                 return;
  17         if(intermission == 1)
  18                 return;
  19         if(intermission == 2)
  20                 return;
  21         if (getstati(STAT_HEALTH) <= 0)
  22                 return;
  23
  24         dir = view_forward;
  25
  26         if(angles_held_status)
  27         {
  28                 makevectors(angles_held);
  29                 dir = v_forward;
  30         }
  31
  32         p = view_origin;
  33
  34         polyline[0] = p;
  35         idx = 1;
  36         portal_number = 0;
  37         nextdir = dir;
  38
  39         for(;;)
  40         {
  41                 dir = nextdir;
  42                 traceline(p, p + 65536 * dir, TRUE, porto);
  43                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  44                         return;
  45                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  46                 p = trace_endpos;
  47                 polyline[idx] = p;
  48                 ++idx;
  49                 if(idx >= 16)
  50                         return;
  51                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  52                         continue;
  53                 ++portal_number;
  54                 ang = vectoangles2(trace_plane_normal, dir);
  55                 ang_x = -ang_x;
  56                 makevectors(ang);
  57                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  58                         return;
  59                 if(portal_number == 1)
  60                         portal1_idx = idx;
  61                 if(portal_number >= 2)
  62                         break;
  63         }
  64
  65         while(idx >= 2)
  66         {
  67                 p = polyline[idx-2];
  68                 q = polyline[idx-1];
  69                 if(idx == 2)
  70                         p = p - view_up * 16;
  71                 if(idx-1 >= portal1_idx)
  72                 {
  73                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  74                 }
  75                 else
  76                 {
  77                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  78                 }
  79                 --idx;
  80         }
  81 }
  82
  83 /**
  84  * Checks whether the server initiated a map restart (stat_game_starttime changed)
  85  *
  86  * TODO: Use a better solution where a common shared entitiy is used that contains
  87  * timelimit, fraglimit and game_starttime! Requires engine changes (remove STAT_TIMELIMIT
  88  * and STAT_FRAGLIMIT to be auto-sent)
  89  */
  90 void CheckForGamestartChange() {
  91         float startTime;
  92         startTime = getstatf(STAT_GAMESTARTTIME);
  93         if (previous_game_starttime != startTime) {
  94                 if ((time + 5.0) < startTime) {
  95                         //if connecting to server while restart was active don't always play prepareforbattle
  96                         sound(world, CHAN_AUTO, strcat("announcer/", autocvar_cl_announcer, "/prepareforbattle.wav"), VOL_BASEVOICE, ATTN_NONE);
  97                 }
  98                 if (time < startTime) {
  99                         restartAnnouncer = spawn();
 100                         restartAnnouncer.think = restartAnnouncer_Think;
 101                         restartAnnouncer.nextthink = startTime - floor(startTime - time); //synchronize nextthink to startTime
 102                 }
 103         }
 104         previous_game_starttime = startTime;
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
 120
 121         zoomsensitivity = autocvar_cl_zoomsensitivity;
 122         zoomfactor = autocvar_cl_zoomfactor;
 123         if(zoomfactor < 1 || zoomfactor > 16)
 124                 zoomfactor = 2.5;
 125         zoomspeed = autocvar_cl_zoomspeed;
 126         if(zoomspeed >= 0)
 127                 if(zoomspeed < 0.5 || zoomspeed > 16)
 128                         zoomspeed = 3.5;
 129
 130         zoomdir = button_zoom;
 131         if(hud == HUD_NORMAL)
 132         if((getstati(STAT_ACTIVEWEAPON) == WEP_NEX && nex_scope) || (getstati(STAT_ACTIVEWEAPON) == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 133                 zoomdir += button_attack2;
 134         if(spectatee_status > 0 || isdemo())
 135         {
 136                 if(spectatorbutton_zoom)
 137                         zoomdir = 0 + !zoomdir;
 138                 // do not even THINK about removing this 0
 139                 // _I_ know what I am doing
 140                 // fteqcc does not
 141         }
 142
 143         if(zoomdir)
 144                 zoomin_effect = 0;
 145
 146         if(zoomin_effect || camera_active)
 147         {
 148                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 149         }
 150         else
 151         {
 152                 if(zoomspeed < 0) // instant zoom
 153                 {
 154                         if(zoomdir)
 155                                 current_viewzoom = 1 / zoomfactor;
 156                         else
 157                                 current_viewzoom = 1;
 158                 }
 159                 else
 160                 {
 161                         if(zoomdir)
 162                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 163                         else
 164                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 165                 }
 166         }
 167
 168         if(almost_equals(current_viewzoom, 1))
 169                 current_zoomfraction = 0;
 170         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 171                 current_zoomfraction = 1;
 172         else
 173                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 174
 175         if(zoomsensitivity < 1)
 176                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 177         else
 178                 setsensitivityscale(1);
 179
 180         velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 181         avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 182         velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 183
 184         //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 185
 186         float frustumx, frustumy, fovx, fovy;
 187         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 188         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 189         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 190         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 191
 192         return '1 0 0' * fovx + '0 1 0' * fovy;
 193 }
 194
 195 // this function must match W_SetupShot!
 196 float zoomscript_caught;
 197
 198 vector wcross_origin;
 199 float wcross_scale_prev, wcross_alpha_prev;
 200 vector wcross_color_prev;
 201 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 202 vector wcross_color_goal_prev;
 203 float wcross_changedonetime;
 204
 205 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 206 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 207 float wcross_name_changestarttime, wcross_name_changedonetime;
 208 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 209 entity trueaim;
 210 entity trueaim_rifle;
 211
 212 #define SHOTTYPE_HITTEAM 1
 213 #define SHOTTYPE_HITOBSTRUCTION 2
 214 #define SHOTTYPE_HITWORLD 3
 215 #define SHOTTYPE_HITENEMY 4
 216
 217 void TrueAim_Init()
 218 {
 219         trueaim = spawn();
 220         trueaim.classname = "trueaim";
 221         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 222         trueaim_rifle = spawn();
 223         trueaim_rifle.classname = "trueaim_rifle";
 224         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 225 }
 226
 227 float EnemyHitCheck()
 228 {
 229         float t;
 230         wcross_origin = project_3d_to_2d(trace_endpos);
 231         wcross_origin_z = 0;
 232         if(trace_networkentity < 1)
 233                 return SHOTTYPE_HITWORLD;
 234         if(trace_networkentity > maxclients)
 235                 return SHOTTYPE_HITWORLD;
 236         t = GetPlayerColor(trace_networkentity - 1);
 237         if(teamplay)
 238                 if(t == myteam)
 239                         return SHOTTYPE_HITTEAM;
 240         if(t == COLOR_SPECTATOR)
 241                 return SHOTTYPE_HITWORLD;
 242         return SHOTTYPE_HITENEMY;
 243 }
 244
 245 float TrueAimCheck()
 246 {
 247         float nudge = 1; // added to traceline target and subtracted from result
 248         vector vecs, trueaimpoint, w_shotorg;
 249         vector mi, ma, dv;
 250         float shottype;
 251         entity ta;
 252         float mv;
 253
 254         mi = ma = '0 0 0';
 255         ta = trueaim;
 256         mv = MOVE_NOMONSTERS;
 257
 258         switch(activeweapon)
 259         {
 260                 case WEP_TUBA: // no aim
 261                 case WEP_PORTO: // shoots from eye
 262                 case WEP_HOOK: // no trueaim
 263                 case WEP_GRENADE_LAUNCHER: // toss curve
 264                         return SHOTTYPE_HITWORLD;
 265                 case WEP_NEX:
 266                 case WEP_MINSTANEX:
 267                         mv = MOVE_NORMAL;
 268                         break;
 269                 case WEP_RIFLE:
 270                         ta = trueaim_rifle;
 271                         mv = MOVE_NORMAL;
 272                         if(zoomscript_caught)
 273                         {
 274                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 275                                 return EnemyHitCheck();
 276                         }
 277                         break;
 278                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 279                         mi = '-3 -3 -3';
 280                         ma = '3 3 3';
 281                         break;
 282                 case WEP_FIREBALL: // projectile has a size!
 283                         mi = '-16 -16 -16';
 284                         ma = '16 16 16';
 285                         break;
 286                 case WEP_SEEKER: // projectile has a size!
 287                         mi = '-2 -2 -2';
 288                         ma = '2 2 2';
 289                         break;
 290                 case WEP_ELECTRO: // projectile has a size!
 291                         mi = '0 0 -3';
 292                         ma = '0 0 -3';
 293                         break;
 294         }
 295
 296         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 297
 298         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 299         trueaimpoint = trace_endpos;
 300
 301         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 302                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 303
 304         if(vecs_x > 0)
 305                 vecs_y = -vecs_y;
 306         else
 307                 vecs = '0 0 0';
 308
 309         dv = view_right * vecs_y + view_up * vecs_z;
 310         w_shotorg = view_origin + dv;
 311
 312         // now move the vecs forward as much as requested if possible
 313         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 314         w_shotorg = trace_endpos - view_forward * nudge;
 315
 316         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 317         shottype = EnemyHitCheck();
 318         if(shottype != SHOTTYPE_HITWORLD)
 319                 return shottype;
 320
 321 #if 0
 322         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 323         // or rather, I know why, but see no fix
 324         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 325                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 326                 return SHOTTYPE_HITOBSTRUCTION;
 327 #endif
 328
 329         return SHOTTYPE_HITWORLD;
 330 }
 331
 332 void CSQC_common_hud(void);
 333
 334 void PostInit(void);
 335 void CSQC_Demo_Camera();
 336 float HUD_WouldDrawScoreboard();
 337 float camera_mode;
 338 float reticle_type;
 339 string NextFrameCommand;
 340 void CSQC_SPIDER_HUD();
 341 void CSQC_RAPTOR_HUD();
 342
 343 vector freeze_org, freeze_ang;
 344 entity nightvision_noise, nightvision_noise2;
 345
 346 float pickup_crosshair_time, pickup_crosshair_size;
 347 float hit_time, typehit_time;
 348 float nextsound_hit_time, nextsound_typehit_time;
 349 float hitindication_crosshair_time, hitindication_crosshair_size;
 350 float use_nex_chargepool;
 351
 352 float myhealth, myhealth_prev;
 353 float myhealth_flash;
 354
 355 float old_blurradius, old_bluralpha;
 356 float old_sharpen_intensity;
 357
 358 vector myhealth_gentlergb;
 359
 360 float contentavgalpha, liquidalpha_prev;
 361 vector liquidcolor_prev;
 362
 363 float eventchase_current_distance;
 364
 365 vector damage_blurpostprocess, content_blurpostprocess;
 366
 367 float checkfail[16];
 368
 369 void CSQC_UpdateView(float w, float h)
 370 {
 371         entity e;
 372         float fov;
 373         float f, i, j;
 374         vector v;
 375         vector vf_size, vf_min;
 376         float a;
 377         hud = getstati(STAT_HUD);
 378
 379         button_attack2 = (input_buttons & BUTTON_3);
 380         button_zoom = (input_buttons & BUTTON_4);
 381
 382 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 383         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 384         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 385         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 386         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 387         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 388         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 389
 390         vf_size = R_SetView3fv(VF_SIZE);
 391         vf_min = R_SetView3fv(VF_MIN);
 392         vid_width = vf_size_x;
 393         vid_height = vf_size_y;
 394
 395         vector reticle_pos, reticle_size;
 396         vector splash_pos, splash_size;
 397
 398         WaypointSprite_Load();
 399
 400         if(spectatee_status)
 401                 myteam = GetPlayerColor(spectatee_status - 1);
 402         else
 403                 myteam = GetPlayerColor(player_localentnum - 1);
 404
 405         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 406
 407         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 408         {
 409                 R_SetView(VF_ORIGIN, freeze_org);
 410                 R_SetView(VF_ANGLES, freeze_ang);
 411         }
 412         else
 413         {
 414                 freeze_org = R_SetView3fv(VF_ORIGIN);
 415                 freeze_ang = R_SetView3fv(VF_ANGLES);
 416         }
 417
 418         // event chase camera
 419         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 420         {
 421                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 422                 {
 423                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 424                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 425                         if(!autocvar_chase_active)
 426                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 427
 428                         // make the camera smooth back
 429                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 430                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 431                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 432                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 433
 434                         vector eventchase_target_origin;
 435                         makevectors(view_angles);
 436                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 437                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance;
 438
 439                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 440                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 441                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 442                         eventchase_target_origin = freeze_org - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 443                         WarpZone_TraceLine(freeze_org, eventchase_target_origin, MOVE_WORLDONLY, self);
 444
 445                         R_SetView(VF_ORIGIN, trace_endpos);
 446                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 447                 }
 448                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 449                 {
 450                         cvar_set("chase_active", "0");
 451                         eventchase_current_distance = 0; // start from 0 next time
 452                 }
 453         }
 454
 455         WarpZone_FixView();
 456         //WarpZone_FixPMove();
 457
 458         // Render the Scene
 459         view_origin = R_SetView3fv(VF_ORIGIN);
 460         view_angles = R_SetView3fv(VF_ANGLES);
 461         makevectors(view_angles);
 462         view_forward = v_forward;
 463         view_right = v_right;
 464         view_up = v_up;
 465
 466 #ifdef BLURTEST
 467         if(time > blurtest_time0 && time < blurtest_time1)
 468         {
 469                 float r, t;
 470
 471                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 472                 r = t * blurtest_radius;
 473                 f = 1 / pow(t, blurtest_power) - 1;
 474
 475                 cvar_set("r_glsl_postprocess", "1");
 476                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 477         }
 478         else
 479         {
 480                 cvar_set("r_glsl_postprocess", "0");
 481                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 482         }
 483 #endif
 484
 485         TargetMusic_Advance();
 486         Fog_Force();
 487
 488         if(drawtime == 0)
 489                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 490         else
 491                 drawframetime = bound(0.000001, time - drawtime, 1);
 492         drawtime = time;
 493
 494         // watch for gametype changes here...
 495         // in ParseStuffCMD the cmd isn't executed yet :/
 496         // might even be better to add the gametype to TE_CSQC_INIT...?
 497         if(!postinit)
 498                 PostInit();
 499
 500         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 501                 if(calledhooks & HOOK_START)
 502                 {
 503                         localcmd("\ncl_hook_gameend\n");
 504                         calledhooks |= HOOK_END;
 505                 }
 506
 507         CheckForGamestartChange();
 508         serverAnnouncer();
 509         maptimeAnnouncer();
 510         carrierAnnouncer();
 511
 512         fov = autocvar_fov;
 513         if(fov <= 59.5)
 514         {
 515                 if(!zoomscript_caught)
 516                 {
 517                         localcmd("+button9\n");
 518                         zoomscript_caught = 1;
 519                 }
 520         }
 521         else
 522         {
 523                 if(zoomscript_caught)
 524                 {
 525                         localcmd("-button9\n");
 526                         zoomscript_caught = 0;
 527                 }
 528         }
 529
 530         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 531         activeweapon = getstati(STAT_SWITCHWEAPON);
 532         f = (serverflags & SERVERFLAG_TEAMPLAY);
 533         if(f != teamplay)
 534         {
 535                 teamplay = f;
 536                 HUD_InitScores();
 537         }
 538
 539         if(last_weapon != activeweapon) {
 540                 weapontime = time;
 541                 last_weapon = activeweapon;
 542
 543                 e = get_weaponinfo(activeweapon);
 544                 if(e.netname != "")
 545                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 546                 else
 547                         localcmd("\ncl_hook_activeweapon none\n");
 548         }
 549
 550         // ALWAYS Clear Current Scene First
 551         R_ClearScene();
 552         R_SetView(VF_ORIGIN, view_origin);
 553         R_SetView(VF_ANGLES, view_angles);
 554
 555         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 556         R_SetView(VF_SIZE, vf_size);
 557         R_SetView(VF_MIN, vf_min);
 558
 559         // Assign Standard Viewflags
 560         // Draw the World (and sky)
 561         R_SetView(VF_DRAWWORLD, 1);
 562
 563         // Set the console size vars
 564         vid_conwidth = autocvar_vid_conwidth;
 565         vid_conheight = autocvar_vid_conheight;
 566         vid_pixelheight = autocvar_vid_pixelheight;
 567
 568         R_SetView(VF_FOV, GetCurrentFov(fov));
 569
 570         // Camera for demo playback
 571         if(camera_active)
 572         {
 573                 if(autocvar_camera_enable)
 574                         CSQC_Demo_Camera();
 575                 else
 576                 {
 577                         cvar_set("chase_active", ftos(chase_active_backup));
 578                         cvar_set("cl_demo_mousegrab", "0");
 579                         camera_active = FALSE;
 580                 }
 581         }
 582 #ifdef CAMERATEST
 583         else if(autocvar_camera_enable)
 584 #else
 585         else if(autocvar_camera_enable && isdemo())
 586 #endif
 587         {
 588                 // Enable required Darkplaces cvars
 589                 chase_active_backup = autocvar_chase_active;
 590                 cvar_set("chase_active", "2");
 591                 cvar_set("cl_demo_mousegrab", "1");
 592                 camera_active = TRUE;
 593                 camera_mode = FALSE;
 594         }
 595
 596         // Draw the Crosshair
 597         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 598
 599         // Draw the Engine Status Bar (the default Quake HUD)
 600         R_SetView(VF_DRAWENGINEHUD, 0);
 601
 602         // Update the mouse position
 603         /*
 604            mousepos_x = vid_conwidth;
 605            mousepos_y = vid_conheight;
 606            mousepos = mousepos*0.5 + getmousepos();
 607          */
 608
 609         e = self;
 610         for(self = world; (self = nextent(self)); )
 611                 if(self.draw)
 612                         self.draw();
 613         self = e;
 614
 615         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 616         R_RenderScene();
 617
 618         // now switch to 2D drawing mode by calling a 2D drawing function
 619         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 620         // next R_RenderScene call
 621         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 622
 623         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 624         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 625         {
 626                 // apply night vision effect
 627                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 628
 629                 if(!nightvision_noise)
 630                 {
 631                         nightvision_noise = spawn();
 632                         nightvision_noise.classname = "nightvision_noise";
 633                 }
 634                 if(!nightvision_noise2)
 635                 {
 636                         nightvision_noise2 = spawn();
 637                         nightvision_noise2.classname = "nightvision_noise2";
 638                 }
 639
 640                 // color tint in yellow
 641                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 642
 643                 // draw BG
 644                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 645                 rgb = '1 1 1';
 646                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 647                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 648                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 649                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 650                 tc_11 = tc_01 + tc_10 - tc_00;
 651                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 652                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 653                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 654                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 655                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 656                 R_EndPolygon();
 657
 658                 // draw FG
 659                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 660                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 661                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 662                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 663                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 664                 tc_11 = tc_01 + tc_10 - tc_00;
 665                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 666                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 667                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 668                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 669                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 670                 R_EndPolygon();
 671         }
 672
 673         // Draw the aiming reticle for weapons that use it
 674         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 675         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 676         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 677         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 678                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 679         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 680                 reticle_type = 2; // nex zoom
 681         else if(button_zoom || zoomscript_caught)
 682                 reticle_type = 1; // normal zoom
 683         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 684                 reticle_type = 2; // nex zoom
 685
 686         if (reticle_type)
 687         {
 688                 if(autocvar_cl_reticle_stretch)
 689                 {
 690                         reticle_size_x = vid_conwidth;
 691                         reticle_size_y = vid_conheight;
 692                         reticle_pos_x = 0;
 693                         reticle_pos_y = 0;
 694                 }
 695                 else
 696                 {
 697                         reticle_size_x = max(vid_conwidth, vid_conheight);
 698                         reticle_size_y = max(vid_conwidth, vid_conheight);
 699                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 700                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 701                 }
 702
 703                 f = current_zoomfraction;
 704                 if(zoomscript_caught)
 705                         f = 1;
 706                 if(autocvar_cl_reticle_item_normal)
 707                 {
 708                         if(reticle_type == 1 && f)
 709                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 710                 }
 711                 if(autocvar_cl_reticle_item_nex)
 712                 {
 713                         if(reticle_type == 2 && f)
 714                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 715                 }
 716         }
 717
 718
 719         // improved polyblend
 720         vector rgb;
 721         if(autocvar_hud_contents)
 722         {
 723                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 724                 vector liquidcolor;
 725
 726                 switch(pointcontents(view_origin))
 727                 {
 728                         case CONTENT_WATER:
 729                                 liquidalpha = autocvar_hud_contents_water_alpha;
 730                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 731                                 incontent = 1;
 732                                 break;
 733
 734                         case CONTENT_LAVA:
 735                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 736                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 737                                 incontent = 1;
 738                                 break;
 739
 740                         case CONTENT_SLIME:
 741                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 742                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 743                                 incontent = 1;
 744                                 break;
 745
 746                         default:
 747                                 liquidalpha = 0;
 748                                 liquidcolor = '0 0 0';
 749                                 incontent = 0;
 750                                 break;
 751                 }
 752
 753                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 754                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 755                         contentfadetime = autocvar_hud_contents_fadeintime;
 756                         liquidalpha_prev = liquidalpha;
 757                         liquidcolor_prev = liquidcolor;
 758                 }
 759                 else
 760                         contentfadetime = autocvar_hud_contents_fadeouttime;
 761
 762                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 763                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 764
 765                 if(contentavgalpha)
 766                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 767
 768                 if(autocvar_hud_postprocessing)
 769                 {
 770                         if(autocvar_hud_contents_blur && contentavgalpha)
 771                         {
 772                                 content_blurpostprocess_x = 1;
 773                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 774                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 775                         }
 776                         else
 777                         {
 778                                 content_blurpostprocess_x = 0;
 779                                 content_blurpostprocess_y = 0;
 780                                 content_blurpostprocess_z = 0;
 781                         }
 782                 }
 783         }
 784
 785         if(autocvar_hud_damage && !autocvar_chase_active)
 786
 787         {
 788                 splash_size_x = max(vid_conwidth, vid_conheight);
 789                 splash_size_y = max(vid_conwidth, vid_conheight);
 790                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 791                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 792
 793                 float myhealth_flash_temp;
 794                 myhealth = getstati(STAT_HEALTH);
 795
 796                 // fade out
 797                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 798                 // add new damage
 799                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 800
 801                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 802                 pain_threshold = autocvar_hud_damage_pain_threshold;
 803                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 804                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 805
 806                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 807                 {
 808                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 809                 }
 810
 811                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 812
 813                 if(myhealth_prev < 1)
 814                 {
 815                         if(myhealth >= 1)
 816                         {
 817                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 818                                 myhealth_flash_temp = 0;
 819                         }
 820                         else
 821                         {
 822                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 823                         }
 824                 }
 825
 826                 if(spectatee_status == -1 || intermission)
 827                 {
 828                         myhealth_flash = 0; // observing, or match ended
 829                         myhealth_flash_temp = 0;
 830                 }
 831
 832                 myhealth_prev = myhealth;
 833
 834                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 835                 {
 836                         if(autocvar_cl_gentle_damage == 2)
 837                         {
 838                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 839                                 {
 840                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 841                                 }
 842                         }
 843                         else
 844                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 845
 846                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 847                 }
 848                 else
 849                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 850
 851                 if(autocvar_hud_postprocessing)
 852                 {
 853                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 854                         {
 855                                 damage_blurpostprocess_x = 1;
 856                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 857                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 858                         }
 859                         else
 860                         {
 861                                 damage_blurpostprocess_x = 0;
 862                                 damage_blurpostprocess_y = 0;
 863                                 damage_blurpostprocess_z = 0;
 864                         }
 865                 }
 866         }
 867
 868         if(autocvar_hud_postprocessing)
 869         {
 870                 // all of this should be done in the engine eventually
 871
 872                 // enable or disable rendering types if they are used or not
 873                 if(cvar("r_glsl_postprocess_uservec1_enable") != (cvar("hud_postprocessing_maxbluralpha") != 0))
 874                         cvar_set("r_glsl_postprocess_uservec1_enable", ftos(cvar("hud_postprocessing_maxbluralpha") != 0));
 875                 if(cvar("r_glsl_postprocess_uservec2_enable") != (cvar("hud_powerup") != 0))
 876                         cvar_set("r_glsl_postprocess_uservec2_enable", ftos(cvar("hud_powerup") != 0));
 877
 878                 // lets apply the postprocess effects from the previous two functions if needed
 879                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 880                 {
 881                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 882                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 883                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 884                         {
 885                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 886                                 old_blurradius = blurradius;
 887                                 old_bluralpha = bluralpha;
 888                         }
 889                 }
 890                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 891                 {
 892                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 893                         old_blurradius = 0;
 894                         old_bluralpha = 0;
 895                 }
 896
 897                 float sharpen_intensity;
 898                 if (getstatf(STAT_STRENGTH_FINISHED) - time > 0)
 899                         sharpen_intensity += (getstatf(STAT_STRENGTH_FINISHED) - time);
 900                 if (getstatf(STAT_INVINCIBLE_FINISHED) - time > 0)
 901                         sharpen_intensity += (getstatf(STAT_INVINCIBLE_FINISHED) - time);
 902
 903                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 904                 {
 905                         sharpen_intensity = bound(0, sharpen_intensity, 5); // powerup warning time is 5 seconds, so fade the effect from there
 906
 907                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 908                         {
 909                                 cvar_set("r_glsl_postprocess_uservec2", strcat("0 ", ftos(-sharpen_intensity * cvar("hud_powerup")), " 0 0"));
 910                                 old_sharpen_intensity = sharpen_intensity;
 911                         }
 912                 }
 913                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 914                 {
 915                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 916                         old_sharpen_intensity = 0;
 917                 }
 918         }
 919
 920         if(menu_visible)
 921                 menu_show();
 922
 923         /*if(gametype == GAME_CTF)
 924           {
 925           ctf_view();
 926           } else */
 927
 928         // draw 2D entities
 929         e = self;
 930         for(self = world; (self = nextent(self)); )
 931                 if(self.draw2d)
 932                         self.draw2d();
 933         self = e;
 934         Draw_ShowNames_All();
 935
 936         scoreboard_active = HUD_WouldDrawScoreboard();
 937
 938         hit_time = getstatf(STAT_HIT_TIME);
 939         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 940         {
 941                 sound(world, CHAN_AUTO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 942                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 943         }
 944         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 945         if(typehit_time > nextsound_typehit_time)
 946         {
 947                 sound(world, CHAN_AUTO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 948                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 949         }
 950
 951         //else
 952         {
 953                 if(gametype == GAME_FREEZETAG)
 954                 {
 955                         if(getstati(STAT_FROZEN))
 956                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 957                         if(getstatf(STAT_REVIVE_PROGRESS))
 958                         {
 959                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 960                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 961                         }
 962                 }
 963
 964                 if(autocvar_r_letterbox == 0)
 965                         if(autocvar_viewsize < 120)
 966                                 CSQC_common_hud();
 967
 968                 // crosshair goes VERY LAST
 969                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 970                         string wcross_style;
 971                         float wcross_alpha, wcross_resolution;
 972                         wcross_style = autocvar_crosshair;
 973                         if (wcross_style == "0")
 974                                 return;
 975                         wcross_resolution = autocvar_crosshair_size;
 976                         if (wcross_resolution == 0)
 977                                 return;
 978                         wcross_alpha = autocvar_crosshair_alpha;
 979                         if (wcross_alpha == 0)
 980                                 return;
 981
 982                         // TrueAim check
 983                         float shottype;
 984
 985                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 986                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 987                         wcross_origin_z = 0;
 988                         if(autocvar_crosshair_hittest)
 989                         {
 990                                 vector wcross_oldorigin;
 991                                 wcross_oldorigin = wcross_origin;
 992                                 shottype = TrueAimCheck();
 993                                 if(shottype == SHOTTYPE_HITWORLD)
 994                                 {
 995                                         v = wcross_origin - wcross_oldorigin;
 996                                         v_x /= vid_conwidth;
 997                                         v_y /= vid_conheight;
 998                                         if(vlen(v) > 0.01)
 999                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1000                                 }
1001                                 if(!autocvar_crosshair_hittest_showimpact)
1002                                         wcross_origin = wcross_oldorigin;
1003                         }
1004                         else
1005                                 shottype = SHOTTYPE_HITWORLD;
1006
1007                         vector wcross_color, wcross_size;
1008                         string wcross_wep, wcross_name;
1009                         float wcross_scale, wcross_blur;
1010
1011                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1012                                 e = get_weaponinfo(activeweapon);
1013                                 if (e && e.netname != "")
1014                                 {
1015                                         wcross_wep = e.netname;
1016                                         if(autocvar_crosshair_per_weapon)
1017                                         {
1018                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1019                                                 if (wcross_resolution == 0)
1020                                                         return;
1021                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1022                                                 if (wcross_alpha == 0)
1023                                                         return;
1024
1025                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1026                                                 if(wcross_style == "" || wcross_style == "0")
1027                                                         wcross_style = wcross_wep;
1028                                         }
1029                                 }
1030                         }
1031                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1032                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1033                         else if(autocvar_crosshair_color_by_health)
1034                         {
1035                                 local float x = getstati(STAT_HEALTH);
1036
1037                                 //x = red
1038                                 //y = green
1039                                 //z = blue
1040
1041                                 wcross_color_z = 0;
1042
1043                                 if(x > 200)
1044                                 {
1045                                         wcross_color_x = 0;
1046                                         wcross_color_y = 1;
1047                                 }
1048                                 else if(x > 150)
1049                                 {
1050                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1051                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1052                                 }
1053                                 else if(x > 100)
1054                                 {
1055                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1056                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1057                                         wcross_color_z = 1 - (x-100)*0.02;
1058                                 }
1059                                 else if(x > 50)
1060                                 {
1061                                         wcross_color_x = 1;
1062                                         wcross_color_y = 1;
1063                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1064                                 }
1065                                 else if(x > 20)
1066                                 {
1067                                         wcross_color_x = 1;
1068                                         wcross_color_y = (x-20)*90/27/100;
1069                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1070                                 }
1071                                 else
1072                                 {
1073                                         wcross_color_x = 1;
1074                                         wcross_color_y = 0;
1075                                 }
1076                         }
1077                         else
1078                                 wcross_color = stov(autocvar_crosshair_color);
1079
1080                         wcross_name = strcat("gfx/crosshair", wcross_style);
1081
1082                         if(autocvar_crosshair_effect_scalefade)
1083                         {
1084                                 wcross_scale = wcross_resolution;
1085                                 wcross_resolution = 1;
1086                         }
1087                         else
1088                         {
1089                                 wcross_scale = 1;
1090                         }
1091
1092                         if(autocvar_crosshair_pickup)
1093                         {
1094                                 if(pickup_crosshair_time < getstatf(STAT_LAST_PICKUP))
1095                                 {
1096                                         pickup_crosshair_size = 1;
1097                                         pickup_crosshair_time = getstatf(STAT_LAST_PICKUP);
1098                                 }
1099
1100                                 if(pickup_crosshair_size > 0)
1101                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1102                                 else
1103                                         pickup_crosshair_size = 0;
1104
1105                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1106                         }
1107
1108                         vector hitindication_color;
1109                         if(autocvar_crosshair_hitindication)
1110                         {
1111                                 hitindication_color = stov(autocvar_crosshair_hitindication_color);
1112                                 if(hitindication_crosshair_time < hit_time)
1113                                 {
1114                                         hitindication_crosshair_size = 1;
1115                                         hitindication_crosshair_time = hit_time;
1116                                 }
1117
1118                                 if(hitindication_crosshair_size > 0)
1119                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1120                                 else
1121                                         hitindication_crosshair_size = 0;
1122
1123                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1124                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1125                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1126                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1127                         }
1128
1129                         if(shottype == SHOTTYPE_HITENEMY)
1130                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1131                         if(shottype == SHOTTYPE_HITTEAM)
1132                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1133
1134                         f = autocvar_crosshair_effect_speed;
1135                         if(f < 0)
1136                                 f *= -2 * g_weaponswitchdelay;
1137                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1138                         {
1139                                 wcross_changedonetime = time + f;
1140                         }
1141                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1142                         {
1143                                 wcross_name_changestarttime = time;
1144                                 wcross_name_changedonetime = time + f;
1145                                 if(wcross_name_goal_prev_prev)
1146                                         strunzone(wcross_name_goal_prev_prev);
1147                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1148                                 wcross_name_goal_prev = strzone(wcross_name);
1149                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1150                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1151                                 wcross_resolution_goal_prev = wcross_resolution;
1152                         }
1153
1154                         wcross_scale_goal_prev = wcross_scale;
1155                         wcross_alpha_goal_prev = wcross_alpha;
1156                         wcross_color_goal_prev = wcross_color;
1157
1158                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1159                         {
1160                                 wcross_blur = 1;
1161                                 wcross_alpha *= 0.75;
1162                         }
1163                         else
1164                                 wcross_blur = 0;
1165                         // *_prev is at time-frametime
1166                         // * is at wcross_changedonetime+f
1167                         // what do we have at time?
1168                         if(time < wcross_changedonetime)
1169                         {
1170                                 f = frametime / (wcross_changedonetime - time + frametime);
1171                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1172                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1173                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1174                         }
1175
1176                         wcross_scale_prev = wcross_scale;
1177                         wcross_alpha_prev = wcross_alpha;
1178                         wcross_color_prev = wcross_color;
1179
1180                         wcross_scale *= 1 - autocvar__menu_alpha;
1181                         wcross_alpha *= 1 - autocvar__menu_alpha;
1182                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1183
1184                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1185                         {
1186                                 // crosshair rings for weapon stats
1187                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1188                                 {
1189                                         // declarations and stats
1190                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1191                                         string ring_image, ring_inner_image;
1192                                         vector ring_rgb, ring_inner_rgb;
1193
1194                                         ring_scale = autocvar_crosshair_ring_size;
1195
1196                                         float weapon_clipload, weapon_clipsize;
1197                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1198                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1199
1200                                         float nex_charge, nex_chargepool;
1201                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1202                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1203
1204                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1205                                                 nex_charge_movingavg = nex_charge;
1206
1207
1208                                         // handle the values
1209                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1210                                         {
1211                                                 if (nex_chargepool || use_nex_chargepool) {
1212                                                         use_nex_chargepool = 1;
1213                                                         ring_inner_value = nex_chargepool;
1214                                                 } else {
1215                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1216                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1217                                                 }
1218
1219                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1220                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1221                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1222
1223                                                 // draw the outer ring to show the current charge of the weapon
1224                                                 ring_value = nex_charge;
1225                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1226                                                 ring_rgb = wcross_color;
1227                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1228                                         }
1229                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1230                                         {
1231                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1232                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1233                                                 ring_rgb = wcross_color;
1234                                                 ring_image = "gfx/crosshair_ring.tga";
1235                                         }
1236                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1237                                         {
1238                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1239                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1240                                                 ring_rgb = wcross_color;
1241                                                 ring_image = "gfx/crosshair_ring.tga";
1242                                         }
1243
1244                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1245                                         {
1246                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1247                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1248                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1249                                                 ring_rgb = wcross_color;
1250
1251                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1252                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1253                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1254                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1255                                                 else
1256                                                         ring_image = "gfx/crosshair_ring.tga";
1257                                         }
1258
1259                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1260                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1261
1262                                         if (ring_value)
1263                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1264                                 }
1265
1266 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1267                                 do \
1268                                 { \
1269                                         if(wcross_blur > 0) \
1270                                         { \
1271                                                 for(i = -2; i <= 2; ++i) \
1272                                                 for(j = -2; j <= 2; ++j) \
1273                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1274                                         } \
1275                                         else \
1276                                         { \
1277                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1278                                         } \
1279                                 } \
1280                                 while(0)
1281
1282 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1283                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1284
1285 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1286                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1287
1288                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1289                                 {
1290                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1291                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1292                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1293                                         f = 1 - f;
1294                                 }
1295                                 else
1296                                 {
1297                                         f = 1;
1298                                 }
1299                                 wcross_name_alpha_goal_prev = f;
1300
1301                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1302                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1303
1304                                 if(autocvar_crosshair_dot)
1305                                 {
1306                                         vector wcross_color_old;
1307                                         wcross_color_old = wcross_color;
1308                                         if(autocvar_crosshair_dot_color != "0")
1309                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1310                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1311                                         // FIXME why don't we use wcross_alpha here?
1312                                         wcross_color = wcross_color_old;
1313                                 }
1314                         }
1315                 }
1316                 else
1317                 {
1318                         wcross_scale_prev = 0;
1319                         wcross_alpha_prev = 0;
1320                         wcross_scale_goal_prev = 0;
1321                         wcross_alpha_goal_prev = 0;
1322                         wcross_changedonetime = 0;
1323                         if(wcross_name_goal_prev)
1324                                 strunzone(wcross_name_goal_prev);
1325                         wcross_name_goal_prev = string_null;
1326                         if(wcross_name_goal_prev_prev)
1327                                 strunzone(wcross_name_goal_prev_prev);
1328                         wcross_name_goal_prev_prev = string_null;
1329                         wcross_name_changestarttime = 0;
1330                         wcross_name_changedonetime = 0;
1331                         wcross_name_alpha_goal_prev = 0;
1332                         wcross_name_alpha_goal_prev_prev = 0;
1333                         wcross_resolution_goal_prev = 0;
1334                         wcross_resolution_goal_prev_prev = 0;
1335                 }
1336         }
1337
1338         if(NextFrameCommand)
1339         {
1340                 localcmd("\n", NextFrameCommand, "\n");
1341                 NextFrameCommand = string_null;
1342         }
1343
1344         // we must do this check AFTER a frame was rendered, or it won't work
1345         if(cs_project_is_b0rked == 0)
1346         {
1347                 string w0, h0;
1348                 w0 = ftos(autocvar_vid_conwidth);
1349                 h0 = ftos(autocvar_vid_conheight);
1350                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1351                 //R_SetView(VF_FOV, '90 90 0');
1352                 R_SetView(VF_ORIGIN, '0 0 0');
1353                 R_SetView(VF_ANGLES, '0 0 0');
1354                 R_SetView(VF_PERSPECTIVE, 1);
1355                 makevectors('0 0 0');
1356                 vector v1, v2;
1357                 cvar_set("vid_conwidth", "800");
1358                 cvar_set("vid_conheight", "600");
1359                 v1 = cs_project(v_forward);
1360                 cvar_set("vid_conwidth", "640");
1361                 cvar_set("vid_conheight", "480");
1362                 v2 = cs_project(v_forward);
1363                 if(v1 == v2)
1364                         cs_project_is_b0rked = 1;
1365                 else
1366                         cs_project_is_b0rked = -1;
1367                 cvar_set("vid_conwidth", w0);
1368                 cvar_set("vid_conheight", h0);
1369         }
1370
1371         if(autocvar__hud_configure)
1372                 HUD_Panel_Mouse();
1373
1374     if(hud && !intermission)
1375     {
1376         if(hud == HUD_SPIDERBOT)
1377             CSQC_SPIDER_HUD();
1378         else if(hud == HUD_WAKIZASHI)
1379             CSQC_WAKIZASHI_HUD();
1380         else if(hud == HUD_RAPTOR)
1381             CSQC_RAPTOR_HUD();
1382         else if(hud == HUD_BUMBLEBEE)
1383             CSQC_BUMBLE_HUD();
1384     }
1385         // let's reset the view back to normal for the end
1386         R_SetView(VF_MIN, '0 0 0');
1387         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1388 }
1389
1390
1391 void CSQC_common_hud(void)
1392 {
1393     // do some accuracy var caching
1394     float i;
1395     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1396     {
1397         if(autocvar_accuracy_color_levels != acc_color_levels)
1398         {
1399             if(acc_color_levels)
1400                 strunzone(acc_color_levels);
1401             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1402             acc_levels = tokenize(acc_color_levels);
1403             if (acc_levels > MAX_ACCURACY_LEVELS)
1404                 acc_levels = MAX_ACCURACY_LEVELS;
1405
1406             for (i = 0; i < acc_levels; ++i)
1407                 acc_lev[i] = stof(argv(i)) / 100.0;
1408         }
1409         // let know that acc_col[] needs to be loaded
1410         acc_col_x[0] = -1;
1411     }
1412
1413     HUD_Main(); // always run these functions for alpha checks
1414     HUD_DrawScoreboard();
1415
1416     if (scoreboard_active) // scoreboard/accuracy
1417     {
1418         HUD_Reset();
1419         // HUD_DrawScoreboard takes care of centerprint_start
1420     }
1421     else if (intermission == 2) // map voting screen
1422     {
1423         HUD_FinaleOverlay();
1424         HUD_Reset();
1425
1426         centerprint_start_x = 0;
1427         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1428     }
1429     else // hud
1430     {
1431         centerprint_start_x = 0;
1432         centerprint_start_y = autocvar_scr_centerpos * vid_conheight;
1433     }
1434
1435         /*
1436         switch(hud)
1437         {
1438                 case HUD_SPIDERBOT:
1439                         CSQC_SPIDER_HUD();
1440                         break;
1441
1442                 case HUD_WAKIZASHI:
1443                         CSQC_WAKIZASHI_HUD();
1444                         break;
1445
1446         case HUD_BUMBLEBEE:
1447             CSQC_BUMBLE_HUD();
1448             break;
1449         }
1450         */
1451
1452     HUD_DrawCenterPrint();
1453
1454 }
1455
1456
1457 // following vectors must be global to allow seamless switching between camera modes
1458 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1459 void CSQC_Demo_Camera()
1460 {
1461         float speed, attenuation, dimensions;
1462         vector tmp, delta;
1463
1464         if( autocvar_camera_reset || !camera_mode )
1465         {
1466                 camera_offset = '0 0 0';
1467                 current_angles = '0 0 0';
1468                 camera_direction = '0 0 0';
1469                 camera_offset_z += 30;
1470                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1471                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1472                 current_origin = view_origin;
1473                 current_camera_offset  = camera_offset;
1474                 cvar_set("camera_reset", "0");
1475                 camera_mode = CAMERA_CHASE;
1476         }
1477
1478         // Camera angles
1479         if( camera_roll )
1480                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1481
1482         if(autocvar_camera_look_player)
1483         {
1484                 local vector dir;
1485                 local float n;
1486
1487                 dir = normalize(view_origin - current_position);
1488                 n = mouse_angles_z;
1489                 mouse_angles = vectoangles(dir);
1490                 mouse_angles_x = mouse_angles_x * -1;
1491                 mouse_angles_z = n;
1492         }
1493         else
1494         {
1495                 tmp = getmousepos() * 0.1;
1496                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1497                 {
1498                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1499                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1500                 }
1501         }
1502
1503         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1504         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1505         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1506         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1507
1508         // Fix difference when angles don't have the same sign
1509         delta = '0 0 0';
1510         if(mouse_angles_y < -60 && current_angles_y > 60)
1511                 delta = '0 360 0';
1512         if(mouse_angles_y > 60 && current_angles_y < -60)
1513                 delta = '0 -360 0';
1514
1515         if(autocvar_camera_look_player)
1516                 attenuation = autocvar_camera_look_attenuation;
1517         else
1518                 attenuation = autocvar_camera_speed_attenuation;
1519
1520         attenuation = 1 / max(1, attenuation);
1521         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1522
1523         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1524         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1525         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1526         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1527
1528         // Camera position
1529         tmp = '0 0 0';
1530         dimensions = 0;
1531
1532         if( camera_direction_x )
1533         {
1534                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1535                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1536                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1537                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1538                 ++dimensions;
1539         }
1540
1541         if( camera_direction_y )
1542         {
1543                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1544                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1545                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1546                 ++dimensions;
1547         }
1548
1549         if( camera_direction_z )
1550         {
1551                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1552                 ++dimensions;
1553         }
1554
1555         if(autocvar_camera_free)
1556                 speed = autocvar_camera_speed_free;
1557         else
1558                 speed = autocvar_camera_speed_chase;
1559
1560         if(dimensions)
1561         {
1562                 speed = speed * sqrt(1 / dimensions);
1563                 camera_offset += tmp * speed;
1564         }
1565
1566         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1567
1568         // Camera modes
1569         if( autocvar_camera_free )
1570         {
1571                 if ( camera_mode == CAMERA_CHASE )
1572                 {
1573                         current_camera_offset = current_origin + current_camera_offset;
1574                         camera_offset = current_origin + camera_offset;
1575                 }
1576
1577                 camera_mode = CAMERA_FREE;
1578                 current_position = current_camera_offset;
1579         }
1580         else
1581         {
1582                 if ( camera_mode == CAMERA_FREE )
1583                 {
1584                         current_origin = view_origin;
1585                         camera_offset = camera_offset - current_origin;
1586                         current_camera_offset = current_camera_offset - current_origin;
1587                 }
1588
1589                 camera_mode = CAMERA_CHASE;
1590
1591                 if(autocvar_camera_chase_smoothly)
1592                         current_origin += (view_origin - current_origin) * attenuation;
1593                 else
1594                         current_origin = view_origin;
1595
1596                 current_position = current_origin + current_camera_offset;
1597         }
1598
1599         R_SetView(VF_ANGLES, current_angles);
1600         R_SetView(VF_ORIGIN, current_position);
1601 }