qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', "ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!", '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49 #ifdef USE_FTE
  50 #pragma target ID
  51         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  52         if(!__engine_check)
  53         {
  54                 print("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n");
  55                 localcmd("\ndisconnect\n");
  56                 return;
  57         }
  58 #pragma target FTE
  59 #endif
  60
  61         check_unacceptable_compiler_bugs();
  62
  63 #ifdef WATERMARK
  64         print("^4CSQC Build information: ", WATERMARK(), "\n");
  65 #endif
  66
  67         float i;
  68         CSQC_CheckEngine();
  69
  70         binddb = db_create();
  71         tempdb = db_create();
  72         ClientProgsDB = db_load("client.db");
  73         compressShortVector_init();
  74
  75         drawfont = 0;
  76         menu_visible = FALSE;
  77         menu_show = menu_show_error;
  78         menu_action = menu_sub_null;
  79
  80         for(i = 0; i < 255; ++i)
  81                 if(getplayerkey(i, "viewentity") == "")
  82                         break;
  83         maxclients = i;
  84
  85         //ctf_temp_1 = "";
  86         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  87         //registercmd("ctf_menu");
  88         registercmd("ons_map");
  89         registercmd("hud_configure");
  90         registercmd("hud_save");
  91         //registercmd("menu_action");
  92
  93         registercmd("+button3");
  94         registercmd("-button3");
  95         registercmd("+button4");
  96         registercmd("-button4");
  97         registercmd("+showscores");registercmd("-showscores");
  98         registercmd("+showaccuracy");registercmd("-showaccuracy");
  99
 100 #ifndef CAMERATEST
 101         if(isdemo())
 102         {
 103 #endif
 104                 registercmd("+forward");registercmd("-forward");
 105                 registercmd("+back");registercmd("-back");
 106                 registercmd("+moveup");registercmd("-moveup");
 107                 registercmd("+movedown");registercmd("-movedown");
 108                 registercmd("+moveright");registercmd("-moveright");
 109                 registercmd("+moveleft");registercmd("-moveleft");
 110                 registercmd("+roll_right");registercmd("-roll_right");
 111                 registercmd("+roll_left");registercmd("-roll_left");
 112 #ifndef CAMERATEST
 113         }
 114 #endif
 115         registercvar("hud_usecsqc", "1");
 116         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 117
 118         gametype = 0;
 119
 120         // hud_fields uses strunzone on the titles!
 121         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 122                 hud_title[i] = strzone("(null)");
 123
 124         postinit = false;
 125
 126         calledhooks = 0;
 127
 128         teams = Sort_Spawn();
 129         players = Sort_Spawn();
 130
 131         GetTeam(COLOR_SPECTATOR, true); // add specs first
 132
 133         RegisterWeapons();
 134
 135         WaypointSprite_Load();
 136
 137         // precaches
 138         Projectile_Precache();
 139         Hook_Precache();
 140         GibSplash_Precache();
 141         Casings_Precache();
 142         DamageInfo_Precache();
 143         if(cvar_string("cl_announcer") != cl_announcer_prev) {
 144                 Announcer_Precache();
 145                 if(cl_announcer_prev)
 146                         strunzone(cl_announcer_prev);
 147                 cl_announcer_prev = strzone(cvar_string("cl_announcer"));
 148         }
 149         Tuba_Precache();
 150
 151         get_mi_min_max_texcoords(1); // try the CLEVER way first
 152         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 153         shortmapname = mi_shortname;
 154
 155         if(precache_pic(minimapname) == "")
 156         {
 157                 // but maybe we have a non-clever minimap
 158                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 159                 if(precache_pic(minimapname) == "")
 160                         minimapname = ""; // FAIL
 161                 else
 162                         get_mi_min_max_texcoords(0); // load new texcoords
 163         }
 164
 165         mi_center = (mi_min + mi_max) * 0.5;
 166         mi_scale = mi_max - mi_min;
 167         minimapname = strzone(minimapname);
 168
 169         WarpZone_Init();
 170         hud_configure_prev = -1;
 171 }
 172
 173 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 174 void CSQC_Shutdown(void)
 175 {
 176 #ifdef USE_FTE
 177 #pragma TARGET id
 178         if(!__engine_check)
 179                 return 0;
 180 #pragma TARGET fte
 181 #endif
 182
 183         WarpZone_Shutdown();
 184
 185         remove(teams);
 186         remove(players);
 187         db_close(binddb);
 188         db_close(tempdb);
 189         db_save(ClientProgsDB, "client.db");
 190         db_close(ClientProgsDB);
 191
 192         cvar_clientsettemp_restore();
 193
 194         if(camera_active)
 195                 cvar_set("chase_active",ftos(chase_active_backup));
 196
 197         if not(isdemo())
 198         {
 199                 if not(calledhooks & HOOK_START)
 200                         localcmd("\n_cl_hook_gamestart nop\n");
 201                 if not(calledhooks & HOOK_END)
 202                         localcmd("\ncl_hook_gameend\n");
 203         }
 204 }
 205
 206 .float has_team;
 207 float SetTeam(entity o, float Team)
 208 {
 209         entity tm;
 210         if(teamplay)
 211         {
 212                 switch(Team)
 213                 {
 214                         case -1:
 215                         case COLOR_TEAM1:
 216                         case COLOR_TEAM2:
 217                         case COLOR_TEAM3:
 218                         case COLOR_TEAM4:
 219                                 break;
 220                         default:
 221                                 if(GetTeam(Team, false) == NULL)
 222                                 {
 223                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 224                                         Team = COLOR_SPECTATOR;
 225                                 }
 226                                 break;
 227                 }
 228         }
 229         else
 230         {
 231                 switch(Team)
 232                 {
 233                         case -1:
 234                         case 0:
 235                                 break;
 236                         default:
 237                                 if(GetTeam(Team, false) == NULL)
 238                                 {
 239                                         print("trying to switch to unsupported team ", ftos(Team), "\n");
 240                                         Team = COLOR_SPECTATOR;
 241                                 }
 242                                 break;
 243                 }
 244         }
 245         if(Team == -1) // leave
 246         {
 247                 if(o.has_team)
 248                 {
 249                         //print("(DISCONNECT) leave team ", ftos(o.team), "\n");
 250                         tm = GetTeam(o.team, false);
 251                         tm.team_size -= 1;
 252                         o.has_team = 0;
 253                         return TRUE;
 254                 }
 255         }
 256         else
 257         {
 258                 if not(o.has_team)
 259                 {
 260                         //print("(CONNECT) enter team ", ftos(o.team), "\n");
 261                         o.team = Team;
 262                         tm = GetTeam(Team, true);
 263                         tm.team_size += 1;
 264                         o.has_team = 1;
 265                         return TRUE;
 266                 }
 267                 else if(Team != o.team)
 268                 {
 269                         //print("(CHANGE) leave team ", ftos(o.team), "\n");
 270                         tm = GetTeam(o.team, false);
 271                         tm.team_size -= 1;
 272                         o.team = Team;
 273                         //print("(CHANGE) enter team ", ftos(o.team), "\n");
 274                         tm = GetTeam(Team, true);
 275                         tm.team_size += 1;
 276                         return TRUE;
 277                 }
 278         }
 279         return FALSE;
 280 }
 281
 282 void Playerchecker_Think()
 283 {
 284         float i;
 285         entity e;
 286         for(i = 0; i < maxclients; ++i)
 287         {
 288                 e = playerslots[i];
 289                 if(GetPlayerName(i) == "")
 290                 {
 291                         if(e.sort_prev)
 292                         {
 293                                 //print("playerchecker: KILL KILL KILL\n");
 294                                 // player disconnected
 295                                 SetTeam(e, -1);
 296                                 RemovePlayer(e);
 297                                 e.sort_prev = world;
 298                                 //e.gotscores = 0;
 299                         }
 300                 }
 301                 else
 302                 {
 303                         if not(e.sort_prev)
 304                         {
 305                                 //print("playerchecker: SPAWN SPAWN SPAWN\n");
 306                                 // player connected
 307                                 if not(e)
 308                                         playerslots[i] = e = spawn();
 309                                 e.sv_entnum = i;
 310                                 e.ping = 0;
 311                                 e.ping_packetloss = 0;
 312                                 e.ping_movementloss = 0;
 313                                 //e.gotscores = 0; // we might already have the scores...
 314                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 315                                 RegisterPlayer(e);
 316                                 HUD_UpdatePlayerPos(e);
 317                         }
 318                 }
 319         }
 320         self.nextthink = time + 0.2;
 321 }
 322
 323 void Porto_Init();
 324 void TrueAim_Init();
 325 void PostInit(void)
 326 {
 327         print(strcat("PostInit\n    maxclients = ", ftos(maxclients), "\n"));
 328         localcmd(strcat("\nscoreboard_columns_set ", cvar_string("scoreboard_columns"), ";\n"));
 329
 330         entity playerchecker;
 331         playerchecker = spawn();
 332         playerchecker.think = Playerchecker_Think;
 333         playerchecker.nextthink = time + 0.2;
 334
 335         Porto_Init();
 336         TrueAim_Init();
 337
 338         postinit = true;
 339 }
 340
 341 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 342 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 343 float button_zoom;
 344 void Cmd_HUD_SetFields(float);
 345 void Cmd_HUD_Help(float);
 346 float CSQC_ConsoleCommand(string strMessage)
 347 {
 348         float argc;
 349         // Tokenize String
 350         //argc = tokenize(strMessage);
 351         argc = tokenize_console(strMessage);
 352
 353         // Acquire Command
 354         local string strCmd;
 355         strCmd = argv(0);
 356
 357         if(strCmd == "hud_configure") { // config hud
 358                 cvar_set("_hud_configure", ftos(!cvar("_hud_configure")));
 359                 return true;
 360         } else if(strCmd == "hud_save") { // save hud config
 361                 if(argv(1) == "" || argv(2)) {
 362                         print("Usage:\n");
 363                         print("hud_save configname   (saves to hud_skinname_configname.cfg)\n");
 364                 }
 365                 else
 366                         HUD_Panel_ExportCfg(argv(1));
 367                 return true;
 368         } else if(strCmd == "+button4") { // zoom
 369                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 370                 if(ignore_plus_zoom)
 371                 {
 372                         --ignore_plus_zoom;
 373                         return false;
 374                 }
 375                 button_zoom = 1;
 376                 return true;
 377         } else if(strCmd == "-button4") { // zoom
 378                 if(ignore_minus_zoom)
 379                 {
 380                         --ignore_minus_zoom;
 381                         return false;
 382                 }
 383                 button_zoom = 0;
 384                 return true;
 385         } else if(strCmd == "+button3") { // secondary
 386                 button_attack2 = 1;
 387                 return false;
 388         } else if(strCmd == "-button3") { // secondary
 389                 button_attack2 = 0;
 390                 return false;
 391         } else if(strCmd == "+showscores") {
 392                 scoreboard_showscores = true;
 393                 return true;
 394         } else if(strCmd == "-showscores") {
 395                 scoreboard_showscores = false;
 396                 return true;
 397         } else if(strCmd == "+showaccuracy") {
 398                 scoreboard_showaccuracy = true;
 399                 return true;
 400         } else if(strCmd == "-showaccuracy") {
 401                 scoreboard_showaccuracy = false;
 402                 return true;
 403         }
 404
 405         if(camera_active)
 406         if(strCmd == "+forward" || strCmd == "-back") {
 407                 ++camera_direction_x;
 408                 return true;
 409         } else if(strCmd == "-forward" || strCmd == "+back") {
 410                 --camera_direction_x;
 411                 return true;
 412         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 413                 --camera_direction_y;
 414                 return true;
 415         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 416                 ++camera_direction_y;
 417                 return true;
 418         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 419                 ++camera_direction_z;
 420                 return true;
 421         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 422                 --camera_direction_z;
 423                 return true;
 424         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 425                 ++camera_roll;
 426                 return true;
 427         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 428                 --camera_roll;
 429                 return true;
 430         }
 431
 432         return false;
 433 }
 434
 435 .vector view_ofs;
 436 entity debug_shotorg;
 437 void ShotOrg_Draw()
 438 {
 439         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 440         self.angles = view_angles;
 441         self.angles_x = -self.angles_x;
 442         if not(self.cnt)
 443                 self.drawmask = MASK_NORMAL;
 444         else
 445                 self.drawmask = 0;
 446 }
 447 void ShotOrg_Draw2D()
 448 {
 449         vector coord2d_topleft, coord2d_topright, coord2d;
 450         string s;
 451         vector fs;
 452
 453         s = vtos(self.view_ofs);
 454         s = substring(s, 1, strlen(s) - 2);
 455         if(tokenize_console(s) == 3)
 456                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 457
 458         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 459         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 460
 461         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 462
 463         coord2d = coord2d_topleft;
 464         if(fs_x < 8)
 465         {
 466                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 467                 fs = '8 8 0';
 468         }
 469         coord2d_y -= fs_y;
 470         coord2d_z = 0;
 471         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 472 }
 473
 474 void ShotOrg_Spawn()
 475 {
 476         debug_shotorg = spawn();
 477         debug_shotorg.draw = ShotOrg_Draw;
 478         debug_shotorg.draw2d = ShotOrg_Draw2D;
 479         debug_shotorg.renderflags = RF_VIEWMODEL;
 480         debug_shotorg.effects = EF_FULLBRIGHT;
 481         precache_model("models/shotorg_adjuster.md3");
 482         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 483         debug_shotorg.scale = 2;
 484         debug_shotorg.view_ofs = '25 8 -8';
 485 }
 486
 487 void DrawDebugModel()
 488 {
 489         if(time - floor(time) > 0.5)
 490         {
 491                 PolyDrawModel(self);
 492                 self.drawmask = 0;
 493         }
 494         else
 495         {
 496                 self.renderflags = 0;
 497                 self.drawmask = MASK_NORMAL;
 498         }
 499 }
 500
 501 void GameCommand(string msg)
 502 {
 503         string s;
 504         float argc;
 505         entity e;
 506         argc = tokenize_console(msg);
 507
 508         if(argv(0) == "help" || argc == 0)
 509         {
 510                 print("Usage: cl_cmd COMMAND..., where possible commands are:\n");
 511                 print("  settemp cvar value\n");
 512                 print("  scoreboard_columns_set ...\n");
 513                 print("  scoreboard_columns_help\n");
 514                 GameCommand_Generic("help");
 515                 return;
 516         }
 517
 518         if(GameCommand_Generic(msg))
 519                 return;
 520
 521         string cmd;
 522         cmd = argv(0);
 523         if(cmd == "mv_download") {
 524                 Cmd_MapVote_MapDownload(argc);
 525         }
 526         else if(cmd == "settemp") {
 527                 cvar_clientsettemp(argv(1), argv(2));
 528         }
 529         else if(cmd == "scoreboard_columns_set") {
 530                 Cmd_HUD_SetFields(argc);
 531         }
 532         else if(cmd == "scoreboard_columns_help") {
 533                 Cmd_HUD_Help(argc);
 534         }
 535 #ifdef BLURTEST
 536         else if(cmd == "blurtest") {
 537                 blurtest_time0 = time;
 538                 blurtest_time1 = time + stof(argv(1));
 539                 blurtest_radius = stof(argv(2));
 540                 blurtest_power = stof(argv(3));
 541         }
 542 #endif
 543         else if(cmd == "shotorg_move") {
 544                 if(!debug_shotorg)
 545                         ShotOrg_Spawn();
 546                 else
 547                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 548                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 549         }
 550         else if(cmd == "shotorg_movez") {
 551                 if(!debug_shotorg)
 552                         ShotOrg_Spawn();
 553                 else
 554                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 555                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 556         }
 557         else if(cmd == "shotorg_set") {
 558                 if(!debug_shotorg)
 559                         ShotOrg_Spawn();
 560                 else
 561                         debug_shotorg.view_ofs = stov(argv(1));
 562                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 563         }
 564         else if(cmd == "shotorg_setz") {
 565                 if(!debug_shotorg)
 566                         ShotOrg_Spawn();
 567                 else
 568                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 569                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 570         }
 571         else if(cmd == "shotorg_toggle_hide") {
 572                 if(debug_shotorg)
 573                 {
 574                         debug_shotorg.cnt = !debug_shotorg.cnt;
 575                 }
 576         }
 577         else if(cmd == "shotorg_end") {
 578                 if(debug_shotorg)
 579                 {
 580                         print(vtos(debug_shotorg.view_ofs), "\n");
 581                         remove(debug_shotorg);
 582                         debug_shotorg = world;
 583                 }
 584                 localcmd("sv_cmd debug_shotorg\n");
 585         }
 586         else if(cmd == "sendcvar") {
 587                 // W_FixWeaponOrder will trash argv, so save what we need.
 588                 string thiscvar;
 589                 thiscvar = strzone(argv(1));
 590                 s = cvar_string(thiscvar);
 591                 if(thiscvar == "cl_weaponpriority")
 592                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 593                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 594                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 595                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 596                 strunzone(thiscvar);
 597         }
 598         else if(cmd == "spawn") {
 599                 s = argv(1);
 600                 e = spawn();
 601                 precache_model(s);
 602                 setmodel(e, s);
 603                 setorigin(e, view_origin);
 604                 e.angles = view_angles;
 605                 e.draw = DrawDebugModel;
 606                 e.classname = "debugmodel";
 607         }
 608         else
 609         {
 610                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 611         }
 612
 613         return;
 614 }
 615
 616 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 617 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 618 // All keys are in ascii.
 619 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 620 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 621 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 622 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 623 {
 624         local float bSkipKey;
 625         bSkipKey = false;
 626
 627         if(autocvar_cl_allow_uid2name == -1 && (gametype == GAME_CTS || gametype == GAME_RACE) && panel_fg_alpha && !scoreboard_active) // don't lock keys before we actually see what's going on
 628         {
 629                 /*
 630                 string vyes_keys;
 631                 float keys;
 632                 vyes_keys = findkeysforcommand("vyes");
 633                 keys = tokenize(vyes_keys);
 634
 635                 float i;
 636                 for (i = 0; i < keys; ++i)
 637                 {
 638                         print(ftos(nPrimary), " ", argv(i), "\n");
 639                         if(nPrimary == stof(argv(i)))
 640                         {
 641                                 vote_active = 0;
 642                                 cvar_set("cl_allow_uid2name", "1");
 643                                 return TRUE;
 644                         }
 645                 }
 646
 647                 string vno_keys;
 648                 vno_keys = findkeysforcommand("vno");
 649                 keys = tokenize(vno_keys);
 650
 651                 float i;
 652                 for (i = 0; i < keys; ++i)
 653                 {
 654                         if(nPrimary == stof(argv(i)))
 655                         {
 656                                 vote_active = 0;
 657                                 cvar_set("cl_allow_uid2name", "0");
 658                                 return TRUE;
 659                         }
 660                 }
 661                 */ // If only I could grab F1-F12 in CSQC... but no
 662
 663                 if(nPrimary == 121) // ascii value for y
 664                 {
 665                         vote_active = 0;
 666                         cvar_set("cl_allow_uid2name", "1");
 667                         return TRUE;
 668                 }
 669                 else if(nPrimary == 110) // ascii value for n
 670                 {
 671                         vote_active = 0;
 672                         cvar_set("cl_allow_uid2name", "0");
 673                         return TRUE;
 674                 }
 675                 else if(nPrimary == 27) // ascii value for esc
 676                 {
 677                         return FALSE;
 678                 }
 679                 return TRUE; // capture all other keys to get more attention
 680         }
 681
 682         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 683                 return true;
 684
 685         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 686                 return true;
 687
 688         if(menu_visible)
 689                 if(menu_action(bInputType, nPrimary, nSecondary))
 690                         return TRUE;
 691
 692         return bSkipKey;
 693 }
 694
 695 // END REQUIRED CSQC FUNCTIONS
 696 // --------------------------------------------------------------------------
 697
 698 // --------------------------------------------------------------------------
 699 // BEGIN OPTIONAL CSQC FUNCTIONS
 700 void Ent_ReadEntCS()
 701 {
 702         InterpolateOrigin_Undo();
 703
 704         self.classname = "entcs_receiver";
 705         self.sv_entnum = ReadByte() - 1;
 706         self.origin_x = ReadShort();
 707         self.origin_y = ReadShort();
 708         self.origin_z = ReadShort();
 709         self.angles_y = ReadByte() * 360.0 / 256;
 710         self.origin_z = self.angles_x = self.angles_z = 0;
 711
 712         InterpolateOrigin_Note();
 713 }
 714
 715 void Ent_Remove();
 716
 717 void Ent_RemovePlayerScore()
 718 {
 719         float i;
 720
 721         if(self.owner)
 722         {
 723                 SetTeam(self.owner, -1);
 724                 self.owner.gotscores = 0;
 725                 for(i = 0; i < MAX_SCORE; ++i)
 726                         self.owner.(scores[i]) = 0; // clear all scores
 727         }
 728 }
 729
 730 void Ent_ReadPlayerScore()
 731 {
 732         float i, n;
 733         float isNew;
 734         entity o;
 735
 736         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 737         // (no I've never heard of M-x replace-string, sed, or anything like that)
 738         isNew = !self.owner; // workaround for DP bug
 739         n = ReadByte()-1;
 740
 741 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 742         if(!isNew && n != self.sv_entnum)
 743         {
 744                 print("A CSQC entity changed its owner!\n");
 745                 isNew = true;
 746                 Ent_Remove();
 747                 self.enttype = ENT_CLIENT_SCORES;
 748         }
 749 #endif
 750
 751         self.sv_entnum = n;
 752
 753         if not(playerslots[self.sv_entnum])
 754                 playerslots[self.sv_entnum] = spawn();
 755         o = self.owner = playerslots[self.sv_entnum];
 756         o.sv_entnum = self.sv_entnum;
 757         o.gotscores = 1;
 758
 759         //if not(o.sort_prev)
 760         //      RegisterPlayer(o);
 761         //playerchecker will do this for us later, if it has not already done so
 762
 763         float sf, lf;
 764 #if MAX_SCORE <= 8
 765         sf = ReadByte();
 766         lf = ReadByte();
 767 #else
 768         sf = ReadShort();
 769         lf = ReadShort();
 770 #endif
 771         float p;
 772         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 773                 if(sf & p)
 774                 {
 775                         if(lf & p)
 776                                 o.(scores[i]) = ReadInt24_t();
 777                         else
 778                                 o.(scores[i]) = ReadChar();
 779                 }
 780
 781         if(o.sort_prev)
 782                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 783
 784         self.entremove = Ent_RemovePlayerScore;
 785 }
 786
 787 void Ent_ReadTeamScore()
 788 {
 789         float i;
 790         entity o;
 791
 792         self.team = ReadByte();
 793         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 794
 795         float sf, lf;
 796 #if MAX_TEAMSCORE <= 8
 797         sf = ReadByte();
 798         lf = ReadByte();
 799 #else
 800         sf = ReadShort();
 801         lf = ReadShort();
 802 #endif
 803         float p;
 804         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 805                 if(sf & p)
 806                 {
 807                         if(lf & p)
 808                                 o.(teamscores[i]) = ReadInt24_t();
 809                         else
 810                                 o.(teamscores[i]) = ReadChar();
 811                 }
 812
 813         HUD_UpdateTeamPos(o);
 814 }
 815
 816 void Net_Reset()
 817 {
 818 }
 819
 820 void Ent_ClientData()
 821 {
 822         float f;
 823         float newspectatee_status;
 824
 825         f = ReadByte();
 826
 827         scoreboard_showscores_force = (f & 1);
 828
 829         if(f & 2)
 830         {
 831                 newspectatee_status = ReadByte();
 832                 if(newspectatee_status == player_localentnum)
 833                         newspectatee_status = -1; // observing
 834         }
 835         else
 836                 newspectatee_status = 0;
 837
 838         spectatorbutton_zoom = (f & 4);
 839
 840         if(f & 8)
 841         {
 842                 angles_held_status = 1;
 843                 angles_held_x = ReadAngle();
 844                 angles_held_y = ReadAngle();
 845                 angles_held_z = 0;
 846         }
 847         else
 848                 angles_held_status = 0;
 849
 850         if(newspectatee_status != spectatee_status)
 851         {
 852                 float i;
 853                 // clear the weapon accuracy stats
 854                 for(i = WEP_FIRST; i <= WEP_LAST; ++i) {
 855                         weapon_hits[i] = 0;
 856                         weapon_fired[i] = 0;
 857                 }
 858
 859                 // clear race stuff
 860                 race_laptime = 0;
 861                 race_checkpointtime = 0;
 862         }
 863         spectatee_status = newspectatee_status;
 864 }
 865
 866 void Ent_Nagger()
 867 {
 868         float nags, i, j, b, f;
 869
 870         nags = ReadByte();
 871
 872         if(nags & 128)
 873         {
 874                 if(vote_called_vote)
 875                         strunzone(vote_called_vote);
 876                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 877         }
 878
 879         if(nags & 1)
 880         {
 881                 for(j = 0; j < maxclients; ++j)
 882                         if(playerslots[j])
 883                                 playerslots[j].ready = 1;
 884                 for(i = 1; i <= maxclients; i += 8)
 885                 {
 886                         f = ReadByte();
 887                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 888                                 if not(f & b)
 889                                         if(playerslots[j])
 890                                                 playerslots[j].ready = 0;
 891                 }
 892         }
 893
 894         ready_waiting = (nags & 1);
 895         ready_waiting_for_me = (nags & 2);
 896         vote_waiting = (nags & 4);
 897         vote_waiting_for_me = (nags & 8);
 898         warmup_stage = (nags & 16);
 899 }
 900
 901 void Ent_RandomSeed()
 902 {
 903         float s;
 904         prandom_debug();
 905         s = ReadShort();
 906         psrandom(s);
 907 }
 908
 909 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 910 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 911 void Ent_RadarLink();
 912 void Ent_Init();
 913 void Ent_ScoresInfo();
 914 void(float bIsNewEntity) CSQC_Ent_Update =
 915 {
 916         float t;
 917         float savetime;
 918         t = ReadByte();
 919
 920         // set up the "time" global for received entities to be correct for interpolation purposes
 921         savetime = time;
 922         if(servertime)
 923         {
 924                 time = servertime;
 925         }
 926         else
 927         {
 928                 serverprevtime = time;
 929                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 930                 time = serverprevtime + serverdeltatime;
 931         }
 932
 933 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 934         if(self.enttype)
 935                 if(t != self.enttype)
 936                 {
 937                         print("A CSQC entity changed its type!\n");
 938                         Ent_Remove();
 939                         bIsNewEntity = 1;
 940                 }
 941 #endif
 942         self.enttype = t;
 943         switch(t)
 944         {
 945                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 946                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 947                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 948                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 949                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 950                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 951                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 952                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 953                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 954                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 955                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 956                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 957                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 958                 case ENT_CLIENT_INIT: Ent_Init(); break;
 959                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 960                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 961                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 962                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 963                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 964                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 965                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 966                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 967                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 968                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 969                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 970                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 971                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 972                 default:
 973                         error(strcat("unknown entity type in CSQC_Ent_Update: ", ftos(self.enttype), "\n"));
 974                         break;
 975         }
 976
 977         time = savetime;
 978 };
 979 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 980 // used when an entity changes its type. For an entity that someone interacts
 981 // with others, make sure it can no longer do so.
 982 void Ent_Remove()
 983 {
 984         if(self.entremove)
 985                 self.entremove();
 986
 987         self.enttype = 0;
 988         self.classname = "";
 989         self.draw = menu_sub_null;
 990         self.entremove = menu_sub_null;
 991         // TODO possibly set more stuff to defaults
 992 }
 993 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 994 void CSQC_Ent_Remove()
 995 {
 996         if(self.enttype)
 997                 Ent_Remove();
 998         remove(self);
 999 }
