qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 entity clearentity_ent;
   6 void clearentity(entity e)
   7 {
   8         if (!clearentity_ent)
   9         {
  10                 clearentity_ent = spawn();
  11                 clearentity_ent.classname = "clearentity";
  12         }
  13         float n = e.entnum;
  14         copyentity(clearentity_ent, e);
  15         e.entnum = n;
  16 }
  17
  18 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
  19 void menu_show_error()
  20 {
  21         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  22 }
  23
  24 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  25 // Useful for precaching things
  26
  27 void menu_sub_null()
  28 {
  29 }
  30
  31 string forcefog;
  32 void WaypointSprite_Load();
  33 void ConsoleCommand_macro_init();
  34 void CSQC_Init(void)
  35 {
  36         prvm_language = strzone(cvar_string("prvm_language"));
  37
  38 #ifdef WATERMARK
  39         dprintf("^4CSQC Build information: ^1%s\n", WATERMARK);
  40 #endif
  41
  42         float i;
  43
  44         binddb = db_create();
  45         tempdb = db_create();
  46         ClientProgsDB = db_load("client.db");
  47         compressShortVector_init();
  48
  49         draw_endBoldFont();
  50         menu_visible = FALSE;
  51         menu_show = menu_show_error;
  52         menu_action = func_null;
  53
  54         for(i = 0; i < 255; ++i)
  55                 if(getplayerkeyvalue(i, "viewentity") == "")
  56                         break;
  57         maxclients = i;
  58
  59         //registercommand("hud_configure");
  60         //registercommand("hud_save");
  61         //registercommand("menu_action");
  62
  63         ConsoleCommand_macro_init();
  64
  65         registercvar("hud_usecsqc", "1");
  66         registercvar("scoreboard_columns", "default");
  67
  68         registercvar("cl_nade_type", "3");
  69         registercvar("cl_pokenade_type", "zombie");
  70
  71         gametype = 0;
  72
  73         // hud_fields uses strunzone on the titles!
  74         for(i = 0; i < MAX_HUD_FIELDS; ++i)
  75                 hud_title[i] = strzone("(null)");
  76
  77         Cmd_HUD_SetFields(0);
  78
  79         postinit = false;
  80
  81         calledhooks = 0;
  82
  83         teams = Sort_Spawn();
  84         players = Sort_Spawn();
  85
  86         GetTeam(NUM_SPECTATOR, true); // add specs first
  87
  88         // needs to be done so early because of the constants they create
  89         CALL_ACCUMULATED_FUNCTION(RegisterWeapons);
  90         CALL_ACCUMULATED_FUNCTION(RegisterMonsters);
  91         CALL_ACCUMULATED_FUNCTION(RegisterGametypes);
  92         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
  93         CALL_ACCUMULATED_FUNCTION(RegisterDeathtypes);
  94         CALL_ACCUMULATED_FUNCTION(RegisterHUD_Panels);
  95         CALL_ACCUMULATED_FUNCTION(RegisterBuffs);
  96
  97         WaypointSprite_Load();
  98
  99         // precaches
 100         precache_model("null");
 101         precache_sound("misc/hit.wav");
 102         precache_sound("misc/typehit.wav");
 103
 104         Projectile_Precache();
 105         Hook_Precache();
 106         GibSplash_Precache();
 107         Casings_Precache();
 108         Vehicles_Precache();
 109         turrets_precache();
 110         Tuba_Precache();
 111         CSQCPlayer_Precache();
 112
 113         if(autocvar_cl_reticle)
 114         {
 115                 precache_pic("gfx/reticle_normal");
 116                 // weapon reticles are precached in weapon files
 117         }
 118
 119         get_mi_min_max_texcoords(1); // try the CLEVER way first
 120         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 121         shortmapname = mi_shortname;
 122
 123         if(precache_pic(minimapname) == "")
 124         {
 125                 // but maybe we have a non-clever minimap
 126                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 127                 if(precache_pic(minimapname) == "")
 128                         minimapname = ""; // FAIL
 129                 else
 130                         get_mi_min_max_texcoords(0); // load new texcoords
 131         }
 132
 133         mi_center = (mi_min + mi_max) * 0.5;
 134         mi_scale = mi_max - mi_min;
 135         minimapname = strzone(minimapname);
 136
 137         WarpZone_Init();
 138
 139         hud_skin_path = strzone(strcat("gfx/hud/", autocvar_hud_skin));
 140         hud_configure_prev = -1;
 141
 142         draw_currentSkin = strzone(strcat("gfx/menu/", cvar_string("menu_skin")));
 143 }
 144
 145 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 146 void Shutdown(void)
 147 {
 148         WarpZone_Shutdown();
 149
 150         remove(teams);
 151         remove(players);
 152         db_close(binddb);
 153         db_close(tempdb);
 154         if(autocvar_cl_db_saveasdump)
 155                 db_dump(ClientProgsDB, "client.db");
 156         else
 157                 db_save(ClientProgsDB, "client.db");
 158         db_close(ClientProgsDB);
 159
 160         if(camera_active)
 161                 cvar_set("chase_active",ftos(chase_active_backup));
 162
 163         // unset the event chasecam's chase_active
 164         if(autocvar_chase_active < 0)
 165                 cvar_set("chase_active", "0");
 166
 167         if (!isdemo())
 168         {
 169                 if (!(calledhooks & HOOK_START))
 170                         localcmd("\n_cl_hook_gamestart nop\n");
 171                 if (!(calledhooks & HOOK_END))
 172                         localcmd("\ncl_hook_gameend\n");
 173         }
 174 }
 175
 176 .float has_team;
 177 float SetTeam(entity o, float Team)
 178 {
 179         entity tm;
 180         if(teamplay)
 181         {
 182                 switch(Team)
 183                 {
 184                         case -1:
 185                         case NUM_TEAM_1:
 186                         case NUM_TEAM_2:
 187                         case NUM_TEAM_3:
 188                         case NUM_TEAM_4:
 189                                 break;
 190                         default:
 191                                 if(GetTeam(Team, false) == world)
 192                                 {
 193                                         dprintf("trying to switch to unsupported team %d\n", Team);
 194                                         Team = NUM_SPECTATOR;
 195                                 }
 196                                 break;
 197                 }
 198         }
 199         else
 200         {
 201                 switch(Team)
 202                 {
 203                         case -1:
 204                         case 0:
 205                                 break;
 206                         default:
 207                                 if(GetTeam(Team, false) == world)
 208                                 {
 209                                         dprintf("trying to switch to unsupported team %d\n", Team);
 210                                         Team = NUM_SPECTATOR;
 211                                 }
 212                                 break;
 213                 }
 214         }
 215         if(Team == -1) // leave
 216         {
 217                 if(o.has_team)
 218                 {
 219                         tm = GetTeam(o.team, false);
 220                         tm.team_size -= 1;
 221                         o.has_team = 0;
 222                         return TRUE;
 223                 }
 224         }
 225         else
 226         {
 227                 if (!o.has_team)
 228                 {
 229                         o.team = Team;
 230                         tm = GetTeam(Team, true);
 231                         tm.team_size += 1;
 232                         o.has_team = 1;
 233                         return TRUE;
 234                 }
 235                 else if(Team != o.team)
 236                 {
 237                         tm = GetTeam(o.team, false);
 238                         tm.team_size -= 1;
 239                         o.team = Team;
 240                         tm = GetTeam(Team, true);
 241                         tm.team_size += 1;
 242                         return TRUE;
 243                 }
 244         }
 245         return FALSE;
 246 }
 247
 248 void Playerchecker_Think()
 249 {
 250         float i;
 251         entity e;
 252         for(i = 0; i < maxclients; ++i)
 253         {
 254                 e = playerslots[i];
 255                 if(GetPlayerName(i) == "")
 256                 {
 257                         if(e.sort_prev)
 258                         {
 259                                 // player disconnected
 260                                 SetTeam(e, -1);
 261                                 RemovePlayer(e);
 262                                 e.sort_prev = world;
 263                                 //e.gotscores = 0;
 264                         }
 265                 }
 266                 else
 267                 {
 268                         if (!e.sort_prev)
 269                         {
 270                                 // player connected
 271                                 if (!e)
 272                                         playerslots[i] = e = spawn();
 273                                 e.sv_entnum = i;
 274                                 e.ping = 0;
 275                                 e.ping_packetloss = 0;
 276                                 e.ping_movementloss = 0;
 277                                 //e.gotscores = 0; // we might already have the scores...
 278                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 279                                 RegisterPlayer(e);
 280                                 HUD_UpdatePlayerPos(e);
 281                         }
 282                 }
 283         }
 284         self.nextthink = time + 0.2;
 285 }
 286
 287 void Porto_Init();
 288 void TrueAim_Init();
 289 void PostInit(void)
 290 {
 291         entity playerchecker;
 292         playerchecker = spawn();
 293         playerchecker.think = Playerchecker_Think;
 294         playerchecker.nextthink = time + 0.2;
 295
 296         Porto_Init();
 297         TrueAim_Init();
 298
 299         postinit = true;
 300 }
 301
 302 float button_zoom;
 303
 304 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 305 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 306 // All keys are in ascii.
 307 // bInputType = 0 is key pressed, 1 is key released, 2 and 3 are mouse input.
 308 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 309 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 310 // In the case of mouse input after a setcursormode(1) call, nPrimary is xpos, nSecondary is ypos.
 311 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 312 {
 313         float bSkipKey;
 314         bSkipKey = false;
 315
 316         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 317                 return true;
 318
 319         if (HUD_QuickMenu_InputEvent(bInputType, nPrimary, nSecondary))
 320                 return true;
 321
 322         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 323                 return true;
 324
 325         if(menu_visible && menu_action)
 326                 if(menu_action(bInputType, nPrimary, nSecondary))
 327                         return TRUE;
 328
 329         return bSkipKey;
 330 }
 331
 332 // END REQUIRED CSQC FUNCTIONS
 333 // --------------------------------------------------------------------------
 334
 335 // --------------------------------------------------------------------------
 336 // BEGIN OPTIONAL CSQC FUNCTIONS
 337 void Ent_RemoveEntCS()
 338 {
 339         entcs_receiver[self.sv_entnum] = world;
 340 }
 341 void Ent_ReadEntCS()
 342 {
 343         float sf;
 344         InterpolateOrigin_Undo();
 345
 346         self.classname = "entcs_receiver";
 347         sf = ReadByte();
 348
 349         if(sf & 1)
 350                 self.sv_entnum = ReadByte();
 351         if(sf & 2)
 352         {
 353                 self.origin_x = ReadShort();
 354                 self.origin_y = ReadShort();
 355                 self.origin_z = ReadShort();
 356                 setorigin(self, self.origin);
 357         }
 358         if(sf & 4)
 359         {
 360                 self.angles_y = ReadByte() * 360.0 / 256;
 361                 self.angles_x = self.angles_z = 0;
 362         }
 363         if(sf & 8)
 364                 self.healthvalue = ReadByte() * 10;
 365         if(sf & 16)
 366                 self.armorvalue = ReadByte() * 10;
 367
 368         entcs_receiver[self.sv_entnum] = self;
 369         self.entremove = Ent_RemoveEntCS;
 370         self.iflags |= IFLAG_ORIGIN;
 371
 372         InterpolateOrigin_Note();
 373 }
 374
 375 void Ent_Remove();
 376
 377 void Ent_RemovePlayerScore()
 378 {
 379         float i;
 380
 381         if(self.owner)
 382         {
 383                 SetTeam(self.owner, -1);
 384                 self.owner.gotscores = 0;
 385                 for(i = 0; i < MAX_SCORE; ++i)
 386                         self.owner.(scores[i]) = 0; // clear all scores
 387         }
 388 }
 389
 390 void Ent_ReadPlayerScore()
 391 {
 392         float i, n;
 393         float isNew;
 394         entity o;
 395
 396         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 397         // (no I've never heard of M-x replace-string, sed, or anything like that)
 398         isNew = !self.owner; // workaround for DP bug
 399         n = ReadByte()-1;
 400
 401 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 402         if(!isNew && n != self.sv_entnum)
 403         {
 404                 //print("A CSQC entity changed its owner!\n");
 405                 printf("A CSQC entity changed its owner! (edict: %d, classname: %s)\n", num_for_edict(self), self.classname);
 406                 isNew = true;
 407                 Ent_Remove();
 408                 self.enttype = ENT_CLIENT_SCORES;
 409         }
 410 #endif
 411
 412         self.sv_entnum = n;
 413
 414         if (!(playerslots[self.sv_entnum]))
 415                 playerslots[self.sv_entnum] = spawn();
 416         o = self.owner = playerslots[self.sv_entnum];
 417         o.sv_entnum = self.sv_entnum;
 418         o.gotscores = 1;
 419
 420         //if (!o.sort_prev)
 421         //      RegisterPlayer(o);
 422         //playerchecker will do this for us later, if it has not already done so
 423
 424         float sf, lf;
 425 #if MAX_SCORE <= 8
 426         sf = ReadByte();
 427         lf = ReadByte();
 428 #else
 429         sf = ReadShort();
 430         lf = ReadShort();
 431 #endif
 432         float p;
 433         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 434                 if(sf & p)
 435                 {
 436                         if(lf & p)
 437                                 o.(scores[i]) = ReadInt24_t();
 438                         else
 439                                 o.(scores[i]) = ReadChar();
 440                 }
 441
 442         if(o.sort_prev)
 443                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 444
 445         self.entremove = Ent_RemovePlayerScore;
 446 }
 447
 448 void Ent_ReadTeamScore()
 449 {
 450         float i;
 451         entity o;
 452
 453         self.team = ReadByte();
 454         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 455
 456         float sf, lf;
 457 #if MAX_TEAMSCORE <= 8
 458         sf = ReadByte();
 459         lf = ReadByte();
 460 #else
 461         sf = ReadShort();
 462         lf = ReadShort();
 463 #endif
 464         float p;
 465         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 466                 if(sf & p)
 467                 {
 468                         if(lf & p)
 469                                 o.(teamscores[i]) = ReadInt24_t();
 470                         else
 471                                 o.(teamscores[i]) = ReadChar();
 472                 }
 473
 474         HUD_UpdateTeamPos(o);
 475 }
 476
 477 void Ent_ClientData()
 478 {
 479         float f;
 480         float newspectatee_status;
 481
 482         f = ReadByte();
 483
 484         scoreboard_showscores_force = (f & 1);
 485
 486         if(f & 2)
 487         {
 488                 newspectatee_status = ReadByte();
 489                 if(newspectatee_status == player_localnum + 1)
 490                         newspectatee_status = -1; // observing
 491         }
 492         else
 493                 newspectatee_status = 0;
 494
 495         spectatorbutton_zoom = (f & 4);
 496
 497         if(f & 8)
 498         {
 499                 angles_held_status = 1;
 500                 angles_held_x = ReadAngle();
 501                 angles_held_y = ReadAngle();
 502                 angles_held_z = 0;
 503         }
 504         else
 505                 angles_held_status = 0;
 506
 507         if(newspectatee_status != spectatee_status)
 508         {
 509                 // clear race stuff
 510                 race_laptime = 0;
 511                 race_checkpointtime = 0;
 512         }
 513         if (autocvar_hud_panel_healtharmor_progressbar_gfx)
 514         {
 515                 if ( (spectatee_status == -1 && newspectatee_status > 0) //before observing, now spectating
 516                   || (spectatee_status > 0 && newspectatee_status > 0 && spectatee_status != newspectatee_status) //changed spectated player
 517                 )
 518                         prev_p_health = -1;
 519                 else if(spectatee_status && !newspectatee_status) //before observing/spectating, now playing
 520                         prev_health = -1;
 521         }
 522         spectatee_status = newspectatee_status;
 523
 524         // we could get rid of spectatee_status, and derive it from player_localentnum and player_localnum
 525 }
 526
 527 void Ent_Nagger()
 528 {
 529         float nags, i, j, b, f;
 530
 531         nags = ReadByte(); // NAGS NAGS NAGS NAGS NAGS NAGS NADZ NAGS NAGS NAGS
 532
 533         if(!(nags & 4))
 534         {
 535                 if(vote_called_vote)
 536                         strunzone(vote_called_vote);
 537                 vote_called_vote = string_null;
 538                 vote_active = 0;
 539         }
 540         else
 541         {
 542                 vote_active = 1;
 543         }
 544
 545         if(nags & 64)
 546         {
 547                 vote_yescount = ReadByte();
 548                 vote_nocount = ReadByte();
 549                 vote_needed = ReadByte();
 550                 vote_highlighted = ReadChar();
 551         }
 552
 553         if(nags & 128)
 554         {
 555                 if(vote_called_vote)
 556                         strunzone(vote_called_vote);
 557                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 558         }
 559
 560         if(nags & 1)
 561         {
 562                 for(j = 0; j < maxclients; ++j)
 563                         if(playerslots[j])
 564                                 playerslots[j].ready = 1;
 565                 for(i = 1; i <= maxclients; i += 8)
 566                 {
 567                         f = ReadByte();
 568                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 569                                 if (!(f & b))
 570                                         if(playerslots[j])
 571                                                 playerslots[j].ready = 0;
 572                 }
 573         }
 574
 575         ready_waiting = (nags & 1);
 576         ready_waiting_for_me = (nags & 2);
 577         vote_waiting = (nags & 4);
 578         vote_waiting_for_me = (nags & 8);
 579         warmup_stage = (nags & 16);
 580 }
 581
 582 void Ent_EliminatedPlayers()
 583 {
 584         float sf, i, j, b, f;
 585
 586         sf = ReadByte();
 587         if(sf & 1)
 588         {
 589                 for(j = 0; j < maxclients; ++j)
 590                         if(playerslots[j])
 591                                 playerslots[j].eliminated = 1;
 592                 for(i = 1; i <= maxclients; i += 8)
 593                 {
 594                         f = ReadByte();
 595                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 596                                 if (!(f & b))
 597                                         if(playerslots[j])
 598                                                 playerslots[j].eliminated = 0;
 599                 }
 600         }
 601 }
 602
 603 void Ent_RandomSeed()
 604 {
 605         float s;
 606         prandom_debug();
 607         s = ReadShort();
 608         psrandom(s);
 609 }
 610
 611 void Ent_ReadAccuracy(void)
 612 {
 613         float sf, f, w, b;
 614         sf = ReadInt24_t();
 615         if(sf == 0)
 616         {
 617                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 618                         weapon_accuracy[w] = -1;
 619                 return;
 620         }
 621
 622         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w)
 623         {
 624                 if(sf & f)
 625                 {
 626                         b = ReadByte();
 627                         if(b == 0)
 628                                 weapon_accuracy[w] = -1;
 629                         else if(b == 255)
 630                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 631                         else
 632                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 633                 }
 634                 if(f == 0x800000)
 635                         f = 1;
 636                 else
 637                         f *= 2;
 638         }
 639 }
 640
 641 void Spawn_Draw(void)
 642 {
 643         pointparticles(self.cnt, self.origin + '0 0 28', '0 0 2', bound(0, frametime, 0.1));
 644 }
 645
 646 void Ent_ReadSpawnPoint(float is_new) // entity for spawnpoint
 647 {
 648         float teamnum = (ReadByte() - 1);
 649         vector spn_origin;
 650         spn_origin_x = ReadShort();
 651         spn_origin_y = ReadShort();
 652         spn_origin_z = ReadShort();
 653
 654         if(is_new)
 655         {
 656                 self.origin = spn_origin;
 657                 setsize(self, PL_MIN, PL_MAX);
 658                 droptofloor();
 659
 660                 /*if(autocvar_cl_spawn_point_model) // needs a model first
 661                 {
 662                         self.mdl = "models/spawnpoint.md3";
 663                         self.colormod = Team_ColorRGB(teamnum);
 664                         precache_model(self.mdl);
 665                         setmodel(self, self.mdl);
 666                         self.drawmask = MASK_NORMAL;
 667                         //self.movetype = MOVETYPE_NOCLIP;
 668                         //self.draw = Spawn_Draw;
 669                 }*/
 670                 if(autocvar_cl_spawn_point_particles)
 671                 {
 672                         if((serverflags & SERVERFLAG_TEAMPLAY))
 673                         {
 674                                 switch(teamnum)
 675                                 {
 676                                         case NUM_TEAM_1: self.cnt = particleeffectnum("spawn_point_red"); break;
 677                                         case NUM_TEAM_2: self.cnt = particleeffectnum("spawn_point_blue"); break;
 678                                         case NUM_TEAM_3: self.cnt = particleeffectnum("spawn_point_yellow"); break;
 679                                         case NUM_TEAM_4: self.cnt = particleeffectnum("spawn_point_pink"); break;
 680                                         default: self.cnt = particleeffectnum("spawn_point_neutral"); break;
 681                                 }
 682                         }
 683                         else { self.cnt = particleeffectnum("spawn_point_neutral"); }
 684
 685                         self.draw = Spawn_Draw;
 686                 }
 687         }
 688
 689         //printf("Ent_ReadSpawnPoint(is_new = %d); origin = %s, team = %d, effect = %d\n", is_new, vtos(self.origin), teamnum, self.cnt);
 690 }
 691
 692 void Ent_ReadSpawnEvent(float is_new)
 693 {
 694         // If entnum is 0, ONLY do the local spawn actions
 695         // this way the server can disable the sending of
 696         // spawn origin or such to clients if wanted.
 697         float entnum = ReadByte();
 698
 699         if(entnum)
 700         {
 701                 self.origin_x = ReadShort();
 702                 self.origin_y = ReadShort();
 703                 self.origin_z = ReadShort();
 704
 705                 if(is_new)
 706                 {
 707                         float teamnum = GetPlayerColor(entnum - 1);
 708
 709                         if(autocvar_cl_spawn_event_particles)
 710                         {
 711                                 switch(teamnum)
 712                                 {
 713                                         case NUM_TEAM_1: pointparticles(particleeffectnum("spawn_event_red"), self.origin, '0 0 0', 1); break;
 714                                         case NUM_TEAM_2: pointparticles(particleeffectnum("spawn_event_blue"), self.origin, '0 0 0', 1); break;
 715                                         case NUM_TEAM_3: pointparticles(particleeffectnum("spawn_event_yellow"), self.origin, '0 0 0', 1); break;
 716                                         case NUM_TEAM_4: pointparticles(particleeffectnum("spawn_event_pink"), self.origin, '0 0 0', 1); break;
 717                                         default: pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); break;
 718                                 }
 719                         }
 720                         if(autocvar_cl_spawn_event_sound)
 721                         {
 722                                 sound(self, CH_TRIGGER, "misc/spawn.wav", VOL_BASE, ATTEN_NORM);
 723                         }
 724                 }
 725         }
 726
 727         // local spawn actions
 728         if(is_new && (!entnum || (entnum == player_localentnum)))
 729         {
 730                 zoomin_effect = 1;
 731                 current_viewzoom = (1 / bound(1, autocvar_cl_spawnzoom_factor, 16));
 732
 733                 if(autocvar_cl_unpress_zoom_on_spawn)
 734                 {
 735                         localcmd("-zoom\n");
 736                         button_zoom = FALSE;
 737                 }
 738         }
 739
 740         //printf("Ent_ReadSpawnEvent(is_new = %d); origin = %s, entnum = %d, localentnum = %d\n", is_new, vtos(self.origin), entnum, player_localentnum);
 741 }
 742
 743 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 744 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 745 void Ent_RadarLink();
 746 void Ent_Init();
 747 void Ent_ScoresInfo();
 748 void CSQC_Ent_Update(float bIsNewEntity)
 749 {
 750         float t;
 751         float savetime;
 752         t = ReadByte();
 753
 754         if(autocvar_developer_csqcentities)
 755                 printf("CSQC_Ent_Update(%d) with self=%i self.entnum=%d self.enttype=%d t=%d\n", bIsNewEntity, self, self.entnum, self.enttype, t);
 756
 757         // set up the "time" global for received entities to be correct for interpolation purposes
 758         savetime = time;
 759         if(servertime)
 760         {
 761                 time = servertime;
 762         }
 763         else
 764         {
 765                 serverprevtime = time;
 766                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 767                 time = serverprevtime + serverdeltatime;
 768         }
 769
 770 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 771         if(self.enttype)
 772         {
 773                 if(t != self.enttype || bIsNewEntity)
 774                 {
 775                         //print("A CSQC entity changed its type!\n");
 776                         printf("A CSQC entity changed its type! (edict: %d, server: %d, type: %d -> %d)\n", num_for_edict(self), self.entnum, self.enttype, t);
 777                         Ent_Remove();
 778                         clearentity(self);
 779                         bIsNewEntity = 1;
 780                 }
 781         }
 782         else
 783         {
 784                 if(!bIsNewEntity)
 785                 {
 786                         printf("A CSQC entity appeared out of nowhere! (edict: %d, server: %d, type: %d)\n", num_for_edict(self), self.entnum, t);
 787                         bIsNewEntity = 1;
 788                 }
 789         }
 790 #endif
 791         self.enttype = t;
 792         switch(t)
 793         {
 794                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 795                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 796                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 797                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 798                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 799                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 800                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 801                 case ENT_CLIENT_ELIMINATEDPLAYERS: Ent_EliminatedPlayers(); break;
 802                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 803                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 804                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 805                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 806                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 807                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 808                 case ENT_CLIENT_INIT: Ent_Init(); break;
 809                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 810                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 811                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 812                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 813                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 814                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 815                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 816                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 817                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 818                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 819                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 820                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 821                 case ENT_CLIENT_ARC_BEAM: Ent_ReadArcBeam(bIsNewEntity); break;
 822                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 823                 case ENT_CLIENT_AUXILIARYXHAIR: Net_AuXair2(bIsNewEntity); break;
 824                 case ENT_CLIENT_TURRET: ent_turret(); break;
 825                 case ENT_CLIENT_MODEL: CSQCModel_Read(bIsNewEntity); break;
 826                 case ENT_CLIENT_ITEM: ItemRead(bIsNewEntity); break;
 827                 case ENT_CLIENT_BUMBLE_RAYGUN: bumble_raygun_read(bIsNewEntity); break;
 828                 case ENT_CLIENT_SPAWNPOINT: Ent_ReadSpawnPoint(bIsNewEntity); break;
 829                 case ENT_CLIENT_SPAWNEVENT: Ent_ReadSpawnEvent(bIsNewEntity); break;
 830                 case ENT_CLIENT_NOTIFICATION: Read_Notification(bIsNewEntity); break;
 831                 case ENT_CLIENT_HEALING_ORB: ent_healer(); break;
 832
 833                 default:
 834                         //error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 835                         error(sprintf("Unknown entity type in CSQC_Ent_Update (enttype: %d, edict: %d, classname: %s)\n", self.enttype, num_for_edict(self), self.classname));
 836                         break;
 837         }
 838
 839         time = savetime;
 840 }
 841 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 842 // used when an entity changes its type. For an entity that someone interacts
 843 // with others, make sure it can no longer do so.
 844 void Ent_Remove()
 845 {
 846         if(self.entremove)
 847                 self.entremove();
 848
 849         if(self.skeletonindex)
 850         {
 851                 skel_delete(self.skeletonindex);
 852                 self.skeletonindex = 0;
 853         }
 854
 855         if(self.snd_looping > 0)
 856         {
 857                 sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
 858                 self.snd_looping = 0;
 859         }
 860
 861         self.enttype = 0;
 862         self.classname = "";
 863         self.draw = menu_sub_null;
 864         self.entremove = menu_sub_null;
 865         // TODO possibly set more stuff to defaults
 866 }
 867 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 868 void CSQC_Ent_Remove()
 869 {
 870         if(autocvar_developer_csqcentities)
 871                 printf("CSQC_Ent_Remove() with self=%i self.entnum=%d self.enttype=%d\n", self, self.entnum, self.enttype);
 872
 873         if(wasfreed(self))
 874         {
 875                 print("WARNING: CSQC_Ent_Remove called for already removed entity. Packet loss?\n");
 876                 return;
 877         }
 878         if(self.enttype)
 879                 Ent_Remove();
 880         remove(self);
 881 }
 882
 883 void Gamemode_Init()
 884 {
 885         if (!isdemo())
 886         {
 887                 if(!(calledhooks & HOOK_START))
 888                         localcmd("\n_cl_hook_gamestart ", MapInfo_Type_ToString(gametype), "\n");
 889                 calledhooks |= HOOK_START;
 890         }
 891 }
 892 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
 893 void CSQC_Parse_StuffCmd(string strMessage)
 894 {
 895         if(autocvar_developer_csqcentities)
 896                 printf("CSQC_Parse_StuffCmd(\"%s\")\n", strMessage);
 897
 898         localcmd(strMessage);
 899 }
 900 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
 901 void CSQC_Parse_Print(string strMessage)
 902 {
 903         if(autocvar_developer_csqcentities)
 904                 printf("CSQC_Parse_Print(\"%s\")\n", strMessage);
 905
 906         print(ColorTranslateRGB(strMessage));
 907 }
 908
 909 // CSQC_Parse_CenterPrint : Provides the centerprint_hud string in the first parameter that the server provided.
 910 void CSQC_Parse_CenterPrint(string strMessage)
 911 {
 912         if(autocvar_developer_csqcentities)
 913                 printf("CSQC_Parse_CenterPrint(\"%s\")\n", strMessage);
 914
 915         centerprint_hud(strMessage);
 916 }
 917
 918 string notranslate_fogcmd1 = "\nfog ";
 919 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
 920 void Fog_Force()
 921 {
 922         // TODO somehow thwart prvm_globalset client ...
 923
 924         if(autocvar_cl_orthoview && autocvar_cl_orthoview_nofog)
 925                 { localcmd("\nr_drawfog 0\n"); }
 926         else if(forcefog != "")
 927                 { localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2)); }
 928 }
 929
 930 void Gamemode_Init();
 931 void Ent_ScoresInfo()
 932 {
 933         float i;
 934         self.classname = "ent_client_scores_info";
 935         gametype = ReadInt24_t();
 936         HUD_ModIcons_SetFunc();
 937         for(i = 0; i < MAX_SCORE; ++i)
 938         {
 939                 if(scores_label[i])
 940                         strunzone(scores_label[i]);
 941                 scores_label[i] = strzone(ReadString());
 942                 scores_flags[i] = ReadByte();
 943         }
 944         for(i = 0; i < MAX_TEAMSCORE; ++i)
 945         {
 946                 if(teamscores_label[i])
 947                         strunzone(teamscores_label[i]);
 948                 teamscores_label[i] = strzone(ReadString());
 949                 teamscores_flags[i] = ReadByte();
 950         }
 951         HUD_InitScores();
 952         Gamemode_Init();
 953 }
 954
 955 void Ent_Init()
 956 {
 957         self.classname = "ent_client_init";
 958
 959         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
 960
 961         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 962         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 963         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 964         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 965         arc_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
 966         arc_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
 967         arc_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
 968         arc_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
 969
 970         if(forcefog)
 971                 strunzone(forcefog);
 972         forcefog = strzone(ReadString());
 973
 974         armorblockpercent = ReadByte() / 255.0;
 975
 976         g_balance_mortar_bouncefactor = ReadCoord();
 977         g_balance_mortar_bouncestop = ReadCoord();
 978         g_balance_electro_secondary_bouncefactor = ReadCoord();
 979         g_balance_electro_secondary_bouncestop = ReadCoord();
 980
 981         vortex_scope = !ReadByte();
 982         rifle_scope = !ReadByte();
 983
 984         serverflags = ReadByte();
 985
 986         minelayer_maxmines = ReadByte();
 987
 988         hagar_maxrockets = ReadByte();
 989
 990         g_trueaim_minrange = ReadCoord();
 991         g_balance_porto_secondary = ReadByte();
 992
 993         if(!postinit)
 994                 PostInit();
 995 }
 996
 997 void Net_ReadRace()
 998 {
 999         float b;
1000
1001         b = ReadByte();
1002
1003         switch(b)
1004         {
1005                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1006                         race_checkpoint = ReadByte();
1007                         race_time = ReadInt24_t();
1008                         race_previousbesttime = ReadInt24_t();
1009                         if(race_previousbestname)
1010                                 strunzone(race_previousbestname);
1011                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1012
1013                         race_checkpointtime = time;
1014
1015                         if(race_checkpoint == 0 || race_checkpoint == 254)
1016                         {
1017                                 race_penaltyaccumulator = 0;
1018                                 race_laptime = time; // valid
1019                         }
1020
1021                         break;
1022
1023                 case RACE_NET_CHECKPOINT_CLEAR:
1024                         race_laptime = 0;
1025                         race_checkpointtime = 0;
1026                         break;
1027
1028                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1029                         race_laptime = ReadCoord();
1030                         race_checkpointtime = -99999;
1031                         // fall through
1032                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1033                         race_nextcheckpoint = ReadByte();
1034
1035                         race_nextbesttime = ReadInt24_t();
1036                         if(race_nextbestname)
1037                                 strunzone(race_nextbestname);
1038                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1039                         break;
1040
1041                 case RACE_NET_CHECKPOINT_HIT_RACE:
1042                         race_mycheckpoint = ReadByte();
1043                         race_mycheckpointtime = time;
1044                         race_mycheckpointdelta = ReadInt24_t();
1045                         race_mycheckpointlapsdelta = ReadByte();
1046                         if(race_mycheckpointlapsdelta >= 128)
1047                                 race_mycheckpointlapsdelta -= 256;
1048                         if(race_mycheckpointenemy)
1049                                 strunzone(race_mycheckpointenemy);
1050                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1051                         break;
1052
1053                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1054                         race_othercheckpoint = ReadByte();
1055                         race_othercheckpointtime = time;
1056                         race_othercheckpointdelta = ReadInt24_t();
1057                         race_othercheckpointlapsdelta = ReadByte();
1058                         if(race_othercheckpointlapsdelta >= 128)
1059                                 race_othercheckpointlapsdelta -= 256;
1060                         if(race_othercheckpointenemy)
1061                                 strunzone(race_othercheckpointenemy);
1062                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1063                         break;
1064
1065                 case RACE_NET_PENALTY_RACE:
1066                         race_penaltyeventtime = time;
1067                         race_penaltytime = ReadShort();
1068                         //race_penaltyaccumulator += race_penaltytime;
1069                         if(race_penaltyreason)
1070                                 strunzone(race_penaltyreason);
1071                         race_penaltyreason = strzone(ReadString());
1072                         break;
1073
1074                 case RACE_NET_PENALTY_QUALIFYING:
1075                         race_penaltyeventtime = time;
1076                         race_penaltytime = ReadShort();
1077                         race_penaltyaccumulator += race_penaltytime;
1078                         if(race_penaltyreason)
1079                                 strunzone(race_penaltyreason);
1080                         race_penaltyreason = strzone(ReadString());
1081                         break;
1082
1083                 case RACE_NET_SERVER_RECORD:
1084                         race_server_record = ReadInt24_t();
1085                         break;
1086                 case RACE_NET_SPEED_AWARD:
1087                         race_speedaward = ReadInt24_t();
1088                         if(race_speedaward_holder)
1089                                 strunzone(race_speedaward_holder);
1090                         race_speedaward_holder = strzone(ReadString());
1091                         break;
1092                 case RACE_NET_SPEED_AWARD_BEST:
1093                         race_speedaward_alltimebest = ReadInt24_t();
1094                         if(race_speedaward_alltimebest_holder)
1095                                 strunzone(race_speedaward_alltimebest_holder);
1096                         race_speedaward_alltimebest_holder = strzone(ReadString());
1097                         break;
1098                 case RACE_NET_SERVER_RANKINGS:
1099                         float pos, prevpos, del;
1100                         pos = ReadShort();
1101                         prevpos = ReadShort();
1102                         del = ReadShort();
1103
1104                         // move other rankings out of the way
1105                         float i;
1106                         if (prevpos) {
1107                                 for (i=prevpos-1;i>pos-1;--i) {
1108                                         grecordtime[i] = grecordtime[i-1];
1109                                         if(grecordholder[i])
1110                                                 strunzone(grecordholder[i]);
1111                                         grecordholder[i] = strzone(grecordholder[i-1]);
1112                                 }
1113                         } else if (del) { // a record has been deleted by the admin
1114                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1115                                         if (i == RANKINGS_CNT-1) { // clear out last record
1116                                                 grecordtime[i] = 0;
1117                                                 if (grecordholder[i])
1118                                                         strunzone(grecordholder[i]);
1119                                                 grecordholder[i] = string_null;
1120                                         }
1121                                         else {
1122                                                 grecordtime[i] = grecordtime[i+1];
1123                                                 if (grecordholder[i])
1124                                                         strunzone(grecordholder[i]);
1125                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1126                                         }
1127                                 }
1128                         } else { // player has no ranked record yet
1129                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1130                                         grecordtime[i] = grecordtime[i-1];
1131                                         if(grecordholder[i])
1132                                                 strunzone(grecordholder[i]);
1133                                         grecordholder[i] = strzone(grecordholder[i-1]);
1134                                 }
1135                         }
1136
1137                         // store new ranking
1138                         if(grecordholder[pos-1] != "")
1139                                 strunzone(grecordholder[pos-1]);
1140                         grecordholder[pos-1] = strzone(ReadString());
1141                         grecordtime[pos-1] = ReadInt24_t();
1142                         if(grecordholder[pos-1] == GetPlayerName(player_localnum))
1143                                 race_myrank = pos;
1144                         break;
1145                 case RACE_NET_SERVER_STATUS:
1146                         race_status = ReadShort();
1147                         if(race_status_name)
1148                                 strunzone(race_status_name);
1149                         race_status_name = strzone(ReadString());
1150         }
1151 }
1152
1153 void Net_TeamNagger()
1154 {
1155         teamnagger = 1;
1156 }
1157
1158 void Net_ReadPingPLReport()
1159 {
1160         float e, pi, pl, ml;
1161         e = ReadByte();
1162         pi = ReadShort();
1163         pl = ReadByte();
1164         ml = ReadByte();
1165         if (!(playerslots[e]))
1166                 return;
1167         playerslots[e].ping = pi;
1168         playerslots[e].ping_packetloss = pl / 255.0;
1169         playerslots[e].ping_movementloss = ml / 255.0;
1170 }
1171
1172 void Net_WeaponComplain()
1173 {
1174         complain_weapon = ReadByte();
1175
1176         if(complain_weapon_name)
1177                 strunzone(complain_weapon_name);
1178         complain_weapon_name = strzone(WEP_NAME(complain_weapon));
1179
1180         complain_weapon_type = ReadByte();
1181
1182         complain_weapon_time = time;
1183         weapontime = time; // ping the weapon panel
1184
1185         switch(complain_weapon_type)
1186         {
1187                 case 0: Local_Notification(MSG_MULTI, ITEM_WEAPON_NOAMMO, complain_weapon); break;
1188                 case 1: Local_Notification(MSG_MULTI, ITEM_WEAPON_DONTHAVE, complain_weapon); break;
1189                 default: Local_Notification(MSG_MULTI, ITEM_WEAPON_UNAVAILABLE, complain_weapon); break;
1190         }
1191 }
1192
1193 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1194 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1195 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1196 float CSQC_Parse_TempEntity()
1197 {
1198         float bHandled;
1199                 bHandled  = true;
1200         // Acquire TE ID
1201         float nTEID;
1202                 nTEID = ReadByte();
1203
1204         if(autocvar_developer_csqcentities)
1205                 printf("CSQC_Parse_TempEntity() with nTEID=%d\n", nTEID);
1206
1207                 // NOTE: Could just do return instead of break...
1208         switch(nTEID)
1209         {
1210                 case TE_CSQC_TARGET_MUSIC:
1211                         Net_TargetMusic();
1212                         bHandled = true;
1213                         break;
1214                 case TE_CSQC_PICTURE:
1215                         Net_MapVote_Picture();
1216                         bHandled = true;
1217                         break;
1218                 case TE_CSQC_RACE:
1219                         Net_ReadRace();
1220                         bHandled = true;
1221                         break;
1222                 case TE_CSQC_VORTEXBEAMPARTICLE:
1223                         Net_ReadVortexBeamParticle();
1224                         bHandled = true;
1225                         break;
1226                 case TE_CSQC_TEAMNAGGER:
1227                         Net_TeamNagger();
1228                         bHandled = true;
1229                         break;
1230                 case TE_CSQC_ARC:
1231                         Net_ReadArc();
1232                         bHandled = true;
1233                         break;
1234                 case TE_CSQC_PINGPLREPORT:
1235                         Net_ReadPingPLReport();
1236                         bHandled = true;
1237                         break;
1238                 case TE_CSQC_WEAPONCOMPLAIN:
1239                         Net_WeaponComplain();
1240                         bHandled = true;
1241                         break;
1242                 case TE_CSQC_VEHICLESETUP:
1243                         Net_VehicleSetup();
1244                         bHandled = true;
1245                         break;
1246                 case TE_CSQC_SVNOTICE:
1247                         cl_notice_read();
1248                         bHandled = true;
1249                         break;
1250                 case TE_CSQC_SHOCKWAVEPARTICLE:
1251                         Net_ReadShockwaveParticle();
1252                         bHandled = true;
1253                         break;
1254                 default:
1255                         // No special logic for this temporary entity; return 0 so the engine can handle it
1256                         bHandled = false;
1257                         break;
1258         }
1259
1260         return bHandled;
1261 }
1262
1263 string getcommandkey(string text, string command)
1264 {
1265         string keys;
1266         float n, j, k, l = 0;
1267
1268         if (!autocvar_hud_showbinds)
1269                 return text;
1270
1271         keys = db_get(binddb, command);
1272         if (keys == "")
1273         {
1274                 n = tokenize(findkeysforcommand(command, 0)); // uses '...' strings
1275                 for(j = 0; j < n; ++j)
1276                 {
1277                         k = stof(argv(j));
1278                         if(k != -1)
1279                         {
1280                                 if ("" == keys)
1281                                         keys = keynumtostring(k);
1282                                 else
1283                                         keys = strcat(keys, ", ", keynumtostring(k));
1284
1285                                 ++l;
1286                                 if (autocvar_hud_showbinds_limit > 0 && autocvar_hud_showbinds_limit <= l)
1287                                         break;
1288                         }
1289
1290                 }
1291                 if (keys == "")
1292                         keys = "NO_KEY";
1293                 db_put(binddb, command, keys);
1294         }
1295
1296         if (keys == "NO_KEY") {
1297                 if (autocvar_hud_showbinds > 1)
1298                         return sprintf(_("%s (not bound)"), text);
1299                 else
1300                         return text;
1301         }
1302         else if (autocvar_hud_showbinds > 1)
1303                 return sprintf("%s (%s)", text, keys);
1304         else
1305                 return keys;
1306 }