qcsrc/server/vehicles/vehicle.qc

   1 #include "vehicle.qh"
   2
   3 #include "../_all.qh"
   4 #include "../cl_player.qh"
   5 #include "../../common/constants.qh"
   6 #include "../waypointsprites.qh"
   7
   8 #include "../bot/waypoints.qh"
   9
  10 float autocvar_g_vehicles_crush_dmg;
  11 float autocvar_g_vehicles_crush_force;
  12 float autocvar_g_vehicles_delayspawn;
  13 float autocvar_g_vehicles_delayspawn_jitter;
  14
  15 float autocvar_g_vehicles_vortex_damagerate = 0.5;
  16 float autocvar_g_vehicles_machinegun_damagerate = 0.5;
  17 float autocvar_g_vehicles_rifle_damagerate = 0.75;
  18 float autocvar_g_vehicles_vaporizer_damagerate = 0.001;
  19 float autocvar_g_vehicles_tag_damagerate = 5;
  20
  21 float autocvar_g_vehicles;
  22
  23 void vehicles_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
  24 void vehicles_return();
  25 void vehicles_enter();
  26 void vehicles_reset_colors();
  27 void vehicles_clearreturn();
  28 void vehicles_setreturn();
  29
  30
  31 /** AuxiliaryXhair*
  32     Send additional points of interest to be drawn, to vehicle owner
  33 **/
  34 const float MAX_AXH = 4;
  35 .entity AuxiliaryXhairs[MAX_AXH];
  36
  37 float SendAuxiliaryXhair(entity to, int sf)
  38 {
  39
  40         WriteByte(MSG_ENTITY, ENT_CLIENT_AUXILIARYXHAIR);
  41
  42         WriteByte(MSG_ENTITY, self.cnt);
  43
  44         WriteCoord(MSG_ENTITY, self.origin.x);
  45         WriteCoord(MSG_ENTITY, self.origin.y);
  46         WriteCoord(MSG_ENTITY, self.origin.z);
  47
  48     WriteByte(MSG_ENTITY, rint(self.colormod.x * 255));
  49     WriteByte(MSG_ENTITY, rint(self.colormod.y * 255));
  50     WriteByte(MSG_ENTITY, rint(self.colormod.z * 255));
  51
  52     return true;
  53 }
  54
  55 void UpdateAuxiliaryXhair(entity own, vector loc, vector clr, int axh_id)
  56 {
  57     if (!IS_REAL_CLIENT(own))
  58         return;
  59
  60     entity axh;
  61
  62     axh_id = bound(0, axh_id, MAX_AXH);
  63     axh = own.(AuxiliaryXhairs[axh_id]);
  64
  65     if(axh == world || wasfreed(axh))  // MADNESS? THIS IS QQQQCCCCCCCCC (wasfreed, why do you exsist?)
  66     {
  67         axh                     = spawn();
  68         axh.cnt                 = axh_id;
  69         axh.drawonlytoclient    = own;
  70         axh.owner               = own;
  71         Net_LinkEntity(axh, false, 0, SendAuxiliaryXhair);
  72     }
  73
  74     setorigin(axh, loc);
  75     axh.colormod            = clr;
  76     axh.SendFlags           = 0x01;
  77     own.(AuxiliaryXhairs[axh_id]) = axh;
  78 }
  79
  80 /*
  81 // SVC_TEMPENTITY based, horrible with even 50 ping. hm.
  82 // WriteByte(MSG_ONE, SVC_TEMPENTITY) uses reliable messagess, never use for thinsg that need continous updates.
  83 void SendAuxiliaryXhair2(entity own, vector loc, vector clr, float axh_id)
  84 {
  85         msgexntity = own;
  86
  87         WriteByte(MSG_ONE, SVC_TEMPENTITY);
  88         WriteByte(MSG_ONE, TE_CSQC_AUXILIARYXHAIR);
  89
  90         WriteByte(MSG_ONE, axh_id);
  91
  92         WriteCoord(MSG_ONE, loc_x);
  93         WriteCoord(MSG_ONE, loc_y);
  94         WriteCoord(MSG_ONE, loc_z);
  95
  96     WriteByte(MSG_ONE, rint(clr_x * 255));
  97     WriteByte(MSG_ONE, rint(clr_y * 255));
  98     WriteByte(MSG_ONE, rint(clr_z * 255));
  99
 100 }
 101 */
 102 // End AuxiliaryXhair
 103
 104 /**
 105     Notifies the client that he enterd a vehicle, and sends
 106     realavent data.
 107
 108     only sends vehicle_id atm (wich is a HUD_* constant, ex. HUD_SPIDERBOT)
 109 **/
 110 void CSQCVehicleSetup(entity own, float vehicle_id)
 111 {
 112     if (!IS_REAL_CLIENT(own))
 113         return;
 114
 115         msg_entity = own;
 116
 117         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 118         WriteByte(MSG_ONE, TE_CSQC_VEHICLESETUP);
 119         if(vehicle_id != 0)
 120             WriteByte(MSG_ONE, vehicle_id);
 121         else
 122         WriteByte(MSG_ONE, 1 + own.vehicle.vehicle_weapon2mode + HUD_VEHICLE_LAST);
 123 }
 124
 125
 126 const float     DAMAGE_TARGETDRONE = 10;
 127
 128 vector targetdrone_getnewspot()
 129 {
 130
 131         vector spot;
 132         float i;
 133         for(i = 0; i < 100; ++i)
 134         {
 135                 spot = self.origin + randomvec() * 1024;
 136                 tracebox(spot, self.mins, self.maxs, spot, MOVE_NORMAL, self);
 137                 if(trace_fraction == 1.0 && trace_startsolid == 0 && trace_allsolid == 0)
 138                         return spot;
 139         }
 140         return self.origin;
 141 }
 142
 143 #if 0
 144 void targetdrone_think();
 145 void targetdrone_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force);
 146 void targetdrone_renwe()
 147 {
 148         self.think = targetdrone_think;
 149         self.nextthink = time + 0.1;
 150         setorigin(self, targetdrone_getnewspot());
 151         self.health = 200;
 152         self.takedamage = DAMAGE_TARGETDRONE;
 153         self.event_damage = targetdrone_damage;
 154         self.solid = SOLID_BBOX;
 155         setmodel(self, "models/runematch/rune.mdl");
 156         self.effects = EF_LOWPRECISION;
 157         self.scale = 10;
 158         self.movetype = MOVETYPE_BOUNCEMISSILE;
 159         setsize(self, '-100 -100 -100', '100 100 100');
 160
 161 }
 162 void targetdrone_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 163 {
 164         self.health -= damage;
 165         if(self.health <= 0)
 166         {
 167                 pointparticles(particleeffectnum("explosion_medium"), self.origin, '0 0 0', 1);
 168
 169                 if(!self.cnt)
 170                         remove(self);
 171                 else
 172                 {
 173                         self.think = targetdrone_renwe;
 174                         self.nextthink = time + 1 + random() * 2;
 175                         self.solid = SOLID_NOT;
 176                         setmodel(self, "");
 177                 }
 178         }
 179 }
 180 entity targetdrone_getfear()
 181 {
 182         entity fear;
 183         float i;
 184
 185         for(i = 64; i <= 1024; i += 64)
 186         {
 187                 fear = findradius(self.origin, i);
 188                 while(fear)
 189                 {
 190                         if(fear.bot_dodge)
 191                                 return fear;
 192
 193                         fear = fear.chain;
 194                 }
 195         }
 196
 197         return world;
 198 }
 199 void targetdrone_think()
 200 {
 201         self.nextthink = time + 0.1;
 202
 203         if(self.wp00)
 204         if(self.wp00.deadflag != DEAD_NO)
 205                 self.wp00 = targetdrone_getfear();
 206
 207         if(!self.wp00)
 208                 self.wp00 = targetdrone_getfear();
 209
 210         vector newdir;
 211
 212         if(self.wp00)
 213                 newdir = steerlib_push(self.wp00.origin) + randomvec() * 0.75;
 214         else
 215                 newdir = randomvec() * 0.75;
 216
 217         newdir = newdir * 0.5 + normalize(self.velocity) * 0.5;
 218
 219         if(self.wp00)
 220                 self.velocity = normalize(newdir) * (500 + (1024 / min(vlen(self.wp00.origin - self.origin), 1024)) * 700);
 221         else
 222                 self.velocity = normalize(newdir) * 750;
 223
 224         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 2, MOVE_NORMAL, self);
 225         if(trace_fraction != 1.0)
 226                 self.velocity = self.velocity * -1;
 227
 228         //normalize((normalize(self.velocity) * 0.5 + newdir * 0.5)) * 750;
 229 }
 230
 231 void targetdrone_spawn(vector _where, float _autorenew)
 232 {
 233         entity drone = spawn();
 234         setorigin(drone, _where);
 235         drone.think = targetdrone_renwe;
 236         drone.nextthink = time + 0.1;
 237         drone.cnt = _autorenew;
 238 }
 239 #endif
 240
 241 void vehicles_locktarget(float incr, float decr, float _lock_time)
 242 {
 243     if(self.lock_target && self.lock_target.deadflag != DEAD_NO)
 244     {
 245         self.lock_target    = world;
 246         self.lock_strength  = 0;
 247         self.lock_time      = 0;
 248     }
 249
 250     if(self.lock_time > time)
 251     {
 252         if(self.lock_target)
 253         if(self.lock_soundtime < time)
 254         {
 255             self.lock_soundtime = time + 0.5;
 256             play2(self.owner, "vehicles/locked.wav");
 257         }
 258
 259         return;
 260     }
 261
 262     if(trace_ent != world)
 263     {
 264         if(teamplay && trace_ent.team == self.team)
 265             trace_ent = world;
 266
 267         if(trace_ent.deadflag != DEAD_NO)
 268             trace_ent = world;
 269         if(!(
 270             (trace_ent.vehicle_flags & VHF_ISVEHICLE) ||
 271             (trace_ent.turrcaps_flags & TFL_TURRCAPS_ISTURRET) ||
 272             (trace_ent.takedamage == DAMAGE_TARGETDRONE)
 273             )) { trace_ent = world; }
 274     }
 275
 276     if(self.lock_target == world && trace_ent != world)
 277         self.lock_target = trace_ent;
 278
 279     if(self.lock_target && trace_ent == self.lock_target)
 280     {
 281         if(self.lock_strength != 1 && self.lock_strength + incr >= 1)
 282         {
 283             play2(self.owner, "vehicles/lock.wav");
 284             self.lock_soundtime = time + 0.8;
 285         }
 286         else if (self.lock_strength != 1 && self.lock_soundtime < time)
 287         {
 288             play2(self.owner, "vehicles/locking.wav");
 289             self.lock_soundtime = time + 0.3;
 290         }
 291
 292     }
 293
 294     // Have a locking target
 295     // Trace hit current target
 296     if(trace_ent == self.lock_target && trace_ent != world)
 297     {
 298         self.lock_strength = min(self.lock_strength + incr, 1);
 299         if(self.lock_strength == 1)
 300             self.lock_time = time + _lock_time;
 301     }
 302     else
 303     {
 304         if(trace_ent)
 305             self.lock_strength = max(self.lock_strength - decr * 2, 0);
 306         else
 307             self.lock_strength = max(self.lock_strength - decr, 0);
 308
 309         if(self.lock_strength == 0)
 310             self.lock_target = world;
 311     }
 312 }
 313
 314
 315 #define vehicles_sweap_collision(orig,vel,dt,acm,mult) \
 316 traceline(orig, orig + vel * dt, MOVE_NORMAL, self); \
 317 if(trace_fraction != 1) \
 318     acm += normalize(self.origin - trace_endpos) * (vlen(vel) * mult)
 319
 320 // Hover movement support
 321 float  force_fromtag_power;
 322 vector force_fromtag_origin;
 323 vector vehicles_force_fromtag_hover(string tag_name, float spring_length, float max_power)
 324 {
 325     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 326     v_forward  = normalize(v_forward) * -1;
 327     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 328
 329     force_fromtag_power = (1 - trace_fraction) * max_power;
 330     force_fromtag_normpower = force_fromtag_power / max_power;
 331
 332     return v_forward  * force_fromtag_power;
 333 }
 334
 335 // Experimental hovermode wich uses attraction/repulstion from surface insted of gravity/repulsion
 336 // Can possibly be use to move abt any surface (inclusing walls/celings)
 337 vector vehicles_force_fromtag_maglev(string tag_name, float spring_length, float max_power)
 338 {
 339
 340     force_fromtag_origin = gettaginfo(self, gettagindex(self, tag_name));
 341     v_forward  = normalize(v_forward) * -1;
 342     traceline(force_fromtag_origin, force_fromtag_origin - (v_forward  * spring_length), MOVE_NORMAL, self);
 343
 344     // TODO - this may NOT be compatible with wall/celing movement, unhardcode 0.25 (engine count multiplier)
 345     if(trace_fraction == 1.0)
 346     {
 347         force_fromtag_normpower = -0.25;
 348         return '0 0 -200';
 349     }
 350
 351     force_fromtag_power = ((1 - trace_fraction) - trace_fraction) * max_power;
 352     force_fromtag_normpower = force_fromtag_power / max_power;
 353
 354     return v_forward  * force_fromtag_power;
 355 }
 356
 357 // Generic vehile projectile system
 358 void vehicles_projectile_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 359 {
 360     // Ignore damage from oterh projectiles from my owner (dont mess up volly's)
 361     if(inflictor.owner == self.owner)
 362         return;
 363
 364     self.health -= damage;
 365     self.velocity += force;
 366     if(self.health < 1)
 367     {
 368         self.takedamage = DAMAGE_NO;
 369         self.event_damage = func_null;
 370         self.think = self.use;
 371         self.nextthink = time;
 372     }
 373 }
 374
 375 void vehicles_projectile_explode()
 376 {
 377     if(self.owner && other != world)
 378     {
 379         if(other == self.owner.vehicle)
 380             return;
 381
 382         if(other == self.owner.vehicle.tur_head)
 383             return;
 384     }
 385
 386         PROJECTILE_TOUCH;
 387
 388         self.event_damage = func_null;
 389     RadiusDamage (self, self.realowner, self.shot_dmg, 0, self.shot_radius, self, world, self.shot_force, self.totalfrags, other);
 390
 391     remove (self);
 392 }
 393
 394 entity vehicles_projectile(string _mzlfx, string _mzlsound,
 395                            vector _org, vector _vel,
 396                            float _dmg, float _radi, float _force,  float _size,
 397                            float _deahtype, float _projtype, float _health,
 398                            float _cull, float _clianim, entity _owner)
 399 {
 400     entity proj;
 401
 402     proj = spawn();
 403
 404     PROJECTILE_MAKETRIGGER(proj);
 405     setorigin(proj, _org);
 406
 407     proj.shot_dmg         = _dmg;
 408     proj.shot_radius      = _radi;
 409     proj.shot_force       = _force;
 410     proj.totalfrags       = _deahtype;
 411     proj.solid            = SOLID_BBOX;
 412     proj.movetype         = MOVETYPE_FLYMISSILE;
 413     proj.flags            = FL_PROJECTILE;
 414     proj.bot_dodge        = true;
 415     proj.bot_dodgerating  = _dmg;
 416     proj.velocity         = _vel;
 417     proj.touch            = vehicles_projectile_explode;
 418     proj.use              = vehicles_projectile_explode;
 419     proj.owner            = self;
 420     proj.realowner        = _owner;
 421     proj.think            = SUB_Remove;
 422     proj.nextthink        = time + 30;
 423
 424     if(_health)
 425     {
 426         proj.takedamage       = DAMAGE_AIM;
 427         proj.event_damage     = vehicles_projectile_damage;
 428         proj.health           = _health;
 429     }
 430     else
 431         proj.flags           = FL_PROJECTILE | FL_NOTARGET;
 432
 433     if(_mzlsound)
 434         sound (self, CH_WEAPON_A, _mzlsound, VOL_BASE, ATTEN_NORM);
 435
 436     if(_mzlfx)
 437         pointparticles(particleeffectnum(_mzlfx), proj.origin, proj.velocity, 1);
 438
 439
 440     setsize (proj, '-1 -1 -1' * _size, '1 1 1' * _size);
 441
 442     CSQCProjectile(proj, _clianim, _projtype, _cull);
 443
 444     return proj;
 445 }
 446 // End generic vehile projectile system
 447
 448 void vehicles_reset()
 449 {
 450         if(self.owner)
 451         {
 452                 entity oldself = self;
 453                 self = self.owner;
 454                 vehicles_exit(VHEF_RELESE);
 455                 self = oldself;
 456         }
 457         self.alpha      = -1;
 458         self.movetype   = MOVETYPE_NONE;
 459         self.effects    = EF_NODRAW;
 460         self.colormod  = '0 0 0';
 461         self.avelocity = '0 0 0';
 462         self.velocity  = '0 0 0';
 463         self.event_damage = func_null;
 464         self.solid = SOLID_NOT;
 465         self.deadflag = DEAD_NO;
 466
 467         self.touch = func_null;
 468         self.nextthink = 0;
 469         vehicles_setreturn();
 470 }
 471
 472 /** vehicles_spawn
 473     Exetuted for all vehicles on (re)spawn.
 474     Sets defaults for newly spawned units.
 475 **/
 476 void vehicles_spawn()
 477 {
 478     dprint("Spawning vehicle: ", self.netname, "\n");
 479
 480     // De-own & reset
 481     self.vehicle_hudmodel.viewmodelforclient = self;
 482
 483     self.owner              = world;
 484     self.touch              = vehicles_touch;
 485     self.event_damage       = vehicles_damage;
 486     self.reset              = vehicles_reset;
 487     self.iscreature         = true;
 488     self.teleportable       = false; // no teleporting for vehicles, too buggy
 489     self.damagedbycontents      = true;
 490     self.movetype           = MOVETYPE_WALK;
 491     self.solid              = SOLID_SLIDEBOX;
 492     self.takedamage         = DAMAGE_AIM;
 493         self.deadflag           = DEAD_NO;
 494     self.bot_attack         = true;
 495     self.flags              = FL_NOTARGET;
 496     self.avelocity          = '0 0 0';
 497     self.velocity           = '0 0 0';
 498
 499     // Reset locking
 500     self.lock_strength      = 0;
 501     self.lock_target        = world;
 502     self.misc_bulletcounter = 0;
 503
 504     // Return to spawn
 505     self.angles             = self.pos2;
 506     setorigin(self, self.pos1 + '0 0 0');
 507     // Show it
 508     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 509
 510     if(self.vehicle_controller)
 511         self.team = self.vehicle_controller.team;
 512
 513     vehicles_reset_colors();
 514     self.vehicle_spawn(VHSF_NORMAL);
 515 }
 516
 517 // Better way of determening whats crushable needed! (fl_crushable?)
 518 float vehicles_crushable(entity e)
 519 {
 520     if(IS_PLAYER(e))
 521         return true;
 522
 523     if(e.flags & FL_MONSTER)
 524         return true;
 525
 526     return false;
 527 }
 528
 529 void vehicles_impact(float _minspeed, float _speedfac, float _maxpain)
 530 {
 531     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 532         return;
 533
 534     if(self.play_time < time)
 535     {
 536         float wc = vlen(self.velocity - self.oldvelocity);
 537         //dprint("oldvel: ", vtos(self.oldvelocity), "\n");
 538         //dprint("vel: ", vtos(self.velocity), "\n");
 539         if(_minspeed < wc)
 540         {
 541             float take = min(_speedfac * wc, _maxpain);
 542             Damage (self, world, world, take, DEATH_FALL, self.origin, '0 0 0');
 543             self.play_time = time + 0.25;
 544
 545             //dprint("wc: ", ftos(wc), "\n");
 546             //dprint("take: ", ftos(take), "\n");
 547         }
 548     }
 549 }
 550
 551 void vehicles_touch()
 552 {
 553         if(MUTATOR_CALLHOOK(VehicleTouch))
 554                 return;
 555
 556     // Vehicle currently in use
 557     if(self.owner)
 558     {
 559         if(other != world)
 560         if(vehicles_crushable(other))
 561         {
 562             if(vlen(self.velocity) != 0)
 563                 Damage(other, self, self.owner, autocvar_g_vehicles_crush_dmg, DEATH_VH_CRUSH, '0 0 0', normalize(other.origin - self.origin) * autocvar_g_vehicles_crush_force);
 564
 565             return; // Dont do selfdamage when hitting "soft targets".
 566         }
 567
 568         if(self.play_time < time)
 569         if(self.vehicle_impact)
 570             self.vehicle_impact();
 571
 572         return;
 573     }
 574
 575     if (!IS_PLAYER(other))
 576         return;
 577
 578     if(other.deadflag != DEAD_NO)
 579         return;
 580
 581     if(other.vehicle != world)
 582         return;
 583
 584     vehicles_enter();
 585 }
 586 .float monster_attack;
 587 void vehicles_enter()
 588 {
 589    // Remove this when bots know how to use vehicles
 590
 591     if (IS_BOT_CLIENT(other))
 592         if (autocvar_g_vehicles_allow_bots)
 593             dprint("Bot enters vehicle\n"); // This is where we need to disconnect (some, all?) normal bot AI and hand over to vehicle's _aiframe()
 594         else
 595             return;
 596
 597     if(self.phase > time)
 598         return;
 599     if(other.frozen)
 600         return;
 601     if(other.vehicle)
 602         return;
 603     if(other.deadflag != DEAD_NO)
 604         return;
 605
 606     if(teamplay)
 607     if(self.team)
 608     if(self.team != other.team)
 609         return;
 610
 611     RemoveGrapplingHook(other);
 612
 613     self.vehicle_ammo1   = 0;
 614     self.vehicle_ammo2   = 0;
 615     self.vehicle_reload1 = 0;
 616     self.vehicle_reload2 = 0;
 617     self.vehicle_energy  = 0;
 618
 619     self.owner          = other;
 620     self.switchweapon   = other.switchweapon;
 621
 622     // .viewmodelforclient works better.
 623     //self.vehicle_hudmodel.drawonlytoclient = self.owner;
 624
 625     self.vehicle_hudmodel.viewmodelforclient = self.owner;
 626
 627     self.event_damage         = vehicles_damage;
 628     self.nextthink            = 0;
 629     self.owner.angles         = self.angles;
 630     self.owner.takedamage     = DAMAGE_NO;
 631     self.owner.solid          = SOLID_NOT;
 632     self.owner.movetype       = MOVETYPE_NOCLIP;
 633     self.owner.alpha          = -1;
 634     self.owner.vehicle        = self;
 635     self.owner.event_damage   = func_null;
 636     self.owner.view_ofs       = '0 0 0';
 637     self.colormap             = self.owner.colormap;
 638     if(self.tur_head)
 639         self.tur_head.colormap    = self.owner.colormap;
 640
 641     self.owner.hud            = self.hud;
 642     self.owner.PlayerPhysplug = self.PlayerPhysplug;
 643
 644     self.owner.vehicle_ammo1    = self.vehicle_ammo1;
 645     self.owner.vehicle_ammo2    = self.vehicle_ammo2;
 646     self.owner.vehicle_reload1  = self.vehicle_reload1;
 647     self.owner.vehicle_reload2  = self.vehicle_reload2;
 648
 649     // Cant do this, hides attached objects too.
 650     //self.exteriormodeltoclient = self.owner;
 651     //self.tur_head.exteriormodeltoclient = self.owner;
 652
 653     other.flags &= ~FL_ONGROUND;
 654     self.flags  &= ~FL_ONGROUND;
 655
 656     self.team                 = self.owner.team;
 657     self.flags               -= FL_NOTARGET;
 658     self.monster_attack       = true;
 659
 660     if (IS_REAL_CLIENT(other))
 661     {
 662         msg_entity = other;
 663         WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 664         WriteEntity(MSG_ONE, self.vehicle_viewport);
 665
 666         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 667         if(self.tur_head)
 668         {
 669             WriteAngle(MSG_ONE, self.tur_head.angles.x + self.angles.x); // tilt
 670             WriteAngle(MSG_ONE, self.tur_head.angles.y + self.angles.y); // yaw
 671             WriteAngle(MSG_ONE, 0);                                      // roll
 672         }
 673         else
 674         {
 675             WriteAngle(MSG_ONE,  self.angles.x * -1); // tilt
 676             WriteAngle(MSG_ONE,  self.angles.y);      // yaw
 677             WriteAngle(MSG_ONE,  0);                  // roll
 678         }
 679     }
 680
 681     vehicles_clearreturn();
 682
 683     CSQCVehicleSetup(self.owner, self.hud);
 684
 685     vh_player = other;
 686     vh_vehicle = self;
 687     MUTATOR_CALLHOOK(VehicleEnter);
 688     other = vh_player;
 689     self = vh_vehicle;
 690
 691     self.vehicle_enter();
 692     antilag_clear(other);
 693 }
 694
 695 /** vehicles_findgoodexit
 696     Locates a valid location for the player to exit the vehicle.
 697     Will first try prefer_spot, then up 100 random spots arround the vehicle
 698     wich are in direct line of sight and empty enougth to hold a players bbox
 699 **/
 700 vector vehicles_findgoodexit(vector prefer_spot)
 701 {
 702     //vector exitspot;
 703     float mysize;
 704
 705     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, prefer_spot, MOVE_NORMAL, self.owner);
 706     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 707         return prefer_spot;
 708
 709     mysize = 1.5 * vlen(self.maxs - self.mins);
 710     float i;
 711     vector v, v2;
 712     v2 = 0.5 * (self.absmin + self.absmax);
 713     for(i = 0; i < 100; ++i)
 714     {
 715         v = randomvec();
 716         v.z = 0;
 717         v = v2 + normalize(v) * mysize;
 718         tracebox(v2, PL_MIN, PL_MAX, v, MOVE_NORMAL, self.owner);
 719         if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 720             return v;
 721     }
 722
 723     /*
 724     exitspot = (self.origin + '0 0 48') + v_forward * mysize;
 725     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 726     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 727         return exitspot;
 728
 729     exitspot = (self.origin + '0 0 48') - v_forward * mysize;
 730     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 731     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 732         return exitspot;
 733
 734     exitspot = (self.origin + '0 0 48') + v_right * mysize;
 735     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 736     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 737         return exitspot;
 738
 739     exitspot = (self.origin + '0 0 48') - v_right * mysize;
 740     tracebox(self.origin + '0 0 32', PL_MIN, PL_MAX, exitspot, MOVE_NORMAL, self.owner);
 741     if(trace_fraction == 1.0 && !trace_startsolid && !trace_allsolid)
 742         return exitspot;
 743     */
 744
 745     return self.origin;
 746 }
 747
 748 /** vehicles_exit
 749     Standarrd vehicle release fucntion.
 750     custom code goes in self.vehicle_exit
 751 **/
 752 float vehicles_exit_running;
 753 void vehicles_exit(float eject)
 754 {
 755     entity _vehicle;
 756     entity _player;
 757     entity _oldself = self;
 758
 759     if(vehicles_exit_running)
 760     {
 761         dprint("^1vehicles_exit allready running! this is not good..\n");
 762         return;
 763     }
 764
 765     vehicles_exit_running = true;
 766     if(IS_CLIENT(self))
 767     {
 768         _vehicle = self.vehicle;
 769
 770         if (_vehicle.vehicle_flags & VHF_PLAYERSLOT)
 771         {
 772             _vehicle.vehicle_exit(eject);
 773             self = _oldself;
 774             vehicles_exit_running = false;
 775             return;
 776         }
 777     }
 778     else
 779         _vehicle = self;
 780
 781     _player = _vehicle.owner;
 782
 783     self = _vehicle;
 784
 785     if (_player)
 786     {
 787         if (IS_REAL_CLIENT(_player))
 788         {
 789             msg_entity = _player;
 790             WriteByte (MSG_ONE, SVC_SETVIEWPORT);
 791             WriteEntity( MSG_ONE, _player);
 792
 793             WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
 794             WriteAngle(MSG_ONE, 0);
 795             WriteAngle(MSG_ONE, _vehicle.angles.y);
 796             WriteAngle(MSG_ONE, 0);
 797         }
 798
 799         setsize(_player, PL_MIN,PL_MAX);
 800
 801         _player.takedamage     = DAMAGE_AIM;
 802         _player.solid          = SOLID_SLIDEBOX;
 803         _player.movetype       = MOVETYPE_WALK;
 804         _player.effects        &= ~EF_NODRAW;
 805         _player.alpha          = 1;
 806         _player.PlayerPhysplug = func_null;
 807         _player.vehicle        = world;
 808         _player.view_ofs       = PL_VIEW_OFS;
 809         _player.event_damage   = PlayerDamage;
 810         _player.hud            = HUD_NORMAL;
 811         _player.switchweapon   = _vehicle.switchweapon;
 812
 813         CSQCVehicleSetup(_player, HUD_NORMAL);
 814     }
 815     _vehicle.flags |= FL_NOTARGET;
 816
 817     if(_vehicle.deadflag == DEAD_NO)
 818         _vehicle.avelocity          = '0 0 0';
 819
 820     _vehicle.tur_head.nodrawtoclient             = world;
 821
 822     if(!teamplay)
 823         _vehicle.team = 0;
 824
 825     vh_player = _player;
 826     vh_vehicle = _vehicle;
 827     MUTATOR_CALLHOOK(VehicleExit);
 828     _player = vh_player;
 829     _vehicle = vh_vehicle;
 830
 831     _vehicle.team = _vehicle.tur_head.team;
 832
 833     sound (_vehicle, CH_TRIGGER_SINGLE, "misc/null.wav", 1, ATTEN_NORM);
 834     _vehicle.vehicle_hudmodel.viewmodelforclient = _vehicle;
 835     _vehicle.phase = time + 1;
 836     _vehicle.monster_attack = false;
 837
 838     _vehicle.vehicle_exit(eject);
 839
 840     vehicles_setreturn();
 841     vehicles_reset_colors();
 842     _vehicle.owner = world;
 843     self = _oldself;
 844
 845     vehicles_exit_running = false;
 846 }
 847
 848
 849 void vehicles_regen(float timer, .float regen_field, float field_max, float rpause, float regen, float delta_time, float _healthscale)
 850 {
 851     if (self.(regen_field) < field_max)
 852     if (timer + rpause < time)
 853     {
 854         if (_healthscale)
 855             regen = regen * (self.vehicle_health / self.tur_health);
 856
 857         self.(regen_field) = min(self.(regen_field) + regen * delta_time, field_max);
 858
 859         if (self.owner)
 860             self.owner.(regen_field) = (self.(regen_field) / field_max) * 100;
 861     }
 862 }
 863
 864 void shieldhit_think()
 865 {
 866     self.alpha -= 0.1;
 867     if (self.alpha <= 0)
 868     {
 869         //setmodel(self, "");
 870         self.alpha = -1;
 871         self.effects |= EF_NODRAW;
 872     }
 873     else
 874     {
 875         self.nextthink = time + 0.1;
 876     }
 877 }
 878
 879 void vehicles_painframe()
 880 {
 881     if(self.owner.vehicle_health <= 50)
 882     if(self.pain_frame < time)
 883     {
 884         float _ftmp;
 885         _ftmp = self.owner.vehicle_health / 50;
 886         self.pain_frame = time + 0.1 + (random() * 0.5 * _ftmp);
 887         pointparticles(particleeffectnum("smoke_small"), (self.origin + (randomvec() * 80)), '0 0 0', 1);
 888
 889         if(self.vehicle_flags & VHF_DMGSHAKE)
 890             self.velocity += randomvec() * 30;
 891
 892         if(self.vehicle_flags & VHF_DMGROLL)
 893             if(self.vehicle_flags & VHF_DMGHEADROLL)
 894                 self.tur_head.angles += randomvec();
 895             else
 896                 self.angles += randomvec();
 897
 898     }
 899 }
 900
 901 void vehicles_damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 902 {
 903     self.dmg_time = time;
 904
 905         // WEAPONTODO
 906     if(DEATH_ISWEAPON(deathtype, WEP_VORTEX))
 907         damage *= autocvar_g_vehicles_vortex_damagerate;
 908
 909     if(DEATH_ISWEAPON(deathtype, WEP_MACHINEGUN))
 910         damage *= autocvar_g_vehicles_machinegun_damagerate;
 911
 912     if(DEATH_ISWEAPON(deathtype, WEP_RIFLE))
 913         damage *= autocvar_g_vehicles_rifle_damagerate;
 914
 915     if(DEATH_ISWEAPON(deathtype, WEP_VAPORIZER))
 916         damage *= autocvar_g_vehicles_vaporizer_damagerate;
 917
 918     if(DEATH_ISWEAPON(deathtype, WEP_SEEKER))
 919         damage *= autocvar_g_vehicles_tag_damagerate;
 920
 921     self.enemy = attacker;
 922
 923     if((self.vehicle_flags & VHF_HASSHIELD) && (self.vehicle_shield > 0))
 924     {
 925         if (wasfreed(self.vehicle_shieldent) || self.vehicle_shieldent == world)
 926         {
 927             self.vehicle_shieldent = spawn();
 928             self.vehicle_shieldent.effects = EF_LOWPRECISION;
 929
 930             setmodel(self.vehicle_shieldent, "models/vhshield.md3");
 931             setattachment(self.vehicle_shieldent, self, "");
 932             setorigin(self.vehicle_shieldent, real_origin(self) - self.origin);
 933             self.vehicle_shieldent.scale       = 256 / vlen(self.maxs - self.mins);
 934             self.vehicle_shieldent.think       = shieldhit_think;
 935         }
 936
 937         self.vehicle_shieldent.colormod    = '1 1 1';
 938         self.vehicle_shieldent.alpha       = 0.45;
 939         self.vehicle_shieldent.angles      = vectoangles(normalize(hitloc - (self.origin + self.vehicle_shieldent.origin))) - self.angles;
 940         self.vehicle_shieldent.nextthink   = time;
 941         self.vehicle_shieldent.effects &= ~EF_NODRAW;
 942
 943         self.vehicle_shield -= damage;
 944
 945         if(self.vehicle_shield < 0)
 946         {
 947             self.vehicle_health            -= fabs(self.vehicle_shield);
 948             self.vehicle_shieldent.colormod = '2 0 0';
 949             self.vehicle_shield             = 0;
 950             self.vehicle_shieldent.alpha    = 0.75;
 951
 952                 if(sound_allowed(MSG_BROADCAST, attacker))
 953                 spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);   // FIXME: PLACEHOLDER
 954         }
 955         else
 956                 if(sound_allowed(MSG_BROADCAST, attacker))
 957                 spamsound (self, CH_PAIN, "onslaught/electricity_explode.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 958
 959     }
 960     else
 961     {
 962         self.vehicle_health -= damage;
 963
 964         if(sound_allowed(MSG_BROADCAST, attacker))
 965             spamsound (self, CH_PAIN, "onslaught/ons_hit2.wav", VOL_BASE, ATTEN_NORM);  // FIXME: PLACEHOLDER
 966     }
 967
 968         if(self.damageforcescale < 1 && self.damageforcescale > 0)
 969                 self.velocity += force * self.damageforcescale;
 970         else
 971                 self.velocity += force;
 972
 973     if(self.vehicle_health <= 0)
 974     {
 975         if(self.owner)
 976             if(self.vehicle_flags & VHF_DEATHEJECT)
 977                 vehicles_exit(VHEF_EJECT);
 978             else
 979                 vehicles_exit(VHEF_RELESE);
 980
 981
 982         antilag_clear(self);
 983
 984         self.vehicle_die();
 985         vehicles_setreturn();
 986     }
 987 }
 988
 989 void vehicles_clearreturn()
 990 {
 991     entity ret;
 992     // Remove "return helper", if any.
 993     ret = findchain(classname, "vehicle_return");
 994     while(ret)
 995     {
 996         if(ret.wp00 == self)
 997         {
 998             ret.classname   = "";
 999             ret.think       = SUB_Remove;
1000             ret.nextthink   = time + 0.1;
1001
1002             if(ret.waypointsprite_attached)
1003                 WaypointSprite_Kill(ret.waypointsprite_attached);
1004
1005             return;
1006         }
1007         ret = ret.chain;
1008     }
1009 }
1010
1011 void vehicles_return()
1012 {
1013     pointparticles(particleeffectnum("teleport"), self.wp00.origin + '0 0 64', '0 0 0', 1);
1014
1015     self.wp00.think     = vehicles_spawn;
1016     self.wp00.nextthink = time;
1017
1018     if(self.waypointsprite_attached)
1019         WaypointSprite_Kill(self.waypointsprite_attached);
1020
1021     remove(self);
1022 }
1023
1024 void vehicles_showwp_goaway()
1025 {
1026     if(self.waypointsprite_attached)
1027         WaypointSprite_Kill(self.waypointsprite_attached);
1028
1029     remove(self);
1030
1031 }
1032
1033 void vehicles_showwp()
1034 {
1035     entity oldself = world;
1036     vector rgb;
1037
1038     if(self.cnt)
1039     {
1040         self.think      = vehicles_return;
1041         self.nextthink  = self.cnt;
1042     }
1043     else
1044     {
1045         self.think      = vehicles_return;
1046         self.nextthink  = time +1;
1047
1048         oldself = self;
1049         self = spawn();
1050         setmodel(self, "null");
1051         self.team = oldself.wp00.team;
1052         self.wp00 = oldself.wp00;
1053         setorigin(self, oldself.wp00.pos1);
1054
1055         self.nextthink = time + 5;
1056         self.think = vehicles_showwp_goaway;
1057     }
1058
1059     if(teamplay && self.team)
1060             rgb = Team_ColorRGB(self.team);
1061     else
1062             rgb = '1 1 1';
1063     WaypointSprite_Spawn("vehicle", 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
1064     if(self.waypointsprite_attached)
1065     {
1066         WaypointSprite_UpdateRule(self.waypointsprite_attached, self.wp00.team, SPRITERULE_DEFAULT);
1067         if(oldself == world)
1068             WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, self.nextthink);
1069         WaypointSprite_Ping(self.waypointsprite_attached);
1070     }
1071
1072     if(oldself != world)
1073         self = oldself;
1074 }
1075
1076 void vehicles_setreturn()
1077 {
1078     entity ret;
1079
1080     vehicles_clearreturn();
1081
1082     ret = spawn();
1083     ret.classname   = "vehicle_return";
1084     ret.wp00       = self;
1085     ret.team        = self.team;
1086     ret.think       = vehicles_showwp;
1087
1088         if(self.deadflag != DEAD_NO)
1089         {
1090                 ret.cnt = max(game_starttime, time) + self.vehicle_respawntime;
1091                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 5);
1092         }
1093         else
1094                 ret.nextthink = max(game_starttime, time) + max(0, self.vehicle_respawntime - 1);
1095
1096     setmodel(ret, "null");
1097     setorigin(ret, self.pos1 + '0 0 96');
1098 }
1099
1100 void vehicles_reset_colors()
1101 {
1102     entity e;
1103     float _effects = 0, _colormap;
1104     vector _glowmod, _colormod;
1105
1106     if(autocvar_g_nodepthtestplayers)
1107         _effects |= EF_NODEPTHTEST;
1108
1109     if(autocvar_g_fullbrightplayers)
1110         _effects |= EF_FULLBRIGHT;
1111
1112     if(self.team)
1113         _colormap = 1024 + (self.team - 1) * 17;
1114     else
1115         _colormap = 1024;
1116
1117     _glowmod  = '0 0 0';
1118     _colormod = '0 0 0';
1119
1120     // Find all ents attacked to main model and setup effects, colormod etc.
1121     e = findchainentity(tag_entity, self);
1122     while(e)
1123     {
1124         if(e != self.vehicle_shieldent)
1125         {
1126             e.effects   = _effects; //  | EF_LOWPRECISION;
1127             e.colormod  = _colormod;
1128             e.colormap  = _colormap;
1129             e.alpha     = 1;
1130         }
1131         e = e.chain;
1132     }
1133
1134     self.vehicle_hudmodel.effects  = self.effects  = _effects; // | EF_LOWPRECISION;
1135     self.vehicle_hudmodel.colormod = self.colormod = _colormod;
1136     self.vehicle_hudmodel.colormap = self.colormap = _colormap;
1137     self.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1138
1139     self.alpha     = 1;
1140     self.avelocity = '0 0 0';
1141     self.velocity  = '0 0 0';
1142     self.effects   = _effects;
1143 }
1144
1145 void vehicle_use()
1146 {
1147     dprint("vehicle ",self.netname, " used by ", activator.classname, "\n");
1148
1149     self.tur_head.team = activator.team;
1150
1151     if(self.tur_head.team == 0)
1152         self.active = ACTIVE_NOT;
1153     else
1154         self.active = ACTIVE_ACTIVE;
1155
1156     if(self.active == ACTIVE_ACTIVE && self.deadflag == DEAD_NO)
1157     {
1158         dprint("^3Eat shit yall!\n");
1159         vehicles_setreturn();
1160         vehicles_reset_colors();
1161     }
1162     else if(self.active == ACTIVE_NOT && self.deadflag != DEAD_NO)
1163     {
1164
1165     }
1166 }
1167
1168 float vehicle_addplayerslot(    entity _owner,
1169                                 entity _slot,
1170                                 float _hud,
1171                                 string _hud_model,
1172                                 float() _framefunc,
1173                                 void(float) _exitfunc)
1174 {
1175     if (!(_owner.vehicle_flags & VHF_MULTISLOT))
1176         _owner.vehicle_flags |= VHF_MULTISLOT;
1177
1178     _slot.PlayerPhysplug = _framefunc;
1179     _slot.vehicle_exit = _exitfunc;
1180     _slot.hud = _hud;
1181     _slot.vehicle_flags = VHF_PLAYERSLOT;
1182     _slot.vehicle_viewport = spawn();
1183     _slot.vehicle_hudmodel = spawn();
1184     _slot.vehicle_hudmodel.viewmodelforclient = _slot;
1185     _slot.vehicle_viewport.effects = (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NOGUNBOB | EF_NOSHADOW | EF_LOWPRECISION | EF_SELECTABLE | EF_TELEPORT_BIT);
1186
1187     setmodel(_slot.vehicle_hudmodel, _hud_model);
1188     setmodel(_slot.vehicle_viewport, "null");
1189
1190     setattachment(_slot.vehicle_hudmodel, _slot, "");
1191     setattachment(_slot.vehicle_viewport, _slot.vehicle_hudmodel, "");
1192
1193     return true;
1194 }
1195
1196 float vehicle_initialize(string  net_name,
1197                          string  bodymodel,
1198                          string  topmodel,
1199                          string  hudmodel,
1200                          string  toptag,
1201                          string  hudtag,
1202                          string  viewtag,
1203                          float   vhud,
1204                          vector  min_s,
1205                          vector  max_s,
1206                          float   nodrop,
1207                          void(float _spawnflag)  spawnproc,
1208                          float   _respawntime,
1209                          float() physproc,
1210                          void()  enterproc,
1211                          void(float extflag) exitfunc,
1212                          void() dieproc,
1213                          void() thinkproc,
1214                          float  use_csqc,
1215                          float _max_health,
1216                          float _max_shield)
1217 {
1218         if(!autocvar_g_vehicles)
1219                 return false;
1220
1221     if(self.targetname)
1222     {
1223         self.vehicle_controller = find(world, target, self.targetname);
1224         if(!self.vehicle_controller)
1225         {
1226             bprint("^1WARNING: ^7Vehicle with invalid .targetname\n");
1227         }
1228         else
1229         {
1230             self.team = self.vehicle_controller.team;
1231             self.use = vehicle_use;
1232
1233             if(teamplay)
1234             {
1235                 if(self.vehicle_controller.team == 0)
1236                     self.active = ACTIVE_NOT;
1237                 else
1238                     self.active = ACTIVE_ACTIVE;
1239             }
1240         }
1241     }
1242
1243     precache_sound("onslaught/ons_hit2.wav");
1244     precache_sound("onslaught/electricity_explode.wav");
1245
1246
1247     addstat(STAT_HUD, AS_INT,  hud);
1248         addstat(STAT_VEHICLESTAT_HEALTH,  AS_INT, vehicle_health);
1249         addstat(STAT_VEHICLESTAT_SHIELD,  AS_INT, vehicle_shield);
1250         addstat(STAT_VEHICLESTAT_ENERGY,  AS_INT, vehicle_energy);
1251
1252         addstat(STAT_VEHICLESTAT_AMMO1,   AS_INT, vehicle_ammo1);
1253         addstat(STAT_VEHICLESTAT_RELOAD1, AS_INT, vehicle_reload1);
1254
1255         addstat(STAT_VEHICLESTAT_AMMO2,   AS_INT, vehicle_ammo2);
1256         addstat(STAT_VEHICLESTAT_RELOAD2, AS_INT, vehicle_reload2);
1257
1258     if(bodymodel == "")
1259         error("vehicles: missing bodymodel!");
1260
1261     if(hudmodel == "")
1262         error("vehicles: missing hudmodel!");
1263
1264     if(net_name == "")
1265         self.netname = self.classname;
1266     else
1267         self.netname = net_name;
1268
1269     if(self.team && !teamplay)
1270         self.team = 0;
1271
1272     self.vehicle_flags |= VHF_ISVEHICLE;
1273
1274     setmodel(self, bodymodel);
1275
1276     self.vehicle_viewport   = spawn();
1277     self.vehicle_hudmodel   = spawn();
1278     self.tur_head           = spawn();
1279     self.tur_head.owner     = self;
1280     self.takedamage         = DAMAGE_AIM;
1281     self.bot_attack         = true;
1282     self.iscreature         = true;
1283     self.teleportable       = false; // no teleporting for vehicles, too buggy
1284     self.damagedbycontents      = true;
1285     self.hud                = vhud;
1286     self.tur_health          = _max_health;
1287     self.tur_head.tur_health = _max_shield;
1288     self.vehicle_die         = dieproc;
1289     self.vehicle_exit        = exitfunc;
1290     self.vehicle_enter       = enterproc;
1291     self.PlayerPhysplug      = physproc;
1292     self.event_damage        = func_null;
1293     self.touch               = vehicles_touch;
1294     self.think               = vehicles_spawn;
1295     self.vehicle_spawn       = spawnproc;
1296         self.vehicle_respawntime = max(0, _respawntime);
1297     self.effects             = EF_NODRAW;
1298         self.dphitcontentsmask   = DPCONTENTS_BODY | DPCONTENTS_SOLID;
1299         if(!autocvar_g_vehicles_delayspawn || !self.vehicle_respawntime)
1300                 self.nextthink = time;
1301         else
1302                 self.nextthink = max(time, game_starttime) + max(0, self.vehicle_respawntime + ((random() * 2 - 1) * autocvar_g_vehicles_delayspawn_jitter));
1303
1304         if(autocvar_g_playerclip_collisions)
1305                 self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
1306
1307     if(autocvar_g_nodepthtestplayers)
1308         self.effects = self.effects | EF_NODEPTHTEST;
1309
1310     if(autocvar_g_fullbrightplayers)
1311         self.effects = self.effects | EF_FULLBRIGHT;
1312
1313     setmodel(self.vehicle_hudmodel, hudmodel);
1314     setmodel(self.vehicle_viewport, "null");
1315
1316     if(topmodel != "")
1317     {
1318         setmodel(self.tur_head, topmodel);
1319         setattachment(self.tur_head, self, toptag);
1320         setattachment(self.vehicle_hudmodel, self.tur_head, hudtag);
1321         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1322     }
1323     else
1324     {
1325         setattachment(self.tur_head, self, "");
1326         setattachment(self.vehicle_hudmodel, self, hudtag);
1327         setattachment(self.vehicle_viewport, self.vehicle_hudmodel, viewtag);
1328     }
1329
1330     setsize(self, min_s, max_s);
1331     if (!nodrop)
1332     {
1333         setorigin(self, self.origin);
1334         tracebox(self.origin + '0 0 100', min_s, max_s, self.origin - '0 0 10000', MOVE_WORLDONLY, self);
1335         setorigin(self, trace_endpos);
1336     }
1337
1338     self.pos1 = self.origin;
1339     self.pos2 = self.angles;
1340     self.tur_head.team = self.team;
1341
1342         if(MUTATOR_CALLHOOK(VehicleSpawn))
1343                 return false;
1344
1345     return true;
1346 }
1347
1348 vector vehicle_aimturret(entity _vehic, vector _target, entity _turrret, string _tagname,
1349                          float _pichlimit_min, float _pichlimit_max,
1350                          float _rotlimit_min, float _rotlimit_max, float _aimspeed)
1351 {
1352     vector vtmp, vtag;
1353     float ftmp;
1354     vtag = gettaginfo(_turrret, gettagindex(_turrret, _tagname));
1355     vtmp = vectoangles(normalize(_target - vtag));
1356     vtmp = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(_vehic.angles), AnglesTransform_FromAngles(vtmp))) - _turrret.angles;
1357     vtmp = AnglesTransform_Normalize(vtmp, true);
1358     ftmp = _aimspeed * frametime;
1359     vtmp.y = bound(-ftmp, vtmp.y, ftmp);
1360     vtmp.x = bound(-ftmp, vtmp.x, ftmp);
1361     _turrret.angles_y = bound(_rotlimit_min, _turrret.angles.y + vtmp.y, _rotlimit_max);
1362     _turrret.angles_x = bound(_pichlimit_min, _turrret.angles.x + vtmp.x, _pichlimit_max);
1363     return vtag;
1364 }
1365
1366 void vehicles_gib_explode()
1367 {
1368         sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTEN_NORM);
1369         pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
1370         remove(self);
1371 }
1372
1373 void vehicles_gib_think()
1374 {
1375         self.alpha -= 0.1;
1376         if(self.cnt >= time)
1377                 remove(self);
1378         else
1379                 self.nextthink = time + 0.1;
1380 }
1381
1382 entity vehicle_tossgib(entity _template, vector _vel, string _tag, float _burn, float _explode, float _maxtime, vector _rot)
1383 {
1384         entity _gib = spawn();
1385         setmodel(_gib, _template.model);
1386         setorigin(_gib, gettaginfo(self, gettagindex(self, _tag)));
1387         _gib.velocity = _vel;
1388         _gib.movetype = MOVETYPE_TOSS;
1389         _gib.solid = SOLID_CORPSE;
1390         _gib.colormod = '-0.5 -0.5 -0.5';
1391         _gib.effects = EF_LOWPRECISION;
1392         _gib.avelocity = _rot;
1393
1394         if(_burn)
1395                 _gib.effects |= EF_FLAME;
1396
1397         if(_explode)
1398         {
1399                 _gib.think = vehicles_gib_explode;
1400                 _gib.nextthink = time + random() * _explode;
1401                 _gib.touch = vehicles_gib_explode;
1402         }
1403         else
1404         {
1405                 _gib.cnt = time + _maxtime;
1406                 _gib.think = vehicles_gib_think;
1407                 _gib.nextthink = time + _maxtime - 1;
1408                 _gib.alpha = 1;
1409         }
1410         return _gib;
1411 }
1412
1413 /*
1414 vector predict_target(entity _targ, vector _from, float _shot_speed)
1415 {
1416     float i;                // loop
1417     float _distance;        // How far to target
1418     float _impact_time;     // How long untill projectile impacts
1419     vector _predict_pos;    // Predicted enemy location
1420     vector _original_origin;// Where target is before predicted
1421
1422      _original_origin = real_origin(_targ); // Typicaly center of target BBOX
1423
1424     _predict_pos = _original_origin;
1425     for(i = 0; i < 4; ++i)  // Loop a few times to increase prediction accuracy (increase loop count if accuracy is to low)
1426     {
1427         _distance = vlen(_predict_pos - _from); // Get distance to previos predicted location
1428         _impact_time = _distance / _shot_speed; // Calculate impact time
1429         _predict_pos = _original_origin + _targ.velocity * _impact_time; // Calculate new predicted location
1430     }
1431
1432     return _predict_pos;
1433 }
1434 */