qcsrc/server/teamplay.qc

   1 string cache_mutatormsg;
   2 string cache_lastmutatormsg;
   3
   4 // client counts for each team
   5 float c1, c2, c3, c4;
   6 // # of bots on those teams
   7 float cb1, cb2, cb3, cb4;
   8
   9 float audit_teams_time;
  10
  11 float IsTeamBalanceForced()
  12 {
  13         if(intermission_running)
  14                 return 0; // no rebalancing whatsoever please
  15         if(!teamplay)
  16                 return 0;
  17         if(autocvar_g_campaign)
  18                 return 0;
  19         if(autocvar_bot_vs_human && (c3==-1 && c4==-1))
  20                 return 0;
  21         if(!autocvar_g_balance_teams_force)
  22                 return -1;
  23         return 1;
  24 }
  25
  26 void TeamchangeFrags(entity e)
  27 {
  28         PlayerScore_Clear(e);
  29 }
  30
  31 vector TeamColor(float teem)
  32 {
  33         switch(teem)
  34         {
  35                 case COLOR_TEAM1:
  36                         return '1 0.0625 0.0625';
  37                 case COLOR_TEAM2:
  38                         return '0.0625 0.0625 1';
  39                 case COLOR_TEAM3:
  40                         return '1 1 0.0625';
  41                 case COLOR_TEAM4:
  42                         return '1 0.0625 1';
  43                 default:
  44                         return '1 1 1';
  45         }
  46 }
  47
  48 string TeamName(float t)
  49 {
  50         return strcat(Team_ColorName(t), " Team");
  51 }
  52 string ColoredTeamName(float t)
  53 {
  54         return strcat(Team_ColorCode(t), Team_ColorName(t), " Team^7");
  55 }
  56 string TeamNoName(float t)
  57 {
  58         // fixme: Search for team entities and get their .netname's!
  59         if(t == 1)
  60                 return "Red Team";
  61         if(t == 2)
  62                 return "Blue Team";
  63         if(t == 3)
  64                 return "Yellow Team";
  65         if(t == 4)
  66                 return "Pink Team";
  67         return "Neutral Team";
  68 }
  69
  70 void dom_init();
  71 void ctf_init();
  72 void runematch_init();
  73 void tdm_init();
  74 void entcs_init();
  75
  76 void LogTeamchange(float player_id, float team_number, float type)
  77 {
  78         if(!autocvar_sv_eventlog)
  79                 return;
  80
  81         if(player_id < 1)
  82                 return;
  83
  84         GameLogEcho(strcat(":team:", ftos(player_id), ":", ftos(team_number), ":", ftos(type)));
  85 }
  86
  87 void default_delayedinit()
  88 {
  89         if(!scores_initialized)
  90                 ScoreRules_generic();
  91 }
  92
  93 void ActivateTeamplay()
  94 {
  95         serverflags |= SERVERFLAG_TEAMPLAY;
  96         teamplay = 1;
  97 }
  98
  99 void InitGameplayMode()
 100 {
 101         float fraglimit_override, timelimit_override, leadlimit_override, qualifying_override;
 102
 103         qualifying_override = -1;
 104
 105         VoteReset();
 106
 107         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 108         get_mi_min_max(1);
 109         world.mins = mi_min;
 110         world.maxs = mi_max;
 111
 112         MapInfo_LoadMapSettings(mapname);
 113         teamplay = 0;
 114         serverflags &~= SERVERFLAG_TEAMPLAY;
 115
 116         if not(cvar_value_issafe(world.fog))
 117         {
 118                 print("The current map contains a potentially harmful fog setting, ignored\n");
 119                 world.fog = string_null;
 120         }
 121         if(MapInfo_Map_fog != "")
 122                 if(MapInfo_Map_fog == "none")
 123                         world.fog = string_null;
 124                 else
 125                         world.fog = strzone(MapInfo_Map_fog);
 126         clientstuff = strzone(MapInfo_Map_clientstuff);
 127
 128         MapInfo_ClearTemps();
 129
 130         // set both here, gamemode can override it later
 131         timelimit_override = autocvar_timelimit_override;
 132         fraglimit_override = autocvar_fraglimit_override;
 133         leadlimit_override = autocvar_leadlimit_override;
 134         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 135
 136         if(g_dm)
 137         {
 138         }
 139
 140         if(g_tdm)
 141         {
 142                 ActivateTeamplay();
 143                 tdm_init();
 144                 if(autocvar_g_tdm_team_spawns)
 145                         have_team_spawns = -1; // request team spawns
 146         }
 147
 148         if(g_domination)
 149         {
 150                 ActivateTeamplay();
 151                 fraglimit_override = autocvar_g_domination_point_limit;
 152                 leadlimit_override = autocvar_g_domination_point_leadlimit;
 153                 dom_init();
 154                 have_team_spawns = -1; // request team spawns
 155         }
 156
 157         if(g_ctf)
 158         {
 159                 ActivateTeamplay();
 160                 g_ctf_ignore_frags = autocvar_g_ctf_ignore_frags;
 161                 fraglimit_override = autocvar_capturelimit_override;
 162                 leadlimit_override = autocvar_captureleadlimit_override;
 163                 ctf_init();
 164                 have_team_spawns = -1; // request team spawns
 165         }
 166
 167         if(g_runematch)
 168         {
 169                 // ActivateTeamplay();
 170                 fraglimit_override = autocvar_g_runematch_point_limit;
 171                 leadlimit_override = autocvar_g_runematch_point_leadlimit;
 172                 runematch_init();
 173         }
 174
 175         if(g_lms)
 176         {
 177                 fraglimit_override = autocvar_g_lms_lives_override;
 178                 leadlimit_override = 0; // not supported by LMS
 179                 if(fraglimit_override == 0)
 180                         fraglimit_override = -1;
 181                 lms_lowest_lives = 9999;
 182                 lms_next_place = 0;
 183                 ScoreRules_lms();
 184         }
 185
 186         if(g_arena)
 187         {
 188                 fraglimit_override = autocvar_g_arena_point_limit;
 189                 leadlimit_override = autocvar_g_arena_point_leadlimit;
 190                 maxspawned = autocvar_g_arena_maxspawned;
 191                 if(maxspawned < 2)
 192                         maxspawned = 2;
 193                 arena_roundbased = autocvar_g_arena_roundbased;
 194         }
 195
 196         if(g_ca)
 197         {
 198                 ActivateTeamplay();
 199                 fraglimit_override = autocvar_g_ca_point_limit;
 200                 leadlimit_override = autocvar_g_ca_point_leadlimit;
 201                 precache_sound("ctf/red_capture.wav");
 202                 precache_sound("ctf/blue_capture.wav");
 203         }
 204         if(g_keyhunt)
 205         {
 206                 ActivateTeamplay();
 207                 fraglimit_override = autocvar_g_keyhunt_point_limit;
 208                 leadlimit_override = autocvar_g_keyhunt_point_leadlimit;
 209                 MUTATOR_ADD(gamemode_keyhunt);
 210         }
 211
 212         if(g_freezetag)
 213         {
 214                 ActivateTeamplay();
 215                 fraglimit_override = autocvar_g_freezetag_point_limit;
 216                 leadlimit_override = autocvar_g_freezetag_point_leadlimit;
 217                 MUTATOR_ADD(gamemode_freezetag);
 218         }
 219
 220         if(g_assault)
 221         {
 222                 ActivateTeamplay();
 223                 ScoreRules_assault();
 224                 have_team_spawns = -1; // request team spawns
 225         }
 226
 227         if(g_onslaught)
 228         {
 229                 ActivateTeamplay();
 230                 have_team_spawns = -1; // request team spawns
 231         }
 232
 233         if(g_race)
 234         {
 235
 236                 if(autocvar_g_race_teams)
 237                 {
 238                         ActivateTeamplay();
 239                         race_teams = bound(2, autocvar_g_race_teams, 4);
 240                         have_team_spawns = -1; // request team spawns
 241                 }
 242                 else
 243                         race_teams = 0;
 244
 245                 qualifying_override = autocvar_g_race_qualifying_timelimit_override;
 246                 fraglimit_override = autocvar_g_race_laps_limit;
 247                 leadlimit_override = 0; // currently not supported by race
 248         }
 249
 250         if(g_cts)
 251         {
 252                 g_race_qualifying = 1;
 253                 fraglimit_override = 0;
 254                 leadlimit_override = 0;
 255         }
 256
 257         if(g_nexball)
 258         {
 259         fraglimit_override = autocvar_g_nexball_goallimit;
 260         leadlimit_override = autocvar_g_nexball_goalleadlimit;
 261         ActivateTeamplay();
 262         have_team_spawns = -1; // request team spawns
 263             MUTATOR_ADD(gamemode_nexball);
 264         }
 265
 266         if(g_keepaway)
 267         {
 268                 MUTATOR_ADD(gamemode_keepaway);
 269         }
 270
 271         if(teamplay)
 272                 entcs_init();
 273
 274         cache_mutatormsg = strzone("");
 275         cache_lastmutatormsg = strzone("");
 276
 277         // enforce the server's universal frag/time limits
 278         if(!autocvar_g_campaign)
 279         {
 280                 if(fraglimit_override >= 0)
 281                         cvar_set("fraglimit", ftos(fraglimit_override));
 282                 if(timelimit_override >= 0)
 283                         cvar_set("timelimit", ftos(timelimit_override));
 284                 if(leadlimit_override >= 0)
 285                         cvar_set("leadlimit", ftos(leadlimit_override));
 286                 if(qualifying_override >= 0)
 287                         cvar_set("g_race_qualifying_timelimit", ftos(qualifying_override));
 288         }
 289
 290         if(g_race)
 291         {
 292                 // we need to find out the correct value for g_race_qualifying
 293                 if(autocvar_g_campaign)
 294                 {
 295                         g_race_qualifying = 1;
 296                 }
 297                 else if(!autocvar_g_campaign && autocvar_g_race_qualifying_timelimit > 0)
 298                 {
 299                         g_race_qualifying = 2;
 300                         race_fraglimit = autocvar_fraglimit;
 301                         race_leadlimit = autocvar_leadlimit;
 302                         race_timelimit = autocvar_timelimit;
 303                         cvar_set("fraglimit", "0");
 304                         cvar_set("leadlimit", "0");
 305                         cvar_set("timelimit", ftos(autocvar_g_race_qualifying_timelimit));
 306                 }
 307                 else
 308                         g_race_qualifying = 0;
 309         }
 310
 311         if(g_race || g_cts)
 312         {
 313                 if(g_race_qualifying)
 314                         independent_players = 1;
 315
 316                 ScoreRules_race();
 317         }
 318
 319         InitializeEntity(world, default_delayedinit, INITPRIO_GAMETYPE_FALLBACK);
 320 }
 321
 322 string GetClientVersionMessage() {
 323         string versionmsg;
 324         if (self.version_mismatch) {
 325                 if(self.version < autocvar_gameversion) {
 326                         versionmsg = "^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8";
 327                 } else {
 328                         versionmsg = "^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8";
 329                 }
 330         } else {
 331                 versionmsg = "^2client version and server version are compatible.^8";
 332         }
 333         return versionmsg;
 334 }
 335
 336 string getwelcomemessage(void)
 337 {
 338         string s, modifications, motd;
 339
 340         ret_string = "";
 341         MUTATOR_CALLHOOK(BuildMutatorsPrettyString);
 342         modifications = ret_string;
 343
 344         if(g_minstagib)
 345                 modifications = strcat(modifications, ", MinstaGib");
 346         if(g_weaponarena)
 347         {
 348                 if(g_weaponarena_random)
 349                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
 350                 else
 351                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
 352         }
 353         if(autocvar_g_start_weapon_laser == 0)
 354                 modifications = strcat(modifications, ", No start weapons");
 355         if(autocvar_sv_gravity < 800)
 356                 modifications = strcat(modifications, ", Low gravity");
 357         if(g_cloaked && !g_cts)
 358                 modifications = strcat(modifications, ", Cloaked");
 359         if(g_grappling_hook)
 360                 modifications = strcat(modifications, ", Hook");
 361         if(g_midair)
 362                 modifications = strcat(modifications, ", Midair");
 363         if(g_pinata)
 364                 modifications = strcat(modifications, ", Piñata");
 365         if(g_weapon_stay && !g_cts)
 366                 modifications = strcat(modifications, ", Weapons stay");
 367         if(g_bloodloss > 0)
 368                 modifications = strcat(modifications, ", Blood loss");
 369         if(g_jetpack)
 370                 modifications = strcat(modifications, ", Jet pack");
 371         if(autocvar_g_powerups == 0)
 372                 modifications = strcat(modifications, ", No powerups");
 373         if(autocvar_g_powerups > 0)
 374                 modifications = strcat(modifications, ", Powerups");
 375         modifications = substring(modifications, 2, strlen(modifications) - 2);
 376
 377         string versionmessage;
 378         versionmessage = GetClientVersionMessage();
 379
 380         s = strcat("This is Xonotic ", autocvar_g_xonoticversion, "\n", versionmessage);
 381         s = strcat(s, "^8\n\nmatch type is ^1", gamemode_name, "^8\n");
 382
 383         if(modifications != "")
 384                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
 385
 386         if (g_grappling_hook)
 387                 s = strcat(s, "\n\n^3grappling hook^8 is enabled, press 'e' to use it\n");
 388
 389         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
 390         {
 391                 if(cache_lastmutatormsg)
 392                         strunzone(cache_lastmutatormsg);
 393                 if(cache_mutatormsg)
 394                         strunzone(cache_mutatormsg);
 395                 cache_lastmutatormsg = strzone(autocvar_g_mutatormsg);
 396                 cache_mutatormsg = strzone(cache_lastmutatormsg);
 397         }
 398
 399         if (cache_mutatormsg != "") {
 400                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
 401         }
 402
 403         motd = autocvar_sv_motd;
 404         if (motd != "") {
 405                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
 406         }
 407         return s;
 408 }
 409
 410 void SetPlayerColors(entity pl, float _color)
 411 {
 412         /*string s;
 413         s = ftos(cl);
 414         stuffcmd(pl, strcat("color ", s, " ", s, "\n")  );
 415         pl.team = cl + 1;
 416         //pl.clientcolors = pl.clientcolors - (pl.clientcolors & 15) + cl;
 417         pl.clientcolors = 16*cl + cl;*/
 418
 419         float pants, shirt;
 420         pants = _color & 0x0F;
 421         shirt = _color & 0xF0;
 422
 423
 424         if(teamplay) {
 425                 setcolor(pl, 16*pants + pants);
 426         } else {
 427                 setcolor(pl, shirt + pants);
 428         }
 429 }
 430
 431 void SetPlayerTeam(entity pl, float t, float s, float noprint)
 432 {
 433         float _color;
 434
 435         if(t == 4)
 436                 _color = COLOR_TEAM4 - 1;
 437         else if(t == 3)
 438                 _color = COLOR_TEAM3 - 1;
 439         else if(t == 2)
 440                 _color = COLOR_TEAM2 - 1;
 441         else
 442                 _color = COLOR_TEAM1 - 1;
 443
 444         SetPlayerColors(pl,_color);
 445
 446         if(t != s) {
 447                 LogTeamchange(pl.playerid, pl.team, 3);  // log manual team join
 448
 449                 if(!noprint)
 450                 bprint(pl.netname, "^7 has changed from ", TeamNoName(s), " to ", TeamNoName(t), "\n");
 451         }
 452
 453 }
 454
 455 // set c1...c4 to show what teams are allowed
 456 void CheckAllowedTeams (entity for_whom)
 457 {
 458         float dm;
 459         entity head;
 460         string teament_name;
 461
 462         c1 = c2 = c3 = c4 = -1;
 463         cb1 = cb2 = cb3 = cb4 = 0;
 464
 465         if(g_onslaught)
 466         {
 467                 // onslaught is special
 468                 head = findchain(classname, "onslaught_generator");
 469                 while (head)
 470                 {
 471                         if (head.team == COLOR_TEAM1) c1 = 0;
 472                         if (head.team == COLOR_TEAM2) c2 = 0;
 473                         if (head.team == COLOR_TEAM3) c3 = 0;
 474                         if (head.team == COLOR_TEAM4) c4 = 0;
 475                         head = head.chain;
 476                 }
 477         }
 478         else if(g_domination)
 479                 teament_name = "dom_team";
 480         else if(g_ctf)
 481                 teament_name = "ctf_team";
 482         else if(g_tdm)
 483                 teament_name = "tdm_team";
 484         else if(g_nexball)
 485                 teament_name = "nexball_team";
 486         else if(g_assault)
 487                 c1 = c2 = 0; // Assault always has 2 teams
 488         else
 489         {
 490                 // cover anything else by treating it like tdm with no teams spawned
 491                 if(g_race)
 492                         dm = race_teams;
 493                 else
 494                         dm = 2;
 495
 496                 ret_float = dm;
 497                 MUTATOR_CALLHOOK(GetTeamCount);
 498                 dm = ret_float;
 499
 500                 if(dm >= 4)
 501                         c1 = c2 = c3 = c4 = 0;
 502                 else if(dm >= 3)
 503                         c1 = c2 = c3 = 0;
 504                 else
 505                         c1 = c2 = 0;
 506         }
 507
 508         // find out what teams are allowed if necessary
 509         if(teament_name)
 510         {
 511                 head = find(world, classname, teament_name);
 512                 while(head)
 513                 {
 514                         if(!(g_domination && head.netname == ""))
 515                         {
 516                                 if(head.team == COLOR_TEAM1)
 517                                         c1 = 0;
 518                                 else if(head.team == COLOR_TEAM2)
 519                                         c2 = 0;
 520                                 else if(head.team == COLOR_TEAM3)
 521                                         c3 = 0;
 522                                 else if(head.team == COLOR_TEAM4)
 523                                         c4 = 0;
 524                         }
 525                         head = find(head, classname, teament_name);
 526                 }
 527         }
 528
 529         // TODO: Balance quantity of bots across > 2 teams when bot_vs_human is set (and remove next line)
 530         if(c3==-1 && c4==-1)
 531         if(autocvar_bot_vs_human && for_whom)
 532         {
 533                 if(autocvar_bot_vs_human > 0)
 534                 {
 535                         // bots are all blue
 536                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 537                                 c1 = c3 = c4 = -1;
 538                         else
 539                                 c2 = -1;
 540                 }
 541                 else
 542                 {
 543                         // bots are all red
 544                         if(clienttype(for_whom) == CLIENTTYPE_BOT)
 545                                 c2 = c3 = c4 = -1;
 546                         else
 547                                 c1 = -1;
 548                 }
 549         }
 550
 551         // if player has a forced team, ONLY allow that one
 552         if(self.team_forced == COLOR_TEAM1 && c1 >= 0)
 553                 c2 = c3 = c4 = -1;
 554         else if(self.team_forced == COLOR_TEAM2 && c2 >= 0)
 555                 c1 = c3 = c4 = -1;
 556         else if(self.team_forced == COLOR_TEAM3 && c3 >= 0)
 557                 c1 = c2 = c4 = -1;
 558         else if(self.team_forced == COLOR_TEAM4 && c4 >= 0)
 559                 c1 = c2 = c3 = -1;
 560 }
 561
 562 float PlayerValue(entity p)
 563 {
 564         if(IsTeamBalanceForced() == 1)
 565                 return 1;
 566         return 1;
 567         // FIXME: it always returns 1...
 568 }
 569
 570 // c1...c4 should be set to -1 (not allowed) or 0 (allowed).
 571 // teams that are allowed will now have their player counts stored in c1...c4
 572 void GetTeamCounts(entity ignore)
 573 {
 574         entity head;
 575         float value, bvalue;
 576         // now count how many players are on each team already
 577
 578         // FIXME: also find and memorize the lowest-scoring bot on each team (in case players must be shuffled around)
 579         // also remember the lowest-scoring player
 580
 581         FOR_EACH_CLIENT(head)
 582         {
 583                 float t;
 584                 if(head.classname == "player")
 585                         t = head.team;
 586                 else if(head.team_forced > 0)
 587                         t = head.team_forced; // reserve the spot
 588                 else
 589                         continue;
 590                 if(head != ignore)// && head.netname != "")
 591                 {
 592                         value = PlayerValue(head);
 593                         if(clienttype(head) == CLIENTTYPE_BOT)
 594                                 bvalue = value;
 595                         else
 596                                 bvalue = 0;
 597                         if(t == COLOR_TEAM1)
 598                         {
 599                                 if(c1 >= 0)
 600                                 {
 601                                         c1 = c1 + value;
 602                                         cb1 = cb1 + bvalue;
 603                                 }
 604                         }
 605                         if(t == COLOR_TEAM2)
 606                         {
 607                                 if(c2 >= 0)
 608                                 {
 609                                         c2 = c2 + value;
 610                                         cb2 = cb2 + bvalue;
 611                                 }
 612                         }
 613                         if(t == COLOR_TEAM3)
 614                         {
 615                                 if(c3 >= 0)
 616                                 {
 617                                         c3 = c3 + value;
 618                                         cb3 = cb3 + bvalue;
 619                                 }
 620                         }
 621                         if(t == COLOR_TEAM4)
 622                         {
 623                                 if(c4 >= 0)
 624                                 {
 625                                         c4 = c4 + value;
 626                                         cb4 = cb4 + bvalue;
 627                                 }
 628                         }
 629                 }
 630         }
 631
 632         // if the player who has a forced team has not joined yet, reserve the spot
 633         if(autocvar_g_campaign)
 634         {
 635                 switch(autocvar_g_campaign_forceteam)
 636                 {
 637                         case 1: if(c1 == cb1) ++c1; break;
 638                         case 2: if(c2 == cb2) ++c2; break;
 639                         case 3: if(c3 == cb3) ++c3; break;
 640                         case 4: if(c4 == cb4) ++c4; break;
 641                 }
 642         }
 643 }
 644
 645 // returns # of smallest team (1, 2, 3, 4)
 646 // NOTE: Assumes CheckAllowedTeams has already been called!
 647 float FindSmallestTeam(entity pl, float ignore_pl)
 648 {
 649         float totalteams, balance_type, maxc;
 650         totalteams = 0;
 651
 652         // find out what teams are available
 653         //CheckAllowedTeams();
 654
 655         // make sure there are at least 2 teams to join
 656         if(c1 >= 0)
 657                 totalteams = totalteams + 1;
 658         if(c2 >= 0)
 659                 totalteams = totalteams + 1;
 660         if(c3 >= 0)
 661                 totalteams = totalteams + 1;
 662         if(c4 >= 0)
 663                 totalteams = totalteams + 1;
 664
 665         if((autocvar_bot_vs_human || pl.team_forced > 0) && totalteams == 1)
 666                 totalteams += 1;
 667
 668         if(totalteams <= 1)
 669         {
 670                 if(autocvar_g_campaign && pl && clienttype(pl) == CLIENTTYPE_REAL)
 671                         return 1; // special case for campaign and player joining
 672                 else if(g_domination)
 673                         error("Too few teams available for domination\n");
 674                 else if(g_ctf)
 675                         error("Too few teams available for ctf\n");
 676                 else if(g_keyhunt)
 677                         error("Too few teams available for key hunt\n");
 678                 else if(g_freezetag)
 679                         error("Too few teams available for freeze tag\n");
 680                 else
 681                         error("Too few teams available for team deathmatch\n");
 682         }
 683
 684         // count how many players are in each team
 685         if(ignore_pl)
 686                 GetTeamCounts(pl);
 687         else
 688                 GetTeamCounts(world);
 689
 690         // c1...c4 now have counts of each team
 691         // figure out which is smallest, giving priority to the team the player is already on as a tie-breaker
 692
 693         // 2 gives priority to what team you're already on, 1 goes in order
 694         // 2 doesn't seem to work though...
 695         balance_type = 1;
 696
 697         if(bots_would_leave)
 698         //if(pl.classname != "player")
 699         if(clienttype(pl) != CLIENTTYPE_BOT)
 700         {
 701                 c1 -= cb1 * 255.0/256.0;
 702                 c2 -= cb2 * 255.0/256.0;
 703                 c3 -= cb3 * 255.0/256.0;
 704                 c4 -= cb4 * 255.0/256.0;
 705         }
 706         maxc = max4(c1, c2, c3, c4);
 707
 708         RandomSelection_Init();
 709         if(balance_type == 1)
 710         {
 711                 // 1: use team count, then score (note: can only use 8 significant bits of score)
 712                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score) / 256.0);
 713                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score) / 256.0);
 714                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score) / 256.0);
 715                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score) / 256.0);
 716         }
 717         else if(balance_type == 2)
 718         {
 719                 // 1: use team count, if equal prefer own team
 720                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM1) / 512.0);
 721                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM2) / 512.0);
 722                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM3) / 512.0);
 723                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c1) + (self.team == COLOR_TEAM4) / 512.0);
 724         }
 725         else if(balance_type == 3)
 726         {
 727                 // 1: use team count, then score, if equal prefer own team (probably fails due to float accuracy problems)
 728                 if(c1 >= 0) RandomSelection_Add(world, 1, string_null, 1, (maxc - c1) + float2range01(-team1_score + 0.5 * (self.team == COLOR_TEAM1)) / 256.0);
 729                 if(c2 >= 0) RandomSelection_Add(world, 2, string_null, 1, (maxc - c2) + float2range01(-team2_score + 0.5 * (self.team == COLOR_TEAM2)) / 256.0);
 730                 if(c3 >= 0) RandomSelection_Add(world, 3, string_null, 1, (maxc - c3) + float2range01(-team3_score + 0.5 * (self.team == COLOR_TEAM3)) / 256.0);
 731                 if(c4 >= 0) RandomSelection_Add(world, 4, string_null, 1, (maxc - c4) + float2range01(-team4_score + 0.5 * (self.team == COLOR_TEAM4)) / 256.0);
 732         }
 733         return RandomSelection_chosen_float;
 734 }
 735
 736 float JoinBestTeam(entity pl, float only_return_best, float forcebestteam)
 737 {
 738         float smallest, selectedteam;
 739
 740         // don't join a team if we're not playing a team game
 741         if(!teamplay)
 742                 return 0;
 743
 744         // find out what teams are available
 745         CheckAllowedTeams(pl);
 746
 747         // if we don't care what team he ends up on, put him on whatever team he entered as.
 748         // if he's not on a valid team, then let other code put him on the smallest team
 749         if(!forcebestteam)
 750         {
 751                 if(     c1 >= 0 && pl.team == COLOR_TEAM1)
 752                         selectedteam = pl.team;
 753                 else if(c2 >= 0 && pl.team == COLOR_TEAM2)
 754                         selectedteam = pl.team;
 755                 else if(c3 >= 0 && pl.team == COLOR_TEAM3)
 756                         selectedteam = pl.team;
 757                 else if(c4 >= 0 && pl.team == COLOR_TEAM4)
 758                         selectedteam = pl.team;
 759                 else
 760                         selectedteam = -1;
 761
 762                 if(selectedteam > 0)
 763                 {
 764                         if(!only_return_best)
 765                         {
 766                                 SetPlayerColors(pl, selectedteam - 1);
 767
 768                                 // when JoinBestTeam is called by client.qc/ClientKill_Now_TeamChange the players team is -1 and thus skipped
 769                                 // when JoinBestTeam is called by cl_client.qc/ClientConnect the player_id is 0 the log attempt is rejected
 770                                 LogTeamchange(pl.playerid, pl.team, 99);
 771                         }
 772                         return selectedteam;
 773                 }
 774                 // otherwise end up on the smallest team (handled below)
 775         }
 776
 777         smallest = FindSmallestTeam(pl, TRUE);
 778
 779         if(!only_return_best && !pl.bot_forced_team)
 780         {
 781                 TeamchangeFrags(self);
 782                 if(smallest == 1)
 783                 {
 784                         SetPlayerColors(pl, COLOR_TEAM1 - 1);
 785                 }
 786                 else if(smallest == 2)
 787                 {
 788                         SetPlayerColors(pl, COLOR_TEAM2 - 1);
 789                 }
 790                 else if(smallest == 3)
 791                 {
 792                         SetPlayerColors(pl, COLOR_TEAM3 - 1);
 793                 }
 794                 else if(smallest == 4)
 795                 {
 796                         SetPlayerColors(pl, COLOR_TEAM4 - 1);
 797                 }
 798                 else
 799                 {
 800                         error("smallest team: invalid team\n");
 801                 }
 802
 803                 LogTeamchange(pl.playerid, pl.team, 2); // log auto join
 804
 805                 if(pl.deadflag == DEAD_NO)
 806                         Damage(pl, pl, pl, 100000, DEATH_TEAMCHANGE, pl.origin, '0 0 0');
 807         }
 808
 809         return smallest;
 810 }
 811
 812 //void() ctf_playerchanged;
 813 void SV_ChangeTeam(float _color)
 814 {
 815         float scolor, dcolor, steam, dteam, dbotcount, scount, dcount;
 816
 817         // in normal deathmatch we can just apply the color and we're done
 818         if(!teamplay) {
 819                 SetPlayerColors(self, _color);
 820                 return;
 821         }
 822
 823         scolor = self.clientcolors & 0x0F;
 824         dcolor = _color & 0x0F;
 825
 826         if(scolor == COLOR_TEAM1 - 1)
 827                 steam = 1;
 828         else if(scolor == COLOR_TEAM2 - 1)
 829                 steam = 2;
 830         else if(scolor == COLOR_TEAM3 - 1)
 831                 steam = 3;
 832         else // if(scolor == COLOR_TEAM4 - 1)
 833                 steam = 4;
 834         if(dcolor == COLOR_TEAM1 - 1)
 835                 dteam = 1;
 836         else if(dcolor == COLOR_TEAM2 - 1)
 837                 dteam = 2;
 838         else if(dcolor == COLOR_TEAM3 - 1)
 839                 dteam = 3;
 840         else // if(dcolor == COLOR_TEAM4 - 1)
 841                 dteam = 4;
 842
 843         CheckAllowedTeams(self);
 844
 845         if(dteam == 1 && c1 < 0) dteam = 4;
 846         if(dteam == 4 && c4 < 0) dteam = 3;
 847         if(dteam == 3 && c3 < 0) dteam = 2;
 848         if(dteam == 2 && c2 < 0) dteam = 1;
 849
 850         // not changing teams
 851         if(scolor == dcolor)
 852         {
 853                 //bprint("same team change\n");
 854                 SetPlayerTeam(self, dteam, steam, TRUE);
 855                 return;
 856         }
 857
 858         if((autocvar_g_campaign) || (autocvar_g_changeteam_banned && self.wasplayer)) {
 859                 sprint(self, "Team changes not allowed\n");
 860                 return; // changing teams is not allowed
 861         }
 862
 863         if(autocvar_g_balance_teams_prevent_imbalance)
 864         {
 865                 // only allow changing to a smaller or equal size team
 866
 867                 // find out what teams are available
 868                 //CheckAllowedTeams();
 869                 // count how many players on each team
 870                 GetTeamCounts(world);
 871
 872                 // get desired team
 873                 if(dteam == 1 && c1 >= 0)//dcolor == COLOR_TEAM1 - 1)
 874                 {
 875                         dcount = c1;
 876                         dbotcount = cb1;
 877                 }
 878                 else if(dteam == 2 && c2 >= 0)//dcolor == COLOR_TEAM2 - 1)
 879                 {
 880                         dcount = c2;
 881                         dbotcount = cb2;
 882                 }
 883                 else if(dteam == 3 && c3 >= 0)//dcolor == COLOR_TEAM3 - 1)
 884                 {
 885                         dcount = c3;
 886                         dbotcount = cb3;
 887                 }
 888                 else if(dteam == 4 && c4 >= 0)//dcolor == COLOR_TEAM4 - 1)
 889                 {
 890                         dcount = c4;
 891                         dbotcount = cb4;
 892                 }
 893                 else
 894                 {
 895                         sprint(self, "Cannot change to an invalid team\n");
 896
 897                         return;
 898                 }
 899
 900                 // get starting team
 901                 if(steam == 1)//scolor == COLOR_TEAM1 - 1)
 902                         scount = c1;
 903                 else if(steam == 2)//scolor == COLOR_TEAM2 - 1)
 904                         scount = c2;
 905                 else if(steam == 3)//scolor == COLOR_TEAM3 - 1)
 906                         scount = c3;
 907                 else if(steam == 4)//scolor == COLOR_TEAM4 - 1)
 908                         scount = c4;
 909
 910                 if(scount) // started at a valid, nonempty team
 911                 {
 912                         // check if we're trying to change to a larger team that doens't have bots to swap with
 913                         if(dcount >= scount && dbotcount <= 0)
 914                         {
 915                                 sprint(self, "Cannot change to a larger team\n");
 916                                 return; // can't change to a larger team
 917                         }
 918                 }
 919         }
 920
 921 //      bprint("allow change teams from ", ftos(steam), " to ", ftos(dteam), "\n");
 922
 923         if(self.classname == "player" && steam != dteam)
 924         {
 925                 // reduce frags during a team change
 926                 TeamchangeFrags(self);
 927         }
 928
 929         SetPlayerTeam(self, dteam, steam, FALSE);
 930
 931         if(self.classname == "player" && steam != dteam)
 932         {
 933                 // kill player when changing teams
 934                 if(self.deadflag == DEAD_NO)
 935                         Damage(self, self, self, 100000, DEATH_TEAMCHANGE, self.origin, '0 0 0');
 936         }
 937         //ctf_playerchanged();
 938 }
 939
 940 void ShufflePlayerOutOfTeam (float source_team)
 941 {
 942         float smallestteam, smallestteam_count, steam;
 943         float lowest_bot_score, lowest_player_score;
 944         entity head, lowest_bot, lowest_player, selected;
 945
 946         smallestteam = 0;
 947         smallestteam_count = 999999999;
 948
 949         if(c1 >= 0 && c1 < smallestteam_count)
 950         {
 951                 smallestteam = 1;
 952                 smallestteam_count = c1;
 953         }
 954         if(c2 >= 0 && c2 < smallestteam_count)
 955         {
 956                 smallestteam = 2;
 957                 smallestteam_count = c2;
 958         }
 959         if(c3 >= 0 && c3 < smallestteam_count)
 960         {
 961                 smallestteam = 3;
 962                 smallestteam_count = c3;
 963         }
 964         if(c4 >= 0 && c4 < smallestteam_count)
 965         {
 966                 smallestteam = 4;
 967                 smallestteam_count = c4;
 968         }
 969
 970         if(!smallestteam)
 971         {
 972                 bprint("warning: no smallest team\n");
 973                 return;
 974         }
 975
 976         if(source_team == 1)
 977                 steam = COLOR_TEAM1;
 978         else if(source_team == 2)
 979                 steam = COLOR_TEAM2;
 980         else if(source_team == 3)
 981                 steam = COLOR_TEAM3;
 982         else if(source_team == 4)
 983                 steam = COLOR_TEAM4;
 984
 985         lowest_bot = world;
 986         lowest_bot_score = 999999999;
 987         lowest_player = world;
 988         lowest_player_score = 999999999;
 989
 990         // find the lowest-scoring player & bot of that team
 991         FOR_EACH_PLAYER(head)
 992         {
 993                 if(head.team == steam)
 994                 {
 995                         if(head.isbot)
 996                         {
 997                                 if(head.totalfrags < lowest_bot_score)
 998                                 {
 999                                         lowest_bot = head;
1000                                         lowest_bot_score = head.totalfrags;
1001                                 }
1002                         }
1003                         else
1004                         {
1005                                 if(head.totalfrags < lowest_player_score)
1006                                 {
1007                                         lowest_player = head;
1008                                         lowest_player_score = head.totalfrags;
1009                                 }
1010                         }
1011                 }
1012         }
1013
1014         // prefers to move a bot...
1015         if(lowest_bot != world)
1016                 selected = lowest_bot;
1017         // but it will move a player if it has to
1018         else
1019                 selected = lowest_player;
1020         // don't do anything if it couldn't find anyone
1021         if(!selected)
1022         {
1023                 bprint("warning: couldn't find a player to move from team\n");
1024                 return;
1025         }
1026
1027         // smallest team gains a member
1028         if(smallestteam == 1)
1029         {
1030                 c1 = c1 + 1;
1031         }
1032         else if(smallestteam == 2)
1033         {
1034                 c2 = c2 + 1;
1035         }
1036         else if(smallestteam == 3)
1037         {
1038                 c3 = c3 + 1;
1039         }
1040         else if(smallestteam == 4)
1041         {
1042                 c4 = c4 + 1;
1043         }
1044         else
1045         {
1046                 bprint("warning: destination team invalid\n");
1047                 return;
1048         }
1049         // source team loses a member
1050         if(source_team == 1)
1051         {
1052                 c1 = c1 + 1;
1053         }
1054         else if(source_team == 2)
1055         {
1056                 c2 = c2 + 2;
1057         }
1058         else if(source_team == 3)
1059         {
1060                 c3 = c3 + 3;
1061         }
1062         else if(source_team == 4)
1063         {
1064                 c4 = c4 + 4;
1065         }
1066         else
1067         {
1068                 bprint("warning: source team invalid\n");
1069                 return;
1070         }
1071
1072         // move the player to the new team
1073         TeamchangeFrags(selected);
1074         SetPlayerTeam(selected, smallestteam, source_team, FALSE);
1075
1076         if(selected.deadflag == DEAD_NO)
1077                 Damage(selected, selected, selected, 100000, DEATH_AUTOTEAMCHANGE, selected.origin, '0 0 0');
1078         centerprint(selected, strcat("You have been moved into a different team to improve team balance\nYou are now on: ", ColoredTeamName(selected.team)));
1079 }
1080
1081 void CauseRebalance(float source_team, float howmany_toomany)
1082 {
1083         if(IsTeamBalanceForced() == 1)
1084         {
1085                 bprint("Rebalancing Teams\n");
1086                 ShufflePlayerOutOfTeam(source_team);
1087         }
1088 }
1089
1090 // part of g_balance_teams_force
1091 // occasionally perform an audit of the teams to make
1092 // sure they're more or less balanced in player count.
1093 void AuditTeams()
1094 {
1095         float numplayers, numteams, smallest, toomany;
1096         float balance;
1097         balance = IsTeamBalanceForced();
1098         if(balance == 0)
1099                 return;
1100
1101         if(audit_teams_time > time)
1102                 return;
1103
1104         audit_teams_time = time + 4 + random();
1105
1106 //      bprint("Auditing teams\n");
1107
1108         CheckAllowedTeams(world);
1109         GetTeamCounts(world);
1110
1111
1112         numteams = numplayers = smallest = 0;
1113         if(c1 >= 0)
1114         {
1115                 numteams = numteams + 1;
1116                 numplayers = numplayers + c1;
1117                 smallest = c1;
1118         }
1119         if(c2 >= 0)
1120         {
1121                 numteams = numteams + 1;
1122                 numplayers = numplayers + c2;
1123                 if(c2 < smallest)
1124                         smallest = c2;
1125         }
1126         if(c3 >= 0)
1127         {
1128                 numteams = numteams + 1;
1129                 numplayers = numplayers + c3;
1130                 if(c3 < smallest)
1131                         smallest = c3;
1132         }
1133         if(c4 >= 0)
1134         {
1135                 numteams = numteams + 1;
1136                 numplayers = numplayers + c4;
1137                 if(c4 < smallest)
1138                         smallest = c4;
1139         }
1140
1141         if(numplayers <= 0)
1142                 return; // no players to move around
1143         if(numteams < 2)
1144                 return; // don't bother shuffling if for some reason there aren't any teams
1145
1146         toomany = smallest + 1;
1147
1148         if(c1 && c1 > toomany)
1149                 CauseRebalance(1, c1 - toomany);
1150         if(c2 && c2 > toomany)
1151                 CauseRebalance(2, c2 - toomany);
1152         if(c3 && c3 > toomany)
1153                 CauseRebalance(3, c3 - toomany);
1154         if(c4 && c4 > toomany)
1155                 CauseRebalance(4, c4 - toomany);
1156
1157         // if teams are still unbalanced, balance them further in the next audit,
1158         // which will happen sooner (keep doing rapid audits until things are in order)
1159         audit_teams_time = time + 0.7 + random()*0.3;
1160 }
1161
1162 // code from here on is just to support maps that don't have team entities
1163 void tdm_spawnteam (string teamname, float teamcolor)
1164 {
1165         entity e;
1166         e = spawn();
1167         e.classname = "tdm_team";
1168         e.netname = teamname;
1169         e.cnt = teamcolor;
1170         e.team = e.cnt + 1;
1171 }
1172
1173 // spawn some default teams if the map is not set up for tdm
1174 void tdm_spawnteams()
1175 {
1176         float numteams;
1177
1178         numteams = autocvar_g_tdm_teams_override;
1179         if(numteams < 2)
1180                 numteams = autocvar_g_tdm_teams;
1181         numteams = bound(2, numteams, 4);
1182
1183         tdm_spawnteam("Red", COLOR_TEAM1-1);
1184         tdm_spawnteam("Blue", COLOR_TEAM2-1);
1185         if(numteams >= 3)
1186                 tdm_spawnteam("Yellow", COLOR_TEAM3-1);
1187         if(numteams >= 4)
1188                 tdm_spawnteam("Pink", COLOR_TEAM4-1);
1189 }
1190
1191 void tdm_delayedinit()
1192 {
1193         // if no teams are found, spawn defaults
1194         if (find(world, classname, "tdm_team") == world)
1195                 tdm_spawnteams();
1196 }
1197
1198 void tdm_init()
1199 {
1200         InitializeEntity(world, tdm_delayedinit, INITPRIO_GAMETYPE);
1201 }