qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || (e.weapons & WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         if (item.ammo_cells)
 383                                 player.ammo_cells = bound(player.ammo_cells, 999, player.ammo_cells + autocvar_g_minstagib_ammo_drop);
 384                         player.health = 100;
 385                 }
 386
 387                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 388                 {
 389                         pickedup = TRUE;
 390                         player.items |= it;
 391                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 392                 }
 393
 394                 // extralife powerup
 395                 if (item.max_health)
 396                 {
 397                         pickedup = TRUE;
 398                         // sound not available
 399                         // AnnounceTo(player, "_lives");
 400                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 401                         sprint(player, "^3You picked up some extra lives\n");
 402                 }
 403
 404                 // invis powerup
 405                 if (item.strength_finished)
 406                 {
 407                         pickedup = TRUE;
 408                         // sound not available
 409                         // AnnounceTo(player, "invisible");
 410                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 411                 }
 412
 413                 // speed powerup
 414                 if (item.invincible_finished)
 415                 {
 416                         pickedup = TRUE;
 417                         // sound not available
 418                         // AnnounceTo(player, "speed");
 419                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 420                 }
 421         }
 422         else
 423         {
 424                 // in case the player has autoswitch enabled do the following:
 425                 // if the player is using their best weapon before items are given, they
 426                 // probably want to switch to an even better weapon after items are given
 427                 if (player.autoswitch)
 428                 if (player.switchweapon == w_getbestweapon(player))
 429                         _switchweapon = TRUE;
 430
 431                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 432                         _switchweapon = TRUE;
 433
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 438                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 439                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 440                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 441
 442                 if (item.flags & FL_WEAPON)
 443                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && self.pickup_anyway))
 444                 {
 445                         pickedup = TRUE;
 446                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 447                         {
 448                                 e = get_weaponinfo(i);
 449                                 if(it & e.weapons)
 450                                         W_GiveWeapon (player, e.weapon, item.netname);
 451                         }
 452                 }
 453
 454                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 455                 {
 456                         pickedup = TRUE;
 457                         player.items |= it;
 458                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 459                 }
 460
 461                 if (item.strength_finished)
 462                 {
 463                         pickedup = TRUE;
 464                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 465                 }
 466                 if (item.invincible_finished)
 467                 {
 468                         pickedup = TRUE;
 469                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 470                 }
 471                 if (item.superweapons_finished)
 472                 {
 473                         pickedup = TRUE;
 474                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 475                 }
 476         }
 477
 478 :skip
 479         // always eat teamed entities
 480         if(item.team)
 481                 pickedup = TRUE;
 482
 483         if (!pickedup)
 484                 return 0;
 485
 486         if (_switchweapon)
 487                 if (player.switchweapon != w_getbestweapon(player))
 488                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 489
 490         return 1;
 491 }
 492
 493 void Item_Touch (void)
 494 {
 495         entity e, head;
 496
 497         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 498         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 499         {
 500                 remove(self);
 501                 return;
 502         }
 503         if (other.classname != "player")
 504                 return;
 505         if (other.deadflag)
 506                 return;
 507         if (self.solid != SOLID_TRIGGER)
 508                 return;
 509         if (self.owner == other)
 510                 return;
 511
 512         if (self.classname == "droppedweapon")
 513         {
 514                 self.strength_finished = max(0, self.strength_finished - time);
 515                 self.invincible_finished = max(0, self.invincible_finished - time);
 516                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 517         }
 518
 519         if(!Item_GiveTo(self, other))
 520         {
 521                 if (self.classname == "droppedweapon")
 522                 {
 523                         // undo what we did above
 524                         self.strength_finished += time;
 525                         self.invincible_finished += time;
 526                         self.superweapons_finished += time;
 527                 }
 528                 return;
 529         }
 530
 531         other.last_pickup = time;
 532
 533         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 534         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 535
 536         if (self.classname == "droppedweapon")
 537                 remove (self);
 538         else if not(self.spawnshieldtime)
 539                 return;
 540         else
 541         {
 542                 if(self.team)
 543                 {
 544                         RandomSelection_Init();
 545                         for(head = world; (head = findfloat(head, team, self.team)); )
 546                         {
 547                                 if(head.flags & FL_ITEM)
 548                                 {
 549                                         Item_Show(head, -1);
 550                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 551                                 }
 552                         }
 553                         e = RandomSelection_chosen_ent;
 554                 }
 555                 else
 556                         e = self;
 557                 Item_ScheduleRespawn(e);
 558         }
 559 }
 560
 561 void Item_Reset()
 562 {
 563         Item_Show(self, !self.state);
 564         setorigin (self, self.origin);
 565
 566         if(self.classname != "droppedweapon")
 567         {
 568                 self.think = SUB_Null;
 569                 self.nextthink = 0;
 570
 571                 if(self.waypointsprite_attached)
 572                         WaypointSprite_Kill(self.waypointsprite_attached);
 573
 574                 if((self.flags & FL_POWERUP) | (self.weapons & WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 575                         Item_ScheduleInitialRespawn(self);
 576         }
 577 }
 578
 579 void Item_FindTeam()
 580 {
 581         entity head, e;
 582
 583         if(self.effects & EF_NODRAW)
 584         {
 585                 // marker for item team search
 586                 dprint("Initializing item team ", ftos(self.team), "\n");
 587                 RandomSelection_Init();
 588                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 589                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 590                 e = RandomSelection_chosen_ent;
 591                 e.state = 0;
 592                 Item_Show(e, 1);
 593
 594                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 595                 {
 596                         if(head != e)
 597                         {
 598                                 // make it a non-spawned item
 599                                 Item_Show(head, -1);
 600                                 head.state = 1; // state 1 = initially hidden item
 601                         }
 602                         head.effects &~= EF_NODRAW;
 603                 }
 604
 605                 Item_Reset();
 606         }
 607 }
 608
 609 // Savage: used for item garbage-collection
 610 // TODO: perhaps nice special effect?
 611 void RemoveItem(void)
 612 {
 613         remove(self);
 614 }
 615
 616 // pickup evaluation functions
 617 // these functions decide how desirable an item is to the bots
 618
 619 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 620
 621 float weapon_pickupevalfunc(entity player, entity item)
 622 {
 623         float c, i, j, position;
 624
 625         // See if I have it already
 626         if(player.weapons & item.weapons == item.weapons)
 627         {
 628                 // If I can pick it up
 629                 if(!item.spawnshieldtime)
 630                         c = 0;
 631                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 632                 {
 633                         // Skilled bots will grab more
 634                         c = bound(0, skill / 10, 1) * 0.5;
 635                 }
 636                 else
 637                         c = 0;
 638         }
 639         else
 640                 c = 1;
 641
 642         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 643         if( bot_custom_weapon && c )
 644         {
 645                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 646                 {
 647                         // Find weapon
 648                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 649                                 continue;
 650
 651                         // Find the highest position on any range
 652                         position = -1;
 653                         for(j = 0; j < WEP_LAST ; ++j){
 654                                 if(
 655                                                 bot_weapons_far[j] == i ||
 656                                                 bot_weapons_mid[j] == i ||
 657                                                 bot_weapons_close[j] == i
 658                                   )
 659                                 {
 660                                         position = j;
 661                                         break;
 662                                 }
 663                         }
 664
 665                         // Rate it
 666                         if (position >= 0 )
 667                         {
 668                                 position = WEP_LAST - position;
 669                                 // item.bot_pickupbasevalue is overwritten here
 670                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 671                         }
 672                 }
 673         }
 674
 675         return item.bot_pickupbasevalue * c;
 676 }
 677
 678 float commodity_pickupevalfunc(entity player, entity item)
 679 {
 680         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 681         entity wi;
 682         c = 0;
 683
 684         // Detect needed ammo
 685         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 686         {
 687                 wi = get_weaponinfo(i);
 688
 689                 if not(wi.weapons & player.weapons)
 690                         continue;
 691
 692                 if(wi.items & IT_SHELLS)
 693                         need_shells = TRUE;
 694                 else if(wi.items & IT_NAILS)
 695                         need_nails = TRUE;
 696                 else if(wi.items & IT_ROCKETS)
 697                         need_rockets = TRUE;
 698                 else if(wi.items & IT_CELLS)
 699                         need_cells = TRUE;
 700                 else if(wi.items & IT_FUEL)
 701                         need_cells = TRUE;
 702         }
 703
 704         // TODO: figure out if the player even has the weapon this ammo is for?
 705         // may not affect strategy much though...
 706         // find out how much more ammo/armor/health the player can hold
 707         if (need_shells)
 708         if (item.ammo_shells)
 709         if (player.ammo_shells < g_pickup_shells_max)
 710                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 711         if (need_nails)
 712         if (item.ammo_nails)
 713         if (player.ammo_nails < g_pickup_nails_max)
 714                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 715         if (need_rockets)
 716         if (item.ammo_rockets)
 717         if (player.ammo_rockets < g_pickup_rockets_max)
 718                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 719         if (need_cells)
 720         if (item.ammo_cells)
 721         if (player.ammo_cells < g_pickup_cells_max)
 722                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 723         if (need_fuel)
 724         if (item.ammo_fuel)
 725         if (player.ammo_fuel < g_pickup_fuel_max)
 726                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 727         if (item.armorvalue)
 728         if (player.armorvalue < item.max_armorvalue)
 729                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 730         if (item.health)
 731         if (player.health < item.max_health)
 732                 c = c + max(0, 1 - player.health / item.max_health);
 733
 734         return item.bot_pickupbasevalue * c;
 735 }
 736
 737
 738 .float is_item;
 739 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 740 {
 741         startitem_failed = FALSE;
 742
 743         self.items = itemid;
 744         self.weapons = weaponid;
 745         self.flags = FL_ITEM | itemflags;
 746
 747         // is it a dropped weapon?
 748         if (self.classname == "droppedweapon")
 749         {
 750                 self.reset = SUB_Remove;
 751                 // it's a dropped weapon
 752                 self.movetype = MOVETYPE_TOSS;
 753
 754                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 755                 self.think = RemoveItem;
 756                 self.nextthink = time + 20;
 757
 758                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 759                 /*
 760                 if(self.items == 0)
 761                 if(self.weapons == (self.weapons & WEPBIT_SUPERWEAPONS)) // only superweapons
 762                 if(self.ammo_nails == 0)
 763                 if(self.ammo_cells == 0)
 764                 if(self.ammo_rockets == 0)
 765                 if(self.ammo_shells == 0)
 766                 if(self.ammo_fuel == 0)
 767                 if(self.health == 0)
 768                 if(self.armorvalue == 0)
 769                 */
 770                 {
 771                         // if item is worthless after a timer, have it expire then
 772                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 773                 }
 774
 775                 // don't drop if in a NODROP zone (such as lava)
 776                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 777                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 778                 {
 779                         startitem_failed = TRUE;
 780                         remove(self);
 781                         return;
 782                 }
 783         }
 784         else
 785         {
 786                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 787                 {
 788                         startitem_failed = TRUE;
 789                         remove(self);
 790                         return;
 791                 }
 792
 793                 if(!have_pickup_item())
 794                 {
 795                         startitem_failed = TRUE;
 796                         remove (self);
 797                         return;
 798                 }
 799
 800                 if(self.model != "")
 801                         itemmodel = self.model;
 802                 if(self.item_pickupsound != "")
 803                         pickupsound = self.item_pickupsound;
 804
 805                 self.reset = Item_Reset;
 806                 // it's a level item
 807                 if(self.spawnflags & 1)
 808                         self.noalign = 1;
 809                 if (self.noalign)
 810                         self.movetype = MOVETYPE_NONE;
 811                 else
 812                         self.movetype = MOVETYPE_TOSS;
 813                 // do item filtering according to game mode and other things
 814                 if (!self.noalign)
 815                 {
 816                         // first nudge it off the floor a little bit to avoid math errors
 817                         setorigin(self, self.origin + '0 0 1');
 818                         // set item size before we spawn a spawnfunc_waypoint
 819                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 820                                 setsize (self, '-16 -16 0', '16 16 48');
 821                         else
 822                                 setsize (self, '-16 -16 0', '16 16 32');
 823                         // note droptofloor returns FALSE if stuck/or would fall too far
 824                         droptofloor();
 825                         waypoint_spawnforitem(self);
 826                 }
 827
 828                 /*
 829                  * can't do it that way, as it would break maps
 830                  * TODO make a target_give like entity another way, that perhaps has
 831                  * the weapon name in a key
 832                 if(self.targetname)
 833                 {
 834                         // target_give not yet supported; maybe later
 835                         print("removed targeted ", self.classname, "\n");
 836                         startitem_failed = TRUE;
 837                         remove (self);
 838                         return;
 839                 }
 840                 */
 841
 842                 if(autocvar_spawn_debug >= 2)
 843                 {
 844                         entity otheritem;
 845                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 846                         {
 847                                 if(otheritem.is_item)
 848                                 {
 849                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 850                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 851                                         error("Mapper sucks.");
 852                                 }
 853                         }
 854                         self.is_item = TRUE;
 855                 }
 856
 857                 weaponsInMap |= weaponid;
 858
 859                 precache_model (itemmodel);
 860                 precache_sound (pickupsound);
 861
 862                 precache_sound ("misc/itemrespawncountdown.wav");
 863                 if(!g_minstagib && itemid == IT_STRENGTH)
 864                         precache_sound ("misc/strength_respawn.wav");
 865                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 866                         precache_sound ("misc/shield_respawn.wav");
 867                 else
 868                         precache_sound ("misc/itemrespawn.wav");
 869
 870                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 871                         self.target = "###item###"; // for finding the nearest item using find()
 872         }
 873
 874         self.bot_pickup = TRUE;
 875         self.bot_pickupevalfunc = pickupevalfunc;
 876         self.bot_pickupbasevalue = pickupbasevalue;
 877         self.mdl = itemmodel;
 878         self.item_pickupsound = pickupsound;
 879         if(self.weapons)
 880                 self.weapon = WEP_FIRST + log2of(lowestbit(self.weapons));
 881         else
 882                 self.weapon = 0;
 883         // let mappers override respawntime
 884         if(!self.respawntime) // both set
 885         {
 886                 self.respawntime = defaultrespawntime;
 887                 self.respawntimejitter = defaultrespawntimejitter;
 888         }
 889         self.netname = itemname;
 890         self.touch = Item_Touch;
 891         setmodel (self, self.mdl); // precision set below
 892         self.effects |= EF_LOWPRECISION;
 893         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 894                 setsize (self, '-16 -16 0', '16 16 48');
 895         else
 896                 setsize (self, '-16 -16 0', '16 16 32');
 897         if(itemflags & FL_WEAPON)
 898                 self.modelflags |= MF_ROTATE;
 899
 900         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 901         if (itemflags & FL_WEAPON)
 902         {
 903                 // neutral team color for pickup weapons
 904                 self.colormap = 1024; // color shirt=0 pants=0 grey
 905         }
 906
 907         self.state = 0;
 908         if(self.team)
 909         {
 910                 if(!self.cnt)
 911                         self.cnt = 1; // item probability weight
 912                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 913                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 914         }
 915         else
 916                 Item_Reset();
 917 }
 918
 919 /* replace items in minstagib
 920  * IT_STRENGTH   = invisibility
 921  * IT_NAILS      = extra lives
 922  * IT_INVINCIBLE = speed
 923  */
 924 void minstagib_items (float itemid)
 925 {
 926         float rnd;
 927         self.classname = "minstagib";
 928
 929         // replace rocket launchers and nex guns with ammo cells
 930         if (itemid == IT_CELLS)
 931         {
 932                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 933                 StartItem ("models/items/a_cells.md3",
 934                         "misc/itempickup.wav", 45, 0,
 935                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 936                 return;
 937         }
 938
 939         // randomize
 940         rnd = random() * 3;
 941         if (rnd <= 1)
 942                 itemid = IT_STRENGTH;
 943         else if (rnd <= 2)
 944                 itemid = IT_NAILS;
 945         else
 946                 itemid = IT_INVINCIBLE;
 947
 948         // replace with invis
 949         if (itemid == IT_STRENGTH)
 950         {
 951                 if(!self.strength_finished)
 952                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 953                 StartItem ("models/items/g_strength.md3",
 954                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 955                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 956         }
 957         // replace with extra lives
 958         if (itemid == IT_NAILS)
 959         {
 960                 self.max_health = 1;
 961                 StartItem ("models/items/g_h100.md3",
 962                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 963                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 964         }
 965         // replace with speed
 966         if (itemid == IT_INVINCIBLE)
 967         {
 968                 if(!self.invincible_finished)
 969                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 970                 StartItem ("models/items/g_invincible.md3",
 971                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 972                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 973         }
 974 }
 975
 976 float minst_no_auto_cells;
 977 void minst_remove_item (void) {
 978         if(minst_no_auto_cells)
 979                 remove(self);
 980 }
 981
 982 float weaponswapping;
 983 float internalteam;
 984
 985 void weapon_defaultspawnfunc(float wpn)
 986 {
 987         entity e;
 988         float t;
 989         var .float ammofield;
 990         string s;
 991         entity oldself;
 992         float i, j;
 993         float f;
 994
 995         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 996         {
 997                 e = get_weaponinfo(wpn);
 998                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 999                 if(s == "0")
1000                 {
1001                         remove(self);
1002                         startitem_failed = TRUE;
1003                         return;
1004                 }
1005                 t = tokenize_console(s);
1006                 if(t >= 2)
1007                 {
1008                         self.team = --internalteam;
1009                         oldself = self;
1010                         for(i = 1; i < t; ++i)
1011                         {
1012                                 s = argv(i);
1013                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1014                                 {
1015                                         e = get_weaponinfo(j);
1016                                         if(e.netname == s)
1017                                         {
1018                                                 self = spawn();
1019                                                 copyentity(oldself, self);
1020                                                 self.classname = "replacedweapon";
1021                                                 weapon_defaultspawnfunc(j);
1022                                                 break;
1023                                         }
1024                                 }
1025                                 if(j > WEP_LAST)
1026                                 {
1027                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1028                                 }
1029                         }
1030                         self = oldself;
1031                 }
1032                 if(t >= 1)
1033                 {
1034                         s = argv(0);
1035                         wpn = 0;
1036                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1037                         {
1038                                 e = get_weaponinfo(j);
1039                                 if(e.netname == s)
1040                                 {
1041                                         wpn = j;
1042                                         break;
1043                                 }
1044                         }
1045                         if(j > WEP_LAST)
1046                         {
1047                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1048                         }
1049                 }
1050                 if(wpn == 0)
1051                 {
1052                         remove(self);
1053                         startitem_failed = TRUE;
1054                         return;
1055                 }
1056         }
1057
1058         e = get_weaponinfo(wpn);
1059
1060         if(!self.respawntime)
1061         {
1062                 if(e.weapons & WEPBIT_SUPERWEAPONS)
1063                 {
1064                         self.respawntime = g_pickup_respawntime_superweapon;
1065                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1066                 }
1067                 else
1068                 {
1069                         self.respawntime = g_pickup_respawntime_weapon;
1070                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1071                 }
1072         }
1073
1074         if(e.weapons & WEPBIT_SUPERWEAPONS)
1075                 if(!self.superweapons_finished)
1076                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1077
1078         if(e.items)
1079         {
1080                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1081                 {
1082                         if(e.items & j)
1083                         {
1084                                 ammofield = Item_CounterField(j);
1085                                 if(!self.ammofield)
1086                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1087                         }
1088                 }
1089         }
1090
1091         // pickup anyway
1092         if(g_pickup_weapons_anyway)
1093                 self.pickup_anyway = TRUE;
1094
1095         f = FL_WEAPON;
1096
1097         // no weapon-stay on superweapons
1098         if(e.weapons & WEPBIT_SUPERWEAPONS)
1099                 f |= FL_NO_WEAPON_STAY;
1100
1101         // weapon stay isn't supported for teamed weapons
1102         if(self.team)
1103                 f |= FL_NO_WEAPON_STAY;
1104
1105         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1106         if (self.modelindex) // don't precache if self was removed
1107                 weapon_action(e.weapon, WR_PRECACHE);
1108 }
1109
1110 void spawnfunc_weapon_shotgun (void);
1111 void spawnfunc_weapon_uzi (void) {
1112         if(autocvar_sv_q3acompat_machineshotgunswap)
1113         if(self.classname != "droppedweapon")
1114         {
1115                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1116                 return;
1117         }
1118         weapon_defaultspawnfunc(WEP_UZI);
1119 }
1120
1121 void spawnfunc_weapon_shotgun (void) {
1122         if(autocvar_sv_q3acompat_machineshotgunswap)
1123         if(self.classname != "droppedweapon")
1124         {
1125                 weapon_defaultspawnfunc(WEP_UZI);
1126                 return;
1127         }
1128         weapon_defaultspawnfunc(WEP_SHOTGUN);
1129 }
1130
1131 void spawnfunc_weapon_nex (void)
1132 {
1133         if (g_minstagib)
1134         {
1135                 minstagib_items(IT_CELLS);
1136                 self.think = minst_remove_item;
1137                 self.nextthink = time;
1138                 return;
1139         }
1140         weapon_defaultspawnfunc(WEP_NEX);
1141 }
1142
1143 void spawnfunc_weapon_minstanex (void)
1144 {
1145         if (g_minstagib)
1146         {
1147                 minstagib_items(IT_CELLS);
1148                 self.think = minst_remove_item;
1149                 self.nextthink = time;
1150                 return;
1151         }
1152         weapon_defaultspawnfunc(WEP_MINSTANEX);
1153 }
1154
1155 void spawnfunc_weapon_rocketlauncher (void)
1156 {
1157         if (g_minstagib)
1158         {
1159                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1160                 self.think = minst_remove_item;
1161                 self.nextthink = time;
1162                 return;
1163         }
1164         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1165 }
1166
1167 void spawnfunc_item_rockets (void) {
1168         if(!self.ammo_rockets)
1169                 self.ammo_rockets = g_pickup_rockets;
1170         if(!self.pickup_anyway)
1171                 self.pickup_anyway = g_pickup_ammo_anyway;
1172         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1173 }
1174
1175 void spawnfunc_item_shells (void);
1176 void spawnfunc_item_bullets (void) {
1177         if(!weaponswapping)
1178         if(autocvar_sv_q3acompat_machineshotgunswap)
1179         if(self.classname != "droppedweapon")
1180         {
1181                 weaponswapping = TRUE;
1182                 spawnfunc_item_shells();
1183                 weaponswapping = FALSE;
1184                 return;
1185         }
1186
1187         if(!self.ammo_nails)
1188                 self.ammo_nails = g_pickup_nails;
1189         if(!self.pickup_anyway)
1190                 self.pickup_anyway = g_pickup_ammo_anyway;
1191         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1192 }
1193
1194 void spawnfunc_item_cells (void) {
1195         if(!self.ammo_cells)
1196                 self.ammo_cells = g_pickup_cells;
1197         if(!self.pickup_anyway)
1198                 self.pickup_anyway = g_pickup_ammo_anyway;
1199         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1200 }
1201
1202 void spawnfunc_item_shells (void) {
1203         if(!weaponswapping)
1204         if(autocvar_sv_q3acompat_machineshotgunswap)
1205         if(self.classname != "droppedweapon")
1206         {
1207                 weaponswapping = TRUE;
1208                 spawnfunc_item_bullets();
1209                 weaponswapping = FALSE;
1210                 return;
1211         }
1212
1213         if(!self.ammo_shells)
1214                 self.ammo_shells = g_pickup_shells;
1215         if(!self.pickup_anyway)
1216                 self.pickup_anyway = g_pickup_ammo_anyway;
1217         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1218 }
1219
1220 void spawnfunc_item_armor_small (void) {
1221         if(!self.armorvalue)
1222                 self.armorvalue = g_pickup_armorsmall;
1223         if(!self.max_armorvalue)
1224                 self.max_armorvalue = g_pickup_armorsmall_max;
1225         if(!self.pickup_anyway)
1226                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1227         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1228 }
1229
1230 void spawnfunc_item_armor_medium (void) {
1231         if(!self.armorvalue)
1232                 self.armorvalue = g_pickup_armormedium;
1233         if(!self.max_armorvalue)
1234                 self.max_armorvalue = g_pickup_armormedium_max;
1235         if(!self.pickup_anyway)
1236                 self.pickup_anyway = g_pickup_armormedium_anyway;
1237         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1238 }
1239
1240 void spawnfunc_item_armor_big (void) {
1241         if(!self.armorvalue)
1242                 self.armorvalue = g_pickup_armorbig;
1243         if(!self.max_armorvalue)
1244                 self.max_armorvalue = g_pickup_armorbig_max;
1245         if(!self.pickup_anyway)
1246                 self.pickup_anyway = g_pickup_armorbig_anyway;
1247         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1248 }
1249
1250 void spawnfunc_item_armor_large (void) {
1251         if(!self.armorvalue)
1252                 self.armorvalue = g_pickup_armorlarge;
1253         if(!self.max_armorvalue)
1254                 self.max_armorvalue = g_pickup_armorlarge_max;
1255         if(!self.pickup_anyway)
1256                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1257         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1258 }
1259
1260 void spawnfunc_item_health_small (void) {
1261         if(!self.max_health)
1262                 self.max_health = g_pickup_healthsmall_max;
1263         if(!self.health)
1264                 self.health = g_pickup_healthsmall;
1265         if(!self.pickup_anyway)
1266                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1267         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1268 }
1269
1270 void spawnfunc_item_health_medium (void) {
1271         if(!self.max_health)
1272                 self.max_health = g_pickup_healthmedium_max;
1273         if(!self.health)
1274                 self.health = g_pickup_healthmedium;
1275         if(!self.pickup_anyway)
1276                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1277         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1278 }
1279
1280 void spawnfunc_item_health_large (void) {
1281         if(!self.max_health)
1282                 self.max_health = g_pickup_healthlarge_max;
1283         if(!self.health)
1284                 self.health = g_pickup_healthlarge;
1285         if(!self.pickup_anyway)
1286                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1287         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1288 }
1289
1290 void spawnfunc_item_health_mega (void) {
1291         if(g_minstagib) {
1292                 minstagib_items(IT_NAILS);
1293         } else {
1294                 if(!self.max_health)
1295                         self.max_health = g_pickup_healthmega_max;
1296                 if(!self.health)
1297                         self.health = g_pickup_healthmega;
1298                 if(!self.pickup_anyway)
1299                         self.pickup_anyway = g_pickup_healthmega_anyway;
1300                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1301         }
1302 }
1303
1304 // support old misnamed entities
1305 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1306 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1307 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1308 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1309 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1310
1311 void spawnfunc_item_strength (void) {
1312         if(g_minstagib) {
1313                 minstagib_items(IT_STRENGTH);
1314         } else {
1315                 precache_sound("weapons/strength_fire.wav");
1316                 if(!self.strength_finished)
1317                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1318                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1319         }
1320 }
1321
1322 void spawnfunc_item_invincible (void) {
1323         if(g_minstagib) {
1324                 minstagib_items(IT_INVINCIBLE);
1325         } else {
1326                 if(!self.invincible_finished)
1327                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1328                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1329         }
1330 }
1331
1332 void spawnfunc_item_minst_cells (void) {
1333         if (g_minstagib)
1334         {
1335                 minst_no_auto_cells = 1;
1336                 minstagib_items(IT_CELLS);
1337         }
1338         else
1339                 remove(self);
1340 }
1341
1342 // compatibility:
1343 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1344
1345 float GiveItems(entity e, float beginarg, float endarg);
1346 void target_items_use (void)
1347 {
1348         if(activator.classname == "droppedweapon")
1349         {
1350                 EXACTTRIGGER_TOUCH;
1351                 remove(activator);
1352                 return;
1353         }
1354
1355         if(activator.classname != "player")
1356                 return;
1357         if(activator.deadflag != DEAD_NO)
1358                 return;
1359         EXACTTRIGGER_TOUCH;
1360
1361         entity e;
1362         for(e = world; (e = find(e, classname, "droppedweapon")); )
1363                 if(e.enemy == activator)
1364                         remove(e);
1365
1366         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1367                 centerprint(activator, self.message);
1368 }
1369
1370 void spawnfunc_target_items (void)
1371 {
1372         float n, i, j;
1373         entity e;
1374
1375         self.use = target_items_use;
1376         if(!self.strength_finished)
1377                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1378         if(!self.invincible_finished)
1379                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1380         if(!self.superweapons_finished)
1381                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1382
1383         precache_sound("misc/itempickup.wav");
1384         precache_sound("misc/megahealth.wav");
1385         precache_sound("misc/armor25.wav");
1386         precache_sound("misc/powerup.wav");
1387         precache_sound("misc/poweroff.wav");
1388         precache_sound("weapons/weaponpickup.wav");
1389
1390         n = tokenize_console(self.netname);
1391         if(argv(0) == "give")
1392         {
1393                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1394         }
1395         else
1396         {
1397                 for(i = 0; i < n; ++i)
1398                 {
1399                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1400                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1401                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1402                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1403                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1404                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1405                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1406                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1407                         else
1408                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1409                         {
1410                                 e = get_weaponinfo(j);
1411                                 if(argv(i) == e.netname)
1412                                 {
1413                                         self.weapons |= e.weapons;
1414                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1415                                                 weapon_action(e.weapon, WR_PRECACHE);
1416                                         break;
1417                                 }
1418                         }
1419                         if(j > WEP_LAST)
1420                                 print("target_items: invalid item ", argv(i), "\n");
1421                 }
1422
1423                 string itemprefix, valueprefix;
1424                 if(self.spawnflags == 0)
1425                 {
1426                         itemprefix = "";
1427                         valueprefix = "";
1428                 }
1429                 else if(self.spawnflags == 1)
1430                 {
1431                         itemprefix = "max ";
1432                         valueprefix = "max ";
1433                 }
1434                 else if(self.spawnflags == 2)
1435                 {
1436                         itemprefix = "min ";
1437                         valueprefix = "min ";
1438                 }
1439                 else if(self.spawnflags == 4)
1440                 {
1441                         itemprefix = "minus ";
1442                         valueprefix = "max ";
1443                 }
1444                 else
1445                         error("invalid spawnflags");
1446
1447                 self.netname = "";
1448                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1449                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1450                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1451                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1452                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1453                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1454                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1455                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1456                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1457                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1458                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1459                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1460                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1461                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1462                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1463                 {
1464                         e = get_weaponinfo(j);
1465                         if(e.weapons)
1466                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1467                 }
1468         }
1469         self.netname = strzone(self.netname);
1470         //print(self.netname, "\n");
1471
1472         n = tokenize_console(self.netname);
1473         for(i = 0; i < n; ++i)
1474         {
1475                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1476                 {
1477                         e = get_weaponinfo(j);
1478                         if(argv(i) == e.netname)
1479                         {
1480                                 weapon_action(e.weapon, WR_PRECACHE);
1481                                 break;
1482                         }
1483                 }
1484         }
1485 }
1486
1487 void spawnfunc_item_fuel(void)
1488 {
1489         if(!self.ammo_fuel)
1490                 self.ammo_fuel = g_pickup_fuel;
1491         if(!self.pickup_anyway)
1492                 self.pickup_anyway = g_pickup_ammo_anyway;
1493         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1494 }
1495
1496 void spawnfunc_item_fuel_regen(void)
1497 {
1498         if(start_items & IT_FUEL_REGEN)
1499         {
1500                 spawnfunc_item_fuel();
1501                 return;
1502         }
1503         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1504 }
1505
1506 void spawnfunc_item_jetpack(void)
1507 {
1508         if(g_grappling_hook)
1509                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1510         if(!self.ammo_fuel)
1511                 self.ammo_fuel = g_pickup_fuel_jetpack;
1512         if(start_items & IT_JETPACK)
1513         {
1514                 spawnfunc_item_fuel();
1515                 return;
1516         }
1517         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1518 }
1519
1520
1521 #define OP_SET 0
1522 #define OP_MIN 1
1523 #define OP_MAX 2
1524 #define OP_PLUS 3
1525 #define OP_MINUS 4
1526
1527 float GiveBit(entity e, .float fld, float bit, float op, float val)
1528 {
1529         float v0, v1;
1530         v0 = (e.fld & bit);
1531         switch(op)
1532         {
1533                 case OP_SET:
1534                         if(val > 0)
1535                                 e.fld |= bit;
1536                         else
1537                                 e.fld &~= bit;
1538                         break;
1539                 case OP_MIN:
1540                 case OP_PLUS:
1541                         if(val > 0)
1542                                 e.fld |= bit;
1543                         break;
1544                 case OP_MAX:
1545                         if(val <= 0)
1546                                 e.fld &~= bit;
1547                         break;
1548                 case OP_MINUS:
1549                         if(val > 0)
1550                                 e.fld &~= bit;
1551                         break;
1552         }
1553         v1 = (e.fld & bit);
1554         return (v0 != v1);
1555 }
1556
1557 float GiveValue(entity e, .float fld, float op, float val)
1558 {
1559         float v0, v1;
1560         v0 = e.fld;
1561         switch(op)
1562         {
1563                 case OP_SET:
1564                         e.fld = val;
1565                         break;
1566                 case OP_MIN:
1567                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1568                         break;
1569                 case OP_MAX:
1570                         e.fld = min(e.fld, val);
1571                         break;
1572                 case OP_PLUS:
1573                         e.fld += val;
1574                         break;
1575                 case OP_MINUS:
1576                         e.fld -= val;
1577                         break;
1578         }
1579         v1 = e.fld;
1580         return (v0 != v1);
1581 }
1582
1583 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1584 {
1585         if(v1 == v0)
1586                 return;
1587         if(v1 <= v0 - t)
1588         {
1589                 if(snd_decr != "")
1590                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1591         }
1592         else if(v0 >= v0 + t)
1593         {
1594                 if(snd_incr != "")
1595                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1596         }
1597 }
1598
1599 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1600 {
1601         if(v0 < v1)
1602                 e.rotfield = max(e.rotfield, time + rottime);
1603         else if(v0 > v1)
1604                 e.regenfield = max(e.regenfield, time + regentime);
1605 }
1606
1607 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1608 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1609 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1610 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1611
1612 float GiveItems(entity e, float beginarg, float endarg)
1613 {
1614         float got, i, j, val, op;
1615         float _switchweapon;
1616         entity wi;
1617         string cmd;
1618
1619         val = 999;
1620         op = OP_SET;
1621
1622         got = 0;
1623
1624         _switchweapon = FALSE;
1625         if (e.autoswitch)
1626                 if (e.switchweapon == w_getbestweapon(e))
1627                         _switchweapon = TRUE;
1628
1629         e.strength_finished = max(0, e.strength_finished - time);
1630         e.invincible_finished = max(0, e.invincible_finished - time);
1631         e.superweapons_finished = max(0, e.superweapons_finished - time);
1632
1633         PREGIVE(e, items);
1634         PREGIVE(e, weapons);
1635         PREGIVE(e, strength_finished);
1636         PREGIVE(e, invincible_finished);
1637         PREGIVE(e, superweapons_finished);
1638         PREGIVE(e, ammo_nails);
1639         PREGIVE(e, ammo_cells);
1640         PREGIVE(e, ammo_shells);
1641         PREGIVE(e, ammo_rockets);
1642         PREGIVE(e, ammo_fuel);
1643         PREGIVE(e, armorvalue);
1644         PREGIVE(e, health);
1645
1646         for(i = beginarg; i < endarg; ++i)
1647         {
1648                 cmd = argv(i);
1649
1650                 if(cmd == "0" || stof(cmd))
1651                 {
1652                         val = stof(cmd);
1653                         continue;
1654                 }
1655                 switch(cmd)
1656                 {
1657                         case "no":
1658                                 op = OP_MAX;
1659                                 val = 0;
1660                                 continue;
1661                         case "max":
1662                                 op = OP_MAX;
1663                                 continue;
1664                         case "min":
1665                                 op = OP_MIN;
1666                                 continue;
1667                         case "plus":
1668                                 op = OP_PLUS;
1669                                 continue;
1670                         case "minus":
1671                                 op = OP_MINUS;
1672                                 continue;
1673                         case "ALL":
1674                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1675                                 got += GiveValue(e, strength_finished, op, val);
1676                                 got += GiveValue(e, invincible_finished, op, val);
1677                                 got += GiveValue(e, superweapons_finished, op, val);
1678                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1679                         case "all":
1680                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1681                                 got += GiveValue(e, health, op, val);
1682                                 got += GiveValue(e, armorvalue, op, val);
1683                         case "allweapons":
1684                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1685                                 {
1686                                         wi = get_weaponinfo(j);
1687                                         if(wi.weapons)
1688                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1689                                 }
1690                         case "allammo":
1691                                 got += GiveValue(e, ammo_cells, op, val);
1692                                 got += GiveValue(e, ammo_shells, op, val);
1693                                 got += GiveValue(e, ammo_nails, op, val);
1694                                 got += GiveValue(e, ammo_rockets, op, val);
1695                                 got += GiveValue(e, ammo_fuel, op, val);
1696                                 break;
1697                         case "unlimited_ammo":
1698                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1699                                 break;
1700                         case "unlimited_weapon_ammo":
1701                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1702                                 break;
1703                         case "unlimited_superweapons":
1704                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1705                                 break;
1706                         case "jetpack":
1707                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1708                                 break;
1709                         case "fuel_regen":
1710                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1711                                 break;
1712                         case "strength":
1713                                 got += GiveValue(e, strength_finished, op, val);
1714                                 break;
1715                         case "invincible":
1716                                 got += GiveValue(e, invincible_finished, op, val);
1717                                 break;
1718                         case "superweapons":
1719                                 got += GiveValue(e, superweapons_finished, op, val);
1720                                 break;
1721                         case "cells":
1722                                 got += GiveValue(e, ammo_cells, op, val);
1723                                 break;
1724                         case "shells":
1725                                 got += GiveValue(e, ammo_shells, op, val);
1726                                 break;
1727                         case "nails":
1728                         case "bullets":
1729                                 got += GiveValue(e, ammo_nails, op, val);
1730                                 break;
1731                         case "rockets":
1732                                 got += GiveValue(e, ammo_rockets, op, val);
1733                                 break;
1734                         case "health":
1735                                 got += GiveValue(e, health, op, val);
1736                                 break;
1737                         case "armor":
1738                                 got += GiveValue(e, armorvalue, op, val);
1739                                 break;
1740                         case "fuel":
1741                                 got += GiveValue(e, ammo_fuel, op, val);
1742                                 break;
1743                         default:
1744                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1745                                 {
1746                                         wi = get_weaponinfo(j);
1747                                         if(cmd == wi.netname)
1748                                         {
1749                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1750                                                 break;
1751                                         }
1752                                 }
1753                                 if(j > WEP_LAST)
1754                                         print("give: invalid item ", cmd, "\n");
1755                                 break;
1756                 }
1757                 val = 999;
1758                 op = OP_SET;
1759         }
1760
1761         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1762         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1763         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1764         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1765         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1766         {
1767                 wi = get_weaponinfo(j);
1768                 if(wi.weapons)
1769                 {
1770                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1771                         if not(save_weapons & wi.weapons)
1772                                 if(e.weapons & wi.weapons)
1773                                         weapon_action(wi.weapon, WR_PRECACHE);
1774                 }
1775         }
1776         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1777         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1778         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1779         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1780         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1781         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1782         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1783         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1784         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1785
1786         if(e.superweapons_finished <= 0)
1787                 if(self.weapons & WEPBIT_SUPERWEAPONS)
1788                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1789
1790         if (g_minstagib)
1791         {
1792                 e.health = bound(0, e.health, 100);
1793                 e.armorvalue = bound(0, e.armorvalue, 999);
1794         }
1795
1796         if(e.strength_finished <= 0)
1797                 e.strength_finished = 0;
1798         else
1799                 e.strength_finished += time;
1800         if(e.invincible_finished <= 0)
1801                 e.invincible_finished = 0;
1802         else
1803                 e.invincible_finished += time;
1804         if(e.superweapons_finished <= 0)
1805                 e.superweapons_finished = 0;
1806         else
1807                 e.superweapons_finished += time;
1808
1809         if not(e.weapons & W_WeaponBit(e.switchweapon))
1810                 _switchweapon = TRUE;
1811         if(_switchweapon)
1812                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1813
1814         return got;
1815 }