qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 void W_MineLayer_Reload()
  10 {
  11         self.reload_ammo_player = ammo_rockets;
  12         self.reload_ammo_min = autocvar_g_balance_minelayer_ammo;
  13         self.reload_ammo_amount = autocvar_g_balance_minelayer_reload_ammo;
  14         self.reload_time = autocvar_g_balance_minelayer_reload_time;
  15         self.reload_sound = "weapons/reload.wav";
  16
  17         W_Reload();
  18 }
  19
  20 void spawnfunc_weapon_minelayer (void)
  21 {
  22         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  23 }
  24
  25 void W_Mine_Stick ()
  26 {
  27         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  28
  29         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  30
  31         entity newmine;
  32         newmine = spawn();
  33         newmine.classname = self.classname;
  34
  35         newmine.bot_dodge = self.bot_dodge;
  36         newmine.bot_dodgerating = self.bot_dodgerating;
  37
  38         newmine.owner = self.owner;
  39         setsize(newmine, '-4 -4 -4', '4 4 4');
  40         setorigin(newmine, self.origin);
  41         setmodel(newmine, "models/mine.md3");
  42         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  43
  44         newmine.takedamage = self.takedamage;
  45         newmine.damageforcescale = self.damageforcescale;
  46         newmine.health = self.health;
  47         newmine.event_damage = self.event_damage;
  48         newmine.spawnshieldtime = self.spawnshieldtime;
  49
  50         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  51         newmine.projectiledeathtype = self.projectiledeathtype;
  52
  53         newmine.mine_time = self.mine_time;
  54
  55         newmine.touch = SUB_Null;
  56         newmine.think = W_Mine_Think;
  57         newmine.nextthink = time;
  58         newmine.cnt = self.cnt;
  59         newmine.flags = self.flags;
  60
  61         remove(self);
  62         self = newmine;
  63 }
  64
  65 void W_Mine_Explode ()
  66 {
  67         if(other.takedamage == DAMAGE_AIM)
  68                 if(other.classname == "player")
  69                         if(IsDifferentTeam(self.owner, other))
  70                                 if(IsFlying(other))
  71                                         AnnounceTo(self.owner, "airshot");
  72
  73         self.event_damage = SUB_Null;
  74         self.takedamage = DAMAGE_NO;
  75
  76         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  77
  78         if (self.owner.weapon == WEP_MINE_LAYER)
  79         {
  80                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  81                 {
  82                         self.owner.cnt = WEP_MINE_LAYER;
  83                         ATTACK_FINISHED(self.owner) = time;
  84                         self.owner.switchweapon = w_getbestweapon(self.owner);
  85                 }
  86         }
  87         remove (self);
  88 }
  89
  90 void W_Mine_DoRemoteExplode ()
  91 {
  92         self.event_damage = SUB_Null;
  93         self.takedamage = DAMAGE_NO;
  94
  95         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  96
  97         if (self.owner.weapon == WEP_MINE_LAYER)
  98         {
  99                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 100                 {
 101                         self.owner.cnt = WEP_MINE_LAYER;
 102                         ATTACK_FINISHED(self.owner) = time;
 103                         self.owner.switchweapon = w_getbestweapon(self.owner);
 104                 }
 105         }
 106         remove (self);
 107 }
 108
 109 void W_Mine_RemoteExplode ()
 110 {
 111         if(self.owner.deadflag == DEAD_NO)
 112                 if((self.spawnshieldtime >= 0)
 113                         ? (time >= self.spawnshieldtime) // timer
 114                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 115                 )
 116                 {
 117                         W_Mine_DoRemoteExplode();
 118                 }
 119 }
 120
 121 void W_Mine_ProximityExplode ()
 122 {
 123         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 124         if(autocvar_g_balance_minelayer_protection && self.minelayer_mines == 0)
 125         {
 126                 entity head;
 127                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 128                 while(head)
 129                 {
 130                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 131                                 return;
 132                         head = head.chain;
 133                 }
 134         }
 135
 136         self.mine_time = 0;
 137         W_Mine_Explode();
 138 }
 139
 140 void W_Mine_Think (void)
 141 {
 142         entity head;
 143
 144         self.nextthink = time;
 145
 146         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 147         // TODO: replace this mine_trigger.wav sound with a real countdown
 148         if ((time > self.cnt) && (!self.mine_time))
 149         {
 150                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 151                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 152                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 153                 self.minelayer_mines = 1; // make the mine super aggressive
 154         }
 155
 156         // a player's mines shall explode if he disconnects or dies
 157         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 158         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 159         {
 160                 other = world;
 161                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 162                 W_Mine_Explode();
 163                 return;
 164         }
 165
 166         // set the mine for detonation when a foe gets close enough
 167         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 168         while(head)
 169         {
 170                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 171                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 172                 if(!self.mine_time)
 173                 {
 174                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 175                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 176                 }
 177                 head = head.chain;
 178         }
 179
 180         // explode if it's time to
 181         if(self.mine_time && time >= self.mine_time)
 182         {
 183                 W_Mine_ProximityExplode();
 184                 return;
 185         }
 186
 187         // remote detonation
 188         if (self.owner.weapon == WEP_MINE_LAYER)
 189         if (self.owner.deadflag == DEAD_NO)
 190         if (self.minelayer_detonate)
 191                 W_Mine_RemoteExplode();
 192 }
 193
 194 void W_Mine_Touch (void)
 195 {
 196         PROJECTILE_TOUCH;
 197         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 198                 W_Mine_Stick();
 199         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 200                 self.velocity = '0 0 0';
 201 }
 202
 203 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 204 {
 205         if (self.health <= 0)
 206                 return;
 207         self.health = self.health - damage;
 208         self.angles = vectoangles(self.velocity);
 209         if (self.health <= 0)
 210                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 211 }
 212
 213 void W_Mine_Attack (void)
 214 {
 215         entity mine;
 216         entity flash;
 217
 218         // scan how many mines we placed, and return if we reached our limit
 219         if(autocvar_g_balance_minelayer_limit)
 220         {
 221                 self.minelayer_mines = 0;
 222                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 223                         self.minelayer_mines += 1;
 224
 225                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 226                 {
 227                         // the refire delay keeps this message from being spammed
 228                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 229                         play2(self, "weapons/unavailable.wav");
 230                         return;
 231                 }
 232         }
 233
 234         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 235         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 236         {
 237                 if(autocvar_g_balance_minelayer_reload_ammo)
 238                 {
 239                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 240                         self.weapon_load[WEP_MINE_LAYER] = self.clip_load;
 241                 }
 242                 else
 243                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 244         }
 245
 246         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 247         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 248
 249         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 250         mine.owner = self;
 251         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 252                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 253         else
 254                 mine.spawnshieldtime = -1;
 255         mine.classname = "mine";
 256         mine.bot_dodge = TRUE;
 257         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 258
 259         mine.takedamage = DAMAGE_YES;
 260         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 261         mine.health = autocvar_g_balance_minelayer_health;
 262         mine.event_damage = W_Mine_Damage;
 263
 264         mine.movetype = MOVETYPE_TOSS;
 265         PROJECTILE_MAKETRIGGER(mine);
 266         mine.projectiledeathtype = WEP_MINE_LAYER;
 267         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 268
 269         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 270         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 271         mine.angles = vectoangles (mine.velocity);
 272
 273         mine.touch = W_Mine_Touch;
 274         mine.think = W_Mine_Think;
 275         mine.nextthink = time;
 276         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 277         mine.flags = FL_PROJECTILE;
 278
 279         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 280
 281         // muzzle flash for 1st person view
 282         flash = spawn ();
 283         setmodel (flash, "models/flash.md3"); // precision set below
 284         SUB_SetFade (flash, time, 0.1);
 285         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 286         W_AttachToShotorg(flash, '5 0 0');
 287
 288         // common properties
 289
 290         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 291 }
 292
 293 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 294
 295 float w_minelayer(float req)
 296 {
 297         entity mine;
 298         float minfound;
 299         float ammo_amount;
 300
 301         if (req == WR_AIM)
 302         {
 303                 // aim and decide to fire if appropriate
 304                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 305                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 306                 {
 307                         // decide whether to detonate mines
 308                         entity targetlist, targ;
 309                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 310                         float selfdamage, teamdamage, enemydamage;
 311                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 312                         coredamage = autocvar_g_balance_minelayer_damage;
 313                         edgeradius = autocvar_g_balance_minelayer_radius;
 314                         recipricoledgeradius = 1 / edgeradius;
 315                         selfdamage = 0;
 316                         teamdamage = 0;
 317                         enemydamage = 0;
 318                         targetlist = findchainfloat(bot_attack, TRUE);
 319                         mine = find(world, classname, "mine");
 320                         while (mine)
 321                         {
 322                                 if (mine.owner != self)
 323                                 {
 324                                         mine = find(mine, classname, "mine");
 325                                         continue;
 326                                 }
 327                                 targ = targetlist;
 328                                 while (targ)
 329                                 {
 330                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 331                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 332                                         // count potential damage according to type of target
 333                                         if (targ == self)
 334                                                 selfdamage = selfdamage + d;
 335                                         else if (targ.team == self.team && teams_matter)
 336                                                 teamdamage = teamdamage + d;
 337                                         else if (bot_shouldattack(targ))
 338                                                 enemydamage = enemydamage + d;
 339                                         targ = targ.chain;
 340                                 }
 341                                 mine = find(mine, classname, "mine");
 342                         }
 343                         float desirabledamage;
 344                         desirabledamage = enemydamage;
 345                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 346                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 347                         if (teams_matter && self.team)
 348                                 desirabledamage = desirabledamage - teamdamage;
 349
 350                         mine = find(world, classname, "mine");
 351                         while (mine)
 352                         {
 353                                 if (mine.owner != self)
 354                                 {
 355                                         mine = find(mine, classname, "mine");
 356                                         continue;
 357                                 }
 358                                 makevectors(mine.v_angle);
 359                                 targ = targetlist;
 360                                 if (skill > 9) // normal players only do this for the target they are tracking
 361                                 {
 362                                         targ = targetlist;
 363                                         while (targ)
 364                                         {
 365                                                 if (
 366                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 367                                                         && desirabledamage > 0.1*coredamage
 368                                                 )self.BUTTON_ATCK2 = TRUE;
 369                                                 targ = targ.chain;
 370                                         }
 371                                 }else{
 372                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 373                                         //As the distance gets larger, a correct detonation gets near imposible
 374                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 375                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 376                                                 if(self.enemy.classname == "player")
 377                                                         if(desirabledamage >= 0.1*coredamage)
 378                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 379                                                                         self.BUTTON_ATCK2 = TRUE;
 380                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 381                                 }
 382
 383                                 mine = find(mine, classname, "mine");
 384                         }
 385                         // if we would be doing at X percent of the core damage, detonate it
 386                         // but don't fire a new shot at the same time!
 387                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 388                                 self.BUTTON_ATCK2 = TRUE;
 389                         if ((skill > 6.5) && (selfdamage > self.health))
 390                                 self.BUTTON_ATCK2 = FALSE;
 391                         //if(self.BUTTON_ATCK2 == TRUE)
 392                         //      dprint(ftos(desirabledamage),"\n");
 393                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 394                 }
 395         }
 396         else if (req == WR_THINK)
 397         {
 398                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 399                         W_MineLayer_Reload();
 400                 else if (self.BUTTON_ATCK)
 401                 {
 402                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 403                         {
 404                                 W_Mine_Attack();
 405                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 406                         }
 407                 }
 408
 409                 else if (self.BUTTON_ATCK2)
 410                 {
 411                         minfound = 0;
 412                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 413                         {
 414                                 if(!mine.minelayer_detonate)
 415                                 {
 416                                         mine.minelayer_detonate = TRUE;
 417                                         minfound = 1;
 418                                 }
 419                         }
 420                         if(minfound)
 421                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 422                 }
 423         }
 424         else if (req == WR_PRECACHE)
 425         {
 426                 precache_model ("models/flash.md3");
 427                 precache_model ("models/mine.md3");
 428                 precache_model ("models/weapons/g_minelayer.md3");
 429                 precache_model ("models/weapons/v_minelayer.md3");
 430                 precache_model ("models/weapons/h_minelayer.iqm");
 431                 precache_sound ("weapons/mine_det.wav");
 432                 precache_sound ("weapons/mine_fire.wav");
 433                 precache_sound ("weapons/mine_stick.wav");
 434                 precache_sound ("weapons/mine_trigger.wav");
 435                 precache_sound ("weapons/reload.wav");
 436         }
 437         else if (req == WR_SETUP)
 438         {
 439                 weapon_setup(WEP_MINE_LAYER);
 440         }
 441         else if (req == WR_CHECKAMMO1)
 442         {
 443                 // don't switch while placing a mine
 444                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 445                 {
 446                         if(autocvar_g_balance_minelayer_reload_ammo)
 447                         {
 448                                 if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo && self.weapon_load[WEP_MINE_LAYER] < autocvar_g_balance_minelayer_ammo)
 449                                         ammo_amount = TRUE;
 450                         }
 451                         else if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 452                                 ammo_amount = TRUE;
 453                         return !ammo_amount;
 454                 }
 455         }
 456         else if (req == WR_CHECKAMMO2)
 457         {
 458                 return FALSE;
 459         }
 460         else if (req == WR_RELOAD)
 461         {
 462                 W_MineLayer_Reload();
 463         }
 464         return TRUE;
 465 };
 466 #endif
 467 #ifdef CSQC
 468 float w_minelayer(float req)
 469 {
 470         if(req == WR_IMPACTEFFECT)
 471         {
 472                 vector org2;
 473                 org2 = w_org + w_backoff * 12;
 474                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 475                 if(!w_issilent)
 476                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 477         }
 478         else if(req == WR_PRECACHE)
 479         {
 480                 precache_sound("weapons/mine_exp.wav");
 481         }
 482         else if (req == WR_SUICIDEMESSAGE)
 483                 w_deathtypestring = _("%s exploded");
 484         else if (req == WR_KILLMESSAGE)
 485         {
 486                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 487                         w_deathtypestring = _("%s got too close to %s's mine");
 488                 else if(w_deathtype & HITTYPE_SPLASH)
 489                         w_deathtypestring = _("%s almost dodged %s's mine");
 490                 else
 491                         w_deathtypestring = _("%s stepped on %s's mine");
 492         }
 493         return TRUE;
 494 }
 495 #endif
 496 #endif