qcsrc/server/vehicles/raptor.qc

   1 #define RAPTOR_MIN '-80 -80 0'
   2 #define RAPTOR_MAX '80 80 70'
   3
   4 float autocvar_g_vehicle_raptor_respawntime;
   5
   6 float autocvar_g_vehicle_raptor_movestyle;
   7 float autocvar_g_vehicle_raptor_turnspeed;
   8 float autocvar_g_vehicle_raptor_pitchspeed;
   9 float autocvar_g_vehicle_raptor_pitchlimit;
  10
  11 float autocvar_g_vehicle_raptor_speed_forward;
  12 float autocvar_g_vehicle_raptor_speed_strafe;
  13 float autocvar_g_vehicle_raptor_speed_up;
  14 float autocvar_g_vehicle_raptor_speed_down;
  15 float autocvar_g_vehicle_raptor_friction;
  16
  17 float autocvar_g_vehicle_raptor_bomblets;
  18 float autocvar_g_vehicle_raptor_bomblet_alt;
  19 float autocvar_g_vehicle_raptor_bomblet_time;
  20 float autocvar_g_vehicle_raptor_bomblet_damage;
  21 float autocvar_g_vehicle_raptor_bomblet_spread;
  22 float autocvar_g_vehicle_raptor_bomblet_edgedamage;
  23 float autocvar_g_vehicle_raptor_bomblet_radius;
  24 float autocvar_g_vehicle_raptor_bomblet_force;
  25 float autocvar_g_vehicle_raptor_bomblet_explode_delay;
  26 float autocvar_g_vehicle_raptor_bombs_refire;
  27
  28 float autocvar_g_vehicle_raptor_cannon_turnspeed;
  29 float autocvar_g_vehicle_raptor_cannon_turnlimit;
  30 float autocvar_g_vehicle_raptor_cannon_pitchlimit_up;
  31 float autocvar_g_vehicle_raptor_cannon_pitchlimit_down;
  32
  33 float autocvar_g_vehicle_raptor_cannon_locktarget;
  34 float autocvar_g_vehicle_raptor_cannon_locking_time;
  35 float autocvar_g_vehicle_raptor_cannon_locking_releasetime;
  36 float autocvar_g_vehicle_raptor_cannon_locked_time;
  37 float autocvar_g_vehicle_raptor_cannon_predicttarget;
  38
  39 float autocvar_g_vehicle_raptor_cannon_cost;
  40 float autocvar_g_vehicle_raptor_cannon_damage;
  41 float autocvar_g_vehicle_raptor_cannon_radius;
  42 float autocvar_g_vehicle_raptor_cannon_refire;
  43 float autocvar_g_vehicle_raptor_cannon_speed;
  44 float autocvar_g_vehicle_raptor_cannon_spread;
  45
  46
  47 float autocvar_g_vehicle_raptor_energy;
  48 float autocvar_g_vehicle_raptor_energy_regen;
  49 float autocvar_g_vehicle_raptor_energy_regen_pause;
  50
  51 float autocvar_g_vehicle_raptor_health;
  52 float autocvar_g_vehicle_raptor_health_regen;
  53 float autocvar_g_vehicle_raptor_health_regen_pause;
  54
  55 float autocvar_g_vehicle_raptor_shield;
  56 float autocvar_g_vehicle_raptor_shield_regen;
  57 float autocvar_g_vehicle_raptor_shield_regen_pause;
  58
  59 void raptor_spawn();
  60 //void raptor_return();
  61 float raptor_frame();
  62 //float raptor_takeoff();
  63
  64 .entity bomb1;
  65 .entity bomb2;
  66 //.entity camera;
  67 //#define RAPTOR_RETARDCAMERA
  68
  69 float raptor_altitude(float amax)
  70 {
  71         tracebox(self.origin, self.mins, self.maxs, self.origin - ('0 0 1' * amax), TRUE, self);
  72     return vlen(self.origin - trace_endpos);
  73 }
  74
  75
  76 void raptor_bomblet_boom()
  77 {
  78     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
  79     pointparticles(particleeffectnum("raptor_bomb_impact"), self.origin, trace_plane_normal * 1000, 1);
  80     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_bomblet_damage,
  81                                     autocvar_g_vehicle_raptor_bomblet_edgedamage,
  82                                     autocvar_g_vehicle_raptor_bomblet_radius, world,
  83                                     autocvar_g_vehicle_raptor_bomblet_force, DEATH_SBROCKET, world);
  84     remove(self);
  85 }
  86
  87 void raptor_bomblet_touch()
  88 {
  89     if(other == self.owner)
  90         return;
  91
  92     PROJECTILE_TOUCH;
  93     self.think = raptor_bomblet_boom;
  94     self.nextthink = time + random() * autocvar_g_vehicle_raptor_bomblet_explode_delay;
  95 }
  96
  97 void raptor_bomb_burst()
  98 {
  99     if(self.cnt > time)
 100     if(autocvar_g_vehicle_raptor_bomblet_alt)
 101     {
 102         self.nextthink = time;
 103         traceline(self.origin, self.origin + (normalize(self.velocity) * autocvar_g_vehicle_raptor_bomblet_alt), MOVE_NORMAL, self);
 104         if(trace_fraction == 1.0)
 105             return;
 106
 107         if(vlen(self.origin - self.owner.origin) < autocvar_g_vehicle_raptor_bomblet_radius)
 108             return;
 109     }
 110
 111     entity bomblet;
 112     float i;
 113
 114     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 115     pointparticles(particleeffectnum("rocket_explode"), self.origin, self.velocity, 1);
 116
 117     for(i = 0; i < autocvar_g_vehicle_raptor_bomblets; ++i)
 118     {
 119         bomblet = spawn();
 120         setorigin(bomblet, self.origin);
 121
 122         bomblet.scale       = 0.5;
 123         bomblet.solid       = SOLID_TRIGGER;
 124         bomblet.movetype    = MOVETYPE_TOSS;
 125         bomblet.touch       = raptor_bomblet_touch;
 126         bomblet.think       = raptor_bomblet_boom;
 127         bomblet.nextthink   = time + 5;
 128         bomblet.owner   = self.owner;
 129         bomblet.realowner   = self.realowner;
 130         bomblet.velocity    = normalize(normalize(self.velocity) + (randomvec() * autocvar_g_vehicle_raptor_bomblet_spread)) * vlen(self.velocity);
 131         PROJECTILE_MAKETRIGGER(bomblet);
 132         CSQCProjectile(bomblet, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 133     }
 134
 135     remove(self);
 136 }
 137
 138 void raptor_bomb_touch()
 139 {
 140     raptor_bomb_burst();
 141 }
 142
 143 void raptor_bombdrop()
 144 {
 145     entity bomb_1, bomb_2;
 146
 147     //self.bomb1.alpha = 0;
 148     //self.bomb2.alpha = 0;
 149
 150     bomb_1 = spawn();
 151     bomb_2 = spawn();
 152
 153     setorigin(bomb_1, gettaginfo(self, gettagindex(self, "bombmount_left")));
 154     setorigin(bomb_2, gettaginfo(self, gettagindex(self, "bombmount_right")));
 155
 156     bomb_1.movetype     = bomb_2.movetype   = MOVETYPE_TOSS;
 157     bomb_1.velocity     = bomb_2.velocity   = self.velocity;
 158     bomb_1.touch        = bomb_2.touch      = raptor_bomb_touch;
 159     bomb_1.think        = bomb_2.think      = raptor_bomb_burst;
 160     bomb_1.cnt          = bomb_2.cnt        = time + 10;
 161
 162     if(autocvar_g_vehicle_raptor_bomblet_alt)
 163         bomb_1.nextthink = bomb_2.nextthink  = time;
 164     else
 165         bomb_1.nextthink = bomb_2.nextthink  = time + autocvar_g_vehicle_raptor_bomblet_time;
 166
 167     bomb_1.owner     = bomb_2.owner      = self;
 168     bomb_1.realowner = bomb_2.realowner  = self.owner;
 169     bomb_1.solid     = bomb_2.solid      = SOLID_BBOX;
 170
 171     PROJECTILE_MAKETRIGGER(bomb_1);
 172     PROJECTILE_MAKETRIGGER(bomb_2);
 173
 174     CSQCProjectile(bomb_1, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 175     CSQCProjectile(bomb_2, TRUE, PROJECTILE_RAPTORBOMB, TRUE);
 176
 177 }
 178
 179 void raptor_bolt_explode()
 180 {
 181         PROJECTILE_TOUCH;
 182     pointparticles(particleeffectnum("raptor_cannon_impact"), findbetterlocation (self.origin, 8), trace_plane_normal * 1000, 1);
 183     RadiusDamage (self, self.realowner, autocvar_g_vehicle_raptor_cannon_damage, 0, autocvar_g_vehicle_raptor_cannon_radius, world, 25, DEATH_WAKIGUN, world);
 184     sound (self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 185     remove (self);
 186 }
 187
 188 void raptor_fire_cannon(entity gun, string tagname)
 189 {
 190     entity bolt;
 191
 192     bolt = spawn();
 193
 194     PROJECTILE_MAKETRIGGER(bolt);
 195     sound (gun, CHAN_WEAPON, "weapons/lasergun_fire.wav", VOL_BASE, ATTN_NORM);
 196     setorigin(bolt, gettaginfo(gun, gettagindex(gun, tagname)));
 197
 198     bolt.movetype        = MOVETYPE_FLYMISSILE;
 199     bolt.flags           = FL_PROJECTILE | FL_NOTARGET;
 200     bolt.owner           = self;
 201     bolt.realowner       = self.owner;
 202     bolt.touch           = raptor_bolt_explode;
 203     bolt.think           = raptor_bolt_explode;
 204     bolt.nextthink       = time + 9;
 205     bolt.bot_dodge       = TRUE;
 206     bolt.bot_dodgerating = autocvar_g_vehicle_raptor_cannon_damage;
 207     bolt.velocity        = normalize(v_forward + randomvec() * autocvar_g_vehicle_raptor_cannon_spread) * autocvar_g_vehicle_raptor_cannon_speed;
 208
 209     pointparticles(particleeffectnum("raptor_cannon_muzzleflash"), bolt.origin, bolt.velocity, 1);
 210     //pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), bolt.origin, bolt.velocity, 1);
 211
 212     CSQCProjectile(bolt, TRUE, PROJECTILE_CRYLINK, TRUE);
 213 }
 214
 215 void raptor_think()
 216 {
 217 }
 218
 219 void raptor_enter()
 220 {
 221     self.movetype   = MOVETYPE_BOUNCEMISSILE;
 222     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_raptor_health);
 223     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_raptor_shield);
 224     self.velocity_z = 1;
 225 #ifdef RAPTOR_RETARDCAMERA
 226     setorigin(self.vehicle_viewport, self.origin);
 227 #endif
 228 }
 229
 230 void raptor_land()
 231 {
 232     float hgt;
 233
 234     hgt = raptor_altitude(512);
 235     self.velocity = (self.velocity * 0.9) + ('0 0 -1800' * (hgt / 256) * sys_frametime);
 236     self.angles_x *= 0.95;
 237     self.angles_z *= 0.95;
 238
 239     if(hgt < 128)
 240         if(self.frame != 0)
 241             self.frame = max(self.frame - 0.25, 0);
 242
 243     self.bomb1.gun1.avelocity_y = 90 + ((self.frame / 25) * 2000);
 244     self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 245
 246     if(hgt < 16)
 247     {
 248         self.movetype   = MOVETYPE_BOUNCE;
 249         self.think      = raptor_think;
 250     }
 251
 252     self.nextthink  = time;
 253 }
 254
 255 void raptor_exit(float eject)
 256 {
 257
 258     if(self.deadflag == DEAD_NO)
 259     {
 260         vehicles_setreturn(autocvar_g_vehicle_raptor_respawntime, raptor_spawn);
 261         self.think      = raptor_land;
 262         self.nextthink  = time;
 263     }
 264
 265     if not (self.owner)
 266         return;
 267
 268         makevectors(self.angles);
 269         if(eject)
 270         {
 271             setorigin(self.owner,self.origin + v_forward * 100 + '0 0 64');
 272             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 273         }
 274         else
 275         setorigin(self.owner,self.origin - v_forward * 200 + '0 0 64');
 276
 277     self.owner = world;
 278 }
 279
 280 float raptor_frame()
 281 {
 282     entity player, raptor;
 283     float ftmp, ftmp2;
 284     vector df;
 285
 286     player = self;
 287     raptor   = self.vehicle;
 288     self    = raptor;
 289
 290     if(player.BUTTON_USE)
 291     {
 292         self = raptor;
 293         vehicles_exit(VHEF_NORMAL);
 294         self = player;
 295         return 0;
 296     }
 297
 298     if(raptor.deadflag != DEAD_NO)
 299     {
 300         self = player;
 301         player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 302         return 1;
 303     }
 304
 305     // Takeoff sequense
 306     if(raptor.frame < 25)
 307     {
 308         raptor.frame += 0.25;
 309         raptor.velocity_z = min(raptor.velocity_z * 1.5, 256);
 310         self.bomb1.gun1.avelocity_y = 90 + ((raptor.frame / 25) * 2000);
 311         self.bomb1.gun2.avelocity_y = -self.bomb1.gun1.avelocity_y;
 312         player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 313         self = player;
 314         return 1;
 315     }
 316     crosshair_trace(player);
 317
 318 #if VEHICLES_VIEWROTATE_CROSSHAIR
 319     df = vectoangles(normalize(trace_endpos - self.origin + '0 0 32'));
 320     if(df_x > 180)  df_x -= 360;
 321     if(df_x < -180) df_x += 360;
 322     if(df_y > 180)  df_y -= 360;
 323     if(df_y < -180) df_y += 360;
 324
 325     // Rotate Body
 326     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 327     ftmp = bound(-ftmp, shortangle_f(df_y - raptor.angles_y, raptor.angles_y), ftmp);
 328
 329     // Turn
 330     raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 331
 332     // Pitch Body
 333     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 334     ftmp = bound(-ftmp, shortangle_f(df_x - raptor.angles_x, raptor.angles_x), ftmp);
 335
 336     raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 337 #else
 338     raptor.angles_x *= -1;
 339     // Rotate Body
 340     ftmp = autocvar_g_vehicle_raptor_turnspeed * sys_frametime;
 341     ftmp = bound(-ftmp, shortangle_f(player.v_angle_y - raptor.angles_y, raptor.angles_y), ftmp);
 342
 343     // Turn
 344     raptor.angles_y = anglemods(raptor.angles_y + ftmp);
 345
 346     // Pitch Body
 347     ftmp = autocvar_g_vehicle_raptor_pitchspeed  * sys_frametime;
 348     ftmp2 = shortangle_f(player.v_angle_x - raptor.angles_x, raptor.angles_x);
 349
 350     if(player.movement_x > 0)
 351         ftmp2 += 20 * ftmp;
 352     else if(player.movement_x < 0)
 353         ftmp2 -= 45 * ftmp;
 354
 355     ftmp = bound(-ftmp, ftmp2, ftmp);
 356     raptor.angles_x = bound(-autocvar_g_vehicle_raptor_pitchlimit, anglemods(raptor.angles_x + ftmp), autocvar_g_vehicle_raptor_pitchlimit);
 357     raptor.angles_x *= -1;
 358 #endif
 359
 360     if(autocvar_g_vehicle_raptor_movestyle == 1)
 361         fixedmakevectors('0 1 0' * raptor.angles_y);
 362     else
 363         makevectors(player.v_angle);
 364
 365 #ifdef RAPTOR_RETARDCAMERA
 366     float spd, back, up;
 367     spd = vlen(self.velocity) + 0.01;
 368     back = spd / autocvar_g_vehicle_raptor_speed_forward;
 369     up = 1 - back;
 370     back = back;
 371     back = back * 1250;
 372     back += 150;
 373     up = up * 200;
 374     up = up + 100;
 375
 376     setorigin(self.vehicle_viewport, self.origin + (v_up * up) + (v_forward * -back));
 377 #endif
 378
 379     df = raptor.velocity * -autocvar_g_vehicle_raptor_friction;
 380
 381     if(player.movement_x != 0)
 382     {
 383         if(player.movement_x > 0)
 384             df += v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 385         else if(player.movement_x < 0)
 386             df -= v_forward  * autocvar_g_vehicle_raptor_speed_forward;
 387     }
 388
 389     if(player.movement_y != 0)
 390     {
 391         if(player.movement_y < 0)
 392             df -= v_right * autocvar_g_vehicle_raptor_speed_strafe;
 393         else if(player.movement_y > 0)
 394             df += v_right * autocvar_g_vehicle_raptor_speed_strafe;
 395
 396         raptor.angles_z = bound(-30,raptor.angles_z + (player.movement_y / autocvar_g_vehicle_raptor_speed_strafe),30);
 397     }
 398     else
 399     {
 400         raptor.angles_z *= 0.95;
 401         if(raptor.angles_z >= -1 && raptor.angles_z <= -1)
 402             raptor.angles_z = 0;
 403     }
 404
 405     if(player.BUTTON_CROUCH)
 406         df -=   v_up * autocvar_g_vehicle_raptor_speed_down;
 407     else if (player.BUTTON_JUMP)
 408         df +=  v_up * autocvar_g_vehicle_raptor_speed_up;
 409
 410     raptor.velocity  += df * frametime;
 411     player.velocity = player.movement  = raptor.velocity;
 412     setorigin(player,raptor.origin + '0 0 32');
 413
 414     vector vf, ad;
 415     // Target lock & predict
 416     if(autocvar_g_vehicle_raptor_cannon_locktarget)
 417     {
 418
 419         vehicles_locktarget2((1 / autocvar_g_vehicle_raptor_cannon_locking_time) * frametime,
 420                              (1 / autocvar_g_vehicle_raptor_cannon_locking_releasetime) * frametime,
 421                              autocvar_g_vehicle_raptor_cannon_locked_time);
 422
 423         if(autocvar_g_vehicle_raptor_cannon_predicttarget && self.lock_strength == 1)
 424         {
 425             if(self.lock_target != world)
 426             {
 427                 float i, distance, impact_time;
 428
 429                 vf = real_origin(raptor.lock_target);
 430                 ad = vf;
 431                 for(i = 0; i < 4; ++i)
 432                 {
 433                     distance = vlen(ad - raptor.origin);
 434                     impact_time = distance / autocvar_g_vehicle_raptor_cannon_speed;
 435                     ad = vf + raptor.lock_target.velocity * impact_time;
 436                 }
 437                 trace_endpos = ad;
 438                 UpdateAuxiliaryXhair(player, trace_endpos, '1 1 1', 0);
 439             }
 440         }
 441
 442         if(self.lock_target)
 443         {
 444             if(raptor.lock_strength == 1)
 445                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '1 0 0', 1);
 446             else if(self.lock_strength > 0.5)
 447                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 1 0', 1);
 448             else if(self.lock_strength < 0.5)
 449                 UpdateAuxiliaryXhair(player, real_origin(raptor.lock_target), '0 0 1', 1);
 450         }
 451
 452         /*
 453         if(self.lock_target != world)
 454         if(self.lock_strength == 1)
 455             UpdateAuxiliaryXhair(player, real_origin(self.lock_target), '0 0 1', 1);
 456         else
 457             UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * (1 - self.lock_strength)) + '0 1 0' * self.lock_strength, 1);
 458         */
 459     }
 460
 461     // Aim the gunz
 462     ftmp2 = autocvar_g_vehicle_raptor_cannon_turnspeed * frametime;
 463     ftmp = -ftmp2;
 464
 465     // Gun1
 466     df = gettaginfo(raptor.gun1, gettagindex(raptor.gun1, "fire1"));
 467     ad = df;
 468     vf = v_forward;
 469     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 470     df = shortangle_vxy(df - (raptor.angles + raptor.gun1.angles), raptor.angles + raptor.gun1.angles);     // Find aim offset
 471     // Bind to aimspeed
 472     df_x = bound(ftmp, df_x, ftmp2);
 473     df_y = bound(ftmp, df_y, ftmp2);
 474     // Bind to limts
 475     raptor.gun1.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun1.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 476     raptor.gun1.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun1.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 477
 478     //df = vectoangles(normalize(trace_endpos - df));
 479
 480     //Gun 2
 481     df = gettaginfo(raptor.gun2, gettagindex(raptor.gun2, "fire1"));
 482     ad += df;
 483     vf += v_forward;
 484     df = vectoangles(normalize(trace_endpos - df)); // Find the direction & angle
 485     df = shortangle_vxy(df - (raptor.angles + raptor.gun2.angles), raptor.angles + raptor.gun2.angles);     // Find aim offset
 486     // Bind to aimspeed
 487     df_x = bound(ftmp, df_x, ftmp2);
 488     df_y = bound(ftmp, df_y, ftmp2);
 489     // Bind to limts
 490     raptor.gun2.angles_x = bound(-autocvar_g_vehicle_raptor_cannon_pitchlimit_down, df_x + raptor.gun2.angles_x, autocvar_g_vehicle_raptor_cannon_pitchlimit_up);
 491     raptor.gun2.angles_y = bound(-autocvar_g_vehicle_raptor_cannon_turnlimit,  df_y + raptor.gun2.angles_y, autocvar_g_vehicle_raptor_cannon_turnlimit);
 492
 493
 494     /*
 495     ad = ad * 0.5;
 496     v_forward = vf * 0.5;
 497     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, raptor);
 498     UpdateAuxiliaryXhair(player, trace_endpos, '0 1 0', 0);
 499     */
 500
 501     if(player.BUTTON_ATCK)
 502     if(raptor.attack_finished_single <= time)
 503     if(raptor.vehicle_energy > autocvar_g_vehicle_raptor_cannon_cost)
 504     {
 505         raptor.misc_bulletcounter += 1;
 506         if(mod(raptor.misc_bulletcounter, 2))
 507             raptor_fire_cannon(self.gun1, "fire1");
 508         else
 509             raptor_fire_cannon(self.gun2, "fire1");
 510
 511         raptor.vehicle_energy -= autocvar_g_vehicle_raptor_cannon_cost;
 512         raptor.attack_finished_single = time + autocvar_g_vehicle_raptor_cannon_refire;
 513         self.cnt = time;
 514     }
 515
 516     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 517         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_raptor_shield, autocvar_g_vehicle_raptor_shield_regen_pause, autocvar_g_vehicle_raptor_shield_regen, frametime);
 518
 519     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 520         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_raptor_health, autocvar_g_vehicle_raptor_health_regen_pause, autocvar_g_vehicle_raptor_health_regen, frametime);
 521
 522     if(self.vehicle_flags  & VHF_ENERGYREGEN)
 523         vehicles_regen(cnt, vehicle_energy, autocvar_g_vehicle_raptor_energy, autocvar_g_vehicle_raptor_energy_regen_pause, autocvar_g_vehicle_raptor_energy_regen, frametime);
 524
 525     player.vehicle_energy = raptor.vehicle_energy / autocvar_g_vehicle_raptor_energy;
 526
 527
 528     if(time > raptor.delay)
 529     {
 530         if(player.BUTTON_ATCK2)
 531         {
 532             raptor_bombdrop();
 533             raptor.delay = time + autocvar_g_vehicle_raptor_bombs_refire;
 534         }
 535         player.vehicle_reload1 = 1;
 536     }
 537     else
 538     {
 539         player.vehicle_reload1 = min(time / raptor.delay, 1);
 540         //raptor.bomb1.alpha = raptor.bomb2.alpha = player.vehicle_reload1;
 541     }
 542
 543     VEHICLE_UPDATE_PLAYER(health, raptor);
 544
 545     if(self.vehicle_flags & VHF_HASSHIELD)
 546         VEHICLE_UPDATE_PLAYER(shield, raptor);
 547
 548     player.BUTTON_ATCK = player.BUTTON_ATCK2 = player.BUTTON_CROUCH = 0;
 549     return 1;
 550 }
 551
 552 void raptor_touch()
 553 {
 554     vehicles_touch();
 555     if(self.owner)
 556     {
 557         if(vlen(self.velocity) == 0)
 558             return;
 559
 560         if(other.classname != "player")
 561             return;
 562
 563         return;
 564     }
 565
 566     if(other.classname != "player")
 567         return;
 568
 569     if(other.deadflag != DEAD_NO)
 570         return;
 571
 572     if(other.vehicle != world)
 573         return;
 574
 575     vehicles_enter();
 576 }
 577
 578 void raptor_blowup()
 579 {
 580     sound (self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 581     pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 582
 583     self.deadflag    = DEAD_DEAD;
 584     self.vehicle_exit(VHEF_NORMAL);
 585     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_WAKIBLOWUP, world);
 586
 587     self.alpha          = -1;
 588     self.movetype       = MOVETYPE_NONE;
 589     self.effects        = EF_NODRAW;
 590     self.colormod       = '0 0 0';
 591     self.avelocity      = '0 0 0';
 592     self.velocity       = '0 0 0';
 593
 594     setorigin(self, self.pos1);
 595     self.touch = SUB_Null;
 596 }
 597
 598 void raptor_die()
 599 {
 600     self.health       = 0;
 601     self.event_damage = SUB_Null;
 602     self.iscreature   = FALSE;
 603     self.solid        = SOLID_CORPSE;
 604     self.takedamage   = DAMAGE_NO;
 605     self.deadflag     = DEAD_DYING;
 606     self.movetype     = MOVETYPE_BOUNCE;
 607     //self.wait         = time;
 608
 609     pointparticles(particleeffectnum("rocket_explode"), findbetterlocation (self.origin, 16), '0 0 0', 1);
 610
 611     self.velocity_z += 128;
 612
 613     if(random() < 0.5)
 614         self.avelocity_z  = 45 + random() * 270;
 615     else
 616         self.avelocity_z  = -45 + random() * -270;
 617
 618     self.colormod = '-0.5 -0.5 -0.5';
 619
 620         self.touch     = raptor_blowup;
 621         self.think     = raptor_spawn;
 622         self.nextthink = time + autocvar_g_vehicle_raptor_respawntime;
 623 }
 624
 625 void raptor_spawn()
 626 {
 627     self.flags     = FL_NOTARGET;
 628     self.effects   = 0;
 629
 630     self.vehicle_health = autocvar_g_vehicle_raptor_health;
 631     self.vehicle_shield = autocvar_g_vehicle_raptor_shield;
 632     self.event_damage   = vehicles_damage;
 633     self.touch          = raptor_touch;
 634     self.iscreature     = TRUE;
 635     self.movetype       = MOVETYPE_FLY;
 636     self.solid          = SOLID_SLIDEBOX;
 637     self.takedamage     = DAMAGE_AIM;
 638         self.deadflag       = DEAD_NO;
 639     self.bot_attack     = TRUE;
 640     self.vehicle_energy = 1;
 641     self.vehicle_hudmodel.viewmodelforclient = self;
 642
 643     self.bomb1.gun1.avelocity_y = 90;
 644     self.bomb1.gun2.avelocity_y = -90;
 645     self.frame = 0;
 646
 647     setorigin(self, self.pos1);
 648     self.angles = self.pos2;
 649
 650     setsize(self, RAPTOR_MIN, RAPTOR_MAX );
 651     pointparticles(particleeffectnum("teleport"), self.origin + '0 0 64', '0 0 0', 1);
 652     self.delay = time;
 653
 654     vehicles_reset_colors();
 655 }
 656
 657 void raptor_dinit()
 658 {
 659     entity spinner;
 660     vector ofs;
 661
 662     if not (vehicle_initialize(
 663              "Raptor",
 664              "models/vehicles/raptor.dpm",
 665              "",
 666              "models/vehicles/raptor_cockpit.dpm",
 667              "", "tag_hud", "tag_camera",
 668              HUD_RAPTOR,
 669              RAPTOR_MIN, RAPTOR_MAX,
 670              FALSE,
 671              raptor_spawn, raptor_frame,
 672              raptor_enter, raptor_exit,
 673              raptor_die,   raptor_think))
 674     {
 675         remove(self);
 676         return;
 677     }
 678
 679     //FIXME: Camera is in a bad place in HUD model.
 680     setorigin(self.vehicle_viewport, '5 0 5');
 681
 682     self.frame = 0;
 683
 684     self.bomb1 = spawn();
 685     self.bomb2 = spawn();
 686     self.gun1  = spawn();
 687     self.gun2  = spawn();
 688
 689 #ifdef RAPTOR_RETARDCAMERA
 690     setattachment(self.vehicle_viewport, world, "");
 691 #endif
 692
 693     setmodel(self.bomb1,"models/vehicles/raptor_bomb.dpm");
 694     setmodel(self.bomb2,"models/vehicles/raptor_bomb.dpm");
 695     setmodel(self.gun1, "models/vehicles/raptor_gun.dpm");
 696     setmodel(self.gun2, "models/vehicles/raptor_gun.dpm");
 697
 698     setattachment(self.bomb1, self,"bombmount_left");
 699     setattachment(self.bomb2, self,"bombmount_right");
 700
 701
 702     // FIXME Guns mounts to angled bones
 703     self.bomb1.angles = self.angles;
 704     self.angles = '0 0 0';
 705     // This messes up gun-aim, so work arround it.
 706     //setattachment(self.gun1, self, "gunmount_left");
 707     ofs = gettaginfo(self, gettagindex(self, "gunmount_left"));
 708     ofs -= self.origin;
 709     setattachment(self.gun1, self, "");
 710     setorigin(self.gun1, ofs);
 711
 712     //setattachment(self.gun2, self, "gunmount_right");
 713     ofs = gettaginfo(self, gettagindex(self, "gunmount_right"));
 714     ofs -= self.origin;
 715     setattachment(self.gun2, self, "");
 716     setorigin(self.gun2, ofs);
 717
 718     self.angles = self.bomb1.angles;
 719     self.bomb1.angles = '0 0 0';
 720
 721
 722     spinner = spawn();
 723     spinner.owner = self;
 724     setmodel(spinner,"models/vehicles/spinner.dpm");
 725     setattachment(spinner, self, "engine_left");
 726     spinner.movetype = MOVETYPE_NOCLIP;
 727     spinner.avelocity = '0 90 0';
 728     self.bomb1.gun1 = spinner;
 729
 730     spinner = spawn();
 731     spinner.owner = self;
 732     setmodel(spinner,"models/vehicles/spinner.dpm");
 733     setattachment(spinner, self, "engine_right");
 734     spinner.movetype = MOVETYPE_NOCLIP;
 735     spinner.avelocity = '0 -90 0';
 736     self.bomb1.gun2 = spinner;
 737
 738     self.mass               = 2200;
 739 }
 740
 741 void spawnfunc_vehicle_raptor()
 742 {
 743     vehicles_configcheck("vehicle_raptor.cfg", autocvar_g_vehicle_raptor_health);
 744
 745     if(autocvar_g_vehicle_raptor_shield)
 746         self.vehicle_flags |= VHF_HASSHIELD;
 747
 748     if(autocvar_g_vehicle_raptor_shield_regen)
 749         self.vehicle_flags |= VHF_SHIELDREGEN;
 750
 751     if(autocvar_g_vehicle_raptor_health_regen)
 752         self.vehicle_flags |= VHF_HEALTHREGEN;
 753
 754     if(autocvar_g_vehicle_raptor_energy_regen)
 755         self.vehicle_flags |= VHF_ENERGYREGEN;
 756
 757     precache_model ("models/vehicles/raptor.dpm");
 758     precache_model ("models/vehicles/raptor_gun.dpm");
 759     precache_model ("models/vehicles/spinner.dpm");
 760     precache_model ("models/vehicles/raptor_cockpit.dpm");
 761     precache_model ("models/vehicles/raptor_bomb.dpm");
 762
 763     self.think = raptor_dinit;
 764     self.nextthink = time + 1;
 765 }