qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
  24 {
  25         if (self.health <= 0)
  26                 return;
  27         self.health = self.health - damage;
  28         self.angles = vectoangles(self.velocity);
  29         if (self.health <= 0)
  30                 W_PrepareExplosionByDamage(attacker, self.think);
  31 }
  32
  33 void W_Hagar_Touch (void)
  34 {
  35         PROJECTILE_TOUCH;
  36         self.use ();
  37 }
  38
  39 void W_Hagar_Touch2 (void)
  40 {
  41         PROJECTILE_TOUCH;
  42
  43         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  44                 self.use();
  45         } else {
  46                 self.cnt++;
  47                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  48                 self.angles = vectoangles (self.velocity);
  49                 self.owner = world;
  50                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  51         }
  52 }
  53
  54 void W_Hagar_Attack (void)
  55 {
  56         local entity missile;
  57
  58         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  59
  60         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_primary_damage);
  61
  62         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  63
  64         missile = spawn ();
  65         missile.owner = missile.realowner = self;
  66         missile.classname = "missile";
  67         missile.bot_dodge = TRUE;
  68         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  69
  70         missile.takedamage = DAMAGE_YES;
  71         missile.health = autocvar_g_balance_hagar_primary_health;
  72         missile.damageforcescale = autocvar_g_balance_hagar_primary_damageforcescale;
  73         missile.event_damage = W_Hagar_Damage;
  74         missile.damagedbycontents = TRUE;
  75
  76         missile.touch = W_Hagar_Touch;
  77         missile.use = W_Hagar_Explode;
  78         missile.think = adaptor_think2use_hittype_splash;
  79         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  80         PROJECTILE_MAKETRIGGER(missile);
  81         missile.projectiledeathtype = WEP_HAGAR;
  82         setorigin (missile, w_shotorg);
  83         setsize(missile, '0 0 0', '0 0 0');
  84
  85         missile.movetype = MOVETYPE_FLY;
  86         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  87
  88         missile.angles = vectoangles (missile.velocity);
  89         missile.flags = FL_PROJECTILE;
  90
  91         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  92
  93         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  94 }
  95
  96 void W_Hagar_Attack2 (void)
  97 {
  98         local entity missile;
  99
 100         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 101
 102         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
 103
 104         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 105
 106         missile = spawn ();
 107         missile.owner = missile.realowner = self;
 108         missile.classname = "missile";
 109         missile.bot_dodge = TRUE;
 110         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 111
 112         missile.takedamage = DAMAGE_YES;
 113         missile.health = autocvar_g_balance_hagar_secondary_health;
 114         missile.damageforcescale = autocvar_g_balance_hagar_secondary_damageforcescale;
 115         missile.event_damage = W_Hagar_Damage;
 116         missile.damagedbycontents = TRUE;
 117
 118         missile.touch = W_Hagar_Touch2;
 119         missile.cnt = 0;
 120         missile.use = W_Hagar_Explode2;
 121         missile.think = adaptor_think2use_hittype_splash;
 122         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 123         PROJECTILE_MAKETRIGGER(missile);
 124         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 125         setorigin (missile, w_shotorg);
 126         setsize(missile, '0 0 0', '0 0 0');
 127
 128         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 129         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 130
 131         missile.angles = vectoangles (missile.velocity);
 132         missile.flags = FL_PROJECTILE;
 133
 134         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 135
 136         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 137 }
 138
 139 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep;
 140 void W_Hagar_Attack2_Load_Release (void)
 141 {
 142         // time to release the rockets we've loaded
 143
 144         local entity missile;
 145         local float counter, shots, spread_pershot;
 146         local vector s;
 147         vector forward, right, up;
 148
 149         if(!self.hagar_load)
 150                 return;
 151
 152         weapon_prepareattack_do(1, autocvar_g_balance_hagar_secondary_refire);
 153
 154         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
 155         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 156
 157         forward = v_forward;
 158         right = v_right;
 159         up = v_up;
 160
 161         shots = self.hagar_load;
 162         missile = world;
 163         while (counter < shots)
 164         {
 165                 missile = spawn ();
 166                 missile.owner = missile.realowner = self;
 167                 missile.classname = "missile";
 168                 missile.bot_dodge = TRUE;
 169                 missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 170
 171                 missile.takedamage = DAMAGE_YES;
 172                 missile.health = autocvar_g_balance_hagar_secondary_health;
 173                 missile.damageforcescale = autocvar_g_balance_hagar_secondary_damageforcescale;
 174                 missile.event_damage = W_Hagar_Damage;
 175                 missile.damagedbycontents = TRUE;
 176
 177                 missile.touch = W_Hagar_Touch; // not bouncy
 178                 missile.use = W_Hagar_Explode2;
 179                 missile.think = adaptor_think2use_hittype_splash;
 180                 missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 181                 PROJECTILE_MAKETRIGGER(missile);
 182                 missile.projectiledeathtype = WEP_HAGAR;
 183                 setorigin (missile, w_shotorg);
 184                 setsize(missile, '0 0 0', '0 0 0');
 185                 missile.movetype = MOVETYPE_FLY;
 186
 187                 // per-shot spread calculation: the more shots there are, the less spread is applied (based on the bias cvar)
 188                 spread_pershot = ((shots - 1) / (autocvar_g_balance_hagar_secondary_load_max - 1));
 189                 spread_pershot = (1 - (spread_pershot * autocvar_g_balance_hagar_secondary_load_spread_bias));
 190                 spread_pershot = (autocvar_g_balance_hagar_secondary_spread * spread_pershot * g_weaponspreadfactor);
 191
 192                 // pattern spread calculation
 193                 s = '0 0 0';
 194                 if (counter == 0)
 195                         s = '0 0 0';
 196                 else
 197                 {
 198                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 199                         s_y = v_forward_x;
 200                         s_z = v_forward_y;
 201                 }
 202                 s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 203
 204                 W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, autocvar_g_balance_hagar_secondary_speed, 0, 0, spread_pershot, FALSE);
 205
 206                 missile.angles = vectoangles (missile.velocity);
 207                 missile.flags = FL_PROJECTILE;
 208
 209                 CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 210
 211                 other = missile; MUTATOR_CALLHOOK(EditProjectile);
 212
 213                 counter = counter + 1;
 214         }
 215
 216         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 217         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire * W_WeaponRateFactor();
 218         self.hagar_load = 0;
 219 }
 220
 221 void W_Hagar_Attack2_Load (void)
 222 {
 223         // loadable hagar secondary attack, must always run each frame
 224
 225         local float loaded, enough_ammo;
 226         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 227
 228         // this is different than WR_CHECKAMMO when it comes to reloading
 229         if(autocvar_g_balance_hagar_reload_ammo)
 230                 enough_ammo = self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 231         else
 232                 enough_ammo = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 233
 234         if(self.BUTTON_ATCK2)
 235         {
 236                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
 237                 {
 238                         if(self.hagar_load)
 239                         {
 240                                 // if we pressed primary fire while loading, unload all rockets and abort
 241                                 self.weaponentity.state = WS_READY;
 242                                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo
 243                                 self.hagar_load = 0;
 244                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 245
 246                                 // pause until we can load rockets again, once we re-press the alt fire button
 247                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 248
 249                                 // require letting go of the alt fire button before we can load again
 250                                 self.hagar_loadblock = TRUE;
 251                         }
 252                 }
 253                 else
 254                 {
 255                         // check if we can attempt to load another rocket
 256                         if(!loaded && enough_ammo)
 257                         {
 258                                 if(!self.hagar_loadblock && self.hagar_loadstep < time)
 259                                 {
 260                                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 261                                         self.weaponentity.state = WS_INUSE;
 262                                         self.hagar_load += 1;
 263                                         sound(self, CH_WEAPON_B, "weapons/hagar_load.wav", VOL_BASE * 0.8, ATTN_NORM); // sound is too loud according to most
 264
 265                                         if (self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max)
 266                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_hold * W_WeaponRateFactor();
 267                                         else
 268                                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 269                                 }
 270                         }
 271                         else if(!self.hagar_loadbeep && self.hagar_load) // prevents the beep from playing each frame
 272                         {
 273                                 // if this is the last rocket we can load, play a beep sound to notify the player
 274                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 275                                 self.hagar_loadbeep = TRUE;
 276                         }
 277                 }
 278         }
 279         else if(self.hagar_loadblock)
 280         {
 281                 // the alt fire button has been released, so re-enable loading if blocked
 282                 self.hagar_loadblock = FALSE;
 283         }
 284
 285         if(self.hagar_load)
 286         {
 287                 if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && autocvar_g_balance_hagar_secondary_load_hold >= 0))
 288                 {
 289                         self.weaponentity.state = WS_READY;
 290                         W_Hagar_Attack2_Load_Release();
 291                 }
 292         }
 293         else
 294         {
 295                 self.hagar_loadbeep = FALSE;
 296         }
 297
 298         // we aren't checking ammo during an attack, so we must do it here
 299         if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
 300         {
 301                 // note: this doesn't force the switch
 302                 W_SwitchToOtherWeapon(self);
 303                 return;
 304         }
 305 }
 306
 307 void spawnfunc_weapon_hagar (void)
 308 {
 309         weapon_defaultspawnfunc(WEP_HAGAR);
 310 }
 311
 312 float w_hagar(float req)
 313 {
 314         float ammo_amount;
 315         if (req == WR_AIM)
 316                 if (random()>0.15)
 317                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 318                 else
 319                 {
 320                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 321                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 322                 }
 323         else if (req == WR_THINK)
 324         {
 325                 local float loadable_secondary;
 326                 loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 327
 328                 if (loadable_secondary)
 329                         W_Hagar_Attack2_Load(); // must always run each frame
 330                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 331                         weapon_action(self.weapon, WR_RELOAD);
 332                 else if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 333                 {
 334                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 335                         {
 336                                 W_Hagar_Attack();
 337                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 338                         }
 339                 }
 340                 else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 341                 {
 342                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 343                         {
 344                                 W_Hagar_Attack2();
 345                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 346                         }
 347                 }
 348         }
 349         else if (req == WR_GONETHINK)
 350         {
 351                 // we lost the weapon and want to prepare switching away
 352                 if(self.hagar_load)
 353                 {
 354                         self.weaponentity.state = WS_READY;
 355                         W_Hagar_Attack2_Load_Release();
 356                 }
 357         }
 358         else if (req == WR_PRECACHE)
 359         {
 360                 precache_model ("models/weapons/g_hagar.md3");
 361                 precache_model ("models/weapons/v_hagar.md3");
 362                 precache_model ("models/weapons/h_hagar.iqm");
 363                 precache_sound ("weapons/hagar_fire.wav");
 364                 precache_sound ("weapons/hagar_load.wav");
 365                 precache_sound ("weapons/hagar_beep.wav");
 366                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 367         }
 368         else if (req == WR_SETUP)
 369         {
 370                 weapon_setup(WEP_HAGAR);
 371                 self.current_ammo = ammo_rockets;
 372                 self.hagar_loadblock = FALSE;
 373
 374                 if(self.hagar_load)
 375                 {
 376                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo if necessary
 377                         self.hagar_load = 0;
 378                 }
 379         }
 380         else if (req == WR_CHECKAMMO1)
 381         {
 382                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 383                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 384                 return ammo_amount;
 385         }
 386         else if (req == WR_CHECKAMMO2)
 387         {
 388                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 389                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 390                 return ammo_amount;
 391         }
 392         else if (req == WR_RESETPLAYER)
 393         {
 394                 self.hagar_load = 0;
 395         }
 396         else if (req == WR_PLAYERDEATH)
 397         {
 398                 // if we have any rockets loaded when we die, release them
 399                 if(self.hagar_load && autocvar_g_balance_hagar_secondary_load_releasedeath)
 400                         W_Hagar_Attack2_Load_Release();
 401         }
 402         else if (req == WR_RELOAD)
 403         {
 404                 if not(self.hagar_load) // require releasing loaded rockets first
 405                         W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 406         }
 407         return TRUE;
 408 };
 409 #endif
 410 #ifdef CSQC
 411 float w_hagar(float req)
 412 {
 413         if(req == WR_IMPACTEFFECT)
 414         {
 415                 vector org2;
 416                 org2 = w_org + w_backoff * 6;
 417                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 418                 if(!w_issilent)
 419                 {
 420                         if (w_random<0.15)
 421                                 sound(self, CH_SHOTS, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 422                         else if (w_random<0.7)
 423                                 sound(self, CH_SHOTS, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 424                         else
 425                                 sound(self, CH_SHOTS, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 426                 }
 427         }
 428         else if(req == WR_PRECACHE)
 429         {
 430                 precache_sound("weapons/hagexp1.wav");
 431                 precache_sound("weapons/hagexp2.wav");
 432                 precache_sound("weapons/hagexp3.wav");
 433         }
 434         else if (req == WR_SUICIDEMESSAGE)
 435                 w_deathtypestring = _("%s played with tiny rockets");
 436         else if (req == WR_KILLMESSAGE)
 437         {
 438                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 439                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 440                 else // unchecked: SPLASH, SECONDARY
 441                         w_deathtypestring = _("%s was pummeled by %s");
 442         }
 443         return TRUE;
 444 }
 445 #endif
 446 #endif