qcsrc/client/Main.qc

   1 // --------------------------------------------------------------------------
   2 // BEGIN REQUIRED CSQC FUNCTIONS
   3 //include "main.qh"
   4
   5 #define DP_CSQC_ENTITY_REMOVE_IS_B0RKED
   6
   7 void cvar_clientsettemp(string cv, string val)
   8 {
   9         entity e;
  10         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  11                 if(e.netname == cv)
  12                         goto saved;
  13         e = spawn();
  14         e.classname = "saved_cvar_value";
  15         e.netname = strzone(cv);
  16         e.message = strzone(cvar_string(cv));
  17 :saved
  18         cvar_set(cv, val);
  19 }
  20
  21 void cvar_clientsettemp_restore()
  22 {
  23         entity e;
  24         for(e = world; (e = find(e, classname, "saved_cvar_value")); )
  25                         cvar_set(e.netname, e.message);
  26 }
  27
  28 void() menu_show_error =
  29 {
  30         drawstring('0 200 0', _("ERROR - MENU IS VISIBLE BUT NO MENU WAS DEFINED!"), '8 8 0', '1 0 0', 1, 0);
  31 };
  32
  33 // CSQC_Init : Called every time the CSQC code is initialized (essentially at map load)
  34 // Useful for precaching things
  35
  36 void() menu_sub_null =
  37 {
  38 };
  39
  40 #ifdef USE_FTE
  41 float __engine_check;
  42 #endif
  43
  44 string forcefog;
  45 string cl_announcer_prev;
  46 void WaypointSprite_Load();
  47 void CSQC_Init(void)
  48 {
  49         prvm_language = cvar_string("prvm_language");
  50
  51 #ifdef USE_FTE
  52 #pragma target ID
  53         __engine_check = checkextension("DP_SV_WRITEPICTURE");
  54         if(!__engine_check)
  55         {
  56                 print(_("^3Your engine build is outdated\n^3This Server uses a newer QC VM. Please update!\n"));
  57                 localcmd("\ndisconnect\n");
  58                 return;
  59         }
  60 #pragma target FTE
  61 #endif
  62
  63         check_unacceptable_compiler_bugs();
  64
  65 #ifdef WATERMARK
  66         print(sprintf(_("^4CSQC Build information: ^1%s\n"), WATERMARK()));
  67 #endif
  68
  69         float i;
  70
  71         binddb = db_create();
  72         tempdb = db_create();
  73         ClientProgsDB = db_load("client.db");
  74         compressShortVector_init();
  75
  76         drawfont = FONT_USER+1;
  77         menu_visible = FALSE;
  78         menu_show = menu_show_error;
  79         menu_action = menu_sub_null;
  80
  81         for(i = 0; i < 255; ++i)
  82                 if(getplayerkey(i, "viewentity") == "")
  83                         break;
  84         maxclients = i;
  85
  86         //ctf_temp_1 = "";
  87         // localcmd("alias order \"cmd order $*\""); enable if ctf-command thingy is used
  88         //registercmd("ctf_menu");
  89         registercmd("ons_map");
  90         registercmd("hud_configure");
  91         registercmd("hud_save");
  92         //registercmd("menu_action");
  93
  94         registercmd("+button3");
  95         registercmd("-button3");
  96         registercmd("+button4");
  97         registercmd("-button4");
  98         registercmd("+showscores");registercmd("-showscores");
  99         registercmd("+showaccuracy");registercmd("-showaccuracy");
 100
 101 #ifndef CAMERATEST
 102         if(isdemo())
 103         {
 104 #endif
 105                 registercmd("+forward");registercmd("-forward");
 106                 registercmd("+back");registercmd("-back");
 107                 registercmd("+moveup");registercmd("-moveup");
 108                 registercmd("+movedown");registercmd("-movedown");
 109                 registercmd("+moveright");registercmd("-moveright");
 110                 registercmd("+moveleft");registercmd("-moveleft");
 111                 registercmd("+roll_right");registercmd("-roll_right");
 112                 registercmd("+roll_left");registercmd("-roll_left");
 113 #ifndef CAMERATEST
 114         }
 115 #endif
 116         registercvar("hud_usecsqc", "1");
 117         registercvar("scoreboard_columns", "default", CVAR_SAVE);
 118
 119         gametype = 0;
 120
 121         // hud_fields uses strunzone on the titles!
 122         for(i = 0; i < MAX_HUD_FIELDS; ++i)
 123                 hud_title[i] = strzone("(null)");
 124
 125         postinit = false;
 126
 127         calledhooks = 0;
 128
 129         teams = Sort_Spawn();
 130         players = Sort_Spawn();
 131
 132         GetTeam(COLOR_SPECTATOR, true); // add specs first
 133
 134         RegisterWeapons();
 135
 136         WaypointSprite_Load();
 137
 138         // precaches
 139         precache_sound("misc/hit.wav");
 140         precache_sound("misc/typehit.wav");
 141         Projectile_Precache();
 142         Hook_Precache();
 143         GibSplash_Precache();
 144         Casings_Precache();
 145         DamageInfo_Precache();
 146         if(autocvar_cl_announcer != cl_announcer_prev) {
 147                 Announcer_Precache();
 148                 if(cl_announcer_prev)
 149                         strunzone(cl_announcer_prev);
 150                 cl_announcer_prev = strzone(autocvar_cl_announcer);
 151         }
 152         Tuba_Precache();
 153
 154         if(autocvar_cl_reticle_item_normal) precache_pic("gfx/reticle_normal");
 155         if(autocvar_cl_reticle_item_nex) precache_pic("gfx/reticle_nex");
 156
 157         get_mi_min_max_texcoords(1); // try the CLEVER way first
 158         minimapname = strcat("gfx/", mi_shortname, "_radar.tga");
 159         shortmapname = mi_shortname;
 160
 161         if(precache_pic(minimapname) == "")
 162         {
 163                 // but maybe we have a non-clever minimap
 164                 minimapname = strcat("gfx/", mi_shortname, "_mini.tga");
 165                 if(precache_pic(minimapname) == "")
 166                         minimapname = ""; // FAIL
 167                 else
 168                         get_mi_min_max_texcoords(0); // load new texcoords
 169         }
 170
 171         mi_center = (mi_min + mi_max) * 0.5;
 172         mi_scale = mi_max - mi_min;
 173         minimapname = strzone(minimapname);
 174
 175         WarpZone_Init();
 176         hud_configure_prev = -1;
 177 }
 178
 179 // CSQC_Shutdown : Called every time the CSQC code is shutdown (changing maps, quitting, etc)
 180 void CSQC_Shutdown(void)
 181 {
 182 #ifdef USE_FTE
 183 #pragma TARGET id
 184         if(!__engine_check)
 185                 return 0;
 186 #pragma TARGET fte
 187 #endif
 188
 189         WarpZone_Shutdown();
 190
 191         remove(teams);
 192         remove(players);
 193         db_close(binddb);
 194         db_close(tempdb);
 195         if(autocvar_cl_db_saveasdump)
 196                 db_dump(ClientProgsDB, "client.db");
 197         else
 198                 db_save(ClientProgsDB, "client.db");
 199         db_close(ClientProgsDB);
 200
 201         cvar_clientsettemp_restore();
 202
 203         if(camera_active)
 204                 cvar_set("chase_active",ftos(chase_active_backup));
 205
 206         if not(isdemo())
 207         {
 208                 if not(calledhooks & HOOK_START)
 209                         localcmd("\n_cl_hook_gamestart nop\n");
 210                 if not(calledhooks & HOOK_END)
 211                         localcmd("\ncl_hook_gameend\n");
 212         }
 213 }
 214
 215 .float has_team;
 216 float SetTeam(entity o, float Team)
 217 {
 218         entity tm;
 219         if(teamplay)
 220         {
 221                 switch(Team)
 222                 {
 223                         case -1:
 224                         case COLOR_TEAM1:
 225                         case COLOR_TEAM2:
 226                         case COLOR_TEAM3:
 227                         case COLOR_TEAM4:
 228                                 break;
 229                         default:
 230                                 if(GetTeam(Team, false) == NULL)
 231                                 {
 232                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 233                                         Team = COLOR_SPECTATOR;
 234                                 }
 235                                 break;
 236                 }
 237         }
 238         else
 239         {
 240                 switch(Team)
 241                 {
 242                         case -1:
 243                         case 0:
 244                                 break;
 245                         default:
 246                                 if(GetTeam(Team, false) == NULL)
 247                                 {
 248                                         print(sprintf(_("trying to switch to unsupported team %d\n"), Team));
 249                                         Team = COLOR_SPECTATOR;
 250                                 }
 251                                 break;
 252                 }
 253         }
 254         if(Team == -1) // leave
 255         {
 256                 if(o.has_team)
 257                 {
 258                         tm = GetTeam(o.team, false);
 259                         tm.team_size -= 1;
 260                         o.has_team = 0;
 261                         return TRUE;
 262                 }
 263         }
 264         else
 265         {
 266                 if not(o.has_team)
 267                 {
 268                         o.team = Team;
 269                         tm = GetTeam(Team, true);
 270                         tm.team_size += 1;
 271                         o.has_team = 1;
 272                         return TRUE;
 273                 }
 274                 else if(Team != o.team)
 275                 {
 276                         tm = GetTeam(o.team, false);
 277                         tm.team_size -= 1;
 278                         o.team = Team;
 279                         tm = GetTeam(Team, true);
 280                         tm.team_size += 1;
 281                         return TRUE;
 282                 }
 283         }
 284         return FALSE;
 285 }
 286
 287 void Playerchecker_Think()
 288 {
 289         float i;
 290         entity e;
 291         for(i = 0; i < maxclients; ++i)
 292         {
 293                 e = playerslots[i];
 294                 if(GetPlayerName(i) == "")
 295                 {
 296                         if(e.sort_prev)
 297                         {
 298                                 // player disconnected
 299                                 SetTeam(e, -1);
 300                                 RemovePlayer(e);
 301                                 e.sort_prev = world;
 302                                 //e.gotscores = 0;
 303                         }
 304                 }
 305                 else
 306                 {
 307                         if not(e.sort_prev)
 308                         {
 309                                 // player connected
 310                                 if not(e)
 311                                         playerslots[i] = e = spawn();
 312                                 e.sv_entnum = i;
 313                                 e.ping = 0;
 314                                 e.ping_packetloss = 0;
 315                                 e.ping_movementloss = 0;
 316                                 //e.gotscores = 0; // we might already have the scores...
 317                                 SetTeam(e, GetPlayerColor(i)); // will not hurt; later updates come with HUD_UpdatePlayerTeams
 318                                 RegisterPlayer(e);
 319                                 HUD_UpdatePlayerPos(e);
 320                         }
 321                 }
 322         }
 323         self.nextthink = time + 0.2;
 324 }
 325
 326 void Porto_Init();
 327 void TrueAim_Init();
 328 void PostInit(void)
 329 {
 330         localcmd(strcat("\nscoreboard_columns_set ", autocvar_scoreboard_columns, ";\n"));
 331
 332         entity playerchecker;
 333         playerchecker = spawn();
 334         playerchecker.think = Playerchecker_Think;
 335         playerchecker.nextthink = time + 0.2;
 336
 337         Porto_Init();
 338         TrueAim_Init();
 339
 340         postinit = true;
 341 }
 342
 343 // CSQC_ConsoleCommand : Used to parse commands in the console that have been registered with the "registercmd" function
 344 // Return value should be 1 if CSQC handled the command, otherwise return 0 to have the engine handle it.
 345 float button_zoom;
 346 void Cmd_HUD_SetFields(float);
 347 void Cmd_HUD_Help(float);
 348 float CSQC_ConsoleCommand(string strMessage)
 349 {
 350         float argc;
 351         // Tokenize String
 352         //argc = tokenize(strMessage);
 353         argc = tokenize_console(strMessage);
 354
 355         // Acquire Command
 356         local string strCmd;
 357         strCmd = argv(0);
 358
 359         if(strCmd == "hud_configure") { // config hud
 360                 cvar_set("_hud_configure", ftos(!autocvar__hud_configure));
 361                 return true;
 362         } else if(strCmd == "hud_save") { // save hud config
 363                 if(argv(1) == "" || argv(2)) {
 364                         print(_("Usage:\n"));
 365                         print(_("hud_save configname   (saves to hud_skinname_configname.cfg)\n"));
 366                 }
 367                 else
 368                         HUD_Panel_ExportCfg(argv(1));
 369                 return true;
 370         } else if(strCmd == "+button4") { // zoom
 371                 // return false, because the message shall be sent to the server anyway (for demos/speccing)
 372                 if(ignore_plus_zoom)
 373                 {
 374                         --ignore_plus_zoom;
 375                         return false;
 376                 }
 377                 button_zoom = 1;
 378                 return true;
 379         } else if(strCmd == "-button4") { // zoom
 380                 if(ignore_minus_zoom)
 381                 {
 382                         --ignore_minus_zoom;
 383                         return false;
 384                 }
 385                 button_zoom = 0;
 386                 return true;
 387         } else if(strCmd == "+button3") { // secondary
 388                 button_attack2 = 1;
 389                 return false;
 390         } else if(strCmd == "-button3") { // secondary
 391                 button_attack2 = 0;
 392                 return false;
 393         } else if(strCmd == "+showscores") {
 394                 scoreboard_showscores = true;
 395                 return true;
 396         } else if(strCmd == "-showscores") {
 397                 scoreboard_showscores = false;
 398                 return true;
 399         } else if(strCmd == "+showaccuracy") {
 400                 scoreboard_showaccuracy = true;
 401                 return true;
 402         } else if(strCmd == "-showaccuracy") {
 403                 scoreboard_showaccuracy = false;
 404                 return true;
 405         }
 406
 407         if(camera_active)
 408         if(strCmd == "+forward" || strCmd == "-back") {
 409                 ++camera_direction_x;
 410                 return true;
 411         } else if(strCmd == "-forward" || strCmd == "+back") {
 412                 --camera_direction_x;
 413                 return true;
 414         } else if(strCmd == "+moveright" || strCmd == "-moveleft") {
 415                 --camera_direction_y;
 416                 return true;
 417         } else if(strCmd == "-moveright" || strCmd == "+moveleft") {
 418                 ++camera_direction_y;
 419                 return true;
 420         } else if(strCmd == "+moveup" || strCmd == "-movedown") {
 421                 ++camera_direction_z;
 422                 return true;
 423         } else if(strCmd == "-moveup" || strCmd == "+movedown") {
 424                 --camera_direction_z;
 425                 return true;
 426         } else if(strCmd == "+roll_right" || strCmd == "-roll_left") {
 427                 ++camera_roll;
 428                 return true;
 429         } else if(strCmd == "+roll_left" || strCmd == "-roll_right") {
 430                 --camera_roll;
 431                 return true;
 432         }
 433
 434         return false;
 435 }
 436
 437 .vector view_ofs;
 438 entity debug_shotorg;
 439 void ShotOrg_Draw()
 440 {
 441         self.origin = view_origin + view_forward * self.view_ofs_x + view_right * self.view_ofs_y + view_up * self.view_ofs_z;
 442         self.angles = view_angles;
 443         self.angles_x = -self.angles_x;
 444         if not(self.cnt)
 445                 self.drawmask = MASK_NORMAL;
 446         else
 447                 self.drawmask = 0;
 448 }
 449 void ShotOrg_Draw2D()
 450 {
 451         vector coord2d_topleft, coord2d_topright, coord2d;
 452         string s;
 453         vector fs;
 454
 455         s = vtos(self.view_ofs);
 456         s = substring(s, 1, strlen(s) - 2);
 457         if(tokenize_console(s) == 3)
 458                 s = strcat(argv(0), " ", argv(1), " ", argv(2));
 459
 460         coord2d_topleft = project_3d_to_2d(self.origin + view_up * 4 - view_right * 4);
 461         coord2d_topright = project_3d_to_2d(self.origin + view_up * 4 + view_right * 4);
 462
 463         fs = '1 1 0' * ((coord2d_topright_x - coord2d_topleft_x) / stringwidth(s, FALSE, '8 8 0'));
 464
 465         coord2d = coord2d_topleft;
 466         if(fs_x < 8)
 467         {
 468                 coord2d_x += (coord2d_topright_x - coord2d_topleft_x) * (1 - 8 / fs_x) * 0.5;
 469                 fs = '8 8 0';
 470         }
 471         coord2d_y -= fs_y;
 472         coord2d_z = 0;
 473         drawstring(coord2d, s, fs, '1 1 1', 1, 0);
 474 }
 475
 476 void ShotOrg_Spawn()
 477 {
 478         debug_shotorg = spawn();
 479         debug_shotorg.draw = ShotOrg_Draw;
 480         debug_shotorg.draw2d = ShotOrg_Draw2D;
 481         debug_shotorg.renderflags = RF_VIEWMODEL;
 482         debug_shotorg.effects = EF_FULLBRIGHT;
 483         precache_model("models/shotorg_adjuster.md3");
 484         setmodel(debug_shotorg, "models/shotorg_adjuster.md3");
 485         debug_shotorg.scale = 2;
 486         debug_shotorg.view_ofs = '25 8 -8';
 487 }
 488
 489 void DrawDebugModel()
 490 {
 491         if(time - floor(time) > 0.5)
 492         {
 493                 PolyDrawModel(self);
 494                 self.drawmask = 0;
 495         }
 496         else
 497         {
 498                 self.renderflags = 0;
 499                 self.drawmask = MASK_NORMAL;
 500         }
 501 }
 502
 503 void GameCommand(string msg)
 504 {
 505         string s;
 506         float argc;
 507         entity e;
 508         argc = tokenize_console(msg);
 509
 510         if(argv(0) == "help" || argc == 0)
 511         {
 512                 print(_("Usage: cl_cmd COMMAND..., where possible commands are:\n"));
 513                 print(_("  settemp cvar value\n"));
 514                 print(_("  scoreboard_columns_set ...\n"));
 515                 print(_("  scoreboard_columns_help\n"));
 516                 GameCommand_Generic("help");
 517                 return;
 518         }
 519
 520         if(GameCommand_Generic(msg))
 521                 return;
 522
 523         string cmd;
 524         cmd = argv(0);
 525         if(cmd == "mv_download") {
 526                 Cmd_MapVote_MapDownload(argc);
 527         }
 528         else if(cmd == "settemp") {
 529                 cvar_clientsettemp(argv(1), argv(2));
 530         }
 531         else if(cmd == "scoreboard_columns_set") {
 532                 Cmd_HUD_SetFields(argc);
 533         }
 534         else if(cmd == "scoreboard_columns_help") {
 535                 Cmd_HUD_Help(argc);
 536         }
 537 #ifdef BLURTEST
 538         else if(cmd == "blurtest") {
 539                 blurtest_time0 = time;
 540                 blurtest_time1 = time + stof(argv(1));
 541                 blurtest_radius = stof(argv(2));
 542                 blurtest_power = stof(argv(3));
 543         }
 544 #endif
 545         else if(cmd == "shotorg_move") {
 546                 if(!debug_shotorg)
 547                         ShotOrg_Spawn();
 548                 else
 549                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stov(argv(1));
 550                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 551         }
 552         else if(cmd == "shotorg_movez") {
 553                 if(!debug_shotorg)
 554                         ShotOrg_Spawn();
 555                 else
 556                         debug_shotorg.view_ofs = debug_shotorg.view_ofs + stof(argv(1)) * (debug_shotorg.view_ofs * (1 / debug_shotorg.view_ofs_x)); // closer/farther, same xy pos
 557                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 558         }
 559         else if(cmd == "shotorg_set") {
 560                 if(!debug_shotorg)
 561                         ShotOrg_Spawn();
 562                 else
 563                         debug_shotorg.view_ofs = stov(argv(1));
 564                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 565         }
 566         else if(cmd == "shotorg_setz") {
 567                 if(!debug_shotorg)
 568                         ShotOrg_Spawn();
 569                 else
 570                         debug_shotorg.view_ofs = debug_shotorg.view_ofs * (stof(argv(1)) / debug_shotorg.view_ofs_x); // closer/farther, same xy pos
 571                 localcmd("sv_cmd debug_shotorg \"", vtos(debug_shotorg.view_ofs), "\"\n");
 572         }
 573         else if(cmd == "shotorg_toggle_hide") {
 574                 if(debug_shotorg)
 575                 {
 576                         debug_shotorg.cnt = !debug_shotorg.cnt;
 577                 }
 578         }
 579         else if(cmd == "shotorg_end") {
 580                 if(debug_shotorg)
 581                 {
 582                         print(vtos(debug_shotorg.view_ofs), "\n");
 583                         remove(debug_shotorg);
 584                         debug_shotorg = world;
 585                 }
 586                 localcmd("sv_cmd debug_shotorg\n");
 587         }
 588         else if(cmd == "sendcvar") {
 589                 // W_FixWeaponOrder will trash argv, so save what we need.
 590                 string thiscvar;
 591                 thiscvar = strzone(argv(1));
 592                 s = cvar_string(thiscvar);
 593                 if(thiscvar == "cl_weaponpriority")
 594                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 1);
 595                 else if(substring(thiscvar, 0, 17) == "cl_weaponpriority" && strlen(thiscvar) == 18)
 596                         s = W_FixWeaponOrder(W_NumberWeaponOrder(s), 0);
 597                 localcmd("cmd sentcvar ", thiscvar, " \"", s, "\"\n");
 598                 strunzone(thiscvar);
 599         }
 600         else if(cmd == "spawn") {
 601                 s = argv(1);
 602                 e = spawn();
 603                 precache_model(s);
 604                 setmodel(e, s);
 605                 setorigin(e, view_origin);
 606                 e.angles = view_angles;
 607                 e.draw = DrawDebugModel;
 608                 e.classname = "debugmodel";
 609         }
 610     else if(cmd == "vyes")
 611     {
 612         if(uid2name_dialog)
 613         {
 614             vote_active = 0; // force the panel to disappear right as we have selected the value (to prevent it from fading out in the normal vote panel pos)
 615             vote_prev = 0;
 616             cvar_set("cl_allow_uid2name", "1");
 617             vote_change = -9999;
 618         }
 619         else
 620         {
 621             localcmd("cmd vote yes\n");
 622         }
 623     }
 624     else if(cmd == "vno")
 625     {
 626         if(uid2name_dialog)
 627         {
 628             vote_active = 0;
 629             vote_prev = 0;
 630             cvar_set("cl_allow_uid2name", "0");
 631             vote_change = -9999;
 632         }
 633         else
 634         {
 635             localcmd("cmd vote no\n");
 636         }
 637     }
 638
 639         else
 640         {
 641                 print("Invalid command. For a list of supported commands, try cl_cmd help.\n");
 642         }
 643
 644         return;
 645 }
 646
 647 // CSQC_InputEvent : Used to perform actions based on any key pressed, key released and mouse on the client.
 648 // Return value should be 1 if CSQC handled the input, otherwise return 0 to have the input passed to the engine.
 649 // All keys are in ascii.
 650 // bInputType = 0 is key pressed, 1 is key released, 2 is mouse input.
 651 // In the case of keyboard input, nPrimary is the ascii code, and nSecondary is 0.
 652 // In the case of mouse input, nPrimary is xdelta, nSecondary is ydelta.
 653 float CSQC_InputEvent(float bInputType, float nPrimary, float nSecondary)
 654 {
 655         local float bSkipKey;
 656         bSkipKey = false;
 657
 658         if (HUD_Panel_InputEvent(bInputType, nPrimary, nSecondary))
 659                 return true;
 660
 661         if (MapVote_InputEvent(bInputType, nPrimary, nSecondary))
 662                 return true;
 663
 664         if(menu_visible)
 665                 if(menu_action(bInputType, nPrimary, nSecondary))
 666                         return TRUE;
 667
 668         return bSkipKey;
 669 }
 670
 671 // END REQUIRED CSQC FUNCTIONS
 672 // --------------------------------------------------------------------------
 673
 674 // --------------------------------------------------------------------------
 675 // BEGIN OPTIONAL CSQC FUNCTIONS
 676 void Ent_ReadEntCS()
 677 {
 678         InterpolateOrigin_Undo();
 679
 680         self.classname = "entcs_receiver";
 681         self.sv_entnum = ReadByte() - 1;
 682         self.origin_x = ReadShort();
 683         self.origin_y = ReadShort();
 684         self.origin_z = ReadShort();
 685         self.angles_y = ReadByte() * 360.0 / 256;
 686         self.origin_z = self.angles_x = self.angles_z = 0;
 687
 688         InterpolateOrigin_Note();
 689 }
 690
 691 void Ent_Remove();
 692
 693 void Ent_RemovePlayerScore()
 694 {
 695         float i;
 696
 697         if(self.owner)
 698         {
 699                 SetTeam(self.owner, -1);
 700                 self.owner.gotscores = 0;
 701                 for(i = 0; i < MAX_SCORE; ++i)
 702                         self.owner.(scores[i]) = 0; // clear all scores
 703         }
 704 }
 705
 706 void Ent_ReadPlayerScore()
 707 {
 708         float i, n;
 709         float isNew;
 710         entity o;
 711
 712         // damnit -.- don't want to go change every single .sv_entnum in hud.qc AGAIN
 713         // (no I've never heard of M-x replace-string, sed, or anything like that)
 714         isNew = !self.owner; // workaround for DP bug
 715         n = ReadByte()-1;
 716
 717 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 718         if(!isNew && n != self.sv_entnum)
 719         {
 720                 print(_("A CSQC entity changed its owner!\n"));
 721                 isNew = true;
 722                 Ent_Remove();
 723                 self.enttype = ENT_CLIENT_SCORES;
 724         }
 725 #endif
 726
 727         self.sv_entnum = n;
 728
 729         if not(playerslots[self.sv_entnum])
 730                 playerslots[self.sv_entnum] = spawn();
 731         o = self.owner = playerslots[self.sv_entnum];
 732         o.sv_entnum = self.sv_entnum;
 733         o.gotscores = 1;
 734
 735         //if not(o.sort_prev)
 736         //      RegisterPlayer(o);
 737         //playerchecker will do this for us later, if it has not already done so
 738
 739         float sf, lf;
 740 #if MAX_SCORE <= 8
 741         sf = ReadByte();
 742         lf = ReadByte();
 743 #else
 744         sf = ReadShort();
 745         lf = ReadShort();
 746 #endif
 747         float p;
 748         for(i = 0, p = 1; i < MAX_SCORE; ++i, p *= 2)
 749                 if(sf & p)
 750                 {
 751                         if(lf & p)
 752                                 o.(scores[i]) = ReadInt24_t();
 753                         else
 754                                 o.(scores[i]) = ReadChar();
 755                 }
 756
 757         if(o.sort_prev)
 758                 HUD_UpdatePlayerPos(o); // if not registered, we cannot do this yet!
 759
 760         self.entremove = Ent_RemovePlayerScore;
 761 }
 762
 763 void Ent_ReadTeamScore()
 764 {
 765         float i;
 766         entity o;
 767
 768         self.team = ReadByte();
 769         o = self.owner = GetTeam(self.team, true); // these team numbers can always be trusted
 770
 771         float sf, lf;
 772 #if MAX_TEAMSCORE <= 8
 773         sf = ReadByte();
 774         lf = ReadByte();
 775 #else
 776         sf = ReadShort();
 777         lf = ReadShort();
 778 #endif
 779         float p;
 780         for(i = 0, p = 1; i < MAX_TEAMSCORE; ++i, p *= 2)
 781                 if(sf & p)
 782                 {
 783                         if(lf & p)
 784                                 o.(teamscores[i]) = ReadInt24_t();
 785                         else
 786                                 o.(teamscores[i]) = ReadChar();
 787                 }
 788
 789         HUD_UpdateTeamPos(o);
 790 }
 791
 792 void Net_Reset()
 793 {
 794 }
 795
 796 void Ent_ClientData()
 797 {
 798         float f;
 799         float newspectatee_status;
 800
 801         f = ReadByte();
 802
 803         scoreboard_showscores_force = (f & 1);
 804
 805         if(f & 2)
 806         {
 807                 newspectatee_status = ReadByte();
 808                 if(newspectatee_status == player_localentnum)
 809                         newspectatee_status = -1; // observing
 810         }
 811         else
 812                 newspectatee_status = 0;
 813
 814         spectatorbutton_zoom = (f & 4);
 815
 816         if(f & 8)
 817         {
 818                 angles_held_status = 1;
 819                 angles_held_x = ReadAngle();
 820                 angles_held_y = ReadAngle();
 821                 angles_held_z = 0;
 822         }
 823         else
 824                 angles_held_status = 0;
 825
 826         if(newspectatee_status != spectatee_status)
 827         {
 828                 float i;
 829
 830                 // clear race stuff
 831                 race_laptime = 0;
 832                 race_checkpointtime = 0;
 833         }
 834         spectatee_status = newspectatee_status;
 835 }
 836
 837 void Ent_Nagger()
 838 {
 839         float nags, i, j, b, f;
 840
 841         nags = ReadByte();
 842
 843         if(nags & 128)
 844         {
 845                 if(vote_called_vote)
 846                         strunzone(vote_called_vote);
 847                 vote_called_vote = strzone(ColorTranslateRGB(ReadString()));
 848         }
 849
 850         if(nags & 1)
 851         {
 852                 for(j = 0; j < maxclients; ++j)
 853                         if(playerslots[j])
 854                                 playerslots[j].ready = 1;
 855                 for(i = 1; i <= maxclients; i += 8)
 856                 {
 857                         f = ReadByte();
 858                         for(j = i-1, b = 1; b < 256; b *= 2, ++j)
 859                                 if not(f & b)
 860                                         if(playerslots[j])
 861                                                 playerslots[j].ready = 0;
 862                 }
 863         }
 864
 865         ready_waiting = (nags & 1);
 866         ready_waiting_for_me = (nags & 2);
 867         vote_waiting = (nags & 4);
 868         vote_waiting_for_me = (nags & 8);
 869         warmup_stage = (nags & 16);
 870 }
 871
 872 void Ent_RandomSeed()
 873 {
 874         float s;
 875         prandom_debug();
 876         s = ReadShort();
 877         psrandom(s);
 878 }
 879
 880 void Ent_ReadAccuracy(void)
 881 {
 882         float sf, f, w, b;
 883         sf = ReadInt24_t();
 884         if(sf == 0)
 885         {
 886                 for(w = 0; w <= WEP_LAST - WEP_FIRST; ++w)
 887                         weapon_accuracy[w] = -1;
 888                 return;
 889         }
 890
 891         for(w = 0, f = 1; w <= WEP_LAST - WEP_FIRST; ++w, f *= 2)
 892         {
 893                 if(sf & f)
 894                 {
 895                         b = ReadByte();
 896                         if(b == 0)
 897                                 weapon_accuracy[w] = -1;
 898                         else if(b == 255)
 899                                 weapon_accuracy[w] = 1.0; // no better error handling yet, sorry
 900                         else
 901                                 weapon_accuracy[w] = (b - 1.0) / 100.0;
 902                 }
 903         }
 904 }
 905
 906 // CSQC_Ent_Update : Called every frame that the server has indicated an update to the SSQC / CSQC entity has occured.
 907 // The only parameter reflects if the entity is "new" to the client, meaning it just came into the client's PVS.
 908 void Ent_RadarLink();
 909 void Ent_Init();
 910 void Ent_ScoresInfo();
 911 void(float bIsNewEntity) CSQC_Ent_Update =
 912 {
 913         float t;
 914         float savetime;
 915         t = ReadByte();
 916
 917         // set up the "time" global for received entities to be correct for interpolation purposes
 918         savetime = time;
 919         if(servertime)
 920         {
 921                 time = servertime;
 922         }
 923         else
 924         {
 925                 serverprevtime = time;
 926                 serverdeltatime = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
 927                 time = serverprevtime + serverdeltatime;
 928         }
 929
 930 #ifdef DP_CSQC_ENTITY_REMOVE_IS_B0RKED
 931         if(self.enttype)
 932                 if(t != self.enttype)
 933                 {
 934                         print(_("A CSQC entity changed its type!\n"));
 935                         Ent_Remove();
 936                         bIsNewEntity = 1;
 937                 }
 938 #endif
 939         self.enttype = t;
 940         switch(t)
 941         {
 942                 case ENT_CLIENT_ENTCS: Ent_ReadEntCS(); break;
 943                 case ENT_CLIENT_SCORES: Ent_ReadPlayerScore(); break;
 944                 case ENT_CLIENT_TEAMSCORES: Ent_ReadTeamScore(); break;
 945                 case ENT_CLIENT_POINTPARTICLES: Ent_PointParticles(); break;
 946                 case ENT_CLIENT_RAINSNOW: Ent_RainOrSnow(); break;
 947                 case ENT_CLIENT_LASER: Ent_Laser(); break;
 948                 case ENT_CLIENT_NAGGER: Ent_Nagger(); break;
 949                 case ENT_CLIENT_WAYPOINT: Ent_WaypointSprite(); break;
 950                 case ENT_CLIENT_RADARLINK: Ent_RadarLink(); break;
 951                 case ENT_CLIENT_PROJECTILE: Ent_Projectile(); break;
 952                 case ENT_CLIENT_GIBSPLASH: Ent_GibSplash(bIsNewEntity); break;
 953                 case ENT_CLIENT_DAMAGEINFO: Ent_DamageInfo(bIsNewEntity); break;
 954                 case ENT_CLIENT_CASING: Ent_Casing(bIsNewEntity); break;
 955                 case ENT_CLIENT_INIT: Ent_Init(); break;
 956                 case ENT_CLIENT_SCORES_INFO: Ent_ScoresInfo(); break;
 957                 case ENT_CLIENT_MAPVOTE: Ent_MapVote(); break;
 958                 case ENT_CLIENT_CLIENTDATA: Ent_ClientData(); break;
 959                 case ENT_CLIENT_RANDOMSEED: Ent_RandomSeed(); break;
 960                 case ENT_CLIENT_WALL: Ent_Wall(); break;
 961                 case ENT_CLIENT_MODELEFFECT: Ent_ModelEffect(bIsNewEntity); break;
 962                 case ENT_CLIENT_TUBANOTE: Ent_TubaNote(bIsNewEntity); break;
 963                 case ENT_CLIENT_WARPZONE: WarpZone_Read(bIsNewEntity); break;
 964                 case ENT_CLIENT_WARPZONE_CAMERA: WarpZone_Camera_Read(bIsNewEntity); break;
 965                 case ENT_CLIENT_WARPZONE_TELEPORTED: WarpZone_Teleported_Read(bIsNewEntity); break;
 966                 case ENT_CLIENT_TRIGGER_MUSIC: Ent_ReadTriggerMusic(); break;
 967                 case ENT_CLIENT_HOOK: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_HOOK); break;
 968                 case ENT_CLIENT_LGBEAM: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_LGBEAM); break;
 969                 case ENT_CLIENT_GAUNTLET: Ent_ReadHook(bIsNewEntity, ENT_CLIENT_GAUNTLET); break;
 970                 case ENT_CLIENT_ACCURACY: Ent_ReadAccuracy(); break;
 971                 default:
 972                         error(strcat(_("unknown entity type in CSQC_Ent_Update: %d\n"), self.enttype));
 973                         break;
 974         }
 975
 976         time = savetime;
 977 };
 978 // Destructor, but does NOT deallocate the entity by calling remove(). Also
 979 // used when an entity changes its type. For an entity that someone interacts
 980 // with others, make sure it can no longer do so.
 981 void Ent_Remove()
 982 {
 983         if(self.entremove)
 984                 self.entremove();
 985
 986         self.enttype = 0;
 987         self.classname = "";
 988         self.draw = menu_sub_null;
 989         self.entremove = menu_sub_null;
 990         // TODO possibly set more stuff to defaults
 991 }
 992 // CSQC_Ent_Remove : Called when the server requests a SSQC / CSQC entity to be removed.  Essentially call remove(self) as well.
 993 void CSQC_Ent_Remove()
 994 {
 995         if(self.enttype)
 996                 Ent_Remove();
 997         remove(self);
 998 }
 999
