qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", _("Nex"))
   3 #else
   4 #ifdef SVQC
   5
   6 void SendCSQCNexBeamParticle(float charge) {
   7         vector v;
   8         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
   9         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  10         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  11         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  12         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  13         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  14         WriteCoord(MSG_BROADCAST, v_x);
  15         WriteCoord(MSG_BROADCAST, v_y);
  16         WriteCoord(MSG_BROADCAST, v_z);
  17         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  18 }
  19
  20 void W_Nex_Attack (float issecondary)
  21 {
  22         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  23         if(issecondary)
  24         {
  25                 mydmg = autocvar_g_balance_nex_secondary_damage;
  26                 myforce = autocvar_g_balance_nex_secondary_force;
  27                 mymindist = autocvar_g_balance_nex_secondary_damagefalloff_mindist;
  28                 mymaxdist = autocvar_g_balance_nex_secondary_damagefalloff_maxdist;
  29                 myhalflife = autocvar_g_balance_nex_secondary_damagefalloff_halflife;
  30                 myforcehalflife = autocvar_g_balance_nex_secondary_damagefalloff_forcehalflife;
  31                 myammo = autocvar_g_balance_nex_secondary_ammo;
  32         }
  33         else
  34         {
  35                 mydmg = autocvar_g_balance_nex_primary_damage;
  36                 myforce = autocvar_g_balance_nex_primary_force;
  37                 mymindist = autocvar_g_balance_nex_primary_damagefalloff_mindist;
  38                 mymaxdist = autocvar_g_balance_nex_primary_damagefalloff_maxdist;
  39                 myhalflife = autocvar_g_balance_nex_primary_damagefalloff_halflife;
  40                 myforcehalflife = autocvar_g_balance_nex_primary_damagefalloff_forcehalflife;
  41                 myammo = autocvar_g_balance_nex_primary_ammo;
  42         }
  43
  44         float flying;
  45         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  46
  47         if(autocvar_g_balance_nex_charge)
  48         {
  49                 charge = autocvar_g_balance_nex_charge_mindmg / mydmg + (1 - autocvar_g_balance_nex_charge_mindmg / mydmg) * self.nex_charge;
  50                 self.nex_charge *= autocvar_g_balance_nex_charge_shot_multiplier; // do this AFTER setting mydmg/myforce
  51                 // O RLY? -- divVerent
  52                 // YA RLY -- FruitieX
  53         }
  54         else
  55                 charge = 1;
  56         mydmg *= charge;
  57         myforce *= charge;
  58
  59         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", CHAN_WEAPON, mydmg);
  60         if(charge > autocvar_g_balance_nex_charge_animlimit && autocvar_g_balance_nex_charge_animlimit) // if the Nex is overcharged, we play an extra sound
  61         {
  62                 sound (self, CHAN_WEAPON2, "weapons/nexcharge.wav", VOL_BASE * (charge - 0.5 * autocvar_g_balance_nex_charge_animlimit) / (1 - 0.5 * autocvar_g_balance_nex_charge_animlimit), ATTN_NORM);
  63         }
  64
  65         yoda = 0;
  66         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
  67
  68         if(yoda && flying)
  69                 AnnounceTo(self, "yoda");
  70
  71         //beam and muzzle flash done on client
  72         SendCSQCNexBeamParticle(charge);
  73
  74         // flash and burn the wall
  75         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  76                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
  77
  78         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  79         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  80         {
  81                 if(autocvar_g_balance_nex_reload_ammo)
  82                 {
  83                         self.clip_load -= myammo;
  84                         self.weapon_load[WEP_NEX] = self.clip_load;
  85                 }
  86                 else
  87                         self.ammo_cells -= myammo;
  88         }
  89 }
  90
  91 void spawnfunc_weapon_nex (void); // defined in t_items.qc
  92
  93 .float nex_chargepool_pauseregen_finished;
  94 float w_nex(float req)
  95 {
  96         float dt;
  97         float ammo_amount;
  98         if (req == WR_AIM)
  99         {
 100                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 101                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
 102         }
 103         else if (req == WR_THINK)
 104         {
 105                 if(autocvar_g_balance_nex_charge && self.nex_charge < autocvar_g_balance_nex_charge_limit)
 106                         self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_rate * frametime / W_TICSPERFRAME);
 107
 108                 if(autocvar_g_balance_nex_secondary_chargepool)
 109                         if(self.nex_chargepool_ammo < 1)
 110                         {
 111                                 if(self.nex_chargepool_pauseregen_finished < time)
 112                                         self.nex_chargepool_ammo = min(1, self.nex_chargepool_ammo + autocvar_g_balance_nex_secondary_chargepool_regen * frametime / W_TICSPERFRAME);
 113                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_nex_secondary_chargepool_pause_health_regen);
 114                         }
 115
 116                 if(autocvar_g_balance_nex_reload_ammo && self.clip_load < min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo)) // forced reload
 117                         weapon_action(self.weapon, WR_RELOAD);
 118                 else
 119                 {
 120                         if (self.BUTTON_ATCK)
 121                         {
 122                                 if (weapon_prepareattack(0, autocvar_g_balance_nex_primary_refire))
 123                                 {
 124                                         W_Nex_Attack(0);
 125                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_primary_animtime, w_ready);
 126                                 }
 127                         }
 128                         if ((autocvar_g_balance_nex_secondary_charge && !autocvar_g_balance_nex_secondary) ? self.BUTTON_ZOOM : self.BUTTON_ATCK2)
 129                         {
 130                                 if(autocvar_g_balance_nex_secondary_charge)
 131                                 {
 132                                         self.nex_charge_rottime = time + autocvar_g_balance_nex_charge_rot_pause;
 133                                         dt = frametime / W_TICSPERFRAME;
 134
 135                                         if(self.nex_charge < 1)
 136                                         {
 137                                                 if(autocvar_g_balance_nex_secondary_chargepool)
 138                                                 {
 139                                                         if(autocvar_g_balance_nex_secondary_ammo)
 140                                                         {
 141                                                                 // always deplete if secondary is held
 142                                                                 self.nex_chargepool_ammo = max(0, self.nex_chargepool_ammo - autocvar_g_balance_nex_secondary_ammo * dt);
 143
 144                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 145                                                                 self.nex_chargepool_pauseregen_finished = time + autocvar_g_balance_nex_secondary_chargepool_pause_regen;
 146                                                                 dt = min(dt, self.nex_chargepool_ammo);
 147                                                                 dt = max(0, dt);
 148
 149                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 150                                                         }
 151                                                 }
 152
 153                                                 else if(autocvar_g_balance_nex_secondary_ammo)
 154                                                 {
 155                                                         if(self.BUTTON_ATCK2) // only eat ammo when the button is pressed
 156                                                         {
 157                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 158                                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 159                                                                 {
 160                                                                         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 161                                                                         if(autocvar_g_balance_nex_reload_ammo)
 162                                                                         {
 163                                                                                 dt = min(dt, (self.clip_load - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 164                                                                                 dt = max(0, dt);
 165                                                                                 if(dt > 0)
 166                                                                                 {
 167                                                                                         self.clip_load = max(autocvar_g_balance_nex_secondary_ammo, self.clip_load - autocvar_g_balance_nex_secondary_ammo * dt);
 168                                                                                 }
 169                                                                                 self.weapon_load[WEP_NEX] = self.clip_load;
 170                                                                         }
 171                                                                         else
 172                                                                         {
 173                                                                                 dt = min(dt, (self.ammo_cells - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 174                                                                                 dt = max(0, dt);
 175                                                                                 if(dt > 0)
 176                                                                                 {
 177                                                                                         self.ammo_cells = max(autocvar_g_balance_nex_secondary_ammo, self.ammo_cells - autocvar_g_balance_nex_secondary_ammo * dt);
 178                                                                                 }
 179                                                                         }
 180                                                                 }
 181                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 182                                                         }
 183                                                 }
 184
 185                                                 else
 186                                                 {
 187                                                         dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 188                                                         self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 189                                                 }
 190                                         }
 191                                 }
 192                                 else if(autocvar_g_balance_nex_secondary)
 193                                 {
 194                                         if (weapon_prepareattack(0, autocvar_g_balance_nex_secondary_refire))
 195                                         {
 196                                                 W_Nex_Attack(1);
 197                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_secondary_animtime, w_ready);
 198                                         }
 199                                 }
 200                         }
 201                 }
 202
 203                 if(autocvar_g_balance_nex_charge)
 204                 {
 205                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
 206                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
 207                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
 208
 209                         if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
 210                         {
 211                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
 212                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
 213                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
 214                         }
 215                 }
 216         }
 217         else if (req == WR_PRECACHE)
 218         {
 219                 precache_model ("models/nexflash.md3");
 220                 precache_model ("models/weapons/g_nex.md3");
 221                 precache_model ("models/weapons/v_nex.md3");
 222                 precache_model ("models/weapons/h_nex.iqm");
 223                 precache_sound ("weapons/nexfire.wav");
 224                 precache_sound ("weapons/nexcharge.wav");
 225                 precache_sound ("weapons/nexwhoosh1.wav");
 226                 precache_sound ("weapons/nexwhoosh2.wav");
 227                 precache_sound ("weapons/nexwhoosh3.wav");
 228                 precache_sound ("weapons/reload.wav");
 229         }
 230         else if (req == WR_SETUP)
 231         {
 232                 weapon_setup(WEP_NEX);
 233         }
 234         else if (req == WR_CHECKAMMO1)
 235         {
 236                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_primary_ammo;
 237                 ammo_amount += (autocvar_g_balance_nex_reload_ammo && self.weapon_load[WEP_NEX] >= autocvar_g_balance_nex_primary_ammo);
 238                 return ammo_amount;
 239         }
 240         else if (req == WR_CHECKAMMO2)
 241         {
 242                 // don't allow charging if we don't have enough ammo
 243                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_secondary_ammo;
 244                 ammo_amount += self.weapon_load[WEP_NEX] >= autocvar_g_balance_nex_secondary_ammo;
 245                 return ammo_amount;
 246         }
 247         else if (req == WR_RELOAD)
 248         {
 249                 W_Reload(ammo_cells, min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo), autocvar_g_balance_nex_reload_ammo, autocvar_g_balance_nex_reload_time, "weapons/reload.wav");
 250         }
 251
 252         return TRUE;
 253 };
 254 #endif
 255 #ifdef CSQC
 256 float w_nex(float req)
 257 {
 258         if(req == WR_IMPACTEFFECT)
 259         {
 260                 vector org2;
 261                 org2 = w_org + w_backoff * 6;
 262                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 263                 if(!w_issilent)
 264                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 265         }
 266         else if(req == WR_PRECACHE)
 267         {
 268                 precache_sound("weapons/neximpact.wav");
 269         }
 270         else if (req == WR_SUICIDEMESSAGE)
 271                 w_deathtypestring = _("%s did the impossible");
 272         else if (req == WR_KILLMESSAGE)
 273                 w_deathtypestring = _("%s has been vaporized by %s");
 274         return TRUE;
 275 }
 276 #endif
 277 #endif