qcsrc/server/vehicles/vehicles.qc

   1 float autocvar_g_vehicles_crush_dmg;
   2 float autocvar_g_vehicles_crush_force;
   3
   4 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
   5 void vehicles_return();
   6 void vehicles_enter();
   7 void vehicles_touch();
   8 void vehicles_reset_colors();
   9 void vehicles_clearrturn();
  10 void vehicles_setreturn();
  11
  12
  13 /** AuxiliaryXhair*
  14     Send addictional points of interest to be drawn, to vehicle owner
  15 **/
  16 float MAX_AXH = 4;
  17 .entity AuxiliaryXhair[MAX_AXH];
  18
  19 float SendAuxiliaryXhair(entity to, float sf)
  20 {
  21
  22         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  23
  24         WriteByte(MSG_ENTITY, self.cnt);
  25
  26         WriteCoord(MSG_ENTITY, self.origin_x);
  27         WriteCoord(MSG_ENTITY, self.origin_y);
  28         WriteCoord(MSG_ENTITY, self.origin_z);
  29
  30     WriteByte(MSG_ENTITY, rint(self.colormod_x * 255));
  31     WriteByte(MSG_ENTITY, rint(self.colormod_y * 255));
  32     WriteByte(MSG_ENTITY, rint(self.colormod_z * 255));
  33
  34     return TRUE;
  35 }
  36
  37 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, float axh_id)
  38 {
  39     entity axh;
  40
  41     axh_id = bound(0, axh_id, MAX_AXH);
  42     axh = own.AuxiliaryXhair[axh_id];
  43
  44     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  45     {
  46         axh                     = spawn();
  47         axh.cnt                 = axh_id;
  48         axh.drawonlytoclient    = own;
  49         axh.owner               = own;
  50         Net_LinkEntity(axh, FALSE, 0, SendAuxiliaryXhair);
  51     }
  52
  53     setorigin(axh, loc);
  54     axh.colormod            = clr;
  55     axh.SendFlags           = 0x01;
  56     own.AuxiliaryXhair[axh_id] = axh;
  57 }
  58
  59 /*
  60 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  61 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  62 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  63 {
  64         msg_entity = own;
  65
  66         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  67         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  68
  69         WriteByte(MSG_ONE, axh_id);
  70
  71         WriteCoord(MSG_ONE, loc_x);
  72         WriteCoord(MSG_ONE, loc_y);
  73         WriteCoord(MSG_ONE, loc_z);
  74
  75     WriteByte(MSG_ONE, rint(clr_x * 255));
  76     WriteByte(MSG_ONE, rint(clr_y * 255));
  77     WriteByte(MSG_ONE, rint(clr_z * 255));
  78
  79 }
  80 */
  81 // End AuxiliaryXhair
  82
  83 void CSQCVehicleSetup(entity own, float vehicle_id)
  84 {
  85         msg_entity = own;
  86
  87         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  88         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
  89         WriteByte(MSG_ONE, vehicle_id);
  90 }
  91
  92 /** vehicles_locktarget
  93
  94     Generic target locking.
  95
  96     Figure out if what target is "locked" (if any), for missile tracking as such.
  97
  98     after calling, "if(self.lock_target != world && self.lock_strength == 1)" mean
  99     you have a locked in target.
 100
 101     Exspects a crosshair_trace() or equivalent to be
 102     dont before calling.
 103
 104 **/
 105 .entity lock_target;
 106 .float  lock_strength;
 107 .float  lock_time;
 108 .float  lock_soundtime;
 109 void vehicles_locktarget(float incr, float decr, float _lock_time)
 110 {
 111     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 112     {
 113         self.lock_target    = world;
 114         self.lock_strength  = 0;
 115         self.lock_time      = 0;
 116     }
 117
 118     if(self.lock_time > time)
 119     {
 120         if(self.lock_target)
 121         if(self.lock_soundtime < time)
 122         {
 123             self.lock_soundtime = time + 0.5;
 124             play2(self.owner, "vehicles/locked.wav");
 125         }
 126
 127         return;
 128     }
 129
 130
 131     if(trace_ent != world)
 132     {
 133         if(teams_matter && trace_ent.team == self.team)
 134             trace_ent = world;
 135
 136         if(trace_ent.deadflag != DEAD_NO)
 137             trace_ent = world;
 138
 139         if not (trace_ent.vehicle_flags & VHF_ISVEHICLE || trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 140             trace_ent = world;
 141     }
 142
 143     if(self.lock_target == world && trace_ent != world)
 144         self.lock_target = trace_ent;
 145
 146     if(self.lock_target && trace_ent == self.lock_target)
 147     {
 148         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 149         {
 150             play2(self.owner, "vehicles/lock.wav");
 151             self.lock_soundtime = time + 0.8;
 152         }
 153         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 154         {
 155             play2(self.owner, "vehicles/locking.wav");
 156             self.lock_soundtime = time + 0.3;
 157         }
 158
 159     }
 160
 161     // Have a locking target
 162     // Trace hit current target
 163     if(trace_ent == self.lock_target && trace_ent != world)
 164     {
 165         self.lock_strength = min(self.lock_strength + incr, 1);
 166         if(self.lock_strength == 1)
 167             self.lock_time = time + _lock_time;
 168     }
 169     else
 170     {
 171         if(trace_ent)
 172             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 173         else
 174             self.lock_strength = max(self.lock_strength - decr, 0);
 175
 176         if(self.lock_strength == 0)
 177             self.lock_target = world;
 178     }
 179 }
 180
 181 #define VEHICLE_UPDATE_PLAYER(fld,vhname) \
 182 self.owner.vehicle_##fld = (self.vehicle_##fld / autocvar_g_vehicle_##vhname##_##fld) * 100
 183
 184 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 185 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 186 if(trace_fraction != 1) \
 187     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 188
 189 // Hover movement support
 190 float  force_fromtag_power;
 191 float  force_fromtag_normpower;
 192 vector force_fromtag_origin;
 193 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 194 {
 195     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 196     v_forward  = normalize(v_forward) * -1;
 197     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 198
 199     force_fromtag_power = (1 - trace_fraction) * max_power;
 200     force_fromtag_normpower = force_fromtag_power / max_power;
 201
 202     return v_forward  * force_fromtag_power;
 203 }
 204
 205 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 206 // Can possibly be use to move abt any surface (inclusing walls/celings)
 207 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 208 {
 209
 210     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 211     v_forward  = normalize(v_forward) * -1;
 212     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 213
 214     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 215     if(trace_fraction == 1.0)
 216     {
 217         force_fromtag_normpower = -0.25;
 218         return '0 0 -200';
 219     }
 220
 221     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 222     force_fromtag_normpower = force_fromtag_power / max_power;
 223
 224     return v_forward  * force_fromtag_power;
 225 }
 226
 227 // Generic vehile projectile system
 228 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 229 {
 230     self.health -= damage;
 231     self.velocity += force;
 232     if(self.health < 1)
 233     {
 234         self.takedamage = DAMAGE_NO;
 235         self.event_damage = SUB_Null;
 236         self.think = self.use;
 237         self.nextthink = time;
 238     }
 239
 240 }
 241
 242 void vehicles_projectile_explode()
 243 {
 244     if(self.owner && other != world)
 245     {
 246         if(other == self.owner.vehicle)
 247             return;
 248
 249         if(other == self.owner.vehicle.tur_head)
 250             return;
 251     }
 252
 253         PROJECTILE_TOUCH;
 254
 255         self.event_damage = SUB_Null;
 256     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, self.shot_force, self.totalfrags, other);
 257
 258     remove (self);
 259 }
 260
 261 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 262                            vector _org, vector _vel,
 263                            float _dmg, float _radi, float _force,  float _size,
 264                            float _deahtype, float _projtype, float _health,
 265                            float _cull, float _clianim)
 266 {
 267     entity proj;
 268
 269     proj = spawn();
 270
 271     PROJECTILE_MAKETRIGGER(proj);
 272     setorigin(proj, _org);
 273
 274     proj.shot_dmg         = _dmg;
 275     proj.shot_radius      = _radi;
 276     proj.shot_force       = _force;
 277     proj.totalfrags       = _deahtype;
 278     proj.solid            = SOLID_BBOX;
 279     proj.movetype         = MOVETYPE_FLYMISSILE;
 280     proj.flags            = FL_PROJECTILE;
 281     proj.bot_dodge        = TRUE;
 282     proj.bot_dodgerating  = _dmg;
 283     proj.velocity         = _vel;
 284     proj.touch            = vehicles_projectile_explode;
 285     proj.use              = vehicles_projectile_explode;
 286     proj.owner            = self;
 287     proj.realowner        = self.owner;
 288     proj.think            = SUB_Remove;
 289     proj.nextthink        = time + 30;
 290
 291     if(_health)
 292     {
 293         proj.takedamage       = DAMAGE_AIM;
 294         proj.event_damage     = vehicles_projectile_damage;
 295         proj.health           = _health;
 296     }
 297     else
 298         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 299
 300     if(_mzlsound)
 301         sound (self, CHAN_WEAPON, _mzlsound, VOL_BASE, ATTN_NORM);
 302
 303     if(_mzlfx)
 304         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 305
 306
 307     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 308
 309     CSQCProjectile(proj, _clianim, _projtype, _cull);
 310
 311     return proj;
 312 }
 313 // End generic vehile projectile system
 314
 315 /** vehicles_spawn
 316     Exetuted for all vehiles on (re)spawn.
 317     Sets defaults for newly spawned units.
 318 **/
 319 void vehicles_spawn()
 320 {
 321     dprint("Spawning vehicle: ", self.netname, "\n");
 322
 323     // De-own & reset
 324     self.vehicle_hudmodel.viewmodelforclient = self;
 325
 326     self.owner              = world;
 327     self.touch              = vehicles_touch;
 328     self.event_damage       = vehicles_damage;
 329     self.iscreature         = TRUE;
 330     self.movetype           = MOVETYPE_WALK;
 331     self.solid              = SOLID_SLIDEBOX;
 332     self.takedamage         = DAMAGE_AIM;
 333         self.deadflag           = DEAD_NO;
 334     self.bot_attack         = TRUE;
 335     self.flags              = FL_NOTARGET;
 336     self.avelocity          = '0 0 0';
 337     self.velocity           = '0 0 0';
 338
 339     // Reset locking
 340     self.lock_strength      = 0;
 341     self.lock_target        = world;
 342     self.misc_bulletcounter = 0;
 343
 344     // Return to spawn
 345     self.angles             = self.pos2;
 346     setorigin(self, self.pos1 + '0 0 128');
 347     // Show it
 348     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 349
 350     vehicles_reset_colors();
 351     self.vehicle_spawn();
 352 }
 353
 354 // Better way of determening whats crushable needed! (fl_crushable?)
 355 float vehicles_crushable(entity e)
 356 {
 357     if(e.classname == "player")
 358         return TRUE;
 359
 360     if(e.classname == "monster_zombie")
 361         return TRUE;
 362
 363     return FALSE;
 364 }
 365
 366 void vehicles_touch()
 367 {
 368     // Vehicle currently in use
 369     if(self.owner)
 370     {
 371         // Colided with world?
 372         if(other == world)
 373         {
 374             // Apply velocity based self damage here
 375         }
 376         else
 377         {
 378             if(other.vehicle_flags & VHF_ISVEHICLE)
 379             {
 380                 //other.velocity += self.velocity * (self.mass / other.mass);
 381             }
 382             else if(vehicles_crushable(other))
 383             {
 384                 if(vlen(self.velocity) != 0)
 385                     Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VHCRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 386             }
 387         }
 388         return;
 389     }
 390
 391     if(other.classname != "player")
 392         return;
 393
 394     if(other.deadflag != DEAD_NO)
 395         return;
 396
 397     if(other.vehicle != world)
 398         return;
 399
 400     // Remove this when bots know how to use vehicles.
 401     if (clienttype(other) != CLIENTTYPE_REAL)
 402         return;
 403
 404     vehicles_enter();
 405 }
 406
 407 void vehicles_enter()
 408 {
 409    // Remove this when bots know how to use vehicles
 410     if (clienttype(other) != CLIENTTYPE_REAL)
 411         return;
 412
 413     if(self.phase > time)
 414         return;
 415
 416     if(teams_matter)
 417     if(self.team)
 418     if(self.team != other.team)
 419         return;
 420
 421     self.vehicle_ammo1   = 0;
 422     self.vehicle_ammo2   = 0;
 423     self.vehicle_reload1 = 0;
 424     self.vehicle_reload2 = 0;
 425     self.vehicle_energy  = 0;
 426
 427     self.owner          = other;
 428     self.switchweapon   = other.switchweapon;
 429
 430     // .viewmodelforclient works better.
 431     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 432
 433 #ifndef VEHICLES_CSQC
 434         self.vehicle_hudmodel.viewmodelforclient = self.owner;
 435 #endif
 436
 437     self.event_damage         = vehicles_damage;
 438     self.nextthink            = 0;
 439     self.owner.angles         = self.angles;
 440     self.owner.takedamage     = DAMAGE_NO;
 441     self.owner.solid          = SOLID_NOT;
 442     self.owner.movetype       = MOVETYPE_NOCLIP;
 443     self.owner.alpha          = -1;
 444     self.owner.vehicle        = self;
 445     self.owner.event_damage   = SUB_Null;
 446     self.owner.view_ofs       = '0 0 0';
 447     self.colormap             = self.owner.colormap;
 448     if(self.tur_head)
 449         self.tur_head.colormap    = self.owner.colormap;
 450
 451     self.owner.hud            = self.hud;
 452     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 453
 454     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 455     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 456     self.owner.vehicle_reload1  = self.vehicle_reload1;
 457     self.owner.vehicle_reload2  = self.vehicle_reload2;
 458
 459     // Cant do this, hides attached objects too.
 460     //self.exteriormodeltoclient = self.owner;
 461     //self.tur_head.exteriormodeltoclient = self.owner;
 462
 463     other.flags &~= FL_ONGROUND;
 464     self.flags  &~= FL_ONGROUND;
 465
 466     self.team                 = self.owner.team;
 467     self.flags               -= FL_NOTARGET;
 468
 469 #ifndef VEHICLES_CSQC
 470     msg_entity = other;
 471     WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 472     WriteEntity(MSG_ONE, self.vehicle_viewport);
 473
 474     WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 475     if(self.tur_head)
 476     {
 477         WriteAngle(MSG_ONE, self.tur_head.angles_x + self.angles_x); // tilt
 478         WriteAngle(MSG_ONE, self.tur_head.angles_y + self.angles_y); // yaw
 479         WriteAngle(MSG_ONE, 0);                                      // roll
 480     }
 481     else
 482     {
 483         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 484         WriteAngle(MSG_ONE,  self.angles_x * -1); // tilt
 485         WriteAngle(MSG_ONE,  self.angles_y);      // yaw
 486         WriteAngle(MSG_ONE,  0);                  // roll
 487     }
 488 #endif
 489 //#endif
 490
 491     vehicles_clearrturn();
 492
 493     CSQCVehicleSetup(self.owner, self.hud);
 494
 495     self.vehicle_enter();
 496 }
 497
 498 vector vehicles_findgoodexit(vector prefer_spot)
 499 {
 500     vector exitspot;
 501     float mysize;
 502
 503     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 504     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 505         return prefer_spot;
 506
 507     mysize = vlen(self.maxs - self.mins);
 508     float i;
 509     vector v, v2;
 510     v2 = 0.5 * (self.absmin + self.absmax);
 511     for(i = 0; i < 100; ++i)
 512     {
 513         v = randomvec();
 514         v_z = 0;
 515         v = v2 + normalize(v) * mysize;
 516         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 517         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 518             return v;
 519     }
 520
 521     /*
 522     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 523     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 524     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 525         return exitspot;
 526
 527     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 528     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 529     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 530         return exitspot;
 531
 532     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 533     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 534     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 535         return exitspot;
 536
 537     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 538     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 539     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 540         return exitspot;
 541     */
 542
 543     return self.origin;
 544 }
 545
 546 void vehicles_exit(float eject)
 547 {
 548         self.flags |= FL_NOTARGET;
 549
 550     if (self.owner)
 551     {
 552         msg_entity = self.owner;
 553         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 554         WriteEntity( MSG_ONE, self.owner);
 555
 556         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 557         WriteAngle(MSG_ONE, 0);                 // pich
 558         WriteAngle(MSG_ONE, self.angles_y);     // yaw
 559         WriteAngle(MSG_ONE, 0);                 // roll
 560
 561         setsize(self.owner, PL_MIN,PL_MAX);
 562
 563         self.owner.takedamage     = DAMAGE_AIM;
 564         self.owner.solid          = SOLID_SLIDEBOX;
 565         self.owner.movetype       = MOVETYPE_WALK;
 566         self.owner.effects        &~= EF_NODRAW;
 567         self.owner.alpha          = 1;
 568         self.owner.PlayerPhysplug = SUB_Null;
 569         self.owner.vehicle        = world;
 570         self.owner.view_ofs       = PL_VIEW_OFS;
 571         self.owner.event_damage   = PlayerDamage;
 572         self.owner.hud            = HUD_NORMAL;
 573         self.owner.switchweapon   = self.switchweapon;
 574         self.owner.BUTTON_USE     = 0;
 575     }
 576
 577     if(self.deadflag == DEAD_NO)
 578         self.avelocity          = '0 0 0';
 579
 580     self.vehicle_hudmodel.viewmodelforclient = self;
 581         self.tur_head.nodrawtoclient             = world;
 582     vehicles_setreturn();
 583
 584     self.phase = time + 1;
 585
 586     if(!teams_matter)
 587         self.team = 0;
 588
 589     self.vehicle_exit(eject);
 590     self.owner = world;
 591 }
 592
 593
 594 void vehicles_regen(.float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time)
 595 {
 596     if(self.regen_field < field_max)
 597     if(self.timer + rpause < time)
 598     {
 599         self.regen_field = min(self.regen_field + regen * delta_time, field_max);
 600
 601         if(self.owner)
 602             self.owner.regen_field = (self.regen_field / field_max) * 100;
 603     }
 604 }
 605
 606 void shieldhit_think()
 607 {
 608     self.alpha -= 0.1;
 609     if (self.alpha <= 0)
 610     {
 611         //setmodel(self, "");
 612         self.alpha = -1;
 613     }
 614     else
 615     {
 616         self.nextthink = time + 0.1;
 617     }
 618 }
 619
 620 void vehicles_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 621 {
 622     self.dmg_time = time;
 623
 624     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 625     {
 626         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 627         {
 628             self.vehicle_shieldent = spawn();
 629             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 630
 631             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 632             setattachment(self.vehicle_shieldent, self, "");
 633             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 634             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 635             self.vehicle_shieldent.think       = shieldhit_think;
 636         }
 637
 638
 639         self.vehicle_shieldent.colormod    = '1 1 1';
 640         self.vehicle_shieldent.alpha       = 0.45;
 641         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 642         self.vehicle_shieldent.nextthink   = time;
 643
 644         self.vehicle_shield -= damage;
 645
 646         if(self.vehicle_shield < 0)
 647         {
 648             self.vehicle_shieldent.colormod = '2 0 0';
 649             self.vehicle_shield             = 0;
 650             self.vehicle_shieldent.alpha    = 0.75;
 651             self.vehicle_health            -= fabs(self.vehicle_shield);
 652         }
 653     }
 654     else
 655         self.vehicle_health -= damage;
 656
 657     self.velocity += force; // * (vlen(force) / self.mass);
 658
 659     if(self.vehicle_health <= 0)
 660     {
 661         if(self.owner)
 662             if(self.vehicle_flags & VHF_DEATHEJECT)
 663                 vehicles_exit(VHEF_EJECT);
 664             else
 665                 vehicles_exit(VHEF_RELESE);
 666
 667         self.vehicle_die();
 668         vehicles_setreturn();
 669     }
 670 }
 671
 672 void vehicles_return()
 673 {
 674     pointparticles(particleeffectnum("teleport"), self.enemy.origin + '0 0 64', '0 0 0', 1);
 675
 676     self.enemy.think     = vehicles_spawn;
 677     self.enemy.nextthink = time;
 678
 679     remove(self);
 680 }
 681
 682 void vehicles_clearrturn()
 683 {
 684     entity ret;
 685     // Remove "return helper", if any.
 686     ret = findchain(classname, "vehicle_return");
 687     while(ret)
 688     {
 689         if(ret.enemy == self)
 690         {
 691             ret.classname   = "";
 692             ret.think       = SUB_Remove;
 693             ret.nextthink   = time + 0.1;
 694             return;
 695         }
 696
 697         ret = ret.chain;
 698     }
 699 }
 700
 701 void vehicles_setreturn()
 702 {
 703     entity ret;
 704
 705     vehicles_clearrturn();
 706
 707     ret = spawn();
 708     ret.classname   = "vehicle_return";
 709     ret.enemy       = self;
 710     ret.think       = vehicles_return;
 711     ret.nextthink   = time + self.vehicle_respawntime;
 712 }
 713
 714 float vehicles_customizeentityforclient()
 715 {
 716     if(self.deadflag  == DEAD_DEAD)
 717         return FALSE;
 718     else
 719         return TRUE;
 720 }
 721
 722 void vehicles_configcheck(string  configname, float check_cvar)
 723 {
 724     if(check_cvar == 0)
 725         localcmd(strcat("exec ", configname, "\n"));
 726 }
 727
 728 void vehicles_reset_colors()
 729 {
 730     entity e;
 731     float _effects, _colormap;
 732     vector _glowmod, _colormod;
 733
 734     if(autocvar_g_nodepthtestplayers)
 735         _effects = EF_NODEPTHTEST;
 736
 737     if(autocvar_g_fullbrightplayers)
 738         _effects |= EF_FULLBRIGHT;
 739
 740     if(self.team)
 741         _colormap = 1024 + (self.team - 1) * 17;
 742     else
 743         _colormap = 1024;
 744
 745     _glowmod  = '0 0 0';
 746     _colormod = '0 0 0';
 747
 748     // Find all ents attacked to main model and setup effects, colormod etc.
 749     e = findchainentity(tag_entity, self);
 750     while(e)
 751     {
 752         if(e != self.vehicle_shieldent)
 753         {
 754             e.effects   = _effects  | EF_LOWPRECISION;
 755             e.colormod  = _colormod;
 756             e.colormap  = _colormap;
 757             e.alpha     = 1;
 758         }
 759         e = e.chain;
 760     }
 761
 762     self.vehicle_hudmodel.effects  = self.effects  = _effects | EF_LOWPRECISION;
 763     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
 764     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
 765     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
 766
 767     self.alpha     = 1;
 768     self.avelocity = '0 0 0';
 769     self.velocity  = '0 0 0';
 770     self.effects   = _effects;
 771 }
 772
 773 float vehicle_initialize(string  net_name,
 774                          string  bodymodel,
 775                          string  topmodel,
 776                          string  hudmodel,
 777                          string  toptag,
 778                          string  hudtag,
 779                          string  viewtag,
 780                          float   vhud,
 781                          vector  min_s,
 782                          vector  max_s,
 783                          float   nodrop,
 784                          void()  spawnproc,
 785                          float   _respawntime,
 786                          float() physproc,
 787                          void()  enterproc,
 788                          void(float extflag) exitfunc,
 789                          void() dieproc,
 790                          void() thinkproc,
 791                          float  use_csqc)
 792 {
 793     addstat(STAT_HUD, AS_INT,  hud);
 794         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
 795         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
 796         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
 797
 798         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT,   vehicle_ammo1);
 799         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
 800
 801         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT,   vehicle_ammo2);
 802         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
 803
 804     if(bodymodel == "")
 805         error("vehicles: missing bodymodel!");
 806
 807     if(hudmodel == "")
 808         error("vehicles: missing hudmodel!");
 809
 810     if(net_name == "")
 811         self.netname = self.classname;
 812     else
 813         self.netname = net_name;
 814
 815     if(self.team && !teams_matter)
 816         self.team = 0;
 817
 818     self.vehicle_flags |= VHF_ISVEHICLE;
 819
 820     setmodel(self, bodymodel);
 821
 822     self.vehicle_viewport   = spawn();
 823     self.vehicle_hudmodel   = spawn();
 824     self.tur_head           = spawn();
 825     self.tur_head.owner     = self;
 826     self.takedamage         = DAMAGE_AIM;
 827     self.bot_attack         = TRUE;
 828     self.iscreature         = TRUE;
 829     self.hud                = vhud;
 830
 831     //self.customizeentityforclient = vehicles_customizeentityforclient;
 832     self.vehicle_die         = dieproc;
 833     self.vehicle_exit        = exitfunc;
 834     self.vehicle_enter       = enterproc;
 835     self.PlayerPhysplug      = physproc;
 836     self.event_damage        = vehicles_damage;
 837     self.touch               = vehicles_touch;
 838     self.think               = vehicles_spawn;
 839     self.nextthink           = time;
 840     self.vehicle_respawntime = _respawntime;
 841     self.vehicle_spawn       = spawnproc;
 842
 843     if(autocvar_g_nodepthtestplayers)
 844         self.effects = self.effects | EF_NODEPTHTEST;
 845
 846     if(autocvar_g_fullbrightplayers)
 847         self.effects = self.effects | EF_FULLBRIGHT;
 848
 849     setmodel(self.vehicle_hudmodel, hudmodel);
 850     setmodel(self.vehicle_viewport, "null");
 851
 852
 853     if(topmodel != "")
 854     {
 855         setmodel(self.tur_head, topmodel);
 856         setattachment(self.tur_head, self, toptag);
 857         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
 858         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 859     }
 860     else
 861     {
 862         setattachment(self.tur_head, self, "");
 863         setattachment(self.vehicle_hudmodel, self, hudtag);
 864         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
 865     }
 866
 867     setsize(self, min_s, max_s);
 868     if not (nodrop)
 869     {
 870         setorigin(self, self.origin);
 871         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
 872         setorigin(self, trace_endpos);
 873     }
 874
 875     self.pos1 = self.origin;
 876     self.pos2 = self.angles;
 877 #ifdef VEHICLES_CSQC
 878     if(use_csqc)
 879         net_link_vehile();
 880 #endif
 881     return TRUE;
 882 }
 883
 884
 885 void bugmenot()
 886 {
 887     self.vehicle_exit       = self.vehicle_exit;
 888     self.vehicle_enter      = self.vehicle_exit;
 889     self.vehicle_die        = self.vehicle_exit;
 890     self.vehicle_spawn      = self.vehicle_exit;
 891     self.AuxiliaryXhair     = self.AuxiliaryXhair;
 892 }