qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick (entity to)
  15 {
  16         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         newmine.realowner = self.realowner;
  29         setsize(newmine, '-4 -4 -4', '4 4 4');
  30         setorigin(newmine, self.origin);
  31         setmodel(newmine, "models/mine.md3");
  32         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  33
  34         newmine.oldvelocity = self.velocity;
  35
  36         newmine.takedamage = self.takedamage;
  37         newmine.damageforcescale = self.damageforcescale;
  38         newmine.health = self.health;
  39         newmine.event_damage = self.event_damage;
  40         newmine.spawnshieldtime = self.spawnshieldtime;
  41         newmine.damagedbycontents = TRUE;
  42
  43         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  44         newmine.projectiledeathtype = self.projectiledeathtype;
  45
  46         newmine.mine_time = self.mine_time;
  47
  48         newmine.touch = SUB_Null;
  49         newmine.think = W_Mine_Think;
  50         newmine.nextthink = time;
  51         newmine.cnt = self.cnt;
  52         newmine.flags = self.flags;
  53
  54         remove(self);
  55         self = newmine;
  56
  57         if(to)
  58                 SetMovetypeFollow(self, to);
  59 }
  60
  61 void W_Mine_Explode ()
  62 {
  63         if(other.takedamage == DAMAGE_AIM)
  64                 if(other.classname == "player")
  65                         if(IsDifferentTeam(self.realowner, other))
  66                                 if(other.deadflag == DEAD_NO)
  67                                         if(IsFlying(other))
  68                                                 AnnounceTo(self.realowner, "airshot");
  69
  70         self.event_damage = SUB_Null;
  71         self.takedamage = DAMAGE_NO;
  72
  73         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  74
  75         if (self.realowner.weapon == WEP_MINE_LAYER)
  76         {
  77                 entity oldself;
  78                 oldself = self;
  79                 self = self.realowner;
  80                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  81                 {
  82                         self.cnt = WEP_MINE_LAYER;
  83                         ATTACK_FINISHED(self) = time;
  84                         self.switchweapon = w_getbestweapon(self);
  85                 }
  86                 self = oldself;
  87         }
  88         self.realowner.minelayer_mines -= 1;
  89         remove (self);
  90 }
  91
  92 void W_Mine_DoRemoteExplode ()
  93 {
  94         self.event_damage = SUB_Null;
  95         self.takedamage = DAMAGE_NO;
  96
  97         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
  98                 self.velocity = self.oldvelocity;
  99
 100         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 101
 102         if (self.realowner.weapon == WEP_MINE_LAYER)
 103         {
 104                 entity oldself;
 105                 oldself = self;
 106                 self = self.realowner;
 107                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
 108                 {
 109                         self.cnt = WEP_MINE_LAYER;
 110                         ATTACK_FINISHED(self) = time;
 111                         self.switchweapon = w_getbestweapon(self);
 112                 }
 113                 self = oldself;
 114         }
 115         self.realowner.minelayer_mines -= 1;
 116         remove (self);
 117 }
 118
 119 void W_Mine_RemoteExplode ()
 120 {
 121         if(self.realowner.deadflag == DEAD_NO)
 122                 if((self.spawnshieldtime >= 0)
 123                         ? (time >= self.spawnshieldtime) // timer
 124                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 125                 )
 126                 {
 127                         W_Mine_DoRemoteExplode();
 128                 }
 129 }
 130
 131 void W_Mine_ProximityExplode ()
 132 {
 133         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 134         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 135         {
 136                 entity head;
 137                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 138                 while(head)
 139                 {
 140                         if(head == self.realowner || !IsDifferentTeam(head, self.realowner))
 141                                 return;
 142                         head = head.chain;
 143                 }
 144         }
 145
 146         self.mine_time = 0;
 147         W_Mine_Explode();
 148 }
 149
 150 float W_Mine_Count(entity e)
 151 {
 152         float minecount;
 153         entity mine;
 154         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 155                 minecount += 1;
 156
 157         return minecount;
 158 }
 159
 160 void W_Mine_Think (void)
 161 {
 162         entity head;
 163
 164         self.nextthink = time;
 165
 166         if(self.movetype == MOVETYPE_FOLLOW)
 167         {
 168                 if(LostMovetypeFollow(self))
 169                 {
 170                         UnsetMovetypeFollow(self);
 171                         self.movetype = MOVETYPE_NONE;
 172                 }
 173         }
 174
 175         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 176         // TODO: replace this mine_trigger.wav sound with a real countdown
 177         if ((time > self.cnt) && (!self.mine_time))
 178         {
 179                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 180                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 181                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 182                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 183         }
 184
 185         // a player's mines shall explode if he disconnects or dies
 186         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 187         if(self.realowner.classname != "player" || self.realowner.deadflag != DEAD_NO)
 188         {
 189                 other = world;
 190                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 191                 W_Mine_Explode();
 192                 return;
 193         }
 194
 195         // set the mine for detonation when a foe gets close enough
 196         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 197         while(head)
 198         {
 199                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 200                 if(head != self.realowner && IsDifferentTeam(head, self.realowner)) // don't trigger for team mates
 201                 if(!self.mine_time)
 202                 {
 203                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 204                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 205                 }
 206                 head = head.chain;
 207         }
 208
 209         // explode if it's time to
 210         if(self.mine_time && time >= self.mine_time)
 211         {
 212                 W_Mine_ProximityExplode();
 213                 return;
 214         }
 215
 216         // remote detonation
 217         if (self.realowner.weapon == WEP_MINE_LAYER)
 218         if (self.realowner.deadflag == DEAD_NO)
 219         if (self.minelayer_detonate)
 220                 W_Mine_RemoteExplode();
 221 }
 222
 223 void W_Mine_Touch (void)
 224 {
 225         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 226                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 227
 228         PROJECTILE_TOUCH;
 229
 230         if(other && other.classname == "player" && other.deadflag == DEAD_NO)
 231         {
 232                 // hit a player
 233                 // don't stick
 234         }
 235         else
 236         {
 237                 W_Mine_Stick(other);
 238         }
 239 }
 240
 241 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 242 {
 243         if (self.health <= 0)
 244                 return;
 245         self.health = self.health - damage;
 246         self.angles = vectoangles(self.velocity);
 247         if (self.health <= 0)
 248                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 249 }
 250
 251 void W_Mine_Attack (void)
 252 {
 253         entity mine;
 254         entity flash;
 255
 256         // scan how many mines we placed, and return if we reached our limit
 257         if(autocvar_g_balance_minelayer_limit)
 258         {
 259
 260                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 261                 {
 262                         // the refire delay keeps this message from being spammed
 263                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 264                         play2(self, "weapons/unavailable.wav");
 265                         return;
 266                 }
 267         }
 268
 269         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 270
 271         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, autocvar_g_balance_minelayer_damage);
 272         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 273
 274         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 275         mine.owner = mine.realowner = self;
 276         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 277                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 278         else
 279                 mine.spawnshieldtime = -1;
 280         mine.classname = "mine";
 281         mine.bot_dodge = TRUE;
 282         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 283
 284         mine.takedamage = DAMAGE_YES;
 285         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 286         mine.health = autocvar_g_balance_minelayer_health;
 287         mine.event_damage = W_Mine_Damage;
 288
 289         mine.movetype = MOVETYPE_TOSS;
 290         PROJECTILE_MAKETRIGGER(mine);
 291         mine.projectiledeathtype = WEP_MINE_LAYER;
 292         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 293
 294         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 295         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 296         mine.angles = vectoangles (mine.velocity);
 297
 298         mine.touch = W_Mine_Touch;
 299         mine.think = W_Mine_Think;
 300         mine.nextthink = time;
 301         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 302         mine.flags = FL_PROJECTILE;
 303
 304         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 305
 306         // muzzle flash for 1st person view
 307         flash = spawn ();
 308         setmodel (flash, "models/flash.md3"); // precision set below
 309         SUB_SetFade (flash, time, 0.1);
 310         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 311         W_AttachToShotorg(flash, '5 0 0');
 312
 313         // common properties
 314
 315         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 316
 317         self.minelayer_mines = W_Mine_Count(self);
 318 }
 319
 320 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 321
 322 float W_PlacedMines(float detonate)
 323 {
 324         entity mine;
 325         float minfound;
 326
 327         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 328         {
 329                 if(detonate)
 330                 {
 331                         if(!mine.minelayer_detonate)
 332                         {
 333                                 mine.minelayer_detonate = TRUE;
 334                                 minfound = 1;
 335                         }
 336                 }
 337                 else
 338                         minfound = 1;
 339         }
 340         return minfound;
 341 }
 342
 343 float w_minelayer(float req)
 344 {
 345         entity mine;
 346         float ammo_amount;
 347
 348         if (req == WR_AIM)
 349         {
 350                 // aim and decide to fire if appropriate
 351                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 352                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 353                 {
 354                         // decide whether to detonate mines
 355                         entity targetlist, targ;
 356                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 357                         float selfdamage, teamdamage, enemydamage;
 358                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 359                         coredamage = autocvar_g_balance_minelayer_damage;
 360                         edgeradius = autocvar_g_balance_minelayer_radius;
 361                         recipricoledgeradius = 1 / edgeradius;
 362                         selfdamage = 0;
 363                         teamdamage = 0;
 364                         enemydamage = 0;
 365                         targetlist = findchainfloat(bot_attack, TRUE);
 366                         mine = find(world, classname, "mine");
 367                         while (mine)
 368                         {
 369                                 if (mine.realowner != self)
 370                                 {
 371                                         mine = find(mine, classname, "mine");
 372                                         continue;
 373                                 }
 374                                 targ = targetlist;
 375                                 while (targ)
 376                                 {
 377                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 378                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 379                                         // count potential damage according to type of target
 380                                         if (targ == self)
 381                                                 selfdamage = selfdamage + d;
 382                                         else if (targ.team == self.team && teamplay)
 383                                                 teamdamage = teamdamage + d;
 384                                         else if (bot_shouldattack(targ))
 385                                                 enemydamage = enemydamage + d;
 386                                         targ = targ.chain;
 387                                 }
 388                                 mine = find(mine, classname, "mine");
 389                         }
 390                         float desirabledamage;
 391                         desirabledamage = enemydamage;
 392                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 393                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 394                         if (teamplay && self.team)
 395                                 desirabledamage = desirabledamage - teamdamage;
 396
 397                         mine = find(world, classname, "mine");
 398                         while (mine)
 399                         {
 400                                 if (mine.realowner != self)
 401                                 {
 402                                         mine = find(mine, classname, "mine");
 403                                         continue;
 404                                 }
 405                                 makevectors(mine.v_angle);
 406                                 targ = targetlist;
 407                                 if (skill > 9) // normal players only do this for the target they are tracking
 408                                 {
 409                                         targ = targetlist;
 410                                         while (targ)
 411                                         {
 412                                                 if (
 413                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 414                                                         && desirabledamage > 0.1*coredamage
 415                                                 )self.BUTTON_ATCK2 = TRUE;
 416                                                 targ = targ.chain;
 417                                         }
 418                                 }else{
 419                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 420                                         //As the distance gets larger, a correct detonation gets near imposible
 421                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 422                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 423                                                 if(self.enemy.classname == "player")
 424                                                         if(desirabledamage >= 0.1*coredamage)
 425                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 426                                                                         self.BUTTON_ATCK2 = TRUE;
 427                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 428                                 }
 429
 430                                 mine = find(mine, classname, "mine");
 431                         }
 432                         // if we would be doing at X percent of the core damage, detonate it
 433                         // but don't fire a new shot at the same time!
 434                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 435                                 self.BUTTON_ATCK2 = TRUE;
 436                         if ((skill > 6.5) && (selfdamage > self.health))
 437                                 self.BUTTON_ATCK2 = FALSE;
 438                         //if(self.BUTTON_ATCK2 == TRUE)
 439                         //      dprint(ftos(desirabledamage),"\n");
 440                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 441                 }
 442         }
 443         else if (req == WR_THINK)
 444         {
 445                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 446                 {
 447                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 448                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 449                                 weapon_action(self.weapon, WR_RELOAD);
 450                 }
 451                 else if (self.BUTTON_ATCK)
 452                 {
 453                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 454                         {
 455                                 W_Mine_Attack();
 456                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 457                         }
 458                 }
 459
 460                 if (self.BUTTON_ATCK2)
 461                 {
 462                         if(W_PlacedMines(TRUE))
 463                                 sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 464                 }
 465         }
 466         else if (req == WR_PRECACHE)
 467         {
 468                 precache_model ("models/flash.md3");
 469                 precache_model ("models/mine.md3");
 470                 precache_model ("models/weapons/g_minelayer.md3");
 471                 precache_model ("models/weapons/v_minelayer.md3");
 472                 precache_model ("models/weapons/h_minelayer.iqm");
 473                 precache_sound ("weapons/mine_det.wav");
 474                 precache_sound ("weapons/mine_fire.wav");
 475                 precache_sound ("weapons/mine_stick.wav");
 476                 precache_sound ("weapons/mine_trigger.wav");
 477                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 478         }
 479         else if (req == WR_SETUP)
 480         {
 481                 weapon_setup(WEP_MINE_LAYER);
 482                 self.current_ammo = ammo_rockets;
 483         }
 484         else if (req == WR_CHECKAMMO1)
 485         {
 486                 // don't switch while placing a mine
 487                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 488                 {
 489                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 490                         ammo_amount += self.weapon_load[WEP_MINE_LAYER] >= autocvar_g_balance_minelayer_ammo;
 491                         return ammo_amount;
 492                 }
 493         }
 494         else if (req == WR_CHECKAMMO2)
 495         {
 496                 if (W_PlacedMines(FALSE))
 497                         return TRUE;
 498                 else
 499                         return FALSE;
 500         }
 501         else if (req == WR_RELOAD)
 502         {
 503                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 504         }
 505         return TRUE;
 506 };
 507 #endif
 508 #ifdef CSQC
 509 float w_minelayer(float req)
 510 {
 511         if(req == WR_IMPACTEFFECT)
 512         {
 513                 vector org2;
 514                 org2 = w_org + w_backoff * 12;
 515                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 516                 if(!w_issilent)
 517                         sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 518         }
 519         else if(req == WR_PRECACHE)
 520         {
 521                 precache_sound("weapons/mine_exp.wav");
 522         }
 523         else if (req == WR_SUICIDEMESSAGE)
 524                 w_deathtypestring = _("%s exploded");
 525         else if (req == WR_KILLMESSAGE)
 526         {
 527                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 528                         w_deathtypestring = _("%s got too close to %s's mine");
 529                 else if(w_deathtype & HITTYPE_SPLASH)
 530                         w_deathtypestring = _("%s almost dodged %s's mine");
 531                 else
 532                         w_deathtypestring = _("%s stepped on %s's mine");
 533         }
 534         return TRUE;
 535 }
 536 #endif
 537 #endif