qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 //float audit_teams_time;
  10
  11 void TeamchangeFrags(entity e)
  12 {
  13         PlayerScore_Clear(e);
  14 }
  15
  16 void tdm_init();
  17 void entcs_init();
  18
  19 void LogTeamchange(float player_id, float team_number, float type)
  20 {
  21         if(!autocvar_sv_eventlog)
  22                 return;
  23
  24         if(player_id < 1)
  25                 return;
  26
  27         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  28 }
  29
  30 void default_delayedinit()
  31 {
  32         if(!scores_initialized)
  33                 ScoreRules_generic();
  34 }
  35
  36 void ActivateTeamplay()
  37 {
  38         serverflags |= SERVERFLAG_TEAMPLAY;
  39         teamplay = 1;
  40 }
  41
  42 void InitGameplayMode()
  43 {
  44         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
  45
  46         qualifying_override = -1;
  47
  48         VoteReset();
  49
  50         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
  51         get_mi_min_max(1);
  52         world.mins = mi_min;
  53         world.maxs = mi_max;
  54
  55         MapInfo_LoadMapSettings(mapname);
  56         teamplay = 0;
  57         serverflags &= ~SERVERFLAG_TEAMPLAY;
  58
  59         if (!cvar_value_issafe(world.fog))
  60         {
  61                 print("The current map contains a potentially harmful fog setting, ignored\n");
  62                 world.fog = string_null;
  63         }
  64         if(MapInfo_Map_fog != "")
  65                 if(MapInfo_Map_fog == "none")
  66                         world.fog = string_null;
  67                 else
  68                         world.fog = strzone(MapInfo_Map_fog);
  69         clientstuff = strzone(MapInfo_Map_clientstuff);
  70
  71         MapInfo_ClearTemps();
  72
  73         // set both here, gamemode can override it later
  74         timelimit_override = autocvar_timelimit_override;
  75         fraglimit_override = autocvar_fraglimit_override;
  76         leadlimit_override = autocvar_leadlimit_override;
  77         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
  78
  79         if(g_dm)
  80         {
  81         }
  82
  83         if(g_tdm)
  84         {
  85                 ActivateTeamplay();
  86                 tdm_init();
  87                 if(autocvar_g_tdm_team_spawns)
  88                         have_team_spawns = -1; // request team spawns
  89         }
  90
  91         if(g_domination)
  92         {
  93                 ActivateTeamplay();
  94                 fraglimit_override = autocvar_g_domination_point_limit;
  95                 leadlimit_override = autocvar_g_domination_point_leadlimit;
  96                 MUTATOR_ADD(gamemode_domination);
  97                 have_team_spawns = -1; // request team spawns
  98         }
  99
 100         if(g_ctf)
 101         {
 102                 ActivateTeamplay();
 103                 fraglimit_override = autocvar_capturelimit_override;
 104                 leadlimit_override = autocvar_captureleadlimit_override;
 105                 MUTATOR_ADD(gamemode_ctf);
 106                 have_team_spawns = -1; // request team spawns
 107         }
 108
 109         if(g_lms)
 110         {
 111                 fraglimit_override = autocvar_g_lms_lives_override;
 112                 leadlimit_override = 0; // not supported by LMS
 113                 if(fraglimit_override == 0)
 114                         fraglimit_override = -1;
 115                 MUTATOR_ADD(gamemode_lms);
 116         }
 117
 118         if(g_ca)
 119         {
 120                 ActivateTeamplay();
 121                 fraglimit_override = autocvar_g_ca_point_limit;
 122                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 123                 MUTATOR_ADD(gamemode_ca);
 124                 if(autocvar_g_ca_team_spawns)
 125                         have_team_spawns = -1; // request team spawns
 126         }
 127
 128         if(g_keyhunt)
 129         {
 130                 ActivateTeamplay();
 131                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 132                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 133                 MUTATOR_ADD(gamemode_keyhunt);
 134         }
 135
 136         if(g_freezetag)
 137         {
 138                 ActivateTeamplay();
 139                 fraglimit_override = autocvar_g_freezetag_point_limit;
 140                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 141                 MUTATOR_ADD(gamemode_freezetag);
 142                 if(autocvar_g_freezetag_team_spawns)
 143                         have_team_spawns = -1; // request team spawns
 144         }
 145
 146         if(g_assault)
 147         {
 148                 ActivateTeamplay();
 149                 MUTATOR_ADD(gamemode_assault);
 150                 have_team_spawns = -1; // request team spawns
 151         }
 152
 153         if(g_onslaught)
 154         {
 155                 ActivateTeamplay();
 156                 have_team_spawns = -1; // request team spawns
 157                 MUTATOR_ADD(gamemode_onslaught);
 158         }
 159
 160         if(g_race)
 161         {
 162                 if(autocvar_g_race_teams)
 163                 {
 164                         ActivateTeamplay();
 165                         race_teams = bound(2, autocvar_g_race_teams, 4);
 166                         have_team_spawns = -1; // request team spawns
 167                 }
 168                 else
 169                         race_teams = 0;
 170
 171                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 172                 fraglimit_override = autocvar_g_race_laps_limit;
 173                 leadlimit_override = 0; // currently not supported by race
 174
 175                 MUTATOR_ADD(gamemode_race);
 176         }
 177
 178         if(g_cts)
 179         {
 180                 g_race_qualifying = 1;
 181                 fraglimit_override = 0;
 182                 leadlimit_override = 0;
 183                 MUTATOR_ADD(gamemode_cts);
 184         }
 185
 186         if(g_nexball)
 187         {
 188         fraglimit_override = autocvar_g_nexball_goallimit;
 189         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 190         ActivateTeamplay();
 191         have_team_spawns = -1; // request team spawns
 192             MUTATOR_ADD(gamemode_nexball);
 193         }
 194
 195         if(g_keepaway)
 196         {
 197                 MUTATOR_ADD(gamemode_keepaway);
 198         }
 199
 200         if(g_invasion)
 201         {
 202                 fraglimit_override = autocvar_g_invasion_point_limit;
 203                 if(autocvar_g_invasion_teams >= 2)
 204                 {
 205                         ActivateTeamplay();
 206                         if(autocvar_g_invasion_team_spawns)
 207                                 have_team_spawns = -1; // request team spawns
 208                 }
 209                 MUTATOR_ADD(gamemode_invasion);
 210         }
 211
 212         if(teamplay)
 213                 entcs_init();
 214
 215         cache_mutatormsg = strzone("");
 216         cache_lastmutatormsg = strzone("");
 217
 218         // enforce the server's universal frag/time limits
 219         if(!autocvar_g_campaign)
 220         {
 221                 if(fraglimit_override >= 0)
 222                         cvar_set("fraglimit", ftos(fraglimit_override));
 223                 if(timelimit_override >= 0)
 224                         cvar_set("timelimit", ftos(timelimit_override));
 225                 if(leadlimit_override >= 0)
 226                         cvar_set("leadlimit", ftos(leadlimit_override));
 227                 if(qualifying_override >= 0)
 228                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 229         }
 230
 231         if(g_race)
 232         {
 233                 // we need to find out the correct value for g_race_qualifying
 234                 if(autocvar_g_campaign)
 235                 {
 236                         g_race_qualifying = 1;
 237                 }
 238                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 239                 {
 240                         g_race_qualifying = 2;
 241                         race_fraglimit = autocvar_fraglimit;
 242                         race_leadlimit = autocvar_leadlimit;
 243                         race_timelimit = autocvar_timelimit;
 244                         cvar_set("fraglimit", "0");
 245                         cvar_set("leadlimit", "0");
 246                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 247                 }
 248                 else
 249                         g_race_qualifying = 0;
 250         }
 251
 252         if(g_race || g_cts)
 253         if(g_race_qualifying)
 254                 independent_players = 1;
 255
 256         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 257 }
 258
 259 string GetClientVersionMessage() {
 260         string versionmsg;
 261         if (self.version_mismatch) {
 262                 if(self.version < autocvar_gameversion) {
 263                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 264                 } else {
 265                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 266                 }
 267         } else {
 268                 versionmsg = "^2client version and server version are compatible.^8";
 269         }
 270         return versionmsg;
 271 }
 272
 273 string getwelcomemessage(void)
 274 {
 275         string s, modifications, motd;
 276
 277         ret_string = "";
 278         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 279         modifications = ret_string;
 280
 281         if(g_weaponarena)
 282         {
 283                 if(g_weaponarena_random)
 284                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 285                 else
 286                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 287         }
 288         if(autocvar_g_start_weapon_laser == 0)
 289                 modifications = strcat(modifications, ", No start weapons");
 290         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
 291                 modifications = strcat(modifications, ", Low gravity");
 292         if(g_cloaked && !g_cts)
 293                 modifications = strcat(modifications, ", Cloaked");
 294         if(g_grappling_hook)
 295                 modifications = strcat(modifications, ", Hook");
 296         if(g_weapon_stay && !g_cts)
 297                 modifications = strcat(modifications, ", Weapons stay");
 298         if(g_jetpack)
 299                 modifications = strcat(modifications, ", Jet pack");
 300         if(autocvar_g_powerups == 0)
 301                 modifications = strcat(modifications, ", No powerups");
 302         if(autocvar_g_powerups > 0)
 303                 modifications = strcat(modifications, ", Powerups");
 304         modifications = substring(modifications, 2, strlen(modifications) - 2);
 305
 306         string versionmessage;
 307         versionmessage = GetClientVersionMessage();
 308
 309         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 310         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 311
 312         if(modifications != "")
 313                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 314
 315         if (g_grappling_hook)
 316                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 317
 318         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 319         {
 320                 if(cache_lastmutatormsg)
 321                         strunzone(cache_lastmutatormsg);
 322                 if(cache_mutatormsg)
 323                         strunzone(cache_mutatormsg);
 324                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 325                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 326         }
 327
 328         if (cache_mutatormsg != "") {
 329                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 330         }
 331
 332         motd = autocvar_sv_motd;
 333         if (motd != "") {
 334                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 335         }
 336         return s;
 337 }
 338
 339 void SetPlayerColors(entity pl, float _color)
 340 {
 341         /*string s;
 342         s = ftos(cl);
 343         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 344         pl.team = cl + 1;
 345         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 346         pl.clientcolors = 16*cl + cl;*/
 347
 348         float pants, shirt;
 349         pants = _color & 0x0F;
 350         shirt = _color & 0xF0;
 351
 352
 353         if(teamplay) {
 354                 setcolor(pl, 16*pants + pants);
 355         } else {
 356                 setcolor(pl, shirt + pants);
 357         }
 358 }
 359
 360 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 361 {
 362         float _color;
 363
 364         if(t == 4)
 365                 _color = NUM_TEAM_4 - 1;
 366         else if(t == 3)
 367                 _color = NUM_TEAM_3 - 1;
 368         else if(t == 2)
 369                 _color = NUM_TEAM_2 - 1;
 370         else
 371                 _color = NUM_TEAM_1 - 1;
 372
 373         SetPlayerColors(pl,_color);
 374
 375         if(t != s) {
 376                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 377
 378                 if(!noprint)
 379                 bprint(pl.netname, "^7 has changed from ", Team_NumberToColoredFullName(s), "^7 to ", Team_NumberToColoredFullName(t), "\n");
 380         }
 381
 382 }
 383
 384 // set c1...c4 to show what teams are allowed
 385 void CheckAllowedTeams (entity for_whom)
 386 {
 387         float dm;
 388         entity head;
 389         string teament_name;
 390
 391         c1 = c2 = c3 = c4 = -1;
 392         cb1 = cb2 = cb3 = cb4 = 0;
 393
 394         teament_name = string_null;
 395         if(g_onslaught)
 396         {
 397                 // onslaught is special
 398                 head = findchain(classname, "onslaught_generator");
 399                 while (head)
 400                 {
 401                         if (head.team == NUM_TEAM_1) c1 = 0;
 402                         if (head.team == NUM_TEAM_2) c2 = 0;
 403                         if (head.team == NUM_TEAM_3) c3 = 0;
 404                         if (head.team == NUM_TEAM_4) c4 = 0;
 405                         head = head.chain;
 406                 }
 407         }
 408         else if(g_domination)
 409                 teament_name = "dom_team";
 410         else if(g_ctf)
 411                 teament_name = "ctf_team";
 412         else if(g_tdm)
 413                 teament_name = "tdm_team";
 414         else if(g_nexball)
 415                 teament_name = "nexball_team";
 416         else if(g_assault)
 417                 c1 = c2 = 0; // Assault always has 2 teams
 418         else
 419         {
 420                 // cover anything else by treating it like tdm with no teams spawned
 421                 dm = 2;
 422
 423                 ret_float = dm;
 424                 MUTATOR_CALLHOOK(GetTeamCount);
 425                 dm = ret_float;
 426
 427                 if(dm >= 4)
 428                         c1 = c2 = c3 = c4 = 0;
 429                 else if(dm >= 3)
 430                         c1 = c2 = c3 = 0;
 431                 else
 432                         c1 = c2 = 0;
 433         }
 434
 435         // find out what teams are allowed if necessary
 436         if(teament_name)
 437         {
 438                 head = find(world, classname, teament_name);
 439                 while(head)
 440                 {
 441                         if(!(g_domination && head.netname == ""))
 442                         {
 443                                 if(head.team == NUM_TEAM_1)
 444                                         c1 = 0;
 445                                 else if(head.team == NUM_TEAM_2)
 446                                         c2 = 0;
 447                                 else if(head.team == NUM_TEAM_3)
 448                                         c3 = 0;
 449                                 else if(head.team == NUM_TEAM_4)
 450                                         c4 = 0;
 451                         }
 452                         head = find(head, classname, teament_name);
 453                 }
 454         }
 455
 456         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 457         if(c3==-1 && c4==-1)
 458         if(autocvar_bot_vs_human && for_whom)
 459         {
 460                 if(autocvar_bot_vs_human > 0)
 461                 {
 462                         // bots are all blue
 463                         if(IS_BOT_CLIENT(for_whom))
 464                                 c1 = c3 = c4 = -1;
 465                         else
 466                                 c2 = -1;
 467                 }
 468                 else
 469                 {
 470                         // bots are all red
 471                         if(IS_BOT_CLIENT(for_whom))
 472                                 c2 = c3 = c4 = -1;
 473                         else
 474                                 c1 = -1;
 475                 }
 476         }
 477
 478         // if player has a forced team, ONLY allow that one
 479         if(self.team_forced == NUM_TEAM_1 && c1 >= 0)
 480                 c2 = c3 = c4 = -1;
 481         else if(self.team_forced == NUM_TEAM_2 && c2 >= 0)
 482                 c1 = c3 = c4 = -1;
 483         else if(self.team_forced == NUM_TEAM_3 && c3 >= 0)
 484                 c1 = c2 = c4 = -1;
 485         else if(self.team_forced == NUM_TEAM_4 && c4 >= 0)
 486                 c1 = c2 = c3 = -1;
 487 }
 488
 489 float PlayerValue(entity p)
 490 {
 491         return 1;
 492         // FIXME: it always returns 1...
 493 }
 494
 495 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 496 // teams that are allowed will now have their player counts stored in c1...c4
 497 void GetTeamCounts(entity ignore)
 498 {
 499         entity head;
 500         float value, bvalue;
 501         // now count how many players are on each team already
 502
 503         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 504         // also remember the lowest-scoring player
 505
 506         FOR_EACH_CLIENT(head)
 507         {
 508                 float t;
 509                 if(IS_PLAYER(head))
 510                         t = head.team;
 511                 else if(head.team_forced > 0)
 512                         t = head.team_forced; // reserve the spot
 513                 else
 514                         continue;
 515                 if(head != ignore)// && head.netname != "")
 516                 {
 517                         value = PlayerValue(head);
 518                         if(IS_BOT_CLIENT(head))
 519                                 bvalue = value;
 520                         else
 521                                 bvalue = 0;
 522                         if(t == NUM_TEAM_1)
 523                         {
 524                                 if(c1 >= 0)
 525                                 {
 526                                         c1 = c1 + value;
 527                                         cb1 = cb1 + bvalue;
 528                                 }
 529                         }
 530                         if(t == NUM_TEAM_2)
 531                         {
 532                                 if(c2 >= 0)
 533                                 {
 534                                         c2 = c2 + value;
 535                                         cb2 = cb2 + bvalue;
 536                                 }
 537                         }
 538                         if(t == NUM_TEAM_3)
 539                         {
 540                                 if(c3 >= 0)
 541                                 {
 542                                         c3 = c3 + value;
 543                                         cb3 = cb3 + bvalue;
 544                                 }
 545                         }
 546                         if(t == NUM_TEAM_4)
 547                         {
 548                                 if(c4 >= 0)
 549                                 {
 550                                         c4 = c4 + value;
 551                                         cb4 = cb4 + bvalue;
 552                                 }
 553                         }
 554                 }
 555         }
 556
 557         // if the player who has a forced team has not joined yet, reserve the spot
 558         if(autocvar_g_campaign)
 559         {
 560                 switch(autocvar_g_campaign_forceteam)
 561                 {
 562                         case 1: if(c1 == cb1) ++c1; break;
 563                         case 2: if(c2 == cb2) ++c2; break;
 564                         case 3: if(c3 == cb3) ++c3; break;
 565                         case 4: if(c4 == cb4) ++c4; break;
 566                 }
 567         }
 568 }
 569
 570 float TeamSmallerEqThanTeam(float ta, float tb, entity e)
 571 {
 572         // we assume that CheckAllowedTeams and GetTeamCounts have already been called
 573         float f;
 574         float ca = -1, cb = -1, cba = 0, cbb = 0, sa = 0, sb = 0;
 575
 576         switch(ta)
 577         {
 578                 case 1: ca = c1; cba = cb1; sa = team1_score; break;
 579                 case 2: ca = c2; cba = cb2; sa = team2_score; break;
 580                 case 3: ca = c3; cba = cb3; sa = team3_score; break;
 581                 case 4: ca = c4; cba = cb4; sa = team4_score; break;
 582         }
 583         switch(tb)
 584         {
 585                 case 1: cb = c1; cbb = cb1; sb = team1_score; break;
 586                 case 2: cb = c2; cbb = cb2; sb = team2_score; break;
 587                 case 3: cb = c3; cbb = cb3; sb = team3_score; break;
 588                 case 4: cb = c4; cbb = cb4; sb = team4_score; break;
 589         }
 590
 591         // invalid
 592         if(ca < 0 || cb < 0)
 593                 return FALSE;
 594
 595         // equal
 596         if(ta == tb)
 597                 return TRUE;
 598
 599         if(IS_REAL_CLIENT(e))
 600         {
 601                 if(bots_would_leave)
 602                 {
 603                         ca -= cba * 0.999;
 604                         cb -= cbb * 0.999;
 605                 }
 606         }
 607
 608         // keep teams alive (teams of size 0 always count as smaller, ignoring score)
 609         if(ca < 1)
 610                 if(cb >= 1)
 611                         return TRUE;
 612         if(ca >= 1)
 613                 if(cb < 1)
 614                         return FALSE;
 615
 616         // first, normalize
 617         f = max(ca, cb, 1);
 618         ca /= f;
 619         cb /= f;
 620         f = max(sa, sb, 1);
 621         sa /= f;
 622         sb /= f;
 623
 624         // the more we're at the end of the match, the more take scores into account
 625         f = bound(0, game_completion_ratio * autocvar_g_balance_teams_scorefactor, 1);
 626         ca += (sa - ca) * f;
 627         cb += (sb - cb) * f;
 628
 629         return ca <= cb;
 630 }
 631
 632 // returns # of smallest team (1, 2, 3, 4)
 633 // NOTE: Assumes CheckAllowedTeams has already been called!
 634 float FindSmallestTeam(entity pl, float ignore_pl)
 635 {
 636         float totalteams, t;
 637         totalteams = 0;
 638
 639         // find out what teams are available
 640         //CheckAllowedTeams();
 641
 642         // make sure there are at least 2 teams to join
 643         if(c1 >= 0)
 644                 totalteams = totalteams + 1;
 645         if(c2 >= 0)
 646                 totalteams = totalteams + 1;
 647         if(c3 >= 0)
 648                 totalteams = totalteams + 1;
 649         if(c4 >= 0)
 650                 totalteams = totalteams + 1;
 651
 652         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 653                 totalteams += 1;
 654
 655         if(totalteams <= 1)
 656         {
 657                 if(autocvar_g_campaign && pl && IS_REAL_CLIENT(pl))
 658                         return 1; // special case for campaign and player joining
 659                 else if(g_domination)
 660                         error("Too few teams available for domination\n");
 661                 else if(g_ctf)
 662                         error("Too few teams available for ctf\n");
 663                 else if(g_keyhunt)
 664                         error("Too few teams available for key hunt\n");
 665                 else if(g_freezetag)
 666                         error("Too few teams available for freeze tag\n");
 667                 else
 668                         error("Too few teams available for team deathmatch\n");
 669         }
 670
 671         // count how many players are in each team
 672         if(ignore_pl)
 673                 GetTeamCounts(pl);
 674         else
 675                 GetTeamCounts(world);
 676
 677         RandomSelection_Init();
 678
 679         t = 1;
 680         if(TeamSmallerEqThanTeam(2, t, pl))
 681                 t = 2;
 682         if(TeamSmallerEqThanTeam(3, t, pl))
 683                 t = 3;
 684         if(TeamSmallerEqThanTeam(4, t, pl))
 685                 t = 4;
 686
 687         // now t is the minimum, or A minimum!
 688         if(t == 1 || TeamSmallerEqThanTeam(1, t, pl))
 689                 RandomSelection_Add(world, 1, string_null, 1, 1);
 690         if(t == 2 || TeamSmallerEqThanTeam(2, t, pl))
 691                 RandomSelection_Add(world, 2, string_null, 1, 1);
 692         if(t == 3 || TeamSmallerEqThanTeam(3, t, pl))
 693                 RandomSelection_Add(world, 3, string_null, 1, 1);
 694         if(t == 4 || TeamSmallerEqThanTeam(4, t, pl))
 695                 RandomSelection_Add(world, 4, string_null, 1, 1);
 696
 697         return RandomSelection_chosen_float;
 698 }
 699
 700 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 701 {
 702         float smallest, selectedteam;
 703
 704         // don't join a team if we're not playing a team game
 705         if(!teamplay)
 706                 return 0;
 707
 708         // find out what teams are available
 709         CheckAllowedTeams(pl);
 710
 711         // if we don't care what team he ends up on, put him on whatever team he entered as.
 712         // if he's not on a valid team, then let other code put him on the smallest team
 713         if(!forcebestteam)
 714         {
 715                 if(     c1 >= 0 && pl.team == NUM_TEAM_1)
 716                         selectedteam = pl.team;
 717                 else if(c2 >= 0 && pl.team == NUM_TEAM_2)
 718                         selectedteam = pl.team;
 719                 else if(c3 >= 0 && pl.team == NUM_TEAM_3)
 720                         selectedteam = pl.team;
 721                 else if(c4 >= 0 && pl.team == NUM_TEAM_4)
 722                         selectedteam = pl.team;
 723                 else
 724                         selectedteam = -1;
 725
 726                 if(selectedteam > 0)
 727                 {
 728                         if(!only_return_best)
 729                         {
 730                                 SetPlayerColors(pl, selectedteam - 1);
 731
 732                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 733                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 734                                 LogTeamchange(pl.playerid, pl.team, 99);
 735                         }
 736                         return selectedteam;
 737                 }
 738                 // otherwise end up on the smallest team (handled below)
 739         }
 740
 741         smallest = FindSmallestTeam(pl, TRUE);
 742
 743         if(!only_return_best && !pl.bot_forced_team)
 744         {
 745                 TeamchangeFrags(self);
 746                 if(smallest == 1)
 747                 {
 748                         SetPlayerColors(pl, NUM_TEAM_1 - 1);
 749                 }
 750                 else if(smallest == 2)
 751                 {
 752                         SetPlayerColors(pl, NUM_TEAM_2 - 1);
 753                 }
 754                 else if(smallest == 3)
 755                 {
 756                         SetPlayerColors(pl, NUM_TEAM_3 - 1);
 757                 }
 758                 else if(smallest == 4)
 759                 {
 760                         SetPlayerColors(pl, NUM_TEAM_4 - 1);
 761                 }
 762                 else
 763                 {
 764                         error("smallest team: invalid team\n");
 765                 }
 766
 767                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 768
 769                 if(pl.deadflag == DEAD_NO)
 770                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 771         }
 772
 773         return smallest;
 774 }
 775
 776 //void() ctf_playerchanged;
 777 void SV_ChangeTeam(float _color)
 778 {
 779         float scolor, dcolor, steam, dteam; //, dbotcount, scount, dcount;
 780
 781         // in normal deathmatch we can just apply the color and we're done
 782         if(!teamplay) {
 783                 SetPlayerColors(self, _color);
 784                 return;
 785         }
 786
 787         scolor = self.clientcolors & 0x0F;
 788         dcolor = _color & 0x0F;
 789
 790         if(scolor == NUM_TEAM_1 - 1)
 791                 steam = 1;
 792         else if(scolor == NUM_TEAM_2 - 1)
 793                 steam = 2;
 794         else if(scolor == NUM_TEAM_3 - 1)
 795                 steam = 3;
 796         else // if(scolor == NUM_TEAM_4 - 1)
 797                 steam = 4;
 798         if(dcolor == NUM_TEAM_1 - 1)
 799                 dteam = 1;
 800         else if(dcolor == NUM_TEAM_2 - 1)
 801                 dteam = 2;
 802         else if(dcolor == NUM_TEAM_3 - 1)
 803                 dteam = 3;
 804         else // if(dcolor == NUM_TEAM_4 - 1)
 805                 dteam = 4;
 806
 807         CheckAllowedTeams(self);
 808
 809         if(dteam == 1 && c1 < 0) dteam = 4;
 810         if(dteam == 4 && c4 < 0) dteam = 3;
 811         if(dteam == 3 && c3 < 0) dteam = 2;
 812         if(dteam == 2 && c2 < 0) dteam = 1;
 813
 814         // not changing teams
 815         if(scolor == dcolor)
 816         {
 817                 //bprint("same team change\n");
 818                 SetPlayerTeam(self, dteam, steam, TRUE);
 819                 return;
 820         }
 821
 822         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 823                 sprint(self, "Team changes not allowed\n");
 824                 return; // changing teams is not allowed
 825         }
 826
 827         // autocvar_g_balance_teams_prevent_imbalance only makes sense if autocvar_g_balance_teams is on, as it makes the team selection dialog pointless
 828         if(autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 829         {
 830                 GetTeamCounts(self);
 831                 if(!TeamSmallerEqThanTeam(dteam, steam, self))
 832                 {
 833                         sprint(self, "Cannot change to a larger/better/shinier team\n");
 834                         return;
 835                 }
 836         }
 837
 838 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 839
 840         if(IS_PLAYER(self) && steam != dteam)
 841         {
 842                 // reduce frags during a team change
 843                 TeamchangeFrags(self);
 844         }
 845
 846         SetPlayerTeam(self, dteam, steam, FALSE);
 847
 848         if(IS_PLAYER(self) && steam != dteam)
 849         {
 850                 // kill player when changing teams
 851                 if(self.deadflag == DEAD_NO)
 852                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 853         }
 854 }
 855
 856 void ShufflePlayerOutOfTeam (float source_team)
 857 {
 858         float smallestteam, smallestteam_count, steam;
 859         float lowest_bot_score, lowest_player_score;
 860         entity head, lowest_bot, lowest_player, selected;
 861
 862         smallestteam = 0;
 863         smallestteam_count = 999999999;
 864
 865         if(c1 >= 0 && c1 < smallestteam_count)
 866         {
 867                 smallestteam = 1;
 868                 smallestteam_count = c1;
 869         }
 870         if(c2 >= 0 && c2 < smallestteam_count)
 871         {
 872                 smallestteam = 2;
 873                 smallestteam_count = c2;
 874         }
 875         if(c3 >= 0 && c3 < smallestteam_count)
 876         {
 877                 smallestteam = 3;
 878                 smallestteam_count = c3;
 879         }
 880         if(c4 >= 0 && c4 < smallestteam_count)
 881         {
 882                 smallestteam = 4;
 883                 smallestteam_count = c4;
 884         }
 885
 886         if(!smallestteam)
 887         {
 888                 bprint("warning: no smallest team\n");
 889                 return;
 890         }
 891
 892         if(source_team == 1)
 893                 steam = NUM_TEAM_1;
 894         else if(source_team == 2)
 895                 steam = NUM_TEAM_2;
 896         else if(source_team == 3)
 897                 steam = NUM_TEAM_3;
 898         else // if(source_team == 4)
 899                 steam = NUM_TEAM_4;
 900
 901         lowest_bot = world;
 902         lowest_bot_score = 999999999;
 903         lowest_player = world;
 904         lowest_player_score = 999999999;
 905
 906         // find the lowest-scoring player & bot of that team
 907         FOR_EACH_PLAYER(head)
 908         {
 909                 if(head.team == steam)
 910                 {
 911                         if(head.isbot)
 912                         {
 913                                 if(head.totalfrags < lowest_bot_score)
 914                                 {
 915                                         lowest_bot = head;
 916                                         lowest_bot_score = head.totalfrags;
 917                                 }
 918                         }
 919                         else
 920                         {
 921                                 if(head.totalfrags < lowest_player_score)
 922                                 {
 923                                         lowest_player = head;
 924                                         lowest_player_score = head.totalfrags;
 925                                 }
 926                         }
 927                 }
 928         }
 929
 930         // prefers to move a bot...
 931         if(lowest_bot != world)
 932                 selected = lowest_bot;
 933         // but it will move a player if it has to
 934         else
 935                 selected = lowest_player;
 936         // don't do anything if it couldn't find anyone
 937         if(!selected)
 938         {
 939                 bprint("warning: couldn't find a player to move from team\n");
 940                 return;
 941         }
 942
 943         // smallest team gains a member
 944         if(smallestteam == 1)
 945         {
 946                 c1 = c1 + 1;
 947         }
 948         else if(smallestteam == 2)
 949         {
 950                 c2 = c2 + 1;
 951         }
 952         else if(smallestteam == 3)
 953         {
 954                 c3 = c3 + 1;
 955         }
 956         else if(smallestteam == 4)
 957         {
 958                 c4 = c4 + 1;
 959         }
 960         else
 961         {
 962                 bprint("warning: destination team invalid\n");
 963                 return;
 964         }
 965         // source team loses a member
 966         if(source_team == 1)
 967         {
 968                 c1 = c1 + 1;
 969         }
 970         else if(source_team == 2)
 971         {
 972                 c2 = c2 + 2;
 973         }
 974         else if(source_team == 3)
 975         {
 976                 c3 = c3 + 3;
 977         }
 978         else if(source_team == 4)
 979         {
 980                 c4 = c4 + 4;
 981         }
 982         else
 983         {
 984                 bprint("warning: source team invalid\n");
 985                 return;
 986         }
 987
 988         // move the player to the new team
 989         TeamchangeFrags(selected);
 990         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
 991
 992         if(selected.deadflag == DEAD_NO)
 993                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
 994         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", Team_ColoredFullName(selected.team)));
 995 }
 996
 997 // code from here on is just to support maps that don't have team entities
 998 void tdm_spawnteam (string teamname, float teamcolor)
 999 {
1000         entity e;
1001         e = spawn();
1002         e.classname = "tdm_team";
1003         e.netname = teamname;
1004         e.cnt = teamcolor;
1005         e.team = e.cnt + 1;
1006 }
1007
1008 // spawn some default teams if the map is not set up for tdm
1009 void tdm_spawnteams()
1010 {
1011         float numteams;
1012
1013         numteams = autocvar_g_tdm_teams_override;
1014         if(numteams < 2)
1015                 numteams = autocvar_g_tdm_teams;
1016         numteams = bound(2, numteams, 4);
1017
1018         tdm_spawnteam("Red", NUM_TEAM_1-1);
1019         tdm_spawnteam("Blue", NUM_TEAM_2-1);
1020         if(numteams >= 3)
1021                 tdm_spawnteam("Yellow", NUM_TEAM_3-1);
1022         if(numteams >= 4)
1023                 tdm_spawnteam("Pink", NUM_TEAM_4-1);
1024 }
1025
1026 void tdm_delayedinit()
1027 {
1028         // if no teams are found, spawn defaults
1029         if (find(world, classname, "tdm_team") == world)
1030                 tdm_spawnteams();
1031 }
1032
1033 void tdm_init()
1034 {
1035         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1036 }