qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_ca)
 119         {
 120                 ActivateTeamplay();
 121                 fraglimit_override = autocvar_g_ca_point_limit;
 122                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 123                 MUTATOR_ADD(gamemode_ca);
 124                 if(autocvar_g_ca_team_spawns)
 125                         have_team_spawns = -1; // request team spawns
 126         }
 127
 128         if(g_keyhunt)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 132                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 133                 MUTATOR_ADD(gamemode_keyhunt);
 134         }
 135
 136         if(g_freezetag)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_freezetag_point_limit;
 140                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_freezetag);
 142                 if(autocvar_g_freezetag_team_spawns)
 143                         have_team_spawns = -1; // request team spawns
 144         }
 145
 146         if(g_assault)
 147         {
 148                 ActivateTeamplay();
 149                 MUTATOR_ADD(gamemode_assault);
 150                 have_team_spawns = -1; // request team spawns
 151         }
 152
 153         if(g_onslaught)
 154         {
 155                 ActivateTeamplay();
 156                 have_team_spawns = -1; // request team spawns
 157                 MUTATOR_ADD(gamemode_onslaught);
 158         }
 159
 160         if(g_race)
 161         {
 162
 163                 if(autocvar_g_race_teams)
 164                 {
 165                         ActivateTeamplay();
 166                         race_teams = bound(2, autocvar_g_race_teams, 4);
 167                         have_team_spawns = -1; // request team spawns
 168                 }
 169                 else
 170                         race_teams = 0;
 171
 172                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 173                 fraglimit_override = autocvar_g_race_laps_limit;
 174                 leadlimit_override = 0; // currently not supported by race
 175         }
 176
 177         if(g_cts)
 178         {
 179                 g_race_qualifying = 1;
 180                 fraglimit_override = 0;
 181                 leadlimit_override = 0;
 182         }
 183
 184         if(g_nexball)
 185         {
 186         fraglimit_override = autocvar_g_nexball_goallimit;
 187         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 188         ActivateTeamplay();
 189         have_team_spawns = -1; // request team spawns
 190             MUTATOR_ADD(gamemode_nexball);
 191         }
 192
 193         if(g_keepaway)
 194         {
 195                 MUTATOR_ADD(gamemode_keepaway);
 196         }
 197
 198         if(g_invasion)
 199         {
 200                 timelimit_override = 0; // no timelimit in invasion, round based
 201                 fraglimit_override = autocvar_g_invasion_round_limit;
 202                 MUTATOR_ADD(gamemode_invasion);
 203         }
 204
 205         if(teamplay)
 206                 entcs_init();
 207
 208         cache_mutatormsg = strzone("");
 209         cache_lastmutatormsg = strzone("");
 210
 211         // enforce the server's universal frag/time limits
 212         if(!autocvar_g_campaign)
 213         {
 214                 if(fraglimit_override >= 0)
 215                         cvar_set("fraglimit", ftos(fraglimit_override));
 216                 if(timelimit_override >= 0)
 217                         cvar_set("timelimit", ftos(timelimit_override));
 218                 if(leadlimit_override >= 0)
 219                         cvar_set("leadlimit", ftos(leadlimit_override));
 220                 if(qualifying_override >= 0)
 221                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 222         }
 223
 224         if(g_race)
 225         {
 226                 // we need to find out the correct value for g_race_qualifying
 227                 if(autocvar_g_campaign)
 228                 {
 229                         g_race_qualifying = 1;
 230                 }
 231                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 232                 {
 233                         g_race_qualifying = 2;
 234                         race_fraglimit = autocvar_fraglimit;
 235                         race_leadlimit = autocvar_leadlimit;
 236                         race_timelimit = autocvar_timelimit;
 237                         cvar_set("fraglimit", "0");
 238                         cvar_set("leadlimit", "0");
 239                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 240                 }
 241                 else
 242                         g_race_qualifying = 0;
 243         }
 244
 245         if(g_invasion)
 246         {
 247                 inv_maxrounds = cvar("fraglimit");
 248                 cvar_set("fraglimit", "0");
 249         }
 250
 251         if(g_race || g_cts)
 252         {
 253                 if(g_race_qualifying)
 254                         independent_players = 1;
 255
 256                 ScoreRules_race();
 257         }
 258
 259         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 260 }
 261
 262 string GetClientVersionMessage() {
 263         string versionmsg;
 264         if (self.version_mismatch) {
 265                 if(self.version < autocvar_gameversion) {
 266                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 267                 } else {
 268                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 269                 }
 270         } else {
 271                 versionmsg = "^2client version and server version are compatible.^8";
 272         }
 273         return versionmsg;
 274 }
 275
 276 string getwelcomemessage(void)
 277 {
 278         string s, modifications, motd;
 279
 280         ret_string = "";
 281         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 282         modifications = ret_string;
 283
 284         if(g_weaponarena)
 285         {
 286                 if(g_weaponarena_random)
 287                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 288                 else
 289                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 290         }
 291         if(autocvar_g_start_weapon_laser == 0)
 292                 modifications = strcat(modifications, ", No start weapons");
 293         if(autocvar_sv_gravity < 800)
 294                 modifications = strcat(modifications, ", Low gravity");
 295         if(g_cloaked && !g_cts)
 296                 modifications = strcat(modifications, ", Cloaked");
 297         if(g_grappling_hook)
 298                 modifications = strcat(modifications, ", Hook");
 299         if(g_weapon_stay && !g_cts)
 300                 modifications = strcat(modifications, ", Weapons stay");
 301         if(g_jetpack)
 302                 modifications = strcat(modifications, ", Jet pack");
 303         if(autocvar_g_powerups == 0)
 304                 modifications = strcat(modifications, ", No powerups");
 305         if(autocvar_g_powerups > 0)
 306                 modifications = strcat(modifications, ", Powerups");
 307         modifications = substring(modifications, 2, strlen(modifications) - 2);
 308
 309         string versionmessage;
 310         versionmessage = GetClientVersionMessage();
 311
 312         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 313         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 314
 315         if(modifications != "")
 316                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 317
 318         if (g_grappling_hook)
 319                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 320
 321         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 322         {
 323                 if(cache_lastmutatormsg)
 324                         strunzone(cache_lastmutatormsg);
 325                 if(cache_mutatormsg)
 326                         strunzone(cache_mutatormsg);
 327                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 328                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 329         }
 330
 331         if (cache_mutatormsg != "") {
 332                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 333         }
 334
 335         motd = autocvar_sv_motd;
 336         if (motd != "") {
 337                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 338         }
 339         return s;
 340 }
 341
 342 void SetPlayerColors(entity pl, float _color)
 343 {
 344         /*string s;
 345         s = ftos(cl);
 346         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 347         pl.team = cl + 1;
 348         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 349         pl.clientcolors = 16*cl + cl;*/
 350
 351         float pants, shirt;
 352         pants = _color & 0x0F;
 353         shirt = _color & 0xF0;
 354
 355
 356         if(teamplay) {
 357                 setcolor(pl, 16*pants + pants);
 358         } else {
 359                 setcolor(pl, shirt + pants);
 360         }
 361 }
 362
 363 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 364 {
 365         float _color;
 366
 367         if(t == 4)
 368                 _color = NUM_TEAM_4 - 1;
 369         else if(t == 3)
 370                 _color = NUM_TEAM_3 - 1;
 371         else if(t == 2)
 372                 _color = NUM_TEAM_2 - 1;
 373         else
 374                 _color = NUM_TEAM_1 - 1;
 375
 376         SetPlayerColors(pl,_color);
 377
 378         if(t != s) {
 379                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 380
 381                 if(!noprint)
 382                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 383         }
 384
 385 }
 386
 387 // set c1...c4 to show what teams are allowed
 388 void CheckAllowedTeams (entity for_whom)
 389 {
 390         float dm;
 391         entity head;
 392         string teament_name;
 393
 394         c1 = c2 = c3 = c4 = -1;
 395         cb1 = cb2 = cb3 = cb4 = 0;
 396
 397         teament_name = string_null;
 398         if(g_onslaught)
 399         {
 400                 // onslaught is special
 401                 head = findchain(classname, "onslaught_generator");
 402                 while (head)
 403                 {
 404                         if (head.team == NUM_TEAM_1) c1 = 0;
 405                         if (head.team == NUM_TEAM_2) c2 = 0;
 406                         if (head.team == NUM_TEAM_3) c3 = 0;
 407                         if (head.team == NUM_TEAM_4) c4 = 0;
 408                         head = head.chain;
 409                 }
 410         }
 411         else if(g_domination)
 412                 teament_name = "dom_team";
 413         else if(g_ctf)
 414                 teament_name = "ctf_team";
 415         else if(g_tdm)
 416                 teament_name = "tdm_team";
 417         else if(g_nexball)
 418                 teament_name = "nexball_team";
 419         else if(g_assault)
 420                 c1 = c2 = 0; // Assault always has 2 teams
 421         else
 422         {
 423                 // cover anything else by treating it like tdm with no teams spawned
 424                 if(g_race)
 425                         dm = race_teams;
 426                 else
 427                         dm = 2;
 428
 429                 ret_float = dm;
 430                 MUTATOR_CALLHOOK(GetTeamCount);
 431                 dm = ret_float;
 432
 433                 if(dm >= 4)
 434                         c1 = c2 = c3 = c4 = 0;
 435                 else if(dm >= 3)
 436                         c1 = c2 = c3 = 0;
 437                 else
 438                         c1 = c2 = 0;
 439         }
 440
 441         // find out what teams are allowed if necessary
 442         if(teament_name)
 443         {
 444                 head = find(world, classname, teament_name);
 445                 while(head)
 446                 {
 447                         if(!(g_domination && head.netname == ""))
 448                         {
 449                                 if(head.team == NUM_TEAM_1)
 450                                         c1 = 0;
 451                                 else if(head.team == NUM_TEAM_2)
 452                                         c2 = 0;
 453                                 else if(head.team == NUM_TEAM_3)
 454                                         c3 = 0;
 455                                 else if(head.team == NUM_TEAM_4)
 456                                         c4 = 0;
 457                         }
 458                         head = find(head, classname, teament_name);
 459                 }
 460         }
 461
 462         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 463         if(c3==-1 && c4==-1)
 464         if(autocvar_bot_vs_human && for_whom)
 465         {
 466                 if(autocvar_bot_vs_human > 0)
 467                 {
 468                         // bots are all blue
 469                         if(IS_BOT_CLIENT(for_whom))
 470                                 c1 = c3 = c4 = -1;
 471                         else
 472                                 c2 = -1;
 473                 }
 474                 else
 475                 {
 476                         // bots are all red
 477                         if(IS_BOT_CLIENT(for_whom))
 478                                 c2 = c3 = c4 = -1;
 479                         else
 480                                 c1 = -1;
 481                 }
 482         }
 483
 484         // if player has a forced team, ONLY allow that one
 485         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 486                 c2 = c3 = c4 = -1;
 487         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 488                 c1 = c3 = c4 = -1;
 489         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 490                 c1 = c2 = c4 = -1;
 491         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 492                 c1 = c2 = c3 = -1;
 493 }
 494
 495 float PlayerValue(entity p)
 496 {
 497         return 1;
 498         // FIXME: it always returns 1...
 499 }
 500
 501 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 502 // teams that are allowed will now have their player counts stored in c1...c4
 503 void GetTeamCounts(entity ignore)
 504 {
 505         entity head;
 506         float value, bvalue;
 507         // now count how many players are on each team already
 508
 509         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 510         // also remember the lowest-scoring player
 511
 512         FOR_EACH_CLIENT(head)
 513         {
 514                 float t;
 515                 if(IS_PLAYER(head))
 516                         t = head.team;
 517                 else if(head.team_forced > 0)
 518                         t = head.team_forced; // reserve the spot
 519                 else
 520                         continue;
 521                 if(head != ignore)// && head.netname != "")
 522                 {
 523                         value = PlayerValue(head);
 524                         if(IS_BOT_CLIENT(head))
 525                                 bvalue = value;
 526                         else
 527                                 bvalue = 0;
 528                         if(t == NUM_TEAM_1)
 529                         {
 530                                 if(c1 >= 0)
 531                                 {
 532                                         c1 = c1 + value;
 533                                         cb1 = cb1 + bvalue;
 534                                 }
 535                         }
 536                         if(t == NUM_TEAM_2)
 537                         {
 538                                 if(c2 >= 0)
 539                                 {
 540                                         c2 = c2 + value;
 541                                         cb2 = cb2 + bvalue;
 542                                 }
 543                         }
 544                         if(t == NUM_TEAM_3)
 545                         {
 546                                 if(c3 >= 0)
 547                                 {
 548                                         c3 = c3 + value;
 549                                         cb3 = cb3 + bvalue;
 550                                 }
 551                         }
 552                         if(t == NUM_TEAM_4)
 553                         {
 554                                 if(c4 >= 0)
 555                                 {
 556                                         c4 = c4 + value;
 557                                         cb4 = cb4 + bvalue;
 558                                 }
 559                         }
 560                 }
 561         }
 562
 563         // if the player who has a forced team has not joined yet, reserve the spot
 564         if(autocvar_g_campaign)
 565         {
 566                 switch(autocvar_g_campaign_forceteam)
 567                 {
 568                         case 1: if(c1 == cb1) ++c1; break;
 569                         case 2: if(c2 == cb2) ++c2; break;
 570                         case 3: if(c3 == cb3) ++c3; break;
 571                         case 4: if(c4 == cb4) ++c4; break;
 572                 }
 573         }
 574 }
 575
 576 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 577 {
 578         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 579         float f;
 580         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 581
 582         switch(ta)
 583         {
 584                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 585                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 586                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 587                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 588         }
 589         switch(tb)
 590         {
 591                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 592                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 593                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 594                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 595         }
 596
 597         // invalid
 598         if(ca < 0 || cb < 0)
 599                 return FALSE;
 600
 601         // equal
 602         if(ta == tb)
 603                 return TRUE;
 604
 605         if(IS_REAL_CLIENT(e))
 606         {
 607                 if(bots_would_leave)
 608                 {
 609                         ca -= cba * 0.999;
 610                         cb -= cbb * 0.999;
 611                 }
 612         }
 613
 614         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 615         if(ca < 1)
 616                 if(cb >= 1)
 617                         return TRUE;
 618         if(ca >= 1)
 619                 if(cb < 1)
 620                         return FALSE;
 621
 622         // first, normalize
 623         f = max(ca, cb, 1);
 624         ca /= f;
 625         cb /= f;
 626         f = max(sa, sb, 1);
 627         sa /= f;
 628         sb /= f;
 629
 630         // the more we're at the end of the match, the more take scores into account
 631         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 632         ca += (sa - ca) * f;
 633         cb += (sb - cb) * f;
 634
 635         return ca <= cb;
 636 }
 637
 638 // returns # of smallest team (1, 2, 3, 4)
 639 // NOTE: Assumes CheckAllowedTeams has already been called!
 640 float FindSmallestTeam(entity pl, float ignore_pl)
 641 {
 642         float totalteams, t;
 643         totalteams = 0;
 644
 645         // find out what teams are available
 646         //CheckAllowedTeams();
 647
 648         // make sure there are at least 2 teams to join
 649         if(c1 >= 0)
 650                 totalteams = totalteams + 1;
 651         if(c2 >= 0)
 652                 totalteams = totalteams + 1;
 653         if(c3 >= 0)
 654                 totalteams = totalteams + 1;
 655         if(c4 >= 0)
 656                 totalteams = totalteams + 1;
 657
 658         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 659                 totalteams += 1;
 660
 661         if(totalteams <= 1)
 662         {
 663                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 664                         return 1; // special case for campaign and player joining
 665                 else if(g_domination)
 666                         error("Too few teams available for domination\n");
 667                 else if(g_ctf)
 668                         error("Too few teams available for ctf\n");
 669                 else if(g_keyhunt)
 670                         error("Too few teams available for key hunt\n");
 671                 else if(g_freezetag)
 672                         error("Too few teams available for freeze tag\n");
 673                 else
 674                         error("Too few teams available for team deathmatch\n");
 675         }
 676
 677         // count how many players are in each team
 678         if(ignore_pl)
 679                 GetTeamCounts(pl);
 680         else
 681                 GetTeamCounts(world);
 682
 683         RandomSelection_Init();
 684
 685         t = 1;
 686         if(TeamSmallerEqThanTeam(2, t, pl))
 687                 t = 2;
 688         if(TeamSmallerEqThanTeam(3, t, pl))
 689                 t = 3;
 690         if(TeamSmallerEqThanTeam(4, t, pl))
 691                 t = 4;
 692
 693         // now t is the minimum, or A minimum!
 694         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 695                 RandomSelection_Add(world, 1, string_null, 1, 1);
 696         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 697                 RandomSelection_Add(world, 2, string_null, 1, 1);
 698         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 699                 RandomSelection_Add(world, 3, string_null, 1, 1);
 700         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 701                 RandomSelection_Add(world, 4, string_null, 1, 1);
 702
 703         return RandomSelection_chosen_float;
 704 }
 705
 706 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 707 {
 708         float smallest, selectedteam;
 709
 710         // don't join a team if we're not playing a team game
 711         if(!teamplay)
 712                 return 0;
 713
 714         // find out what teams are available
 715         CheckAllowedTeams(pl);
 716
 717         // if we don't care what team he ends up on, put him on whatever team he entered as.
 718         // if he's not on a valid team, then let other code put him on the smallest team
 719         if(!forcebestteam)
 720         {
 721                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 722                         selectedteam = pl.team;
 723                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 724                         selectedteam = pl.team;
 725                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 726                         selectedteam = pl.team;
 727                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 728                         selectedteam = pl.team;
 729                 else
 730                         selectedteam = -1;
 731
 732                 if(selectedteam > 0)
 733                 {
 734                         if(!only_return_best)
 735                         {
 736                                 SetPlayerColors(pl, selectedteam - 1);
 737
 738                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 739                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 740                                 LogTeamchange(pl.playerid, pl.team, 99);
 741                         }
 742                         return selectedteam;
 743                 }
 744                 // otherwise end up on the smallest team (handled below)
 745         }
 746
 747         smallest = FindSmallestTeam(pl, TRUE);
 748
 749         if(!only_return_best && !pl.bot_forced_team)
 750         {
 751                 TeamchangeFrags(self);
 752                 if(smallest == 1)
 753                 {
 754                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 755                 }
 756                 else if(smallest == 2)
 757                 {
 758                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 759                 }
 760                 else if(smallest == 3)
 761                 {
 762                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 763                 }
 764                 else if(smallest == 4)
 765                 {
 766                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 767                 }
 768                 else
 769                 {
 770                         error("smallest team: invalid team\n");
 771                 }
 772
 773                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 774
 775                 if(pl.deadflag == DEAD_NO)
 776                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 777         }
 778
 779         return smallest;
 780 }
 781
 782 //void() ctf_playerchanged;
 783 void SV_ChangeTeam(float _color)
 784 {
 785         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 786
 787         // in normal deathmatch we can just apply the color and we're done
 788         if(!teamplay) {
 789                 SetPlayerColors(self, _color);
 790                 return;
 791         }
 792
 793         scolor = self.clientcolors & 0x0F;
 794         dcolor = _color & 0x0F;
 795
 796         if(scolor == NUM_TEAM_1 - 1)
 797                 steam = 1;
 798         else if(scolor == NUM_TEAM_2 - 1)
 799                 steam = 2;
 800         else if(scolor == NUM_TEAM_3 - 1)
 801                 steam = 3;
 802         else // if(scolor == NUM_TEAM_4 - 1)
 803                 steam = 4;
 804         if(dcolor == NUM_TEAM_1 - 1)
 805                 dteam = 1;
 806         else if(dcolor == NUM_TEAM_2 - 1)
 807                 dteam = 2;
 808         else if(dcolor == NUM_TEAM_3 - 1)
 809                 dteam = 3;
 810         else // if(dcolor == NUM_TEAM_4 - 1)
 811                 dteam = 4;
 812
 813         CheckAllowedTeams(self);
 814
 815         if(dteam == 1 && c1 < 0) dteam = 4;
 816         if(dteam == 4 && c4 < 0) dteam = 3;
 817         if(dteam == 3 && c3 < 0) dteam = 2;
 818         if(dteam == 2 && c2 < 0) dteam = 1;
 819
 820         // not changing teams
 821         if(scolor == dcolor)
 822         {
 823                 //bprint("same team change\n");
 824                 SetPlayerTeam(self, dteam, steam, TRUE);
 825                 return;
 826         }
 827
 828         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 829                 sprint(self, "Team changes not allowed\n");
 830                 return; // changing teams is not allowed
 831         }
 832
 833         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 834         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 835         {
 836                 GetTeamCounts(self);
 837                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 838                 {
 839                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 840                         return;
 841                 }
 842         }
 843
 844 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 845
 846         if(IS_PLAYER(self) && steam != dteam)
 847         {
 848                 // reduce frags during a team change
 849                 TeamchangeFrags(self);
 850         }
 851
 852         SetPlayerTeam(self, dteam, steam, FALSE);
 853
 854         if(IS_PLAYER(self) && steam != dteam)
 855         {
 856                 // kill player when changing teams
 857                 if(self.deadflag == DEAD_NO)
 858                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 859         }
 860 }
 861
 862 void ShufflePlayerOutOfTeam (float source_team)
 863 {
 864         float smallestteam, smallestteam_count, steam;
 865         float lowest_bot_score, lowest_player_score;
 866         entity head, lowest_bot, lowest_player, selected;
 867
 868         smallestteam = 0;
 869         smallestteam_count = 999999999;
 870
 871         if(c1 >= 0 && c1 < smallestteam_count)
 872         {
 873                 smallestteam = 1;
 874                 smallestteam_count = c1;
 875         }
 876         if(c2 >= 0 && c2 < smallestteam_count)
 877         {
 878                 smallestteam = 2;
 879                 smallestteam_count = c2;
 880         }
 881         if(c3 >= 0 && c3 < smallestteam_count)
 882         {
 883                 smallestteam = 3;
 884                 smallestteam_count = c3;
 885         }
 886         if(c4 >= 0 && c4 < smallestteam_count)
 887         {
 888                 smallestteam = 4;
 889                 smallestteam_count = c4;
 890         }
 891
 892         if(!smallestteam)
 893         {
 894                 bprint("warning: no smallest team\n");
 895                 return;
 896         }
 897
 898         if(source_team == 1)
 899                 steam = NUM_TEAM_1;
 900         else if(source_team == 2)
 901                 steam = NUM_TEAM_2;
 902         else if(source_team == 3)
 903                 steam = NUM_TEAM_3;
 904         else // if(source_team == 4)
 905                 steam = NUM_TEAM_4;
 906
 907         lowest_bot = world;
 908         lowest_bot_score = 999999999;
 909         lowest_player = world;
 910         lowest_player_score = 999999999;
 911
 912         // find the lowest-scoring player & bot of that team
 913         FOR_EACH_PLAYER(head)
 914         {
 915                 if(head.team == steam)
 916                 {
 917                         if(head.isbot)
 918                         {
 919                                 if(head.totalfrags < lowest_bot_score)
 920                                 {
 921                                         lowest_bot = head;
 922                                         lowest_bot_score = head.totalfrags;
 923                                 }
 924                         }
 925                         else
 926                         {
 927                                 if(head.totalfrags < lowest_player_score)
 928                                 {
 929                                         lowest_player = head;
 930                                         lowest_player_score = head.totalfrags;
 931                                 }
 932                         }
 933                 }
 934         }
 935
 936         // prefers to move a bot...
 937         if(lowest_bot != world)
 938                 selected = lowest_bot;
 939         // but it will move a player if it has to
 940         else
 941                 selected = lowest_player;
 942         // don't do anything if it couldn't find anyone
 943         if(!selected)
 944         {
 945                 bprint("warning: couldn't find a player to move from team\n");
 946                 return;
 947         }
 948
 949         // smallest team gains a member
 950         if(smallestteam == 1)
 951         {
 952                 c1 = c1 + 1;
 953         }
 954         else if(smallestteam == 2)
 955         {
 956                 c2 = c2 + 1;
 957         }
 958         else if(smallestteam == 3)
 959         {
 960                 c3 = c3 + 1;
 961         }
 962         else if(smallestteam == 4)
 963         {
 964                 c4 = c4 + 1;
 965         }
 966         else
 967         {
 968                 bprint("warning: destination team invalid\n");
 969                 return;
 970         }
 971         // source team loses a member
 972         if(source_team == 1)
 973         {
 974                 c1 = c1 + 1;
 975         }
 976         else if(source_team == 2)
 977         {
 978                 c2 = c2 + 2;
 979         }
 980         else if(source_team == 3)
 981         {
 982                 c3 = c3 + 3;
 983         }
 984         else if(source_team == 4)
 985         {
 986                 c4 = c4 + 4;
 987         }
 988         else
 989         {
 990                 bprint("warning: source team invalid\n");
 991                 return;
 992         }
 993
 994         // move the player to the new team
 995         TeamchangeFrags(selected);
 996         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 997
 998         if(selected.deadflag == DEAD_NO)
 999                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1000         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1001 }
1002
1003 // code from here on is just to support maps that don't have team entities
1004 void tdm_spawnteam (string teamname, float teamcolor)
1005 {
1006         entity e;
1007         e = spawn();
1008         e.classname = "tdm_team";
1009         e.netname = teamname;
1010         e.cnt = teamcolor;
1011         e.team = e.cnt + 1;
1012 }
1013
1014 // spawn some default teams if the map is not set up for tdm
1015 void tdm_spawnteams()
1016 {
1017         float numteams;
1018
1019         numteams = autocvar_g_tdm_teams_override;
1020         if(numteams < 2)
1021                 numteams = autocvar_g_tdm_teams;
1022         numteams = bound(2, numteams, 4);
1023
1024         tdm_spawnteam("Red", NUM_TEAM_1-1);
1025         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1026         if(numteams >= 3)
1027                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1028         if(numteams >= 4)
1029                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1030 }
1031
1032 void tdm_delayedinit()
1033 {
1034         // if no teams are found, spawn defaults
1035         if (find(world, classname, "tdm_team") == world)
1036                 tdm_spawnteams();
1037 }
1038
1039 void tdm_init()
1040 {
1041         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1042 }