qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_ca)
 119         {
 120                 ActivateTeamplay();
 121                 fraglimit_override = autocvar_g_ca_point_limit;
 122                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 123                 MUTATOR_ADD(gamemode_ca);
 124                 if(autocvar_g_ca_team_spawns)
 125                         have_team_spawns = -1; // request team spawns
 126         }
 127
 128         if(g_keyhunt)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 132                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 133                 MUTATOR_ADD(gamemode_keyhunt);
 134         }
 135
 136         if(g_freezetag)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_freezetag_point_limit;
 140                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_freezetag);
 142                 if(autocvar_g_freezetag_team_spawns)
 143                         have_team_spawns = -1; // request team spawns
 144         }
 145
 146         if(g_assault)
 147         {
 148                 ActivateTeamplay();
 149                 MUTATOR_ADD(gamemode_assault);
 150                 have_team_spawns = -1; // request team spawns
 151         }
 152
 153         if(g_onslaught)
 154         {
 155                 ActivateTeamplay();
 156                 have_team_spawns = -1; // request team spawns
 157                 MUTATOR_ADD(gamemode_onslaught);
 158         }
 159
 160         if(g_race)
 161         {
 162
 163                 if(autocvar_g_race_teams)
 164                 {
 165                         ActivateTeamplay();
 166                         race_teams = bound(2, autocvar_g_race_teams, 4);
 167                         have_team_spawns = -1; // request team spawns
 168                 }
 169                 else
 170                         race_teams = 0;
 171
 172                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 173                 fraglimit_override = autocvar_g_race_laps_limit;
 174                 leadlimit_override = 0; // currently not supported by race
 175         }
 176
 177         if(g_cts)
 178         {
 179                 g_race_qualifying = 1;
 180                 fraglimit_override = 0;
 181                 leadlimit_override = 0;
 182         }
 183
 184         if(g_nexball)
 185         {
 186         fraglimit_override = autocvar_g_nexball_goallimit;
 187         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 188         ActivateTeamplay();
 189         have_team_spawns = -1; // request team spawns
 190             MUTATOR_ADD(gamemode_nexball);
 191         }
 192
 193         if(g_keepaway)
 194         {
 195                 MUTATOR_ADD(gamemode_keepaway);
 196         }
 197
 198         if(g_invasion)
 199         {
 200                 fraglimit_override = autocvar_g_invasion_point_limit;
 201                 if(autocvar_g_invasion_teams >= 2)
 202                 {
 203                         ActivateTeamplay();
 204                         if(autocvar_g_invasion_team_spawns)
 205                                 have_team_spawns = -1; // request team spawns
 206                 }
 207                 MUTATOR_ADD(gamemode_invasion);
 208         }
 209
 210         if(teamplay)
 211                 entcs_init();
 212
 213         cache_mutatormsg = strzone("");
 214         cache_lastmutatormsg = strzone("");
 215
 216         // enforce the server's universal frag/time limits
 217         if(!autocvar_g_campaign)
 218         {
 219                 if(fraglimit_override >= 0)
 220                         cvar_set("fraglimit", ftos(fraglimit_override));
 221                 if(timelimit_override >= 0)
 222                         cvar_set("timelimit", ftos(timelimit_override));
 223                 if(leadlimit_override >= 0)
 224                         cvar_set("leadlimit", ftos(leadlimit_override));
 225                 if(qualifying_override >= 0)
 226                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 227         }
 228
 229         if(g_race)
 230         {
 231                 // we need to find out the correct value for g_race_qualifying
 232                 if(autocvar_g_campaign)
 233                 {
 234                         g_race_qualifying = 1;
 235                 }
 236                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 237                 {
 238                         g_race_qualifying = 2;
 239                         race_fraglimit = autocvar_fraglimit;
 240                         race_leadlimit = autocvar_leadlimit;
 241                         race_timelimit = autocvar_timelimit;
 242                         cvar_set("fraglimit", "0");
 243                         cvar_set("leadlimit", "0");
 244                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 245                 }
 246                 else
 247                         g_race_qualifying = 0;
 248         }
 249
 250         if(g_race || g_cts)
 251         {
 252                 if(g_race_qualifying)
 253                         independent_players = 1;
 254
 255                 ScoreRules_race();
 256         }
 257
 258         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 259 }
 260
 261 string GetClientVersionMessage() {
 262         string versionmsg;
 263         if (self.version_mismatch) {
 264                 if(self.version < autocvar_gameversion) {
 265                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 266                 } else {
 267                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 268                 }
 269         } else {
 270                 versionmsg = "^2client version and server version are compatible.^8";
 271         }
 272         return versionmsg;
 273 }
 274
 275 string getwelcomemessage(void)
 276 {
 277         string s, modifications, motd;
 278
 279         ret_string = "";
 280         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 281         modifications = ret_string;
 282
 283         if(g_weaponarena)
 284         {
 285                 if(g_weaponarena_random)
 286                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 287                 else
 288                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 289         }
 290         if(cvar("g_balance_blaster_weaponstart") == 0)
 291                 modifications = strcat(modifications, ", No start weapons");
 292         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 293                 modifications = strcat(modifications, ", Low gravity");
 294         if(g_cloaked && !g_cts)
 295                 modifications = strcat(modifications, ", Cloaked");
 296         if(g_grappling_hook)
 297                 modifications = strcat(modifications, ", Hook");
 298         if(g_weapon_stay && !g_cts)
 299                 modifications = strcat(modifications, ", Weapons stay");
 300         if(g_jetpack)
 301                 modifications = strcat(modifications, ", Jet pack");
 302         if(autocvar_g_powerups == 0)
 303                 modifications = strcat(modifications, ", No powerups");
 304         if(autocvar_g_powerups > 0)
 305                 modifications = strcat(modifications, ", Powerups");
 306         modifications = substring(modifications, 2, strlen(modifications) - 2);
 307
 308         string versionmessage;
 309         versionmessage = GetClientVersionMessage();
 310
 311         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 312         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 313
 314         if(modifications != "")
 315                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 316
 317         if (g_grappling_hook)
 318                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 319
 320         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 321         {
 322                 if(cache_lastmutatormsg)
 323                         strunzone(cache_lastmutatormsg);
 324                 if(cache_mutatormsg)
 325                         strunzone(cache_mutatormsg);
 326                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 327                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 328         }
 329
 330         if (cache_mutatormsg != "") {
 331                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 332         }
 333
 334         motd = autocvar_sv_motd;
 335         if (motd != "") {
 336                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 337         }
 338         return s;
 339 }
 340
 341 void SetPlayerColors(entity pl, float _color)
 342 {
 343         /*string s;
 344         s = ftos(cl);
 345         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 346         pl.team = cl + 1;
 347         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 348         pl.clientcolors = 16*cl + cl;*/
 349
 350         float pants, shirt;
 351         pants = _color & 0x0F;
 352         shirt = _color & 0xF0;
 353
 354
 355         if(teamplay) {
 356                 setcolor(pl, 16*pants + pants);
 357         } else {
 358                 setcolor(pl, shirt + pants);
 359         }
 360 }
 361
 362 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 363 {
 364         float _color;
 365
 366         if(t == 4)
 367                 _color = NUM_TEAM_4 - 1;
 368         else if(t == 3)
 369                 _color = NUM_TEAM_3 - 1;
 370         else if(t == 2)
 371                 _color = NUM_TEAM_2 - 1;
 372         else
 373                 _color = NUM_TEAM_1 - 1;
 374
 375         SetPlayerColors(pl,_color);
 376
 377         if(t != s) {
 378                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 379
 380                 if(!noprint)
 381                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 382         }
 383
 384 }
 385
 386 // set c1...c4 to show what teams are allowed
 387 void CheckAllowedTeams (entity for_whom)
 388 {
 389         float dm;
 390         entity head;
 391         string teament_name;
 392
 393         c1 = c2 = c3 = c4 = -1;
 394         cb1 = cb2 = cb3 = cb4 = 0;
 395
 396         teament_name = string_null;
 397         if(g_onslaught)
 398         {
 399                 // onslaught is special
 400                 head = findchain(classname, "onslaught_generator");
 401                 while (head)
 402                 {
 403                         if (head.team == NUM_TEAM_1) c1 = 0;
 404                         if (head.team == NUM_TEAM_2) c2 = 0;
 405                         if (head.team == NUM_TEAM_3) c3 = 0;
 406                         if (head.team == NUM_TEAM_4) c4 = 0;
 407                         head = head.chain;
 408                 }
 409         }
 410         else if(g_domination)
 411                 teament_name = "dom_team";
 412         else if(g_ctf)
 413                 teament_name = "ctf_team";
 414         else if(g_tdm)
 415                 teament_name = "tdm_team";
 416         else if(g_nexball)
 417                 teament_name = "nexball_team";
 418         else if(g_assault)
 419                 c1 = c2 = 0; // Assault always has 2 teams
 420         else
 421         {
 422                 // cover anything else by treating it like tdm with no teams spawned
 423                 if(g_race)
 424                         dm = race_teams;
 425                 else
 426                         dm = 2;
 427
 428                 ret_float = dm;
 429                 MUTATOR_CALLHOOK(GetTeamCount);
 430                 dm = ret_float;
 431
 432                 if(dm >= 4)
 433                         c1 = c2 = c3 = c4 = 0;
 434                 else if(dm >= 3)
 435                         c1 = c2 = c3 = 0;
 436                 else
 437                         c1 = c2 = 0;
 438         }
 439
 440         // find out what teams are allowed if necessary
 441         if(teament_name)
 442         {
 443                 head = find(world, classname, teament_name);
 444                 while(head)
 445                 {
 446                         if(!(g_domination && head.netname == ""))
 447                         {
 448                                 if(head.team == NUM_TEAM_1)
 449                                         c1 = 0;
 450                                 else if(head.team == NUM_TEAM_2)
 451                                         c2 = 0;
 452                                 else if(head.team == NUM_TEAM_3)
 453                                         c3 = 0;
 454                                 else if(head.team == NUM_TEAM_4)
 455                                         c4 = 0;
 456                         }
 457                         head = find(head, classname, teament_name);
 458                 }
 459         }
 460
 461         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 462         if(c3==-1 && c4==-1)
 463         if(autocvar_bot_vs_human && for_whom)
 464         {
 465                 if(autocvar_bot_vs_human > 0)
 466                 {
 467                         // bots are all blue
 468                         if(IS_BOT_CLIENT(for_whom))
 469                                 c1 = c3 = c4 = -1;
 470                         else
 471                                 c2 = -1;
 472                 }
 473                 else
 474                 {
 475                         // bots are all red
 476                         if(IS_BOT_CLIENT(for_whom))
 477                                 c2 = c3 = c4 = -1;
 478                         else
 479                                 c1 = -1;
 480                 }
 481         }
 482
 483         // if player has a forced team, ONLY allow that one
 484         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 485                 c2 = c3 = c4 = -1;
 486         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 487                 c1 = c3 = c4 = -1;
 488         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 489                 c1 = c2 = c4 = -1;
 490         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 491                 c1 = c2 = c3 = -1;
 492 }
 493
 494 float PlayerValue(entity p)
 495 {
 496         return 1;
 497         // FIXME: it always returns 1...
 498 }
 499
 500 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 501 // teams that are allowed will now have their player counts stored in c1...c4
 502 void GetTeamCounts(entity ignore)
 503 {
 504         entity head;
 505         float value, bvalue;
 506         // now count how many players are on each team already
 507
 508         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 509         // also remember the lowest-scoring player
 510
 511         FOR_EACH_CLIENT(head)
 512         {
 513                 float t;
 514                 if(IS_PLAYER(head))
 515                         t = head.team;
 516                 else if(head.team_forced > 0)
 517                         t = head.team_forced; // reserve the spot
 518                 else
 519                         continue;
 520                 if(head != ignore)// && head.netname != "")
 521                 {
 522                         value = PlayerValue(head);
 523                         if(IS_BOT_CLIENT(head))
 524                                 bvalue = value;
 525                         else
 526                                 bvalue = 0;
 527                         if(t == NUM_TEAM_1)
 528                         {
 529                                 if(c1 >= 0)
 530                                 {
 531                                         c1 = c1 + value;
 532                                         cb1 = cb1 + bvalue;
 533                                 }
 534                         }
 535                         if(t == NUM_TEAM_2)
 536                         {
 537                                 if(c2 >= 0)
 538                                 {
 539                                         c2 = c2 + value;
 540                                         cb2 = cb2 + bvalue;
 541                                 }
 542                         }
 543                         if(t == NUM_TEAM_3)
 544                         {
 545                                 if(c3 >= 0)
 546                                 {
 547                                         c3 = c3 + value;
 548                                         cb3 = cb3 + bvalue;
 549                                 }
 550                         }
 551                         if(t == NUM_TEAM_4)
 552                         {
 553                                 if(c4 >= 0)
 554                                 {
 555                                         c4 = c4 + value;
 556                                         cb4 = cb4 + bvalue;
 557                                 }
 558                         }
 559                 }
 560         }
 561
 562         // if the player who has a forced team has not joined yet, reserve the spot
 563         if(autocvar_g_campaign)
 564         {
 565                 switch(autocvar_g_campaign_forceteam)
 566                 {
 567                         case 1: if(c1 == cb1) ++c1; break;
 568                         case 2: if(c2 == cb2) ++c2; break;
 569                         case 3: if(c3 == cb3) ++c3; break;
 570                         case 4: if(c4 == cb4) ++c4; break;
 571                 }
 572         }
 573 }
 574
 575 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 576 {
 577         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 578         float f;
 579         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 580
 581         switch(ta)
 582         {
 583                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 584                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 585                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 586                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 587         }
 588         switch(tb)
 589         {
 590                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 591                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 592                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 593                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 594         }
 595
 596         // invalid
 597         if(ca < 0 || cb < 0)
 598                 return FALSE;
 599
 600         // equal
 601         if(ta == tb)
 602                 return TRUE;
 603
 604         if(IS_REAL_CLIENT(e))
 605         {
 606                 if(bots_would_leave)
 607                 {
 608                         ca -= cba * 0.999;
 609                         cb -= cbb * 0.999;
 610                 }
 611         }
 612
 613         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 614         if(ca < 1)
 615                 if(cb >= 1)
 616                         return TRUE;
 617         if(ca >= 1)
 618                 if(cb < 1)
 619                         return FALSE;
 620
 621         // first, normalize
 622         f = max(ca, cb, 1);
 623         ca /= f;
 624         cb /= f;
 625         f = max(sa, sb, 1);
 626         sa /= f;
 627         sb /= f;
 628
 629         // the more we're at the end of the match, the more take scores into account
 630         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 631         ca += (sa - ca) * f;
 632         cb += (sb - cb) * f;
 633
 634         return ca <= cb;
 635 }
 636
 637 // returns # of smallest team (1, 2, 3, 4)
 638 // NOTE: Assumes CheckAllowedTeams has already been called!
 639 float FindSmallestTeam(entity pl, float ignore_pl)
 640 {
 641         float totalteams, t;
 642         totalteams = 0;
 643
 644         // find out what teams are available
 645         //CheckAllowedTeams();
 646
 647         // make sure there are at least 2 teams to join
 648         if(c1 >= 0)
 649                 totalteams = totalteams + 1;
 650         if(c2 >= 0)
 651                 totalteams = totalteams + 1;
 652         if(c3 >= 0)
 653                 totalteams = totalteams + 1;
 654         if(c4 >= 0)
 655                 totalteams = totalteams + 1;
 656
 657         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 658                 totalteams += 1;
 659
 660         if(totalteams <= 1)
 661         {
 662                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 663                         return 1; // special case for campaign and player joining
 664                 else if(g_domination)
 665                         error("Too few teams available for domination\n");
 666                 else if(g_ctf)
 667                         error("Too few teams available for ctf\n");
 668                 else if(g_keyhunt)
 669                         error("Too few teams available for key hunt\n");
 670                 else if(g_freezetag)
 671                         error("Too few teams available for freeze tag\n");
 672                 else
 673                         error("Too few teams available for team deathmatch\n");
 674         }
 675
 676         // count how many players are in each team
 677         if(ignore_pl)
 678                 GetTeamCounts(pl);
 679         else
 680                 GetTeamCounts(world);
 681
 682         RandomSelection_Init();
 683
 684         t = 1;
 685         if(TeamSmallerEqThanTeam(2, t, pl))
 686                 t = 2;
 687         if(TeamSmallerEqThanTeam(3, t, pl))
 688                 t = 3;
 689         if(TeamSmallerEqThanTeam(4, t, pl))
 690                 t = 4;
 691
 692         // now t is the minimum, or A minimum!
 693         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 694                 RandomSelection_Add(world, 1, string_null, 1, 1);
 695         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 696                 RandomSelection_Add(world, 2, string_null, 1, 1);
 697         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 698                 RandomSelection_Add(world, 3, string_null, 1, 1);
 699         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 700                 RandomSelection_Add(world, 4, string_null, 1, 1);
 701
 702         return RandomSelection_chosen_float;
 703 }
 704
 705 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 706 {
 707         float smallest, selectedteam;
 708
 709         // don't join a team if we're not playing a team game
 710         if(!teamplay)
 711                 return 0;
 712
 713         // find out what teams are available
 714         CheckAllowedTeams(pl);
 715
 716         // if we don't care what team he ends up on, put him on whatever team he entered as.
 717         // if he's not on a valid team, then let other code put him on the smallest team
 718         if(!forcebestteam)
 719         {
 720                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 721                         selectedteam = pl.team;
 722                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 723                         selectedteam = pl.team;
 724                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 725                         selectedteam = pl.team;
 726                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 727                         selectedteam = pl.team;
 728                 else
 729                         selectedteam = -1;
 730
 731                 if(selectedteam > 0)
 732                 {
 733                         if(!only_return_best)
 734                         {
 735                                 SetPlayerColors(pl, selectedteam - 1);
 736
 737                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 738                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 739                                 LogTeamchange(pl.playerid, pl.team, 99);
 740                         }
 741                         return selectedteam;
 742                 }
 743                 // otherwise end up on the smallest team (handled below)
 744         }
 745
 746         smallest = FindSmallestTeam(pl, TRUE);
 747
 748         if(!only_return_best && !pl.bot_forced_team)
 749         {
 750                 TeamchangeFrags(self);
 751                 if(smallest == 1)
 752                 {
 753                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 754                 }
 755                 else if(smallest == 2)
 756                 {
 757                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 758                 }
 759                 else if(smallest == 3)
 760                 {
 761                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 762                 }
 763                 else if(smallest == 4)
 764                 {
 765                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 766                 }
 767                 else
 768                 {
 769                         error("smallest team: invalid team\n");
 770                 }
 771
 772                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 773
 774                 if(pl.deadflag == DEAD_NO)
 775                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 776         }
 777
 778         return smallest;
 779 }
 780
 781 //void() ctf_playerchanged;
 782 void SV_ChangeTeam(float _color)
 783 {
 784         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 785
 786         // in normal deathmatch we can just apply the color and we're done
 787         if(!teamplay) {
 788                 SetPlayerColors(self, _color);
 789                 return;
 790         }
 791
 792         scolor = self.clientcolors & 0x0F;
 793         dcolor = _color & 0x0F;
 794
 795         if(scolor == NUM_TEAM_1 - 1)
 796                 steam = 1;
 797         else if(scolor == NUM_TEAM_2 - 1)
 798                 steam = 2;
 799         else if(scolor == NUM_TEAM_3 - 1)
 800                 steam = 3;
 801         else // if(scolor == NUM_TEAM_4 - 1)
 802                 steam = 4;
 803         if(dcolor == NUM_TEAM_1 - 1)
 804                 dteam = 1;
 805         else if(dcolor == NUM_TEAM_2 - 1)
 806                 dteam = 2;
 807         else if(dcolor == NUM_TEAM_3 - 1)
 808                 dteam = 3;
 809         else // if(dcolor == NUM_TEAM_4 - 1)
 810                 dteam = 4;
 811
 812         CheckAllowedTeams(self);
 813
 814         if(dteam == 1 && c1 < 0) dteam = 4;
 815         if(dteam == 4 && c4 < 0) dteam = 3;
 816         if(dteam == 3 && c3 < 0) dteam = 2;
 817         if(dteam == 2 && c2 < 0) dteam = 1;
 818
 819         // not changing teams
 820         if(scolor == dcolor)
 821         {
 822                 //bprint("same team change\n");
 823                 SetPlayerTeam(self, dteam, steam, TRUE);
 824                 return;
 825         }
 826
 827         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 828                 sprint(self, "Team changes not allowed\n");
 829                 return; // changing teams is not allowed
 830         }
 831
 832         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 833         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 834         {
 835                 GetTeamCounts(self);
 836                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 837                 {
 838                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 839                         return;
 840                 }
 841         }
 842
 843 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 844
 845         if(IS_PLAYER(self) && steam != dteam)
 846         {
 847                 // reduce frags during a team change
 848                 TeamchangeFrags(self);
 849         }
 850
 851         SetPlayerTeam(self, dteam, steam, FALSE);
 852
 853         if(IS_PLAYER(self) && steam != dteam)
 854         {
 855                 // kill player when changing teams
 856                 if(self.deadflag == DEAD_NO)
 857                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 858         }
 859 }
 860
 861 void ShufflePlayerOutOfTeam (float source_team)
 862 {
 863         float smallestteam, smallestteam_count, steam;
 864         float lowest_bot_score, lowest_player_score;
 865         entity head, lowest_bot, lowest_player, selected;
 866
 867         smallestteam = 0;
 868         smallestteam_count = 999999999;
 869
 870         if(c1 >= 0 && c1 < smallestteam_count)
 871         {
 872                 smallestteam = 1;
 873                 smallestteam_count = c1;
 874         }
 875         if(c2 >= 0 && c2 < smallestteam_count)
 876         {
 877                 smallestteam = 2;
 878                 smallestteam_count = c2;
 879         }
 880         if(c3 >= 0 && c3 < smallestteam_count)
 881         {
 882                 smallestteam = 3;
 883                 smallestteam_count = c3;
 884         }
 885         if(c4 >= 0 && c4 < smallestteam_count)
 886         {
 887                 smallestteam = 4;
 888                 smallestteam_count = c4;
 889         }
 890
 891         if(!smallestteam)
 892         {
 893                 bprint("warning: no smallest team\n");
 894                 return;
 895         }
 896
 897         if(source_team == 1)
 898                 steam = NUM_TEAM_1;
 899         else if(source_team == 2)
 900                 steam = NUM_TEAM_2;
 901         else if(source_team == 3)
 902                 steam = NUM_TEAM_3;
 903         else // if(source_team == 4)
 904                 steam = NUM_TEAM_4;
 905
 906         lowest_bot = world;
 907         lowest_bot_score = 999999999;
 908         lowest_player = world;
 909         lowest_player_score = 999999999;
 910
 911         // find the lowest-scoring player & bot of that team
 912         FOR_EACH_PLAYER(head)
 913         {
 914                 if(head.team == steam)
 915                 {
 916                         if(head.isbot)
 917                         {
 918                                 if(head.totalfrags < lowest_bot_score)
 919                                 {
 920                                         lowest_bot = head;
 921                                         lowest_bot_score = head.totalfrags;
 922                                 }
 923                         }
 924                         else
 925                         {
 926                                 if(head.totalfrags < lowest_player_score)
 927                                 {
 928                                         lowest_player = head;
 929                                         lowest_player_score = head.totalfrags;
 930                                 }
 931                         }
 932                 }
 933         }
 934
 935         // prefers to move a bot...
 936         if(lowest_bot != world)
 937                 selected = lowest_bot;
 938         // but it will move a player if it has to
 939         else
 940                 selected = lowest_player;
 941         // don't do anything if it couldn't find anyone
 942         if(!selected)
 943         {
 944                 bprint("warning: couldn't find a player to move from team\n");
 945                 return;
 946         }
 947
 948         // smallest team gains a member
 949         if(smallestteam == 1)
 950         {
 951                 c1 = c1 + 1;
 952         }
 953         else if(smallestteam == 2)
 954         {
 955                 c2 = c2 + 1;
 956         }
 957         else if(smallestteam == 3)
 958         {
 959                 c3 = c3 + 1;
 960         }
 961         else if(smallestteam == 4)
 962         {
 963                 c4 = c4 + 1;
 964         }
 965         else
 966         {
 967                 bprint("warning: destination team invalid\n");
 968                 return;
 969         }
 970         // source team loses a member
 971         if(source_team == 1)
 972         {
 973                 c1 = c1 + 1;
 974         }
 975         else if(source_team == 2)
 976         {
 977                 c2 = c2 + 2;
 978         }
 979         else if(source_team == 3)
 980         {
 981                 c3 = c3 + 3;
 982         }
 983         else if(source_team == 4)
 984         {
 985                 c4 = c4 + 4;
 986         }
 987         else
 988         {
 989                 bprint("warning: source team invalid\n");
 990                 return;
 991         }
 992
 993         // move the player to the new team
 994         TeamchangeFrags(selected);
 995         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 996
 997         if(selected.deadflag == DEAD_NO)
 998                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 999         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
1000 }
1001
1002 // code from here on is just to support maps that don't have team entities
1003 void tdm_spawnteam (string teamname, float teamcolor)
1004 {
1005         entity e;
1006         e = spawn();
1007         e.classname = "tdm_team";
1008         e.netname = teamname;
1009         e.cnt = teamcolor;
1010         e.team = e.cnt + 1;
1011 }
1012
1013 // spawn some default teams if the map is not set up for tdm
1014 void tdm_spawnteams()
1015 {
1016         float numteams;
1017
1018         numteams = autocvar_g_tdm_teams_override;
1019         if(numteams < 2)
1020                 numteams = autocvar_g_tdm_teams;
1021         numteams = bound(2, numteams, 4);
1022
1023         tdm_spawnteam("Red", NUM_TEAM_1-1);
1024         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1025         if(numteams >= 3)
1026                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1027         if(numteams >= 4)
1028                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1029 }
1030
1031 void tdm_delayedinit()
1032 {
1033         // if no teams are found, spawn defaults
1034         if (find(world, classname, "tdm_team") == world)
1035                 tdm_spawnteams();
1036 }
1037
1038 void tdm_init()
1039 {
1040         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1041 }