misc/tools/xonotic-map-compiler

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use POSIX;
   6 use File::Temp;
   7
   8 # change these to match your system, or define them in ~/.xonotic-map-compiler
   9 # (just copy paste this part to the file ~/.xonotic-map-compiler)
  10
  11         # Path to Xonotic (where the data directory is in)
  12         our $XONOTICDIR   = '/home/rpolzer/Games/Xonotic';
  13
  14         # Path to your q3map2 program. You find it in your GtkRadiant/install
  15         # directory.
  16         our $Q3MAP2      = '/home/rpolzer/Games/Xonotic/netradiant/install/q3map2.x86';
  17
  18         # General flags for q3map2 (for example -threads 4)
  19         our $Q3MAP2FLAGS = '-fs_forbiddenpath xonotic*-data*.pk3* -fs_forbiddenpath xonotic*-nexcompat*.pk3*';
  20
  21         # Default flags for the -bsp stage
  22         our $BSPFLAGS    = '-meta -maxarea -samplesize 8 -mv 1000000 -mi 6000000';
  23
  24         # Default flags for the -vis stage
  25         our $VISFLAGS    = '';
  26
  27         # Default flags for the -light stage
  28         our $LIGHTFLAGS  = '-lightmapsearchpower 3 -deluxe -patchshadows -randomsamples -samples 4 -lightmapsize 512 -fast -fastbounce -dirty -bouncegrid -fill';
  29
  30         # Default flags for the -minimap stage
  31         our $MINIMAPFLAGS = '';
  32
  33         # Default order of commands
  34         our $ORDER = 'vis,light';
  35
  36 # end of user changable part
  37
  38 do "$ENV{HOME}/.xonotic-map-compiler";
  39
  40 sub Usage()
  41 {
  42         print <<EOF;
  43 Usage:
  44 $0 mapname [-bsp bspflags...] [-vis visflags...] [-light lightflags...] [-minimap minimapflags]
  45 EOF
  46         exit 1;
  47 }
  48
  49 my $options =
  50 {
  51         bsp => [split /\s+/, $BSPFLAGS],
  52         vis => [split /\s+/, $VISFLAGS],
  53         light => [split /\s+/, $LIGHTFLAGS],
  54         minimap => [split /\s+/, $MINIMAPFLAGS],
  55         scale => [], # can't have defaults atm
  56         order => [split /\s*,\s*/, $ORDER],
  57         maps => [],
  58         scalefactor => 1,
  59         bsp_timeout => 0,
  60         vis_timeout => 0,
  61         light_timeout => 0,
  62         minimap_timeout => 0,
  63         scale_timeout => 0
  64 };
  65
  66 my $curmode = 'maps';
  67
  68 while(@ARGV)
  69 {
  70         $_ = shift @ARGV;
  71         my $enterflags = undef;
  72         if($_ eq '-bsp')
  73         {
  74                 $enterflags = 'bsp';
  75         }
  76         elsif($_ eq '-vis')
  77         {
  78                 $enterflags = 'vis';
  79         }
  80         elsif($_ eq '-light')
  81         {
  82                 $enterflags = 'light';
  83         }
  84         elsif($_ eq '-minimap')
  85         {
  86                 $enterflags = 'minimap';
  87         }
  88         elsif($_ eq '-map')
  89         {
  90                 $curmode = 'maps';
  91         }
  92         elsif($_ eq '-scale')
  93         {
  94                 $options->{scalefactor} = @ARGV ? shift(@ARGV) : 1;
  95                 $enterflags = 'scale';
  96         }
  97         elsif($_ eq '-novis')
  98         {
  99                 $options->{vis} = undef;
 100         }
 101         elsif($_ eq '-nolight')
 102         {
 103                 $options->{light} = undef;
 104         }
 105         elsif($_ eq '-nominimap')
 106         {
 107                 $options->{minimap} = undef;
 108         }
 109         elsif($_ eq '-noshaderlist')
 110         {
 111                 $options->{noshaderlist} = 1;
 112         }
 113         elsif($_ eq '-bsp_timeout')
 114         {
 115                 $options->{bsp_timeout} = shift @ARGV;
 116         }
 117         elsif($_ eq '-vis_timeout')
 118         {
 119                 $options->{vis_timeout} = shift @ARGV;
 120         }
 121         elsif($_ eq '-light_timeout')
 122         {
 123                 $options->{light_timeout} = shift @ARGV;
 124         }
 125         elsif($_ eq '-minimap_timeout')
 126         {
 127                 $options->{minimap_timeout} = shift @ARGV;
 128         }
 129         elsif($_ eq '-scale_timeout')
 130         {
 131                 $options->{scale_timeout} = shift @ARGV;
 132         }
 133         elsif($_ eq '-order')
 134         {
 135                 $options->{order} = [split /\s*,\s*/, shift @ARGV];
 136         }
 137         elsif($_ eq '-sRGB')
 138         {
 139                 push @{$options->{bsp}}, "-sRGBtex", "-sRGBcolor";
 140                 push @{$options->{light}}, "-sRGBtex", "-sRGBcolor", "-sRGBlight";
 141         }
 142         elsif($_ eq '-nosRGB')
 143         {
 144                 push @{$options->{bsp}}, "-nosRGBtex", "-nosRGBcolor";
 145                 push @{$options->{light}}, "-nosRGBtex", "-nosRGBcolor", "-nosRGBlight";
 146         }
 147         elsif($_ =~ /^--no(-.*)/)
 148         {
 149                 if($curmode eq 'maps')
 150                 {
 151                         $curmode = 'bsp';
 152                 }
 153                 my $flag = $1;
 154                 @{$options->{$curmode}} = grep { (($_ eq $flag) ... /^-/) !~ /^[0-9]+$/ } @{$options->{$curmode}};
 155                         # so, e.g. --no-samplesize removes "-samplesize" and a following "3"
 156         }
 157         elsif($_ =~ /^-(-.*)/)
 158         {
 159                 if($curmode eq 'maps')
 160                 {
 161                         $curmode = 'bsp';
 162                 }
 163                 push @{$options->{$curmode}}, $1;
 164         }
 165         elsif($_ =~ /^-/ and $curmode eq 'maps')
 166         {
 167                 $curmode = 'bsp';
 168                 push @{$options->{$curmode}}, $_;
 169         }
 170         else
 171         {
 172                 push @{$options->{$curmode}}, $_;
 173         }
 174         if(defined $enterflags)
 175         {
 176                 $curmode = $enterflags;
 177                 if($ARGV[0] eq '+')
 178                 {
 179                         shift @ARGV;
 180                 }
 181                 else
 182                 {
 183                         $options->{$curmode} = [];
 184                 }
 185         }
 186 }
 187
 188 my $linkdir = File::Temp::tempdir("xonotic-map-compiler.XXXXXX", TMPDIR => 1, CLEANUP => 1);
 189
 190 sub q3map2(@)
 191 {
 192         my $mode = $_[0];
 193         my $timeout = undef;
 194         $timeout = $options->{bsp_timeout} if $mode eq '-bsp';
 195         $timeout = $options->{vis_timeout} if $mode eq '-vis';
 196         $timeout = $options->{light_timeout} if $mode eq '-light';
 197         $timeout = $options->{minimap_timeout} if $mode eq '-minimap';
 198         $timeout = $options->{scale_timeout} if $mode eq '-scale';
 199         die "Invalid call: not a standard q3map2 stage" if not defined $timeout;
 200         my @args = ($Q3MAP2, split(/\s+/, $Q3MAP2FLAGS), '-game', 'xonotic', '-fs_basepath', $XONOTICDIR, '-fs_basepath', $linkdir, '-v', @_);
 201         print "\$ @args\n";
 202         defined(my $pid = fork())
 203                 or die "fork: $!";
 204         if($pid) # parent
 205         {
 206                 local $SIG{ALRM} = sub { warn "SIGALRM caught\n"; kill TERM => $pid; };
 207                 alarm $timeout
 208                         if $timeout;
 209                 if(waitpid($pid, 0) != $pid)
 210                 {
 211                         die "waitpid: did not return our child process $pid: $!";
 212                 }
 213                 alarm 0;
 214                 return ($? == 0);
 215         }
 216         else # child
 217         {
 218                 exec @args
 219                         or die "exec: $!";
 220         }
 221 }
 222
 223 (my $mapdir = getcwd()) =~ s!/[^/]*(?:$)!!;
 224 $mapdir = "/" if $mapdir eq "";
 225 symlink "$mapdir", "$linkdir/data";
 226
 227 my ($prescale, $postscale) = ($options->{scalefactor} =~ /^([0-9.]+)(?::([0-9.]+))?$/);
 228 $prescale = 1 if not defined $prescale;
 229 $postscale = 1 if not defined $postscale;
 230
 231 for my $m(@{$options->{maps}})
 232 {
 233         $m =~ s/\.(?:map|bsp)$//;
 234
 235         if($prescale != 1)
 236         {
 237                 unshift @{$options->{bsp}}, "-keeplights";
 238         }
 239
 240         my %shaders = map { m!/([^/.]*)\.shader(?:$)! ? ($1 => 1) : () } glob "../scripts/*.shader";
 241
 242         my $restore_shaderlist = sub { };
 243         if(!$options->{noshaderlist})
 244         {
 245                 my $previous_shaderlist = undef;
 246                 my $shaderlist = "";
 247                 if(open my $fh, "<", "$XONOTICDIR/data/scripts/shaderlist.txt")
 248                 {
 249                         while(<$fh>)
 250                         {
 251                                 $shaderlist .= $_;
 252                         }
 253
 254                         # we may have to restore the file on exit
 255                         $previous_shaderlist = $shaderlist
 256                                 if "$XONOTICDIR/data" eq $mapdir;
 257                 }
 258                 else
 259                 {
 260                         # possibly extract the shader list from a pk3?
 261                         local $ENV{N} = $XONOTICDIR;
 262                         $shaderlist = `cd "\$N" && for X in "\$N"/data/data*.pk3; do Y=\$X; done; unzip -p "\$Y" scripts/shaderlist.txt`;
 263                 }
 264
 265                 my $shaderlist_new = "";
 266                 for(split /\r?\n|\r/, $shaderlist)
 267                 {
 268                         delete $shaders{$_};
 269                         $shaderlist_new .= "$_\n";
 270                 }
 271                 if(%shaders)
 272                 {
 273                         for(sort keys %shaders)
 274                         {
 275                                 $shaderlist_new .= "$_\n";
 276                         }
 277                 }
 278                 else
 279                 {
 280                         $shaderlist_new = undef;
 281                 }
 282
 283                 $restore_shaderlist = sub
 284                 {
 285                         if(defined $shaderlist_new)
 286                         {
 287                                 if(defined $previous_shaderlist)
 288                                 {
 289                                         open my $fh, ">", "$mapdir/scripts/shaderlist.txt";
 290                                         print $fh $previous_shaderlist;
 291                                         close $fh;
 292                                 }
 293                                 else
 294                                 {
 295                                         unlink "$mapdir/scripts/shaderlist.txt";
 296                                 }
 297                         }
 298                 };
 299
 300                 if(defined $shaderlist_new)
 301                 {
 302                         mkdir "$mapdir/scripts";
 303                         open my $fh, ">", "$mapdir/scripts/shaderlist.txt";
 304                         print $fh $shaderlist_new;
 305                         close $fh;
 306                 }
 307         }
 308
 309         local $SIG{INT} = sub
 310         {
 311                 print "SIGINT caught, cleaning up...\n";
 312                 $restore_shaderlist->();
 313                 exit 0;
 314         };
 315
 316         eval
 317         {
 318                 unlink <$m/lm_*>; # delete old external lightmaps
 319                 q3map2 '-bsp', @{$options->{bsp}},   "$m.map"
 320                         or die "-bsp: $?";
 321                 if($prescale != 1)
 322                 {
 323                         q3map2 '-scale', @{$options->{scale}}, $prescale, "$m.bsp"
 324                                 or die "-scale: $?";
 325                         rename "${m}_s.bsp", "$m.bsp"
 326                                 or die "rename ${m}_s.bsp $m.bsp: $!";
 327                 }
 328                 my @o = @{$options->{order}};
 329                 push @o, qw/light vis/;
 330                 my %o = ();
 331
 332                 for(@o)
 333                 {
 334                         next if $o{$_}++;
 335                         if($_ eq 'light')
 336                         {
 337                                 if(defined $options->{light})
 338                                 {
 339                                         q3map2 '-light',        @{$options->{light}}, "$m.map"
 340                                                 or die "-light: $?";
 341                                 }
 342                         }
 343                         if($_ eq 'vis')
 344                         {
 345                                 if(defined $options->{vis})
 346                                 {
 347                                         q3map2 '-vis',          @{$options->{vis}},   "$m.map"
 348                                                 or die "-vis: $?";
 349                                 }
 350                         }
 351                 }
 352
 353                 if($postscale != 1)
 354                 {
 355                         q3map2 '-scale', @{$options->{scale}}, $postscale, "$m.bsp"
 356                                 or die "-scale: $?";
 357                         rename "${m}_s.bsp", "$m.bsp"
 358                                 or die "rename ${m}_s.bsp $m.bsp: $!";
 359                 }
 360
 361                 if(defined $options->{minimap})
 362                 {
 363                         q3map2 '-minimap',      @{$options->{minimap}}, "$m.map"
 364                                 or die "-minimap: $?";
 365                 }
 366
 367                 unlink "$m.srf";
 368                 unlink "$m.prt";
 369
 370                 $restore_shaderlist->();
 371                 1;
 372         }
 373         or do
 374         {
 375                 $restore_shaderlist->();
 376                 die $@;
 377         };
 378 }