qcsrc/server/w_rocketlauncher.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(ROCKET_LAUNCHER, w_rlauncher, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "rl", "rocketlauncher", _("Rocket Launcher"))
   3 #else
   4 #ifdef SVQC
   5 .float rl_release;
   6 .float rl_detonate_later;
   7
   8 .float rocketlauncher_load;
   9
  10 void W_RocketLauncher_SetAmmoCounter()
  11 {
  12         // set clip_load to the weapon we have switched to, if the gun uses reloading
  13         if(!autocvar_g_balance_rocketlauncher_reload_ammo)
  14                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  15         else
  16         {
  17                 self.clip_load = self.rocketlauncher_load;
  18                 self.clip_size = autocvar_g_balance_rocketlauncher_reload_ammo; // for the crosshair ammo display
  19         }
  20 }
  21
  22 void W_RocketLauncher_ReloadedAndReady()
  23 {
  24         float t;
  25
  26         // now do the ammo transfer
  27         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  28         while(self.clip_load < autocvar_g_balance_rocketlauncher_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  29         {
  30                 self.clip_load += 1;
  31                 self.ammo_rockets -= 1;
  32         }
  33         self.rocketlauncher_load = self.clip_load;
  34
  35         t = ATTACK_FINISHED(self) - autocvar_g_balance_rocketlauncher_reload_time - 1;
  36         ATTACK_FINISHED(self) = t;
  37         w_ready();
  38 }
  39
  40 void W_RocketLauncher_Reload()
  41 {
  42         // return if reloading is disabled for this weapon
  43         if(!autocvar_g_balance_rocketlauncher_reload_ammo)
  44                 return;
  45
  46         if(!W_ReloadCheck(self.ammo_rockets, autocvar_g_balance_rocketlauncher_ammo))
  47                 return;
  48
  49         float t;
  50
  51         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  52
  53         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_rocketlauncher_reload_time + 1;
  54         ATTACK_FINISHED(self) = t;
  55
  56         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_rocketlauncher_reload_time, W_RocketLauncher_ReloadedAndReady);
  57
  58         self.old_clip_load = self.clip_load;
  59         self.clip_load = -1;
  60 }
  61
  62 void W_Rocket_Unregister()
  63 {
  64         if(self.owner && self.owner.lastrocket == self)
  65         {
  66                 self.owner.lastrocket = world;
  67                 // self.owner.rl_release = 1;
  68         }
  69 }
  70
  71 void W_Rocket_Explode ()
  72 {
  73         W_Rocket_Unregister();
  74
  75         if(other.takedamage == DAMAGE_AIM)
  76                 if(other.classname == "player")
  77                         if(IsDifferentTeam(self.owner, other))
  78                                 if(IsFlying(other))
  79                                         AnnounceTo(self.owner, "airshot");
  80
  81         self.event_damage = SUB_Null;
  82         self.takedamage = DAMAGE_NO;
  83
  84         RadiusDamage (self, self.owner, autocvar_g_balance_rocketlauncher_damage, autocvar_g_balance_rocketlauncher_edgedamage, autocvar_g_balance_rocketlauncher_radius, world, autocvar_g_balance_rocketlauncher_force, self.projectiledeathtype, other);
  85
  86         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
  87         {
  88                 if(self.owner.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
  89                 {
  90                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
  91                         ATTACK_FINISHED(self.owner) = time;
  92                         self.owner.switchweapon = w_getbestweapon(self.owner);
  93                 }
  94         }
  95         remove (self);
  96 }
  97
  98 void W_Rocket_DoRemoteExplode ()
  99 {
 100         W_Rocket_Unregister();
 101
 102         self.event_damage = SUB_Null;
 103         self.takedamage = DAMAGE_NO;
 104
 105         RadiusDamage (self, self.owner, autocvar_g_balance_rocketlauncher_remote_damage, autocvar_g_balance_rocketlauncher_remote_edgedamage, autocvar_g_balance_rocketlauncher_remote_radius, world, autocvar_g_balance_rocketlauncher_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 106
 107         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 108         {
 109                 if(self.owner.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
 110                 {
 111                         self.owner.cnt = WEP_ROCKET_LAUNCHER;
 112                         ATTACK_FINISHED(self.owner) = time;
 113                         self.owner.switchweapon = w_getbestweapon(self.owner);
 114                 }
 115         }
 116         remove (self);
 117 }
 118
 119 entity FindLaserTarget(entity e, float dist_variance, float dot_variance)
 120 {
 121         entity head, selected;
 122         vector dir;
 123         float dist, maxdist,// bestdist,
 124                 dot,// bestdot,
 125                 points, bestpoints;
 126         //bestdist = 9999;
 127         //bestdot = -2;
 128         bestpoints = 0;
 129         maxdist = 800;
 130         selected = world;
 131
 132         makevectors(e.angles);
 133
 134         head = find(world, classname, "laser_target");
 135         while(head)
 136         {
 137                 points = 0;
 138                 dir = normalize(head.origin - self.origin);
 139                 dot = dir * v_forward;
 140                 dist = vlen(head.origin - self.origin);
 141                 if(dist > maxdist)
 142                         dist = maxdist;
 143
 144                 // gain points for being in front
 145                 points = points + ((dot+1)*0.5) * 500
 146                         * (1 + crandom()*dot_variance);
 147                 // gain points for being close away
 148                 points = points + (1 - dist/maxdist) * 1000
 149                         * (1 + crandom()*dot_variance);
 150
 151                 traceline(e.origin, head.origin, TRUE, self);
 152                 if(trace_fraction < 1)
 153                 {
 154                         points = 0;
 155                 }
 156
 157                 if(points > bestpoints)//random() > 0.5)//
 158                 {
 159                         bestpoints = points;
 160                         selected = head;
 161                 }
 162
 163                 head = find(head, classname, "laser_target");
 164         }
 165
 166         //bprint(selected.owner.netname);
 167         //bprint("\n");
 168         return selected;
 169 }
 170
 171 void W_Rocket_RemoteExplode()
 172 {
 173         if(self.owner.deadflag == DEAD_NO)
 174         if(self.owner.lastrocket)
 175         {
 176                 if((self.spawnshieldtime >= 0)
 177                         ? (time >= self.spawnshieldtime) // timer
 178                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_rocketlauncher_remote_radius) // safety device
 179                 )
 180                 {
 181                         W_Rocket_DoRemoteExplode();
 182                 }
 183         }
 184 }
 185
 186 vector rocket_steerto(vector thisdir, vector goaldir, float maxturn_cos)
 187 {
 188         if(thisdir * goaldir > maxturn_cos)
 189                 return goaldir;
 190         float f, m2;
 191         vector v;
 192         // solve:
 193         //   g = normalize(thisdir + goaldir * X)
 194         //   thisdir * g = maxturn
 195         //
 196         //   gg = thisdir + goaldir * X
 197         //   (thisdir * gg)^2 = maxturn^2 * (gg * gg)
 198         //
 199         //   (1 + (thisdir * goaldir) * X)^2 = maxturn^2 * (1 + X*X + 2 * X * thisdir * goaldir)
 200         f = thisdir * goaldir;
 201         //   (1 + f * X)^2 = maxturn^2 * (1 + X*X + 2 * X * f)
 202         //   0 = (m^2 - f^2) * x^2 + (2 * f * (m^2 - 1)) * x + (m^2 - 1)
 203         m2 = maxturn_cos * maxturn_cos;
 204         v = solve_quadratic(m2 - f * f, 2 * f * (m2 - 1), m2 - 1);
 205         return normalize(thisdir + goaldir * v_y); // the larger solution!
 206 }
 207
 208 void W_Rocket_Think (void)
 209 {
 210         vector desireddir, olddir, newdir, desiredorigin, goal;
 211 #if 0
 212         float cosminang, cosmaxang, cosang;
 213 #endif
 214         float velspeed, f;
 215         self.nextthink = time;
 216         if (time > self.cnt)
 217         {
 218                 other = world;
 219                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 220                 W_Rocket_Explode ();
 221                 return;
 222         }
 223
 224         // accelerate
 225         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 226         velspeed = autocvar_g_balance_rocketlauncher_speed * g_weaponspeedfactor - (self.velocity * v_forward);
 227         if (velspeed > 0)
 228                 self.velocity = self.velocity + v_forward * min(autocvar_g_balance_rocketlauncher_speedaccel * g_weaponspeedfactor * frametime, velspeed);
 229
 230         // laser guided, or remote detonation
 231         if (self.owner.weapon == WEP_ROCKET_LAUNCHER)
 232         {
 233                 if(self == self.owner.lastrocket)
 234                 if not(self.owner.rl_release)
 235                 if not(self.BUTTON_ATCK2)
 236                 if(autocvar_g_balance_rocketlauncher_guiderate)
 237                 if(time > self.pushltime)
 238                 if(self.owner.deadflag == DEAD_NO)
 239                 {
 240                         f = autocvar_g_balance_rocketlauncher_guideratedelay;
 241                         if(f)
 242                                 f = bound(0, (time - self.pushltime) / f, 1);
 243                         else
 244                                 f = 1;
 245
 246                         velspeed = vlen(self.velocity);
 247
 248                         makevectors(self.owner.v_angle);
 249                         desireddir = WarpZone_RefSys_TransformVelocity(self.owner, self, v_forward);
 250                         desiredorigin = WarpZone_RefSys_TransformOrigin(self.owner, self, self.owner.origin + self.owner.view_ofs);
 251                         olddir = normalize(self.velocity);
 252
 253                         // now it gets tricky... we want to move like some curve to approximate the target direction
 254                         // but we are limiting the rate at which we can turn!
 255                         goal = desiredorigin + ((self.origin - desiredorigin) * desireddir + autocvar_g_balance_rocketlauncher_guidegoal) * desireddir;
 256                         newdir = rocket_steerto(olddir, normalize(goal - self.origin), cos(autocvar_g_balance_rocketlauncher_guiderate * f * frametime * DEG2RAD));
 257
 258                         self.velocity = newdir * velspeed;
 259                         self.angles = vectoangles(self.velocity);
 260
 261                         if(!self.count)
 262                         {
 263                                 pointparticles(particleeffectnum("rocket_guide"), self.origin, self.velocity, 1);
 264                                 // TODO add a better sound here
 265                                 sound (self.owner, CHAN_WEAPON2, "weapons/rocket_mode.wav", VOL_BASE, ATTN_NORM);
 266                                 self.count = 1;
 267                         }
 268                 }
 269
 270                 if(self.rl_detonate_later)
 271                         W_Rocket_RemoteExplode();
 272         }
 273
 274         if(self.csqcprojectile_clientanimate == 0)
 275                 UpdateCSQCProjectile(self);
 276 }
 277
 278 void W_Rocket_Touch (void)
 279 {
 280         if(WarpZone_Projectile_Touch())
 281         {
 282                 if(wasfreed(self))
 283                         W_Rocket_Unregister();
 284                 return;
 285         }
 286         W_Rocket_Unregister();
 287         W_Rocket_Explode ();
 288 }
 289
 290 void W_Rocket_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 291 {
 292         if (self.health <= 0)
 293                 return;
 294         self.health = self.health - damage;
 295         self.angles = vectoangles(self.velocity);
 296         if (self.health <= 0)
 297                 W_PrepareExplosionByDamage(attacker, W_Rocket_Explode);
 298 }
 299
 300 void W_Rocket_Attack (void)
 301 {
 302         local entity missile;
 303         local entity flash;
 304
 305         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 306         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 307         {
 308                 if(autocvar_g_balance_rocketlauncher_reload_ammo)
 309                 {
 310                         self.clip_load -= autocvar_g_balance_rocketlauncher_ammo;
 311                         self.rocketlauncher_load = self.clip_load;
 312                 }
 313                 else
 314                         self.ammo_rockets -= autocvar_g_balance_rocketlauncher_ammo;
 315         }
 316
 317         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/rocket_fire.wav", CHAN_WEAPON, autocvar_g_balance_rocketlauncher_damage);
 318         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 319
 320         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 321         missile.owner = self;
 322         self.lastrocket = missile;
 323         if(autocvar_g_balance_rocketlauncher_detonatedelay >= 0)
 324                 missile.spawnshieldtime = time + autocvar_g_balance_rocketlauncher_detonatedelay;
 325         else
 326                 missile.spawnshieldtime = -1;
 327         missile.pushltime = time + autocvar_g_balance_rocketlauncher_guidedelay;
 328         missile.classname = "rocket";
 329         missile.bot_dodge = TRUE;
 330         missile.bot_dodgerating = autocvar_g_balance_rocketlauncher_damage * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 331
 332         missile.takedamage = DAMAGE_YES;
 333         missile.damageforcescale = autocvar_g_balance_rocketlauncher_damageforcescale;
 334         missile.health = autocvar_g_balance_rocketlauncher_health;
 335         missile.event_damage = W_Rocket_Damage;
 336
 337         missile.movetype = MOVETYPE_FLY;
 338         PROJECTILE_MAKETRIGGER(missile);
 339         missile.projectiledeathtype = WEP_ROCKET_LAUNCHER;
 340         setsize (missile, '-3 -3 -3', '3 3 3'); // give it some size so it can be shot
 341
 342         setorigin (missile, w_shotorg - v_forward * 3); // move it back so it hits the wall at the right point
 343         W_SetupProjectileVelocity(missile, autocvar_g_balance_rocketlauncher_speedstart, 0);
 344         missile.angles = vectoangles (missile.velocity);
 345
 346         missile.touch = W_Rocket_Touch;
 347         missile.think = W_Rocket_Think;
 348         missile.nextthink = time;
 349         missile.cnt = time + autocvar_g_balance_rocketlauncher_lifetime;
 350         missile.flags = FL_PROJECTILE;
 351
 352         CSQCProjectile(missile, autocvar_g_balance_rocketlauncher_guiderate == 0 && autocvar_g_balance_rocketlauncher_speedaccel == 0, PROJECTILE_ROCKET, FALSE); // because of fly sound
 353
 354         // muzzle flash for 1st person view
 355         flash = spawn ();
 356         setmodel (flash, "models/flash.md3"); // precision set below
 357         SUB_SetFade (flash, time, 0.1);
 358         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 359         W_AttachToShotorg(flash, '5 0 0');
 360
 361         // common properties
 362         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 363 }
 364
 365 void spawnfunc_weapon_rocketlauncher (void); // defined in t_items.qc
 366
 367 float w_rlauncher(float req)
 368 {
 369         entity rock;
 370         float rockfound;
 371         if (req == WR_AIM)
 372         {
 373                 // aim and decide to fire if appropriate
 374                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_rocketlauncher_speed, 0, autocvar_g_balance_rocketlauncher_lifetime, FALSE);
 375                 if(skill >= 2) // skill 0 and 1 bots won't detonate rockets!
 376                 {
 377                         // decide whether to detonate rockets
 378                         local entity missile, targetlist, targ;
 379                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 380                         local float selfdamage, teamdamage, enemydamage;
 381                         edgedamage = autocvar_g_balance_rocketlauncher_edgedamage;
 382                         coredamage = autocvar_g_balance_rocketlauncher_damage;
 383                         edgeradius = autocvar_g_balance_rocketlauncher_radius;
 384                         recipricoledgeradius = 1 / edgeradius;
 385                         selfdamage = 0;
 386                         teamdamage = 0;
 387                         enemydamage = 0;
 388                         targetlist = findchainfloat(bot_attack, TRUE);
 389                         missile = find(world, classname, "rocket");
 390                         while (missile)
 391                         {
 392                                 if (missile.owner != self)
 393                                 {
 394                                         missile = find(missile, classname, "rocket");
 395                                         continue;
 396                                 }
 397                                 targ = targetlist;
 398                                 while (targ)
 399                                 {
 400                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - missile.origin);
 401                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 402                                         // count potential damage according to type of target
 403                                         if (targ == self)
 404                                                 selfdamage = selfdamage + d;
 405                                         else if (targ.team == self.team && teams_matter)
 406                                                 teamdamage = teamdamage + d;
 407                                         else if (bot_shouldattack(targ))
 408                                                 enemydamage = enemydamage + d;
 409                                         targ = targ.chain;
 410                                 }
 411                                 missile = find(missile, classname, "rocket");
 412                         }
 413                         local float desirabledamage;
 414                         desirabledamage = enemydamage;
 415                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 416                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 417                         if (teams_matter && self.team)
 418                                 desirabledamage = desirabledamage - teamdamage;
 419
 420                         missile = find(world, classname, "rocket");
 421                         while (missile)
 422                         {
 423                                 if (missile.owner != self)
 424                                 {
 425                                         missile = find(missile, classname, "rocket");
 426                                         continue;
 427                                 }
 428                                 makevectors(missile.v_angle);
 429                                 targ = targetlist;
 430                                 if (skill > 9) // normal players only do this for the target they are tracking
 431                                 {
 432                                         targ = targetlist;
 433                                         while (targ)
 434                                         {
 435                                                 if (
 436                                                         (v_forward * normalize(missile.origin - targ.origin)< 0.1)
 437                                                         && desirabledamage > 0.1*coredamage
 438                                                 )self.BUTTON_ATCK2 = TRUE;
 439                                                 targ = targ.chain;
 440                                         }
 441                                 }else{
 442                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 443                                         //As the distance gets larger, a correct detonation gets near imposible
 444                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 445                                         if(v_forward * normalize(missile.origin - self.enemy.origin)< 0.1)
 446                                                 if(self.enemy.classname == "player")
 447                                                         if(desirabledamage >= 0.1*coredamage)
 448                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 449                                                                         self.BUTTON_ATCK2 = TRUE;
 450                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 451                                 }
 452
 453                                 missile = find(missile, classname, "rocket");
 454                         }
 455                         // if we would be doing at X percent of the core damage, detonate it
 456                         // but don't fire a new shot at the same time!
 457                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 458                                 self.BUTTON_ATCK2 = TRUE;
 459                         if ((skill > 6.5) && (selfdamage > self.health))
 460                                 self.BUTTON_ATCK2 = FALSE;
 461                         //if(self.BUTTON_ATCK2 == TRUE)
 462                         //      dprint(ftos(desirabledamage),"\n");
 463                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 464                 }
 465         }
 466         else if (req == WR_THINK)
 467         {
 468                 if(autocvar_g_balance_rocketlauncher_reload_ammo && self.clip_load < autocvar_g_balance_rocketlauncher_ammo) // forced reload
 469                         W_RocketLauncher_Reload();
 470                 else
 471                 {
 472                         if (self.BUTTON_ATCK)
 473                         {
 474                                 if(self.rl_release || autocvar_g_balance_rocketlauncher_guidestop)
 475                                 if(weapon_prepareattack(0, autocvar_g_balance_rocketlauncher_refire))
 476                                 {
 477                                         W_Rocket_Attack();
 478                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_rocketlauncher_animtime, w_ready);
 479                                         self.rl_release = 0;
 480                                 }
 481                         }
 482                         else
 483                                 self.rl_release = 1;
 484
 485                         if (self.BUTTON_ATCK2)
 486                         {
 487                                 rockfound = 0;
 488                                 for(rock = world; (rock = find(rock, classname, "rocket")); ) if(rock.owner == self)
 489                                 {
 490                                         if(!rock.rl_detonate_later)
 491                                         {
 492                                                 rock.rl_detonate_later = TRUE;
 493                                                 rockfound = 1;
 494                                         }
 495                                 }
 496                                 if(rockfound)
 497                                         sound (self, CHAN_WEAPON2, "weapons/rocket_det.wav", VOL_BASE, ATTN_NORM);
 498                         }
 499                 }
 500         if(self.wish_reload)
 501         {
 502             if(self.switchweapon == self.weapon)
 503             {
 504                 if(self.weaponentity.state == WS_READY)
 505                 {
 506                     self.wish_reload = 0;
 507                     W_RocketLauncher_Reload();
 508                 }
 509             }
 510         }
 511         }
 512         else if (req == WR_PRECACHE)
 513         {
 514                 precache_model ("models/flash.md3");
 515                 precache_model ("models/weapons/g_rl.md3");
 516                 precache_model ("models/weapons/v_rl.md3");
 517                 precache_model ("models/weapons/h_rl.iqm");
 518                 precache_sound ("weapons/rocket_det.wav");
 519                 precache_sound ("weapons/rocket_fire.wav");
 520                 precache_sound ("weapons/rocket_mode.wav");
 521         }
 522         else if (req == WR_SETUP)
 523         {
 524                 weapon_setup(WEP_ROCKET_LAUNCHER);
 525                 W_RocketLauncher_SetAmmoCounter();
 526                 self.rl_release = 1;
 527         }
 528         else if (req == WR_CHECKAMMO1)
 529         {
 530                 if(autocvar_g_balance_rocketlauncher_reload_ammo)
 531                 {
 532                         // don't switch while guiding a missile
 533                         if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 534                                 && self.clip_load < autocvar_g_balance_rocketlauncher_ammo)
 535                                 return FALSE;
 536                 }
 537                 else
 538                 {
 539                         // don't switch while guiding a missile
 540                         if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_ROCKET_LAUNCHER)
 541                                 && self.ammo_rockets < autocvar_g_balance_rocketlauncher_ammo)
 542                                 return FALSE;
 543                 }
 544         }
 545         else if (req == WR_CHECKAMMO2)
 546                 return FALSE;
 547         else if (req == WR_RESETPLAYER)
 548         {
 549                 self.rl_release = 0;
 550         }
 551         else if (req == WR_RELOAD)
 552         {
 553                 W_RocketLauncher_Reload();
 554         }
 555         return TRUE;
 556 };
 557 #endif
 558 #ifdef CSQC
 559 float w_rlauncher(float req)
 560 {
 561         if(req == WR_IMPACTEFFECT)
 562         {
 563                 vector org2;
 564                 org2 = w_org + w_backoff * 12;
 565                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 566                 if(!w_issilent)
 567                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 568         }
 569         else if(req == WR_PRECACHE)
 570         {
 571                 precache_sound("weapons/rocket_impact.wav");
 572         }
 573         else if (req == WR_SUICIDEMESSAGE)
 574                 w_deathtypestring = "%s exploded";
 575         else if (req == WR_KILLMESSAGE)
 576         {
 577                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 578                         w_deathtypestring = "%s got too close to %s's rocket";
 579                 else if(w_deathtype & HITTYPE_SPLASH)
 580                         w_deathtypestring = "%s almost dodged %s's rocket";
 581                 else
 582                         w_deathtypestring = "%s ate %s's rocket";
 583         }
 584         return TRUE;
 585 }
 586 #endif
 587 #endif