misc/tools/midichannels.pl

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5 use MIDI;
   6 use MIDI::Opus;
   7
   8 my ($filename, @others) = @ARGV;
   9 my $opus = MIDI::Opus->new({from_file => $filename});
  10
  11 my %chanpos = (
  12         note_off => 2,
  13         note_on => 2,
  14         key_after_touch => 2,
  15         control_change => 2,
  16         patch_change => 2,
  17         channel_after_touch => 2,
  18         pitch_wheel_change => 2
  19 );
  20
  21 my %isclean = (
  22         set_tempo => sub { 1; },
  23         note_off => sub { 1; },
  24         note_on => sub { 1; },
  25         control_change => sub { $_[3] == 64; },
  26 );
  27
  28 sub abstime(@)
  29 {
  30         my $t = 0;
  31         return map { [$_->[0], $t += $_->[1], @{$_}[2..(@$_-1)]]; } @_;
  32 }
  33
  34 sub reltime(@)
  35 {
  36         my $t = 0;
  37         return map { my $tsave = $t; $t = $_->[1]; [$_->[0], $t - $tsave, @{$_}[2..(@$_-1)]]; } @_;
  38 }
  39
  40 sub clean(@)
  41 {
  42         return reltime grep { ($isclean{$_->[0]} // sub { 0; })->(@$_) } abstime @_;
  43 }
  44
  45 for(@others)
  46 {
  47         my $opus2 = MIDI::Opus->new({from_file => $_});
  48         if($opus2->ticks() != $opus->ticks())
  49         {
  50                 my $tickfactor = $opus->ticks() / $opus2->ticks();
  51                 for($opus2->tracks())
  52                 {
  53                         $_->events(reltime map { $_->[1] = int($_->[1] * $tickfactor + 0.5); $_; } abstime $_->events());
  54                 }
  55         }
  56         $opus->tracks($opus->tracks(), $opus2->tracks());
  57 }
  58
  59 while(<STDIN>)
  60 {
  61         chomp;
  62         my @arg = split /\s+/, $_;
  63         my $cmd = shift @arg;
  64         print "Executing: $cmd @arg\n";
  65         if($cmd eq 'clean')
  66         {
  67                 my $tracks = $opus->tracks_r();
  68                 $tracks->[$_]->events_r([clean($tracks->[$_]->events())])
  69                         for 0..@$tracks-1;
  70         }
  71         elsif($cmd eq 'dump')
  72         {
  73                 print $opus->dump({ dump_tracks => 1 });
  74         }
  75         elsif($cmd eq 'ticks')
  76         {
  77                 if(@arg)
  78                 {
  79                         $opus->ticks($arg[0]);
  80                 }
  81                 else
  82                 {
  83                         print "Ticks: ", $opus->ticks(), "\n";
  84                 }
  85         }
  86         elsif($cmd eq 'tricks')
  87         {
  88                 print "haha, very funny\n";
  89         }
  90         elsif($cmd eq 'retrack')
  91         {
  92                 my $tracks = $opus->tracks_r();
  93                 my @newtracks = ();
  94                 for(0..@$tracks-1)
  95                 {
  96                         for(abstime $tracks->[$_]->events())
  97                         {
  98                                 my $p = $chanpos{$_->[0]};
  99                                 if(defined $p)
 100                                 {
 101                                         my $c = $_->[$p] + 1;
 102                                         push @{$newtracks[$c]}, $_;
 103                                 }
 104                                 else
 105                                 {
 106                                         push @{$newtracks[0]}, $_;
 107                                 }
 108                         }
 109                 }
 110                 $opus->tracks_r([map { ($_ && @$_) ? MIDI::Track->new({ events => [reltime @$_] }) : () } @newtracks]);
 111         }
 112         elsif($cmd eq 'program')
 113         {
 114                 my $tracks = $opus->tracks_r();
 115                 my ($channel, $program) = @arg;
 116                 for(0..@$tracks-1)
 117                 {
 118                         my @events = ();
 119                         my $added = 0;
 120                         for(abstime $tracks->[$_]->events())
 121                         {
 122                                 my $p = $chanpos{$_->[0]};
 123                                 if(defined $p)
 124                                 {
 125                                         my $c = $_->[$p] + 1;
 126                                         if($c == $channel)
 127                                         {
 128                                                 next
 129                                                         if $_->[0] eq 'patch_change';
 130                                                 if(!$added)
 131                                                 {
 132                                                         push @events, ['patch_change', $_->[1], $c-1, $program-1]
 133                                                                 if $program;
 134                                                         $added = 1;
 135                                                 }
 136                                         }
 137                                 }
 138                                 push @events, $_;
 139                         }
 140                         $tracks->[$_]->events_r([reltime @events]);
 141                 }
 142         }
 143         elsif($cmd eq 'transpose')
 144         {
 145                 my $tracks = $opus->tracks_r();
 146                 my ($track, $channel, $delta) = @arg;
 147                 for(($track eq '*') ? (0..@$tracks-1) : $track)
 148                 {
 149                         for($tracks->[$_]->events())
 150                         {
 151                                 my $p = $chanpos{$_->[0]};
 152                                 if(defined $p)
 153                                 {
 154                                         my $c = $_->[$p] + 1;
 155                                         if($channel eq '*' || $c == $channel)
 156                                         {
 157                                                 if($_->[0] eq 'note_on' || $_->[0] eq 'note_off')
 158                                                 {
 159                                                         $_->[3] += $delta;
 160                                                 }
 161                                         }
 162                                 }
 163                         }
 164                 }
 165         }
 166         elsif($cmd eq 'percussion')
 167         {
 168                 my $tracks = $opus->tracks_r();
 169                 my %map = @arg;
 170                 for(0..@$tracks-1)
 171                 {
 172                         my @events = ();
 173                         for(abstime $tracks->[$_]->events())
 174                         {
 175                                 my $p = $chanpos{$_->[0]};
 176                                 if(defined $p)
 177                                 {
 178                                         my $c = $_->[$p] + 1;
 179                                         if($c == 10)
 180                                         {
 181                                                 if($_->[0] eq 'note_on' || $_->[0] eq 'note_off')
 182                                                 {
 183                                                         if(length $map{$_->[3]})
 184                                                         {
 185                                                                 $_->[3] = $map{$_->[3]};
 186                                                         }
 187                                                         elsif(exists $map{$_->[3]})
 188                                                         {
 189                                                                 next;
 190                                                         }
 191                                                 }
 192                                         }
 193                                 }
 194                                 push @events, $_;
 195                         }
 196                         $tracks->[$_]->events_r([reltime @events]);
 197                 }
 198         }
 199         elsif($cmd eq 'tracks')
 200         {
 201                 my $tracks = $opus->tracks_r();
 202                 if(@arg)
 203                 {
 204                         my %taken = ();
 205                         my @t = ();
 206                         my $force = 0;
 207                         for(@arg)
 208                         {
 209                                 if($_ eq '--force')
 210                                 {
 211                                         $force = 1;
 212                                         next;
 213                                 }
 214                                 next if $taken{$_}++ and not $force;
 215                                 push @t, $tracks->[$_];
 216                         }
 217                         $opus->tracks_r(\@t);
 218                 }
 219                 else
 220                 {
 221                         for(0..@$tracks-1)
 222                         {
 223                                 print "Track $_:";
 224                                 my $name = undef;
 225                                 my %channels = ();
 226                                 my $notes = 0;
 227                                 my %notehash = ();
 228                                 my $t = 0;
 229                                 my $events = 0;
 230                                 for($tracks->[$_]->events())
 231                                 {
 232                                         ++$events;
 233                                         $_->[0] = 'note_off' if $_->[0] eq 'note_on' and $_->[4] == 0;
 234                                         $t += $_->[1];
 235                                         my $p = $chanpos{$_->[0]};
 236                                         if(defined $p)
 237                                         {
 238                                                 my $c = $_->[$p] + 1;
 239                                                 $channels{$c} //= {};
 240                                                 if($_->[0] eq 'patch_change')
 241                                                 {
 242                                                         ++$channels{$c}{$_->[3]};
 243                                                 }
 244                                         }
 245                                         ++$notes if $_->[0] eq 'note_on';
 246                                         $notehash{$_->[2]}{$_->[3]} = $t if $_->[0] eq 'note_on';
 247                                         $notehash{$_->[2]}{$_->[3]} = undef if $_->[0] eq 'note_off';
 248                                         $name = $_->[2] if $_->[0] eq 'track_name';
 249                                 }
 250                                 my $channels = join " ", map { sprintf "%s(%s)", $_, join ",", sort { $a <=> $b } keys %{$channels{$_}} } sort { $a <=> $b } keys %channels;
 251                                 my @stuck = ();
 252                                 while(my ($k1, $v1) = each %notehash)
 253                                 {
 254                                         while(my ($k2, $v2) = each %$v1)
 255                                         {
 256                                                 push @stuck, sprintf "%d:%d@%.1f%%", $k1+1, $k2, $v2 * 100.0 / $t
 257                                                         if defined $v2;
 258                                         }
 259                                 }
 260                                 print " $name" if defined $name;
 261                                 print " (channel $channels)" if $channels ne "";
 262                                 print " ($events events)" if $events;
 263                                 print " ($notes notes)" if $notes;
 264                                 print " (notes @stuck stuck)" if @stuck;
 265                                 print "\n";
 266                         }
 267                 }
 268         }
 269         elsif($cmd eq 'save')
 270         {
 271                 $opus->write_to_file($arg[0]);
 272         }
 273         else
 274         {
 275                 print "Unknown command, allowed commands:\n";
 276                 print "  clean\n";
 277                 print "  dump\n";
 278                 print "  ticks [value]\n";
 279                 print "  retrack\n";
 280                 print "  program <channel> <program (1-based)>\n";
 281                 print "  transpose <track|*> <channel|*> <delta>\n";
 282                 print "  percussion <from> <to> [<from> <to> ...]\n";
 283                 print "  tracks [trackno] [trackno] ...\n";
 284         }
 285         print "Done with: $cmd @arg\n";
 286 }