qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 #ifdef SVQC
   5 float autocvar_g_vehicle_spiderbot_respawntime;
   6
   7 float autocvar_g_vehicle_spiderbot_speed_stop;
   8 float autocvar_g_vehicle_spiderbot_speed_strafe;
   9 float autocvar_g_vehicle_spiderbot_speed_walk;
  10 float autocvar_g_vehicle_spiderbot_turnspeed;
  11 float autocvar_g_vehicle_spiderbot_movement_inertia;
  12
  13 float autocvar_g_vehicle_spiderbot_springlength;
  14 float autocvar_g_vehicle_spiderbot_springup;
  15 float autocvar_g_vehicle_spiderbot_springblend;
  16
  17 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  18 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  19 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  20 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  21 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  22
  23 //float autocvar_g_vehicle_spiderbot_energy;
  24 //float autocvar_g_vehicle_spiderbot_energy_regen;
  25 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  26
  27 float autocvar_g_vehicle_spiderbot_health;
  28 float autocvar_g_vehicle_spiderbot_health_regen;
  29 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  30
  31 float autocvar_g_vehicle_spiderbot_shield;
  32 float autocvar_g_vehicle_spiderbot_shield_regen;
  33 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  34
  35 float autocvar_g_vehicle_spiderbot_minigun_damage;
  36 float autocvar_g_vehicle_spiderbot_minigun_refire;
  37 float autocvar_g_vehicle_spiderbot_minigun_spread;
  38 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  39 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  40 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  41 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_force;
  45 float autocvar_g_vehicle_spiderbot_rocket_radius;
  46 float autocvar_g_vehicle_spiderbot_rocket_speed;
  47 float autocvar_g_vehicle_spiderbot_rocket_refire;
  48 float autocvar_g_vehicle_spiderbot_rocket_reload;
  49 float autocvar_g_vehicle_spiderbot_rocket_health;
  50 float autocvar_g_vehicle_spiderbot_rocket_noise;
  51 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  52 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  53
  54 void spiderbot_exit(float eject);
  55 void spiderbot_enter();
  56 void spiderbot_spawn();
  57
  58 void spiderbot_rocket_unguided()
  59 {
  60     vector newdir, olddir;
  61
  62     self.nextthink  = time;
  63
  64     olddir = normalize(self.velocity);
  65     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  66     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  67
  68     UpdateCSQCProjectile(self);
  69
  70     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  71         self.use();
  72 }
  73
  74 void spiderbot_rocket_guided()
  75 {
  76     vector newdir, olddir;
  77
  78     self.nextthink  = time;
  79
  80     if not (self.realowner.vehicle)
  81         self.think = spiderbot_rocket_unguided;
  82
  83     crosshair_trace(self.realowner);
  84     olddir = normalize(self.velocity);
  85     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  86     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  87
  88     UpdateCSQCProjectile(self);
  89
  90     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  91         self.use();
  92 }
  93
  94 void spiderbot_guide_release()
  95 {
  96     entity rkt;
  97     rkt = findchainentity(realowner, self.owner);
  98     if not (rkt)
  99         return;
 100
 101     crosshair_trace(self.owner);
 102     while(rkt)
 103     {
 104         if(rkt.think == spiderbot_rocket_guided)
 105         {
 106             rkt.pos1 = trace_endpos;
 107             rkt.think = spiderbot_rocket_unguided;
 108         }
 109         rkt = rkt.chain;
 110     }
 111 }
 112
 113 void spiderbot_rocket_do()
 114 {
 115
 116     vector v;
 117     entity rocket;
 118
 119     if (self.owner.BUTTON_ATCK2)
 120     {
 121         if (self.wait == 1)
 122         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 123         {
 124             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 125                 self.tur_head.frame = 1;
 126
 127             return;
 128         }
 129         self.wait = 1;
 130     }
 131     else
 132     {
 133         if(self.wait)
 134             spiderbot_guide_release();
 135
 136         self.wait = 0;
 137     }
 138
 139     if(self.gun2.cnt > time)
 140         return;
 141
 142     if (self.tur_head.frame >= 9)
 143         self.tur_head.frame = 1;
 144
 145     if not (self.owner.BUTTON_ATCK2)
 146         return;
 147
 148     crosshair_trace(self.owner);
 149
 150     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 151     rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 152                            v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 153                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 154                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE);
 155
 156     rocket.cnt        = time + 15;
 157     rocket.classname  = "spiderbot_rocket";
 158     rocket.pos1       = trace_endpos;
 159     rocket.think      = spiderbot_rocket_guided;
 160     rocket.nextthink  = time;
 161     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 162
 163     self.tur_head.frame += 1;
 164     if (self.tur_head.frame == 9)
 165         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 166     else
 167         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 168
 169     self.gun2.cnt = time + self.attack_finished_single;
 170 }
 171
 172 float spiderbot_frame()
 173 {
 174     vector ad;
 175     entity player, spider;
 176     float ftmp;
 177
 178     player = self;
 179     spider = self.vehicle;
 180
 181     player.BUTTON_ZOOM      = 0;
 182     player.BUTTON_CROUCH    = 0;
 183     player.switchweapon     = 0;
 184
 185     if(player.BUTTON_USE)
 186     {
 187         self = spider;
 188         vehicles_exit(VHEF_NORMAL);
 189         self = player;
 190         return 0;
 191     }
 192
 193     self = spider;
 194
 195     crosshair_trace(player);
 196     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 197
 198 #if VEHICLES_VIEWROTATE_CROSSHAIR
 199     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 200     if(ad_x > 180) ad_x -= 360;
 201     if(ad_x < -180) ad_x += 360;
 202     if(ad_y > 180) ad_y -= 360;
 203     if(ad_y < -180) ad_y += 360;
 204
 205     // Rotate head
 206     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 207     ad_y = bound(-ftmp, ad_y, ftmp);
 208     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 209
 210     // Pitch head
 211     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 212     //ad_x = bound(-ftmp, ad_x, ftmp);
 213     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 214
 215     // Turn Body
 216     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 217     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 218 #else
 219
 220     player.v_angle_x *= -1;
 221     ad = player.v_angle - (spider.tur_head.angles + spider.angles);
 222     player.v_angle_x *= -1;
 223     if(ad_x > 180)  ad_x -= 360;
 224     if(ad_x < -180) ad_x += 360;
 225     if(ad_y > 180)  ad_y -= 360;
 226     if(ad_y < -180) ad_y += 360;
 227
 228     // Rotate head
 229     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 230     ad_y = bound(-ftmp, ad_y, ftmp);
 231     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 232
 233     // Pitch head
 234 #if 0 // Enable to pich by cross-trace (more precise in chase, but less predictable)
 235     ad = vectoangles(normalize(trace_endpos - gettaginfo(spider.tur_head,gettagindex(spider.tur_head,"tag_hud")))) - (spider.tur_head.angles + spider.angles);
 236     if(ad_x > 180) ad_x -= 360;
 237     if(ad_x < -180) ad_x += 360;
 238 #endif
 239     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 240     ad_x = bound(ftmp * -1, ad_x, ftmp);
 241     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 242
 243     // Turn Body
 244     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 245     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 246
 247 #endif
 248     makevectors(spider.angles + '-2 0 0' * spider.angles_x);
 249
 250 /*
 251     vector ofs;
 252     ofs = self.origin + v_up * 128;
 253     te_lightning1(world, ofs, ofs + v_up * 32);
 254     te_lightning1(world, ofs, ofs + v_right * 128);
 255     te_lightning1(world, ofs, ofs + v_forward * 256);
 256 */
 257
 258     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 259
 260     if(spider.flags & FL_ONGROUND)
 261     {
 262         if(spider.frame == 4 && self.tur_head.wait != 0)
 263         {
 264             sound (self, CHAN_VOICE, "vehicles/spiderbot_land.wav", VOL_BASE, ATTN_NORM);
 265             spider.frame = 5;
 266         }
 267
 268         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 269         {
 270             sound (self, CHAN_VOICE, "vehicles/spiderbot_jump.wav", VOL_BASE, ATTN_NORM);
 271             //dprint("spiderbot_jump:", ftos(soundlength("vehicles/spiderbot_jump.wav")), "\n");
 272             self.delay = 0;
 273
 274             self.tur_head.wait = time + 2;
 275             player.BUTTON_JUMP = 0;
 276             spider.velocity   = v_forward * 700 + v_up * 600;
 277             spider.frame = 4;
 278         }
 279         else
 280         {
 281             if(vlen(player.movement) == 0)
 282             {
 283                 if(self.sound_nexttime < time || self.delay != 3)
 284                 {
 285                     self.delay = 3;
 286                     self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_idle.wav");
 287                     //dprint("spiderbot_idle:", ftos(soundlength("vehicles/spiderbot_idle.wav")), "\n");
 288                     sound (self, CHAN_VOICE, "vehicles/spiderbot_idle.wav", VOL_BASE, ATTN_NORM);
 289                 }
 290                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 291                 spider.frame = 5;
 292             }
 293             else
 294             {
 295                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 296                 spider.tur_head.angles_y -= ftmp;
 297
 298                 if(player.movement_x != 0)
 299                 {
 300                     if(player.movement_x > 0)
 301                     {
 302                         player.movement_x = 1;
 303                         spider.frame = 0;
 304                     }
 305                     else if(player.movement_x < 0)
 306                     {
 307                         player.movement_x = -1;
 308                         spider.frame = 1;
 309                     }
 310                     player.movement_y = 0;
 311                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 312
 313                     if(self.sound_nexttime < time || self.delay != 1)
 314                     {
 315                         self.delay = 1;
 316                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_walk.wav");
 317                         sound (self, CHAN_VOICE, "vehicles/spiderbot_walk.wav", VOL_BASE, ATTN_NORM);
 318                         //dprint("spiderbot_walk:", ftos(soundlength("vehicles/spiderbot_walk.wav")), "\n");
 319                     }
 320                 }
 321                 else if(player.movement_y != 0)
 322                 {
 323                     if(player.movement_y < 0)
 324                     {
 325                         player.movement_y = -1;
 326                         spider.frame = 2;
 327                     }
 328                     else if(player.movement_y > 0)
 329                     {
 330                         player.movement_y = 1;
 331                         spider.frame = 3;
 332                     }
 333                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 334                     if(self.sound_nexttime < time || self.delay != 2)
 335                     {
 336                         self.delay = 2;
 337                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_strafe.wav");
 338                         sound (self, CHAN_VOICE, "vehicles/spiderbot_strafe.wav", VOL_BASE, ATTN_NORM);
 339                         //dprint("spiderbot_strafe:", ftos(soundlength("vehicles/spiderbot_strafe.wav")), "\n");
 340                     }
 341                 }
 342             }
 343         }
 344     }
 345
 346     self.angles_x = bound(-45, self.angles_x, 45);
 347     self.angles_z = bound(-45, self.angles_z, 45);
 348
 349     if(player.BUTTON_ATCK)
 350     {
 351         spider.cnt = time;
 352         if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 353         {
 354             entity gun;
 355             vector v;
 356             spider.misc_bulletcounter += 1;
 357
 358             self = player;
 359
 360             mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 361             v = gettaginfo(gun, gettagindex(gun, "barrels"));
 362             v_forward = normalize(v_forward);
 363             v += v_forward * 50;
 364
 365             fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 366                 autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 367
 368             sound (gun, CHAN_WEAPON, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 369             trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 370             pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 371
 372             self = spider;
 373
 374             spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 375             spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 376             player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 377         }
 378     }
 379     else
 380         vehicles_regen(cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 381                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 382                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime);
 383
 384     spiderbot_rocket_do();
 385
 386     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 387         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 388
 389     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 390         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 391
 392     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 393     player.vehicle_ammo2 = spider.tur_head.frame;
 394
 395     if(spider.gun2.cnt <= time)
 396         player.vehicle_reload2 = 100;
 397     else
 398         player.vehicle_reload2 = 100 - ((spider.gun2.cnt - time) / spider.attack_finished_single) * 100;
 399
 400     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 401     player.velocity = spider.velocity;
 402
 403     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 404
 405     if(self.vehicle_flags & VHF_HASSHIELD)
 406         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 407
 408 #if 1 // 0 to enable per-gun impact aux crosshairs
 409     // Avarage gun impact point's -> aux cross
 410     vector vf;
 411     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 412     vf = v_forward;
 413     ad += gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 414     vf += v_forward;
 415     ad = ad * 0.5;
 416     v_forward = vf * 0.5;
 417     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 418     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 419
 420 #else
 421     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 422     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 423     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 424
 425     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 426     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 427     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 428 #endif
 429
 430     self = player;
 431     return 1;
 432 }
 433
 434 void spiderbot_think()
 435 {
 436     if(self.flags & FL_ONGROUND)
 437         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 438
 439     self.nextthink = time;
 440 }
 441
 442 void spiderbot_enter()
 443 {
 444     self.movetype   = MOVETYPE_WALK;
 445     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health);
 446     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield);
 447 }
 448
 449 void spiderbot_exit(float eject)
 450 {
 451     entity e;
 452     vector spot;
 453
 454     e = findchain(classname,"spiderbot_rocket");
 455     while(e)
 456     {
 457         if(e.owner == self.owner)
 458         {
 459             e.realowner = self.owner;
 460             e.owner = world;
 461         }
 462         e = e.chain;
 463     }
 464
 465     self.velocity   = '0 0 0';
 466     self.think      = spiderbot_think;
 467     self.nextthink  = time;
 468     self.frame      = 5;
 469     self.movetype   = MOVETYPE_WALK;
 470
 471     if not (self.owner)
 472         return;
 473
 474         makevectors(self.angles);
 475         if(eject)
 476         {
 477             spot = self.origin + v_forward * 100 + '0 0 64';
 478             spot = vehicles_findgoodexit(spot);
 479             setorigin(self.owner , spot);
 480             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 481         }
 482         else
 483         {
 484             spot = self.origin - v_forward * 200 + '0 0 64';
 485             spot = vehicles_findgoodexit(spot);
 486             setorigin(self.owner , spot);
 487         }
 488
 489     self.owner = world;
 490 }
 491
 492 void spiderbot_spawn()
 493 {
 494     self.frame              = 5;
 495     self.tur_head.frame     = 1;
 496     self.think              = spiderbot_think;
 497     self.nextthink          = time;
 498     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 499     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 500     self.movetype           = MOVETYPE_WALK;
 501     self.solid              = SOLID_SLIDEBOX;
 502     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 503     self.tur_head.angles    = '0 0 0';
 504
 505     setorigin(self, self.pos1 + '0 0 128');
 506     self.angles = self.pos2;
 507 }
 508
 509 void spiderbot_headfade()
 510 {
 511         self.think = spiderbot_headfade;
 512         self.nextthink = self.fade_time;
 513         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 514
 515     if(self.cnt < time || self.alpha < 0.1)
 516     {
 517         if(self.alpha > 0.1)
 518         {
 519             sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 520             pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 521         }
 522         remove(self);
 523     }
 524 }
 525
 526 void spiderbot_blowup()
 527 {
 528     float i;
 529     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 530
 531     for(i = 0; i < 5; ++i)
 532         pointparticles(particleeffectnum("rocket_explode"), self.origin + (randomvec() * 100) + '0 0 100', '0 0 0', 1);
 533
 534     entity h, g1, g2, b;
 535     b = spawn();
 536     h = spawn();
 537     g1 = spawn();
 538     g2 = spawn();
 539
 540     setmodel(b,  "models/vehicles/spiderbot.dpm");
 541     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 542     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 543     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 544
 545     setorigin(b, self.origin);
 546     b.frame         = 11;
 547     b.angles        = self.angles;
 548     setsize(b, self.mins, self.maxs);
 549
 550     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 551     h.movetype      = MOVETYPE_BOUNCE;
 552     h.solid         = SOLID_BBOX;
 553     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 554     h.modelflags    = MF_ROCKET;
 555     h.effects       = EF_FLAME | EF_LOWPRECISION;
 556     h.avelocity     = randomvec() * 360;
 557
 558     h.alpha         = 1;
 559     h.cnt           = time + (3.5 * random());
 560     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 561     h.fade_time     = time;
 562     h.think         = spiderbot_headfade;
 563     h.nextthink     = time;
 564
 565     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 566     g1.movetype     = MOVETYPE_TOSS;
 567     g1.solid        = SOLID_CORPSE;
 568     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 569     g1.avelocity    = randomvec() * 180;
 570
 571     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 572     g2.movetype     = MOVETYPE_TOSS;
 573     g2.solid        = SOLID_CORPSE;
 574     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 575     g2.avelocity    = randomvec() * 180;
 576
 577     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 578
 579     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 580     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 581     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 582     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 583
 584     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 585
 586     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 587     self.movetype   = MOVETYPE_NONE;
 588     self.deadflag   = DEAD_DEAD;
 589     self.solid      = SOLID_NOT;
 590     self.tur_head.effects  &~=  EF_FLAME;
 591         self.vehicle_hudmodel.viewmodelforclient = self;
 592
 593     //self.nextthink  = time + autocvar_g_vehicle_spiderbot_respawntime;
 594     //self.think      = spiderbot_spawn;
 595
 596     //setorigin(self, self.tur_aimpos);
 597 }
 598
 599 void spiderbot_die()
 600 {
 601     sound (self, CHAN_VOICE, "vehicles/spiderbot_die.wav", VOL_BASE, ATTN_NORM);
 602     //sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 603     pointparticles(particleeffectnum("rocket_explode"), self.origin + '0 0 100', '0 0 0', 1);
 604
 605     self.health         = 0;
 606     self.event_damage   = SUB_Null;
 607     self.takedamage     = DAMAGE_NO;
 608     self.touch          = SUB_Null;
 609     self.nextthink      = 3.4 + time + random() * 2;
 610     self.think          = spiderbot_blowup;
 611     self.deadflag       = DEAD_DYING;
 612         self.frame          = 5;
 613         self.tur_head.effects        |= EF_FLAME;
 614         self.colormod = self.tur_head.colormod = '-1 -1 -1';
 615         self.frame = 10;
 616         self.movetype = MOVETYPE_TOSS;
 617
 618 }
 619
 620 void vewhicle_spiderbot_dinit()
 621 {
 622     if not (vehicle_initialize(
 623              "Spiderbot",
 624              "models/vehicles/spiderbot.dpm",
 625              "models/vehicles/spiderbot_top.dpm",
 626              "models/vehicles/spiderbot_cockpit.dpm",
 627              "tag_head", "tag_hud", "",
 628              HUD_SPIDERBOT,
 629              SPIDERBOT_MIN, SPIDERBOT_MAX,
 630              FALSE,
 631              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 632              spiderbot_frame,
 633              spiderbot_enter, spiderbot_exit,
 634              spiderbot_die,   spiderbot_think,
 635              FALSE))
 636     {
 637         remove(self);
 638         return;
 639     }
 640
 641     self.gun1               = spawn();
 642     self.gun2               = spawn();
 643
 644     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 645     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 646
 647     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 648     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 649
 650     self.gravity            = 2;
 651     self.mass               = 5000;
 652 }
 653
 654 void spawnfunc_vehicle_spiderbot()
 655 {
 656     precache_model ( "models/vhshield.md3");
 657     precache_model ( "models/vehicles/spiderbot.dpm");
 658     precache_model ( "models/vehicles/spiderbot_top.dpm");
 659     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 660     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 661     precache_model ( "models/uziflash.md3");
 662
 663     precache_sound ( "weapons/rocket_impact.wav" );
 664     precache_sound ( "weapons/uzi_fire.wav" );
 665     precache_sound ( "weapons/rocket_impact.wav");
 666
 667     precache_sound ( "vehicles/spiderbot_die.wav");
 668     precache_sound ( "vehicles/spiderbot_idle.wav");
 669     precache_sound ( "vehicles/spiderbot_jump.wav");
 670     precache_sound ( "vehicles/spiderbot_strafe.wav");
 671     precache_sound ( "vehicles/spiderbot_walk.wav");
 672     precache_sound ( "vehicles/spiderbot_land.wav");
 673
 674     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 675     if(autocvar_g_vehicle_spiderbot_shield)
 676         self.vehicle_flags |= VHF_HASSHIELD;
 677
 678     if(autocvar_g_vehicle_spiderbot_shield_regen)
 679         self.vehicle_flags |= VHF_SHIELDREGEN;
 680
 681     if(autocvar_g_vehicle_spiderbot_health_regen)
 682         self.vehicle_flags |= VHF_HEALTHREGEN;
 683
 684     self.think = vewhicle_spiderbot_dinit;
 685     self.nextthink = time + 0.5;
 686 }
 687 #endif // SVQC
 688
 689 #ifdef CSQC
 690 void spiderbot_draw()
 691 {
 692
 693 }
 694
 695 void spiderbot_draw2d()
 696 {
 697
 698 }
 699
 700 void spiderbot_read_extra()
 701 {
 702
 703 }
 704
 705 void vehicle_spiderbot_assemble()
 706 {
 707
 708 }
 709 #endif //CSQC