misc/tools/progs-analyzer.pl

   1 use strict;
   2 use warnings;
   3 use Digest::SHA;
   4
   5 sub id()
   6 {
   7         return sub { $_[0]; };
   8 }
   9
  10 sub signed($)
  11 {
  12         my ($bits) = @_;
  13         return sub { $_[0] >= (2**($bits-1)) ? $_[0]-(2**$bits) : $_[0]; };
  14 }
  15
  16 use constant OPCODE_E => [qw[
  17         DONE
  18         MUL_F MUL_V MUL_FV MUL_VF
  19         DIV_F
  20         ADD_F ADD_V
  21         SUB_F SUB_V
  22         EQ_F EQ_V EQ_S EQ_E EQ_FNC
  23         NE_F NE_V NE_S NE_E NE_FNC
  24         LE GE LT GT
  25         LOAD_F LOAD_V LOAD_S LOAD_ENT LOAD_FLD LOAD_FNC
  26         ADDRESS
  27         STORE_F STORE_V STORE_S STORE_ENT STORE_FLD STORE_FNC
  28         STOREP_F STOREP_V STOREP_S STOREP_ENT STOREP_FLD STOREP_FNC
  29         RETURN
  30         NOT_F NOT_V NOT_S NOT_ENT NOT_FNC
  31         IF IFNOT
  32         CALL0 CALL1 CALL2 CALL3 CALL4 CALL5 CALL6 CALL7 CALL8
  33         STATE
  34         GOTO
  35         AND OR
  36         BITAND BITOR
  37 ]];
  38 use constant ETYPE_E => [qw[
  39         void
  40         string
  41         float
  42         vector
  43         entity
  44         field
  45         function
  46         pointer
  47 ]];
  48 use constant DEF_SAVEGLOBAL => 32768;
  49 sub typesize($)
  50 {
  51         my ($type) = @_;
  52         return 3 if $type eq 'vector';
  53         return 1;
  54 }
  55
  56 sub checkop($)
  57 {
  58         my ($op) = @_;
  59         if($op =~ /^IF.*_V$/)
  60         {
  61                 return { a => 'inglobalvec', b => 'ipoffset', isjump => 'b', isconditional => 1 };
  62         }
  63         if($op =~ /^IF/)
  64         {
  65                 return { a => 'inglobal', b => 'ipoffset', isjump => 'b', isconditional => 1 };
  66         }
  67         if($op eq 'GOTO')
  68         {
  69                 return { a => 'ipoffset', isjump => 'a', isconditional => 0 };
  70         }
  71         if($op =~ /^ADD_V$|^SUB_V$/)
  72         {
  73                 return { a => 'inglobalvec', b => 'inglobalvec', c => 'outglobalvec' };
  74         }
  75         if($op =~ /^MUL_V$|^EQ_V$|^NE_V$/)
  76         {
  77                 return { a => 'inglobalvec', b => 'inglobalvec', c => 'outglobal' };
  78         }
  79         if($op eq 'MUL_FV')
  80         {
  81                 return { a => 'inglobal', b => 'inglobalvec', c => 'outglobalvec' };
  82         }
  83         if($op eq 'MUL_VF')
  84         {
  85                 return { a => 'inglobalvec', b => 'inglobal', c => 'outglobalvec' };
  86         }
  87         if($op eq 'LOAD_V')
  88         {
  89                 return { a => 'inglobal', b => 'inglobal', c => 'outglobalvec' };
  90         }
  91         if($op =~ /^NOT_V/)
  92         {
  93                 return { a => 'inglobalvec', c => 'outglobal' };
  94         }
  95         if($op =~ /^NOT_/)
  96         {
  97                 return { a => 'inglobal', c => 'outglobal' };
  98         }
  99         if($op eq 'STOREP_V')
 100         {
 101                 return { a => 'inglobalvec', b => 'inglobal' };
 102         }
 103         if($op eq 'STORE_V')
 104         {
 105                 return { a => 'inglobalvec', b => 'outglobalvec' };
 106         }
 107         if($op =~ /^STOREP_/)
 108         {
 109                 return { a => 'inglobal', b => 'inglobal' };
 110         }
 111         if($op =~ /^STORE_/)
 112         {
 113                 return { a => 'inglobal', b => 'outglobal' };
 114         }
 115         if($op =~ /^CALL/)
 116         {
 117                 return { a => 'inglobalfunc', iscall => 1 };
 118         }
 119         if($op =~ /^DONE$|^RETURN$/)
 120         {
 121                 return { a => 'inglobal', isreturn => 1 };
 122         }
 123         return { a => 'inglobal', b => 'inglobal', c => 'outglobal' };
 124 }
 125
 126 use constant TYPES => {
 127         int => ['V', 4, signed 32],
 128         ushort => ['v', 2, id],
 129         short => ['v', 2, signed 16],
 130         opcode => ['v', 2, sub { OPCODE_E->[$_[0]] or die "Invalid opcode: $_[0]"; }],
 131         float => ['f', 4, id],
 132         uchar8 => ['a8', 8, sub { [unpack 'C8', $_[0]] }],
 133         global => ['i', 4, sub { { int => $_[0], float => unpack "f", pack "L", $_[0] }; }],
 134         deftype => ['v', 2, sub { { type => ETYPE_E->[$_[0] & ~DEF_SAVEGLOBAL], save => !!($_[0] & DEF_SAVEGLOBAL) }; }],
 135 };
 136
 137 use constant DPROGRAMS_T => [
 138         [int => 'version'],
 139         [int => 'crc'],
 140         [int => 'ofs_statements'],
 141         [int => 'numstatements'],
 142         [int => 'ofs_globaldefs'],
 143         [int => 'numglobaldefs'],
 144         [int => 'ofs_fielddefs'],
 145         [int => 'numfielddefs'],
 146         [int => 'ofs_functions'],
 147         [int => 'numfunctions'],
 148         [int => 'ofs_strings'],
 149         [int => 'numstrings'],
 150         [int => 'ofs_globals'],
 151         [int => 'numglobals'],
 152         [int => 'entityfields']
 153 ];
 154
 155 use constant DSTATEMENT_T => [
 156         [opcode => 'op'],
 157         [short => 'a'],
 158         [short => 'b'],
 159         [short => 'c']
 160 ];
 161
 162 use constant DDEF_T => [
 163         [deftype => 'type'],
 164         [ushort => 'ofs'],
 165         [int => 's_name']
 166 ];
 167
 168 use constant DGLOBAL_T => [
 169         [global => 'v'],
 170 ];
 171
 172 use constant DFUNCTION_T => [
 173         [int => 'first_statement'],
 174         [int => 'parm_start'],
 175         [int => 'locals'],
 176         [int => 'profile'],
 177         [int => 's_name'],
 178         [int => 's_file'],
 179         [int => 'numparms'],
 180         [uchar8 => 'parm_size'],
 181 ];
 182
 183 sub get_section($$$)
 184 {
 185         my ($fh, $start, $len) = @_;
 186         seek $fh, $start, 0
 187                 or die "seek: $!";
 188         $len == read $fh, my $buf, $len
 189                 or die "short read";
 190         return $buf;
 191 }
 192
 193 sub parse_section($$$$$)
 194 {
 195         my ($fh, $struct, $start, $len, $cnt) = @_;
 196
 197         my $itemlen = 0;
 198         $itemlen += TYPES->{$_->[0]}->[1]
 199                 for @$struct;
 200         my $packspec = join '', map { TYPES->{$_->[0]}->[0]; } @$struct;
 201         my @packnames = map { $_->[1]; } @$struct;
 202
 203         $len = $cnt * $itemlen
 204                 if not defined $len and defined $cnt;
 205         $cnt = int($len / $itemlen)
 206                 if not defined $cnt and defined $len;
 207         die "Invalid length specification"
 208                 unless defined $len and defined $cnt and $len == $cnt * $itemlen;
 209         die "Invalid length specification in scalar context"
 210                 unless wantarray or $cnt == 1;
 211
 212         seek $fh, $start, 0
 213                 or die "seek: $!";
 214         my @out = map
 215         {
 216                 $itemlen == read $fh, my $buf, $itemlen
 217                         or die "short read";
 218                 my %h = ();
 219                 @h{@packnames} = unpack $packspec, $buf;
 220                 $h{$_->[1]} = TYPES->{$_->[0]}->[2]->($h{$_->[1]})
 221                         for @$struct;
 222                 \%h;
 223         }
 224         0..($cnt-1);
 225         return @out
 226                 if wantarray;
 227         return $out[0];
 228 }
 229
 230 sub nfa_default_state_checker()
 231 {
 232         my %seen;
 233         return sub
 234         {
 235                 my ($ip, $state) = @_;
 236                 return $seen{"$ip $state"}++;
 237         };
 238 }
 239
 240 sub run_nfa($$$$$$)
 241 {
 242         my ($progs, $ip, $state, $copy_handler, $state_checker, $instruction_handler) = @_;
 243
 244         my $statements = $progs->{statements};
 245
 246         my $nfa;
 247         $nfa = sub
 248         {
 249                 no warnings 'recursion';
 250
 251                 my ($ip, $state) = @_;
 252
 253                 for(;;)
 254                 {
 255                         return
 256                                 if $state_checker->($ip, $state);
 257
 258                         my $s = $statements->[$ip];
 259                         my $c = checkop $s->{op};
 260
 261                         if($instruction_handler->($ip, $state, $s, $c))
 262                         {
 263                                 # abort execution
 264                                 last;
 265                         }
 266
 267                         if($c->{isreturn})
 268                         {
 269                                 last;
 270                         }
 271                         elsif($c->{isjump})
 272                         {
 273                                 if($c->{isconditional})
 274                                 {
 275                                         if(rand 2)
 276                                         {
 277                                                 $nfa->($ip+$s->{$c->{isjump}}, $copy_handler->($state));
 278                                                 $ip += 1;
 279                                         }
 280                                         else
 281                                         {
 282                                                 $nfa->($ip+1, $copy_handler->($state));
 283                                                 $ip += $s->{$c->{isjump}};
 284                                         }
 285                                 }
 286                                 else
 287                                 {
 288                                         $ip += $s->{$c->{isjump}};
 289                                 }
 290                         }
 291                         else
 292                         {
 293                                 $ip += 1;
 294                         }
 295                 }
 296         };
 297
 298         $nfa->($ip, $copy_handler->($state));
 299 }
 300
 301 sub get_constant($$)
 302 {
 303         my ($progs, $g) = @_;
 304         if($g->{int} == 0)
 305         {
 306                 return undef;
 307         }
 308         elsif($g->{int} > 0 && $g->{int} < 16777216)
 309         {
 310                 if($g->{int} < length $progs->{strings} && $g->{int} > 0)
 311                 {
 312                         return str($progs->{getstring}->($g->{int}));
 313                 }
 314                 else
 315                 {
 316                         return $g->{int} . "i";
 317                 }
 318         }
 319         else
 320         {
 321                 return $g->{float};
 322         }
 323 }
 324
 325 use constant PRE_MARK_STATEMENT => "";
 326 use constant POST_MARK_STATEMENT => "";
 327 use constant PRE_MARK_OPERAND => "*** ";
 328 use constant POST_MARK_OPERAND => " ***";
 329
 330 use constant INSTRUCTION_FORMAT => "%8s %3s | %-12s ";
 331 use constant OPERAND_FORMAT => "%s";
 332 use constant OPERAND_SEPARATOR => ", ";
 333 use constant INSTRUCTION_SEPARATOR => "\n";
 334
 335 sub str($)
 336 {
 337         my ($str) = @_;
 338         $str =~ s/[\000-\037\\\"\177-\377]/sprintf "\\%03o", ord $&/ge;
 339         return "\"$str\"";
 340 }
 341
 342 sub disassemble_function($$;$)
 343 {
 344         my ($progs, $func, $highlight) = @_;
 345
 346         print "$func->{debugname}:\n";
 347
 348         my $initializer = sub
 349         {
 350                 my ($ofs) = @_;
 351                 my $g = get_constant($progs, $progs->{globals}[$ofs]{v});
 352                 print " = $g"
 353                         if defined $g;
 354         };
 355
 356         printf INSTRUCTION_FORMAT, '', '', '.PARM_START';
 357         printf OPERAND_FORMAT, "$func->{parm_start}";
 358         print INSTRUCTION_SEPARATOR;
 359
 360         printf INSTRUCTION_FORMAT, '', '', '.LOCALS';
 361         printf OPERAND_FORMAT, "$func->{locals}";
 362         print INSTRUCTION_SEPARATOR;
 363
 364         my %override_locals = ();
 365         my $p = $func->{parm_start};
 366         for(0..($func->{numparms}-1))
 367         {
 368                 $override_locals{$p} //= "argv_$_";
 369                 for my $comp(0..($func->{parm_size}[$_]-1))
 370                 {
 371                         $override_locals{$p} //= "argv_$_\[$comp]";
 372                         ++$p;
 373                 }
 374                 printf INSTRUCTION_FORMAT, '', '', '.ARG';
 375                 printf OPERAND_FORMAT, "argv_$_";
 376                 print OPERAND_SEPARATOR;
 377                 printf OPERAND_FORMAT, $func->{parm_size}[$_];
 378                 print INSTRUCTION_SEPARATOR;
 379         }
 380         for($func->{parm_start}..($func->{parm_start} + $func->{locals} - 1))
 381         {
 382                 next
 383                         if exists $override_locals{$_};
 384                 $override_locals{$_} = "local_$_";
 385
 386                 printf INSTRUCTION_FORMAT, '', '', '.LOCAL';
 387                 printf OPERAND_FORMAT, "local_$_";
 388                 $initializer->($_);
 389                 print INSTRUCTION_SEPARATOR;
 390         }
 391
 392         my $getname = sub
 393         {
 394                 my ($ofs) = @_;
 395                 $ofs &= 0xFFFF;
 396                 return $override_locals{$ofs}
 397                         if exists $override_locals{$ofs};
 398                 my $def = $progs->{globaldef_byoffset}->($ofs);
 399                 return $def->{debugname};
 400         };
 401
 402         my $operand = sub
 403         {
 404                 my ($ip, $type, $operand) = @_;
 405                 if($type eq 'inglobal')
 406                 {
 407                         my $name = $getname->($operand);
 408                         printf OPERAND_FORMAT, "$name";
 409                 }
 410                 elsif($type eq 'outglobal')
 411                 {
 412                         my $name = $getname->($operand);
 413                         printf OPERAND_FORMAT, "&$name";
 414                 }
 415                 elsif($type eq 'inglobalvec')
 416                 {
 417                         my $name = $getname->($operand);
 418                         printf OPERAND_FORMAT, "$name\[\]";
 419                 }
 420                 elsif($type eq 'outglobalvec')
 421                 {
 422                         my $name = $getname->($operand);
 423                         printf OPERAND_FORMAT, "&$name\[\]";
 424                 }
 425                 elsif($type eq 'inglobalfunc')
 426                 {
 427                         my $name = $getname->($operand);
 428                         printf OPERAND_FORMAT, "$name()";
 429                 }
 430                 elsif($type eq 'ipoffset')
 431                 {
 432                         printf OPERAND_FORMAT, "@{[$ip + $operand]}" . sprintf ' ($%+d)', $operand;
 433                 }
 434                 else
 435                 {
 436                         die "unknown type: $type";
 437                 }
 438         };
 439
 440         my %statements = ();
 441         my %come_from = ();
 442         run_nfa $progs, $func->{first_statement}, "", id, nfa_default_state_checker,
 443                 sub
 444                 {
 445                         my ($ip, $state, $s, $c) = @_;
 446                         ++$statements{$ip};
 447
 448                         if(my $j = $c->{isjump})
 449                         {
 450                                 my $t = $ip + $s->{$j};
 451                                 $come_from{$t}{$ip} = $c->{isconditional};
 452                         }
 453
 454                         return 0;
 455                 };
 456
 457         my $ipprev = undef;
 458         for my $ip(sort { $a <=> $b } keys %statements)
 459         {
 460                 if($ip == $func->{first_statement})
 461                 {
 462                         printf INSTRUCTION_FORMAT, $ip, '', '.ENTRY';
 463                         print INSTRUCTION_SEPARATOR;
 464                 }
 465                 if(defined $ipprev && $ip != $ipprev + 1)
 466                 {
 467                         printf INSTRUCTION_FORMAT, $ip, '', '.SKIP';
 468                         printf OPERAND_FORMAT, $ip - $ipprev - 1;
 469                         print INSTRUCTION_SEPARATOR;
 470                 }
 471                 if(my $cf = $come_from{$ip})
 472                 {
 473                         printf INSTRUCTION_FORMAT, $ip, '', '.XREF';
 474                         my $cnt = 0;
 475                         for(sort { $a <=> $b } keys %$cf)
 476                         {
 477                                 print OPERAND_SEPARATOR
 478                                         if $cnt++;
 479                                 printf OPERAND_FORMAT, ($cf->{$_} ? 'c' : 'j') . $_ . sprintf ' ($%+d)', $_ - $ip;
 480                         }
 481                         print INSTRUCTION_SEPARATOR;
 482                 }
 483
 484                 my $op = $progs->{statements}[$ip]{op};
 485                 my $ipt = $progs->{statements}[$ip];
 486                 my $opprop = checkop $op;
 487
 488                 print PRE_MARK_STATEMENT
 489                         if $highlight and $highlight->{$ip};
 490
 491                 my $showip = $opprop->{isjump};
 492                 printf INSTRUCTION_FORMAT, $showip ? $ip : '', $highlight->{$ip} ? "<!>" : "", $op;
 493
 494                 my $cnt = 0;
 495                 for my $o(qw(a b c))
 496                 {
 497                         next
 498                                 if not defined $opprop->{$o};
 499                         print OPERAND_SEPARATOR
 500                                 if $cnt++;
 501                         print PRE_MARK_OPERAND
 502                                 if $highlight and $highlight->{$ip} and $highlight->{$ip}{$o};
 503                         $operand->($ip, $opprop->{$o}, $ipt->{$o});
 504                         print POST_MARK_OPERAND
 505                                 if $highlight and $highlight->{$ip} and $highlight->{$ip}{$o};
 506                 }
 507
 508                 print POST_MARK_STATEMENT
 509                         if $highlight and $highlight->{$ip};
 510
 511                 print INSTRUCTION_SEPARATOR;
 512         }
 513 }
 514
 515 sub find_uninitialized_locals($$)
 516 {
 517         my ($progs, $func) = @_;
 518
 519         return
 520                 if $func->{first_statement} < 0; # builtin
 521
 522         print STDERR "Checking $func->{debugname}...\n";
 523
 524         my $p = $func->{parm_start};
 525         for(0..($func->{numparms}-1))
 526         {
 527                 $p += $func->{parm_size}[$_];
 528         }
 529
 530         use constant WATCHME_R => 1;
 531         use constant WATCHME_W => 2;
 532         use constant WATCHME_X => 4;
 533         use constant WATCHME_T => 8;
 534         my %watchme = map { $_ => WATCHME_X } ($func->{parm_start} .. ($func->{parm_start} + $func->{locals} - 1));
 535
 536         for(keys %{$progs->{temps}})
 537         {
 538                 $watchme{$_} = WATCHME_T | WATCHME_X
 539                         if not exists $watchme{$_};
 540         }
 541
 542         run_nfa $progs, $func->{first_statement}, "", id, nfa_default_state_checker,
 543                 sub
 544                 {
 545                         my ($ip, $state, $s, $c) = @_;
 546                         for(qw(a b c))
 547                         {
 548                                 my $type = $c->{$_};
 549                                 next
 550                                         unless defined $type;
 551
 552                                 my $ofs = $s->{$_};
 553                                 if($type eq 'inglobal' || $type eq 'inglobalfunc')
 554                                 {
 555                                         $watchme{$ofs} |= WATCHME_R;
 556                                 }
 557                                 elsif($type eq 'inglobalvec')
 558                                 {
 559                                         $watchme{$ofs} |= WATCHME_R;
 560                                         $watchme{$ofs+1} |= WATCHME_R;
 561                                         $watchme{$ofs+2} |= WATCHME_R;
 562                                 }
 563                                 elsif($type eq 'outglobal')
 564                                 {
 565                                         $watchme{$ofs} |= WATCHME_W;
 566                                 }
 567                                 elsif($type eq 'outglobalvec')
 568                                 {
 569                                         $watchme{$ofs} |= WATCHME_W;
 570                                         $watchme{$ofs+1} |= WATCHME_W;
 571                                         $watchme{$ofs+2} |= WATCHME_W;
 572                                 }
 573                         }
 574
 575                         return 0;
 576                 };
 577
 578         for(keys %watchme)
 579         {
 580                 delete $watchme{$_}
 581                         if ($watchme{$_} & (WATCHME_R | WATCHME_W | WATCHME_X)) != (WATCHME_R | WATCHME_W | WATCHME_X);
 582         }
 583
 584         return
 585                 if not keys %watchme;
 586
 587         for(keys %watchme)
 588         {
 589                 $watchme{$_} = {
 590                         flags => $watchme{$_},
 591                         valid => 0
 592                 };
 593         }
 594
 595         # mark parameters as initialized
 596         for($func->{parm_start} .. ($p-1))
 597         {
 598                 $watchme{$_}{valid} = 1
 599                         if defined $watchme{$_};
 600         }
 601         # an initial run of STORE instruction is for receiving extra parameters
 602         # (beyond 8). Only possible if the function is declared as having 8 params.
 603         # Extra parameters behave otherwise like temps, but are initialized at
 604         # startup.
 605         for($func->{first_statement} .. (@{$progs->{statements}}-1))
 606         {
 607                 my $s = $progs->{statements}[$_];
 608                 if($s->{op} eq 'STORE_V')
 609                 {
 610                         $watchme{$s->{a}}{valid} = 1
 611                                 if defined $watchme{$s->{a}};
 612                         $watchme{$s->{a}+1}{valid} = 1
 613                                 if defined $watchme{$s->{a}+1};
 614                         $watchme{$s->{a}+2}{valid} = 1
 615                                 if defined $watchme{$s->{a}+2};
 616                 }
 617                 elsif($s->{op} =~ /^STORE_/)
 618                 {
 619                         $watchme{$s->{a}}{valid} = 1
 620                                 if defined $watchme{$s->{a}};
 621                 }
 622                 else
 623                 {
 624                         last;
 625                 }
 626         }
 627
 628         my %warned = ();
 629         my %ip_seen = ();
 630         run_nfa $progs, $func->{first_statement}, \%watchme,
 631                 sub {
 632                         my ($h) = @_;
 633                         return { map { $_ => { %{$h->{$_}} } } keys %$h };
 634                 },
 635                 sub {
 636                         my ($ip, $state) = @_;
 637                         my $s = $ip_seen{$ip};
 638                         if($s)
 639                         {
 640                                 # if $state is stronger or equal to $s, return 1
 641                                 for(keys %$state)
 642                                 {
 643                                         if($state->{$_}{valid} < $s->{$_})
 644                                         {
 645                                                 # The current state is LESS valid than the previously run one. We NEED to run this.
 646                                                 # The saved state can safely become the intersection [citation needed].
 647                                                 for(keys %$state)
 648                                                 {
 649                                                         $s->{$_} = $state->{$_}{valid}
 650                                                                 if $state->{$_}{valid} < $s->{$_};
 651                                                 }
 652                                                 return 0;
 653                                         }
 654                                 }
 655                                 # if we get here, $state is stronger or equal. No need to try it.
 656                                 return 1;
 657                         }
 658                         else
 659                         {
 660                                 # Never seen this IP yet.
 661                                 $ip_seen{$ip} = { map { ($_ => $state->{$_}{valid}); } keys %$state };
 662                                 return 0;
 663                         }
 664                 },
 665                 sub {
 666                         my ($ip, $state, $s, $c) = @_;
 667                         my $op = $s->{op};
 668                         for(qw(a b c))
 669                         {
 670                                 my $type = $c->{$_};
 671                                 next
 672                                         unless defined $type;
 673
 674                                 my $ofs = $s->{$_};
 675
 676                                 my $read = sub
 677                                 {
 678                                         my ($ofs) = @_;
 679                                         return
 680                                                 if not exists $state->{$ofs};
 681                                         my $valid = $state->{$ofs}{valid};
 682                                         if($valid == 0)
 683                                         {
 684                                                 print "; Use of uninitialized value $ofs in $func->{debugname} at $ip.$_\n";
 685                                                 ++$warned{$ip}{$_};
 686                                         }
 687                                         elsif($valid < 0)
 688                                         {
 689                                                 print "; Use of temporary $ofs across CALL in $func->{debugname} at $ip.$_\n";
 690                                                 ++$warned{$ip}{$_};
 691                                         }
 692                                 };
 693                                 my $write = sub
 694                                 {
 695                                         my ($ofs) = @_;
 696                                         $state->{$ofs}{valid} = 1
 697                                                 if exists $state->{$ofs};
 698                                 };
 699
 700                                 if($type eq 'inglobal' || $type eq 'inglobalfunc')
 701                                 {
 702                                         if($op ne 'OR' && $op ne 'AND') # fteqcc logicops cause this
 703                                         {
 704                                                 $read->($ofs);
 705                                         }
 706                                 }
 707                                 elsif($type eq 'inglobalvec')
 708                                 {
 709                                         if($op ne 'OR' && $op ne 'AND') # fteqcc logicops cause this
 710                                         {
 711                                                 $read->($ofs);
 712                                                 $read->($ofs+1);
 713                                                 $read->($ofs+2);
 714                                         }
 715                                 }
 716                                 elsif($type eq 'outglobal')
 717                                 {
 718                                         $write->($ofs);
 719                                 }
 720                                 elsif($type eq 'outglobalvec')
 721                                 {
 722                                         $write->($ofs);
 723                                         $write->($ofs+1);
 724                                         $write->($ofs+2);
 725                                 }
 726                         }
 727                         if($c->{iscall})
 728                         {
 729                                 # builtin calls may clobber stuff
 730                                 my $func = $s->{a};
 731                                 my $funcid = $progs->{globals}[$func]{v}{int};
 732                                 my $funcobj = $progs->{functions}[$funcid];
 733                                 if(!$funcobj || $funcobj->{first_statement} >= 0)
 734                                 {
 735                                         # invalidate temps
 736                                         for(values %$state)
 737                                         {
 738                                                 if($_->{flags} & WATCHME_T)
 739                                                 {
 740                                                         $_->{valid} = -1;
 741                                                 }
 742                                         }
 743                                 }
 744                                 else # builtin
 745                                 {
 746                                         my $def = $progs->{globaldef_byoffset}->($func);
 747                                         return 1
 748                                                 if $def->{debugname} eq 'error';
 749                                 }
 750                         }
 751
 752                         return 0;
 753                 };
 754
 755         disassemble_function($progs, $func, \%warned)
 756                 if keys %warned;
 757 }
 758
 759 use constant DEFAULTGLOBALS => [
 760         "OFS_NULL",
 761         "OFS_RETURN",
 762         "OFS_RETURN[1]",
 763         "OFS_RETURN[2]",
 764         "OFS_PARM0",
 765         "OFS_PARM0[1]",
 766         "OFS_PARM0[2]",
 767         "OFS_PARM1",
 768         "OFS_PARM1[1]",
 769         "OFS_PARM1[2]",
 770         "OFS_PARM2",
 771         "OFS_PARM2[1]",
 772         "OFS_PARM2[2]",
 773         "OFS_PARM3",
 774         "OFS_PARM3[1]",
 775         "OFS_PARM3[2]",
 776         "OFS_PARM4",
 777         "OFS_PARM4[1]",
 778         "OFS_PARM4[2]",
 779         "OFS_PARM5",
 780         "OFS_PARM5[1]",
 781         "OFS_PARM5[2]",
 782         "OFS_PARM6",
 783         "OFS_PARM6[1]",
 784         "OFS_PARM6[2]",
 785         "OFS_PARM7",
 786         "OFS_PARM7[1]",
 787         "OFS_PARM7[2]"
 788 ];
 789
 790 sub defaultglobal($)
 791 {
 792         my ($ofs) = @_;
 793         if($ofs < @{(DEFAULTGLOBALS)})
 794         {
 795                 return { ofs => $ofs, s_name => undef, debugname => DEFAULTGLOBALS->[$ofs], type => undef };
 796         }
 797         return { ofs => $ofs, s_name => undef, debugname => "<undefined>\@$ofs", type => undef };
 798 }
 799
 800 sub parse_progs($)
 801 {
 802         my ($fh) = @_;
 803
 804         my %p = ();
 805
 806         print STDERR "Parsing header...\n";
 807         $p{header} = parse_section $fh, DPROGRAMS_T, 0, undef, 1;
 808
 809         print STDERR "Parsing strings...\n";
 810         $p{strings} = get_section $fh, $p{header}{ofs_strings}, $p{header}{numstrings};
 811         $p{getstring} = sub
 812         {
 813                 my ($startpos) = @_;
 814                 my $endpos = index $p{strings}, "\0", $startpos;
 815                 return substr $p{strings}, $startpos, $endpos - $startpos;
 816         };
 817
 818         print STDERR "Parsing statements...\n";
 819         $p{statements} = [parse_section $fh, DSTATEMENT_T, $p{header}{ofs_statements}, undef, $p{header}{numstatements}];
 820
 821         print STDERR "Parsing globaldefs...\n";
 822         $p{globaldefs} = [parse_section $fh, DDEF_T, $p{header}{ofs_globaldefs}, undef, $p{header}{numglobaldefs}];
 823
 824         print STDERR "Parsing fielddefs...\n";
 825         $p{fielddefs} = [parse_section $fh, DDEF_T, $p{header}{ofs_fielddefs}, undef, $p{header}{numfielddefs}];
 826
 827         print STDERR "Parsing globals...\n";
 828         $p{globals} = [parse_section $fh, DGLOBAL_T, $p{header}{ofs_globals}, undef, $p{header}{numglobals}];
 829
 830         print STDERR "Parsing functions...\n";
 831         $p{functions} = [parse_section $fh, DFUNCTION_T, $p{header}{ofs_functions}, undef, $p{header}{numfunctions}];
 832
 833         print STDERR "Detecting temps...\n";
 834         my %offsets_saved = ();
 835         for(@{$p{globaldefs}})
 836         {
 837                 my $type = $_->{type};
 838                 my $name = $p{getstring}->($_->{s_name});
 839                 next
 840                         unless $type->{save} or $name ne "";
 841                 for my $i(0..(typesize($_->{type}{type})-1))
 842                 {
 843                         ++$offsets_saved{$_->{ofs}+$i};
 844                 }
 845         }
 846         my %offsets_initialized = ();
 847         for(0..(@{$p{globals}}-1))
 848         {
 849                 if($p{globals}[$_]{v}{int})
 850                 {
 851                         ++$offsets_initialized{$_};
 852                 }
 853         }
 854         my %istemp = ();
 855         my %isconst = ();
 856         for(0..(@{$p{globals}}-1))
 857         {
 858                 next
 859                         if $_ < @{(DEFAULTGLOBALS)};
 860                 ++$isconst{$_}
 861                         if !$offsets_saved{$_} and $offsets_initialized{$_};
 862                 ++$istemp{$_}
 863                         if !$offsets_saved{$_} and !$offsets_initialized{$_};
 864         }
 865         $p{temps} = \%istemp;
 866         $p{consts} = \%isconst;
 867
 868         print STDERR "Naming...\n";
 869
 870         # globaldefs
 871         my @globaldefs = ();
 872         for(@{$p{globaldefs}})
 873         {
 874                 my $s = $p{getstring}->($_->{s_name});
 875                 $_->{debugname} //= "_$s"
 876                         if length $s;
 877         }
 878         for(@{$p{globaldefs}})
 879         {
 880                 $globaldefs[$_->{ofs}] //= $_
 881                         if defined $_->{debugname};
 882         }
 883         for(@{$p{globaldefs}})
 884         {
 885                 $globaldefs[$_->{ofs}] //= $_;
 886         }
 887         for(0..(@{$p{globals}}-1))
 888         {
 889                 $globaldefs[$_] //= {
 890                         ofs => $_,
 891                         s_name => undef,
 892                         debugname => undef
 893                 };
 894         }
 895         my %globaldefs = ();
 896         for(@globaldefs)
 897         {
 898                 if(!defined $_->{debugname})
 899                 {
 900                         if($istemp{$_->{ofs}})
 901                         {
 902                                 $_->{debugname} = "temp_$_->{ofs}";
 903                         }
 904                         elsif($isconst{$_->{ofs}})
 905                         {
 906                                 $_->{debugname} = "(" . get_constant(\%p, $p{globals}[$_->{ofs}]{v}) . ")";
 907                         }
 908                         else
 909                         {
 910                                 $_->{debugname} = "global_$_->{ofs}";
 911                         }
 912                 }
 913                 ++$globaldefs{$_->{debugname}};
 914         }
 915         for(@globaldefs)
 916         {
 917                 next
 918                         if $globaldefs{$_->{debugname}} <= 1;
 919                 print "Not unique: $_->{debugname} at $_->{ofs}\n";
 920                 $_->{debugname} .= "\@$_->{ofs}";
 921         }
 922         $p{globaldef_byoffset} = sub
 923         {
 924                 my ($ofs) = @_;
 925                 $ofs &= 0xFFFF;
 926                 if($ofs >= 0 && $ofs < @{(DEFAULTGLOBALS)})
 927                 {
 928                         return { ofs => $ofs, s_name => undef, debugname => DEFAULTGLOBALS->[$ofs], type => undef };
 929                 }
 930                 my $def = $globaldefs[$ofs];
 931                 return $def;
 932         };
 933
 934         # functions
 935         my %functions = ();
 936         for(@{$p{functions}})
 937         {
 938                 my $file = $p{getstring}->($_->{s_file});
 939                 my $name = $p{getstring}->($_->{s_name});
 940                 $name = "$file:$name"
 941                         if length $file;
 942                 $_->{debugname} = $name;
 943                 $functions{$_->{first_statement}} = $_;
 944         }
 945         $p{function_byoffset} = sub
 946         {
 947                 my ($ofs) = @_;
 948                 return $functions{$ofs};
 949         };
 950
 951         # what do we want to do?
 952         my $checkfunc = \&find_uninitialized_locals;
 953         #my $checkfunc = \&disassemble_function;
 954         for(sort { $a->{debugname} cmp $b->{debugname} } @{$p{functions}})
 955         {
 956                 $checkfunc->(\%p, $_);
 957         }
 958 }
 959
 960 open my $fh, '<', $ARGV[0];
 961 parse_progs $fh;