qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 void Porto_Draw()
   4 {
   5         vector p, dir, ang, q, nextdir;
   6         float idx, portal_number, portal1_idx;
   7
   8         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
   9                 return;
  10         if(g_balance_porto_secondary)
  11                 return;
  12         if(intermission == 1)
  13                 return;
  14         if(intermission == 2)
  15                 return;
  16         if (getstati(STAT_HEALTH) <= 0)
  17                 return;
  18
  19         dir = view_forward;
  20
  21         if(angles_held_status)
  22         {
  23                 makevectors(angles_held);
  24                 dir = v_forward;
  25         }
  26
  27         p = view_origin;
  28
  29         polyline[0] = p;
  30         idx = 1;
  31         portal_number = 0;
  32         nextdir = dir;
  33
  34         for(;;)
  35         {
  36                 dir = nextdir;
  37                 traceline(p, p + 65536 * dir, TRUE, porto);
  38                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  39                         return;
  40                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  41                 p = trace_endpos;
  42                 polyline[idx] = p;
  43                 ++idx;
  44                 if(idx >= 16)
  45                         return;
  46                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  47                         continue;
  48                 ++portal_number;
  49                 ang = vectoangles2(trace_plane_normal, dir);
  50                 ang_x = -ang_x;
  51                 makevectors(ang);
  52                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  53                         return;
  54                 if(portal_number == 1)
  55                 {
  56                         portal1_idx = idx;
  57                         if(portal_number >= 2)
  58                                 break;
  59                 }
  60         }
  61
  62         while(idx >= 2)
  63         {
  64                 p = polyline[idx-2];
  65                 q = polyline[idx-1];
  66                 if(idx == 2)
  67                         p = p - view_up * 16;
  68                 if(idx-1 >= portal1_idx)
  69                 {
  70                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  71                 }
  72                 else
  73                 {
  74                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  75                 }
  76                 --idx;
  77         }
  78 }
  79
  80 void Porto_Init()
  81 {
  82         porto = spawn();
  83         porto.classname = "porto";
  84         porto.draw = Porto_Draw;
  85         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  86 }
  87
  88 float drawtime;
  89 float avgspeed;
  90 vector GetCurrentFov(float fov)
  91 {
  92         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
  93         float velocityzoom, curspeed;
  94         vector v;
  95
  96         zoomsensitivity = autocvar_cl_zoomsensitivity;
  97         zoomfactor = autocvar_cl_zoomfactor;
  98         if(zoomfactor < 1 || zoomfactor > 16)
  99                 zoomfactor = 2.5;
 100         zoomspeed = autocvar_cl_zoomspeed;
 101         if(zoomspeed >= 0)
 102         if(zoomspeed < 0.5 || zoomspeed > 16)
 103                         zoomspeed = 3.5;
 104
 105         zoomdir = button_zoom;
 106         if(hud == HUD_NORMAL)
 107         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 108                 zoomdir += button_attack2;
 109         if(spectatee_status > 0 || isdemo())
 110         {
 111                 if(spectatorbutton_zoom)
 112                 {
 113                         if(zoomdir)
 114                                 zoomdir = 0;
 115                         else
 116                                 zoomdir = 1;
 117                 }
 118                 // fteqcc failed twice here already, don't optimize this
 119         }
 120
 121         if(zoomdir) { zoomin_effect = 0; }
 122
 123         if(camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else if(autocvar_cl_spawnzoom && zoomin_effect)
 128         {
 129                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 130
 131                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 132                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 133                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 134         }
 135         else
 136         {
 137                 if(zoomspeed < 0) // instant zoom
 138                 {
 139                         if(zoomdir)
 140                                 current_viewzoom = 1 / zoomfactor;
 141                         else
 142                                 current_viewzoom = 1;
 143                 }
 144                 else
 145                 {
 146                         if(zoomdir)
 147                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 148                         else
 149                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 150                 }
 151         }
 152
 153         if(almost_equals(current_viewzoom, 1))
 154                 current_zoomfraction = 0;
 155         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 156                 current_zoomfraction = 1;
 157         else
 158                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 159
 160         if(zoomsensitivity < 1)
 161                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 162         else
 163                 setsensitivityscale(1);
 164
 165         makevectors(view_angles);
 166
 167         if(autocvar_cl_velocityzoom && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 168         {
 169                 if(intermission) { curspeed = 0; }
 170                 else
 171                 {
 172                         v = pmove_vel;
 173                         if(csqcplayer)
 174                                 v = csqcplayer.velocity;
 175
 176                         switch(autocvar_cl_velocityzoom_type)
 177                         {
 178                                 case 3: curspeed = max(0, v_forward * v); break;
 179                                 case 2: curspeed = (v_forward * v); break;
 180                                 case 1: default: curspeed = vlen(v); break;
 181                         }
 182                 }
 183
 184                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 185                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 186                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 187
 188                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 189         }
 190         else
 191                 velocityzoom = 1;
 192
 193         float frustumx, frustumy, fovx, fovy;
 194         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 195         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 196         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 197         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 198
 199         return '1 0 0' * fovx + '0 1 0' * fovy;
 200 }
 201
 202 // this function must match W_SetupShot!
 203 float zoomscript_caught;
 204
 205 vector wcross_origin;
 206 float wcross_scale_prev, wcross_alpha_prev;
 207 vector wcross_color_prev;
 208 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 209 vector wcross_color_goal_prev;
 210 float wcross_changedonetime;
 211
 212 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 213 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 214 float wcross_name_changestarttime, wcross_name_changedonetime;
 215 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 216
 217 float wcross_ring_prev;
 218
 219 entity trueaim;
 220 entity trueaim_rifle;
 221
 222 #define SHOTTYPE_HITTEAM 1
 223 #define SHOTTYPE_HITOBSTRUCTION 2
 224 #define SHOTTYPE_HITWORLD 3
 225 #define SHOTTYPE_HITENEMY 4
 226
 227 void TrueAim_Init()
 228 {
 229         trueaim = spawn();
 230         trueaim.classname = "trueaim";
 231         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 232         trueaim_rifle = spawn();
 233         trueaim_rifle.classname = "trueaim_rifle";
 234         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 235 }
 236
 237 float EnemyHitCheck()
 238 {
 239         float t, n;
 240         wcross_origin = project_3d_to_2d(trace_endpos);
 241         wcross_origin_z = 0;
 242         if(trace_ent)
 243                 n = trace_ent.entnum;
 244         else
 245                 n = trace_networkentity;
 246         if(n < 1)
 247                 return SHOTTYPE_HITWORLD;
 248         if(n > maxclients)
 249                 return SHOTTYPE_HITWORLD;
 250         t = GetPlayerColor(n - 1);
 251         if(teamplay)
 252                 if(t == myteam)
 253                         return SHOTTYPE_HITTEAM;
 254         if(t == NUM_SPECTATOR)
 255                 return SHOTTYPE_HITWORLD;
 256         return SHOTTYPE_HITENEMY;
 257 }
 258
 259 float TrueAimCheck()
 260 {
 261         float nudge = 1; // added to traceline target and subtracted from result
 262         vector vecs, trueaimpoint, w_shotorg;
 263         vector mi, ma, dv;
 264         float shottype;
 265         entity ta;
 266         float mv;
 267
 268         mi = ma = '0 0 0';
 269         ta = trueaim;
 270         mv = MOVE_NOMONSTERS;
 271
 272         switch(activeweapon) // WEAPONTODO
 273         {
 274                 case WEP_TUBA: // no aim
 275                 case WEP_PORTO: // shoots from eye
 276                 case WEP_HOOK: // no trueaim
 277                 case WEP_MORTAR: // toss curve
 278                         return SHOTTYPE_HITWORLD;
 279                 case WEP_VORTEX:
 280                 case WEP_VAPORIZER:
 281                         mv = MOVE_NORMAL;
 282                         break;
 283                 case WEP_RIFLE:
 284                         ta = trueaim_rifle;
 285                         mv = MOVE_NORMAL;
 286                         if(zoomscript_caught)
 287                         {
 288                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 289                                 return EnemyHitCheck();
 290                         }
 291                         break;
 292                 case WEP_DEVASTATOR: // projectile has a size!
 293                         mi = '-3 -3 -3';
 294                         ma = '3 3 3';
 295                         break;
 296                 case WEP_FIREBALL: // projectile has a size!
 297                         mi = '-16 -16 -16';
 298                         ma = '16 16 16';
 299                         break;
 300                 case WEP_SEEKER: // projectile has a size!
 301                         mi = '-2 -2 -2';
 302                         ma = '2 2 2';
 303                         break;
 304                 case WEP_ELECTRO: // projectile has a size!
 305                         mi = '0 0 -3';
 306                         ma = '0 0 -3';
 307                         break;
 308         }
 309
 310         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 311
 312         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 313         trueaimpoint = trace_endpos;
 314
 315         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 316                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 317
 318         if(vecs_x > 0)
 319                 vecs_y = -vecs_y;
 320         else
 321                 vecs = '0 0 0';
 322
 323         dv = view_right * vecs_y + view_up * vecs_z;
 324         w_shotorg = view_origin + dv;
 325
 326         // now move the vecs forward as much as requested if possible
 327         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 328         w_shotorg = trace_endpos - view_forward * nudge;
 329
 330         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 331         shottype = EnemyHitCheck();
 332         if(shottype != SHOTTYPE_HITWORLD)
 333                 return shottype;
 334
 335 #if 0
 336         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 337         // or rather, I know why, but see no fix
 338         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 339                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 340                 return SHOTTYPE_HITOBSTRUCTION;
 341 #endif
 342
 343         return SHOTTYPE_HITWORLD;
 344 }
 345
 346 void CSQC_common_hud(void);
 347
 348 void PostInit(void);
 349 void CSQC_Demo_Camera();
 350 float HUD_WouldDrawScoreboard();
 351 float camera_mode;
 352 const float CAMERA_FREE = 1;
 353 const float CAMERA_CHASE = 2;
 354 float reticle_type;
 355 string reticle_image;
 356 string NextFrameCommand;
 357 void CSQC_SPIDER_HUD();
 358 void CSQC_RAPTOR_HUD();
 359
 360 vector freeze_org, freeze_ang;
 361 entity nightvision_noise, nightvision_noise2;
 362
 363 #define MAX_TIME_DIFF 5
 364 float pickup_crosshair_time, pickup_crosshair_size;
 365 float hit_time, typehit_time;
 366 float nextsound_hit_time, nextsound_typehit_time;
 367 float hitindication_crosshair_time, hitindication_crosshair_size;
 368 float use_vortex_chargepool;
 369
 370 float myhealth, myhealth_prev;
 371 float myhealth_flash;
 372
 373 float old_blurradius, old_bluralpha;
 374 float old_sharpen_intensity;
 375
 376 vector myhealth_gentlergb;
 377
 378 float contentavgalpha, liquidalpha_prev;
 379 vector liquidcolor_prev;
 380
 381 float eventchase_current_distance;
 382
 383 vector damage_blurpostprocess, content_blurpostprocess;
 384
 385 float checkfail[16];
 386
 387 float rainbow_last_flicker;
 388 vector rainbow_prev_color;
 389
 390 #define BUTTON_3 4
 391 #define BUTTON_4 8
 392 float cl_notice_run();
 393 float prev_myteam;
 394 void CSQC_UpdateView(float w, float h)
 395 {
 396         entity e;
 397         float fov;
 398         float f, i, j;
 399         vector v;
 400         vector vf_size, vf_min;
 401         float a;
 402
 403         execute_next_frame();
 404
 405         ++framecount;
 406
 407         hud = getstati(STAT_HUD);
 408
 409         if(autocvar__hud_showbinds_reload) // menu can set this one
 410         {
 411                 db_close(binddb);
 412                 binddb = db_create();
 413                 cvar_set("_hud_showbinds_reload", "0");
 414         }
 415
 416         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
 417                 view_quality = getproperty(VF_MINFPS_QUALITY);
 418         else
 419                 view_quality = 1;
 420
 421         button_attack2 = (input_buttons & BUTTON_3);
 422         button_zoom = (input_buttons & BUTTON_4);
 423
 424 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 425         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 426         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 427         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 428         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 429         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 430         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 431         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 432
 433         vf_size = getpropertyvec(VF_SIZE);
 434         vf_min = getpropertyvec(VF_MIN);
 435         vid_width = vf_size_x;
 436         vid_height = vf_size_y;
 437
 438         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
 439         vector splash_pos = '0 0 0', splash_size = '0 0 0';
 440
 441         WaypointSprite_Load();
 442
 443         CSQCPlayer_SetCamera();
 444
 445 #ifdef COMPAT_XON050_ENGINE
 446         if(spectatee_status)
 447                 myteam = GetPlayerColor(spectatee_status - 1);
 448         else
 449 #endif
 450                 myteam = GetPlayerColor(player_localentnum - 1);
 451
 452         if(myteam != prev_myteam)
 453         {
 454                 myteamcolors = colormapPaletteColor(myteam, 1);
 455                 for(i = 0; i < HUD_PANEL_NUM; ++i)
 456                         hud_panel[i].update_time = time;
 457                 prev_myteam = myteam;
 458         }
 459
 460         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 461
 462         float is_dead = (getstati(STAT_HEALTH) <= 0);
 463
 464         // FIXME do we need this hack?
 465         if(isdemo())
 466         {
 467                 // in demos, input_buttons do not work
 468                 button_zoom = (autocvar__togglezoom == "-");
 469         }
 470         else if(button_zoom
 471                 && autocvar_cl_unpress_zoom_on_death
 472                 && (spectatee_status >= 0)
 473                 && (is_dead || intermission))
 474         {
 475                 // no zoom while dead or in intermission please
 476                 localcmd("-zoom\n");
 477                 button_zoom = FALSE;
 478         }
 479
 480         // event chase camera
 481         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 482         {
 483                 if((spectatee_status >= 0 && (autocvar_cl_eventchase_death && is_dead)) || intermission)
 484                 {
 485                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 486                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 487
 488                         // detect maximum viewoffset and use it
 489                         if(autocvar_cl_eventchase_viewoffset)
 490                         {
 491                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs_z), MOVE_WORLDONLY, self);
 492                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
 493                                 else { current_view_origin_z += max(0, (trace_endpos_z - current_view_origin_z) - autocvar_cl_eventchase_maxs_z); }
 494                         }
 495
 496                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 497                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 498                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 499                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 500
 501                         // make the camera smooth back
 502                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 503                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 504                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 505                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 506
 507                         makevectors(view_angles);
 508
 509                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 510                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
 511
 512                         // If the boxtrace fails, revert back to line tracing.
 513                         if(trace_startsolid)
 514                         {
 515                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
 516                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 517                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins_z)));
 518                         }
 519                         else { setproperty(VF_ORIGIN, trace_endpos); }
 520
 521                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 522                 }
 523                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 524                 {
 525                         cvar_set("chase_active", "0");
 526                         eventchase_current_distance = 0; // start from 0 next time
 527                 }
 528         }
 529         // workaround for camera stuck between player's legs when using chase_active 1
 530         // because the engine stops updating the chase_active camera when the game ends
 531         else if(intermission)
 532         {
 533                 cvar_settemp("chase_active", "-1");
 534                 eventchase_current_distance = 0;
 535         }
 536
 537         // do lockview after event chase camera so that it still applies whenever necessary.
 538         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
 539         {
 540                 setproperty(VF_ORIGIN, freeze_org);
 541                 setproperty(VF_ANGLES, freeze_ang);
 542         }
 543         else
 544         {
 545                 freeze_org = getpropertyvec(VF_ORIGIN);
 546                 freeze_ang = getpropertyvec(VF_ANGLES);
 547         }
 548
 549         WarpZone_FixView();
 550         //WarpZone_FixPMove();
 551
 552         // Render the Scene
 553         view_origin = getpropertyvec(VF_ORIGIN);
 554         view_angles = getpropertyvec(VF_ANGLES);
 555         makevectors(view_angles);
 556         view_forward = v_forward;
 557         view_right = v_right;
 558         view_up = v_up;
 559
 560 #ifdef BLURTEST
 561         if(time > blurtest_time0 && time < blurtest_time1)
 562         {
 563                 float r, t;
 564
 565                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 566                 r = t * blurtest_radius;
 567                 f = 1 / pow(t, blurtest_power) - 1;
 568
 569                 cvar_set("r_glsl_postprocess", "1");
 570                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 571         }
 572         else
 573         {
 574                 cvar_set("r_glsl_postprocess", "0");
 575                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 576         }
 577 #endif
 578
 579         TargetMusic_Advance();
 580         Fog_Force();
 581
 582         if(drawtime == 0)
 583                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 584         else
 585                 drawframetime = bound(0.000001, time - drawtime, 1);
 586         drawtime = time;
 587
 588         // watch for gametype changes here...
 589         // in ParseStuffCMD the cmd isn't executed yet :/
 590         // might even be better to add the gametype to TE_CSQC_INIT...?
 591         if(!postinit)
 592                 PostInit();
 593
 594         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 595         {
 596                 if(calledhooks & HOOK_START)
 597                 {
 598                         localcmd("\ncl_hook_gameend\n");
 599                         calledhooks |= HOOK_END;
 600                 }
 601         }
 602
 603         Announcer();
 604
 605         fov = autocvar_fov;
 606         if(fov <= 59.5)
 607         {
 608                 if(!zoomscript_caught)
 609                 {
 610                         localcmd("+button9\n");
 611                         zoomscript_caught = 1;
 612                 }
 613         }
 614         else
 615         {
 616                 if(zoomscript_caught)
 617                 {
 618                         localcmd("-button9\n");
 619                         zoomscript_caught = 0;
 620                 }
 621         }
 622
 623         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 624
 625         // next WANTED weapon (for HUD)
 626         switchweapon = getstati(STAT_SWITCHWEAPON);
 627
 628         // currently switching-to weapon (for crosshair)
 629         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 630
 631         // actually active weapon (for zoom)
 632         activeweapon = getstati(STAT_ACTIVEWEAPON);
 633
 634         f = (serverflags & SERVERFLAG_TEAMPLAY);
 635         if(f != teamplay)
 636         {
 637                 teamplay = f;
 638                 HUD_InitScores();
 639         }
 640
 641         if(last_switchweapon != switchweapon)
 642         {
 643                 weapontime = time;
 644                 last_switchweapon = switchweapon;
 645                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
 646                 {
 647                         localcmd("-zoom\n");
 648                         button_zoom = FALSE;
 649                 }
 650                 if(autocvar_cl_unpress_attack_on_weapon_switch)
 651                 {
 652                         localcmd("-fire\n");
 653                         localcmd("-fire2\n");
 654                         button_attack2 = FALSE;
 655                 }
 656         }
 657         if(last_activeweapon != activeweapon)
 658         {
 659                 last_activeweapon = activeweapon;
 660
 661                 e = get_weaponinfo(activeweapon);
 662                 if(e.netname != "")
 663                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 664                 else
 665                         localcmd("\ncl_hook_activeweapon none\n");
 666         }
 667
 668         // ALWAYS Clear Current Scene First
 669         clearscene();
 670 #ifdef WORKAROUND_XON010
 671         if(checkextension("DP_CSQC_ROTATEMOVES"))
 672         {
 673 #endif
 674         setproperty(VF_ORIGIN, view_origin);
 675         setproperty(VF_ANGLES, view_angles);
 676 #ifdef WORKAROUND_XON010
 677         }
 678 #endif
 679
 680         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 681         setproperty(VF_SIZE, vf_size);
 682         setproperty(VF_MIN, vf_min);
 683
 684         // Assign Standard Viewflags
 685         // Draw the World (and sky)
 686         setproperty(VF_DRAWWORLD, 1);
 687
 688         // Set the console size vars
 689         vid_conwidth = autocvar_vid_conwidth;
 690         vid_conheight = autocvar_vid_conheight;
 691         vid_pixelheight = autocvar_vid_pixelheight;
 692
 693         setproperty(VF_FOV, GetCurrentFov(fov));
 694
 695         // Camera for demo playback
 696         if(camera_active)
 697         {
 698                 if(autocvar_camera_enable)
 699                         CSQC_Demo_Camera();
 700                 else
 701                 {
 702                         cvar_set("chase_active", ftos(chase_active_backup));
 703                         cvar_set("cl_demo_mousegrab", "0");
 704                         camera_active = FALSE;
 705                 }
 706         }
 707 #ifdef CAMERATEST
 708         else if(autocvar_camera_enable)
 709 #else
 710         else if(autocvar_camera_enable && isdemo())
 711 #endif
 712         {
 713                 // Enable required Darkplaces cvars
 714                 chase_active_backup = autocvar_chase_active;
 715                 cvar_set("chase_active", "2");
 716                 cvar_set("cl_demo_mousegrab", "1");
 717                 camera_active = TRUE;
 718                 camera_mode = FALSE;
 719         }
 720
 721         // Draw the Crosshair
 722         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 723
 724         // Draw the Engine Status Bar (the default Quake HUD)
 725         setproperty(VF_DRAWENGINESBAR, 0);
 726
 727         // Update the mouse position
 728         /*
 729            mousepos_x = vid_conwidth;
 730            mousepos_y = vid_conheight;
 731            mousepos = mousepos*0.5 + getmousepos();
 732          */
 733
 734         e = self;
 735         for(self = world; (self = nextent(self)); )
 736                 if(self.draw)
 737                         self.draw();
 738         self = e;
 739
 740         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 741         renderscene();
 742
 743         // now switch to 2D drawing mode by calling a 2D drawing function
 744         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 745         // next R_RenderScene call
 746         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 747
 748         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 749         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
 750         {
 751                 // apply night vision effect
 752                 vector tc_00, tc_01, tc_10, tc_11;
 753                 vector rgb;
 754                 rgb_x = 0; // fteqcc sucks
 755                 rgb_y = 0; // fteqcc sucks
 756                 rgb_z = 0; // fteqcc sucks
 757
 758                 if(!nightvision_noise)
 759                 {
 760                         nightvision_noise = spawn();
 761                         nightvision_noise.classname = "nightvision_noise";
 762                 }
 763                 if(!nightvision_noise2)
 764                 {
 765                         nightvision_noise2 = spawn();
 766                         nightvision_noise2.classname = "nightvision_noise2";
 767                 }
 768
 769                 // color tint in yellow
 770                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 771
 772                 // draw BG
 773                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 774                 rgb = '1 1 1';
 775                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 776                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 777                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 778                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 779                 tc_11 = tc_01 + tc_10 - tc_00;
 780                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 781                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 782                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 783                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 784                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 785                 R_EndPolygon();
 786
 787                 // draw FG
 788                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 789                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 790                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 791                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 792                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 793                 tc_11 = tc_01 + tc_10 - tc_00;
 794                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 795                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 796                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 797                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 798                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 799                 R_EndPolygon();
 800         }
 801
 802         if(autocvar_cl_reticle)
 803         {
 804                 // Draw the aiming reticle for weapons that use it
 805                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 806                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 807                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
 808                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
 809                 {
 810                         // no zoom reticle while dead
 811                         reticle_type = 0;
 812                 }
 813                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
 814                 {
 815                         if(reticle_image != "") { reticle_type = 2; }
 816                         else { reticle_type = 0; }
 817                 }
 818                 else if(button_zoom || zoomscript_caught)
 819                 {
 820                         // normal zoom
 821                         reticle_type = 1;
 822                 }
 823
 824                 if(reticle_type)
 825                 {
 826                         if(autocvar_cl_reticle_stretch)
 827                         {
 828                                 reticle_size_x = vid_conwidth;
 829                                 reticle_size_y = vid_conheight;
 830                                 reticle_pos_x = 0;
 831                                 reticle_pos_y = 0;
 832                         }
 833                         else
 834                         {
 835                                 reticle_size_x = max(vid_conwidth, vid_conheight);
 836                                 reticle_size_y = max(vid_conwidth, vid_conheight);
 837                                 reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 838                                 reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 839                         }
 840
 841                         if(zoomscript_caught)
 842                                 f = 1;
 843                         else
 844                                 f = current_zoomfraction;
 845
 846                         if(f)
 847                         {
 848                                 switch(reticle_type)
 849                                 {
 850                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
 851                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
 852                                 }
 853                         }
 854                 }
 855         }
 856         else
 857         {
 858                 if(reticle_type != 0) { reticle_type = 0; }
 859         }
 860
 861
 862         // improved polyblend
 863         if(autocvar_hud_contents)
 864         {
 865                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 866                 vector liquidcolor;
 867
 868                 switch(pointcontents(view_origin))
 869                 {
 870                         case CONTENT_WATER:
 871                                 liquidalpha = autocvar_hud_contents_water_alpha;
 872                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 873                                 incontent = 1;
 874                                 break;
 875
 876                         case CONTENT_LAVA:
 877                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 878                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 879                                 incontent = 1;
 880                                 break;
 881
 882                         case CONTENT_SLIME:
 883                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 884                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 885                                 incontent = 1;
 886                                 break;
 887
 888                         default:
 889                                 liquidalpha = 0;
 890                                 liquidcolor = '0 0 0';
 891                                 incontent = 0;
 892                                 break;
 893                 }
 894
 895                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 896                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 897                         contentfadetime = autocvar_hud_contents_fadeintime;
 898                         liquidalpha_prev = liquidalpha;
 899                         liquidcolor_prev = liquidcolor;
 900                 }
 901                 else
 902                         contentfadetime = autocvar_hud_contents_fadeouttime;
 903
 904                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 905                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 906
 907                 if(contentavgalpha)
 908                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 909
 910                 if(autocvar_hud_postprocessing)
 911                 {
 912                         if(autocvar_hud_contents_blur && contentavgalpha)
 913                         {
 914                                 content_blurpostprocess_x = 1;
 915                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 916                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 917                         }
 918                         else
 919                         {
 920                                 content_blurpostprocess_x = 0;
 921                                 content_blurpostprocess_y = 0;
 922                                 content_blurpostprocess_z = 0;
 923                         }
 924                 }
 925         }
 926
 927         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
 928         {
 929                 splash_size_x = max(vid_conwidth, vid_conheight);
 930                 splash_size_y = max(vid_conwidth, vid_conheight);
 931                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 932                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 933
 934                 float myhealth_flash_temp;
 935                 myhealth = getstati(STAT_HEALTH);
 936
 937                 // fade out
 938                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 939                 // add new damage
 940                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 941
 942                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 943                 pain_threshold = autocvar_hud_damage_pain_threshold;
 944                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 945                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 946
 947                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 948                 {
 949                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 950                 }
 951
 952                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 953
 954                 if(myhealth_prev < 1)
 955                 {
 956                         if(myhealth >= 1)
 957                         {
 958                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 959                                 myhealth_flash_temp = 0;
 960                         }
 961                         else
 962                         {
 963                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 964                         }
 965                 }
 966
 967                 if(spectatee_status == -1 || intermission)
 968                 {
 969                         myhealth_flash = 0; // observing, or match ended
 970                         myhealth_flash_temp = 0;
 971                 }
 972
 973                 myhealth_prev = myhealth;
 974
 975                 // IDEA: change damage color/picture based on player model for robot/alien species?
 976                 // pro: matches model better
 977                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 978                 // maybe different reddish pics?
 979                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 980                 {
 981                         if(autocvar_cl_gentle_damage == 2)
 982                         {
 983                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 984                                 {
 985                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 986                                 }
 987                         }
 988                         else
 989                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 990
 991                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 992                 }
 993                 else
 994                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 995
 996                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 997                 {
 998                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 999                         {
1000                                 damage_blurpostprocess_x = 1;
1001                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1002                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1003                         }
1004                         else
1005                         {
1006                                 damage_blurpostprocess_x = 0;
1007                                 damage_blurpostprocess_y = 0;
1008                                 damage_blurpostprocess_z = 0;
1009                         }
1010                 }
1011         }
1012
1013         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1014         float e2 = (autocvar_hud_powerup != 0);
1015         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1016         {
1017                 // enable or disable rendering types if they are used or not
1018                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1019                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1020
1021                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1022                 if((damage_blurpostprocess_x || content_blurpostprocess_x))
1023                 {
1024                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
1025                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
1026                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1027                         {
1028                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1029                                 old_blurradius = blurradius;
1030                                 old_bluralpha = bluralpha;
1031                         }
1032                 }
1033                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1034                 {
1035                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1036                         old_blurradius = 0;
1037                         old_bluralpha = 0;
1038                 }
1039
1040                 // edge detection postprocess handling done second (used by hud_powerup)
1041                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1042                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1043                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1044
1045                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1046
1047                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1048                 {
1049                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1050                         {
1051                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1052                                 old_sharpen_intensity = sharpen_intensity;
1053                         }
1054                 }
1055                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1056                 {
1057                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1058                         old_sharpen_intensity = 0;
1059                 }
1060
1061                 if(cvar("r_glsl_postprocess") == 0)
1062                         cvar_set("r_glsl_postprocess", "2");
1063         }
1064         else if(cvar("r_glsl_postprocess") == 2)
1065                 cvar_set("r_glsl_postprocess", "0");
1066
1067         if(menu_visible)
1068                 menu_show();
1069
1070         /*if(gametype == MAPINFO_TYPE_CTF)
1071           {
1072           ctf_view();
1073           } else */
1074
1075         // draw 2D entities
1076         e = self;
1077         for(self = world; (self = nextent(self)); )
1078                 if(self.draw2d)
1079                         self.draw2d();
1080         self = e;
1081         Draw_ShowNames_All();
1082
1083         scoreboard_active = HUD_WouldDrawScoreboard();
1084
1085         hit_time = getstatf(STAT_HIT_TIME);
1086         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
1087         {
1088                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1089                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTEN_NONE);
1090
1091                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
1092         }
1093         typehit_time = getstatf(STAT_TYPEHIT_TIME);
1094         if(typehit_time > nextsound_typehit_time)
1095         {
1096                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
1097                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTEN_NONE);
1098
1099                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
1100         }
1101
1102         //else
1103         {
1104                 if(gametype == MAPINFO_TYPE_FREEZETAG)
1105                 {
1106                         if(getstati(STAT_FROZEN))
1107                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1108                         if(getstatf(STAT_REVIVE_PROGRESS))
1109                         {
1110                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1111                                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1112                         }
1113                 }
1114
1115                 if(autocvar_r_letterbox == 0)
1116                         if(autocvar_viewsize < 120)
1117                                 CSQC_common_hud();
1118
1119                 // crosshair goes VERY LAST
1120                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
1121                 {
1122                         if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1123                                 return;
1124
1125                         string wcross_style;
1126                         float wcross_alpha, wcross_resolution;
1127                         wcross_style = autocvar_crosshair;
1128                         if (wcross_style == "0")
1129                                 return;
1130                         wcross_resolution = autocvar_crosshair_size;
1131                         if (wcross_resolution == 0)
1132                                 return;
1133                         wcross_alpha = autocvar_crosshair_alpha;
1134                         if (wcross_alpha == 0)
1135                                 return;
1136
1137                         // TrueAim check
1138                         float shottype;
1139
1140                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1141                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1142                         wcross_origin_z = 0;
1143                         if(autocvar_crosshair_hittest)
1144                         {
1145                                 vector wcross_oldorigin;
1146                                 wcross_oldorigin = wcross_origin;
1147                                 shottype = TrueAimCheck();
1148                                 if(shottype == SHOTTYPE_HITWORLD)
1149                                 {
1150                                         v = wcross_origin - wcross_oldorigin;
1151                                         v_x /= vid_conwidth;
1152                                         v_y /= vid_conheight;
1153                                         if(vlen(v) > 0.01)
1154                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1155                                 }
1156                                 if(!autocvar_crosshair_hittest_showimpact)
1157                                         wcross_origin = wcross_oldorigin;
1158                         }
1159                         else
1160                                 shottype = SHOTTYPE_HITWORLD;
1161
1162                         vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1163                         string wcross_wep = "", wcross_name;
1164                         float wcross_scale, wcross_blur;
1165
1166                         if (autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1167                         {
1168                                 e = get_weaponinfo(switchingweapon);
1169                                 if (e && e.netname != "")
1170                                 {
1171                                         wcross_wep = e.netname;
1172                                         if(autocvar_crosshair_per_weapon)
1173                                         {
1174                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1175                                                 if (wcross_resolution == 0)
1176                                                         return;
1177                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1178                                                 if (wcross_alpha == 0)
1179                                                         return;
1180
1181                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1182                                                 if(wcross_style == "" || wcross_style == "0")
1183                                                         wcross_style = wcross_wep;
1184                                         }
1185                                 }
1186                         }
1187
1188                         //print(sprintf("crosshair style: %s\n", wcross_style));
1189                         wcross_name = strcat("gfx/crosshair", wcross_style);
1190
1191                         // MAIN CROSSHAIR COLOR DECISION
1192                         switch(autocvar_crosshair_color_special)
1193                         {
1194                                 case 1: // crosshair_color_per_weapon
1195                                 {
1196                                         if(wcross_wep != "")
1197                                         {
1198                                                 wcross_color = stov(cvar_string(sprintf("crosshair_%s_color", wcross_wep)));
1199                                                 break;
1200                                         }
1201                                         else { goto normalcolor; }
1202                                 }
1203
1204                                 case 2: // crosshair_color_by_health
1205                                 {
1206                                         float x = getstati(STAT_HEALTH);
1207
1208                                         //x = red
1209                                         //y = green
1210                                         //z = blue
1211
1212                                         wcross_color_z = 0;
1213
1214                                         if(x > 200)
1215                                         {
1216                                                 wcross_color_x = 0;
1217                                                 wcross_color_y = 1;
1218                                         }
1219                                         else if(x > 150)
1220                                         {
1221                                                 wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1222                                                 wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1223                                         }
1224                                         else if(x > 100)
1225                                         {
1226                                                 wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1227                                                 wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1228                                                 wcross_color_z = 1 - (x-100)*0.02;
1229                                         }
1230                                         else if(x > 50)
1231                                         {
1232                                                 wcross_color_x = 1;
1233                                                 wcross_color_y = 1;
1234                                                 wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1235                                         }
1236                                         else if(x > 20)
1237                                         {
1238                                                 wcross_color_x = 1;
1239                                                 wcross_color_y = (x-20)*90/27/100;
1240                                                 wcross_color_z = (x-20)*90/27/100 * 0.2;
1241                                         }
1242                                         else
1243                                         {
1244                                                 wcross_color_x = 1;
1245                                                 wcross_color_y = 0;
1246                                         }
1247                                         break;
1248                                 }
1249
1250                                 case 3: // crosshair_color_rainbow
1251                                 {
1252                                         if(time >= rainbow_last_flicker)
1253                                         {
1254                                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1255                                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1256                                         }
1257                                         wcross_color = rainbow_prev_color;
1258                                         break;
1259                                 }
1260                                 :normalcolor
1261                                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1262                         }
1263
1264                         if(autocvar_crosshair_effect_scalefade)
1265                         {
1266                                 wcross_scale = wcross_resolution;
1267                                 wcross_resolution = 1;
1268                         }
1269                         else
1270                         {
1271                                 wcross_scale = 1;
1272                         }
1273
1274                         if(autocvar_crosshair_pickup)
1275                         {
1276                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1277
1278                                 if(pickup_crosshair_time < stat_pickup_time)
1279                                 {
1280                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1281                                                 pickup_crosshair_size = 1;
1282
1283                                         pickup_crosshair_time = stat_pickup_time;
1284                                 }
1285
1286                                 if(pickup_crosshair_size > 0)
1287                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1288                                 else
1289                                         pickup_crosshair_size = 0;
1290
1291                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1292                         }
1293
1294                         if(autocvar_crosshair_hitindication)
1295                         {
1296                                 vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1297
1298                                 if(hitindication_crosshair_time < hit_time)
1299                                 {
1300                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1301                                                 hitindication_crosshair_size = 1;
1302
1303                                         hitindication_crosshair_time = hit_time;
1304                                 }
1305
1306                                 if(hitindication_crosshair_size > 0)
1307                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1308                                 else
1309                                         hitindication_crosshair_size = 0;
1310
1311                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1312                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1313                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1314                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1315                         }
1316
1317                         if(shottype == SHOTTYPE_HITENEMY)
1318                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1319                         if(shottype == SHOTTYPE_HITTEAM)
1320                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1321
1322                         f = fabs(autocvar_crosshair_effect_time);
1323                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1324                         {
1325                                 wcross_changedonetime = time + f;
1326                         }
1327                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1328                         {
1329                                 wcross_name_changestarttime = time;
1330                                 wcross_name_changedonetime = time + f;
1331                                 if(wcross_name_goal_prev_prev)
1332                                         strunzone(wcross_name_goal_prev_prev);
1333                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1334                                 wcross_name_goal_prev = strzone(wcross_name);
1335                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1336                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1337                                 wcross_resolution_goal_prev = wcross_resolution;
1338                         }
1339
1340                         wcross_scale_goal_prev = wcross_scale;
1341                         wcross_alpha_goal_prev = wcross_alpha;
1342                         wcross_color_goal_prev = wcross_color;
1343
1344                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1345                         {
1346                                 wcross_blur = 1;
1347                                 wcross_alpha *= 0.75;
1348                         }
1349                         else
1350                                 wcross_blur = 0;
1351                         // *_prev is at time-frametime
1352                         // * is at wcross_changedonetime+f
1353                         // what do we have at time?
1354                         if(time < wcross_changedonetime)
1355                         {
1356                                 f = frametime / (wcross_changedonetime - time + frametime);
1357                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1358                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1359                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1360                         }
1361
1362                         wcross_scale_prev = wcross_scale;
1363                         wcross_alpha_prev = wcross_alpha;
1364                         wcross_color_prev = wcross_color;
1365
1366                         wcross_scale *= 1 - autocvar__menu_alpha;
1367                         wcross_alpha *= 1 - autocvar__menu_alpha;
1368                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1369
1370                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1371                         {
1372                                 // crosshair rings for weapon stats
1373                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1374                                 {
1375                                         // declarations and stats
1376                                         float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1377                                         string ring_image = string_null, ring_inner_image = string_null;
1378                                         vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1379
1380                                         ring_scale = autocvar_crosshair_ring_size;
1381
1382                                         float weapon_clipload, weapon_clipsize;
1383                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1384                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1385
1386                                         float vortex_charge, vortex_chargepool;
1387                                         vortex_charge = getstatf(STAT_VORTEX_CHARGE);
1388                                         vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
1389
1390                                         if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1391                                                 vortex_charge_movingavg = vortex_charge;
1392
1393
1394                                         // handle the values
1395                                         if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1396                                         {
1397                                                 if (vortex_chargepool || use_vortex_chargepool) {
1398                                                         use_vortex_chargepool = 1;
1399                                                         ring_inner_value = vortex_chargepool;
1400                                                 } else {
1401                                                         vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1402                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1403                                                 }
1404
1405                                                 ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1406                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1407                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1408
1409                                                 // draw the outer ring to show the current charge of the weapon
1410                                                 ring_value = vortex_charge;
1411                                                 ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1412                                                 ring_rgb = wcross_color;
1413                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1414                                         }
1415                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1416                                         {
1417                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1418                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1419                                                 ring_rgb = wcross_color;
1420                                                 ring_image = "gfx/crosshair_ring.tga";
1421                                         }
1422                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1423                                         {
1424                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1425                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1426                                                 ring_rgb = wcross_color;
1427                                                 ring_image = "gfx/crosshair_ring.tga";
1428                                         }
1429
1430                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1431                                         {
1432                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1433                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1434                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1435                                                 ring_rgb = wcross_color;
1436
1437                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1438                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1439                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1440                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1441                                                 else
1442                                                         ring_image = "gfx/crosshair_ring.tga";
1443                                         }
1444
1445                                         // if in weapon switch animation, fade ring out/in
1446                                         if(autocvar_crosshair_effect_time > 0)
1447                                         {
1448                                                 f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1449                                                 if (!(f < 1))
1450                                                 {
1451                                                         wcross_ring_prev = ((ring_image) ? TRUE : FALSE);
1452                                                 }
1453
1454                                                 if(wcross_ring_prev)
1455                                                 {
1456                                                         if(f < 1)
1457                                                                 ring_alpha *= fabs(1 - bound(0, f, 1));
1458                                                 }
1459                                                 else
1460                                                 {
1461                                                         if(f < 1)
1462                                                                 ring_alpha *= bound(0, f, 1);
1463                                                 }
1464                                         }
1465
1466                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1467                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1468
1469                                         if (ring_value)
1470                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1471                                 }
1472
1473 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1474                                 do \
1475                                 { \
1476                                         if(wcross_blur > 0) \
1477                                         { \
1478                                                 for(i = -2; i <= 2; ++i) \
1479                                                 for(j = -2; j <= 2; ++j) \
1480                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1481                                         } \
1482                                         else \
1483                                         { \
1484                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1485                                         } \
1486                                 } \
1487                                 while(0)
1488
1489 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1490                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1491
1492 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1493                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1494
1495                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1496                                 {
1497                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1498                                         wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1499                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1500                                         f = 1 - f;
1501                                 }
1502                                 else
1503                                 {
1504                                         f = 1;
1505                                 }
1506                                 wcross_name_alpha_goal_prev = f;
1507
1508                                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1509                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1510
1511                                 if(autocvar_crosshair_dot)
1512                                 {
1513                                         vector wcross_color_old;
1514                                         wcross_color_old = wcross_color;
1515
1516                                         if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1517                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1518
1519                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1520                                         // FIXME why don't we use wcross_alpha here?cl_notice_run();
1521                                         wcross_color = wcross_color_old;
1522                                 }
1523                         }
1524                 }
1525                 else
1526                 {
1527                         wcross_scale_prev = 0;
1528                         wcross_alpha_prev = 0;
1529                         wcross_scale_goal_prev = 0;
1530                         wcross_alpha_goal_prev = 0;
1531                         wcross_changedonetime = 0;
1532                         if(wcross_name_goal_prev)
1533                                 strunzone(wcross_name_goal_prev);
1534                         wcross_name_goal_prev = string_null;
1535                         if(wcross_name_goal_prev_prev)
1536                                 strunzone(wcross_name_goal_prev_prev);
1537                         wcross_name_goal_prev_prev = string_null;
1538                         wcross_name_changestarttime = 0;
1539                         wcross_name_changedonetime = 0;
1540                         wcross_name_alpha_goal_prev = 0;
1541                         wcross_name_alpha_goal_prev_prev = 0;
1542                         wcross_resolution_goal_prev = 0;
1543                         wcross_resolution_goal_prev_prev = 0;
1544                 }
1545         }
1546
1547         if(NextFrameCommand)
1548         {
1549                 localcmd("\n", NextFrameCommand, "\n");
1550                 NextFrameCommand = string_null;
1551         }
1552
1553         // we must do this check AFTER a frame was rendered, or it won't work
1554         if(cs_project_is_b0rked == 0)
1555         {
1556                 string w0, h0;
1557                 w0 = ftos(autocvar_vid_conwidth);
1558                 h0 = ftos(autocvar_vid_conheight);
1559                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1560                 //setproperty(VF_FOV, '90 90 0');
1561                 setproperty(VF_ORIGIN, '0 0 0');
1562                 setproperty(VF_ANGLES, '0 0 0');
1563                 setproperty(VF_PERSPECTIVE, 1);
1564                 makevectors('0 0 0');
1565                 vector v1, v2;
1566                 cvar_set("vid_conwidth", "800");
1567                 cvar_set("vid_conheight", "600");
1568                 v1 = cs_project(v_forward);
1569                 cvar_set("vid_conwidth", "640");
1570                 cvar_set("vid_conheight", "480");
1571                 v2 = cs_project(v_forward);
1572                 if(v1 == v2)
1573                         cs_project_is_b0rked = 1;
1574                 else
1575                         cs_project_is_b0rked = -1;
1576                 cvar_set("vid_conwidth", w0);
1577                 cvar_set("vid_conheight", h0);
1578         }
1579
1580         if(autocvar__hud_configure)
1581                 HUD_Panel_Mouse();
1582
1583     if(hud && !intermission)
1584     {
1585         if(hud == HUD_SPIDERBOT)
1586             CSQC_SPIDER_HUD();
1587         else if(hud == HUD_WAKIZASHI)
1588             CSQC_WAKIZASHI_HUD();
1589         else if(hud == HUD_RAPTOR)
1590             CSQC_RAPTOR_HUD();
1591         else if(hud == HUD_BUMBLEBEE)
1592             CSQC_BUMBLE_HUD();
1593         else if(hud == HUD_BUMBLEBEE_GUN)
1594             CSQC_BUMBLE_GUN_HUD();
1595     }
1596
1597         cl_notice_run();
1598
1599         // let's reset the view back to normal for the end
1600         setproperty(VF_MIN, '0 0 0');
1601         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1602 }
1603
1604
1605 void CSQC_common_hud(void)
1606 {
1607         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1608                 Accuracy_LoadLevels();
1609
1610     HUD_Main(); // always run these functions for alpha checks
1611     HUD_DrawScoreboard();
1612
1613     if (scoreboard_active) // scoreboard/accuracy
1614         HUD_Reset();
1615     else if (intermission == 2) // map voting screen
1616     {
1617         HUD_FinaleOverlay();
1618         HUD_Reset();
1619     }
1620         /*
1621         switch(hud)
1622         {
1623                 case HUD_SPIDERBOT:
1624                         CSQC_SPIDER_HUD();
1625                         break;
1626
1627                 case HUD_WAKIZASHI:
1628                         CSQC_WAKIZASHI_HUD();
1629                         break;
1630
1631         case HUD_BUMBLEBEE:
1632             CSQC_BUMBLE_HUD();
1633             break;
1634         }
1635         */
1636 }
1637
1638
1639 // following vectors must be global to allow seamless switching between camera modes
1640 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1641 void CSQC_Demo_Camera()
1642 {
1643         float speed, attenuation, dimensions;
1644         vector tmp, delta;
1645
1646         if( autocvar_camera_reset || !camera_mode )
1647         {
1648                 camera_offset = '0 0 0';
1649                 current_angles = '0 0 0';
1650                 camera_direction = '0 0 0';
1651                 camera_offset_z += 30;
1652                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1653                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1654                 current_origin = view_origin;
1655                 current_camera_offset  = camera_offset;
1656                 cvar_set("camera_reset", "0");
1657                 camera_mode = CAMERA_CHASE;
1658         }
1659
1660         // Camera angles
1661         if( camera_roll )
1662                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1663
1664         if(autocvar_camera_look_player)
1665         {
1666                 vector dir;
1667                 float n;
1668
1669                 dir = normalize(view_origin - current_position);
1670                 n = mouse_angles_z;
1671                 mouse_angles = vectoangles(dir);
1672                 mouse_angles_x = mouse_angles_x * -1;
1673                 mouse_angles_z = n;
1674         }
1675         else
1676         {
1677                 tmp = getmousepos() * 0.1;
1678                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1679                 {
1680                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1681                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1682                 }
1683         }
1684
1685         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1686         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1687         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1688         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1689
1690         // Fix difference when angles don't have the same sign
1691         delta = '0 0 0';
1692         if(mouse_angles_y < -60 && current_angles_y > 60)
1693                 delta = '0 360 0';
1694         if(mouse_angles_y > 60 && current_angles_y < -60)
1695                 delta = '0 -360 0';
1696
1697         if(autocvar_camera_look_player)
1698                 attenuation = autocvar_camera_look_attenuation;
1699         else
1700                 attenuation = autocvar_camera_speed_attenuation;
1701
1702         attenuation = 1 / max(1, attenuation);
1703         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1704
1705         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1706         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1707         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1708         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1709
1710         // Camera position
1711         tmp = '0 0 0';
1712         dimensions = 0;
1713
1714         if( camera_direction_x )
1715         {
1716                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1717                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1718                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1719                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1720                 ++dimensions;
1721         }
1722
1723         if( camera_direction_y )
1724         {
1725                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1726                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1727                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1728                 ++dimensions;
1729         }
1730
1731         if( camera_direction_z )
1732         {
1733                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1734                 ++dimensions;
1735         }
1736
1737         if(autocvar_camera_free)
1738                 speed = autocvar_camera_speed_free;
1739         else
1740                 speed = autocvar_camera_speed_chase;
1741
1742         if(dimensions)
1743         {
1744                 speed = speed * sqrt(1 / dimensions);
1745                 camera_offset += tmp * speed;
1746         }
1747
1748         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1749
1750         // Camera modes
1751         if( autocvar_camera_free )
1752         {
1753                 if ( camera_mode == CAMERA_CHASE )
1754                 {
1755                         current_camera_offset = current_origin + current_camera_offset;
1756                         camera_offset = current_origin + camera_offset;
1757                 }
1758
1759                 camera_mode = CAMERA_FREE;
1760                 current_position = current_camera_offset;
1761         }
1762         else
1763         {
1764                 if ( camera_mode == CAMERA_FREE )
1765                 {
1766                         current_origin = view_origin;
1767                         camera_offset = camera_offset - current_origin;
1768                         current_camera_offset = current_camera_offset - current_origin;
1769                 }
1770
1771                 camera_mode = CAMERA_CHASE;
1772
1773                 if(autocvar_camera_chase_smoothly)
1774                         current_origin += (view_origin - current_origin) * attenuation;
1775                 else
1776                         current_origin = view_origin;
1777
1778                 current_position = current_origin + current_camera_offset;
1779         }
1780
1781         setproperty(VF_ANGLES, current_angles);
1782         setproperty(VF_ORIGIN, current_position);
1783 }