server/rcon2irc/rcon2irc.pl

   1 #!/usr/bin/perl
   2
   3 our $VERSION = '0.4.2 svn $Revision$';
   4
   5 # Copyright (c) 2008 Rudolf "divVerent" Polzer
   6 #
   7 # Permission is hereby granted, free of charge, to any person
   8 # obtaining a copy of this software and associated documentation
   9 # files (the "Software"), to deal in the Software without
  10 # restriction, including without limitation the rights to use,
  11 # copy, modify, merge, publish, distribute, sublicense, and/or sell
  12 # copies of the Software, and to permit persons to whom the
  13 # Software is furnished to do so, subject to the following
  14 # conditions:
  15 #
  16 # The above copyright notice and this permission notice shall be
  17 # included in all copies or substantial portions of the Software.
  18 #
  19 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  21 # OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  22 # NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  23 # HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  24 # WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  26 # OTHER DEALINGS IN THE SOFTWARE.
  27
  28 # MISC STRING UTILITY ROUTINES to convert between DarkPlaces and IRC conventions
  29
  30 # convert mIRC color codes to DP color codes
  31 our $color_utf8_enable = 1;
  32 our @color_irc2dp_table = (7, 0, 4, 2, 1, 1, 6, 1, 3, 2, 5, 5, 4, 6, 7, 7);
  33 our @color_dp2irc_table = (-1, 4, 9, 8, 12, 11, 13, -1, -1, -1); # not accurate, but legible
  34 our @color_dp2ansi_table = ("m", "1;31m", "1;32m", "1;33m", "1;34m", "1;36m", "1;35m", "m", "1m", "1m"); # not accurate, but legible
  35 our %color_team2dp_table = (5 => 1, 14 => 4, 13 => 3, 10 => 6);
  36 our %color_team2irc_table = (5 => 4, 14 => 12, 13 => 8, 10 => 13);
  37 sub color_irc2dp($)
  38 {
  39         my ($message) = @_;
  40         $message =~ s/\^/^^/g;
  41         my $color = 7;
  42         $message =~ s{\003(\d\d?)(?:,(\d?\d?))?|(\017)}{
  43                 # $1 is FG, $2 is BG, but let's ignore BG
  44                 my $oldcolor = $color;
  45                 if($3)
  46                 {
  47                         $color = 7;
  48                 }
  49                 else
  50                 {
  51                         $color = $color_irc2dp_table[$1];
  52                         $color = $oldcolor if not defined $color;
  53                 }
  54                 ($color == $oldcolor) ? '' : '^' . $color;
  55         }esg;
  56         $message =~ s{[\000-\037]}{}gs; # kill bold etc. for now
  57         return $message;
  58 }
  59
  60 our @text_qfont_table = ( # ripped from DP console.c qfont_table
  61     '',   '#',  '#',  '#',  '#',  '.',  '#',  '#',
  62     '#',  9,    10,   '#',  ' ',  13,   '.',  '.',
  63     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  64     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  65     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  66     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  67     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  68     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  69     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  70     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  71     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  72     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  73     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  74     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  75     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  76     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<',
  77     '<',  '=',  '>',  '#',  '#',  '.',  '#',  '#',
  78     '#',  '#',  ' ',  '#',  ' ',  '>',  '.',  '.',
  79     '[',  ']',  '0',  '1',  '2',  '3',  '4',  '5',
  80     '6',  '7',  '8',  '9',  '.',  '<',  '=',  '>',
  81     ' ',  '!',  '"',  '#',  '$',  '%',  '&',  '\'',
  82     '(',  ')',  '*',  '+',  ',',  '-',  '.',  '/',
  83     '0',  '1',  '2',  '3',  '4',  '5',  '6',  '7',
  84     '8',  '9',  ':',  ';',  '<',  '=',  '>',  '?',
  85     '@',  'A',  'B',  'C',  'D',  'E',  'F',  'G',
  86     'H',  'I',  'J',  'K',  'L',  'M',  'N',  'O',
  87     'P',  'Q',  'R',  'S',  'T',  'U',  'V',  'W',
  88     'X',  'Y',  'Z',  '[',  '\\', ']',  '^',  '_',
  89     '`',  'a',  'b',  'c',  'd',  'e',  'f',  'g',
  90     'h',  'i',  'j',  'k',  'l',  'm',  'n',  'o',
  91     'p',  'q',  'r',  's',  't',  'u',  'v',  'w',
  92     'x',  'y',  'z',  '{',  '|',  '}',  '~',  '<'
  93 );
  94 sub text_qfont_table($)
  95 {
  96         my ($char) = @_;
  97         my $o = ord $char;
  98         if($color_utf8_enable)
  99         {
 100                 return (($o & 0xFF00) == 0xE000) ? $text_qfont_table[$o & 0xFF] : $char;
 101         }
 102         else
 103         {
 104                 return $text_qfont_table[$o];
 105         }
 106 }
 107 sub text_dp2ascii($)
 108 {
 109         my ($message) = @_;
 110         $message = join '', map { text_qfont_table $_ } split //, $message;
 111 }
 112
 113 sub color_dp_transform(&$)
 114 {
 115         my ($block, $message) = @_;
 116         $message =~ s{(?:(\^\^)|\^x([0-9a-fA-F])([0-9a-fA-F])([0-9a-fA-F])|\^([0-9])|(.))(?=([0-9,]?))}{
 117                 defined $1 ? $block->(char => '^', $7) :
 118                 defined $2 ? $block->(rgb => [hex $2, hex $3, hex $4], $7) :
 119                 defined $5 ? $block->(color => $5, $7) :
 120                 defined $6 ? $block->(char => $6, $7) :
 121                         die "Invalid match";
 122         }esg;
 123
 124         return $message;
 125 }
 126
 127 sub color_dp2none($)
 128 {
 129         my ($message) = @_;
 130
 131         return color_dp_transform
 132         {
 133                 my ($type, $data, $next) = @_;
 134                 $type eq 'char'
 135                         ? text_qfont_table $data
 136                         : "";
 137         }
 138         $message;
 139 }
 140
 141 sub color_rgb2basic($)
 142 {
 143         my ($data) = @_;
 144         my ($R, $G, $B) = @$data;
 145         my $min = [sort { $a <=> $b } ($R, $G, $B)]->[0];
 146         my $max = [sort { $a <=> $b } ($R, $G, $B)]->[-1];
 147
 148         my $v = $max / 15;
 149         my $s = ($max == $min) ? 0 : 1 - $min/$max;
 150
 151         if($s < 0.2)
 152         {
 153                 return 0 if $v < 0.5;
 154                 return 7;
 155         }
 156
 157         my $h;
 158         if($max == $min)
 159         {
 160                 $h = 0;
 161         }
 162         elsif($max == $R)
 163         {
 164                 $h = (60 * ($G - $B) / ($max - $min)) % 360;
 165         }
 166         elsif($max == $G)
 167         {
 168                 $h = (60 * ($B - $R) / ($max - $min)) + 120;
 169         }
 170         elsif($max == $B)
 171         {
 172                 $h = (60 * ($R - $G) / ($max - $min)) + 240;
 173         }
 174
 175         return 1 if $h < 36;
 176         return 3 if $h < 80;
 177         return 2 if $h < 150;
 178         return 5 if $h < 200;
 179         return 4 if $h < 270;
 180         return 6 if $h < 330;
 181         return 1;
 182 }
 183
 184 sub color_dp_rgb2basic($)
 185 {
 186         my ($message) = @_;
 187         return color_dp_transform
 188         {
 189                 my ($type, $data, $next) = @_;
 190                 $type eq 'char'  ? ($data eq '^' ? '^^' : $data) :
 191                 $type eq 'color' ? "^$data" :
 192                 $type eq 'rgb'   ? "^" . color_rgb2basic $data :
 193                         die "Invalid type";
 194         }
 195         $message;
 196 }
 197
 198 sub color_dp2irc($)
 199 {
 200         my ($message) = @_;
 201         my $color = -1;
 202         return color_dp_transform
 203         {
 204                 my ($type, $data, $next) = @_;
 205
 206                 if($type eq 'rgb')
 207                 {
 208                         $type = 'color';
 209                         $data = color_rgb2basic $data;
 210                 }
 211
 212                 $type eq 'char'  ? text_qfont_table $data :
 213                 $type eq 'color' ? do {
 214                         my $oldcolor = $color;
 215                         $color = $color_dp2irc_table[$data];
 216
 217                         $color == $oldcolor               ? '' :
 218                         $color < 0                        ? "\017" :
 219                         (index '0123456789,', $next) >= 0 ? "\003$color\002\002" :
 220                                                             "\003$color";
 221                 } :
 222                         die "Invalid type";
 223         }
 224         $message;
 225 }
 226
 227 sub color_dp2ansi($)
 228 {
 229         my ($message) = @_;
 230         my $color = -1;
 231         return color_dp_transform
 232         {
 233                 my ($type, $data, $next) = @_;
 234
 235                 if($type eq 'rgb')
 236                 {
 237                         $type = 'color';
 238                         $data = color_rgb2basic $data;
 239                 }
 240
 241                 $type eq 'char'  ? text_qfont_table $data :
 242                 $type eq 'color' ? do {
 243                         my $oldcolor = $color;
 244                         $color = $color_dp2ansi_table[$data];
 245
 246                         $color eq $oldcolor ? '' :
 247                                               "\033[${color}"
 248                 } :
 249                         die "Invalid type";
 250         }
 251         $message;
 252 }
 253
 254 sub color_dpfix($)
 255 {
 256         my ($message) = @_;
 257         # if the message ends with an odd number of ^, kill one
 258         chop $message if $message =~ /(?:^|[^\^])\^(\^\^)*$/;
 259         return $message;
 260 }
 261
 262
 263
 264
 265 # Interfaces:
 266 #   Connection:
 267 #     $conn->sockname() returns a connection type specific representation
 268 #       string of the local address, or undef if not applicable.
 269 #     $conn->peername() returns a connection type specific representation
 270 #       string of the remote address, or undef if not applicable.
 271 #     $conn->send("string") sends something over the connection.
 272 #     $conn->recv() receives a string from the connection, or returns "" if no
 273 #       data is available.
 274 #     $conn->fds() returns all file descriptors used by the connection, so one
 275 #       can use select() on them.
 276 #   Channel:
 277 #     Usually wraps around a connection and implements a command based
 278 #     structure over it. It usually is constructed using new
 279 #     ChannelType($connection, someparameters...)
 280 #     @cmds = $chan->join_commands(@cmds) joins multiple commands to a single
 281 #       command string if the protocol supports it, or does nothing and leaves
 282 #       @cmds unchanged if the protocol does not support that usage (this is
 283 #       meant to save send() invocations).
 284 #     $chan->send($command, $nothrottle) sends a command over the channel. If
 285 #       $nothrottle is sent, the command must not be left out even if the channel
 286 #       is saturated (for example, because of IRC's flood control mechanism).
 287 #     $chan->quote($str) returns a string in a quoted form so it can safely be
 288 #       inserted as a substring into a command, or returns $str as is if not
 289 #       applicable. It is assumed that the result of the quote method is used
 290 #       as part of a quoted string, if the protocol supports that.
 291 #     $chan->recv() returns a list of received commands from the channel, or
 292 #       the empty list if none are available.
 293 #     $conn->fds() returns all file descriptors used by the channel's
 294 #       connections, so one can use select() on them.
 295
 296
 297
 298
 299
 300
 301
 302 # Socket connection.
 303 # Represents a connection over a socket.
 304 # Mainly used to wrap a channel around it for, in this case, line based or rcon-like operation.
 305 package Connection::Socket;
 306 use strict;
 307 use warnings;
 308 use IO::Socket::INET;
 309 use IO::Handle;
 310
 311 # Constructor:
 312 #   my $conn = new Connection::Socket(tcp => "localaddress" => "remoteaddress" => 6667);
 313 # If the remote address does not contain a port number, the numeric port is
 314 # used (it serves as a default port).
 315 sub new($$)
 316 {
 317         my ($class, $proto, $local, $remote, $defaultport) = @_;
 318         my $sock = IO::Socket::INET->new(
 319                 Proto => $proto,
 320                 (length($local) ? (LocalAddr => $local) : ()),
 321                 PeerAddr => $remote,
 322                 PeerPort => $defaultport
 323         ) or die "socket $proto/$local/$remote/$defaultport: $!";
 324         binmode $sock;
 325         $sock->blocking(0);
 326         my $you = {
 327                 # Mortal fool! Release me from this wretched tomb! I must be set free
 328                 # or I will haunt you forever! I will hide your keys beneath the
 329                 # cushions of your upholstered furniture... and NEVERMORE will you be
 330                 # able to find socks that match!
 331                 sock => $sock,
 332                 # My demonic powers have made me OMNIPOTENT! Bwahahahahahahaha!
 333         };
 334         return
 335                 bless $you, 'Connection::Socket';
 336 }
 337
 338 # $sock->sockname() returns the local address of the socket.
 339 sub sockname($)
 340 {
 341         my ($self) = @_;
 342         my ($port, $addr) = sockaddr_in $self->{sock}->sockname();
 343         return "@{[inet_ntoa $addr]}:$port";
 344 }
 345
 346 # $sock->peername() returns the remote address of the socket.
 347 sub peername($)
 348 {
 349         my ($self) = @_;
 350         my ($port, $addr) = sockaddr_in $self->{sock}->peername();
 351         return "@{[inet_ntoa $addr]}:$port";
 352 }
 353
 354 # $sock->send($data) sends some data over the socket; on success, 1 is returned.
 355 sub send($$)
 356 {
 357         my ($self, $data) = @_;
 358         return 1
 359                 if not length $data;
 360         if(not eval { $self->{sock}->send($data); })
 361         {
 362                 warn "$@";
 363                 return 0;
 364         }
 365         return 1;
 366 }
 367
 368 # $sock->recv() receives as much as possible from the socket (or at most 32k). Returns "" if no data is available.
 369 sub recv($)
 370 {
 371         my ($self) = @_;
 372         my $data = "";
 373         if(defined $self->{sock}->recv($data, 32768, 0))
 374         {
 375                 return $data;
 376         }
 377         elsif($!{EAGAIN})
 378         {
 379                 return "";
 380         }
 381         else
 382         {
 383                 return undef;
 384         }
 385 }
 386
 387 # $sock->fds() returns the socket file descriptor.
 388 sub fds($)
 389 {
 390         my ($self) = @_;
 391         return fileno $self->{sock};
 392 }
 393
 394
 395
 396
 397
 398
 399
 400 # Line-based buffered connectionless FIFO channel.
 401 # Whatever is sent to it using send() is echoed back when using recv().
 402 package Channel::FIFO;
 403 use strict;
 404 use warnings;
 405
 406 # Constructor:
 407 #   my $chan = new Channel::FIFO();
 408 sub new($)
 409 {
 410         my ($class) = @_;
 411         my $you = {
 412                 buffer => []
 413         };
 414         return
 415                 bless $you, 'Channel::FIFO';
 416 }
 417
 418 sub join_commands($@)
 419 {
 420         my ($self, @data) = @_;
 421         return @data;
 422 }
 423
 424 sub send($$$)
 425 {
 426         my ($self, $line, $nothrottle) = @_;
 427         push @{$self->{buffer}}, $line;
 428 }
 429
 430 sub quote($$)
 431 {
 432         my ($self, $data) = @_;
 433         return $data;
 434 }
 435
 436 sub recv($)
 437 {
 438         my ($self) = @_;
 439         my $r = $self->{buffer};
 440         $self->{buffer} = [];
 441         return @$r;
 442 }
 443
 444 sub fds($)
 445 {
 446         my ($self) = @_;
 447         return ();
 448 }
 449
 450
 451
 452
 453
 454
 455
 456 # QW rcon protocol channel.
 457 # Wraps around a UDP based Connection and sends commands as rcon commands as
 458 # well as receives rcon replies. The quote and join_commands methods are using
 459 # DarkPlaces engine specific rcon protocol extensions.
 460 package Channel::QW;
 461 use strict;
 462 use warnings;
 463 use Digest::HMAC;
 464 use Digest::MD4;
 465
 466 # Constructor:
 467 #   my $chan = new Channel::QW($connection, "password");
 468 sub new($$$)
 469 {
 470         my ($class, $conn, $password, $secure, $timeout) = @_;
 471         my $you = {
 472                 connector => $conn,
 473                 password => $password,
 474                 recvbuf => "",
 475                 secure => $secure,
 476                 timeout => $timeout,
 477         };
 478         return
 479                 bless $you, 'Channel::QW';
 480 }
 481
 482 # Note: multiple commands in one rcon packet is a DarkPlaces extension.
 483 sub join_commands($@)
 484 {
 485         my ($self, @data) = @_;
 486         return join "\0", @data;
 487 }
 488
 489 sub send($$$)
 490 {
 491         my ($self, $line, $nothrottle) = @_;
 492         utf8::encode $line
 493                 if $color_utf8_enable;
 494         if($self->{secure} > 1)
 495         {
 496                 $self->{connector}->send("\377\377\377\377getchallenge");
 497                 my $c = $self->recvchallenge();
 498                 return 0 if not defined $c;
 499                 my $key = Digest::HMAC::hmac("$c $line", $self->{password}, \&Digest::MD4::md4);
 500                 return $self->{connector}->send("\377\377\377\377srcon HMAC-MD4 CHALLENGE $key $c $line");
 501         }
 502         elsif($self->{secure})
 503         {
 504                 my $t = sprintf "%ld.%06d", time(), int rand 1000000;
 505                 my $key = Digest::HMAC::hmac("$t $line", $self->{password}, \&Digest::MD4::md4);
 506                 return $self->{connector}->send("\377\377\377\377srcon HMAC-MD4 TIME $key $t $line");
 507         }
 508         else
 509         {
 510                 return $self->{connector}->send("\377\377\377\377rcon $self->{password} $line");
 511         }
 512 }
 513
 514 # Note: backslash and quotation mark escaping is a DarkPlaces extension.
 515 sub quote($$)
 516 {
 517         my ($self, $data) = @_;
 518         $data =~ s/[\000-\037]//g;
 519         $data =~ s/([\\"])/\\$1/g;
 520         $data =~ s/\$/\$\$/g;
 521         return $data;
 522 }
 523
 524 sub recvchallenge($)
 525 {
 526         my ($self) = @_;
 527
 528         my $sel = IO::Select->new($self->fds());
 529         my $endtime_max = Time::HiRes::time() + $self->{timeout};
 530         my $endtime = $endtime_max;
 531
 532         while((my $dt = $endtime - Time::HiRes::time()) > 0)
 533         {
 534                 if($sel->can_read($dt))
 535                 {
 536                         for(;;)
 537                         {
 538                                 my $s = $self->{connector}->recv();
 539                                 die "read error\n"
 540                                         if not defined $s;
 541                                 length $s
 542                                         or last;
 543                                 if($s =~ /^\377\377\377\377challenge (.*?)(?:$|\0)/s)
 544                                 {
 545                                         return $1;
 546                                 }
 547                                 next
 548                                         if $s !~ /^\377\377\377\377n(.*)$/s;
 549                                 $self->{recvbuf} .= $1;
 550                         }
 551                 }
 552         }
 553         return undef;
 554 }
 555
 556 sub recv($)
 557 {
 558         my ($self) = @_;
 559         for(;;)
 560         {
 561                 my $s = $self->{connector}->recv();
 562                 die "read error\n"
 563                         if not defined $s;
 564                 length $s
 565                         or last;
 566                 next
 567                         if $s !~ /^\377\377\377\377n(.*)$/s;
 568                 $self->{recvbuf} .= $1;
 569         }
 570         my @out = ();
 571         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 572         {
 573                 my $s = $1;
 574                 utf8::decode $s
 575                         if $color_utf8_enable;
 576                 push @out, $s;
 577         }
 578         return @out;
 579 }
 580
 581 sub fds($)
 582 {
 583         my ($self) = @_;
 584         return $self->{connector}->fds();
 585 }
 586
 587
 588
 589
 590
 591
 592
 593 # Line based protocol channel.
 594 # Wraps around a TCP based Connection and sends commands as text lines
 595 # (separated by CRLF). When reading responses from the Connection, any type of
 596 # line ending is accepted.
 597 # A flood control mechanism is implemented.
 598 package Channel::Line;
 599 use strict;
 600 use warnings;
 601 use Time::HiRes qw/time/;
 602
 603 # Constructor:
 604 #   my $chan = new Channel::Line($connection);
 605 sub new($$)
 606 {
 607         my ($class, $conn) = @_;
 608         my $you = {
 609                 connector => $conn,
 610                 recvbuf => "",
 611                 capacity => undef,
 612                 linepersec => undef,
 613                 maxlines => undef,
 614                 lastsend => time()
 615         };
 616         return
 617                 bless $you, 'Channel::Line';
 618 }
 619
 620 sub join_commands($@)
 621 {
 622         my ($self, @data) = @_;
 623         return @data;
 624 }
 625
 626 # Sets new flood control parameters:
 627 #   $chan->throttle(maximum lines per second, maximum burst length allowed to
 628 #     exceed the lines per second limit);
 629 #   RFC 1459 describes these parameters to be 0.5 and 5 for the IRC protocol.
 630 #   If the $nothrottle flag is set while sending, the line is sent anyway even
 631 #   if flooding would take place.
 632 sub throttle($$$)
 633 {
 634         my ($self, $linepersec, $maxlines) = @_;
 635         $self->{linepersec} = $linepersec;
 636         $self->{maxlines} = $maxlines;
 637         $self->{capacity} = $maxlines;
 638 }
 639
 640 sub send($$$)
 641 {
 642         my ($self, $line, $nothrottle) = @_;
 643         utf8::encode $line
 644                 if $color_utf8_enable;
 645         my $t = time();
 646         if(defined $self->{capacity})
 647         {
 648                 $self->{capacity} += ($t - $self->{lastsend}) * $self->{linepersec};
 649                 $self->{lastsend} = $t;
 650                 $self->{capacity} = $self->{maxlines}
 651                         if $self->{capacity} > $self->{maxlines};
 652                 if(!$nothrottle)
 653                 {
 654                         return -1
 655                                 if $self->{capacity} < 0;
 656                 }
 657                 $self->{capacity} -= 1;
 658         }
 659         $line =~ s/\r|\n//g;
 660         return $self->{connector}->send("$line\r\n");
 661 }
 662
 663 sub quote($$)
 664 {
 665         my ($self, $data) = @_;
 666         $data =~ s/\r\n?/\n/g;
 667         $data =~ s/\n/*/g;
 668         return $data;
 669 }
 670
 671 sub recv($)
 672 {
 673         my ($self) = @_;
 674         for(;;)
 675         {
 676                 my $s = $self->{connector}->recv();
 677                 die "read error\n"
 678                         if not defined $s;
 679                 length $s
 680                         or last;
 681                 $self->{recvbuf} .= $s;
 682         }
 683         my @out = ();
 684         while($self->{recvbuf} =~ s/^(.*?)(?:\r\n?|\n)//)
 685         {
 686                 my $s = $1;
 687                 utf8::decode $s
 688                         if $color_utf8_enable;
 689                 push @out, $s;
 690         }
 691         return @out;
 692 }
 693
 694 sub fds($)
 695 {
 696         my ($self) = @_;
 697         return $self->{connector}->fds();
 698 }
 699
 700
 701
 702
 703
 704
 705 # main program... a gateway between IRC and DarkPlaces servers
 706 package main;
 707
 708 use strict;
 709 use warnings;
 710 use IO::Select;
 711 use Digest::SHA;
 712 use Digest::HMAC;
 713 use Time::HiRes qw/time/;
 714
 715 our @handlers = (); # list of [channel, expression, sub to handle result]
 716 our @tasks = (); # list of [time, sub]
 717 our %channels = ();
 718 our %store = (
 719         irc_nick => "",
 720         playernick_byid_0 => "(console)",
 721 );
 722 our %config = (
 723         irc_server => undef,
 724         irc_nick => undef,
 725         irc_nick_alternates => "",
 726         irc_user => undef,
 727         irc_channel => undef,
 728         irc_ping_delay => 120,
 729         irc_trigger => "",
 730
 731         irc_nickserv_password => "",
 732         irc_nickserv_identify => 'PRIVMSG NickServ :IDENTIFY %2$s',
 733         irc_nickserv_ghost => 'PRIVMSG NickServ :GHOST %1$s %2$s',
 734         irc_nickserv_ghost_attempts => 3,
 735
 736         irc_quakenet_authname => "",
 737         irc_quakenet_password => "",
 738         irc_quakenet_authusers => "",
 739         irc_quakenet_getchallenge => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGE',
 740         irc_quakenet_challengeauth => 'PRIVMSG Q@CServe.quakenet.org :CHALLENGEAUTH',
 741         irc_quakenet_challengeprefix => ':Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :CHALLENGE',
 742
 743         irc_announce_slotsfree => 1,
 744         irc_announce_mapchange => 'always',
 745
 746         dp_server => undef,
 747         dp_secure => 1,
 748         dp_secure_challengetimeout => 1,
 749         dp_listen => "",
 750         dp_password => undef,
 751         dp_status_delay => 30,
 752         dp_server_from_wan => "",
 753         dp_listen_from_server => "",
 754         dp_utf8_enable => $color_utf8_enable,
 755         irc_local => "",
 756
 757         irc_admin_password => "",
 758         irc_admin_timeout => 3600,
 759         irc_admin_quote_re => "",
 760
 761         irc_reconnect_delay => 300,
 762         irc_commands => "",
 763
 764         plugins => "",
 765 );
 766
 767 sub pickip($$)
 768 {
 769         my ($wan, $lan) = @_;
 770         # $wan shall override $lan
 771         return $lan
 772                 if not length $wan;
 773         return $wan
 774                 if $wan =~ /:\d+$/; # full override
 775         return $wan
 776                 if $lan !~ /:(\d+)$/;
 777         return "$wan:$1";
 778 }
 779
 780
 781
 782 # Xonotic specific parsing of some server messages
 783
 784 sub xon_slotsstring()
 785 {
 786         my $slotsstr = "";
 787         if(defined $store{slots_max})
 788         {
 789                 my $slots = $store{slots_max} - $store{slots_active};
 790                 my $slots_s = ($slots == 1) ? '' : 's';
 791                 $slotsstr = " ($slots free slot$slots_s)";
 792                 my $s = pickip($config{dp_server_from_wan}, $config{dp_server});
 793                 $slotsstr .= "; join now: \002xonotic +connect $s"
 794                         if $slots >= 1 and not $store{lms_blocked};
 795         }
 796         return $slotsstr;
 797 }
 798
 799
 800
 801 # Do we have a config file? If yes, read and parse it (syntax: key = value
 802 # pairs, separated by newlines), if not, complain.
 803 die "Usage: $0 configfile\n"
 804         unless @ARGV == 1;
 805
 806 open my $fh, "<", $ARGV[0]
 807         or die "open $ARGV[0]: $!";
 808 while(<$fh>)
 809 {
 810         chomp;
 811         /^#/ and next;
 812         /^(.*?)\s*=(?:\s*(.*))?$/ or next;
 813         warn "Undefined config item: $1"
 814                 unless exists $config{$1};
 815         $config{$1} = defined $2 ? $2 : "";
 816 }
 817 close $fh;
 818 my @missing = grep { !defined $config{$_} } keys %config;
 819 die "The following config items are missing: @missing"
 820         if @missing;
 821
 822 $color_utf8_enable = $config{dp_utf8_enable};
 823
 824
 825 # Create a channel for error messages and other internal status messages...
 826
 827 $channels{system} = new Channel::FIFO();
 828
 829 # for example, quit messages caused by signals (if SIGTERM or SIGINT is first
 830 # received, try to shut down cleanly, and if such a signal is received a second
 831 # time, just exit)
 832 my $quitting = 0;
 833 $SIG{INT} = sub {
 834         exit 1 if $quitting++;
 835         $channels{system}->send("quit SIGINT");
 836 };
 837 $SIG{TERM} = sub {
 838         exit 1 if $quitting++;
 839         $channels{system}->send("quit SIGTERM");
 840 };
 841
 842
 843
 844 # Create the two channels to gateway between...
 845
 846 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => $config{irc_local} => $config{irc_server} => 6667));
 847 $channels{dp} = new Channel::QW(my $dpsock = new Connection::Socket(udp => $config{dp_listen} => $config{dp_server} => 26000), $config{dp_password}, $config{dp_secure}, $config{dp_secure_challengetimeout});
 848 $config{dp_listen} = $dpsock->sockname();
 849 $config{dp_server} = $dpsock->peername();
 850 print "Listening on $config{dp_listen}\n";
 851
 852 $channels{irc}->throttle(0.5, 5);
 853
 854
 855 # Utility routine to write to a channel by name, also outputting what's been written and some status
 856 sub out($$@)
 857 {
 858         my $chanstr = shift;
 859         my $nothrottle = shift;
 860         my $chan = $channels{$chanstr};
 861         if(!$chan)
 862         {
 863                 print "UNDEFINED: $chanstr, ignoring message\n";
 864                 return;
 865         }
 866         @_ = $chan->join_commands(@_);
 867         for(@_)
 868         {
 869                 my $result = $chan->send($_, $nothrottle);
 870                 if($result > 0)
 871                 {
 872                         print "           $chanstr << $_\n";
 873                 }
 874                 elsif($result < 0)
 875                 {
 876                         print "FLOOD:     $chanstr << $_\n";
 877                 }
 878                 else
 879                 {
 880                         print "ERROR:     $chanstr << $_\n";
 881                         $channels{system}->send("error $chanstr", 0);
 882                 }
 883         }
 884 }
 885
 886
 887
 888 # Schedule a task for later execution by the main loop; usage: schedule sub {
 889 # task... }, $time; When a scheduled task is run, a reference to the task's own
 890 # sub is passed as first argument; that way, the task is able to re-schedule
 891 # itself so it gets periodically executed.
 892 sub schedule($$)
 893 {
 894         my ($sub, $time) = @_;
 895         push @tasks, [time() + $time, $sub];
 896 }
 897
 898 # On IRC error, delete some data store variables of the connection, and
 899 # reconnect to the IRC server soon (but only if someone is actually playing)
 900 sub irc_error()
 901 {
 902         # prevent multiple instances of this timer
 903         return if $store{irc_error_active};
 904         $store{irc_error_active} = 1;
 905
 906         delete $channels{irc};
 907         schedule sub {
 908                 my ($timer) = @_;
 909                 if(!defined $store{slots_active})
 910                 {
 911                         # DP is not running, then delay IRC reconnecting
 912                         #use Data::Dumper; print Dumper \$timer;
 913                         schedule $timer => 1;
 914                         return;
 915                         # this will keep irc_error_active
 916                 }
 917                 $channels{irc} = new Channel::Line(new Connection::Socket(tcp => $config{irc_local} => $config{irc_server} => 6667));
 918                 delete $store{$_} for grep { /^irc_/ } keys %store;
 919                 $store{irc_nick} = "";
 920                 schedule sub {
 921                         my ($timer) = @_;
 922                         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp';
 923                         $store{status_waiting} = -1;
 924                 } => 1;
 925                 # this will clear irc_error_active
 926         } => $config{irc_reconnect_delay};
 927         return 0;
 928 }
 929
 930 sub uniq(@)
 931 {
 932         my @out = ();
 933         my %found = ();
 934         for(@_)
 935         {
 936                 next if $found{$_}++;
 937                 push @out, $_;
 938         }
 939         return @out;
 940 }
 941
 942 # IRC joining (if this is called as response to a nick name collision, $is433 is set);
 943 # among other stuff, it performs NickServ or Quakenet authentication. This is to be called
 944 # until the channel has been joined for every message that may be "interesting" (basically,
 945 # IRC 001 hello messages, 443 nick collision messages and some notices by services).
 946 sub irc_joinstage($)
 947 {
 948         my($is433) = @_;
 949
 950         return 0
 951                 if $store{irc_joined_channel};
 952
 953                 #use Data::Dumper; print Dumper \%store;
 954
 955         if($is433)
 956         {
 957                 if(length $store{irc_nick})
 958                 {
 959                         # we already have another nick, but couldn't change to the new one
 960                         # try ghosting and then get the nick again
 961                         if(length $config{irc_nickserv_password})
 962                         {
 963                                 if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
 964                                 {
 965                                         $store{irc_nick_requested} = $config{irc_nick};
 966                                         out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
 967                                         schedule sub {
 968                                                 out irc => 1, "NICK $config{irc_nick}";
 969                                         } => 1;
 970                                         return; # we'll get here again for the NICK success message, or for a 433 failure
 971                                 }
 972                                 # otherwise, we failed to ghost and will continue with the wrong
 973                                 # nick... also, no need to try to identify here
 974                         }
 975                         # otherwise, we can't handle this and will continue with our wrong nick
 976                 }
 977                 else
 978                 {
 979                         # we failed to get an initial nickname
 980                         # change ours a bit and try again
 981
 982                         my @alternates = uniq ($config{irc_nick}, grep { $_ ne "" } split /\s+/, $config{irc_nick_alternates});
 983                         my $nextnick = undef;
 984                         for(0..@alternates-2)
 985                         {
 986                                 if($store{irc_nick_requested} eq $alternates[$_])
 987                                 {
 988                                         $nextnick = $alternates[$_+1];
 989                                 }
 990                         }
 991                         if($store{irc_nick_requested} eq $alternates[@alternates-1]) # this will only happen once
 992                         {
 993                                 $store{irc_nick_requested} = $alternates[0];
 994                                 # but don't set nextnick, so we edit it
 995                         }
 996                         if(defined $nextnick)
 997                         {
 998                                 $store{irc_nick_requested} = $nextnick;
 999                         }
1000                         else
1001                         {
1002                                 for(;;)
1003                                 {
1004                                         if(length $store{irc_nick_requested} < 9)
1005                                         {
1006                                                 $store{irc_nick_requested} .= '_';
1007                                         }
1008                                         else
1009                                         {
1010                                                 substr $store{irc_nick_requested}, int(rand length $store{irc_nick_requested}), 1, chr(97 + int rand 26);
1011                                         }
1012                                         last unless grep { $_ eq $store{irc_nick_requested} } @alternates;
1013                                 }
1014                         }
1015                         out irc => 1, "NICK $store{irc_nick_requested}";
1016                         return; # when it fails, we'll get here again, and when it succeeds, we will continue
1017                 }
1018         }
1019
1020         # we got a 001 or a NICK message, so $store{irc_nick} has been updated
1021         if(length $config{irc_nickserv_password})
1022         {
1023                 if($store{irc_nick} eq $config{irc_nick})
1024                 {
1025                         # identify
1026                         out irc => 1, sprintf($config{irc_nickserv_identify}, $config{irc_nick}, $config{irc_nickserv_password});
1027                 }
1028                 else
1029                 {
1030                         # ghost
1031                         if(++$store{irc_nickserv_ghost_attempts} <= $config{irc_nickserv_ghost_attempts})
1032                         {
1033                                 $store{irc_nick_requested} = $config{irc_nick};
1034                                 out irc => 1, sprintf($config{irc_nickserv_ghost}, $config{irc_nick}, $config{irc_nickserv_password});
1035                                 schedule sub {
1036                                         out irc => 1, "NICK $config{irc_nick}";
1037                                 } => 1;
1038                                 return; # we'll get here again for the NICK success message, or for a 433 failure
1039                         }
1040                         # otherwise, we failed to ghost and will continue with the wrong
1041                         # nick... also, no need to try to identify here
1042                 }
1043         }
1044
1045         # we are on Quakenet. Try to authenticate.
1046         if(length $config{irc_quakenet_password} and length $config{irc_quakenet_authname})
1047         {
1048                 if(defined $store{irc_quakenet_challenge})
1049                 {
1050                         if($store{irc_quakenet_challenge} =~ /^([0-9a-f]*)\b.*\bHMAC-SHA-256\b/)
1051                         {
1052                                 my $challenge = $1;
1053                                 my $hash1 = Digest::SHA::sha256_hex(substr $config{irc_quakenet_password}, 0, 10);
1054                                 my $key = Digest::SHA::sha256_hex("@{[lc $config{irc_quakenet_authname}]}:$hash1");
1055                                 my $digest = Digest::HMAC::hmac_hex($challenge, $key, \&Digest::SHA::sha256);
1056                                 out irc => 1, "$config{irc_quakenet_challengeauth} $config{irc_quakenet_authname} $digest HMAC-SHA-256";
1057                         }
1058                 }
1059                 else
1060                 {
1061                         out irc => 1, $config{irc_quakenet_getchallenge};
1062                         return;
1063                         # we get here again when Q asks us
1064                 }
1065         }
1066
1067         for(split / *; */, $store{irc_commands})
1068         {
1069                 s/\$nick/$store{irc_nick}/g;
1070                 out irc => 1, $_;
1071         }
1072
1073         # if we get here, we are on IRC
1074         $store{irc_joined_channel} = 1;
1075         schedule sub {
1076                 # wait 1 sec to let stuff calm down
1077                 out irc => 1, "JOIN $config{irc_channel}";
1078         } => 1;
1079         return 0;
1080 }
1081
1082 my $RE_FAIL = qr/$ $/;
1083 my $RE_SUCCEED = qr//;
1084 sub cond($)
1085 {
1086         return $_[0] ? $RE_FAIL : $RE_SUCCEED;
1087 }
1088
1089
1090 # List of all handlers on the various sockets. Additional handlers can be added by a plugin.
1091 @handlers = (
1092         # detect a server restart and set it up again
1093         [ dp => q{ *(?:Warning: Could not expand \$|Unknown command ")(?:rcon2irc_[a-z0-9_]*)[" ]*} => sub {
1094                 out dp => 0,
1095                         'alias rcon2irc_eval "$*"',
1096                         'log_dest_udp',
1097                         'sv_logscores_console 0',
1098                         'sv_logscores_bots 1',
1099                         'sv_eventlog 1',
1100                         'sv_eventlog_console 1',
1101                         'alias rcon2irc_say_as "set say_as_restorenick \"$sv_adminnick\"; sv_adminnick \"$1^3\"; say \"^7$2\"; rcon2irc_say_as_restore"',
1102                         'alias rcon2irc_say_as_restore "set sv_adminnick \"$say_as_restorenick\""',
1103                         'alias rcon2irc_quit "echo \"quitting rcon2irc $1: log_dest_udp is $log_dest_udp\""'; # note: \\\\\\" ->perl \\\" ->console \"
1104                 return 0;
1105         } ],
1106
1107         # detect missing entry in log_dest_udp and fix it
1108         [ dp => q{"log_dest_udp" is "([^"]*)" \["[^"]*"\]} => sub {
1109                 my ($dest) = @_;
1110                 my @dests = split ' ', $dest;
1111                 return 0 if grep { $_ eq pickip($config{dp_listen_from_server}, $config{dp_listen}) } @dests;
1112                 out dp => 0, 'log_dest_udp "' . join(" ", @dests, pickip($config{dp_listen_from_server}, $config{dp_listen})) . '"';
1113                 return 0;
1114         } ],
1115
1116         # retrieve list of banned hosts
1117         [ dp => q{#(\d+): (\S+) is still banned for (\S+) seconds} => sub {
1118                 return 0 unless $store{status_waiting} < 0;
1119                 my ($id, $ip, $time) = @_;
1120                 $store{bans_new} = [] if $id == 0;
1121                 $store{bans_new}[$id] = { ip => $ip, 'time' => $time };
1122                 return 0;
1123         } ],
1124
1125         # retrieve hostname from status replies
1126         [ dp => q{host:     (.*)} => sub {
1127                 return 0 unless $store{status_waiting} < 0;
1128                 my ($name) = @_;
1129                 $store{dp_hostname} = $name;
1130                 $store{bans} = $store{bans_new};
1131                 return 0;
1132         } ],
1133
1134         # retrieve version from status replies
1135         [ dp => q{version:  (.*)} => sub {
1136                 return 0 unless $store{status_waiting} < 0;
1137                 my ($version) = @_;
1138                 $store{dp_version} = $version;
1139                 return 0;
1140         } ],
1141
1142         # retrieve player names
1143         [ dp => q{players:  (\d+) active \((\d+) max\)} => sub {
1144                 return 0 unless $store{status_waiting} < 0;
1145                 my ($active, $max) = @_;
1146                 my $full = ($active >= $max);
1147                 $store{slots_max} = $max;
1148                 $store{slots_active} = $active;
1149                 $store{status_waiting} = $active;
1150                 $store{playerslots_active_new} = [];
1151                 if($store{status_waiting} == 0)
1152                 {
1153                         $store{playerslots_active} = $store{playerslots_active_new};
1154                 }
1155                 if($full != ($store{slots_full} || 0))
1156                 {
1157                         $store{slots_full} = $full;
1158                         return 0 if $store{lms_blocked};
1159                         return 0 if !$config{irc_announce_slotsfree};
1160                         if($full)
1161                         {
1162                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION is full!\001";
1163                         }
1164                         else
1165                         {
1166                                 my $slotsstr = xon_slotsstring();
1167                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can be joined again$slotsstr!\001";
1168                         }
1169                 }
1170                 return 0;
1171         } ],
1172
1173         # retrieve player names
1174         [ dp => q{\^\d(\S+)\s+(\d+)\s+(\d+)\s+(\S+)\s+(-?\d+)\s+\#(\d+)\s+\^\d(.*)} => sub {
1175                 return 0 unless $store{status_waiting} > 0;
1176                 my ($ip, $pl, $ping, $time, $frags, $no, $name) = ($1, $2, $3, $4, $5, $6, $7);
1177                 $store{"playerslot_$no"} = { ip => $ip, pl => $pl, ping => $ping, 'time' => $time, frags => $frags, no => $no, name => $name };
1178                 push @{$store{playerslots_active_new}}, $no;
1179                 if(--$store{status_waiting} == 0)
1180                 {
1181                         $store{playerslots_active} = $store{playerslots_active_new};
1182                 }
1183                 return 0;
1184         } ],
1185
1186         # IRC admin commands
1187         [ irc => q{:(([^! ]*)![^ ]*) (?i:PRIVMSG) [^&#%]\S* :(.*)} => sub {
1188                 return 0 unless ($config{irc_admin_password} ne '' || $store{irc_quakenet_users});
1189
1190                 my ($hostmask, $nick, $command) = @_;
1191                 my $dpnick = color_dpfix $nick;
1192
1193                 if($command eq "login $config{irc_admin_password}")
1194                 {
1195                         $store{logins}{$hostmask} = time() + $config{irc_admin_timeout};
1196                         out irc => 0, "PRIVMSG $nick :my wish is your command";
1197                         return -1;
1198                 }
1199
1200                 if($command =~ /^login /)
1201                 {
1202                         out irc => 0, "PRIVMSG $nick :invalid password";
1203                         return -1;
1204                 }
1205
1206                 if(($store{logins}{$hostmask} || 0) < time())
1207                 {
1208                         out irc => 0, "PRIVMSG $nick :authentication required";
1209                         return -1;
1210                 }
1211
1212                 if($command =~ /^status(?: (.*))?$/)
1213                 {
1214                         my ($match) = $1;
1215                         my $found = 0;
1216                         my $foundany = 0;
1217                         for my $slot(@{$store{playerslots_active} || []})
1218                         {
1219                                 my $s = $store{"playerslot_$slot"};
1220                                 next unless $s;
1221                                 if(not defined $match or index(color_dp2none($s->{name}), $match) >= 0)
1222                                 {
1223                                         out irc => 0, sprintf 'PRIVMSG %s :%-21s %2i %4i %8s %4i #%-3u %s', $nick, $s->{ip}, $s->{pl}, $s->{ping}, $s->{time}, $s->{frags}, $slot, color_dp2irc $s->{name};
1224                                         ++$found;
1225                                 }
1226                                 ++$foundany;
1227                         }
1228                         if(!$found)
1229                         {
1230                                 if(!$foundany)
1231                                 {
1232                                         out irc => 0, "PRIVMSG $nick :the server is empty";
1233                                 }
1234                                 else
1235                                 {
1236                                         out irc => 0, "PRIVMSG $nick :no nicknames match";
1237                                 }
1238                         }
1239                         return 0;
1240                 }
1241
1242                 if($command =~ /^kick # (\d+) (.*)$/)
1243                 {
1244                         my ($id, $reason) = ($1, $2);
1245                         my $dpreason = color_irc2dp $reason;
1246                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1247                         $dpreason =~ s/(["\\])/\\$1/g;
1248                         out dp => 0, "kick # $id $dpreason";
1249                         my $slotnik = "playerslot_$id";
1250                         out irc => 0, "PRIVMSG $nick :kicked #$id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip}) ($reason)";
1251                         return 0;
1252                 }
1253
1254                 if($command =~ /^kickban # (\d+) (\d+) (\d+) (.*)$/)
1255                 {
1256                         my ($id, $bantime, $mask, $reason) = ($1, $2, $3, $4);
1257                         my $dpreason = color_irc2dp $reason;
1258                         $dpreason =~ s/^(~?)(.*)/$1irc $dpnick: $2/g;
1259                         $dpreason =~ s/(["\\])/\\$1/g;
1260                         out dp => 0, "kickban # $id $bantime $mask $dpreason";
1261                         my $slotnik = "playerslot_$id";
1262                         out irc => 0, "PRIVMSG $nick :kickbanned #$id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip}), netmask $mask, for $bantime seconds ($reason)";
1263                         return 0;
1264                 }
1265
1266                 if($command eq "bans")
1267                 {
1268                         my $banlist =
1269                                 join ", ",
1270                                 map { "$_ ($store{bans}[$_]{ip}, $store{bans}[$_]{time}s)" }
1271                                 0..@{$store{bans} || []}-1;
1272                         $banlist = "no bans"
1273                                 if $banlist eq "";
1274                         out irc => 0, "PRIVMSG $nick :$banlist";
1275                         return 0;
1276                 }
1277
1278                 if($command =~ /^unban (\d+)$/)
1279                 {
1280                         my ($id) = ($1);
1281                         out dp => 0, "unban $id";
1282                         out irc => 0, "PRIVMSG $nick :removed ban $id ($store{bans}[$id]{ip})";
1283                         return 0;
1284                 }
1285
1286                 if($command =~ /^mute (\d+)$/)
1287                 {
1288                         my $id = $1;
1289                         out dp => 0, "mute $id";
1290                         my $slotnik = "playerslot_$id";
1291                         out irc => 0, "PRIVMSG $nick :muted $id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip})";
1292                         return 0;
1293                 }
1294
1295                 if($command =~ /^unmute (\d+)$/)
1296                 {
1297                         my ($id) = ($1);
1298                         out dp => 0, "unmute $id";
1299                         my $slotnik = "playerslot_$id";
1300                         out irc => 0, "PRIVMSG $nick :unmuted $id (@{[color_dp2irc $store{$slotnik}{name}]}\017 @ $store{$slotnik}{ip})";
1301                         return 0;
1302                 }
1303
1304                 if($command =~ /^quote (.*)$/)
1305                 {
1306                         my ($cmd) = ($1);
1307                         if($cmd =~ /^(??{$config{irc_admin_quote_re}})$/si)
1308                         {
1309                                 out irc => 0, $cmd;
1310                                 out irc => 0, "PRIVMSG $nick :executed your command";
1311                         }
1312                         else
1313                         {
1314                                 out irc => 0, "PRIVMSG $nick :permission denied";
1315                         }
1316                         return 0;
1317                 }
1318
1319                 out irc => 0, "PRIVMSG $nick :unknown command (supported: status [substring], kick # id reason, kickban # id bantime mask reason, bans, unban banid, mute id, unmute id)";
1320
1321                 return -1;
1322         } ],
1323
1324         # LMS: detect "no more lives" message
1325         [ dp => q{\^4.*\^4 has no more lives left} => sub {
1326                 if(!$store{lms_blocked})
1327                 {
1328                         $store{lms_blocked} = 1;
1329                         if(!$store{slots_full})
1330                         {
1331                                 schedule sub {
1332                                         if($store{lms_blocked})
1333                                         {
1334                                                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION can't be joined until next round (a player has no more lives left)\001";
1335                                         }
1336                                 } => 1;
1337                         }
1338                 }
1339         } ],
1340
1341         # detect IRC errors and reconnect
1342         [ irc => q{ERROR .*} => \&irc_error ],
1343         [ irc => q{:[^ ]* 404 .*} => \&irc_error ], # cannot send to channel
1344         [ system => q{error irc} => \&irc_error ],
1345
1346         # IRC nick in use
1347         [ irc => q{:[^ ]* 433 .*} => sub {
1348                 return irc_joinstage(433);
1349         } ],
1350
1351         # IRC welcome
1352         [ irc => q{:[^ ]* 001 .*} => sub {
1353                 $store{irc_seen_welcome} = 1;
1354                 $store{irc_nick} = $store{irc_nick_requested};
1355
1356                 # If users for quakenet are listed, parse them into a hash and schedule a sub to query information
1357                 if ($config{irc_quakenet_authusers} ne '') {
1358                         $store{irc_quakenet_users} = { map { $_ => 1 } split / /, $config{irc_quakenet_authusers} };
1359
1360                         schedule sub {
1361                                 my ($timer) = @_;
1362                                 out irc => 0, "PRIVMSG Q :users " . $config{irc_channel};
1363                                 schedule $timer => 300;;
1364                         } => 1;
1365                 }
1366
1367                 return irc_joinstage(0);
1368         } ],
1369
1370         # IRC my nickname changed
1371         [ irc => q{:(?i:(??{$store{irc_nick}}))![^ ]* (?i:NICK) :(.*)} => sub {
1372                 my ($n) = @_;
1373                 $store{irc_nick} = $n;
1374                 return irc_joinstage(0);
1375         } ],
1376
1377         # Quakenet: challenge from Q
1378         [ irc => q{(??{$config{irc_quakenet_challengeprefix}}) (.*)} => sub {
1379                 $store{irc_quakenet_challenge} = $1;
1380                 return irc_joinstage(0);
1381         } ],
1382
1383         # Catch joins of people in a channel the bot is in and catch our own joins of a channel,
1384         # detect channel join message and note hostname length to get the maximum allowed line length
1385         [ irc => q{:(([^! ]*)![^ ]*) JOIN (#.+)} => sub {
1386                 my ($hostmask, $nick, $chan) = @_;
1387
1388                 if ($nick eq $store{irc_nick}) {
1389                         $store{irc_maxlen} = 510 - length($hostmask);
1390                         if($store{irc_joined_channel} == 1)
1391                         {
1392                                 $store{irc_joined_channel} = 2;
1393                         }
1394                         print "* detected maximum line length for channel messages: $store{irc_maxlen}\n";
1395                 }
1396
1397                 return 0 unless ($store{irc_quakenet_users});
1398
1399                 if ($nick eq $store{irc_nick}) {
1400                         out irc => 0, "PRIVMSG Q :users $chan"; # get auths for all users
1401                 } else {
1402                         $store{quakenet_hosts}->{$nick} = $hostmask;
1403                         out irc => 0, "PRIVMSG Q :whois $nick"; # get auth for single user
1404                 }
1405
1406                 return 0;
1407         } ],
1408
1409         # Catch response of users request
1410         [ irc => q{:Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :[@\+\s]?(\S+)\s+(\S+)\s*(\S*)\s*\((.*)\)} => sub {
1411                 my ($nick, $username, $flags, $host) = @_;
1412                 return 0 unless ($store{irc_quakenet_users});
1413
1414                 $store{logins}{"$nick!$host"} = time() + 600 if ($store{irc_quakenet_users}->{$username});
1415
1416                 return 0;
1417         } ],
1418
1419         # Catch response of whois request
1420         [ irc => q{:Q!TheQBot@CServe.quakenet.org NOTICE [^:]+ :-Information for user (.*) \(using account (.*)\):} => sub {
1421                 my ($nick, $username) = @_;
1422                 return 0 unless ($store{irc_quakenet_users});
1423
1424                 if ($store{irc_quakenet_users}->{$username}) {
1425                         my $hostmask = $store{quakenet_hosts}->{$nick};
1426                         $store{logins}{$hostmask} = time() + 600;
1427                 }
1428
1429                 return 0;
1430         } ],
1431
1432         # shut down everything on SIGINT
1433         [ system => q{quit (.*)} => sub {
1434                 my ($cause) = @_;
1435                 out irc => 1, "QUIT :$cause";
1436                 $store{quitcookie} = int rand 1000000000;
1437                 out dp => 0, "rcon2irc_quit $store{quitcookie}";
1438         } ],
1439
1440         # remove myself from the log destinations and exit everything
1441         [ dp => q{quitting rcon2irc (??{$store{quitcookie}}): log_dest_udp is (.*) *} => sub {
1442                 my ($dest) = @_;
1443                 my @dests = grep { $_ ne pickip($config{dp_listen_from_server}, $config{dp_listen}) } split ' ', $dest;
1444                 out dp => 0, 'log_dest_udp "' . join(" ", @dests) . '"';
1445                 exit 0;
1446                 return 0;
1447         } ],
1448
1449         # IRC PING
1450         [ irc => q{PING (.*)} => sub {
1451                 my ($data) = @_;
1452                 out irc => 1, "PONG $data";
1453                 return 1;
1454         } ],
1455
1456         # IRC PONG
1457         [ irc => q{:[^ ]* PONG .* :(.*)} => sub {
1458                 my ($data) = @_;
1459                 return 0
1460                         if not defined $store{irc_pingtime};
1461                 return 0
1462                         if $data ne $store{irc_pingtime};
1463                 print "* measured IRC line delay: @{[time() - $store{irc_pingtime}]}\n";
1464                 undef $store{irc_pingtime};
1465                 return 0;
1466         } ],
1467
1468         # chat: Xonotic server -> IRC channel
1469         [ dp => q{\001(.*?)\^7: (.*)} => sub {
1470                 my ($nick, $message) = map { color_dp2irc $_ } @_;
1471                 out irc => 0, "PRIVMSG $config{irc_channel} :<$nick\017> $message";
1472                 return 0;
1473         } ],
1474
1475         # chat: Xonotic server -> IRC channel, nick set
1476         [ dp => q{:join:(\d+):(\d+):([^:]*):(.*)} => sub {
1477                 my ($id, $slot, $ip, $nick) = @_;
1478                 $store{"playernickraw_byid_$id"} = $nick;
1479                 $nick = color_dp2irc $nick;
1480                 $store{"playernick_byid_$id"} = $nick;
1481                 $store{"playerip_byid_$id"} = $ip;
1482                 $store{"playerslot_byid_$id"} = $slot;
1483                 $store{"playerid_byslot_$slot"} = $id;
1484                 return 0;
1485         } ],
1486
1487         # chat: Xonotic server -> IRC channel, nick change/set
1488         [ dp => q{:name:(\d+):(.*)} => sub {
1489                 my ($id, $nick) = @_;
1490                 $store{"playernickraw_byid_$id"} = $nick;
1491                 $nick = color_dp2irc $nick;
1492                 my $oldnick = $store{"playernick_byid_$id"};
1493                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 is now known as $nick";
1494                 $store{"playernick_byid_$id"} = $nick;
1495                 return 0;
1496         } ],
1497
1498         # chat: Xonotic server -> IRC channel, vote call
1499         [ dp => q{:vote:vcall:(\d+):(.*)} => sub {
1500                 my ($id, $command) = @_;
1501                 $command = color_dp2irc $command;
1502                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1503                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 calls a vote for \"$command\017\"";
1504                 return 0;
1505         } ],
1506
1507         # chat: Xonotic server -> IRC channel, vote stop
1508         [ dp => q{:vote:vstop:(\d+)} => sub {
1509                 my ($id) = @_;
1510                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1511                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 stopped the vote";
1512                 return 0;
1513         } ],
1514
1515         # chat: Xonotic server -> IRC channel, master login
1516         [ dp => q{:vote:vlogin:(\d+)} => sub {
1517                 my ($id) = @_;
1518                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1519                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 logged in as master";
1520                 return 0;
1521         } ],
1522
1523         # chat: Xonotic server -> IRC channel, master do
1524         [ dp => q{:vote:vdo:(\d+):(.*)} => sub {
1525                 my ($id, $command) = @_;
1526                 $command = color_dp2irc $command;
1527                 my $oldnick = $id ? $store{"playernick_byid_$id"} : "(console)";
1528                 out irc => 0, "PRIVMSG $config{irc_channel} :* $oldnick\017 used his master status to do \"$command\017\"";
1529                 return 0;
1530         } ],
1531
1532         # chat: Xonotic server -> IRC channel, result
1533         [ dp => q{:vote:v(yes|no|timeout):(\d+):(\d+):(\d+):(\d+):(-?\d+)} => sub {
1534                 my ($result, $yes, $no, $abstain, $not, $min) = @_;
1535                 my $spam = "$yes:$no" . (($min >= 0) ? " ($min needed)" : "") . ", $abstain didn't care, $not didn't vote";
1536                 out irc => 0, "PRIVMSG $config{irc_channel} :* the vote ended with $result: $spam";
1537                 return 0;
1538         } ],
1539
1540         # chat: IRC channel -> Xonotic server
1541         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$store{irc_nick}}))(?: |: ?|, ?)(.*)} => sub {
1542                 my ($nick, $message) = @_;
1543                 $nick = color_dpfix $nick;
1544                         # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1545                 $message = color_irc2dp $message;
1546                 $message =~ s/(["\\])/\\$1/g;
1547                 out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1548                 return 0;
1549         } ],
1550
1551         (
1552                 length $config{irc_trigger}
1553                         ?
1554                                 [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$config{irc_channel}})) :(?i:(??{$config{irc_trigger}}))(?: |: ?|, ?)(.*)} => sub {
1555                                         my ($nick, $message) = @_;
1556                                         $nick = color_dpfix $nick;
1557                                                 # allow the nickname to contain colors in DP format! Therefore, NO color_irc2dp on the nickname!
1558                                         $message = color_irc2dp $message;
1559                                         $message =~ s/(["\\])/\\$1/g;
1560                                         out dp => 0, "rcon2irc_say_as \"$nick on IRC\" \"$message\"";
1561                                         return 0;
1562                                 } ]
1563                         :
1564                                 ()
1565         ),
1566
1567         # irc: CTCP VERSION reply
1568         [ irc => q{:([^! ]*)![^ ]* (?i:PRIVMSG) (?i:(??{$store{irc_nick}})) :\001VERSION( .*)?\001} => sub {
1569                 my ($nick) = @_;
1570                 my $ver = $store{dp_version} or return 0;
1571                 $ver .= ", rcon2irc $VERSION";
1572                 out irc => 0, "NOTICE $nick :\001VERSION $ver\001";
1573         } ],
1574
1575         # on game start, notify the channel
1576         [ dp => q{:gamestart:(.*):[0-9.]*} => sub {
1577                 my ($map) = @_;
1578                 $store{playing} = 1;
1579                 $store{map} = $map;
1580                 $store{map_starttime} = time();
1581                 if ($config{irc_announce_mapchange} eq 'always' || ($config{irc_announce_mapchange} eq 'notempty' && $store{slots_active} > 0)) {
1582                         my $slotsstr = xon_slotsstring();
1583                         out irc => 0, "PRIVMSG $config{irc_channel} :\00304" . $map . "\017 has begun$slotsstr";
1584                 }
1585                 delete $store{lms_blocked};
1586                 return 0;
1587         } ],
1588
1589         # on game over, clear the current map
1590         [ dp => q{:gameover} => sub {
1591                 $store{playing} = 0;
1592                 return 0;
1593         } ],
1594
1595         # scores: Xonotic server -> IRC channel (start)
1596         [ dp => q{:scores:(.*):(\d+)} => sub {
1597                 my ($map, $time) = @_;
1598                 $store{scores} = {};
1599                 $store{scores}{map} = $map;
1600                 $store{scores}{time} = $time;
1601                 $store{scores}{players} = [];
1602                 delete $store{lms_blocked};
1603                 return 0;
1604         } ],
1605
1606         # scores: Xonotic server -> IRC channel, legacy format
1607         [ dp => q{:player:(-?\d+):(\d+):(\d+):(\d+):(\d+):(.*)} => sub {
1608                 my ($frags, $deaths, $time, $team, $id, $name) = @_;
1609                 return if not exists $store{scores};
1610                 push @{$store{scores}{players}}, [$frags, $team, $name]
1611                         unless $frags <= -666; # no spectators
1612                 return 0;
1613         } ],
1614
1615         # scores: Xonotic server -> IRC channel (CTF), legacy format
1616         [ dp => q{:teamscores:(\d+:-?\d*(?::\d+:-?\d*)*)} => sub {
1617                 my ($teams) = @_;
1618                 return if not exists $store{scores};
1619                 $store{scores}{teams} = {split /:/, $teams};
1620                 return 0;
1621         } ],
1622
1623         # scores: Xonotic server -> IRC channel, new format
1624         [ dp => q{:player:see-labels:(-?\d+)[-0-9,]*:(\d+):(\d+):(\d+):(.*)} => sub {
1625                 my ($frags, $time, $team, $id, $name) = @_;
1626                 return if not exists $store{scores};
1627                 push @{$store{scores}{players}}, [$frags, $team, $name];
1628                 return 0;
1629         } ],
1630
1631         # scores: Xonotic server -> IRC channel (CTF), new format
1632         [ dp => q{:teamscores:see-labels:(-?\d+)[-0-9,]*:(\d+)} => sub {
1633                 my ($frags, $team) = @_;
1634                 return if not exists $store{scores};
1635                 $store{scores}{teams}{$team} = $frags;
1636                 return 0;
1637         } ],
1638
1639         # scores: Xonotic server -> IRC channel
1640         [ dp => q{:end} => sub {
1641                 return if not exists $store{scores};
1642                 my $s = $store{scores};
1643                 delete $store{scores};
1644                 my $teams_matter = defined $s->{teams};
1645
1646                 my @t = ();
1647                 my @p = ();
1648
1649                 if($teams_matter)
1650                 {
1651                         # put players into teams
1652                         my %t = ();
1653                         for(@{$s->{players}})
1654                         {
1655                                 my $thisteam = ($t{$_->[1]} ||= {score => 0, team => $_->[1], players => []});
1656                                 push @{$thisteam->{players}}, [$_->[0], $_->[1], $_->[2]];
1657                                 if($s->{teams})
1658                                 {
1659                                         $thisteam->{score} = $s->{teams}{$_->[1]};
1660                                 }
1661                                 else
1662                                 {
1663                                         $thisteam->{score} += $_->[0];
1664                                 }
1665                         }
1666
1667                         # sort by team score
1668                         @t = sort { $b->{score} <=> $a->{score} } values %t;
1669
1670                         # sort by player score
1671                         @p = ();
1672                         for(@t)
1673                         {
1674                                 @{$_->{players}} = sort { $b->[0] <=> $a->[0] } @{$_->{players}};
1675                                 push @p, @{$_->{players}};
1676                         }
1677                 }
1678                 else
1679                 {
1680                         @p = sort { $b->[0] <=> $a->[0] } @{$s->{players}};
1681                 }
1682
1683                 # no display for empty server
1684                 return 0
1685                         if !@p;
1686
1687                 # make message fit somehow
1688                 for my $maxnamelen(reverse 3..64)
1689                 {
1690                         my $scores_string = "PRIVMSG $config{irc_channel} :\00304" . $s->{map} . "\017 ended:";
1691                         if($teams_matter)
1692                         {
1693                                 my $sep = ' ';
1694                                 for(@t)
1695                                 {
1696                                         $scores_string .= $sep . "\003" . $color_team2irc_table{$_->{team}}. "\002\002" . $_->{score} . "\017";
1697                                         $sep = ':';
1698                                 }
1699                         }
1700                         my $sep = '';
1701                         for(@p)
1702                         {
1703                                 my ($frags, $team, $name) = @$_;
1704                                 $name = color_dpfix substr($name, 0, $maxnamelen);
1705                                 if($teams_matter)
1706                                 {
1707                                         $name = "\003" . $color_team2irc_table{$team} . " " . color_dp2none $name;
1708                                 }
1709                                 else
1710                                 {
1711                                         $name = " " . color_dp2irc $name;
1712                                 }
1713                                 $scores_string .= "$sep$name\017 $frags";
1714                                 $sep = ',';
1715                         }
1716                         if(length($scores_string) <= ($store{irc_maxlen} || 256))
1717                         {
1718                                 out irc => 0, $scores_string;
1719                                 return 0;
1720                         }
1721                 }
1722                 out irc => 0, "PRIVMSG $config{irc_channel} :\001ACTION would have LIKED to put the scores here, but they wouldn't fit :(\001";
1723                 return 0;
1724         } ],
1725
1726         # complain when system load gets too high
1727         [ dp => q{timing:   (([0-9.]*)% CPU, ([0-9.]*)% lost, offset avg ([0-9.]*)ms, max ([0-9.]*)ms, sdev ([0-9.]*)ms)} => sub {
1728                 my ($all, $cpu, $lost, $avg, $max, $sdev) = @_;
1729                 return 0 # don't complain when just on the voting screen
1730                         if !$store{playing};
1731                 return 0 # don't complain if it was less than 0.5%
1732                         if $lost < 0.5;
1733                 return 0 # don't complain if nobody is looking
1734                         if $store{slots_active} == 0;
1735                 return 0 # don't complain in the first two minutes
1736                         if time() - $store{map_starttime} < 120;
1737                 return 0 # don't complain if it was already at least half as bad in this round
1738                         if $store{map_starttime} == $store{timingerror_map_starttime} and $lost <= 2 * $store{timingerror_lost};
1739                 $store{timingerror_map_starttime} = $store{map_starttime};
1740                 $store{timingerror_lost} = $lost;
1741                 out dp => 0, 'rcon2irc_say_as server "There are currently some severe system load problems. The admins have been notified."';
1742                 out irc => 1, "PRIVMSG $config{irc_channel} :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1743                 #out irc => 1, "PRIVMSG OpBaI :\001ACTION has big trouble on $store{map} after @{[int(time() - $store{map_starttime})]}s: $all\001";
1744                 return 0;
1745         } ],
1746 );
1747
1748
1749
1750 # Load plugins and add them to the handler list in the front.
1751 for my $p(split ' ', $config{plugins})
1752 {
1753         my @h = eval { do $p; }
1754                 or die "Invalid plugin $p: $@";
1755         for(reverse @h)
1756         {
1757                 ref $_ eq 'ARRAY' or die "Invalid plugin $p: did not return a list of arrays";
1758                 @$_ == 3 or die "Invalid plugin $p: did not return a list of three-element arrays";
1759                 !ref $_->[0] && !ref $_->[1] && ref $_->[2] eq 'CODE' or die "Invalid plugin $p: did not return a list of string-string-sub arrays";
1760                 unshift @handlers, $_;
1761         }
1762 }
1763
1764
1765
1766 # verify that the server is up by letting it echo back a string that causes
1767 # re-initialization of the required aliases
1768 out dp => 0, 'echo "Unknown command \"rcon2irc_eval\""'; # assume the server has been restarted
1769
1770
1771
1772 # regularily, query the server status and if it still is connected to us using
1773 # the log_dest_udp feature. If not, we will detect the response to this rcon
1774 # command and re-initialize the server's connection to us (either by log_dest_udp
1775 # not containing our own IP:port, or by rcon2irc_eval not being a defined command).
1776 schedule sub {
1777         my ($timer) = @_;
1778         out dp => 0, 'sv_cmd bans', 'status 1', 'log_dest_udp', 'rcon2irc_eval set dummy 1';
1779         $store{status_waiting} = -1;
1780         schedule $timer => (exists $store{dp_hostname} ? $config{dp_status_delay} : 1);;
1781 } => 1;
1782
1783
1784
1785 # Continue with connecting to IRC as soon as we get our first status reply from
1786 # the DP server (which contains the server's hostname that we'll use as
1787 # realname for IRC).
1788 schedule sub {
1789         my ($timer) = @_;
1790
1791         # log on to IRC when needed
1792         if(exists $store{dp_hostname} && !exists $store{irc_seen_welcome})
1793         {
1794                 $store{irc_nick_requested} = $config{irc_nick};
1795                 out irc => 1, "NICK $config{irc_nick}", "USER $config{irc_user} localhost localhost :$store{dp_hostname}";
1796                 $store{irc_logged_in} = 1;
1797                 undef $store{irc_maxlen};
1798                 undef $store{irc_pingtime};
1799         }
1800
1801         schedule $timer => 1;;
1802 } => 1;
1803
1804
1805
1806 # Regularily ping the IRC server to detect if the connection is down. If it is,
1807 # schedule an IRC error that will cause reconnection later.
1808 schedule sub {
1809         my ($timer) = @_;
1810
1811         if($store{irc_logged_in})
1812         {
1813                 if(defined $store{irc_pingtime})
1814                 {
1815                         # IRC connection apparently broke
1816                         # so... KILL IT WITH FIRE
1817                         $channels{system}->send("error irc", 0);
1818                 }
1819                 else
1820                 {
1821                         # everything is fine, send a new ping
1822                         $store{irc_pingtime} = time();
1823                         out irc => 1, "PING $store{irc_pingtime}";
1824                 }
1825         }
1826
1827         schedule $timer => $config{irc_ping_delay};;
1828 } => 1;
1829
1830
1831
1832 # Main loop.
1833 for(;;)
1834 {
1835         # Build up an IO::Select object for all our channels.
1836         my $s = IO::Select->new();
1837         for my $chan(values %channels)
1838         {
1839                 $s->add($_) for $chan->fds();
1840         }
1841
1842         # wait for something to happen on our sockets, or wait 2 seconds without anything happening there
1843         $s->can_read(2);
1844         my @errors = $s->has_exception(0);
1845
1846         # on every channel, look for incoming messages
1847         CHANNEL:
1848         for my $chanstr(keys %channels)
1849         {
1850                 my $chan = $channels{$chanstr};
1851                 my @chanfds = $chan->fds();
1852
1853                 for my $chanfd(@chanfds)
1854                 {
1855                         if(grep { $_ == $chanfd } @errors)
1856                         {
1857                                 # STOP! This channel errored!
1858                                 $channels{system}->send("error $chanstr", 0);
1859                                 next CHANNEL;
1860                         }
1861                 }
1862
1863                 eval
1864                 {
1865                         for my $line($chan->recv())
1866                         {
1867                                 # found one! Check if it matches the regular expression of one of
1868                                 # our handlers...
1869                                 my $handled = 0;
1870                                 my $private = 0;
1871                                 for my $h(@handlers)
1872                                 {
1873                                         my ($chanstr_wanted, $re, $sub) = @$h;
1874                                         next
1875                                                 if $chanstr_wanted ne $chanstr;
1876                                         use re 'eval';
1877                                         my @matches = ($line =~ /^$re$/s);
1878                                         no re 'eval';
1879                                         next
1880                                                 unless @matches;
1881                                         # and if it is a match, handle it.
1882                                         ++$handled;
1883                                         my $result = $sub->(@matches);
1884                                         $private = 1
1885                                                 if $result < 0;
1886                                         last
1887                                                 if $result;
1888                                 }
1889                                 # print the message, together with info on whether it has been handled or not
1890                                 if($private)
1891                                 {
1892                                         print "           $chanstr >> (private)\n";
1893                                 }
1894                                 elsif($handled)
1895                                 {
1896                                         print "           $chanstr >> $line\n";
1897                                 }
1898                                 else
1899                                 {
1900                                         print "unhandled: $chanstr >> $line\n";
1901                                 }
1902                         }
1903                         1;
1904                 } or do {
1905                         if($@ eq "read error\n")
1906                         {
1907                                 $channels{system}->send("error $chanstr", 0);
1908                                 next CHANNEL;
1909                         }
1910                         else
1911                         {
1912                                 # re-throw
1913                                 die $@;
1914                         }
1915                 };
1916         }
1917
1918         # handle scheduled tasks...
1919         my @t = @tasks;
1920         my $t = time();
1921         # by emptying the list of tasks...
1922         @tasks = ();
1923         for(@t)
1924         {
1925                 my ($time, $sub) = @$_;
1926                 if($t >= $time)
1927                 {
1928                         # calling them if they are schedled for the "past"...
1929                         $sub->($sub);
1930                 }
1931                 else
1932                 {
1933                         # or re-adding them to the task list if they still are scheduled for the "future"
1934                         push @tasks, [$time, $sub];
1935                 }
1936         }
1937 }