misc/tools/xonotic-map-compiler

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use POSIX;
   6 use File::Temp;
   7
   8 # change these to match your system, or define them in ~/.xonotic-map-compiler
   9 # (just copy paste this part to the file ~/.xonotic-map-compiler)
  10
  11         # Path to Xonotic (where the data directory is in)
  12         our $XONOTICDIR   = '/home/rpolzer/Games/Xonotic';
  13
  14         # Path to your q3map2 program. You find it in your GtkRadiant/install
  15         # directory.
  16         our $Q3MAP2      = '/home/rpolzer/Games/Xonotic/netradiant/install/q3map2.x86';
  17
  18         # General flags for q3map2 (for example -threads 4)
  19         our $Q3MAP2FLAGS = '';
  20
  21         # Default flags for the -bsp stage
  22         our $BSPFLAGS    = '-meta -samplesize 8 -minsamplesize 4 -mv 1000000 -mi 6000000';
  23
  24         # Default flags for the -vis stage
  25         our $VISFLAGS    = '';
  26
  27         # Default flags for the -light stage
  28         our $LIGHTFLAGS  = '-deluxe -patchshadows -samples 3 -lightmapsize 512';
  29
  30         # Default flags for the -minimap stage
  31         our $MINIMAPFLAGS = '';
  32
  33         # Default order of commands
  34         our $ORDER = 'light,vis,minimap';
  35
  36 # end of user changable part
  37
  38 do "$ENV{HOME}/.xonotic-map-compiler";
  39
  40 sub Usage()
  41 {
  42         print <<EOF;
  43 Usage:
  44 $0 mapname [-bsp bspflags...] [-vis visflags...] [-light lightflags...] [-minimap minimapflags]
  45 EOF
  46         exit 1;
  47 }
  48
  49 my $options =
  50 {
  51         bsp => [split /\s+/, $BSPFLAGS],
  52         vis => [split /\s+/, $VISFLAGS],
  53         light => [split /\s+/, $LIGHTFLAGS],
  54         minimap => [split /\s+/, $MINIMAPFLAGS],
  55         scale => [], # can't have defaults atm
  56         order => [split /\s*,\s*/, $ORDER],
  57         maps => [],
  58         scale => 1,
  59         bsp_timeout => 0,
  60         vis_timeout => 0,
  61         light_timeout => 0,
  62         minimap_timeout => 0,
  63         scale_timeout => 0
  64 };
  65
  66 my $curmode = 'maps';
  67
  68 while(@ARGV)
  69 {
  70         $_ = shift @ARGV;
  71         my $enterflags = undef;
  72         if($_ eq '-bsp')
  73         {
  74                 $enterflags = 'bsp';
  75         }
  76         elsif($_ eq '-vis')
  77         {
  78                 $enterflags = 'vis';
  79         }
  80         elsif($_ eq '-light')
  81         {
  82                 $enterflags = 'light';
  83         }
  84         elsif($_ eq '-minimap')
  85         {
  86                 $enterflags = 'minimap';
  87         }
  88         elsif($_ eq '-map')
  89         {
  90                 $curmode = 'maps';
  91         }
  92         elsif($_ eq '-scale')
  93         {
  94                 $options->{scale} = (shift @ARGV) || 1;
  95                 $enterflags = 'scale';
  96         }
  97         elsif($_ eq '-novis')
  98         {
  99                 $options->{vis} = undef;
 100         }
 101         elsif($_ eq '-nolight')
 102         {
 103                 $options->{light} = undef;
 104         }
 105         elsif($_ eq '-nominimap')
 106         {
 107                 $options->{minimap} = undef;
 108         }
 109         elsif($_ eq '-noshaderlist')
 110         {
 111                 $options->{noshaderlist} = 1;
 112         }
 113         elsif($_ eq '-bsp_timeout')
 114         {
 115                 $options->{bsp_timeout} = shift @ARGV;
 116         }
 117         elsif($_ eq '-vis_timeout')
 118         {
 119                 $options->{vis_timeout} = shift @ARGV;
 120         }
 121         elsif($_ eq '-light_timeout')
 122         {
 123                 $options->{light_timeout} = shift @ARGV;
 124         }
 125         elsif($_ eq '-minimap_timeout')
 126         {
 127                 $options->{minimap_timeout} = shift @ARGV;
 128         }
 129         elsif($_ eq '-scale_timeout')
 130         {
 131                 $options->{minimap_timeout} = shift @ARGV;
 132         }
 133         elsif($_ eq '-order')
 134         {
 135                 $options->{order} = [split /\s*,\s*/, shift @ARGV];
 136         }
 137         elsif($_ =~ /^-(-.*)/)
 138         {
 139                 if($curmode eq 'maps')
 140                 {
 141                         $curmode = 'bsp';
 142                 }
 143                 push @{$options->{$curmode}}, $1;
 144         }
 145         elsif($_ =~ /^-/ and $curmode eq 'maps')
 146         {
 147                 $curmode = 'bsp';
 148                 push @{$options->{$curmode}}, $_;
 149         }
 150         else
 151         {
 152                 push @{$options->{$curmode}}, $_;
 153         }
 154         if(defined $enterflags)
 155         {
 156                 $curmode = $enterflags;
 157                 if($ARGV[0] eq '+')
 158                 {
 159                         shift @ARGV;
 160                 }
 161                 else
 162                 {
 163                         $options->{$curmode} = [];
 164                 }
 165         }
 166 }
 167
 168 my $linkdir = File::Temp::tempdir("xonotic-map-compiler.XXXXXX", TMPDIR => 1, CLEANUP => 1);
 169
 170 sub q3map2(@)
 171 {
 172         my $mode = $_[0];
 173         my $timeout = undef;
 174         $timeout = $options->{bsp_timeout} if $mode eq '-bsp';
 175         $timeout = $options->{vis_timeout} if $mode eq '-vis';
 176         $timeout = $options->{light_timeout} if $mode eq '-light';
 177         $timeout = $options->{minimap_timeout} if $mode eq '-minimap';
 178         $timeout = $options->{scale_timeout} if $mode eq '-scale';
 179         die "Invalid call: not a standard q3map2 stage" if not defined $timeout;
 180         my @args = ($Q3MAP2, split(/\s+/, $Q3MAP2FLAGS), '-game', 'xonotic', '-fs_basepath', $XONOTICDIR, '-fs_basepath', $linkdir, '-v', @_);
 181         print "\$ @args\n";
 182         defined(my $pid = fork())
 183                 or die "fork: $!";
 184         if($pid) # parent
 185         {
 186                 if($timeout)
 187                 {
 188                         local $SIG{ALRM} = sub { kill $pid; };
 189                         alarm $timeout;
 190                 }
 191                 if(waitpid $pid, 0 != $pid)
 192                 {
 193                         die "waitpid: did not return our child process $pid: $!";
 194                 }
 195                 return !$?;
 196         }
 197         else # child
 198         {
 199                 exec @args
 200                         or die "exec: $!";
 201         }
 202 }
 203
 204 (my $mapdir = getcwd()) =~ s!/[^/]*(?:$)!!;
 205 $mapdir = "/" if $mapdir eq "";
 206 symlink "$mapdir", "$linkdir/data";
 207
 208 my ($prescale, $postscale) = ($options->{scale} =~ /^([0-9.]+)(?::([0-9.]+))?$/);
 209 $postscale = 1 if not defined $postscale;
 210
 211 for my $m(@{$options->{maps}})
 212 {
 213         $m =~ s/\.(?:map|bsp)$//;
 214         if($prescale != 1)
 215         {
 216                 open my $checkfh, "<", "$m.map"
 217                         or die "open $m.map: $!";
 218                 my $keeplights = 0;
 219                 while(<$checkfh>)
 220                 {
 221                         /^\s*"_keeplights"\s+"1"\s*$/
 222                                 or next;
 223                         $keeplights = 1;
 224                 }
 225                 close $checkfh;
 226                 die "$m does not define _keeplights to 1"
 227                         unless $keeplights;
 228         }
 229
 230         my %shaders = map { m!/([^/.]*)\.shader(?:$)! ? ($1 => 1) : () } glob "../scripts/*.shader";
 231
 232         my $restore_shaderlist = sub { };
 233         if(!$options->{noshaderlist})
 234         {
 235                 my $previous_shaderlist = undef;
 236                 my $shaderlist = "";
 237                 if(open my $fh, "<", "$XONOTICDIR/data/scripts/shaderlist.txt")
 238                 {
 239                         while(<$fh>)
 240                         {
 241                                 $shaderlist .= $_;
 242                         }
 243
 244                         # we may have to restore the file on exit
 245                         $previous_shaderlist = $shaderlist
 246                                 if "$XONOTICDIR/data" eq $mapdir;
 247                 }
 248                 else
 249                 {
 250                         # possibly extract the shader list from a pk3?
 251                         local $ENV{N} = $XONOTICDIR;
 252                         $shaderlist = `cd "\$N" && for X in "\$N"/data/data*.pk3; do Y=\$X; done; unzip -p "\$Y" scripts/shaderlist.txt`;
 253                 }
 254
 255                 my $shaderlist_new = "";
 256                 for(split /\r?\n|\r/, $shaderlist)
 257                 {
 258                         delete $shaders{$_};
 259                         $shaderlist_new .= "$_\n";
 260                 }
 261                 if(%shaders)
 262                 {
 263                         for(sort keys %shaders)
 264                         {
 265                                 $shaderlist_new .= "$_\n";
 266                         }
 267                 }
 268                 else
 269                 {
 270                         $shaderlist_new = undef;
 271                 }
 272
 273                 $restore_shaderlist = sub
 274                 {
 275                         if(defined $shaderlist_new)
 276                         {
 277                                 if(defined $previous_shaderlist)
 278                                 {
 279                                         open my $fh, ">", "$mapdir/scripts/shaderlist.txt";
 280                                         print $fh $previous_shaderlist;
 281                                         close $fh;
 282                                 }
 283                                 else
 284                                 {
 285                                         unlink "$mapdir/scripts/shaderlist.txt";
 286                                 }
 287                         }
 288                 };
 289
 290                 if(defined $shaderlist_new)
 291                 {
 292                         mkdir "$mapdir/scripts";
 293                         open my $fh, ">", "$mapdir/scripts/shaderlist.txt";
 294                         print $fh $shaderlist_new;
 295                         close $fh;
 296                 }
 297         }
 298
 299         local $SIG{INT} = sub
 300         {
 301                 print "SIGINT caught, cleaning up...\n";
 302                 $restore_shaderlist->();
 303                 exit 0;
 304         };
 305
 306         eval
 307         {
 308                 unlink <$m/lm_*>; # delete old external lightmaps
 309                 q3map2 '-bsp', @{$options->{bsp}},   "$m.map"
 310                         or die "-bsp: $?";
 311                 if($prescale != 1)
 312                 {
 313                         q3map2 '-scale', @{$options->{scale}}, $prescale, "$m.bsp"
 314                                 or die "-scale: $?";
 315                         rename "${m}_s.bsp", "$m.bsp"
 316                                 or die "rename ${m}_s.bsp $m.bsp: $!";
 317                 }
 318                 my @o = @{$options->{order}};
 319                 push @o, qw/light vis minimap/;
 320                 my %o = ();
 321
 322                 for(@o)
 323                 {
 324                         next if $o{$_}++;
 325                         if($_ eq 'light')
 326                         {
 327                                 if(defined $options->{light})
 328                                 {
 329                                         q3map2 '-light',        @{$options->{light}}, "$m.map"
 330                                                 or die "-light: $?";
 331                                 }
 332                         }
 333                         if($_ eq 'vis')
 334                         {
 335                                 if(defined $options->{vis})
 336                                 {
 337                                         q3map2 '-vis',          @{$options->{vis}},   "$m.map"
 338                                                 or die "-vis: $?";
 339                                 }
 340                         }
 341                         if($_ eq 'minimap')
 342                         {
 343                                 if(defined $options->{minimap})
 344                                 {
 345                                         q3map2 '-minimap',      @{$options->{minimap}}, "$m.map"
 346                                                 or die "-minimap: $?";
 347                                 }
 348                         }
 349                 }
 350
 351                 if($postscale != 1)
 352                 {
 353                         q3map2 '-scale', @{$options->{scale}}, $postscale, "$m.bsp"
 354                                 or die "-scale: $?";
 355                         rename "${m}_s.bsp", "$m.bsp"
 356                                 or die "rename ${m}_s.bsp $m.bsp: $!";
 357                 }
 358
 359                 unlink "$m.srf";
 360                 unlink "$m.prt";
 361
 362                 $restore_shaderlist->();
 363                 1;
 364         }
 365         or do
 366         {
 367                 $restore_shaderlist->();
 368                 die $@;
 369         };
 370 }