qcsrc/server/t_items.qc

   1 float have_pickup_item(void)
   2 {
   3         // minstagib: only allow filtered items
   4         if(g_minstagib)
   5                 if(self.classname != "minstagib")
   6                         return FALSE;
   7
   8         if(self.flags & FL_POWERUP)
   9         {
  10                 if(autocvar_g_powerups > 0)
  11                         return TRUE;
  12                 if(autocvar_g_powerups == 0)
  13                         return FALSE;
  14                 if(g_lms)
  15                         return FALSE;
  16                 if(g_ca)
  17                         return FALSE;
  18                 if(g_arena)
  19                         return FALSE;
  20         }
  21         else
  22         {
  23                 if(autocvar_g_pickup_items > 0)
  24                         return TRUE;
  25                 if(autocvar_g_pickup_items == 0)
  26                         return FALSE;
  27                 if(g_lms)
  28                         return FALSE;
  29                 if(g_ca)
  30                         return FALSE;
  31                 if(g_weaponarena)
  32                         if((self.weapons & WEPBIT_ALL) || (self.items & IT_AMMO))
  33                                 return FALSE;
  34         }
  35         return TRUE;
  36 }
  37
  38 #define ITEM_RESPAWN_TICKS 10
  39
  40 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
  41         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
  42 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
  43         // range: 10 .. respawntime + respawntimejitter
  44
  45 floatfield Item_CounterField(float it)
  46 {
  47         switch(it)
  48         {
  49                 case IT_SHELLS:      return ammo_shells;
  50                 case IT_NAILS:       return ammo_nails;
  51                 case IT_ROCKETS:     return ammo_rockets;
  52                 case IT_CELLS:       return ammo_cells;
  53                 case IT_FUEL:        return ammo_fuel;
  54                 case IT_5HP:         return health;
  55                 case IT_25HP:        return health;
  56                 case IT_HEALTH:      return health;
  57                 case IT_ARMOR_SHARD: return armorvalue;
  58                 case IT_ARMOR:       return armorvalue;
  59                 // add more things here (health, armor)
  60                 default:             error("requested item has no counter field");
  61         }
  62 }
  63
  64 string Item_CounterFieldName(float it)
  65 {
  66         switch(it)
  67         {
  68                 case IT_SHELLS:      return "shells";
  69                 case IT_NAILS:       return "nails";
  70                 case IT_ROCKETS:     return "rockets";
  71                 case IT_CELLS:       return "cells";
  72                 case IT_FUEL:        return "fuel";
  73
  74                 // add more things here (health, armor)
  75                 default:             error("requested item has no counter field name");
  76         }
  77 }
  78
  79 .float max_armorvalue;
  80 .float pickup_anyway;
  81
  82 float Item_Customize()
  83 {
  84         if(self.spawnshieldtime)
  85                 return TRUE;
  86         if(self.weapons != (self.weapons & other.weapons))
  87         {
  88                 self.colormod = '0 0 0';
  89                 self.glowmod = self.colormod;
  90                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  91                 return TRUE;
  92         }
  93         else
  94         {
  95                 if(g_ghost_items)
  96                 {
  97                         self.colormod = stov(autocvar_g_ghost_items_color);
  98                         self.glowmod = self.colormod;
  99                         self.alpha = g_ghost_items;
 100                         return TRUE;
 101                 }
 102                 else
 103                         return FALSE;
 104         }
 105 }
 106
 107 void Item_Show (entity e, float mode)
 108 {
 109         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST;
 110         if (mode > 0)
 111         {
 112                 // make the item look normal, and be touchable
 113                 e.model = e.mdl;
 114                 e.solid = SOLID_TRIGGER;
 115                 e.colormod = '0 0 0';
 116                 self.glowmod = self.colormod;
 117                 e.alpha = 0;
 118                 e.customizeentityforclient = func_null;
 119
 120                 e.spawnshieldtime = 1;
 121         }
 122         else if (mode < 0)
 123         {
 124                 // hide the item completely
 125                 e.model = string_null;
 126                 e.solid = SOLID_NOT;
 127                 e.colormod = '0 0 0';
 128                 self.glowmod = self.colormod;
 129                 e.alpha = 0;
 130                 e.customizeentityforclient = func_null;
 131
 132                 e.spawnshieldtime = 1;
 133         }
 134         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 135         {
 136                 // make the item translucent and not touchable
 137                 e.model = e.mdl;
 138                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 139                 e.colormod = '0 0 0';
 140                 self.glowmod = self.colormod;
 141                 e.effects |= EF_STARDUST;
 142                 e.customizeentityforclient = Item_Customize;
 143
 144                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 145         }
 146         else if(g_ghost_items)
 147         {
 148                 // make the item translucent and not touchable
 149                 e.model = e.mdl;
 150                 e.solid = SOLID_NOT;
 151                 e.colormod = stov(autocvar_g_ghost_items_color);
 152                 e.glowmod = e.colormod;
 153                 e.alpha = g_ghost_items;
 154                 e.customizeentityforclient = func_null;
 155
 156                 e.spawnshieldtime = 1;
 157         }
 158         else
 159         {
 160                 // hide the item completely
 161                 e.model = string_null;
 162                 e.solid = SOLID_NOT;
 163                 e.colormod = '0 0 0';
 164                 e.glowmod = e.colormod;
 165                 e.alpha = 0;
 166                 e.customizeentityforclient = func_null;
 167
 168                 e.spawnshieldtime = 1;
 169         }
 170
 171         if (e.items & (IT_STRENGTH | IT_INVINCIBLE))
 172                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 173         if (autocvar_g_nodepthtestitems)
 174                 e.effects |= EF_NODEPTHTEST;
 175         if (autocvar_g_fullbrightitems)
 176                 e.effects |= EF_FULLBRIGHT;
 177
 178         // relink entity (because solid may have changed)
 179         setorigin(e, e.origin);
 180 }
 181
 182 void Item_Respawn (void)
 183 {
 184         Item_Show(self, 1);
 185         if(!g_minstagib && self.items == IT_STRENGTH)
 186                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 187         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 188                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 189         else
 190                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);  // play respawn sound
 191         setorigin (self, self.origin);
 192
 193         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 194         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 195 }
 196
 197 void Item_RespawnCountdown (void)
 198 {
 199         if(self.count >= ITEM_RESPAWN_TICKS)
 200         {
 201                 if(self.waypointsprite_attached)
 202                         WaypointSprite_Kill(self.waypointsprite_attached);
 203                 Item_Respawn();
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 self.count += 1;
 209                 if(self.count == 1)
 210                 {
 211                         string name;
 212                         vector rgb;
 213                         name = string_null;
 214                         if(g_minstagib)
 215                         {
 216                                 switch(self.items)
 217                                 {
 218                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 219                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 220                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 221                                 }
 222                         }
 223                         else
 224                         {
 225                                 switch(self.items)
 226                                 {
 227                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 228                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 229                                 }
 230                         }
 231                         switch(self.items)
 232                         {
 233                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 234                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 235                         }
 236                         if(self.flags & FL_WEAPON)
 237                         {
 238                                 entity wi = get_weaponinfo(self.weapon);
 239                                 if(wi)
 240                                 {
 241                                         name = wi.model2;
 242                                         rgb = '1 0 0';
 243                                 }
 244                         }
 245                         if(!name)
 246                         {
 247                                 print("Unknown powerup-marked item is wanting to respawn\n");
 248                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 249                         }
 250                         if(name)
 251                         {
 252                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE, RADARICON_POWERUP, rgb);
 253                                 if(self.waypointsprite_attached)
 254                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 255                         }
 256                 }
 257                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM); // play respawn sound
 258                 if(self.waypointsprite_attached)
 259                 {
 260                         WaypointSprite_Ping(self.waypointsprite_attached);
 261                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 262                 }
 263         }
 264 }
 265
 266 void Item_ScheduleRespawnIn(entity e, float t)
 267 {
 268         if((e.flags & FL_POWERUP) || (e.weapons & WEPBIT_SUPERWEAPONS))
 269         {
 270                 e.think = Item_RespawnCountdown;
 271                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 272                 e.count = 0;
 273         }
 274         else
 275         {
 276                 e.think = Item_Respawn;
 277                 e.nextthink = time + t;
 278         }
 279 }
 280
 281 void Item_ScheduleRespawn(entity e)
 282 {
 283         if(e.respawntime > 0)
 284         {
 285                 Item_Show(e, 0);
 286                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 287         }
 288         else // if respawntime is -1, this item does not respawn
 289                 Item_Show(e, -1);
 290 }
 291
 292 void Item_ScheduleInitialRespawn(entity e)
 293 {
 294         Item_Show(e, 0);
 295         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 296 }
 297
 298 float ITEM_MODE_NONE = 0;
 299 float ITEM_MODE_HEALTH = 1;
 300 float ITEM_MODE_ARMOR = 2;
 301 float ITEM_MODE_FUEL = 3;
 302 float Item_GiveAmmoTo(entity item, entity player, .float ammofield, float ammomax, float mode)
 303 {
 304         if (!item.ammofield)
 305                 return FALSE;
 306
 307         if (item.spawnshieldtime)
 308         {
 309                 if ((player.ammofield < ammomax) || item.pickup_anyway)
 310                 {
 311                         player.ammofield = bound(player.ammofield, ammomax, player.ammofield + item.ammofield);
 312                         goto YEAH;
 313                 }
 314         }
 315         else if(g_weapon_stay == 2)
 316         {
 317                 float mi = min(item.ammofield, ammomax);
 318                 if (player.ammofield < mi)
 319                 {
 320                         player.ammofield = mi;
 321                         goto YEAH;
 322                 }
 323         }
 324
 325         return FALSE;
 326
 327 :YEAH
 328         switch(mode)
 329         {
 330                 case ITEM_MODE_FUEL:
 331                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 332                         break;
 333                 case ITEM_MODE_HEALTH:
 334                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 335                         break;
 336                 case ITEM_MODE_ARMOR:
 337                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 338                         break;
 339                 default:
 340                         break;
 341         }
 342         return TRUE;
 343 }
 344
 345 float Item_GiveTo(entity item, entity player)
 346 {
 347         float _switchweapon;
 348         float pickedup;
 349         float it;
 350         float i;
 351         entity e;
 352
 353         // if nothing happens to player, just return without taking the item
 354         pickedup = FALSE;
 355         _switchweapon = FALSE;
 356
 357         if (g_minstagib)
 358         {
 359                 float prevcells = player.ammo_cells;
 360
 361                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 362                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, 999, ITEM_MODE_NONE);
 363
 364                 if(player.ammo_cells > prevcells)
 365                 {
 366                         _switchweapon = TRUE;
 367
 368                         // play some cool sounds ;)
 369                         if (clienttype(player) == CLIENTTYPE_REAL)
 370                         {
 371                                 if(player.health <= 5)
 372                                         AnnounceTo(player, "lastsecond");
 373                                 else if(player.health < 50)
 374                                         AnnounceTo(player, "narrowly");
 375                         }
 376                         // sound not available
 377                         // else if(item.items == IT_CELLS)
 378                         //      AnnounceTo(player, "ammo");
 379
 380                         if (item.weapons & WEPBIT_MINSTANEX)
 381                                 W_GiveWeapon (player, WEP_MINSTANEX, item.netname);
 382                         player.health = 100;
 383                 }
 384
 385                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 386                 {
 387                         pickedup = TRUE;
 388                         player.items |= it;
 389                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 390                 }
 391
 392                 // extralife powerup
 393                 if (item.max_health)
 394                 {
 395                         pickedup = TRUE;
 396                         // sound not available
 397                         // AnnounceTo(player, "_lives");
 398                         player.armorvalue = bound(player.armorvalue, 999, player.armorvalue + autocvar_g_minstagib_extralives);
 399                         sprint(player, "^3You picked up some extra lives\n");
 400                 }
 401
 402                 // invis powerup
 403                 if (item.strength_finished)
 404                 {
 405                         pickedup = TRUE;
 406                         // sound not available
 407                         // AnnounceTo(player, "invisible");
 408                         player.strength_finished = max(player.strength_finished, time) + autocvar_g_balance_powerup_strength_time;
 409                 }
 410
 411                 // speed powerup
 412                 if (item.invincible_finished)
 413                 {
 414                         pickedup = TRUE;
 415                         // sound not available
 416                         // AnnounceTo(player, "speed");
 417                         player.invincible_finished = max(player.invincible_finished, time) + autocvar_g_balance_powerup_strength_time;
 418                 }
 419         }
 420         else
 421         {
 422                 // in case the player has autoswitch enabled do the following:
 423                 // if the player is using their best weapon before items are given, they
 424                 // probably want to switch to an even better weapon after items are given
 425                 if (player.autoswitch)
 426                 if (player.switchweapon == w_getbestweapon(player))
 427                         _switchweapon = TRUE;
 428
 429                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 430                         _switchweapon = TRUE;
 431
 432                 pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 433                 pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 434                 pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 435                 pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 436                 pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 437                 pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 438                 pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 439
 440                 if (item.flags & FL_WEAPON)
 441                 if ((it = item.weapons - (item.weapons & player.weapons)) || (item.spawnshieldtime && self.pickup_anyway))
 442                 {
 443                         pickedup = TRUE;
 444                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 445                         {
 446                                 e = get_weaponinfo(i);
 447                                 if(it & e.weapons)
 448                                         W_GiveWeapon (player, e.weapon, item.netname);
 449                         }
 450                 }
 451
 452                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 453                 {
 454                         pickedup = TRUE;
 455                         player.items |= it;
 456                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 457                 }
 458
 459                 if (item.strength_finished)
 460                 {
 461                         pickedup = TRUE;
 462                         player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 463                 }
 464                 if (item.invincible_finished)
 465                 {
 466                         pickedup = TRUE;
 467                         player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 468                 }
 469                 if (item.superweapons_finished)
 470                 {
 471                         pickedup = TRUE;
 472                         player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 473                 }
 474         }
 475
 476 :skip
 477         // always eat teamed entities
 478         if(item.team)
 479                 pickedup = TRUE;
 480
 481         if (!pickedup)
 482                 return 0;
 483
 484         if (_switchweapon)
 485                 if (player.switchweapon != w_getbestweapon(player))
 486                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 487
 488         return 1;
 489 }
 490
 491 void Item_Touch (void)
 492 {
 493         entity e, head;
 494
 495         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 496         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 497         {
 498                 remove(self);
 499                 return;
 500         }
 501         if (other.classname != "player")
 502                 return;
 503         if (other.deadflag)
 504                 return;
 505         if (self.solid != SOLID_TRIGGER)
 506                 return;
 507         if (self.owner == other)
 508                 return;
 509
 510         if (self.classname == "droppedweapon")
 511         {
 512                 self.strength_finished = max(0, self.strength_finished - time);
 513                 self.invincible_finished = max(0, self.invincible_finished - time);
 514                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 515         }
 516
 517         if(!Item_GiveTo(self, other))
 518         {
 519                 if (self.classname == "droppedweapon")
 520                 {
 521                         // undo what we did above
 522                         self.strength_finished += time;
 523                         self.invincible_finished += time;
 524                         self.superweapons_finished += time;
 525                 }
 526                 return;
 527         }
 528
 529         other.last_pickup = time;
 530
 531         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 532         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTN_NORM);
 533
 534         if (self.classname == "droppedweapon")
 535                 remove (self);
 536         else if not(self.spawnshieldtime)
 537                 return;
 538         else
 539         {
 540                 if(self.team)
 541                 {
 542                         RandomSelection_Init();
 543                         for(head = world; (head = findfloat(head, team, self.team)); )
 544                         {
 545                                 if(head.flags & FL_ITEM)
 546                                 {
 547                                         Item_Show(head, -1);
 548                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 549                                 }
 550                         }
 551                         e = RandomSelection_chosen_ent;
 552                 }
 553                 else
 554                         e = self;
 555                 Item_ScheduleRespawn(e);
 556         }
 557 }
 558
 559 void Item_Reset()
 560 {
 561         Item_Show(self, !self.state);
 562         setorigin (self, self.origin);
 563
 564         if(self.classname != "droppedweapon")
 565         {
 566                 self.think = SUB_Null;
 567                 self.nextthink = 0;
 568
 569                 if(self.waypointsprite_attached)
 570                         WaypointSprite_Kill(self.waypointsprite_attached);
 571
 572                 if((self.flags & FL_POWERUP) | (self.weapons & WEPBIT_SUPERWEAPONS)) // do not spawn powerups initially!
 573                         Item_ScheduleInitialRespawn(self);
 574         }
 575 }
 576
 577 void Item_FindTeam()
 578 {
 579         entity head, e;
 580
 581         if(self.effects & EF_NODRAW)
 582         {
 583                 // marker for item team search
 584                 dprint("Initializing item team ", ftos(self.team), "\n");
 585                 RandomSelection_Init();
 586                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 587                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 588                 e = RandomSelection_chosen_ent;
 589                 e.state = 0;
 590                 Item_Show(e, 1);
 591
 592                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 593                 {
 594                         if(head != e)
 595                         {
 596                                 // make it a non-spawned item
 597                                 Item_Show(head, -1);
 598                                 head.state = 1; // state 1 = initially hidden item
 599                         }
 600                         head.effects &~= EF_NODRAW;
 601                 }
 602
 603                 Item_Reset();
 604         }
 605 }
 606
 607 // Savage: used for item garbage-collection
 608 // TODO: perhaps nice special effect?
 609 void RemoveItem(void)
 610 {
 611         remove(self);
 612 }
 613
 614 // pickup evaluation functions
 615 // these functions decide how desirable an item is to the bots
 616
 617 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
 618
 619 float weapon_pickupevalfunc(entity player, entity item)
 620 {
 621         float c, i, j, position;
 622
 623         // See if I have it already
 624         if(player.weapons & item.weapons == item.weapons)
 625         {
 626                 // If I can pick it up
 627                 if(!item.spawnshieldtime)
 628                         c = 0;
 629                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 630                 {
 631                         // Skilled bots will grab more
 632                         c = bound(0, skill / 10, 1) * 0.5;
 633                 }
 634                 else
 635                         c = 0;
 636         }
 637         else
 638                 c = 1;
 639
 640         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 641         if( bot_custom_weapon && c )
 642         {
 643                 for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 644                 {
 645                         // Find weapon
 646                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 647                                 continue;
 648
 649                         // Find the highest position on any range
 650                         position = -1;
 651                         for(j = 0; j < WEP_LAST ; ++j){
 652                                 if(
 653                                                 bot_weapons_far[j] == i ||
 654                                                 bot_weapons_mid[j] == i ||
 655                                                 bot_weapons_close[j] == i
 656                                   )
 657                                 {
 658                                         position = j;
 659                                         break;
 660                                 }
 661                         }
 662
 663                         // Rate it
 664                         if (position >= 0 )
 665                         {
 666                                 position = WEP_LAST - position;
 667                                 // item.bot_pickupbasevalue is overwritten here
 668                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 669                         }
 670                 }
 671         }
 672
 673         return item.bot_pickupbasevalue * c;
 674 }
 675
 676 float commodity_pickupevalfunc(entity player, entity item)
 677 {
 678         float c, i, need_shells, need_nails, need_rockets, need_cells, need_fuel;
 679         entity wi;
 680         c = 0;
 681
 682         // Detect needed ammo
 683         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
 684         {
 685                 wi = get_weaponinfo(i);
 686
 687                 if not(wi.weapons & player.weapons)
 688                         continue;
 689
 690                 if(wi.items & IT_SHELLS)
 691                         need_shells = TRUE;
 692                 else if(wi.items & IT_NAILS)
 693                         need_nails = TRUE;
 694                 else if(wi.items & IT_ROCKETS)
 695                         need_rockets = TRUE;
 696                 else if(wi.items & IT_CELLS)
 697                         need_cells = TRUE;
 698                 else if(wi.items & IT_FUEL)
 699                         need_cells = TRUE;
 700         }
 701
 702         // TODO: figure out if the player even has the weapon this ammo is for?
 703         // may not affect strategy much though...
 704         // find out how much more ammo/armor/health the player can hold
 705         if (need_shells)
 706         if (item.ammo_shells)
 707         if (player.ammo_shells < g_pickup_shells_max)
 708                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 709         if (need_nails)
 710         if (item.ammo_nails)
 711         if (player.ammo_nails < g_pickup_nails_max)
 712                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 713         if (need_rockets)
 714         if (item.ammo_rockets)
 715         if (player.ammo_rockets < g_pickup_rockets_max)
 716                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 717         if (need_cells)
 718         if (item.ammo_cells)
 719         if (player.ammo_cells < g_pickup_cells_max)
 720                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 721         if (need_fuel)
 722         if (item.ammo_fuel)
 723         if (player.ammo_fuel < g_pickup_fuel_max)
 724                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
 725         if (item.armorvalue)
 726         if (player.armorvalue < item.max_armorvalue)
 727                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 728         if (item.health)
 729         if (player.health < item.max_health)
 730                 c = c + max(0, 1 - player.health / item.max_health);
 731
 732         return item.bot_pickupbasevalue * c;
 733 }
 734
 735
 736 .float is_item;
 737 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 738 {
 739         startitem_failed = FALSE;
 740
 741         self.items = itemid;
 742         self.weapons = weaponid;
 743         self.flags = FL_ITEM | itemflags;
 744
 745         // is it a dropped weapon?
 746         if (self.classname == "droppedweapon")
 747         {
 748                 self.reset = SUB_Remove;
 749                 // it's a dropped weapon
 750                 self.movetype = MOVETYPE_TOSS;
 751
 752                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 753                 self.think = RemoveItem;
 754                 self.nextthink = time + 20;
 755
 756                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
 757                 /*
 758                 if(self.items == 0)
 759                 if(self.weapons == (self.weapons & WEPBIT_SUPERWEAPONS)) // only superweapons
 760                 if(self.ammo_nails == 0)
 761                 if(self.ammo_cells == 0)
 762                 if(self.ammo_rockets == 0)
 763                 if(self.ammo_shells == 0)
 764                 if(self.ammo_fuel == 0)
 765                 if(self.health == 0)
 766                 if(self.armorvalue == 0)
 767                 */
 768                 {
 769                         // if item is worthless after a timer, have it expire then
 770                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
 771                 }
 772
 773                 // don't drop if in a NODROP zone (such as lava)
 774                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 775                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 776                 {
 777                         startitem_failed = TRUE;
 778                         remove(self);
 779                         return;
 780                 }
 781         }
 782         else
 783         {
 784                 if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
 785                 {
 786                         startitem_failed = TRUE;
 787                         remove(self);
 788                         return;
 789                 }
 790
 791                 if(!have_pickup_item())
 792                 {
 793                         startitem_failed = TRUE;
 794                         remove (self);
 795                         return;
 796                 }
 797
 798                 if(self.model != "")
 799                         itemmodel = self.model;
 800                 if(self.item_pickupsound != "")
 801                         pickupsound = self.item_pickupsound;
 802
 803                 self.reset = Item_Reset;
 804                 // it's a level item
 805                 if(self.spawnflags & 1)
 806                         self.noalign = 1;
 807                 if (self.noalign)
 808                         self.movetype = MOVETYPE_NONE;
 809                 else
 810                         self.movetype = MOVETYPE_TOSS;
 811                 // do item filtering according to game mode and other things
 812                 if (!self.noalign)
 813                 {
 814                         // first nudge it off the floor a little bit to avoid math errors
 815                         setorigin(self, self.origin + '0 0 1');
 816                         // set item size before we spawn a spawnfunc_waypoint
 817                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 818                                 setsize (self, '-16 -16 0', '16 16 48');
 819                         else
 820                                 setsize (self, '-16 -16 0', '16 16 32');
 821                         // note droptofloor returns FALSE if stuck/or would fall too far
 822                         droptofloor();
 823                         waypoint_spawnforitem(self);
 824                 }
 825
 826                 /*
 827                  * can't do it that way, as it would break maps
 828                  * TODO make a target_give like entity another way, that perhaps has
 829                  * the weapon name in a key
 830                 if(self.targetname)
 831                 {
 832                         // target_give not yet supported; maybe later
 833                         print("removed targeted ", self.classname, "\n");
 834                         startitem_failed = TRUE;
 835                         remove (self);
 836                         return;
 837                 }
 838                 */
 839
 840                 if(autocvar_spawn_debug >= 2)
 841                 {
 842                         entity otheritem;
 843                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 844                         {
 845                                 if(otheritem.is_item)
 846                                 {
 847                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 848                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 849                                         error("Mapper sucks.");
 850                                 }
 851                         }
 852                         self.is_item = TRUE;
 853                 }
 854
 855                 weaponsInMap |= weaponid;
 856
 857                 precache_model (itemmodel);
 858                 precache_sound (pickupsound);
 859
 860                 precache_sound ("misc/itemrespawncountdown.wav");
 861                 if(!g_minstagib && itemid == IT_STRENGTH)
 862                         precache_sound ("misc/strength_respawn.wav");
 863                 else if(!g_minstagib && itemid == IT_INVINCIBLE)
 864                         precache_sound ("misc/shield_respawn.wav");
 865                 else
 866                         precache_sound ("misc/itemrespawn.wav");
 867
 868                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
 869                         self.target = "###item###"; // for finding the nearest item using find()
 870         }
 871
 872         self.bot_pickup = TRUE;
 873         self.bot_pickupevalfunc = pickupevalfunc;
 874         self.bot_pickupbasevalue = pickupbasevalue;
 875         self.mdl = itemmodel;
 876         self.item_pickupsound = pickupsound;
 877         if(self.weapons)
 878                 self.weapon = WEP_FIRST + log2of(lowestbit(self.weapons));
 879         else
 880                 self.weapon = 0;
 881         // let mappers override respawntime
 882         if(!self.respawntime) // both set
 883         {
 884                 self.respawntime = defaultrespawntime;
 885                 self.respawntimejitter = defaultrespawntimejitter;
 886         }
 887         self.netname = itemname;
 888         self.touch = Item_Touch;
 889         setmodel (self, self.mdl); // precision set below
 890         self.effects |= EF_LOWPRECISION;
 891         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 892                 setsize (self, '-16 -16 0', '16 16 48');
 893         else
 894                 setsize (self, '-16 -16 0', '16 16 32');
 895         if(itemflags & FL_WEAPON)
 896                 self.modelflags |= MF_ROTATE;
 897
 898         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 899         if (itemflags & FL_WEAPON)
 900         {
 901                 // neutral team color for pickup weapons
 902                 self.colormap = 1024; // color shirt=0 pants=0 grey
 903         }
 904
 905         self.state = 0;
 906         if(self.team)
 907         {
 908                 if(!self.cnt)
 909                         self.cnt = 1; // item probability weight
 910                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 911                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 912         }
 913         else
 914                 Item_Reset();
 915 }
 916
 917 /* replace items in minstagib
 918  * IT_STRENGTH   = invisibility
 919  * IT_NAILS      = extra lives
 920  * IT_INVINCIBLE = speed
 921  */
 922 void minstagib_items (float itemid)
 923 {
 924         float rnd;
 925         self.classname = "minstagib";
 926
 927         // replace rocket launchers and nex guns with ammo cells
 928         if (itemid == IT_CELLS)
 929         {
 930                 self.ammo_cells = autocvar_g_minstagib_ammo_drop;
 931                 StartItem ("models/items/a_cells.md3",
 932                         "misc/itempickup.wav", 45, 0,
 933                         "MinstaNex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 934                 return;
 935         }
 936
 937         // randomize
 938         rnd = random() * 3;
 939         if (rnd <= 1)
 940                 itemid = IT_STRENGTH;
 941         else if (rnd <= 2)
 942                 itemid = IT_NAILS;
 943         else
 944                 itemid = IT_INVINCIBLE;
 945
 946         // replace with invis
 947         if (itemid == IT_STRENGTH)
 948         {
 949                 if(!self.strength_finished)
 950                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
 951                 StartItem ("models/items/g_strength.md3",
 952                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 953                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 954         }
 955         // replace with extra lives
 956         if (itemid == IT_NAILS)
 957         {
 958                 self.max_health = 1;
 959                 StartItem ("models/items/g_h100.md3",
 960                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 961                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 962         }
 963         // replace with speed
 964         if (itemid == IT_INVINCIBLE)
 965         {
 966                 if(!self.invincible_finished)
 967                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
 968                 StartItem ("models/items/g_invincible.md3",
 969                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 970                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 971         }
 972 }
 973
 974 float minst_no_auto_cells;
 975 void minst_remove_item (void) {
 976         if(minst_no_auto_cells)
 977                 remove(self);
 978 }
 979
 980 float weaponswapping;
 981 float internalteam;
 982
 983 void weapon_defaultspawnfunc(float wpn)
 984 {
 985         entity e;
 986         float t;
 987         var .float ammofield;
 988         string s;
 989         entity oldself;
 990         float i, j;
 991         float f;
 992
 993         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 994         {
 995                 e = get_weaponinfo(wpn);
 996                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 997                 if(s == "0")
 998                 {
 999                         remove(self);
1000                         startitem_failed = TRUE;
1001                         return;
1002                 }
1003                 t = tokenize_console(s);
1004                 if(t >= 2)
1005                 {
1006                         self.team = --internalteam;
1007                         oldself = self;
1008                         for(i = 1; i < t; ++i)
1009                         {
1010                                 s = argv(i);
1011                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1012                                 {
1013                                         e = get_weaponinfo(j);
1014                                         if(e.netname == s)
1015                                         {
1016                                                 self = spawn();
1017                                                 copyentity(oldself, self);
1018                                                 self.classname = "replacedweapon";
1019                                                 weapon_defaultspawnfunc(j);
1020                                                 break;
1021                                         }
1022                                 }
1023                                 if(j > WEP_LAST)
1024                                 {
1025                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1026                                 }
1027                         }
1028                         self = oldself;
1029                 }
1030                 if(t >= 1)
1031                 {
1032                         s = argv(0);
1033                         wpn = 0;
1034                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1035                         {
1036                                 e = get_weaponinfo(j);
1037                                 if(e.netname == s)
1038                                 {
1039                                         wpn = j;
1040                                         break;
1041                                 }
1042                         }
1043                         if(j > WEP_LAST)
1044                         {
1045                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1046                         }
1047                 }
1048                 if(wpn == 0)
1049                 {
1050                         remove(self);
1051                         startitem_failed = TRUE;
1052                         return;
1053                 }
1054         }
1055
1056         e = get_weaponinfo(wpn);
1057
1058         if(!self.respawntime)
1059         {
1060                 if(e.weapons & WEPBIT_SUPERWEAPONS)
1061                 {
1062                         self.respawntime = g_pickup_respawntime_superweapon;
1063                         self.respawntimejitter = g_pickup_respawntimejitter_superweapon;
1064                 }
1065                 else
1066                 {
1067                         self.respawntime = g_pickup_respawntime_weapon;
1068                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1069                 }
1070         }
1071
1072         if(e.weapons & WEPBIT_SUPERWEAPONS)
1073                 if(!self.superweapons_finished)
1074                         self.superweapons_finished = autocvar_g_balance_superweapons_time;
1075
1076         if(e.items)
1077         {
1078                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1079                 {
1080                         if(e.items & j)
1081                         {
1082                                 ammofield = Item_CounterField(j);
1083                                 if(!self.ammofield)
1084                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j), "_weapon"));
1085                         }
1086                 }
1087         }
1088
1089         // pickup anyway
1090         if(g_pickup_weapons_anyway)
1091                 self.pickup_anyway = TRUE;
1092
1093         f = FL_WEAPON;
1094
1095         // no weapon-stay on superweapons
1096         if(e.weapons & WEPBIT_SUPERWEAPONS)
1097                 f |= FL_NO_WEAPON_STAY;
1098
1099         // weapon stay isn't supported for teamed weapons
1100         if(self.team)
1101                 f |= FL_NO_WEAPON_STAY;
1102
1103         // stupid minstagib hack, don't ask
1104         if(g_minstagib)
1105                 if(self.ammo_cells)
1106                         self.ammo_cells = autocvar_g_minstagib_ammo_drop;
1107
1108         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, f, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1109         if (self.modelindex) // don't precache if self was removed
1110                 weapon_action(e.weapon, WR_PRECACHE);
1111 }
1112
1113 void spawnfunc_weapon_shotgun (void);
1114 void spawnfunc_weapon_uzi (void) {
1115         if(autocvar_sv_q3acompat_machineshotgunswap)
1116         if(self.classname != "droppedweapon")
1117         {
1118                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1119                 return;
1120         }
1121         weapon_defaultspawnfunc(WEP_UZI);
1122 }
1123
1124 void spawnfunc_weapon_shotgun (void) {
1125         if(autocvar_sv_q3acompat_machineshotgunswap)
1126         if(self.classname != "droppedweapon")
1127         {
1128                 weapon_defaultspawnfunc(WEP_UZI);
1129                 return;
1130         }
1131         weapon_defaultspawnfunc(WEP_SHOTGUN);
1132 }
1133
1134 void spawnfunc_weapon_nex (void)
1135 {
1136         if (g_minstagib)
1137         {
1138                 minstagib_items(IT_CELLS);
1139                 self.think = minst_remove_item;
1140                 self.nextthink = time;
1141                 return;
1142         }
1143         weapon_defaultspawnfunc(WEP_NEX);
1144 }
1145
1146 void spawnfunc_weapon_minstanex (void)
1147 {
1148         if (g_minstagib)
1149         {
1150                 minstagib_items(IT_CELLS);
1151                 self.think = minst_remove_item;
1152                 self.nextthink = time;
1153                 return;
1154         }
1155         weapon_defaultspawnfunc(WEP_MINSTANEX);
1156 }
1157
1158 void spawnfunc_weapon_rocketlauncher (void)
1159 {
1160         if (g_minstagib)
1161         {
1162                 minstagib_items(IT_CELLS); // replace rocketlauncher with cells
1163                 self.think = minst_remove_item;
1164                 self.nextthink = time;
1165                 return;
1166         }
1167         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1168 }
1169
1170 void spawnfunc_item_rockets (void) {
1171         if(!self.ammo_rockets)
1172                 self.ammo_rockets = g_pickup_rockets;
1173         if(!self.pickup_anyway)
1174                 self.pickup_anyway = g_pickup_ammo_anyway;
1175         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1176 }
1177
1178 void spawnfunc_item_shells (void);
1179 void spawnfunc_item_bullets (void) {
1180         if(!weaponswapping)
1181         if(autocvar_sv_q3acompat_machineshotgunswap)
1182         if(self.classname != "droppedweapon")
1183         {
1184                 weaponswapping = TRUE;
1185                 spawnfunc_item_shells();
1186                 weaponswapping = FALSE;
1187                 return;
1188         }
1189
1190         if(!self.ammo_nails)
1191                 self.ammo_nails = g_pickup_nails;
1192         if(!self.pickup_anyway)
1193                 self.pickup_anyway = g_pickup_ammo_anyway;
1194         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1195 }
1196
1197 void spawnfunc_item_cells (void) {
1198         if(!self.ammo_cells)
1199                 self.ammo_cells = g_pickup_cells;
1200         if(!self.pickup_anyway)
1201                 self.pickup_anyway = g_pickup_ammo_anyway;
1202         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1203 }
1204
1205 void spawnfunc_item_shells (void) {
1206         if(!weaponswapping)
1207         if(autocvar_sv_q3acompat_machineshotgunswap)
1208         if(self.classname != "droppedweapon")
1209         {
1210                 weaponswapping = TRUE;
1211                 spawnfunc_item_bullets();
1212                 weaponswapping = FALSE;
1213                 return;
1214         }
1215
1216         if(!self.ammo_shells)
1217                 self.ammo_shells = g_pickup_shells;
1218         if(!self.pickup_anyway)
1219                 self.pickup_anyway = g_pickup_ammo_anyway;
1220         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1221 }
1222
1223 void spawnfunc_item_armor_small (void) {
1224         if(!self.armorvalue)
1225                 self.armorvalue = g_pickup_armorsmall;
1226         if(!self.max_armorvalue)
1227                 self.max_armorvalue = g_pickup_armorsmall_max;
1228         if(!self.pickup_anyway)
1229                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1230         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1231 }
1232
1233 void spawnfunc_item_armor_medium (void) {
1234         if(!self.armorvalue)
1235                 self.armorvalue = g_pickup_armormedium;
1236         if(!self.max_armorvalue)
1237                 self.max_armorvalue = g_pickup_armormedium_max;
1238         if(!self.pickup_anyway)
1239                 self.pickup_anyway = g_pickup_armormedium_anyway;
1240         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1241 }
1242
1243 void spawnfunc_item_armor_big (void) {
1244         if(!self.armorvalue)
1245                 self.armorvalue = g_pickup_armorbig;
1246         if(!self.max_armorvalue)
1247                 self.max_armorvalue = g_pickup_armorbig_max;
1248         if(!self.pickup_anyway)
1249                 self.pickup_anyway = g_pickup_armorbig_anyway;
1250         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1251 }
1252
1253 void spawnfunc_item_armor_large (void) {
1254         if(!self.armorvalue)
1255                 self.armorvalue = g_pickup_armorlarge;
1256         if(!self.max_armorvalue)
1257                 self.max_armorvalue = g_pickup_armorlarge_max;
1258         if(!self.pickup_anyway)
1259                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1260         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1261 }
1262
1263 void spawnfunc_item_health_small (void) {
1264         if(!self.max_health)
1265                 self.max_health = g_pickup_healthsmall_max;
1266         if(!self.health)
1267                 self.health = g_pickup_healthsmall;
1268         if(!self.pickup_anyway)
1269                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1270         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1271 }
1272
1273 void spawnfunc_item_health_medium (void) {
1274         if(!self.max_health)
1275                 self.max_health = g_pickup_healthmedium_max;
1276         if(!self.health)
1277                 self.health = g_pickup_healthmedium;
1278         if(!self.pickup_anyway)
1279                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1280         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1281 }
1282
1283 void spawnfunc_item_health_large (void) {
1284         if(!self.max_health)
1285                 self.max_health = g_pickup_healthlarge_max;
1286         if(!self.health)
1287                 self.health = g_pickup_healthlarge;
1288         if(!self.pickup_anyway)
1289                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1290         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1291 }
1292
1293 void spawnfunc_item_health_mega (void) {
1294         if(g_minstagib) {
1295                 minstagib_items(IT_NAILS);
1296         } else {
1297                 if(!self.max_health)
1298                         self.max_health = g_pickup_healthmega_max;
1299                 if(!self.health)
1300                         self.health = g_pickup_healthmega;
1301                 if(!self.pickup_anyway)
1302                         self.pickup_anyway = g_pickup_healthmega_anyway;
1303                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1304         }
1305 }
1306
1307 // support old misnamed entities
1308 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1309 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1310 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1311 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1312 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1313
1314 void spawnfunc_item_strength (void) {
1315         if(g_minstagib) {
1316                 minstagib_items(IT_STRENGTH);
1317         } else {
1318                 precache_sound("weapons/strength_fire.wav");
1319                 if(!self.strength_finished)
1320                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1321                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1322         }
1323 }
1324
1325 void spawnfunc_item_invincible (void) {
1326         if(g_minstagib) {
1327                 minstagib_items(IT_INVINCIBLE);
1328         } else {
1329                 if(!self.invincible_finished)
1330                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1331                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1332         }
1333 }
1334
1335 void spawnfunc_item_minst_cells (void) {
1336         if (g_minstagib)
1337         {
1338                 minst_no_auto_cells = 1;
1339                 minstagib_items(IT_CELLS);
1340         }
1341         else
1342                 remove(self);
1343 }
1344
1345 // compatibility:
1346 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1347
1348 float GiveItems(entity e, float beginarg, float endarg);
1349 void target_items_use (void)
1350 {
1351         if(activator.classname == "droppedweapon")
1352         {
1353                 EXACTTRIGGER_TOUCH;
1354                 remove(activator);
1355                 return;
1356         }
1357
1358         if(activator.classname != "player")
1359                 return;
1360         if(activator.deadflag != DEAD_NO)
1361                 return;
1362         EXACTTRIGGER_TOUCH;
1363
1364         entity e;
1365         for(e = world; (e = find(e, classname, "droppedweapon")); )
1366                 if(e.enemy == activator)
1367                         remove(e);
1368
1369         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1370                 centerprint(activator, self.message);
1371 }
1372
1373 void spawnfunc_target_items (void)
1374 {
1375         float n, i, j;
1376         entity e;
1377
1378         self.use = target_items_use;
1379         if(!self.strength_finished)
1380                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1381         if(!self.invincible_finished)
1382                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1383         if(!self.superweapons_finished)
1384                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1385
1386         precache_sound("misc/itempickup.wav");
1387         precache_sound("misc/megahealth.wav");
1388         precache_sound("misc/armor25.wav");
1389         precache_sound("misc/powerup.wav");
1390         precache_sound("misc/poweroff.wav");
1391         precache_sound("weapons/weaponpickup.wav");
1392
1393         n = tokenize_console(self.netname);
1394         if(argv(0) == "give")
1395         {
1396                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1397         }
1398         else
1399         {
1400                 for(i = 0; i < n; ++i)
1401                 {
1402                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1403                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1404                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1405                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1406                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1407                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1408                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1409                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1410                         else
1411                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1412                         {
1413                                 e = get_weaponinfo(j);
1414                                 if(argv(i) == e.netname)
1415                                 {
1416                                         self.weapons |= e.weapons;
1417                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1418                                                 weapon_action(e.weapon, WR_PRECACHE);
1419                                         break;
1420                                 }
1421                         }
1422                         if(j > WEP_LAST)
1423                                 print("target_items: invalid item ", argv(i), "\n");
1424                 }
1425
1426                 string itemprefix, valueprefix;
1427                 if(self.spawnflags == 0)
1428                 {
1429                         itemprefix = "";
1430                         valueprefix = "";
1431                 }
1432                 else if(self.spawnflags == 1)
1433                 {
1434                         itemprefix = "max ";
1435                         valueprefix = "max ";
1436                 }
1437                 else if(self.spawnflags == 2)
1438                 {
1439                         itemprefix = "min ";
1440                         valueprefix = "min ";
1441                 }
1442                 else if(self.spawnflags == 4)
1443                 {
1444                         itemprefix = "minus ";
1445                         valueprefix = "max ";
1446                 }
1447                 else
1448                         error("invalid spawnflags");
1449
1450                 self.netname = "";
1451                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1452                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1453                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1454                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1455                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1456                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1457                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1458                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1459                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1460                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1461                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1462                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1463                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1464                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1465                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1466                 {
1467                         e = get_weaponinfo(j);
1468                         if(e.weapons)
1469                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & e.weapons), e.netname);
1470                 }
1471         }
1472         self.netname = strzone(self.netname);
1473         //print(self.netname, "\n");
1474
1475         n = tokenize_console(self.netname);
1476         for(i = 0; i < n; ++i)
1477         {
1478                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1479                 {
1480                         e = get_weaponinfo(j);
1481                         if(argv(i) == e.netname)
1482                         {
1483                                 weapon_action(e.weapon, WR_PRECACHE);
1484                                 break;
1485                         }
1486                 }
1487         }
1488 }
1489
1490 void spawnfunc_item_fuel(void)
1491 {
1492         if(!self.ammo_fuel)
1493                 self.ammo_fuel = g_pickup_fuel;
1494         if(!self.pickup_anyway)
1495                 self.pickup_anyway = g_pickup_ammo_anyway;
1496         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1497 }
1498
1499 void spawnfunc_item_fuel_regen(void)
1500 {
1501         if(start_items & IT_FUEL_REGEN)
1502         {
1503                 spawnfunc_item_fuel();
1504                 return;
1505         }
1506         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1507 }
1508
1509 void spawnfunc_item_jetpack(void)
1510 {
1511         if(g_grappling_hook)
1512                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1513         if(!self.ammo_fuel)
1514                 self.ammo_fuel = g_pickup_fuel_jetpack;
1515         if(start_items & IT_JETPACK)
1516         {
1517                 spawnfunc_item_fuel();
1518                 return;
1519         }
1520         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1521 }
1522
1523
1524 #define OP_SET 0
1525 #define OP_MIN 1
1526 #define OP_MAX 2
1527 #define OP_PLUS 3
1528 #define OP_MINUS 4
1529
1530 float GiveBit(entity e, .float fld, float bit, float op, float val)
1531 {
1532         float v0, v1;
1533         v0 = (e.fld & bit);
1534         switch(op)
1535         {
1536                 case OP_SET:
1537                         if(val > 0)
1538                                 e.fld |= bit;
1539                         else
1540                                 e.fld &~= bit;
1541                         break;
1542                 case OP_MIN:
1543                 case OP_PLUS:
1544                         if(val > 0)
1545                                 e.fld |= bit;
1546                         break;
1547                 case OP_MAX:
1548                         if(val <= 0)
1549                                 e.fld &~= bit;
1550                         break;
1551                 case OP_MINUS:
1552                         if(val > 0)
1553                                 e.fld &~= bit;
1554                         break;
1555         }
1556         v1 = (e.fld & bit);
1557         return (v0 != v1);
1558 }
1559
1560 float GiveValue(entity e, .float fld, float op, float val)
1561 {
1562         float v0, v1;
1563         v0 = e.fld;
1564         switch(op)
1565         {
1566                 case OP_SET:
1567                         e.fld = val;
1568                         break;
1569                 case OP_MIN:
1570                         e.fld = max(e.fld, val); // min 100 cells = at least 100 cells
1571                         break;
1572                 case OP_MAX:
1573                         e.fld = min(e.fld, val);
1574                         break;
1575                 case OP_PLUS:
1576                         e.fld += val;
1577                         break;
1578                 case OP_MINUS:
1579                         e.fld -= val;
1580                         break;
1581         }
1582         v1 = e.fld;
1583         return (v0 != v1);
1584 }
1585
1586 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1587 {
1588         if(v1 == v0)
1589                 return;
1590         if(v1 <= v0 - t)
1591         {
1592                 if(snd_decr != "")
1593                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTN_NORM);
1594         }
1595         else if(v0 >= v0 + t)
1596         {
1597                 if(snd_incr != "")
1598                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTN_NORM);
1599         }
1600 }
1601
1602 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1603 {
1604         if(v0 < v1)
1605                 e.rotfield = max(e.rotfield, time + rottime);
1606         else if(v0 > v1)
1607                 e.regenfield = max(e.regenfield, time + regentime);
1608 }
1609
1610 #define PREGIVE(e,f) float save_##f; save_##f = (e).f
1611 #define POSTGIVE_BIT(e,f,b,snd_incr,snd_decr) GiveSound((e), save_##f & (b), (e).f & (b), 0, snd_incr, snd_decr)
1612 #define POSTGIVE_VALUE(e,f,t,snd_incr,snd_decr) GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1613 #define POSTGIVE_VALUE_ROT(e,f,t,rotfield,rottime,regenfield,regentime,snd_incr,snd_decr) GiveRot((e), save_##f, (e).f, rotfield, rottime, regenfield, regentime); GiveSound((e), save_##f, (e).f, t, snd_incr, snd_decr)
1614
1615 float GiveItems(entity e, float beginarg, float endarg)
1616 {
1617         float got, i, j, val, op;
1618         float _switchweapon;
1619         entity wi;
1620         string cmd;
1621
1622         val = 999;
1623         op = OP_SET;
1624
1625         got = 0;
1626
1627         _switchweapon = FALSE;
1628         if (e.autoswitch)
1629                 if (e.switchweapon == w_getbestweapon(e))
1630                         _switchweapon = TRUE;
1631
1632         e.strength_finished = max(0, e.strength_finished - time);
1633         e.invincible_finished = max(0, e.invincible_finished - time);
1634         e.superweapons_finished = max(0, e.superweapons_finished - time);
1635
1636         PREGIVE(e, items);
1637         PREGIVE(e, weapons);
1638         PREGIVE(e, strength_finished);
1639         PREGIVE(e, invincible_finished);
1640         PREGIVE(e, superweapons_finished);
1641         PREGIVE(e, ammo_nails);
1642         PREGIVE(e, ammo_cells);
1643         PREGIVE(e, ammo_shells);
1644         PREGIVE(e, ammo_rockets);
1645         PREGIVE(e, ammo_fuel);
1646         PREGIVE(e, armorvalue);
1647         PREGIVE(e, health);
1648
1649         for(i = beginarg; i < endarg; ++i)
1650         {
1651                 cmd = argv(i);
1652
1653                 if(cmd == "0" || stof(cmd))
1654                 {
1655                         val = stof(cmd);
1656                         continue;
1657                 }
1658                 switch(cmd)
1659                 {
1660                         case "no":
1661                                 op = OP_MAX;
1662                                 val = 0;
1663                                 continue;
1664                         case "max":
1665                                 op = OP_MAX;
1666                                 continue;
1667                         case "min":
1668                                 op = OP_MIN;
1669                                 continue;
1670                         case "plus":
1671                                 op = OP_PLUS;
1672                                 continue;
1673                         case "minus":
1674                                 op = OP_MINUS;
1675                                 continue;
1676                         case "ALL":
1677                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1678                                 got += GiveValue(e, strength_finished, op, val);
1679                                 got += GiveValue(e, invincible_finished, op, val);
1680                                 got += GiveValue(e, superweapons_finished, op, val);
1681                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1682                         case "all":
1683                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1684                                 got += GiveValue(e, health, op, val);
1685                                 got += GiveValue(e, armorvalue, op, val);
1686                         case "allweapons":
1687                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1688                                 {
1689                                         wi = get_weaponinfo(j);
1690                                         if(wi.weapons)
1691                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1692                                 }
1693                         case "allammo":
1694                                 got += GiveValue(e, ammo_cells, op, val);
1695                                 got += GiveValue(e, ammo_shells, op, val);
1696                                 got += GiveValue(e, ammo_nails, op, val);
1697                                 got += GiveValue(e, ammo_rockets, op, val);
1698                                 got += GiveValue(e, ammo_fuel, op, val);
1699                                 break;
1700                         case "unlimited_ammo":
1701                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1702                                 break;
1703                         case "unlimited_weapon_ammo":
1704                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1705                                 break;
1706                         case "unlimited_superweapons":
1707                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1708                                 break;
1709                         case "jetpack":
1710                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1711                                 break;
1712                         case "fuel_regen":
1713                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1714                                 break;
1715                         case "strength":
1716                                 got += GiveValue(e, strength_finished, op, val);
1717                                 break;
1718                         case "invincible":
1719                                 got += GiveValue(e, invincible_finished, op, val);
1720                                 break;
1721                         case "superweapons":
1722                                 got += GiveValue(e, superweapons_finished, op, val);
1723                                 break;
1724                         case "cells":
1725                                 got += GiveValue(e, ammo_cells, op, val);
1726                                 break;
1727                         case "shells":
1728                                 got += GiveValue(e, ammo_shells, op, val);
1729                                 break;
1730                         case "nails":
1731                         case "bullets":
1732                                 got += GiveValue(e, ammo_nails, op, val);
1733                                 break;
1734                         case "rockets":
1735                                 got += GiveValue(e, ammo_rockets, op, val);
1736                                 break;
1737                         case "health":
1738                                 got += GiveValue(e, health, op, val);
1739                                 break;
1740                         case "armor":
1741                                 got += GiveValue(e, armorvalue, op, val);
1742                                 break;
1743                         case "fuel":
1744                                 got += GiveValue(e, ammo_fuel, op, val);
1745                                 break;
1746                         default:
1747                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1748                                 {
1749                                         wi = get_weaponinfo(j);
1750                                         if(cmd == wi.netname)
1751                                         {
1752                                                 got += GiveBit(e, weapons, wi.weapons, op, val);
1753                                                 break;
1754                                         }
1755                                 }
1756                                 if(j > WEP_LAST)
1757                                         print("give: invalid item ", cmd, "\n");
1758                                 break;
1759                 }
1760                 val = 999;
1761                 op = OP_SET;
1762         }
1763
1764         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1765         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1766         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1767         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1768         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1769         {
1770                 wi = get_weaponinfo(j);
1771                 if(wi.weapons)
1772                 {
1773                         POSTGIVE_BIT(e, weapons, wi.weapons, "weapons/weaponpickup.wav", string_null);
1774                         if not(save_weapons & wi.weapons)
1775                                 if(e.weapons & wi.weapons)
1776                                         weapon_action(wi.weapon, WR_PRECACHE);
1777                 }
1778         }
1779         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1780         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1781         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1782         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1783         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1784         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1785         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1786         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1787         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1788
1789         if(e.superweapons_finished <= 0)
1790                 if(self.weapons & WEPBIT_SUPERWEAPONS)
1791                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
1792
1793         if (g_minstagib)
1794         {
1795                 e.health = bound(0, e.health, 100);
1796                 e.armorvalue = bound(0, e.armorvalue, 999);
1797         }
1798
1799         if(e.strength_finished <= 0)
1800                 e.strength_finished = 0;
1801         else
1802                 e.strength_finished += time;
1803         if(e.invincible_finished <= 0)
1804                 e.invincible_finished = 0;
1805         else
1806                 e.invincible_finished += time;
1807         if(e.superweapons_finished <= 0)
1808                 e.superweapons_finished = 0;
1809         else
1810                 e.superweapons_finished += time;
1811
1812         if not(e.weapons & W_WeaponBit(e.switchweapon))
1813                 _switchweapon = TRUE;
1814         if(_switchweapon)
1815                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
1816
1817         return got;
1818 }