1000 void Gamemode_Init()
1001 {
1002         if(gametype == GAME_ONSLAUGHT) {
1003                 print(strcat("Using ", minimapname, " as minimap.\n"));
1004                 precache_pic("gfx/ons-cp-neutral.tga");
1005                 precache_pic("gfx/ons-cp-red.tga");
1006                 precache_pic("gfx/ons-cp-blue.tga");
1007                 precache_pic("gfx/ons-frame.tga");
1008                 precache_pic("gfx/ons-frame-team.tga");
1009         }
1010
1011         if not(isdemo())
1012         {
1013                 localcmd("\n_cl_hook_gamestart ", GametypeNameFromType(gametype), "\n");
1014                 calledhooks |= HOOK_START;
1015         }
1016 }
1017 // CSQC_Parse_StuffCmd : Provides the stuffcmd string in the first parameter that the server provided.  To execute standard behavior, simply execute localcmd with the string.
1018 void CSQC_Parse_StuffCmd(string strMessage)
1019 {
1020         localcmd(strMessage);
1021 }
1022 // CSQC_Parse_Print : Provides the print string in the first parameter that the server provided.  To execute standard behavior, simply execute print with the string.
1023 void CSQC_Parse_Print(string strMessage)
1024 {
1025         print(ColorTranslateRGB(strMessage));
1026 }
1027
1028 // CSQC_Parse_CenterPrint : Provides the centerprint string in the first parameter that the server provided.
1029 void CSQC_Parse_CenterPrint(string strMessage)
1030 {
1031         centerprint(strMessage);
1032 }
1033
1034 string notranslate_fogcmd1 = "\nfog ";
1035 string notranslate_fogcmd2 = "\nr_fog_exp2 0\nr_drawfog 1\n";
1036 void Fog_Force()
1037 {
1038         // TODO somehow thwart prvm_globalset client ...
1039
1040         if(forcefog != "")
1041                 localcmd(strcat(notranslate_fogcmd1, forcefog, notranslate_fogcmd2));
1042 }
1043
1044 void Gamemode_Init();
1045 void Ent_ScoresInfo()
1046 {
1047         float i;
1048         self.classname = "ent_client_scores_info";
1049         gametype = ReadByte();
1050         for(i = 0; i < MAX_SCORE; ++i)
1051         {
1052                 scores_label[i] = strzone(ReadString());
1053                 scores_flags[i] = ReadByte();
1054         }
1055         for(i = 0; i < MAX_TEAMSCORE; ++i)
1056         {
1057                 teamscores_label[i] = strzone(ReadString());
1058                 teamscores_flags[i] = ReadByte();
1059         }
1060         HUD_InitScores();
1061         Gamemode_Init();
1062 }
1063
1064 void Ent_Init()
1065 {
1066         self.classname = "ent_client_init";
1067
1068         nb_pb_period = ReadByte() / 32; //Accuracy of 1/32th
1069
1070         hook_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1071         hook_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1072         hook_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1073         hook_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1074         electro_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1075         electro_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1076         electro_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1077         electro_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1078         gauntlet_shotorigin[0] = decompressShotOrigin(ReadInt24_t());
1079         gauntlet_shotorigin[1] = decompressShotOrigin(ReadInt24_t());
1080         gauntlet_shotorigin[2] = decompressShotOrigin(ReadInt24_t());
1081         gauntlet_shotorigin[3] = decompressShotOrigin(ReadInt24_t());
1082
1083         if(forcefog)
1084                 strunzone(forcefog);
1085         forcefog = strzone(ReadString());
1086
1087         armorblockpercent = ReadByte() / 255.0;
1088
1089         g_weaponswitchdelay = ReadByte() / 255.0;
1090
1091         g_balance_grenadelauncher_bouncefactor = ReadCoord();
1092         g_balance_grenadelauncher_bouncestop = ReadCoord();
1093         g_balance_electro_secondary_bouncefactor = ReadCoord();
1094         g_balance_electro_secondary_bouncestop = ReadCoord();
1095
1096         nex_scope = !ReadByte();
1097         sniperrifle_scope = !ReadByte();
1098
1099         serverflags = ReadByte();
1100
1101         minelayer_maxmines = ReadByte();
1102
1103         g_trueaim_minrange = ReadCoord();
1104
1105         if(!postinit)
1106                 PostInit();
1107 }
1108
1109 void Net_ReadRace()
1110 {
1111         float b;
1112
1113         b = ReadByte();
1114
1115         switch(b)
1116         {
1117                 case RACE_NET_CHECKPOINT_HIT_QUALIFYING:
1118                         race_checkpoint = ReadByte();
1119                         race_time = ReadInt24_t();
1120                         race_previousbesttime = ReadInt24_t();
1121                         if(race_previousbestname)
1122                                 strunzone(race_previousbestname);
1123                         race_previousbestname = strzone(ColorTranslateRGB(ReadString()));
1124
1125                         race_checkpointtime = time;
1126
1127                         if(race_checkpoint == 0 || race_checkpoint == 254)
1128                         {
1129                                 race_penaltyaccumulator = 0;
1130                                 race_laptime = time; // valid
1131                         }
1132
1133                         break;
1134
1135                 case RACE_NET_CHECKPOINT_CLEAR:
1136                         race_laptime = 0;
1137                         race_checkpointtime = 0;
1138                         break;
1139
1140                 case RACE_NET_CHECKPOINT_NEXT_SPEC_QUALIFYING:
1141                         race_laptime = ReadCoord();
1142                         race_checkpointtime = -99999;
1143                         // fall through
1144                 case RACE_NET_CHECKPOINT_NEXT_QUALIFYING:
1145                         race_nextcheckpoint = ReadByte();
1146
1147                         race_nextbesttime = ReadInt24_t();
1148                         if(race_nextbestname)
1149                                 strunzone(race_nextbestname);
1150                         race_nextbestname = strzone(ColorTranslateRGB(ReadString()));
1151                         break;
1152
1153                 case RACE_NET_CHECKPOINT_HIT_RACE:
1154                         race_mycheckpoint = ReadByte();
1155                         race_mycheckpointtime = time;
1156                         race_mycheckpointdelta = ReadInt24_t();
1157                         race_mycheckpointlapsdelta = ReadByte();
1158                         if(race_mycheckpointlapsdelta >= 128)
1159                                 race_mycheckpointlapsdelta -= 256;
1160                         if(race_mycheckpointenemy)
1161                                 strunzone(race_mycheckpointenemy);
1162                         race_mycheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1163                         break;
1164
1165                 case RACE_NET_CHECKPOINT_HIT_RACE_BY_OPPONENT:
1166                         race_othercheckpoint = ReadByte();
1167                         race_othercheckpointtime = time;
1168                         race_othercheckpointdelta = ReadInt24_t();
1169                         race_othercheckpointlapsdelta = ReadByte();
1170                         if(race_othercheckpointlapsdelta >= 128)
1171                                 race_othercheckpointlapsdelta -= 256;
1172                         if(race_othercheckpointenemy)
1173                                 strunzone(race_othercheckpointenemy);
1174                         race_othercheckpointenemy = strzone(ColorTranslateRGB(ReadString()));
1175                         break;
1176
1177                 case RACE_NET_PENALTY_RACE:
1178                         race_penaltyeventtime = time;
1179                         race_penaltytime = ReadShort();
1180                         //race_penaltyaccumulator += race_penaltytime;
1181                         if(race_penaltyreason)
1182                                 strunzone(race_penaltyreason);
1183                         race_penaltyreason = strzone(ReadString());
1184                         break;
1185
1186                 case RACE_NET_PENALTY_QUALIFYING:
1187                         race_penaltyeventtime = time;
1188                         race_penaltytime = ReadShort();
1189                         race_penaltyaccumulator += race_penaltytime;
1190                         if(race_penaltyreason)
1191                                 strunzone(race_penaltyreason);
1192                         race_penaltyreason = strzone(ReadString());
1193                         break;
1194
1195                 case RACE_NET_SERVER_RECORD:
1196                         race_server_record = ReadInt24_t();
1197                         break;
1198                 case RACE_NET_SPEED_AWARD:
1199                         race_speedaward = ReadInt24_t();
1200                         if(race_speedaward_holder)
1201                                 strunzone(race_speedaward_holder);
1202                         race_speedaward_holder = strzone(ReadString());
1203                         break;
1204                 case RACE_NET_SPEED_AWARD_BEST:
1205                         race_speedaward_alltimebest = ReadInt24_t();
1206                         if(race_speedaward_alltimebest_holder)
1207                                 strunzone(race_speedaward_alltimebest_holder);
1208                         race_speedaward_alltimebest_holder = strzone(ReadString());
1209                         break;
1210                 case RACE_NET_SERVER_RANKINGS:
1211                         float pos, prevpos, del;
1212                         pos = ReadShort();
1213                         prevpos = ReadShort();
1214                         del = ReadShort();
1215
1216                         // move other rankings out of the way
1217                         float i;
1218                         if (prevpos) {
1219                                 for (i=prevpos-1;i>pos-1;--i) {
1220                                         grecordtime[i] = grecordtime[i-1];
1221                                         if(grecordholder[i])
1222                                                 strunzone(grecordholder[i]);
1223                                         grecordholder[i] = strzone(grecordholder[i-1]);
1224                                 }
1225                         } else if (del) { // a record has been deleted by the admin
1226                                 for (i=pos-1; i<= RANKINGS_CNT-1; ++i) {
1227                                         if (i == RANKINGS_CNT-1) { // clear out last record
1228                                                 grecordtime[i] = 0;
1229                                                 if (grecordholder[i])
1230                                                         strunzone(grecordholder[i]);
1231                                                 grecordholder[i] = string_null;
1232                                         }
1233                                         else {
1234                                                 grecordtime[i] = grecordtime[i+1];
1235                                                 if (grecordholder[i])
1236                                                         strunzone(grecordholder[i]);
1237                                                 grecordholder[i] = strzone(grecordholder[i+1]);
1238                                         }
1239                                 }
1240                         } else { // player has no ranked record yet
1241                                 for (i=RANKINGS_CNT-1;i>pos-1;--i) {
1242                                         grecordtime[i] = grecordtime[i-1];
1243                                         if(grecordholder[i])
1244                                                 strunzone(grecordholder[i]);
1245                                         grecordholder[i] = strzone(grecordholder[i-1]);
1246                                 }
1247                         }
1248
1249                         // store new ranking
1250                         if(grecordholder[pos-1] != "")
1251                                 strunzone(grecordholder[pos-1]);
1252                         grecordholder[pos-1] = strzone(ReadString());
1253                         grecordtime[pos-1] = ReadInt24_t();
1254                         if(grecordholder[pos-1] == GetPlayerName(player_localentnum -1))
1255                                 race_myrank = pos;
1256                         break;
1257                 case RACE_NET_SERVER_STATUS:
1258                         race_status = ReadShort();
1259                         if(race_status_name)
1260                                 strunzone(race_status_name);
1261                         race_status_name = strzone(ReadString());
1262         }
1263 }
1264
1265 void Net_ReadSpawn()
1266 {
1267         zoomin_effect = 1;
1268         current_viewzoom = 0.6;
1269 }
1270
1271 void Net_TeamNagger()
1272 {
1273         teamnagger = 1;
1274 }
1275
1276 void Net_ReadPingPLReport()
1277 {
1278         float e, pi, pl, ml;
1279         e = ReadByte();
1280         pi = ReadShort();
1281         pl = ReadByte();
1282         ml = ReadByte();
1283         if not(playerslots[e])
1284                 return;
1285         playerslots[e].ping = pi;
1286         playerslots[e].ping_packetloss = pl / 255.0;
1287         playerslots[e].ping_movementloss = ml / 255.0;
1288 }
1289
1290 void Net_VoteDialog(float highlight) {
1291         if(highlight) {
1292                 vote_highlighted = ReadByte();
1293                 return;
1294         }
1295
1296         vote_yescount = ReadByte();
1297         vote_nocount = ReadByte();
1298         vote_needed = ReadByte();
1299         vote_active = 1;
1300 }
1301
1302 void Net_VoteDialogReset() {
1303         vote_active = 0;
1304 }
1305
1306 void Net_Notify() {
1307         float type;
1308         type = ReadByte();
1309
1310         if(type == CSQC_KILLNOTIFY)
1311         {
1312                 HUD_KillNotify(ReadString(), ReadString(), ReadString(), ReadShort(), ReadByte());
1313         }
1314         else if(type == CSQC_CENTERPRINT)
1315         {
1316                 HUD_Centerprint(ReadString(), ReadString(), ReadShort(), ReadByte());
1317         }
1318 }
1319
1320 void Net_WeaponComplain() {
1321         complain_weapon = ReadByte();
1322
1323         if(complain_weapon_name)
1324                 strunzone(complain_weapon_name);
1325         complain_weapon_name = strzone(ReadString());
1326
1327         complain_weapon_type = ReadByte();
1328
1329         complain_weapon_time = time;
1330         weapontime = time; // ping the weapon panel
1331 }
1332
1333 // CSQC_Parse_TempEntity : Handles all temporary entity network data in the CSQC layer.
1334 // You must ALWAYS first acquire the temporary ID, which is sent as a byte.
1335 // Return value should be 1 if CSQC handled the temporary entity, otherwise return 0 to have the engine process the event.
1336 float CSQC_Parse_TempEntity()
1337 {
1338         local float bHandled;
1339                 bHandled  = true;
1340         // Acquire TE ID
1341         local float nTEID;
1342                 nTEID = ReadByte();
1343
1344                 // NOTE: Could just do return instead of break...
1345         switch(nTEID)
1346         {
1347                 case TE_CSQC_TARGET_MUSIC:
1348                         Net_TargetMusic();
1349                         bHandled = true;
1350                         break;
1351                 case TE_CSQC_PICTURE:
1352                         Net_MapVote_Picture();
1353                         bHandled = true;
1354                         break;
1355                 case TE_CSQC_RACE:
1356                         Net_ReadRace();
1357                         bHandled = true;
1358                         break;
1359                 case TE_CSQC_SPAWN:
1360                         Net_ReadSpawn();
1361                         bHandled = true;
1362                         break;
1363                 case TE_CSQC_ZCURVEPARTICLES:
1364                         Net_ReadZCurveParticles();
1365                         bHandled = true;
1366                         break;
1367                 case TE_CSQC_NEXGUNBEAMPARTICLE:
1368                         Net_ReadNexgunBeamParticle();
1369                         bHandled = true;
1370                         break;
1371                 case TE_CSQC_TEAMNAGGER:
1372                         Net_TeamNagger();
1373                         bHandled = true;
1374                         break;
1375                 case TE_CSQC_VOTE:
1376                         Net_VoteDialog(ReadByte());
1377                         bHandled = true;
1378                         break;
1379                 case TE_CSQC_VOTERESET:
1380                         Net_VoteDialogReset();
1381                         bHandled = true;
1382                         break;
1383                 case TE_CSQC_LIGHTNINGARC:
1384                         Net_ReadLightningarc();
1385                         bHandled = true;
1386                         break;
1387                 case TE_CSQC_PINGPLREPORT:
1388                         Net_ReadPingPLReport();
1389                         bHandled = true;
1390                         break;
1391                 case TE_CSQC_ANNOUNCE:
1392                         announce_snd = strzone(ReadString());
1393                         bHandled = true;
1394                         break;
1395                 case TE_CSQC_NOTIFY:
1396                         Net_Notify();
1397                         bHandled = true;
1398                         break;
1399                 case TE_CSQC_WEAPONCOMPLAIN:
1400                         Net_WeaponComplain();
1401                         bHandled = true;
1402                         break;
1403                 default:
1404                         // No special logic for this temporary entity; return 0 so the engine can handle it
1405                         bHandled = false;
1406                         break;
1407         }
1408
1409         return bHandled;
1410 }
1411
1412 string getcommandkey(string text, string command)
1413 {
1414         string keys;
1415         float n, j, k, l;
1416
1417         if (!hud_showbinds)
1418                 return text;
1419
1420         keys = db_get(binddb, command);
1421         if (!keys)
1422         {
1423                 n = tokenize(findkeysforcommand(command)); // uses '...' strings
1424                 for(j = 0; j < n; ++j)
1425                 {
1426                         k = stof(argv(j));
1427                         if(k != -1)
1428                         {
1429                                 if ("" == keys)
1430                                         keys = keynumtostring(k);
1431                                 else
1432                                         keys = strcat(keys, ", ", keynumtostring(k));
1433
1434                                 ++l;
1435                                 if (hud_showbinds_limit > 0 && hud_showbinds_limit >= l) break;
1436                         }
1437
1438                 }
1439                 db_put(binddb, command, keys);
1440         }
1441
1442         if ("" == keys) {
1443                 if (hud_showbinds > 1)
1444                         return sprintf(_("%s (not bound)"), text);
1445                 else
1446                         return text;
1447         }
1448         else if (hud_showbinds > 1)
1449                 return sprintf(_("%s (%s)"), text, keys);
1450         else
1451                 return keys;
1452 }