misc/tools/xonotic-map-compiler

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use POSIX;
   6 use File::Temp;
   7
   8 # change these to match your system, or define them in ~/.xonotic-map-compiler
   9 # (just copy paste this part to the file ~/.xonotic-map-compiler)
  10
  11         # Path to Xonotic (where the data directory is in)
  12         our $XONOTICDIR   = '/home/rpolzer/Games/Xonotic';
  13
  14         # Path to your q3map2 program. You find it in your GtkRadiant/install
  15         # directory.
  16         our $Q3MAP2      = '/home/rpolzer/Games/Xonotic/netradiant/install/q3map2.x86';
  17
  18         # General flags for q3map2 (for example -threads 4)
  19         our $Q3MAP2FLAGS = '';
  20
  21         # Default flags for the -bsp stage
  22         our $BSPFLAGS    = '-meta -samplesize 8 -minsamplesize 4 -mv 1000000 -mi 6000000';
  23
  24         # Default flags for the -vis stage
  25         our $VISFLAGS    = '';
  26
  27         # Default flags for the -light stage
  28         our $LIGHTFLAGS  = '-deluxe -patchshadows -samples 3 -lightmapsize 512';
  29
  30         # Default flags for the -minimap stage
  31         our $MINIMAPFLAGS = '';
  32
  33         # Default order of commands
  34         our $ORDER = 'light,vis,minimap';
  35
  36 # end of user changable part
  37
  38 do "$ENV{HOME}/.xonotic-map-compiler";
  39
  40 sub Usage()
  41 {
  42         print <<EOF;
  43 Usage:
  44 $0 mapname [-bsp bspflags...] [-vis visflags...] [-light lightflags...] [-minimap minimapflags]
  45 EOF
  46         exit 1;
  47 }
  48
  49 my $options =
  50 {
  51         bsp => [split /\s+/, $BSPFLAGS],
  52         vis => [split /\s+/, $VISFLAGS],
  53         light => [split /\s+/, $LIGHTFLAGS],
  54         minimap => [split /\s+/, $MINIMAPFLAGS],
  55         scale => [], # can't have defaults atm
  56         order => [split /\s*,\s*/, $ORDER],
  57         maps => [],
  58         scale => 1,
  59         bsp_timeout => 0,
  60         vis_timeout => 0,
  61         light_timeout => 0,
  62         minimap_timeout => 0,
  63         scale_timeout => 0
  64 };
  65
  66 my $curmode = 'maps';
  67
  68 while(@ARGV)
  69 {
  70         $_ = shift @ARGV;
  71         my $enterflags = undef;
  72         if($_ eq '-bsp')
  73         {
  74                 $enterflags = 'bsp';
  75         }
  76         elsif($_ eq '-vis')
  77         {
  78                 $enterflags = 'vis';
  79         }
  80         elsif($_ eq '-light')
  81         {
  82                 $enterflags = 'light';
  83         }
  84         elsif($_ eq '-minimap')
  85         {
  86                 $enterflags = 'minimap';
  87         }
  88         elsif($_ eq '-map')
  89         {
  90                 $curmode = 'maps';
  91         }
  92         elsif($_ eq '-scale')
  93         {
  94                 $options->{scale} = (shift @ARGV) || 1;
  95                 $enterflags = 'scale';
  96         }
  97         elsif($_ eq '-novis')
  98         {
  99                 $options->{vis} = undef;
 100         }
 101         elsif($_ eq '-nolight')
 102         {
 103                 $options->{light} = undef;
 104         }
 105         elsif($_ eq '-nominimap')
 106         {
 107                 $options->{minimap} = undef;
 108         }
 109         elsif($_ eq '-noshaderlist')
 110         {
 111                 $options->{noshaderlist} = 1;
 112         }
 113         elsif($_ eq '-bsp_timeout')
 114         {
 115                 $options->{bsp_timeout} = shift @ARGV;
 116         }
 117         elsif($_ eq '-vis_timeout')
 118         {
 119                 $options->{vis_timeout} = shift @ARGV;
 120         }
 121         elsif($_ eq '-light_timeout')
 122         {
 123                 $options->{light_timeout} = shift @ARGV;
 124         }
 125         elsif($_ eq '-minimap_timeout')
 126         {
 127                 $options->{minimap_timeout} = shift @ARGV;
 128         }
 129         elsif($_ eq '-scale_timeout')
 130         {
 131                 $options->{minimap_timeout} = shift @ARGV;
 132         }
 133         elsif($_ eq '-order')
 134         {
 135                 $options->{order} = [split /\s*,\s*/, shift @ARGV];
 136         }
 137         elsif($_ =~ /^-(-.*)/)
 138         {
 139                 if($curmode eq 'maps')
 140                 {
 141                         $curmode = 'bsp';
 142                 }
 143                 push @{$options->{$curmode}}, $1;
 144         }
 145         elsif($_ =~ /^-/ and $curmode eq 'maps')
 146         {
 147                 $curmode = 'bsp';
 148                 push @{$options->{$curmode}}, $_;
 149         }
 150         else
 151         {
 152                 push @{$options->{$curmode}}, $_;
 153         }
 154         if(defined $enterflags)
 155         {
 156                 $curmode = $enterflags;
 157                 if($ARGV[0] eq '+')
 158                 {
 159                         shift @ARGV;
 160                 }
 161                 else
 162                 {
 163                         $options->{$curmode} = [];
 164                 }
 165         }
 166 }
 167
 168 my $linkdir = File::Temp::tempdir("xonotic-map-compiler.XXXXXX", TMPDIR => 1, CLEANUP => 1);
 169
 170 sub q3map2(@)
 171 {
 172         my $mode = $_[0];
 173         my $timeout = undef;
 174         $timeout = $options->{bsp_timeout} if $mode eq '-bsp';
 175         $timeout = $options->{vis_timeout} if $mode eq '-vis';
 176         $timeout = $options->{light_timeout} if $mode eq '-light';
 177         $timeout = $options->{minimap_timeout} if $mode eq '-minimap';
 178         $timeout = $options->{scale_timeout} if $mode eq '-scale';
 179         die "Invalid call: not a standard q3map2 stage" if not defined $timeout;
 180         my @args = ($Q3MAP2, split(/\s+/, $Q3MAP2FLAGS), '-game', 'xonotic', '-fs_basepath', $XONOTICDIR, '-fs_basepath', $linkdir, '-v', @_);
 181         print "\$ @args\n";
 182         defined(my $pid = fork())
 183                 or die "fork: $!";
 184         if($pid) # parent
 185         {
 186                 local $SIG{ALRM} = sub { kill $pid; };
 187                 alarm $timeout
 188                         if $timeout;
 189                 if(waitpid $pid, 0 != $pid)
 190                 {
 191                         die "waitpid: did not return our child process $pid: $!";
 192                 }
 193                 return !$?;
 194         }
 195         else # child
 196         {
 197                 exec @args
 198                         or die "exec: $!";
 199         }
 200 }
 201
 202 (my $mapdir = getcwd()) =~ s!/[^/]*(?:$)!!;
 203 $mapdir = "/" if $mapdir eq "";
 204 symlink "$mapdir", "$linkdir/data";
 205
 206 my ($prescale, $postscale) = ($options->{scale} =~ /^([0-9.]+)(?::([0-9.]+))?$/);
 207 $postscale = 1 if not defined $postscale;
 208
 209 for my $m(@{$options->{maps}})
 210 {
 211         $m =~ s/\.(?:map|bsp)$//;
 212         if($prescale != 1)
 213         {
 214                 open my $checkfh, "<", "$m.map"
 215                         or die "open $m.map: $!";
 216                 my $keeplights = 0;
 217                 while(<$checkfh>)
 218                 {
 219                         /^\s*"_keeplights"\s+"1"\s*$/
 220                                 or next;
 221                         $keeplights = 1;
 222                 }
 223                 close $checkfh;
 224                 die "$m does not define _keeplights to 1"
 225                         unless $keeplights;
 226         }
 227
 228         my %shaders = map { m!/([^/.]*)\.shader(?:$)! ? ($1 => 1) : () } glob "../scripts/*.shader";
 229
 230         my $restore_shaderlist = sub { };
 231         if(!$options->{noshaderlist})
 232         {
 233                 my $previous_shaderlist = undef;
 234                 my $shaderlist = "";
 235                 if(open my $fh, "<", "$XONOTICDIR/data/scripts/shaderlist.txt")
 236                 {
 237                         while(<$fh>)
 238                         {
 239                                 $shaderlist .= $_;
 240                         }
 241
 242                         # we may have to restore the file on exit
 243                         $previous_shaderlist = $shaderlist
 244                                 if "$XONOTICDIR/data" eq $mapdir;
 245                 }
 246                 else
 247                 {
 248                         # possibly extract the shader list from a pk3?
 249                         local $ENV{N} = $XONOTICDIR;
 250                         $shaderlist = `cd "\$N" && for X in "\$N"/data/data*.pk3; do Y=\$X; done; unzip -p "\$Y" scripts/shaderlist.txt`;
 251                 }
 252
 253                 my $shaderlist_new = "";
 254                 for(split /\r?\n|\r/, $shaderlist)
 255                 {
 256                         delete $shaders{$_};
 257                         $shaderlist_new .= "$_\n";
 258                 }
 259                 if(%shaders)
 260                 {
 261                         for(sort keys %shaders)
 262                         {
 263                                 $shaderlist_new .= "$_\n";
 264                         }
 265                 }
 266                 else
 267                 {
 268                         $shaderlist_new = undef;
 269                 }
 270
 271                 $restore_shaderlist = sub
 272                 {
 273                         if(defined $shaderlist_new)
 274                         {
 275                                 if(defined $previous_shaderlist)
 276                                 {
 277                                         open my $fh, ">", "$mapdir/scripts/shaderlist.txt";
 278                                         print $fh $previous_shaderlist;
 279                                         close $fh;
 280                                 }
 281                                 else
 282                                 {
 283                                         unlink "$mapdir/scripts/shaderlist.txt";
 284                                 }
 285                         }
 286                 };
 287
 288                 if(defined $shaderlist_new)
 289                 {
 290                         mkdir "$mapdir/scripts";
 291                         open my $fh, ">", "$mapdir/scripts/shaderlist.txt";
 292                         print $fh $shaderlist_new;
 293                         close $fh;
 294                 }
 295         }
 296
 297         local $SIG{INT} = sub
 298         {
 299                 print "SIGINT caught, cleaning up...\n";
 300                 $restore_shaderlist->();
 301                 exit 0;
 302         };
 303
 304         eval
 305         {
 306                 unlink <$m/lm_*>; # delete old external lightmaps
 307                 q3map2 '-bsp', @{$options->{bsp}},   "$m.map"
 308                         or die "-bsp: $?";
 309                 if($prescale != 1)
 310                 {
 311                         q3map2 '-scale', @{$options->{scale}}, $prescale, "$m.bsp"
 312                                 or die "-scale: $?";
 313                         rename "${m}_s.bsp", "$m.bsp"
 314                                 or die "rename ${m}_s.bsp $m.bsp: $!";
 315                 }
 316                 my @o = @{$options->{order}};
 317                 push @o, qw/light vis minimap/;
 318                 my %o = ();
 319
 320                 for(@o)
 321                 {
 322                         next if $o{$_}++;
 323                         if($_ eq 'light')
 324                         {
 325                                 if(defined $options->{light})
 326                                 {
 327                                         q3map2 '-light',        @{$options->{light}}, "$m.map"
 328                                                 or die "-light: $?";
 329                                 }
 330                         }
 331                         if($_ eq 'vis')
 332                         {
 333                                 if(defined $options->{vis})
 334                                 {
 335                                         q3map2 '-vis',          @{$options->{vis}},   "$m.map"
 336                                                 or die "-vis: $?";
 337                                 }
 338                         }
 339                         if($_ eq 'minimap')
 340                         {
 341                                 if(defined $options->{minimap})
 342                                 {
 343                                         q3map2 '-minimap',      @{$options->{minimap}}, "$m.map"
 344                                                 or die "-minimap: $?";
 345                                 }
 346                         }
 347                 }
 348
 349                 if($postscale != 1)
 350                 {
 351                         q3map2 '-scale', @{$options->{scale}}, $postscale, "$m.bsp"
 352                                 or die "-scale: $?";
 353                         rename "${m}_s.bsp", "$m.bsp"
 354                                 or die "rename ${m}_s.bsp $m.bsp: $!";
 355                 }
 356
 357                 unlink "$m.srf";
 358                 unlink "$m.prt";
 359
 360                 $restore_shaderlist->();
 361                 1;
 362         }
 363         or do
 364         {
 365                 $restore_shaderlist->();
 366                 die $@;
 367         };
 368 }