qcsrc/client/View.qc

   1 entity porto;
   2 vector polyline[16];
   3 float Q3SURFACEFLAG_SLICK = 2; // low friction surface
   4 float DPCONTENTS_SOLID = 1; // blocks player movement
   5 float DPCONTENTS_BODY = 32; // blocks player movement
   6 float DPCONTENTS_CORPSE = 64; // blocks player movement
   7 float DPCONTENTS_PLAYERCLIP = 256; // blocks player movement
   8 void Porto_Draw()
   9 {
  10         vector p, dir, ang, q, nextdir;
  11         float idx, portal_number, portal1_idx;
  12
  13         if(activeweapon != WEP_PORTO || spectatee_status || gametype == GAME_NEXBALL)
  14                 return;
  15         if(intermission == 1)
  16                 return;
  17         if(intermission == 2)
  18                 return;
  19         if (getstati(STAT_HEALTH) <= 0)
  20                 return;
  21
  22         dir = view_forward;
  23
  24         if(angles_held_status)
  25         {
  26                 makevectors(angles_held);
  27                 dir = v_forward;
  28         }
  29
  30         p = view_origin;
  31
  32         polyline[0] = p;
  33         idx = 1;
  34         portal_number = 0;
  35         nextdir = dir;
  36
  37         for(;;)
  38         {
  39                 dir = nextdir;
  40                 traceline(p, p + 65536 * dir, TRUE, porto);
  41                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  42                         return;
  43                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  44                 p = trace_endpos;
  45                 polyline[idx] = p;
  46                 ++idx;
  47                 if(idx >= 16)
  48                         return;
  49                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  50                         continue;
  51                 ++portal_number;
  52                 ang = vectoangles2(trace_plane_normal, dir);
  53                 ang_x = -ang_x;
  54                 makevectors(ang);
  55                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  56                         return;
  57                 if(portal_number == 1)
  58                         portal1_idx = idx;
  59                 if(portal_number >= 2)
  60                         break;
  61         }
  62
  63         while(idx >= 2)
  64         {
  65                 p = polyline[idx-2];
  66                 q = polyline[idx-1];
  67                 if(idx == 2)
  68                         p = p - view_up * 16;
  69                 if(idx-1 >= portal1_idx)
  70                 {
  71                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  72                 }
  73                 else
  74                 {
  75                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  76                 }
  77                 --idx;
  78         }
  79 }
  80
  81 void Porto_Init()
  82 {
  83         porto = spawn();
  84         porto.classname = "porto";
  85         porto.draw = Porto_Draw;
  86         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
  87 }
  88
  89 float drawtime;
  90 float avgspeed;
  91 vector GetCurrentFov(float fov)
  92 {
  93         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir, velocityzoom;
  94
  95         zoomsensitivity = autocvar_cl_zoomsensitivity;
  96         zoomfactor = autocvar_cl_zoomfactor;
  97         if(zoomfactor < 1 || zoomfactor > 16)
  98                 zoomfactor = 2.5;
  99         zoomspeed = autocvar_cl_zoomspeed;
 100         if(zoomspeed >= 0)
 101                 if(zoomspeed < 0.5 || zoomspeed > 16)
 102                         zoomspeed = 3.5;
 103
 104         zoomdir = button_zoom;
 105         if(hud == HUD_NORMAL)
 106         if((activeweapon == WEP_NEX && nex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 107                 zoomdir += button_attack2;
 108         if(spectatee_status > 0 || isdemo())
 109         {
 110                 if(spectatorbutton_zoom)
 111                 {
 112                         if(zoomdir)
 113                                 zoomdir = 0;
 114                         else
 115                                 zoomdir = 1;
 116                 }
 117                 // fteqcc failed twice here already, don't optimize this
 118         }
 119
 120         if(zoomdir)
 121                 zoomin_effect = 0;
 122
 123         if(zoomin_effect || camera_active)
 124         {
 125                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 126         }
 127         else
 128         {
 129                 if(zoomspeed < 0) // instant zoom
 130                 {
 131                         if(zoomdir)
 132                                 current_viewzoom = 1 / zoomfactor;
 133                         else
 134                                 current_viewzoom = 1;
 135                 }
 136                 else
 137                 {
 138                         if(zoomdir)
 139                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 140                         else
 141                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 142                 }
 143         }
 144
 145         if(almost_equals(current_viewzoom, 1))
 146                 current_zoomfraction = 0;
 147         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 148                 current_zoomfraction = 1;
 149         else
 150                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 151
 152         if(zoomsensitivity < 1)
 153                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 154         else
 155                 setsensitivityscale(1);
 156
 157         if (autocvar_cl_velocityzoom)
 158         {
 159                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoomtime), 1);
 160                 avgspeed = avgspeed * (1 - velocityzoom) + (vlen(pmove_vel) / 1000) * velocityzoom;
 161                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom / 1) * 1);
 162                 //print(ftos(avgspeed), " avgspeed, ", ftos(autocvar_cl_velocityzoom), " cvar, ", ftos(velocityzoom), " return\n"); // for debugging
 163         }
 164         else
 165                 velocityzoom = 1;
 166
 167         float frustumx, frustumy, fovx, fovy;
 168         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 169         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 170         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 171         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 172
 173         return '1 0 0' * fovx + '0 1 0' * fovy;
 174 }
 175
 176 // this function must match W_SetupShot!
 177 float zoomscript_caught;
 178
 179 vector wcross_origin;
 180 float wcross_scale_prev, wcross_alpha_prev;
 181 vector wcross_color_prev;
 182 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 183 vector wcross_color_goal_prev;
 184 float wcross_changedonetime;
 185
 186 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 187 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 188 float wcross_name_changestarttime, wcross_name_changedonetime;
 189 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 190 entity trueaim;
 191 entity trueaim_rifle;
 192
 193 #define SHOTTYPE_HITTEAM 1
 194 #define SHOTTYPE_HITOBSTRUCTION 2
 195 #define SHOTTYPE_HITWORLD 3
 196 #define SHOTTYPE_HITENEMY 4
 197
 198 void TrueAim_Init()
 199 {
 200         trueaim = spawn();
 201         trueaim.classname = "trueaim";
 202         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 203         trueaim_rifle = spawn();
 204         trueaim_rifle.classname = "trueaim_rifle";
 205         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 206 }
 207
 208 float EnemyHitCheck()
 209 {
 210         float t;
 211         wcross_origin = project_3d_to_2d(trace_endpos);
 212         wcross_origin_z = 0;
 213         if(trace_networkentity < 1)
 214                 return SHOTTYPE_HITWORLD;
 215         if(trace_networkentity > maxclients)
 216                 return SHOTTYPE_HITWORLD;
 217         t = GetPlayerColor(trace_networkentity - 1);
 218         if(teamplay)
 219                 if(t == myteam)
 220                         return SHOTTYPE_HITTEAM;
 221         if(t == COLOR_SPECTATOR)
 222                 return SHOTTYPE_HITWORLD;
 223         return SHOTTYPE_HITENEMY;
 224 }
 225
 226 float TrueAimCheck()
 227 {
 228         float nudge = 1; // added to traceline target and subtracted from result
 229         vector vecs, trueaimpoint, w_shotorg;
 230         vector mi, ma, dv;
 231         float shottype;
 232         entity ta;
 233         float mv;
 234
 235         mi = ma = '0 0 0';
 236         ta = trueaim;
 237         mv = MOVE_NOMONSTERS;
 238
 239         switch(activeweapon)
 240         {
 241                 case WEP_TUBA: // no aim
 242                 case WEP_PORTO: // shoots from eye
 243                 case WEP_HOOK: // no trueaim
 244                 case WEP_GRENADE_LAUNCHER: // toss curve
 245                         return SHOTTYPE_HITWORLD;
 246                 case WEP_NEX:
 247                 case WEP_MINSTANEX:
 248                         mv = MOVE_NORMAL;
 249                         break;
 250                 case WEP_RIFLE:
 251                         ta = trueaim_rifle;
 252                         mv = MOVE_NORMAL;
 253                         if(zoomscript_caught)
 254                         {
 255                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 256                                 return EnemyHitCheck();
 257                         }
 258                         break;
 259                 case WEP_ROCKET_LAUNCHER: // projectile has a size!
 260                         mi = '-3 -3 -3';
 261                         ma = '3 3 3';
 262                         break;
 263                 case WEP_FIREBALL: // projectile has a size!
 264                         mi = '-16 -16 -16';
 265                         ma = '16 16 16';
 266                         break;
 267                 case WEP_SEEKER: // projectile has a size!
 268                         mi = '-2 -2 -2';
 269                         ma = '2 2 2';
 270                         break;
 271                 case WEP_ELECTRO: // projectile has a size!
 272                         mi = '0 0 -3';
 273                         ma = '0 0 -3';
 274                         break;
 275         }
 276
 277         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 278
 279         traceline(view_origin, view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 280         trueaimpoint = trace_endpos;
 281
 282         if(vlen(trueaimpoint - view_origin) < g_trueaim_minrange)
 283                 trueaimpoint = view_origin + view_forward * g_trueaim_minrange;
 284
 285         if(vecs_x > 0)
 286                 vecs_y = -vecs_y;
 287         else
 288                 vecs = '0 0 0';
 289
 290         dv = view_right * vecs_y + view_up * vecs_z;
 291         w_shotorg = view_origin + dv;
 292
 293         // now move the vecs forward as much as requested if possible
 294         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs_x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 295         w_shotorg = trace_endpos - view_forward * nudge;
 296
 297         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 298         shottype = EnemyHitCheck();
 299         if(shottype != SHOTTYPE_HITWORLD)
 300                 return shottype;
 301
 302 #if 0
 303         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 304         // or rather, I know why, but see no fix
 305         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 306                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 307                 return SHOTTYPE_HITOBSTRUCTION;
 308 #endif
 309
 310         return SHOTTYPE_HITWORLD;
 311 }
 312
 313 void CSQC_common_hud(void);
 314
 315 void PostInit(void);
 316 void CSQC_Demo_Camera();
 317 float HUD_WouldDrawScoreboard();
 318 float camera_mode;
 319 float reticle_type;
 320 string NextFrameCommand;
 321 void CSQC_SPIDER_HUD();
 322 void CSQC_RAPTOR_HUD();
 323
 324 vector freeze_org, freeze_ang;
 325 entity nightvision_noise, nightvision_noise2;
 326
 327 #define MAX_TIME_DIFF 5
 328 float pickup_crosshair_time, pickup_crosshair_size;
 329 float hit_time, typehit_time;
 330 float nextsound_hit_time, nextsound_typehit_time;
 331 float hitindication_crosshair_time, hitindication_crosshair_size;
 332 float use_nex_chargepool;
 333
 334 float myhealth, myhealth_prev;
 335 float myhealth_flash;
 336
 337 float old_blurradius, old_bluralpha;
 338 float old_sharpen_intensity;
 339
 340 vector myhealth_gentlergb;
 341
 342 float contentavgalpha, liquidalpha_prev;
 343 vector liquidcolor_prev;
 344
 345 float eventchase_current_distance;
 346
 347 vector damage_blurpostprocess, content_blurpostprocess;
 348
 349 float checkfail[16];
 350
 351 void CSQC_UpdateView(float w, float h)
 352 {
 353         entity e;
 354         float fov;
 355         float f, i, j;
 356         vector v;
 357         vector vf_size, vf_min;
 358         float a;
 359         hud = getstati(STAT_HUD);
 360
 361         button_attack2 = (input_buttons & BUTTON_3);
 362         button_zoom = (input_buttons & BUTTON_4);
 363
 364         // FIXME do we need this hack?
 365         if(isdemo())
 366         {
 367                 // in demos, input_buttons do not work
 368                 button_zoom = (autocvar__togglezoom == "-");
 369         }
 370
 371 #define CHECKFAIL_ASSERT(flag,func,parm,val) { float checkfailv; checkfailv = (func)(parm); if(checkfailv != (val)) { if(!checkfail[(flag)]) localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv)); checkfail[(flag)] = 1; } } ENDS_WITH_CURLY_BRACE
 372         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
 373         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
 374         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
 375         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
 376         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
 377         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
 378
 379         vf_size = R_SetView3fv(VF_SIZE);
 380         vf_min = R_SetView3fv(VF_MIN);
 381         vid_width = vf_size_x;
 382         vid_height = vf_size_y;
 383
 384         vector reticle_pos, reticle_size;
 385         vector splash_pos, splash_size;
 386
 387         WaypointSprite_Load();
 388
 389         if(spectatee_status)
 390                 myteam = GetPlayerColor(spectatee_status - 1);
 391         else
 392                 myteam = GetPlayerColor(player_localentnum - 1);
 393
 394         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 395
 396         // event chase camera
 397         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 398         {
 399                 if(spectatee_status >= 0 && (autocvar_cl_eventchase_death && getstati(STAT_HEALTH) <= 0 && !intermission) || intermission)
 400                 {
 401                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 402                         vector current_view_origin = R_SetView3fv(VF_ORIGIN);
 403
 404                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 405                         // Ideally, there should be another way to enable third person cameras, such as through R_SetView()
 406                         if(!autocvar_chase_active)
 407                                 cvar_set("chase_active", "-1"); // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 408
 409                         // make the camera smooth back
 410                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
 411                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 412                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
 413                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
 414
 415                         vector eventchase_target_origin;
 416                         makevectors(view_angles);
 417                         // pass 1, used to check where the camera would go and obtain the trace_fraction
 418                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance;
 419                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 420                         // pass 2, also multiplying view_forward with trace_fraction, to prevent the camera from going through walls
 421                         // The 0.1 subtraction is to not limit the camera precisely at the wall surface, as that allows the view to poke through
 422                         eventchase_target_origin = current_view_origin - v_forward * eventchase_current_distance * (trace_fraction - 0.1);
 423                         WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
 424
 425                         R_SetView(VF_ORIGIN, trace_endpos);
 426                         R_SetView(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 427                 }
 428                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 429                 {
 430                         cvar_set("chase_active", "0");
 431                         eventchase_current_distance = 0; // start from 0 next time
 432                 }
 433         }
 434
 435         // do lockview after event chase camera so that it still applies whenever necessary.
 436         if(autocvar_cl_lockview || (autocvar__hud_configure && spectatee_status <= 0) || intermission > 1)
 437         {
 438                 R_SetView(VF_ORIGIN, freeze_org);
 439                 R_SetView(VF_ANGLES, freeze_ang);
 440         }
 441         else
 442         {
 443                 freeze_org = R_SetView3fv(VF_ORIGIN);
 444                 freeze_ang = R_SetView3fv(VF_ANGLES);
 445         }
 446
 447         WarpZone_FixView();
 448         //WarpZone_FixPMove();
 449
 450         // Render the Scene
 451         view_origin = R_SetView3fv(VF_ORIGIN);
 452         view_angles = R_SetView3fv(VF_ANGLES);
 453         makevectors(view_angles);
 454         view_forward = v_forward;
 455         view_right = v_right;
 456         view_up = v_up;
 457
 458 #ifdef BLURTEST
 459         if(time > blurtest_time0 && time < blurtest_time1)
 460         {
 461                 float r, t;
 462
 463                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
 464                 r = t * blurtest_radius;
 465                 f = 1 / pow(t, blurtest_power) - 1;
 466
 467                 cvar_set("r_glsl_postprocess", "1");
 468                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
 469         }
 470         else
 471         {
 472                 cvar_set("r_glsl_postprocess", "0");
 473                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 474         }
 475 #endif
 476
 477         TargetMusic_Advance();
 478         Fog_Force();
 479
 480         if(drawtime == 0)
 481                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
 482         else
 483                 drawframetime = bound(0.000001, time - drawtime, 1);
 484         drawtime = time;
 485
 486         // watch for gametype changes here...
 487         // in ParseStuffCMD the cmd isn't executed yet :/
 488         // might even be better to add the gametype to TE_CSQC_INIT...?
 489         if(!postinit)
 490                 PostInit();
 491
 492         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
 493         {
 494                 if(calledhooks & HOOK_START)
 495                 {
 496                         localcmd("\ncl_hook_gameend\n");
 497                         calledhooks |= HOOK_END;
 498                 }
 499         }
 500
 501   Announcer();
 502
 503         fov = autocvar_fov;
 504         if(fov <= 59.5)
 505         {
 506                 if(!zoomscript_caught)
 507                 {
 508                         localcmd("+button9\n");
 509                         zoomscript_caught = 1;
 510                 }
 511         }
 512         else
 513         {
 514                 if(zoomscript_caught)
 515                 {
 516                         localcmd("-button9\n");
 517                         zoomscript_caught = 0;
 518                 }
 519         }
 520
 521         ColorTranslateMode = autocvar_cl_stripcolorcodes;
 522
 523         // next WANTED weapon (for HUD)
 524         switchweapon = getstati(STAT_SWITCHWEAPON);
 525
 526         // currently switching-to weapon (for crosshair)
 527         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
 528
 529         // actually active weapon (for zoom)
 530         activeweapon = getstati(STAT_ACTIVEWEAPON);
 531
 532         f = (serverflags & SERVERFLAG_TEAMPLAY);
 533         if(f != teamplay)
 534         {
 535                 teamplay = f;
 536                 HUD_InitScores();
 537         }
 538
 539         if(last_switchweapon != switchweapon) {
 540                 weapontime = time;
 541                 last_switchweapon = switchweapon;
 542         }
 543         if(last_activeweapon != activeweapon) {
 544                 last_activeweapon = activeweapon;
 545
 546                 e = get_weaponinfo(activeweapon);
 547                 if(e.netname != "")
 548                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
 549                 else
 550                         localcmd("\ncl_hook_activeweapon none\n");
 551         }
 552
 553         // ALWAYS Clear Current Scene First
 554         R_ClearScene();
 555 #ifdef WORKAROUND_XON010
 556         if(checkextension("DP_CSQC_ROTATEMOVES"))
 557         {
 558 #endif
 559         R_SetView(VF_ORIGIN, view_origin);
 560         R_SetView(VF_ANGLES, view_angles);
 561 #ifdef WORKAROUND_XON010
 562         }
 563 #endif
 564
 565         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
 566         R_SetView(VF_SIZE, vf_size);
 567         R_SetView(VF_MIN, vf_min);
 568
 569         // Assign Standard Viewflags
 570         // Draw the World (and sky)
 571         R_SetView(VF_DRAWWORLD, 1);
 572
 573         // Set the console size vars
 574         vid_conwidth = autocvar_vid_conwidth;
 575         vid_conheight = autocvar_vid_conheight;
 576         vid_pixelheight = autocvar_vid_pixelheight;
 577
 578         R_SetView(VF_FOV, GetCurrentFov(fov));
 579
 580         // Camera for demo playback
 581         if(camera_active)
 582         {
 583                 if(autocvar_camera_enable)
 584                         CSQC_Demo_Camera();
 585                 else
 586                 {
 587                         cvar_set("chase_active", ftos(chase_active_backup));
 588                         cvar_set("cl_demo_mousegrab", "0");
 589                         camera_active = FALSE;
 590                 }
 591         }
 592 #ifdef CAMERATEST
 593         else if(autocvar_camera_enable)
 594 #else
 595         else if(autocvar_camera_enable && isdemo())
 596 #endif
 597         {
 598                 // Enable required Darkplaces cvars
 599                 chase_active_backup = autocvar_chase_active;
 600                 cvar_set("chase_active", "2");
 601                 cvar_set("cl_demo_mousegrab", "1");
 602                 camera_active = TRUE;
 603                 camera_mode = FALSE;
 604         }
 605
 606         // Draw the Crosshair
 607         R_SetView(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
 608
 609         // Draw the Engine Status Bar (the default Quake HUD)
 610         R_SetView(VF_DRAWENGINEHUD, 0);
 611
 612         // Update the mouse position
 613         /*
 614            mousepos_x = vid_conwidth;
 615            mousepos_y = vid_conheight;
 616            mousepos = mousepos*0.5 + getmousepos();
 617          */
 618
 619         e = self;
 620         for(self = world; (self = nextent(self)); )
 621                 if(self.draw)
 622                         self.draw();
 623         self = e;
 624
 625         R_AddEntities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
 626         R_RenderScene();
 627
 628         // now switch to 2D drawing mode by calling a 2D drawing function
 629         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
 630         // next R_RenderScene call
 631         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
 632
 633         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
 634         if not(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT)
 635         {
 636                 // apply night vision effect
 637                 vector rgb, tc_00, tc_01, tc_10, tc_11;
 638
 639                 if(!nightvision_noise)
 640                 {
 641                         nightvision_noise = spawn();
 642                         nightvision_noise.classname = "nightvision_noise";
 643                 }
 644                 if(!nightvision_noise2)
 645                 {
 646                         nightvision_noise2 = spawn();
 647                         nightvision_noise2.classname = "nightvision_noise2";
 648                 }
 649
 650                 // color tint in yellow
 651                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
 652
 653                 // draw BG
 654                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
 655                 rgb = '1 1 1';
 656                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
 657                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
 658                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
 659                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
 660                 tc_11 = tc_01 + tc_10 - tc_00;
 661                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
 662                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 663                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 664                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 665                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 666                 R_EndPolygon();
 667
 668                 // draw FG
 669                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
 670                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
 671                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
 672                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
 673                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
 674                 tc_11 = tc_01 + tc_10 - tc_00;
 675                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
 676                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
 677                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
 678                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
 679                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
 680                 R_EndPolygon();
 681         }
 682
 683         // Draw the aiming reticle for weapons that use it
 684         // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
 685         // It must be a persisted float for fading out to work properly (you let go of the zoom button for
 686         // the view to go back to normal, so reticle_type would become 0 as we fade out)
 687         if(spectatee_status || getstati(STAT_HEALTH) <= 0 || hud != HUD_NORMAL)
 688                 reticle_type = 0; // prevent reticle from showing during the respawn zoom effect or for spectators
 689         else if(activeweapon == WEP_NEX && (button_zoom || zoomscript_caught) || activeweapon == WEP_RIFLE && (button_zoom || zoomscript_caught) || activeweapon == WEP_MINSTANEX && (button_zoom || zoomscript_caught))
 690                 reticle_type = 2; // nex zoom
 691         else if(button_zoom || zoomscript_caught)
 692                 reticle_type = 1; // normal zoom
 693         else if(activeweapon == WEP_NEX && button_attack2 || activeweapon == WEP_RIFLE && button_attack2)
 694                 reticle_type = 2; // nex zoom
 695
 696         if (reticle_type)
 697         {
 698                 if(autocvar_cl_reticle_stretch)
 699                 {
 700                         reticle_size_x = vid_conwidth;
 701                         reticle_size_y = vid_conheight;
 702                         reticle_pos_x = 0;
 703                         reticle_pos_y = 0;
 704                 }
 705                 else
 706                 {
 707                         reticle_size_x = max(vid_conwidth, vid_conheight);
 708                         reticle_size_y = max(vid_conwidth, vid_conheight);
 709                         reticle_pos_x = (vid_conwidth - reticle_size_x) / 2;
 710                         reticle_pos_y = (vid_conheight - reticle_size_y) / 2;
 711                 }
 712
 713                 f = current_zoomfraction;
 714                 if(zoomscript_caught)
 715                         f = 1;
 716                 if(autocvar_cl_reticle_item_normal)
 717                 {
 718                         if(reticle_type == 1 && f)
 719                                 drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_normal, DRAWFLAG_NORMAL);
 720                 }
 721                 if(autocvar_cl_reticle_item_nex)
 722                 {
 723                         if(reticle_type == 2 && f)
 724                                 drawpic(reticle_pos, "gfx/reticle_nex", reticle_size, '1 1 1', f * autocvar_cl_reticle_item_nex, DRAWFLAG_NORMAL);
 725                 }
 726         }
 727
 728
 729         // improved polyblend
 730         vector rgb;
 731         if(autocvar_hud_contents)
 732         {
 733                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
 734                 vector liquidcolor;
 735
 736                 switch(pointcontents(view_origin))
 737                 {
 738                         case CONTENT_WATER:
 739                                 liquidalpha = autocvar_hud_contents_water_alpha;
 740                                 liquidcolor = stov(autocvar_hud_contents_water_color);
 741                                 incontent = 1;
 742                                 break;
 743
 744                         case CONTENT_LAVA:
 745                                 liquidalpha = autocvar_hud_contents_lava_alpha;
 746                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
 747                                 incontent = 1;
 748                                 break;
 749
 750                         case CONTENT_SLIME:
 751                                 liquidalpha = autocvar_hud_contents_slime_alpha;
 752                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
 753                                 incontent = 1;
 754                                 break;
 755
 756                         default:
 757                                 liquidalpha = 0;
 758                                 liquidcolor = '0 0 0';
 759                                 incontent = 0;
 760                                 break;
 761                 }
 762
 763                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
 764                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
 765                         contentfadetime = autocvar_hud_contents_fadeintime;
 766                         liquidalpha_prev = liquidalpha;
 767                         liquidcolor_prev = liquidcolor;
 768                 }
 769                 else
 770                         contentfadetime = autocvar_hud_contents_fadeouttime;
 771
 772                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
 773                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
 774
 775                 if(contentavgalpha)
 776                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
 777
 778                 if(autocvar_hud_postprocessing)
 779                 {
 780                         if(autocvar_hud_contents_blur && contentavgalpha)
 781                         {
 782                                 content_blurpostprocess_x = 1;
 783                                 content_blurpostprocess_y = contentavgalpha * autocvar_hud_contents_blur;
 784                                 content_blurpostprocess_z = contentavgalpha * autocvar_hud_contents_blur_alpha;
 785                         }
 786                         else
 787                         {
 788                                 content_blurpostprocess_x = 0;
 789                                 content_blurpostprocess_y = 0;
 790                                 content_blurpostprocess_z = 0;
 791                         }
 792                 }
 793         }
 794
 795         if(autocvar_hud_damage)
 796         {
 797                 splash_size_x = max(vid_conwidth, vid_conheight);
 798                 splash_size_y = max(vid_conwidth, vid_conheight);
 799                 splash_pos_x = (vid_conwidth - splash_size_x) / 2;
 800                 splash_pos_y = (vid_conheight - splash_size_y) / 2;
 801
 802                 float myhealth_flash_temp;
 803                 myhealth = getstati(STAT_HEALTH);
 804
 805                 // fade out
 806                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
 807                 // add new damage
 808                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
 809
 810                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
 811                 pain_threshold = autocvar_hud_damage_pain_threshold;
 812                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
 813                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
 814
 815                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
 816                 {
 817                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
 818                 }
 819
 820                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
 821
 822                 if(myhealth_prev < 1)
 823                 {
 824                         if(myhealth >= 1)
 825                         {
 826                                 myhealth_flash = 0; // just spawned, clear the flash immediately
 827                                 myhealth_flash_temp = 0;
 828                         }
 829                         else
 830                         {
 831                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
 832                         }
 833                 }
 834
 835                 if(spectatee_status == -1 || intermission)
 836                 {
 837                         myhealth_flash = 0; // observing, or match ended
 838                         myhealth_flash_temp = 0;
 839                 }
 840
 841                 myhealth_prev = myhealth;
 842
 843                 // IDEA: change damage color/picture based on player model for robot/alien species?
 844                 // pro: matches model better
 845                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
 846                 // maybe different reddish pics?
 847                 if(autocvar_chase_active >= 0) // not while the event chase camera is active
 848                 {
 849                         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
 850                         {
 851                                 if(autocvar_cl_gentle_damage == 2)
 852                                 {
 853                                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
 854                                         {
 855                                                 myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
 856                                         }
 857                                 }
 858                                 else
 859                                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
 860
 861                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 862                         }
 863                         else
 864                                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
 865                 }
 866
 867                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
 868                 {
 869                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
 870                         {
 871                                 damage_blurpostprocess_x = 1;
 872                                 damage_blurpostprocess_y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
 873                                 damage_blurpostprocess_z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
 874                         }
 875                         else
 876                         {
 877                                 damage_blurpostprocess_x = 0;
 878                                 damage_blurpostprocess_y = 0;
 879                                 damage_blurpostprocess_z = 0;
 880                         }
 881                 }
 882         }
 883
 884         if(autocvar_hud_postprocessing) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
 885         {
 886                 // enable or disable rendering types if they are used or not
 887                 if(cvar("r_glsl_postprocess_uservec1_enable") != (autocvar_hud_postprocessing_maxbluralpha != 0)) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(autocvar_hud_postprocessing_maxbluralpha != 0)); }
 888                 if(cvar("r_glsl_postprocess_uservec2_enable") != (autocvar_hud_powerup != 0)) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(autocvar_hud_powerup != 0)); }
 889
 890                 // blur postprocess handling done first (used by hud_damage and hud_contents)
 891                 if((damage_blurpostprocess_x || content_blurpostprocess_x) && autocvar_chase_active >= 0) // not while the event chase camera is active
 892                 {
 893                         float blurradius = bound(0, damage_blurpostprocess_y + content_blurpostprocess_y, autocvar_hud_postprocessing_maxblurradius);
 894                         float bluralpha = bound(0, damage_blurpostprocess_z + content_blurpostprocess_z, autocvar_hud_postprocessing_maxbluralpha);
 895                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
 896                         {
 897                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
 898                                 old_blurradius = blurradius;
 899                                 old_bluralpha = bluralpha;
 900                         }
 901                 }
 902                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
 903                 {
 904                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
 905                         old_blurradius = 0;
 906                         old_bluralpha = 0;
 907                 }
 908
 909                 // edge detection postprocess handling done second (used by hud_powerup)
 910                 float sharpen_intensity, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
 911                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
 912                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
 913
 914                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
 915
 916                 if(autocvar_hud_powerup && sharpen_intensity > 0 && autocvar_chase_active >= 0) // not while the event chase camera is active
 917                 {
 918                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
 919                         {
 920                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
 921                                 old_sharpen_intensity = sharpen_intensity;
 922                         }
 923                 }
 924                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
 925                 {
 926                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
 927                         old_sharpen_intensity = 0;
 928                 }
 929         }
 930
 931         if(menu_visible)
 932                 menu_show();
 933
 934         /*if(gametype == GAME_CTF)
 935           {
 936           ctf_view();
 937           } else */
 938
 939         // draw 2D entities
 940         e = self;
 941         for(self = world; (self = nextent(self)); )
 942                 if(self.draw2d)
 943                         self.draw2d();
 944         self = e;
 945         Draw_ShowNames_All();
 946
 947         scoreboard_active = HUD_WouldDrawScoreboard();
 948
 949         hit_time = getstatf(STAT_HIT_TIME);
 950         if(hit_time > nextsound_hit_time && autocvar_cl_hitsound)
 951         {
 952                 if(time - hit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 953                         sound(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE);
 954
 955                 nextsound_hit_time = time + autocvar_cl_hitsound_antispam_time;
 956         }
 957         typehit_time = getstatf(STAT_TYPEHIT_TIME);
 958         if(typehit_time > nextsound_typehit_time)
 959         {
 960                 if(time - typehit_time < MAX_TIME_DIFF) // don't play the sound if it's too old.
 961                         sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 962
 963                 nextsound_typehit_time = time + autocvar_cl_hitsound_antispam_time;
 964         }
 965
 966         //else
 967         {
 968                 if(gametype == GAME_FREEZETAG)
 969                 {
 970                         if(getstati(STAT_FROZEN))
 971                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 972                         if(getstatf(STAT_REVIVE_PROGRESS))
 973                         {
 974                                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 975                                 drawstring_aspect(eY * 0.64 * vid_conheight, "Revival progress", eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 976                         }
 977                 }
 978
 979                 if(autocvar_r_letterbox == 0)
 980                         if(autocvar_viewsize < 120)
 981                                 CSQC_common_hud();
 982
 983                 // crosshair goes VERY LAST
 984                 if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL) {
 985                         string wcross_style;
 986                         float wcross_alpha, wcross_resolution;
 987                         wcross_style = autocvar_crosshair;
 988                         if (wcross_style == "0")
 989                                 return;
 990                         wcross_resolution = autocvar_crosshair_size;
 991                         if (wcross_resolution == 0)
 992                                 return;
 993                         wcross_alpha = autocvar_crosshair_alpha;
 994                         if (wcross_alpha == 0)
 995                                 return;
 996
 997                         // TrueAim check
 998                         float shottype;
 999
1000                         // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1001                         wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
1002                         wcross_origin_z = 0;
1003                         if(autocvar_crosshair_hittest)
1004                         {
1005                                 vector wcross_oldorigin;
1006                                 wcross_oldorigin = wcross_origin;
1007                                 shottype = TrueAimCheck();
1008                                 if(shottype == SHOTTYPE_HITWORLD)
1009                                 {
1010                                         v = wcross_origin - wcross_oldorigin;
1011                                         v_x /= vid_conwidth;
1012                                         v_y /= vid_conheight;
1013                                         if(vlen(v) > 0.01)
1014                                                 shottype = SHOTTYPE_HITOBSTRUCTION;
1015                                 }
1016                                 if(!autocvar_crosshair_hittest_showimpact)
1017                                         wcross_origin = wcross_oldorigin;
1018                         }
1019                         else
1020                                 shottype = SHOTTYPE_HITWORLD;
1021
1022                         vector wcross_color, wcross_size;
1023                         string wcross_wep, wcross_name;
1024                         float wcross_scale, wcross_blur;
1025
1026                         if (autocvar_crosshair_per_weapon || autocvar_crosshair_color_per_weapon) {
1027                                 e = get_weaponinfo(switchingweapon);
1028                                 if (e && e.netname != "")
1029                                 {
1030                                         wcross_wep = e.netname;
1031                                         if(autocvar_crosshair_per_weapon)
1032                                         {
1033                                                 wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1034                                                 if (wcross_resolution == 0)
1035                                                         return;
1036                                                 wcross_alpha *= cvar(strcat("crosshair_", wcross_wep, "_alpha"));
1037                                                 if (wcross_alpha == 0)
1038                                                         return;
1039
1040                                                 wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1041                                                 if(wcross_style == "" || wcross_style == "0")
1042                                                         wcross_style = wcross_wep;
1043                                         }
1044                                 }
1045                         }
1046                         if(wcross_wep != "" && autocvar_crosshair_color_per_weapon)
1047                                 wcross_color = stov(cvar_string(strcat("crosshair_", wcross_wep, "_color")));
1048                         else if(autocvar_crosshair_color_by_health)
1049                         {
1050                                 float x = getstati(STAT_HEALTH);
1051
1052                                 //x = red
1053                                 //y = green
1054                                 //z = blue
1055
1056                                 wcross_color_z = 0;
1057
1058                                 if(x > 200)
1059                                 {
1060                                         wcross_color_x = 0;
1061                                         wcross_color_y = 1;
1062                                 }
1063                                 else if(x > 150)
1064                                 {
1065                                         wcross_color_x = 0.4 - (x-150)*0.02 * 0.4;
1066                                         wcross_color_y = 0.9 + (x-150)*0.02 * 0.1;
1067                                 }
1068                                 else if(x > 100)
1069                                 {
1070                                         wcross_color_x = 1 - (x-100)*0.02 * 0.6;
1071                                         wcross_color_y = 1 - (x-100)*0.02 * 0.1;
1072                                         wcross_color_z = 1 - (x-100)*0.02;
1073                                 }
1074                                 else if(x > 50)
1075                                 {
1076                                         wcross_color_x = 1;
1077                                         wcross_color_y = 1;
1078                                         wcross_color_z = 0.2 + (x-50)*0.02 * 0.8;
1079                                 }
1080                                 else if(x > 20)
1081                                 {
1082                                         wcross_color_x = 1;
1083                                         wcross_color_y = (x-20)*90/27/100;
1084                                         wcross_color_z = (x-20)*90/27/100 * 0.2;
1085                                 }
1086                                 else
1087                                 {
1088                                         wcross_color_x = 1;
1089                                         wcross_color_y = 0;
1090                                 }
1091                         }
1092                         else
1093                                 wcross_color = stov(autocvar_crosshair_color);
1094
1095                         wcross_name = strcat("gfx/crosshair", wcross_style);
1096
1097                         if(autocvar_crosshair_effect_scalefade)
1098                         {
1099                                 wcross_scale = wcross_resolution;
1100                                 wcross_resolution = 1;
1101                         }
1102                         else
1103                         {
1104                                 wcross_scale = 1;
1105                         }
1106
1107                         if(autocvar_crosshair_pickup)
1108                         {
1109                                 float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1110
1111                                 if(pickup_crosshair_time < stat_pickup_time)
1112                                 {
1113                                         if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1114                                                 pickup_crosshair_size = 1;
1115
1116                                         pickup_crosshair_time = stat_pickup_time;
1117                                 }
1118
1119                                 if(pickup_crosshair_size > 0)
1120                                         pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1121                                 else
1122                                         pickup_crosshair_size = 0;
1123
1124                                 wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1125                         }
1126
1127                         if(autocvar_crosshair_hitindication)
1128                         {
1129                                 vector hitindication_color = stov(autocvar_crosshair_hitindication_color);
1130                                 if(hitindication_crosshair_time < hit_time)
1131                                 {
1132                                         if(time - hit_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1133                                                 hitindication_crosshair_size = 1;
1134
1135                                         hitindication_crosshair_time = hit_time;
1136                                 }
1137
1138                                 if(hitindication_crosshair_size > 0)
1139                                         hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1140                                 else
1141                                         hitindication_crosshair_size = 0;
1142
1143                                 wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1144                                 wcross_color_x += sin(hitindication_crosshair_size) * hitindication_color_x;
1145                                 wcross_color_y += sin(hitindication_crosshair_size) * hitindication_color_y;
1146                                 wcross_color_z += sin(hitindication_crosshair_size) * hitindication_color_z;
1147                         }
1148
1149                         if(shottype == SHOTTYPE_HITENEMY)
1150                                 wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1151                         if(shottype == SHOTTYPE_HITTEAM)
1152                                 wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1153
1154                         f = autocvar_crosshair_effect_speed;
1155                         if(f < 0)
1156                                 f *= -2 * g_weaponswitchdelay; // anim starts when weapon has been lowered and new weapon comes up
1157                         if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1158                         {
1159                                 wcross_changedonetime = time + f;
1160                         }
1161                         if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1162                         {
1163                                 wcross_name_changestarttime = time;
1164                                 wcross_name_changedonetime = time + f;
1165                                 if(wcross_name_goal_prev_prev)
1166                                         strunzone(wcross_name_goal_prev_prev);
1167                                 wcross_name_goal_prev_prev = wcross_name_goal_prev;
1168                                 wcross_name_goal_prev = strzone(wcross_name);
1169                                 wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1170                                 wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1171                                 wcross_resolution_goal_prev = wcross_resolution;
1172                         }
1173
1174                         wcross_scale_goal_prev = wcross_scale;
1175                         wcross_alpha_goal_prev = wcross_alpha;
1176                         wcross_color_goal_prev = wcross_color;
1177
1178                         if(shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1179                         {
1180                                 wcross_blur = 1;
1181                                 wcross_alpha *= 0.75;
1182                         }
1183                         else
1184                                 wcross_blur = 0;
1185                         // *_prev is at time-frametime
1186                         // * is at wcross_changedonetime+f
1187                         // what do we have at time?
1188                         if(time < wcross_changedonetime)
1189                         {
1190                                 f = frametime / (wcross_changedonetime - time + frametime);
1191                                 wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1192                                 wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1193                                 wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1194                         }
1195
1196                         wcross_scale_prev = wcross_scale;
1197                         wcross_alpha_prev = wcross_alpha;
1198                         wcross_color_prev = wcross_color;
1199
1200                         wcross_scale *= 1 - autocvar__menu_alpha;
1201                         wcross_alpha *= 1 - autocvar__menu_alpha;
1202                         wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1203
1204                         if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1205                         {
1206                                 // crosshair rings for weapon stats
1207                                 if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1208                                 {
1209                                         // declarations and stats
1210                                         float ring_value, ring_scale, ring_alpha, ring_inner_value, ring_inner_alpha;
1211                                         string ring_image, ring_inner_image;
1212                                         vector ring_rgb, ring_inner_rgb;
1213
1214                                         ring_scale = autocvar_crosshair_ring_size;
1215
1216                                         float weapon_clipload, weapon_clipsize;
1217                                         weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1218                                         weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1219
1220                                         float nex_charge, nex_chargepool;
1221                                         nex_charge = getstatf(STAT_NEX_CHARGE);
1222                                         nex_chargepool = getstatf(STAT_NEX_CHARGEPOOL);
1223
1224                                         if(nex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1225                                                 nex_charge_movingavg = nex_charge;
1226
1227
1228                                         // handle the values
1229                                         if (autocvar_crosshair_ring && activeweapon == WEP_NEX && nex_charge && autocvar_crosshair_ring_nex) // ring around crosshair representing velocity-dependent damage for the nex
1230                                         {
1231                                                 if (nex_chargepool || use_nex_chargepool) {
1232                                                         use_nex_chargepool = 1;
1233                                                         ring_inner_value = nex_chargepool;
1234                                                 } else {
1235                                                         nex_charge_movingavg = (1 - autocvar_crosshair_ring_nex_currentcharge_movingavg_rate) * nex_charge_movingavg + autocvar_crosshair_ring_nex_currentcharge_movingavg_rate * nex_charge;
1236                                                         ring_inner_value = bound(0, autocvar_crosshair_ring_nex_currentcharge_scale * (nex_charge - nex_charge_movingavg), 1);
1237                                                 }
1238
1239                                                 ring_inner_alpha = autocvar_crosshair_ring_nex_inner_alpha;
1240                                                 ring_inner_rgb = eX * autocvar_crosshair_ring_nex_inner_color_red + eY * autocvar_crosshair_ring_nex_inner_color_green + eZ * autocvar_crosshair_ring_nex_inner_color_blue;
1241                                                 ring_inner_image = "gfx/crosshair_ring_inner.tga";
1242
1243                                                 // draw the outer ring to show the current charge of the weapon
1244                                                 ring_value = nex_charge;
1245                                                 ring_alpha = autocvar_crosshair_ring_nex_alpha;
1246                                                 ring_rgb = wcross_color;
1247                                                 ring_image = "gfx/crosshair_ring_nexgun.tga";
1248                                         }
1249                                         else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1250                                         {
1251                                                 ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1252                                                 ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1253                                                 ring_rgb = wcross_color;
1254                                                 ring_image = "gfx/crosshair_ring.tga";
1255                                         }
1256                                         else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1257                                         {
1258                                                 ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1259                                                 ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1260                                                 ring_rgb = wcross_color;
1261                                                 ring_image = "gfx/crosshair_ring.tga";
1262                                         }
1263
1264                                         if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1265                                         {
1266                                                 ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1267                                                 ring_scale = autocvar_crosshair_ring_reload_size;
1268                                                 ring_alpha = autocvar_crosshair_ring_reload_alpha;
1269                                                 ring_rgb = wcross_color;
1270
1271                                                 // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1272                                                 // if a new image for another weapon is added, add the code (and its respective file/value) here
1273                                                 if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1274                                                         ring_image = "gfx/crosshair_ring_rifle.tga";
1275                                                 else
1276                                                         ring_image = "gfx/crosshair_ring.tga";
1277                                         }
1278
1279                                         // if in weapon switch animation, fade ring out/in
1280                                         if(g_weaponswitchdelay > 0)
1281                                         {
1282                                                 f = (time - wcross_name_changestarttime) / g_weaponswitchdelay;
1283                                                 if(f > 0 && f < 2)
1284                                                         ring_alpha *= fabs(1 - f);
1285                                         }
1286
1287                                         if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1288                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1289
1290                                         if (ring_value)
1291                                                 DrawCircleClippedPic(wcross_origin, wcross_size_x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1292                                 }
1293
1294 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1295                                 do \
1296                                 { \
1297                                         if(wcross_blur > 0) \
1298                                         { \
1299                                                 for(i = -2; i <= 2; ++i) \
1300                                                 for(j = -2; j <= 2; ++j) \
1301                                                 M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1302                                         } \
1303                                         else \
1304                                         { \
1305                                                 M(0,0,sz,wcross_name,wcross_alpha); \
1306                                         } \
1307                                 } \
1308                                 while(0)
1309
1310 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1311                                 drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size_x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size_y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1312
1313 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1314                                 CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1315
1316                                 if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1317                                 {
1318                                         f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1319                                         wcross_size = drawgetimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1320                                         CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1321                                         f = 1 - f;
1322                                 }
1323                                 else
1324                                 {
1325                                         f = 1;
1326                                 }
1327                                 wcross_name_alpha_goal_prev = f;
1328
1329                                 wcross_size = drawgetimagesize(wcross_name) * wcross_scale;
1330                                 CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1331
1332                                 if(autocvar_crosshair_dot)
1333                                 {
1334                                         vector wcross_color_old;
1335                                         wcross_color_old = wcross_color;
1336                                         if(autocvar_crosshair_dot_color != "0")
1337                                                 wcross_color = stov(autocvar_crosshair_dot_color);
1338                                         CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1339                                         // FIXME why don't we use wcross_alpha here?
1340                                         wcross_color = wcross_color_old;
1341                                 }
1342                         }
1343                 }
1344                 else
1345                 {
1346                         wcross_scale_prev = 0;
1347                         wcross_alpha_prev = 0;
1348                         wcross_scale_goal_prev = 0;
1349                         wcross_alpha_goal_prev = 0;
1350                         wcross_changedonetime = 0;
1351                         if(wcross_name_goal_prev)
1352                                 strunzone(wcross_name_goal_prev);
1353                         wcross_name_goal_prev = string_null;
1354                         if(wcross_name_goal_prev_prev)
1355                                 strunzone(wcross_name_goal_prev_prev);
1356                         wcross_name_goal_prev_prev = string_null;
1357                         wcross_name_changestarttime = 0;
1358                         wcross_name_changedonetime = 0;
1359                         wcross_name_alpha_goal_prev = 0;
1360                         wcross_name_alpha_goal_prev_prev = 0;
1361                         wcross_resolution_goal_prev = 0;
1362                         wcross_resolution_goal_prev_prev = 0;
1363                 }
1364         }
1365
1366         if(NextFrameCommand)
1367         {
1368                 localcmd("\n", NextFrameCommand, "\n");
1369                 NextFrameCommand = string_null;
1370         }
1371
1372         // we must do this check AFTER a frame was rendered, or it won't work
1373         if(cs_project_is_b0rked == 0)
1374         {
1375                 string w0, h0;
1376                 w0 = ftos(autocvar_vid_conwidth);
1377                 h0 = ftos(autocvar_vid_conheight);
1378                 //R_SetView(VF_VIEWPORT, '0 0 0', '640 480 0');
1379                 //R_SetView(VF_FOV, '90 90 0');
1380                 R_SetView(VF_ORIGIN, '0 0 0');
1381                 R_SetView(VF_ANGLES, '0 0 0');
1382                 R_SetView(VF_PERSPECTIVE, 1);
1383                 makevectors('0 0 0');
1384                 vector v1, v2;
1385                 cvar_set("vid_conwidth", "800");
1386                 cvar_set("vid_conheight", "600");
1387                 v1 = cs_project(v_forward);
1388                 cvar_set("vid_conwidth", "640");
1389                 cvar_set("vid_conheight", "480");
1390                 v2 = cs_project(v_forward);
1391                 if(v1 == v2)
1392                         cs_project_is_b0rked = 1;
1393                 else
1394                         cs_project_is_b0rked = -1;
1395                 cvar_set("vid_conwidth", w0);
1396                 cvar_set("vid_conheight", h0);
1397         }
1398
1399         if(autocvar__hud_configure)
1400                 HUD_Panel_Mouse();
1401
1402     if(hud && !intermission)
1403     {
1404         if(hud == HUD_SPIDERBOT)
1405             CSQC_SPIDER_HUD();
1406         else if(hud == HUD_WAKIZASHI)
1407             CSQC_WAKIZASHI_HUD();
1408         else if(hud == HUD_RAPTOR)
1409             CSQC_RAPTOR_HUD();
1410         else if(hud == HUD_BUMBLEBEE)
1411             CSQC_BUMBLE_HUD();
1412     }
1413         // let's reset the view back to normal for the end
1414         R_SetView(VF_MIN, '0 0 0');
1415         R_SetView(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1416 }
1417
1418
1419 void CSQC_common_hud(void)
1420 {
1421     // do some accuracy var caching
1422     float i;
1423     if(!(gametype == GAME_RACE || gametype == GAME_CTS))
1424     {
1425         if(autocvar_accuracy_color_levels != acc_color_levels)
1426         {
1427             if(acc_color_levels)
1428                 strunzone(acc_color_levels);
1429             acc_color_levels = strzone(autocvar_accuracy_color_levels);
1430             acc_levels = tokenize_console(acc_color_levels);
1431             if (acc_levels > MAX_ACCURACY_LEVELS)
1432                 acc_levels = MAX_ACCURACY_LEVELS;
1433
1434             for (i = 0; i < acc_levels; ++i)
1435                 acc_lev[i] = stof(argv(i)) / 100.0;
1436         }
1437         // let know that acc_col[] needs to be loaded
1438         acc_col_x[0] = -1;
1439     }
1440
1441     HUD_Main(); // always run these functions for alpha checks
1442     HUD_DrawScoreboard();
1443
1444     if (scoreboard_active) // scoreboard/accuracy
1445         HUD_Reset();
1446     else if (intermission == 2) // map voting screen
1447     {
1448         HUD_FinaleOverlay();
1449         HUD_Reset();
1450     }
1451         /*
1452         switch(hud)
1453         {
1454                 case HUD_SPIDERBOT:
1455                         CSQC_SPIDER_HUD();
1456                         break;
1457
1458                 case HUD_WAKIZASHI:
1459                         CSQC_WAKIZASHI_HUD();
1460                         break;
1461
1462         case HUD_BUMBLEBEE:
1463             CSQC_BUMBLE_HUD();
1464             break;
1465         }
1466         */
1467 }
1468
1469
1470 // following vectors must be global to allow seamless switching between camera modes
1471 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1472 void CSQC_Demo_Camera()
1473 {
1474         float speed, attenuation, dimensions;
1475         vector tmp, delta;
1476
1477         if( autocvar_camera_reset || !camera_mode )
1478         {
1479                 camera_offset = '0 0 0';
1480                 current_angles = '0 0 0';
1481                 camera_direction = '0 0 0';
1482                 camera_offset_z += 30;
1483                 camera_offset_x += 30 * -cos(current_angles_y * DEG2RAD);
1484                 camera_offset_y += 30 * -sin(current_angles_y * DEG2RAD);
1485                 current_origin = view_origin;
1486                 current_camera_offset  = camera_offset;
1487                 cvar_set("camera_reset", "0");
1488                 camera_mode = CAMERA_CHASE;
1489         }
1490
1491         // Camera angles
1492         if( camera_roll )
1493                 mouse_angles_z += camera_roll * autocvar_camera_speed_roll;
1494
1495         if(autocvar_camera_look_player)
1496         {
1497                 vector dir;
1498                 float n;
1499
1500                 dir = normalize(view_origin - current_position);
1501                 n = mouse_angles_z;
1502                 mouse_angles = vectoangles(dir);
1503                 mouse_angles_x = mouse_angles_x * -1;
1504                 mouse_angles_z = n;
1505         }
1506         else
1507         {
1508                 tmp = getmousepos() * 0.1;
1509                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1510                 {
1511                         mouse_angles_x += tmp_y * cos(mouse_angles_z * DEG2RAD) + (tmp_x * sin(mouse_angles_z * DEG2RAD));
1512                         mouse_angles_y -= tmp_x * cos(mouse_angles_z * DEG2RAD) + (tmp_y * -sin(mouse_angles_z * DEG2RAD));
1513                 }
1514         }
1515
1516         while (mouse_angles_x < -180) mouse_angles_x = mouse_angles_x + 360;
1517         while (mouse_angles_x > 180) mouse_angles_x = mouse_angles_x - 360;
1518         while (mouse_angles_y < -180) mouse_angles_y = mouse_angles_y + 360;
1519         while (mouse_angles_y > 180) mouse_angles_y = mouse_angles_y - 360;
1520
1521         // Fix difference when angles don't have the same sign
1522         delta = '0 0 0';
1523         if(mouse_angles_y < -60 && current_angles_y > 60)
1524                 delta = '0 360 0';
1525         if(mouse_angles_y > 60 && current_angles_y < -60)
1526                 delta = '0 -360 0';
1527
1528         if(autocvar_camera_look_player)
1529                 attenuation = autocvar_camera_look_attenuation;
1530         else
1531                 attenuation = autocvar_camera_speed_attenuation;
1532
1533         attenuation = 1 / max(1, attenuation);
1534         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1535
1536         while (current_angles_x < -180) current_angles_x = current_angles_x + 360;
1537         while (current_angles_x > 180) current_angles_x = current_angles_x - 360;
1538         while (current_angles_y < -180) current_angles_y = current_angles_y + 360;
1539         while (current_angles_y > 180) current_angles_y = current_angles_y - 360;
1540
1541         // Camera position
1542         tmp = '0 0 0';
1543         dimensions = 0;
1544
1545         if( camera_direction_x )
1546         {
1547                 tmp_x = camera_direction_x * cos(current_angles_y * DEG2RAD);
1548                 tmp_y = camera_direction_x * sin(current_angles_y * DEG2RAD);
1549                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1550                         tmp_z = camera_direction_x * -sin(current_angles_x * DEG2RAD);
1551                 ++dimensions;
1552         }
1553
1554         if( camera_direction_y )
1555         {
1556                 tmp_x += camera_direction_y * -sin(current_angles_y * DEG2RAD);
1557                 tmp_y += camera_direction_y * cos(current_angles_y * DEG2RAD) * cos(current_angles_z * DEG2RAD);
1558                 tmp_z += camera_direction_y * sin(current_angles_z * DEG2RAD);
1559                 ++dimensions;
1560         }
1561
1562         if( camera_direction_z )
1563         {
1564                 tmp_z += camera_direction_z * cos(current_angles_z * DEG2RAD);
1565                 ++dimensions;
1566         }
1567
1568         if(autocvar_camera_free)
1569                 speed = autocvar_camera_speed_free;
1570         else
1571                 speed = autocvar_camera_speed_chase;
1572
1573         if(dimensions)
1574         {
1575                 speed = speed * sqrt(1 / dimensions);
1576                 camera_offset += tmp * speed;
1577         }
1578
1579         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1580
1581         // Camera modes
1582         if( autocvar_camera_free )
1583         {
1584                 if ( camera_mode == CAMERA_CHASE )
1585                 {
1586                         current_camera_offset = current_origin + current_camera_offset;
1587                         camera_offset = current_origin + camera_offset;
1588                 }
1589
1590                 camera_mode = CAMERA_FREE;
1591                 current_position = current_camera_offset;
1592         }
1593         else
1594         {
1595                 if ( camera_mode == CAMERA_FREE )
1596                 {
1597                         current_origin = view_origin;
1598                         camera_offset = camera_offset - current_origin;
1599                         current_camera_offset = current_camera_offset - current_origin;
1600                 }
1601
1602                 camera_mode = CAMERA_CHASE;
1603
1604                 if(autocvar_camera_chase_smoothly)
1605                         current_origin += (view_origin - current_origin) * attenuation;
1606                 else
1607                         current_origin = view_origin;
1608
1609                 current_position = current_origin + current_camera_offset;
1610         }
1611
1612         R_SetView(VF_ANGLES, current_angles);
1613         R_SetView(VF_ORIGIN, current_position);
1614 }