qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15
  16 float autocvar_g_vehicle_raptor_bomblets;
  17 float autocvar_g_vehicle_raptor_bomblet_alt;
  18 float autocvar_g_vehicle_raptor_bomblet_time;
  19 float autocvar_g_vehicle_raptor_bomblet_damage;
  20 float autocvar_g_vehicle_raptor_bomblet_spread;
  21 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  22 float autocvar_g_vehicle_raptor_bomblet_radius;
  23 float autocvar_g_vehicle_raptor_bomblet_force;
  24 float autocvar_g_vehicle_raptor_bombs_refire;
  25
  26 float autocvar_g_vehicle_raptor_guns_turnspeed;
  27 float autocvar_g_vehicle_raptor_guns_turnlimit;
  28 float autocvar_g_vehicle_raptor_guns_pitchlimit_up;
  29 float autocvar_g_vehicle_raptor_guns_pitchlimit_down;
  30
  31 float autocvar_g_vehicle_raptor_cannon_locktarget;
  32 float autocvar_g_vehicle_raptor_cannon_locking_time;
  33 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  34 float autocvar_g_vehicle_raptor_cannon_locked_time;
  35 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  36
  37 float autocvar_g_vehicle_raptor_cannon_cost;
  38 float autocvar_g_vehicle_raptor_cannon_damage;
  39 float autocvar_g_vehicle_raptor_cannon_radius;
  40 float autocvar_g_vehicle_raptor_cannon_refire;
  41 float autocvar_g_vehicle_raptor_cannon_speed;
  42 float autocvar_g_vehicle_raptor_cannon_spread;
  43
  44
  45 float autocvar_g_vehicle_raptor_energy;
  46 float autocvar_g_vehicle_raptor_energy_regen;
  47 float autocvar_g_vehicle_raptor_energy_regen_pause;
  48
  49 float autocvar_g_vehicle_raptor_health;
  50 float autocvar_g_vehicle_raptor_health_regen;
  51 float autocvar_g_vehicle_raptor_health_regen_pause;
  52
  53 float autocvar_g_vehicle_raptor_shield;
  54 float autocvar_g_vehicle_raptor_shield_regen;
  55 float autocvar_g_vehicle_raptor_shield_regen_pause;
  56
  57 void raptor_spawn();
  58 //void raptor_return();
  59 float raptor_frame();
  60 //float raptor_takeoff();
  61
  62 .entity bomb1;
  63 .entity bomb2;
  64 .entity camera;
  65
  66 float raptor_altitude(float amax)
  67 {
  68         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  69     return vlen(self.origin - trace_endpos);
  70 }
  71
  72 void raptor_bombs_return()
  73 {
  74     self.owner.bomb1.alpha = 1;
  75     self.owner.bomb2.alpha = 1;
  76     remove(self);
  77 }
  78
  79 void raptor_bomblet_boom()
  80 {
  81     if(other == self.owner || other.owner == self.owner)
  82         return;
  83
  84     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
  85     RadiusDamage (self, self.enemy, autocvar_g_vehicle_raptor_bomblet_damage,
  86                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  87                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  88                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  89     remove(self);
  90 }
  91
  92 void raptor_bomb_burst()
  93 {
  94     self.angles = vectoangles(self.velocity);
  95
  96
  97     if(autocvar_g_vehicle_raptor_bomblet_alt)
  98     {
  99         self.nextthink = time;
 100         // FIXME: this can make bombs stic forever if fierd at low altitude and land close to vehicle.
 101         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 102         if(trace_fraction == 1.0)
 103             return;
 104
 105         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 106             return;
 107     }
 108
 109     entity bomblet;
 110     float i,v;
 111     vector d;
 112
 113     v = vlen(self.velocity);
 114     d = normalize(self.velocity);
 115     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 116
 117     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 118     {
 119
 120         bomblet = spawn();
 121         setorigin(bomblet,self.origin);
 122
 123         setmodel(bomblet,"models/vehicles/raptor_bomb.dpm");
 124         bomblet.scale = 0.5;
 125
 126         bomblet.solid       = SOLID_TRIGGER;
 127         bomblet.movetype    = MOVETYPE_BOUNCE;
 128         bomblet.touch       = raptor_bomblet_boom;
 129         bomblet.think       = raptor_bomblet_boom;
 130         bomblet.nextthink   = time + 5;
 131         bomblet.owner       = self.owner;
 132
 133         bomblet.modelflags = MF_GRENADE;
 134
 135         bomblet.velocity = normalize(d + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * v;
 136
 137         bomblet.angles = vectoangles(bomblet.velocity);
 138     }
 139
 140     remove(self);
 141 }
 142
 143 void raptor_bomb_touch()
 144 {
 145     raptor_bomb_burst();
 146 }
 147
 148 void raptor_bombdrop()
 149 {
 150     entity bomb_1, bomb_2;
 151
 152     self.bomb1.alpha = 0.25;
 153     self.bomb2.alpha = 0.25;
 154
 155     bomb_1 = spawn();
 156     bomb_2 = spawn();
 157
 158     setmodel(bomb_1,"models/vehicles/raptor_bomb.dpm");
 159     setmodel(bomb_2,"models/vehicles/raptor_bomb.dpm");
 160
 161     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 162     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 163
 164     bomb_1.movetype  = bomb_2.movetype   = MOVETYPE_TOSS;
 165     bomb_1.velocity  = bomb_2.velocity   = self.velocity;
 166     bomb_1.touch     = bomb_2.touch      = raptor_bomb_touch;
 167     bomb_1.think     = bomb_2.think      = raptor_bomb_burst;
 168
 169     if(autocvar_g_vehicle_raptor_bomblet_alt)
 170         bomb_1.nextthink = bomb_2.nextthink  = time;
 171     else
 172         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 173
 174     bomb_1.avelocity = bomb_2.avelocity  = '0 0 180';
 175     bomb_1.owner     = bomb_2.owner      = self;
 176     bomb_1.enemy     = bomb_2.enemy      = self.owner;
 177     bomb_1.angles    = bomb_2.angles     = self.angles;
 178     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 179
 180     bomb_1 = spawn();
 181     bomb_1.owner = self;
 182     bomb_1.think = raptor_bombs_return;
 183     bomb_1.nextthink = time + autocvar_g_vehicle_raptor_bombs_refire;
 184 }
 185
 186 void raptor_bolt_explode()
 187 {
 188         PROJECTILE_TOUCH;
 189     pointparticles(particleeffectnum("raptor_cannon_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 190     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_cannon_damage, 0, autocvar_g_vehicle_raptor_cannon_radius, world, 25, DEATH_WAKIGUN, world);
 191     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 192     remove (self);
 193 }
 194
 195 void raptor_fire_cannon(entity gun, string tagname)
 196 {
 197     entity bolt;
 198
 199     bolt = spawn();
 200
 201     PROJECTILE_MAKETRIGGER(bolt);
 202     sound (gun, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 203     setorigin(bolt, gettaginfo(gun, gettagindex(gun, tagname)));
 204
 205     bolt.movetype        = MOVETYPE_FLYMISSILE;
 206     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 207     bolt.owner           = self;
 208     bolt.realowner       = self.owner;
 209     bolt.touch           = raptor_bolt_explode;
 210     bolt.think           = raptor_bolt_explode;
 211     bolt.nextthink       = time + 9;
 212     bolt.bot_dodge       = TRUE;
 213     bolt.bot_dodgerating = autocvar_g_vehicle_raptor_cannon_damage;
 214     bolt.velocity        = normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed;
 215
 216     pointparticles(particleeffectnum("raptor_cannon_muzzleflash"), bolt.origin, bolt.velocity, 1);
 217     //pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), bolt.origin, bolt.velocity, 1);
 218
 219     CSQCProjectile(bolt, TRUE, PROJECTILE_CRYLINK   , TRUE);
 220 }
 221
 222 void raptor_think()
 223 {
 224 }
 225
 226 void raptor_enter()
 227 {
 228     self.movetype   = MOVETYPE_BOUNCEMISSILE;
 229     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 230     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 231     self.velocity_z = 1;
 232     //setorigin(self.vehicle_viewport, self.origin);
 233 }
 234
 235 void raptor_land()
 236 {
 237     float hgt;
 238
 239     hgt = raptor_altitude(512);
 240     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 241     self.angles_x *= 0.95;
 242     self.angles_z *= 0.95;
 243
 244     if(hgt < 128)
 245         if(self.frame != 0)
 246             self.frame = max(self.frame - 0.25, 0);
 247
 248     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 249     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 250
 251     if(hgt < 16)
 252     {
 253         self.movetype   = MOVETYPE_BOUNCE;
 254         self.think      = raptor_think;
 255     }
 256
 257     self.nextthink  = time;
 258 }
 259
 260 void raptor_exit(float eject)
 261 {
 262
 263     if(self.deadflag == DEAD_NO)
 264     {
 265         vehicles_setreturn(autocvar_g_vehicle_raptor_respawntime, raptor_spawn);
 266         self.think      = raptor_land;
 267         self.nextthink  = time;
 268     }
 269
 270     if not (self.owner)
 271         return;
 272
 273         makevectors(self.angles);
 274         if(eject)
 275         {
 276             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 277             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 278         }
 279         else
 280         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 281
 282     self.owner = world;
 283 }
 284
 285 float raptor_frame()
 286 {
 287     entity player, raptor;
 288     float ftmp, ftmp2;
 289     vector df;
 290
 291     player = self;
 292     raptor   = self.vehicle;
 293     self    = raptor;
 294
 295     if(player.BUTTON_USE)
 296     {
 297         self = raptor;
 298         vehicles_exit(VHEF_NORMAL);
 299         self = player;
 300         return 0;
 301     }
 302
 303     if(raptor.deadflag != DEAD_NO)
 304     {
 305         self = player;
 306         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 307         return 1;
 308     }
 309
 310     // Takeoff sequense
 311     if(raptor.frame < 25)
 312     {
 313         raptor.frame += 0.25;
 314         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 315         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 2000);
 316         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 317         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 318         self = player;
 319         return 1;
 320     }
 321
 322     /*
 323     raptor.angles_x *= -1;
 324     // Rotate Body
 325     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 326     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - raptor.angles_y, raptor.angles_y), ftmp);
 327
 328     // Turn
 329     raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 330
 331     // Pitch Body
 332     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 333     ftmp = bound(-ftmp, shortangle_f(player.v_angle_x - raptor.angles_x, raptor.angles_x), ftmp);
 334
 335     raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 336     raptor.angles_x *= -1;
 337
 338     if(autocvar_g_vehicle_raptor_movestyle == 1)
 339     {
 340         ftmp = raptor.angles_z;
 341         raptor.angles_z = 0;
 342         ftmp2 = raptor.angles_x;
 343         raptor.angles_x = 0;
 344         fixedmakevectors(raptor.angles);
 345         raptor.angles_z = ftmp;
 346         raptor.angles_x = ftmp2;
 347     }
 348     else
 349         makevectors(player.v_angle);
 350     */
 351     crosshair_trace(player);
 352     //df = vectoangles(normalize(trace_endpos - gettaginfo(raptor ,gettagindex(raptor, "tag_hud"))) - raptor.angles);
 353     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 354     if(df_x > 180)  df_x -= 360;
 355     if(df_x < -180) df_x += 360;
 356     if(df_y > 180)  df_y -= 360;
 357     if(df_y < -180) df_y += 360;
 358
 359     //raptor.angles_x *= -1;
 360     // Rotate Body
 361     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 362     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 363
 364     // Turn
 365     raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 366
 367     // Pitch Body
 368     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 369     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 370
 371     raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 372     //raptor.angles_x *= -1;
 373
 374     if(autocvar_g_vehicle_raptor_movestyle == 1)
 375     {
 376         ftmp = raptor.angles_z;
 377         raptor.angles_z = 0;
 378         ftmp2 = raptor.angles_x;
 379         raptor.angles_x = 0;
 380         fixedmakevectors(raptor.angles);
 381         raptor.angles_z = ftmp;
 382         raptor.angles_x = ftmp2;
 383     }
 384     else
 385         makevectors(player.v_angle);
 386
 387
 388
 389     /*
 390     float dist, spd, back, up;
 391     //dist = normalize(self.vehicle_viewport.origin - self.origin);
 392     spd = vlen(self.velocity) + 0.01;
 393     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 394     up = 1 - back;
 395     back = back;
 396     back = back * 1250;
 397     back += 150;
 398     up = up * 200;
 399     up = up + 100;
 400
 401     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 402     */
 403
 404     df = raptor.velocity * -1;
 405
 406     if(player.movement_x != 0)
 407     {
 408         if(player.movement_x > 0)
 409             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 410         else if(player.movement_x < 0)
 411             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 412     }
 413
 414     if(player.movement_y != 0)
 415     {
 416         if(player.movement_y < 0)
 417             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 418         else if(player.movement_y > 0)
 419             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 420
 421         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 422     }
 423     else
 424     {
 425         raptor.angles_z *= 0.95;
 426         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 427             raptor.angles_z = 0;
 428     }
 429
 430     if(player.BUTTON_CROUCH)
 431         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 432     else if (player.BUTTON_JUMP)
 433         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 434
 435     raptor.velocity  += df * frametime;
 436     player.velocity = player.movement  = raptor.velocity;
 437     setorigin(player,raptor.origin + '0 0 32');
 438
 439     vector vf, ad;
 440     // Target lock & predict
 441     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 442     {
 443
 444         vehicles_locktarget2((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 445                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 446                              autocvar_g_vehicle_raptor_cannon_locked_time);
 447
 448         if(autocvar_g_vehicle_raptor_cannon_predicttarget && self.lock_strength == 1)
 449         {
 450             vector o;
 451             if(self.lock_target != world)
 452             {
 453                 float i, distance, impact_time;
 454
 455                 vf = real_origin(raptor.lock_target);
 456                 ad = vf;
 457                 o = raptor.origin;
 458                 for(i = 0; i < 4; ++i)
 459                 {
 460
 461                     distance = vlen(ad - o);
 462                     impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 463                     ad = vf + raptor.lock_target.velocity * impact_time;
 464                     o = raptor.origin + raptor.velocity * impact_time;
 465                 }
 466                 trace_endpos = ad;
 467             }
 468         }
 469
 470         if(self.lock_target != world)
 471         if(self.lock_strength == 1)
 472             UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 1);
 473         else
 474             UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * (1 - self.lock_strength)) + '0 1 0' * self.lock_strength, 1);
 475     }
 476
 477     // Aim the gunz
 478     ftmp2 = autocvar_g_vehicle_raptor_guns_turnspeed * frametime;
 479     ftmp = -ftmp2;
 480
 481     // Gun1
 482     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 483     ad = df;
 484     vf = v_forward;
 485     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 486     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 487     // Bind to aimspeed
 488     df_x = bound(ftmp, df_x, ftmp2);
 489     df_y = bound(ftmp, df_y, ftmp2);
 490     // Bind to limts
 491     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_guns_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_guns_pitchlimit_up);
 492     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_guns_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_guns_turnlimit);
 493
 494     //Gun 2
 495     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 496     ad += df;
 497     vf += v_forward;
 498     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 499     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 500     // Bind to aimspeed
 501     df_x = bound(ftmp, df_x, ftmp2);
 502     df_y = bound(ftmp, df_y, ftmp2);
 503     // Bind to limts
 504     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_guns_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_guns_pitchlimit_up);
 505     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_guns_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_guns_turnlimit);
 506
 507
 508     /*
 509     ad = ad * 0.5;
 510     v_forward = vf * 0.5;
 511     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 512     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 513     */
 514
 515     if(player.BUTTON_ATCK)
 516     if(raptor.attack_finished_single <= time)
 517     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 518     {
 519         raptor_fire_cannon(self.gun1, "fire1");
 520         raptor_fire_cannon(self.gun2, "fire1");
 521
 522         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 523         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 524         self.cnt = time;
 525     }
 526
 527     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 528         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 529
 530     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 531         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 532
 533     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 534         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 535
 536     player.vehicle_energy = raptor.vehicle_energy / autocvar_g_vehicle_raptor_energy;
 537
 538     if(time > raptor.delay)
 539     if(player.BUTTON_ATCK2)
 540     {
 541         raptor_bombdrop();
 542         raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 543         raptor.lip = time;
 544     }
 545
 546     player.vehicle_reload1 = (time - raptor.lip) / (raptor.delay - raptor.lip);
 547     VEHICLE_UPDATE_PLAYER(health, raptor);
 548
 549     if(self.vehicle_flags & VHF_HASSHIELD)
 550         VEHICLE_UPDATE_PLAYER(shield, raptor);
 551
 552     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 553     return 1;
 554 }
 555
 556 void raptor_touch()
 557 {
 558     if(self.owner)
 559     {
 560         if(vlen(self.velocity) == 0)
 561             return;
 562
 563         if(other.classname != "player")
 564             return;
 565
 566         return;
 567     }
 568
 569     if(other.classname != "player")
 570         return;
 571
 572     if(other.deadflag != DEAD_NO)
 573         return;
 574
 575     if(other.vehicle != world)
 576         return;
 577
 578     vehicles_enter();
 579 }
 580
 581 void raptor_blowup()
 582 {
 583     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 584     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 585
 586     self.deadflag    = DEAD_DEAD;
 587     self.vehicle_exit(VHEF_NORMAL);
 588     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 589
 590     self.alpha          = -1;
 591     self.movetype       = MOVETYPE_NONE;
 592     self.effects        = EF_NODRAW;
 593     self.colormod       = '0 0 0';
 594     self.avelocity      = '0 0 0';
 595     self.velocity       = '0 0 0';
 596
 597     setorigin(self, self.pos1);
 598     self.touch = SUB_Null;
 599 }
 600
 601 void raptor_die()
 602 {
 603     self.health       = 0;
 604     self.event_damage = SUB_Null;
 605     self.iscreature   = FALSE;
 606     self.solid        = SOLID_CORPSE;
 607     self.takedamage   = DAMAGE_NO;
 608     self.deadflag     = DEAD_DYING;
 609     self.movetype     = MOVETYPE_BOUNCE;
 610     //self.wait         = time;
 611
 612     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 613
 614     self.velocity_z += 128;
 615
 616     if(random() < 0.5)
 617         self.avelocity_z  = 45 + random() * 270;
 618     else
 619         self.avelocity_z  = -45 + random() * -270;
 620
 621     self.colormod = '-0.5 -0.5 -0.5';
 622
 623         self.touch     = raptor_blowup;
 624         self.think     = raptor_spawn;
 625         self.nextthink = time + autocvar_g_vehicle_raptor_respawntime;
 626 }
 627
 628 void raptor_spawn()
 629 {
 630     self.flags     = FL_NOTARGET;
 631     self.effects   = 0;
 632
 633     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 634     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 635     self.event_damage   = vehicles_damage;
 636     self.touch          = raptor_touch;
 637     self.iscreature     = TRUE;
 638     self.movetype       = MOVETYPE_FLY;
 639     self.solid          = SOLID_SLIDEBOX;
 640     self.takedamage     = DAMAGE_AIM;
 641     self.alpha          = 1;
 642         self.colormap       = 1024;
 643         self.deadflag       = DEAD_NO;
 644     self.bot_attack     = TRUE;
 645     self.colormod       = '1 1 1';
 646     self.avelocity      = '0 0 0';
 647     self.velocity       = '0 0 0';
 648     self.vehicle_energy = 1;
 649     self.vehicle_hudmodel.viewmodelforclient = self;
 650
 651     self.bomb1.gun1.avelocity_y = 90;
 652     self.bomb1.gun2.avelocity_y = -90;
 653     self.frame = 0;
 654
 655     setorigin(self, self.pos1);
 656     self.angles = self.pos2;
 657
 658     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 659     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 660     self.delay = time;
 661
 662     vehicles_common_spawn();
 663 }
 664
 665 void raptor_dinit()
 666 {
 667     entity spinner;
 668     vector ofs;
 669
 670     if not (vehicle_initialize(
 671              "Raptor",
 672              "models/vehicles/raptor.dpm",
 673              "",
 674              "models/vehicles/raptor_cockpit.dpm",
 675              "", "tag_hud", "tag_camera",
 676              HUD_RAPTOR,
 677              RAPTOR_MIN, RAPTOR_MAX,
 678              FALSE,
 679              raptor_spawn, raptor_frame,
 680              raptor_enter, raptor_exit,
 681              raptor_die,   raptor_think))
 682     {
 683         remove(self);
 684         return;
 685     }
 686
 687     //FIXME: Camera is in a bad place in HUD model.
 688     setorigin(self.vehicle_viewport, '10 0 3');
 689
 690     self.frame = 0;
 691
 692     self.bomb1 = spawn();
 693     self.bomb2 = spawn();
 694     self.gun1  = spawn();
 695     self.gun2  = spawn();
 696
 697     //setattachment(self.vehicle_viewport, world, "");
 698
 699     setmodel(self.bomb1,"models/vehicles/raptor_bomb.dpm");
 700     setmodel(self.bomb2,"models/vehicles/raptor_bomb.dpm");
 701     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 702     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 703
 704     setattachment(self.bomb1, self,"bombmount_left");
 705     setattachment(self.bomb2, self,"bombmount_right");
 706
 707     // FIXME Guns mounts to angled bones
 708     // This messes up gun-aim, so work arround it.
 709     //setattachment(self.gun1, self, "gunmount_left");
 710     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 711     ofs -= self.origin;
 712     setattachment(self.gun1, self, "");
 713     setorigin(self.gun1, ofs);
 714
 715     //setattachment(self.gun2, self, "gunmount_right");
 716     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 717     ofs -= self.origin;
 718     setattachment(self.gun2, self, "");
 719     setorigin(self.gun2, ofs);
 720
 721     spinner = spawn();
 722     spinner.owner = self;
 723     setmodel(spinner,"models/vehicles/spinner.dpm");
 724     setattachment(spinner, self, "engine_left");
 725     spinner.movetype = MOVETYPE_NOCLIP;
 726     spinner.avelocity = '0 90 0';
 727     self.bomb1.gun1 = spinner;
 728
 729     spinner = spawn();
 730     spinner.owner = self;
 731     setmodel(spinner,"models/vehicles/spinner.dpm");
 732     setattachment(spinner, self, "engine_right");
 733     spinner.movetype = MOVETYPE_NOCLIP;
 734     spinner.avelocity = '0 -90 0';
 735     self.bomb1.gun2 = spinner;
 736 }
 737
 738 void spawnfunc_vehicle_raptor()
 739 {
 740     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 741
 742     if(autocvar_g_vehicle_raptor_shield)
 743         self.vehicle_flags |= VHF_HASSHIELD;
 744
 745     if(autocvar_g_vehicle_raptor_shield_regen)
 746         self.vehicle_flags |= VHF_SHIELDREGEN;
 747
 748     if(autocvar_g_vehicle_raptor_health_regen)
 749         self.vehicle_flags |= VHF_HEALTHREGEN;
 750
 751     if(autocvar_g_vehicle_raptor_energy_regen)
 752         self.vehicle_flags |= VHF_ENERGYREGEN;
 753
 754     precache_model ("models/vehicles/raptor.dpm");
 755     precache_model ("models/vehicles/raptor_gun.dpm");
 756     precache_model ("models/vehicles/spinner.dpm");
 757     precache_model ("models/vehicles/raptor_cockpit.dpm");
 758     precache_model ("models/vehicles/raptor_bomb.dpm");
 759
 760     self.think = raptor_dinit;
 761     self.nextthink = time + 1;
 762 }