1000
1001 void Gamemode_Init()
1002 {
1003         if(gametype == GAME_ONSLAUGHT) {
1004                 print(strcat("Using ", minimapname, " as minimap.\n"));
1005                 precache_pic("gfx/ons-cp-neutral.tga");
1006                 precache_pic("gfx/ons-cp-red.tga");
1007                 precache_pic("gfx/ons-cp-blue.tga");
1008                 precache_pic("gfx/ons-frame.tga");
1009                 precache_pic("gfx/ons-frame-team.tga");
1010         }
1011
1012         if not(isdemo())
1013         {
1014                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1015                 calledhooks |= HOOK_START;
1016         }
1017 }
1018 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1019 void CSQC_Parse_StuffCmd(string strMessage)
1020 {
1021         localcmd(strMessage);
1022 }
1023 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1024 void CSQC_Parse_Print(string strMessage)
1025 {
1026         print(ColorTranslateRGB(strMessage));
1027 }
1028
1029 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1030 void CSQC_Parse_CenterPrint(string strMessage)
1031 {
1032         centerprint(strMessage);
1033 }
1034
1035 string notranslate_fogcmd1 = "\nfog ";
1036 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1037 void Fog_Force()
1038 {
1039         // TODO somehow thwart prvm_globalset client ...
1040
1041         if(forcefog != "")
1042                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1043 }
1044
1045 void Gamemode_Init();
1046 void Ent_ScoresInfo()
1047 {
1048         float i;
1049         self.classname = "ent_client_scores_info";
1050         gametype = ReadByte();
1051         for(i = 0; i < MAX_SCORE; ++i)
1052         {
1053                 scores_label[i] = strzone(ReadString());
1054                 scores_flags[i] = ReadByte();
1055         }
1056         for(i = 0; i < MAX_TEAMSCORE; ++i)
1057         {
1058                 teamscores_label[i] = strzone(ReadString());
1059                 teamscores_flags[i] = ReadByte();
1060         }
1061         HUD_InitScores();
1062         Gamemode_Init();
1063 }
1064
1065 void Ent_Init()
1066 {
1067         self.classname = "ent_client_init";
1068
1069         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1070
1071         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1072         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1073         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1074         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1075         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1076         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1077         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1078         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1079         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1080         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1081         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1082         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1083
1084         if(forcefog)
1085                 strunzone(forcefog);
1086         forcefog = strzone(ReadString());
1087
1088         armorblockpercent = ReadByte() / 255.0;
1089
1090         g_weaponswitchdelay = ReadByte() / 255.0;
1091
1092         g_balance_grenadelauncher_secondary_bouncefactor = ReadCoord();
1093         g_balance_grenadelauncher_secondary_bouncestop = ReadCoord();
1094
1095         nex_scope = !ReadByte();
1096         campingrifle_scope = !ReadByte();
1097
1098         if(!postinit)
1099                 PostInit();
1100 }
1101
1102 void Net_ReadRace()
1103 {
1104         float b;
1105
1106         b = ReadByte();
1107
1108         switch(b)
1109         {
1110                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1111                         race_checkpoint = ReadByte();
1112                         race_time = ReadInt24_t();
1113                         race_previousbesttime = ReadInt24_t();
1114                         if(race_previousbestname)
1115                                 strunzone(race_previousbestname);
1116                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1117
1118                         race_checkpointtime = time;
1119
1120                         if(race_checkpoint == 0 || race_checkpoint == 254)
1121                         {
1122                                 race_penaltyaccumulator = 0;
1123                                 race_laptime = time; // valid
1124                         }
1125
1126                         break;
1127
1128                 case RACE_NET_CHECKPOINT_CLEAR:
1129                         race_laptime = 0;
1130                         race_checkpointtime = 0;
1131                         break;
1132
1133                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1134                         race_laptime = ReadCoord();
1135                         race_checkpointtime = -99999;
1136                         // fall through
1137                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1138                         race_nextcheckpoint = ReadByte();
1139
1140                         race_nextbesttime = ReadInt24_t();
1141                         if(race_nextbestname)
1142                                 strunzone(race_nextbestname);
1143                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1144                         break;
1145
1146                 case RACE_NET_CHECKPOINT_HIT_RACE:
1147                         race_mycheckpoint = ReadByte();
1148                         race_mycheckpointtime = time;
1149                         race_mycheckpointdelta = ReadInt24_t();
1150                         race_mycheckpointlapsdelta = ReadByte();
1151                         if(race_mycheckpointlapsdelta >= 128)
1152                                 race_mycheckpointlapsdelta -= 256;
1153                         if(race_mycheckpointenemy)
1154                                 strunzone(race_mycheckpointenemy);
1155                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1156                         break;
1157
1158                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1159                         race_othercheckpoint = ReadByte();
1160                         race_othercheckpointtime = time;
1161                         race_othercheckpointdelta = ReadInt24_t();
1162                         race_othercheckpointlapsdelta = ReadByte();
1163                         if(race_othercheckpointlapsdelta >= 128)
1164                                 race_othercheckpointlapsdelta -= 256;
1165                         if(race_othercheckpointenemy)
1166                                 strunzone(race_othercheckpointenemy);
1167                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1168                         break;
1169
1170                 case RACE_NET_PENALTY_RACE:
1171                         race_penaltyeventtime = time;
1172                         race_penaltytime = ReadShort();
1173                         //race_penaltyaccumulator += race_penaltytime;
1174                         if(race_penaltyreason)
1175                                 strunzone(race_penaltyreason);
1176                         race_penaltyreason = strzone(ReadString());
1177                         break;
1178
1179                 case RACE_NET_PENALTY_QUALIFYING:
1180                         race_penaltyeventtime = time;
1181                         race_penaltytime = ReadShort();
1182                         race_penaltyaccumulator += race_penaltytime;
1183                         if(race_penaltyreason)
1184                                 strunzone(race_penaltyreason);
1185                         race_penaltyreason = strzone(ReadString());
1186                         break;
1187
1188                 case RACE_NET_SERVER_RECORD:
1189                         race_server_record = ReadInt24_t();
1190                         break;
1191                 case RACE_NET_SPEED_AWARD:
1192                         race_speedaward = ReadInt24_t();
1193                         if(race_speedaward_holder)
1194                                 strunzone(race_speedaward_holder);
1195                         race_speedaward_holder = strzone(ReadString());
1196                         break;
1197                 case RACE_NET_SPEED_AWARD_BEST:
1198                         race_speedaward_alltimebest = ReadInt24_t();
1199                         if(race_speedaward_alltimebest_holder)
1200                                 strunzone(race_speedaward_alltimebest_holder);
1201                         race_speedaward_alltimebest_holder = strzone(ReadString());
1202                         break;
1203                 case RACE_NET_SERVER_RANKINGS:
1204                         float pos, prevpos, del;
1205                         pos = ReadShort();
1206                         prevpos = ReadShort();
1207                         del = ReadShort();
1208
1209                         // move other rankings out of the way
1210                         float i;
1211                         if (prevpos) {
1212                                 for (i=prevpos-1;i>pos-1;--i) {
1213                                         grecordtime[i] = grecordtime[i-1];
1214                                         if(grecordholder[i])
1215                                                 strunzone(grecordholder[i]);
1216                                         grecordholder[i] = strzone(grecordholder[i-1]);
1217                                 }
1218                         } else if (del) { // a record has been deleted by the admin
1219                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1220                                         if (i == RANKINGS_CNT-1) { // clear out last record
1221                                                 grecordtime[i] = 0;
1222                                                 if (grecordholder[i])
1223                                                         strunzone(grecordholder[i]);
1224                                                 grecordholder[i] = string_null;
1225                                         }
1226                                         else {
1227                                                 grecordtime[i] = grecordtime[i+1];
1228                                                 if (grecordholder[i])
1229                                                         strunzone(grecordholder[i]);
1230                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1231                                         }
1232                                 }
1233                         } else { // player has no ranked record yet
1234                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1235                                         grecordtime[i] = grecordtime[i-1];
1236                                         if(grecordholder[i])
1237                                                 strunzone(grecordholder[i]);
1238                                         grecordholder[i] = strzone(grecordholder[i-1]);
1239                                 }
1240                         }
1241
1242                         // store new ranking
1243                         if(grecordholder[pos-1] != "")
1244                                 strunzone(grecordholder[pos-1]);
1245                         grecordholder[pos-1] = strzone(ReadString());
1246                         grecordtime[pos-1] = ReadInt24_t();
1247                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1248                                 race_myrank = pos;
1249                         break;
1250                 case RACE_NET_SERVER_STATUS:
1251                         race_status = ReadShort();
1252                         if(race_status_name)
1253                                 strunzone(race_status_name);
1254                         race_status_name = strzone(ReadString());
1255         }
1256 }
1257
1258 void Net_ReadSpawn()
1259 {
1260         zoomin_effect = 1;
1261         current_viewzoom = 0.6;
1262 }
1263
1264 void Net_TeamNagger()
1265 {
1266         teamnagger = 1;
1267 }
1268
1269 void Net_ReadPingPLReport()
1270 {
1271         float e, pi, pl, ml;
1272         e = ReadByte();
1273         pi = ReadShort();
1274         pl = ReadByte();
1275         ml = ReadByte();
1276         if not(playerslots[e])
1277                 return;
1278         playerslots[e].ping = pi;
1279         playerslots[e].ping_packetloss = pl / 255.0;
1280         playerslots[e].ping_movementloss = ml / 255.0;
1281 }
1282
1283 void Net_VoteDialog(float highlight) {
1284         if(highlight) {
1285                 vote_highlighted = ReadByte();
1286                 return;
1287         }
1288
1289         vote_yescount = ReadByte();
1290         vote_nocount = ReadByte();
1291         vote_needed = ReadByte();
1292         vote_active = 1;
1293 }
1294
1295 void Net_VoteDialogReset() {
1296         vote_active = 0;
1297 }
1298
1299 void Net_Notify() {
1300         float type;
1301         type = ReadByte();
1302
1303         if(type == CSQC_KILLNOTIFY)
1304         {
1305                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1306         }
1307         else if(type == CSQC_CENTERPRINT)
1308         {
1309                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1310         }
1311 }
1312
1313 void Net_WeaponComplain() {
1314         complain_weapon = ReadByte();
1315
1316         if(complain_weapon_name)
1317                 strunzone(complain_weapon_name);
1318         complain_weapon_name = strzone(ReadString());
1319
1320         complain_weapon_type = ReadByte();
1321
1322         complain_weapon_time = time;
1323         weapontime = time; // ping the weapon panel
1324 }
1325
1326 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1327 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1328 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1329 float CSQC_Parse_TempEntity()
1330 {
1331         local float bHandled;
1332                 bHandled  = true;
1333         // Acquire TE ID
1334         local float nTEID;
1335                 nTEID = ReadByte();
1336
1337                 // NOTE: Could just do return instead of break...
1338         switch(nTEID)
1339         {
1340                 case TE_CSQC_TARGET_MUSIC:
1341                         Net_TargetMusic();
1342                         bHandled = true;
1343                         break;
1344                 case TE_CSQC_PICTURE:
1345                         Net_MapVote_Picture();
1346                         bHandled = true;
1347                         break;
1348                 case TE_CSQC_RACE:
1349                         Net_ReadRace();
1350                         bHandled = true;
1351                         break;
1352                 case TE_CSQC_SPAWN:
1353                         Net_ReadSpawn();
1354                         bHandled = true;
1355                         break;
1356                 case TE_CSQC_ZCURVEPARTICLES:
1357                         Net_ReadZCurveParticles();
1358                         bHandled = true;
1359                         break;
1360                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1361                         Net_ReadNexgunBeamParticle();
1362                         bHandled = true;
1363                         break;
1364                 case TE_CSQC_TEAMNAGGER:
1365                         Net_TeamNagger();
1366                         bHandled = true;
1367                         break;
1368                 case TE_CSQC_VOTE:
1369                         Net_VoteDialog(ReadByte());
1370                         bHandled = true;
1371                         break;
1372                 case TE_CSQC_VOTERESET:
1373                         Net_VoteDialogReset();
1374                         bHandled = true;
1375                         break;
1376                 case TE_CSQC_LIGHTNINGARC:
1377                         Net_ReadLightningarc();
1378                         bHandled = true;
1379                         break;
1380                 case TE_CSQC_PINGPLREPORT:
1381                         Net_ReadPingPLReport();
1382                         bHandled = true;
1383                         break;
1384                 case TE_CSQC_ANNOUNCE:
1385                         announce_snd = strzone(ReadString());
1386                         bHandled = true;
1387                         break;
1388                 case TE_CSQC_NOTIFY:
1389                         Net_Notify();
1390                         bHandled = true;
1391                         break;
1392                 case TE_CSQC_WEAPONCOMPLAIN:
1393                         Net_WeaponComplain();
1394                         bHandled = true;
1395                         break;
1396                 case TE_CSQC_CR_MAXBULLETS:
1397                         cr_maxbullets = ReadByte();
1398                         bHandled = true;
1399                         break;
1400                 default:
1401                         // No special logic for this temporary entity; return 0 so the engine can handle it
1402                         bHandled = false;
1403                         break;
1404         }
1405
1406         return bHandled;
1407 }
1408
1409 string getcommandkey(string text, string command)
1410 {
1411         string keys;
1412         float n, j, k, l;
1413
1414         if (!hud_showbinds)
1415                 return text;
1416
1417         keys = db_get(binddb, command);
1418         if (!keys)
1419         {
1420                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1421                 for(j = 0; j < n; ++j)
1422                 {
1423                         k = stof(argv(j));
1424                         if(k != -1)
1425                         {
1426                                 if ("" == keys)
1427                                         keys = keynumtostring(k);
1428                                 else
1429                                         keys = strcat(keys, ", ", keynumtostring(k));
1430
1431                                 ++l;
1432                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1433                         }
1434
1435                 }
1436                 db_put(binddb, command, keys);
1437         }
1438
1439         if ("" == keys) {
1440                 if (hud_showbinds > 1)
1441                         return strcat(text, " (not bound)");
1442                 else
1443                         return text;
1444         }
1445         else if (hud_showbinds > 1)
1446                 return strcat(text, " (", keys, ")");
1447         else
1448                 return keys;
1449 }