qcsrc/server/cl_weapons.qc

   1 void W_TriggerReload()
   2 {
   3     weapon_action(self.weapon, WR_RELOAD);
   4 }
   5
   6 // switch between weapons
   7 void W_SwitchWeapon(float imp)
   8 {
   9         if (self.switchweapon != imp)
  10         {
  11                 if (client_hasweapon(self, imp, TRUE, TRUE))
  12                         W_SwitchWeapon_Force(self, imp);
  13                 else
  14                         self.selectweapon = imp; // update selectweapon ANYWAY
  15         }
  16         else
  17         {
  18                 W_TriggerReload();
  19         }
  20 }
  21
  22 .float weaponcomplainindex;
  23 float W_GetCycleWeapon(entity pl, string weaponorder, float dir, float imp, float complain, float skipmissing)
  24 {
  25         // We cannot tokenize in this function, as GiveItems calls this
  26         // function. Thus we must use car/cdr.
  27         float weaponwant, first_valid, prev_valid, switchtonext, switchtolast, c;
  28         string rest;
  29         switchtonext = switchtolast = 0;
  30         first_valid = prev_valid = 0;
  31         float weaponcur;
  32
  33         if(skipmissing || pl.selectweapon == 0)
  34                 weaponcur = pl.switchweapon;
  35         else
  36                 weaponcur = pl.selectweapon;
  37
  38         if(dir == 0)
  39                 switchtonext = 1;
  40
  41         c = 0;
  42
  43         rest = weaponorder;
  44         while(rest != "")
  45         {
  46                 weaponwant = stof(car(rest)); rest = cdr(rest);
  47                 if(imp >= 0)
  48                         if((get_weaponinfo(weaponwant)).impulse != imp)
  49                                 continue;
  50
  51                 ++c;
  52
  53                 if(!skipmissing || client_hasweapon(pl, weaponwant, TRUE, FALSE))
  54                 {
  55                         if(switchtonext)
  56                                 return weaponwant;
  57                         if(!first_valid)
  58                                 first_valid = weaponwant;
  59                         if(weaponwant == weaponcur)
  60                         {
  61                                 if(dir >= 0)
  62                                         switchtonext = 1;
  63                                 else if(prev_valid)
  64                                         return prev_valid;
  65                                 else
  66                                         switchtolast = 1;
  67                         }
  68                         prev_valid = weaponwant;
  69                 }
  70         }
  71         if(first_valid)
  72         {
  73                 if(switchtolast)
  74                         return prev_valid;
  75                 else
  76                         return first_valid;
  77         }
  78         // complain (but only for one weapon on the button that has been pressed)
  79         if(complain)
  80         {
  81                 self.weaponcomplainindex += 1;
  82                 c = mod(self.weaponcomplainindex, c) + 1;
  83                 rest = weaponorder;
  84                 while(rest != "")
  85                 {
  86                         weaponwant = stof(car(rest)); rest = cdr(rest);
  87                         if(imp >= 0)
  88                                 if((get_weaponinfo(weaponwant)).impulse != imp)
  89                                         continue;
  90
  91                         --c;
  92                         if(c == 0)
  93                         {
  94                                 client_hasweapon(pl, weaponwant, TRUE, TRUE);
  95                                 break;
  96                         }
  97                 }
  98         }
  99         return 0;
 100 }
 101
 102 void W_CycleWeapon(string weaponorder, float dir)
 103 {
 104         float w;
 105         w = W_GetCycleWeapon(self, weaponorder, dir, -1, 1, TRUE);
 106         if(w > 0)
 107                 W_SwitchWeapon(w);
 108 }
 109
 110 void W_NextWeaponOnImpulse(float imp)
 111 {
 112         float w;
 113         w = W_GetCycleWeapon(self, self.cvar_cl_weaponpriority, +1, imp, 1, (self.cvar_cl_weaponimpulsemode == 0));
 114         if(w > 0)
 115                 W_SwitchWeapon(w);
 116 }
 117
 118 // next weapon
 119 void W_NextWeapon(float list)
 120 {
 121         if(list == 0)
 122                 W_CycleWeapon(weaponorder_byid, -1);
 123         else if(list == 1)
 124                 W_CycleWeapon(self.weaponorder_byimpulse, -1);
 125         else if(list == 2)
 126                 W_CycleWeapon(self.cvar_cl_weaponpriority, -1);
 127 }
 128
 129 // prev weapon
 130 void W_PreviousWeapon(float list)
 131 {
 132         if(list == 0)
 133                 W_CycleWeapon(weaponorder_byid, +1);
 134         else if(list == 1)
 135                 W_CycleWeapon(self.weaponorder_byimpulse, +1);
 136         else if(list == 2)
 137                 W_CycleWeapon(self.cvar_cl_weaponpriority, +1);
 138 }
 139
 140 // previously used if exists and has ammo, (second) best otherwise
 141 void W_LastWeapon()
 142 {
 143         if(client_hasweapon(self, self.cnt, TRUE, FALSE))
 144                 W_SwitchWeapon(self.cnt);
 145         else
 146                 W_SwitchToOtherWeapon(self);
 147 }
 148
 149 float w_getbestweapon(entity e)
 150 {
 151         return W_GetCycleWeapon(e, e.cvar_cl_weaponpriority, 0, -1, FALSE, TRUE);
 152 }
 153
 154 // generic weapons table
 155 // TODO should they be macros instead?
 156 float weapon_action(float wpn, float wrequest)
 157 {
 158         return (get_weaponinfo(wpn)).weapon_func(wrequest);
 159 }
 160
 161 string W_Name(float weaponid)
 162 {
 163         return (get_weaponinfo(weaponid)).message;
 164 }
 165
 166 float W_WeaponBit(float wpn)
 167 {
 168         return (get_weaponinfo(wpn)).weapons;
 169 }
 170
 171 float W_AmmoItemCode(float wpn)
 172 {
 173         return (get_weaponinfo(wpn)).items & IT_AMMO;
 174 }
 175
 176 .float savenextthink;
 177 void thrown_wep_think()
 178 {
 179         self.owner = world;
 180         float timeleft = self.savenextthink - time;
 181         if(timeleft > 1)
 182                 SUB_SetFade(self, self.savenextthink - 1, 1);
 183         else if(timeleft > 0)
 184                 SUB_SetFade(self, time, timeleft);
 185         else
 186                 SUB_VanishOrRemove(self);
 187 }
 188
 189 // returns amount of ammo used as string, or -1 for failure, or 0 for no ammo count
 190 string W_ThrowNewWeapon(entity own, float wpn, float doreduce, vector org, vector velo)
 191 {
 192         entity oldself, wep;
 193         float wa, thisammo, i, j;
 194         string s;
 195         var .float ammofield;
 196
 197         wep = spawn();
 198
 199         setorigin(wep, org);
 200         wep.classname = "droppedweapon";
 201         wep.velocity = velo;
 202         wep.owner = wep.enemy = own;
 203         wep.flags |= FL_TOSSED;
 204         wep.colormap = own.colormap;
 205
 206         if(W_WeaponBit(wpn) & WEPBIT_SUPERWEAPONS)
 207         {
 208                 if(own.items & IT_UNLIMITED_SUPERWEAPONS)
 209                 {
 210                         wep.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 211                 }
 212                 else
 213                 {
 214                         float superweapons = 1;
 215                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 216                                 if(own.weapons & WEPBIT_SUPERWEAPONS & W_WeaponBit(i))
 217                                         ++superweapons;
 218                         if(superweapons <= 1)
 219                         {
 220                                 wep.superweapons_finished = own.superweapons_finished;
 221                                 own.superweapons_finished = 0;
 222                         }
 223                         else
 224                         {
 225                                 float timeleft = own.superweapons_finished - time;
 226                                 float weptimeleft = timeleft / superweapons;
 227                                 wep.superweapons_finished = time + weptimeleft;
 228                                 own.superweapons_finished -= weptimeleft;
 229                         }
 230                 }
 231         }
 232
 233         wa = W_AmmoItemCode(wpn);
 234         if(wa == 0)
 235         {
 236                 oldself = self;
 237                 self = wep;
 238                 weapon_defaultspawnfunc(wpn);
 239                 self = oldself;
 240                 if(startitem_failed)
 241                         return string_null;
 242                 wep.glowmod = own.weaponentity_glowmod;
 243                 wep.think = thrown_wep_think;
 244                 wep.savenextthink = wep.nextthink;
 245                 wep.nextthink = min(wep.nextthink, time + 0.5);
 246                 wep.pickup_anyway = TRUE; // these are ALWAYS pickable
 247                 return "";
 248         }
 249         else
 250         {
 251                 s = "";
 252                 oldself = self;
 253                 self = wep;
 254                 weapon_defaultspawnfunc(wpn);
 255                 self = oldself;
 256                 if(startitem_failed)
 257                         return string_null;
 258                 if(doreduce && g_weapon_stay == 2)
 259                 {
 260                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 261                         {
 262                                 if(wa & j)
 263                                 {
 264                                         ammofield = Item_CounterField(j);
 265
 266                                         // if our weapon is loaded, give its load back to the player
 267                                         if(self.(weapon_load[self.weapon]) > 0)
 268                                         {
 269                                                 own.ammofield += self.(weapon_load[self.weapon]);
 270                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 271                                         }
 272
 273                                         wep.ammofield = 0;
 274                                 }
 275                         }
 276                 }
 277                 else if(doreduce)
 278                 {
 279                         for(i = 0, j = 1; i < 24; ++i, j *= 2)
 280                         {
 281                                 if(wa & j)
 282                                 {
 283                                         ammofield = Item_CounterField(j);
 284
 285                                         // if our weapon is loaded, give its load back to the player
 286                                         if(self.(weapon_load[self.weapon]) > 0)
 287                                         {
 288                                                 own.ammofield += self.(weapon_load[self.weapon]);
 289                                                 self.(weapon_load[self.weapon]) = -1; // schedule the weapon for reloading
 290                                         }
 291
 292                                         thisammo = min(own.ammofield, wep.ammofield);
 293                                         wep.ammofield = thisammo;
 294                                         own.ammofield -= thisammo;
 295                                         s = strcat(s, " and ", ftos(thisammo), " ", Item_CounterFieldName(j));
 296                                 }
 297                         }
 298                         s = substring(s, 5, -1);
 299                 }
 300                 wep.glowmod = own.weaponentity_glowmod;
 301                 wep.think = thrown_wep_think;
 302                 wep.savenextthink = wep.nextthink;
 303                 wep.nextthink = min(wep.nextthink, time + 0.5);
 304                 wep.pickup_anyway = TRUE; // these are ALWAYS pickable
 305                 return s;
 306         }
 307 }
 308
 309 float W_IsWeaponThrowable(float w)
 310 {
 311         float wb, wa;
 312
 313         if (!autocvar_g_pickup_items)
 314                 return 0;
 315         if (g_weaponarena)
 316                 return 0;
 317         if (g_lms)
 318                 return 0;
 319         if (g_ca)
 320                 return 0;
 321         if (g_cts)
 322                 return 0;
 323         if (g_nexball && w == WEP_GRENADE_LAUNCHER)
 324                 return 0;
 325
 326         wb = W_WeaponBit(w);
 327         if(!wb)
 328                 return 0;
 329         wa = W_AmmoItemCode(w);
 330         if(start_weapons & wb)
 331         {
 332                 // start weapons that take no ammo can't be dropped (this prevents dropping the laser, as long as it continues to use no ammo)
 333                 if(start_items & IT_UNLIMITED_WEAPON_AMMO)
 334                         return 0;
 335                 if(wa == 0)
 336                         return 0;
 337         }
 338
 339         return 1;
 340 }
 341
 342 // toss current weapon
 343 void W_ThrowWeapon(vector velo, vector delta, float doreduce)
 344 {
 345         float w, wb;
 346         string a;
 347
 348         w = self.weapon;
 349         if (w == 0)
 350                 return; // just in case
 351         if(MUTATOR_CALLHOOK(ForbidThrowCurrentWeapon))
 352                 return;
 353         if(!autocvar_g_weapon_throwable)
 354                 return;
 355         if(self.weaponentity.state != WS_READY)
 356                 return;
 357         if(!W_IsWeaponThrowable(w))
 358                 return;
 359
 360         wb = W_WeaponBit(w);
 361         if(self.weapons & wb != wb)
 362                 return;
 363
 364         self.weapons &~= wb;
 365         W_SwitchWeapon_Force(self, w_getbestweapon(self));
 366         a = W_ThrowNewWeapon(self, w, doreduce, self.origin + delta, velo);
 367         if not(a)
 368                 return;
 369         if(a == "")
 370                 sprint(self, strcat("You dropped the ^2", W_Name(w), "\n"));
 371         else
 372                 sprint(self, strcat("You dropped the ^2", W_Name(w), " with ", a, "\n"));
 373 }
 374
 375 // Bringed back weapon frame
 376 void W_WeaponFrame()
 377 {
 378         vector fo, ri, up;
 379
 380         if (frametime)
 381                 self.weapon_frametime = frametime;
 382
 383         if(((arena_roundbased || g_ca || g_freezetag) && time < warmup) || ((time < game_starttime) && !autocvar_sv_ready_restart_after_countdown))
 384                 return;
 385
 386         if(self.freezetag_frozen == 1)
 387                 return;
 388
 389         if (!self.weaponentity || self.health < 1)
 390                 return; // Dead player can't use weapons and injure impulse commands
 391
 392         if(!self.switchweapon)
 393         {
 394                 self.weapon = 0;
 395                 self.switchingweapon = 0;
 396                 self.weaponentity.state = WS_CLEAR;
 397                 self.weaponname = "";
 398                 self.items &~= IT_AMMO;
 399                 return;
 400         }
 401
 402         makevectors(self.v_angle);
 403         fo = v_forward; // save them in case the weapon think functions change it
 404         ri = v_right;
 405         up = v_up;
 406
 407         // Change weapon
 408         if (self.weapon != self.switchweapon)
 409         {
 410                 if (self.weaponentity.state == WS_CLEAR)
 411                 {
 412                         // end switching!
 413                         self.switchingweapon = self.switchweapon;
 414
 415                         //setanim(self, self.anim_draw, FALSE, TRUE, TRUE);
 416                         self.weaponentity.state = WS_RAISE;
 417                         weapon_action(self.switchweapon, WR_SETUP);
 418
 419                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 420                         entity e;
 421                         e = get_weaponinfo(self.switchweapon);
 422                         if(e.spawnflags & WEP_FLAG_RELOADABLE && cvar(strcat("g_balance_", e.netname, "_reload_ammo"))) // prevent accessing undefined cvars
 423                         {
 424                                 self.clip_load = self.(weapon_load[self.switchweapon]);
 425                                 self.clip_size = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 426                         }
 427                         else
 428                                 self.clip_load = self.clip_size = 0;
 429
 430                         // VorteX: add player model weapon select frame here
 431                         // setcustomframe(PlayerWeaponRaise);
 432                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_weaponswitchdelay, w_ready);
 433                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');
 434                 }
 435                 else if (self.weaponentity.state == WS_DROP)
 436                 {
 437                         // in dropping phase we can switch at any time
 438                         self.switchingweapon = self.switchweapon;
 439                 }
 440                 else if (self.weaponentity.state == WS_READY)
 441                 {
 442                         // start switching!
 443                         self.switchingweapon = self.switchweapon;
 444
 445 #ifndef INDEPENDENT_ATTACK_FINISHED
 446                         if(ATTACK_FINISHED(self) <= time + self.weapon_frametime * 0.5)
 447                         {
 448 #endif
 449                         sound (self, CH_WEAPON_SINGLE, "weapons/weapon_switch.wav", VOL_BASE, ATTN_NORM);
 450                         self.weaponentity.state = WS_DROP;
 451                         // set up weapon switch think in the future, and start drop anim
 452                         weapon_thinkf(WFRAME_DONTCHANGE, autocvar_g_balance_weaponswitchdelay, w_clear);
 453                         weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);
 454 #ifndef INDEPENDENT_ATTACK_FINISHED
 455                         }
 456 #endif
 457                 }
 458         }
 459
 460         // LordHavoc: network timing test code
 461         //if (self.button0)
 462         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(self)), " >= ", ftos(self.weapon_nextthink), "\n");
 463
 464         float wb;
 465         wb = W_WeaponBit(self.weapon);
 466
 467         // call the think code which may fire the weapon
 468         // and do so multiple times to resolve framerate dependency issues if the
 469         // server framerate is very low and the weapon fire rate very high
 470         float c;
 471         c = 0;
 472         while (c < W_TICSPERFRAME)
 473         {
 474                 c = c + 1;
 475                 if(wb && ((self.weapons & wb) == 0))
 476                 {
 477                         if(self.weapon == self.switchweapon)
 478                                 W_SwitchWeapon_Force(self, w_getbestweapon(self));
 479                         wb = 0;
 480                 }
 481
 482                 v_forward = fo;
 483                 v_right = ri;
 484                 v_up = up;
 485
 486                 if(wb)
 487                         weapon_action(self.weapon, WR_THINK);
 488                 else
 489                         weapon_action(self.weapon, WR_GONETHINK);
 490
 491                 if (time + self.weapon_frametime * 0.5 >= self.weapon_nextthink)
 492                 {
 493                         if(self.weapon_think)
 494                         {
 495                                 v_forward = fo;
 496                                 v_right = ri;
 497                                 v_up = up;
 498                                 self.weapon_think();
 499                         }
 500                         else
 501                                 bprint("\{1}^1ERROR: undefined weapon think function for ", self.netname, "\n");
 502                 }
 503         }
 504
 505         // don't let attack_finished fall behind when not firing (must be after weapon_setup calls!)
 506         //if (ATTACK_FINISHED(self) < time)
 507         //      ATTACK_FINISHED(self) = time;
 508
 509         //if (self.weapon_nextthink < time)
 510         //      self.weapon_nextthink = time;
 511
 512         // update currentammo incase it has changed
 513 #if 0
 514         if (self.items & IT_CELLS)
 515                 self.currentammo = self.ammo_cells;
 516         else if (self.items & IT_ROCKETS)
 517                 self.currentammo = self.ammo_rockets;
 518         else if (self.items & IT_NAILS)
 519                 self.currentammo = self.ammo_nails;
 520         else if (self.items & IT_SHELLS)
 521                 self.currentammo = self.ammo_shells;
 522         else
 523                 self.currentammo = 1;
 524 #endif
 525 }