qcsrc/server/t_items.qc

   1 #include "t_items.qh"
   2
   3 #if defined(SVQC)
   4     #include "_all.qh"
   5
   6     #include "g_subs.qh"
   7     #include "waypointsprites.qh"
   8
   9     #include "bot/bot.qh"
  10     #include "bot/waypoints.qh"
  11
  12     #include "mutators/mutators_include.qh"
  13
  14     #include "weapons/common.qh"
  15     #include "weapons/selection.qh"
  16     #include "weapons/weaponsystem.qh"
  17
  18     #include "../common/constants.qh"
  19     #include "../common/deathtypes.qh"
  20     #include "../common/notifications.qh"
  21     #include "../common/util.qh"
  22
  23     #include "../common/monsters/monsters.qh"
  24
  25     #include "../common/weapons/weapons.qh"
  26
  27     #include "../warpzonelib/util_server.qh"
  28 #endif
  29
  30 #ifdef CSQC
  31 void ItemDraw()
  32 {
  33     if(self.gravity)
  34     {
  35         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  36         if(self.move_flags & FL_ONGROUND)
  37         { // For some reason move_avelocity gets set to '0 0 0' here ...
  38             self.oldorigin = self.origin;
  39             self.gravity = 0;
  40
  41             if(autocvar_cl_animate_items)
  42             { // ... so reset it if animations are requested.
  43                 if(self.ItemStatus & ITS_ANIMATE1)
  44                     self.move_avelocity = '0 180 0';
  45
  46                 if(self.ItemStatus & ITS_ANIMATE2)
  47                     self.move_avelocity = '0 -90 0';
  48             }
  49         }
  50     }
  51     else if (autocvar_cl_animate_items)
  52     {
  53         if(self.ItemStatus & ITS_ANIMATE1)
  54         {
  55             self.angles += self.move_avelocity * frametime;
  56             setorigin(self, '0 0 10' + self.oldorigin + '0 0 8' * sin(time * 2));
  57         }
  58
  59         if(self.ItemStatus & ITS_ANIMATE2)
  60         {
  61             self.angles += self.move_avelocity * frametime;
  62             setorigin(self, '0 0 8' + self.oldorigin + '0 0 4' * sin(time * 3));
  63         }
  64     }
  65 }
  66
  67 void ItemDrawSimple()
  68 {
  69     if(self.gravity)
  70     {
  71         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  72
  73         if(self.move_flags & FL_ONGROUND)
  74             self.gravity = 0;
  75     }
  76 }
  77
  78 void ItemRead(float _IsNew)
  79 {
  80     int sf = ReadByte();
  81
  82     if(sf & ISF_LOCATION)
  83     {
  84         self.origin_x = ReadCoord();
  85         self.origin_y = ReadCoord();
  86         self.origin_z = ReadCoord();
  87         setorigin(self, self.origin);
  88         self.oldorigin = self.origin;
  89     }
  90
  91     if(sf & ISF_ANGLES)
  92     {
  93         self.angles_x = ReadCoord();
  94         self.angles_y = ReadCoord();
  95         self.angles_z = ReadCoord();
  96         self.move_angles = self.angles;
  97     }
  98
  99     if(sf & ISF_SIZE)
 100     {
 101         self.mins_x = ReadCoord();
 102         self.mins_y = ReadCoord();
 103         self.mins_z = ReadCoord();
 104         self.maxs_x = ReadCoord();
 105         self.maxs_y = ReadCoord();
 106         self.maxs_z = ReadCoord();
 107         setsize(self, self.mins, self.maxs);
 108     }
 109
 110     if(sf & ISF_STATUS) // need to read/write status frist so model can handle simple, fb etc.
 111     {
 112         self.ItemStatus = ReadByte();
 113
 114         if(self.ItemStatus & ITS_AVAILABLE)
 115         {
 116             self.alpha = 1;
 117             self.colormod = self.glowmod = '1 1 1';
 118         }
 119         else
 120         {
 121             if (autocvar_cl_ghost_items_color)
 122             {
 123                 self.alpha = autocvar_cl_ghost_items;
 124                 self.colormod = self.glowmod = autocvar_cl_ghost_items_color;
 125             }
 126             else
 127                 self.alpha = -1;
 128         }
 129
 130         if(autocvar_cl_fullbright_items)
 131             if(self.ItemStatus & ITS_ALLOWFB)
 132                 self.effects |= EF_FULLBRIGHT;
 133
 134         if(self.ItemStatus & ITS_STAYWEP)
 135         {
 136             self.colormod = self.glowmod = autocvar_cl_weapon_stay_color;
 137             self.alpha = autocvar_cl_weapon_stay_alpha;
 138
 139         }
 140
 141         if(self.ItemStatus & ITS_POWERUP)
 142         {
 143             if(self.ItemStatus & ITS_AVAILABLE)
 144                 self.effects |= (EF_ADDITIVE | EF_FULLBRIGHT);
 145             else
 146                  self.effects &= ~(EF_ADDITIVE | EF_FULLBRIGHT);
 147         }
 148     }
 149
 150     if(sf & ISF_MODEL)
 151     {
 152         self.drawmask  = MASK_NORMAL;
 153         self.movetype  = MOVETYPE_TOSS;
 154         self.draw       = ItemDraw;
 155
 156         if(self.mdl)
 157             strunzone(self.mdl);
 158
 159         self.mdl = "";
 160         string _fn = ReadString();
 161
 162         if(autocvar_cl_simple_items && (self.ItemStatus & ITS_ALLOWSI))
 163         {
 164             string _fn2 = substring(_fn, 0 , strlen(_fn) -4);
 165             self.draw = ItemDrawSimple;
 166
 167
 168
 169             if(fexists(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix)))
 170                 self.mdl = strzone(sprintf("%s%s.md3", _fn2, autocvar_cl_simpleitems_postfix));
 171             else if(fexists(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix)))
 172                 self.mdl = strzone(sprintf("%s%s.dpm", _fn2, autocvar_cl_simpleitems_postfix));
 173             else if(fexists(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix)))
 174                 self.mdl = strzone(sprintf("%s%s.iqm", _fn2, autocvar_cl_simpleitems_postfix));
 175             else if(fexists(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix)))
 176                 self.mdl = strzone(sprintf("%s%s.obj", _fn2, autocvar_cl_simpleitems_postfix));
 177             else
 178             {
 179                 self.draw = ItemDraw;
 180                 dprint("Simple item requested for ", _fn, " but no model exsist for it\n");
 181             }
 182         }
 183
 184         if(self.draw != ItemDrawSimple)
 185             self.mdl = strzone(_fn);
 186
 187
 188         if(self.mdl == "")
 189             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, " tell tZork aboute this!\n");
 190
 191         precache_model(self.mdl);
 192         setmodel(self, self.mdl);
 193     }
 194
 195     if(sf & ISF_COLORMAP)
 196         self.colormap = ReadShort();
 197
 198     if(sf & ISF_DROP)
 199     {
 200         self.gravity = 1;
 201         //self.move_angles = '0 0 0';
 202         self.move_movetype = MOVETYPE_TOSS;
 203         self.move_velocity_x = ReadCoord();
 204         self.move_velocity_y = ReadCoord();
 205         self.move_velocity_z = ReadCoord();
 206         self.velocity = self.move_velocity;
 207         self.move_origin = self.oldorigin;
 208
 209         if(!self.move_time)
 210         {
 211             self.move_time = time;
 212             self.spawntime = time;
 213         }
 214         else
 215             self.move_time = max(self.move_time, time);
 216     }
 217
 218     if(autocvar_cl_animate_items)
 219     {
 220         if(self.ItemStatus & ITS_ANIMATE1)
 221             self.move_avelocity = '0 180 0';
 222
 223         if(self.ItemStatus & ITS_ANIMATE2)
 224             self.move_avelocity = '0 -90 0';
 225     }
 226 }
 227
 228 #endif
 229
 230 #ifdef SVQC
 231 bool ItemSend(entity to, int sf)
 232 {
 233     if(self.gravity)
 234         sf |= ISF_DROP;
 235     else
 236         sf &= ~ISF_DROP;
 237
 238         WriteByte(MSG_ENTITY, ENT_CLIENT_ITEM);
 239         WriteByte(MSG_ENTITY, sf);
 240
 241         //WriteByte(MSG_ENTITY, self.cnt);
 242     if(sf & ISF_LOCATION)
 243     {
 244         WriteCoord(MSG_ENTITY, self.origin.x);
 245         WriteCoord(MSG_ENTITY, self.origin.y);
 246         WriteCoord(MSG_ENTITY, self.origin.z);
 247     }
 248
 249     if(sf & ISF_ANGLES)
 250     {
 251         WriteCoord(MSG_ENTITY, self.angles.x);
 252         WriteCoord(MSG_ENTITY, self.angles.y);
 253         WriteCoord(MSG_ENTITY, self.angles.z);
 254     }
 255
 256     if(sf & ISF_SIZE)
 257     {
 258         WriteCoord(MSG_ENTITY, self.mins.x);
 259         WriteCoord(MSG_ENTITY, self.mins.y);
 260         WriteCoord(MSG_ENTITY, self.mins.z);
 261         WriteCoord(MSG_ENTITY, self.maxs.x);
 262         WriteCoord(MSG_ENTITY, self.maxs.y);
 263         WriteCoord(MSG_ENTITY, self.maxs.z);
 264     }
 265
 266     if(sf & ISF_STATUS)
 267         WriteByte(MSG_ENTITY, self.ItemStatus);
 268
 269     if(sf & ISF_MODEL)
 270     {
 271
 272         if(self.mdl == "")
 273             dprint("^1WARNING!^7 self.mdl is unset for item ", self.classname, "exspect a crash just aboute now\n");
 274
 275         WriteString(MSG_ENTITY, self.mdl);
 276     }
 277
 278
 279     if(sf & ISF_COLORMAP)
 280         WriteShort(MSG_ENTITY, self.colormap);
 281
 282     if(sf & ISF_DROP)
 283     {
 284         WriteCoord(MSG_ENTITY, self.velocity.x);
 285         WriteCoord(MSG_ENTITY, self.velocity.y);
 286         WriteCoord(MSG_ENTITY, self.velocity.z);
 287     }
 288
 289     return true;
 290 }
 291
 292 void ItemUpdate(entity item)
 293 {
 294         item.SendFlags |= ISF_LOCATION;
 295 }
 296
 297 float have_pickup_item(void)
 298 {
 299         if(self.flags & FL_POWERUP)
 300         {
 301                 if(autocvar_g_powerups > 0)
 302                         return true;
 303                 if(autocvar_g_powerups == 0)
 304                         return false;
 305         }
 306         else
 307         {
 308                 if(autocvar_g_pickup_items > 0)
 309                         return true;
 310                 if(autocvar_g_pickup_items == 0)
 311                         return false;
 312                 if(g_weaponarena)
 313                         if(self.weapons || (self.items & IT_AMMO)) // no item or ammo pickups in weaponarena
 314                                 return false;
 315         }
 316         return true;
 317 }
 318
 319 /*
 320 float Item_Customize()
 321 {
 322         if(self.spawnshieldtime)
 323                 return true;
 324         if(self.weapons & ~other.weapons)
 325         {
 326                 self.colormod = '0 0 0';
 327                 self.glowmod = self.colormod;
 328                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
 329                 return true;
 330         }
 331         else
 332         {
 333                 if(g_ghost_items)
 334                 {
 335                         self.colormod = stov(autocvar_g_ghost_items_color);
 336                         self.glowmod = self.colormod;
 337                         self.alpha = g_ghost_items;
 338                         return true;
 339                 }
 340                 else
 341                         return false;
 342         }
 343 }
 344 */
 345
 346 void Item_Show (entity e, float mode)
 347 {
 348         e.effects &= ~(EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT | EF_NODEPTHTEST);
 349         e.ItemStatus &= ~ITS_STAYWEP;
 350         if (mode > 0)
 351         {
 352                 // make the item look normal, and be touchable
 353                 e.model = e.mdl;
 354                 e.solid = SOLID_TRIGGER;
 355                 e.spawnshieldtime = 1;
 356                 e.ItemStatus |= ITS_AVAILABLE;
 357         }
 358         else if (mode < 0)
 359         {
 360                 // hide the item completely
 361                 e.model = string_null;
 362                 e.solid = SOLID_NOT;
 363                 e.spawnshieldtime = 1;
 364                 e.ItemStatus &= ~ITS_AVAILABLE;
 365         }
 366         else if((e.flags & FL_WEAPON) && !(e.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 367         {
 368                 // make the item translucent and not touchable
 369                 e.model = e.mdl;
 370                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
 371                 e.effects |= EF_STARDUST;
 372                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 373                 e.ItemStatus |= (ITS_AVAILABLE | ITS_STAYWEP);
 374         }
 375         else
 376         {
 377                 //setmodel(e, "null");
 378                 e.solid = SOLID_NOT;
 379                 e.colormod = '0 0 0';
 380                 e.glowmod = e.colormod;
 381                 e.spawnshieldtime = 1;
 382                 e.ItemStatus &= ~ITS_AVAILABLE;
 383         }
 384
 385         if (e.items & IT_STRENGTH || e.items & IT_INVINCIBLE)
 386             e.ItemStatus |= ITS_POWERUP;
 387
 388         if (autocvar_g_nodepthtestitems)
 389                 e.effects |= EF_NODEPTHTEST;
 390
 391
 392     if (autocvar_g_fullbrightitems)
 393                 e.ItemStatus |= ITS_ALLOWFB;
 394
 395         if (autocvar_sv_simple_items)
 396         e.ItemStatus |= ITS_ALLOWSI;
 397
 398         // relink entity (because solid may have changed)
 399         setorigin(e, e.origin);
 400     e.SendFlags |= ISF_STATUS;
 401 }
 402
 403 void Item_Think()
 404 {
 405         self.nextthink = time;
 406         if(self.origin != self.oldorigin)
 407         {
 408                 self.oldorigin = self.origin;
 409                 ItemUpdate(self);
 410         }
 411 }
 412
 413 float it_armor_large_time;
 414 float it_health_mega_time;
 415 float it_invisible_time;
 416 float it_speed_time;
 417 float it_extralife_time;
 418 float it_strength_time;
 419 float it_shield_time;
 420 float it_fuelregen_time;
 421 float it_jetpack_time;
 422 float it_superweapons_time;
 423
 424 void Item_ItemsTime_Init()
 425 {
 426         it_armor_large_time = -1;
 427         it_health_mega_time = -1;
 428         it_invisible_time = -1;
 429         it_speed_time = -1;
 430         it_extralife_time = -1;
 431         it_strength_time = -1;
 432         it_shield_time = -1;
 433         it_fuelregen_time = -1;
 434         it_jetpack_time = -1;
 435         it_superweapons_time = -1;
 436 }
 437 void Item_ItemsTime_Reset()
 438 {
 439         it_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 440         it_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 441         it_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 442         it_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 443         it_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 444         it_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 445         it_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 446         it_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 447         it_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 448         it_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 449 }
 450 void Item_ItemsTime_ResetForPlayer(entity e)
 451 {
 452         e.item_armor_large_time = (it_armor_large_time == -1) ? -1 : 0;
 453         e.item_health_mega_time = (it_health_mega_time == -1) ? -1 : 0;
 454         e.item_invisible_time   = (it_invisible_time   == -1) ? -1 : 0;
 455         e.item_speed_time       = (it_speed_time       == -1) ? -1 : 0;
 456         e.item_extralife_time   = (it_extralife_time   == -1) ? -1 : 0;
 457         e.item_strength_time    = (it_strength_time    == -1) ? -1 : 0;
 458         e.item_shield_time      = (it_shield_time      == -1) ? -1 : 0;
 459         e.item_fuelregen_time   = (it_fuelregen_time   == -1) ? -1 : 0;
 460         e.item_jetpack_time     = (it_jetpack_time     == -1) ? -1 : 0;
 461         e.item_superweapons_time= (it_superweapons_time== -1) ? -1 : 0;
 462 }
 463 void Item_ItemsTime_Get(entity e)
 464 {
 465         e.item_armor_large_time = it_armor_large_time;
 466         e.item_health_mega_time = it_health_mega_time;
 467         e.item_invisible_time = it_invisible_time;
 468         e.item_speed_time = it_speed_time;
 469         e.item_extralife_time = it_extralife_time;
 470         e.item_strength_time = it_strength_time;
 471         e.item_shield_time = it_shield_time;
 472         e.item_fuelregen_time = it_fuelregen_time;
 473         e.item_jetpack_time = it_jetpack_time;
 474         e.item_superweapons_time = it_superweapons_time;
 475 }
 476 float Item_ItemsTime_UpdateTime_Check(float item_time, float t)
 477 {
 478         if(t == 0 && item_time == -1)
 479                 return TRUE;
 480         if(time < t && (item_time <= time || t < item_time))
 481                 return TRUE;
 482         return FALSE;
 483 }
 484 void Item_ItemsTime_UpdateTime(entity e, float t)
 485 {
 486         if(g_instagib)
 487         {
 488                 switch(e.items)
 489                 {
 490                         case IT_STRENGTH://"item-invis"
 491                                 if(Item_ItemsTime_UpdateTime_Check(it_invisible_time, t))
 492                                         it_invisible_time = t;
 493                                 break;
 494                         case IT_NAILS://"item-extralife"
 495                                 if(Item_ItemsTime_UpdateTime_Check(it_extralife_time, t))
 496                                         it_extralife_time = t;
 497                                 break;
 498                         case IT_INVINCIBLE://"item-speed"
 499                                 if(Item_ItemsTime_UpdateTime_Check(it_speed_time, t))
 500                                         it_speed_time = t;
 501                                 break;
 502                 }
 503         }
 504         else
 505         {
 506                 switch(e.items)
 507                 {
 508                         case IT_HEALTH:
 509                                 //if (e.classname == "item_health_mega")
 510                                         if(Item_ItemsTime_UpdateTime_Check(it_health_mega_time, t))
 511                                                 it_health_mega_time = t;
 512                                 break;
 513                         case IT_ARMOR:
 514                                 if (e.classname == "item_armor_large")
 515                                         if(Item_ItemsTime_UpdateTime_Check(it_armor_large_time, t))
 516                                                 it_armor_large_time = t;
 517                                 break;
 518                         case IT_STRENGTH://"item-strength"
 519                                 if(Item_ItemsTime_UpdateTime_Check(it_strength_time, t))
 520                                         it_strength_time = t;
 521                                 break;
 522                         case IT_INVINCIBLE://"item-shield"
 523                                 if(Item_ItemsTime_UpdateTime_Check(it_shield_time, t))
 524                                         it_shield_time = t;
 525                                 break;
 526                         default:
 527                                 if(e.weapons & WEPSET_SUPERWEAPONS)
 528                                         if(Item_ItemsTime_UpdateTime_Check(it_superweapons_time, t))
 529                                                         it_superweapons_time = t;
 530                 }
 531         }
 532         switch(e.items)
 533         {
 534                 case IT_FUEL_REGEN://"item-fuelregen"
 535                         if(Item_ItemsTime_UpdateTime_Check(it_fuelregen_time, t))
 536                                 it_fuelregen_time = t;
 537                         break;
 538                 case IT_JETPACK://"item-jetpack"
 539                         if(Item_ItemsTime_UpdateTime_Check(it_jetpack_time, t))
 540                                 it_jetpack_time = t;
 541                         break;
 542         }
 543 }
 544 void Item_ItemsTime_GetForAll()
 545 {
 546         entity e;
 547         if(warmup_stage)
 548         {
 549                 FOR_EACH_REALCLIENT(e)
 550                         Item_ItemsTime_Get(e);
 551         }
 552         else
 553         {
 554                 FOR_EACH_REALCLIENT(e)
 555                 {
 556                         if (e.classname != "player")
 557                                 Item_ItemsTime_Get(e);
 558                 }
 559         }
 560 }
 561
 562 void Item_Respawn (void)
 563 {
 564         Item_Show(self, 1);
 565         // this is ugly...
 566         if(self.items == IT_STRENGTH)
 567                 sound (self, CH_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTEN_NORM);    // play respawn sound
 568         else if(self.items == IT_INVINCIBLE)
 569                 sound (self, CH_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTEN_NORM);      // play respawn sound
 570         else
 571                 sound (self, CH_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTEN_NORM); // play respawn sound
 572         setorigin (self, self.origin);
 573
 574         if(self.flags & FL_POWERUP || self.classname == "item_armor_large" || self.items == IT_HEALTH || (self.weapons & WEPSET_SUPERWEAPONS))
 575         {
 576                 Item_ItemsTime_UpdateTime(self, 0);
 577                 Item_ItemsTime_GetForAll();
 578         }
 579
 580         self.think = Item_Think;
 581         self.nextthink = time;
 582
 583         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 584         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 585 }
 586
 587 void Item_RespawnCountdown (void)
 588 {
 589         if(self.count >= ITEM_RESPAWN_TICKS)
 590         {
 591                 if(self.waypointsprite_attached)
 592                         WaypointSprite_Kill(self.waypointsprite_attached);
 593                 Item_Respawn();
 594         }
 595         else
 596         {
 597                 self.nextthink = time + 1;
 598                 self.count += 1;
 599                 if(self.count == 1)
 600                 {
 601                         string name;
 602                         vector rgb = '1 0 1';
 603                         name = string_null;
 604                         switch(self.items)
 605                         {
 606                                 case IT_FUEL_REGEN: name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 607                                 case IT_JETPACK:    name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 608                                 case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 609                                 case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 610                                 case IT_HEALTH:
 611                                         //if (self.classname == "item_health_mega")
 612                                                 {name = "item_health_mega"; rgb = '1 0 0';}
 613                                         break;
 614                                 case IT_ARMOR:
 615                                         if (self.classname == "item_armor_large")
 616                                                 {name = "item_armor_large"; rgb = '0 1 0';}
 617                                         break;
 618                         }
 619                         item_name = name;
 620                         item_color = rgb;
 621                         MUTATOR_CALLHOOK(Item_RespawnCountdown);
 622                         name = item_name;
 623                         rgb = item_color;
 624                         if(self.flags & FL_WEAPON)
 625                         {
 626                                 entity wi = get_weaponinfo(self.weapon);
 627                                 if(wi)
 628                                 {
 629                                         name = wi.wpmodel;
 630                                         rgb = '1 0 0';
 631                                 }
 632                         }
 633                         if(name)
 634                         {
 635                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, true, RADARICON_POWERUP, rgb);
 636                                 if(self.waypointsprite_attached)
 637                                 {
 638                                         if (self.items == IT_HEALTH || self.items == IT_ARMOR)
 639                                                 WaypointSprite_UpdateRule(self.waypointsprite_attached, 0, SPRITERULE_SPECTATOR);
 640                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 641                                 }
 642                         }
 643                         else
 644                         {
 645                                 print("Unknown powerup-marked item is wanting to respawn\n");
 646                                 localcmd(sprintf("prvm_edict server %d\n", num_for_edict(self)));
 647                         }
 648                 }
 649                 sound (self, CH_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTEN_NORM);        // play respawn sound
 650                 if(self.waypointsprite_attached)
 651                 {
 652                         WaypointSprite_Ping(self.waypointsprite_attached);
 653                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 654                 }
 655         }
 656 }
 657
 658 void Item_RespawnThink()
 659 {
 660         self.nextthink = time;
 661         if(self.origin != self.oldorigin)
 662         {
 663                 self.oldorigin = self.origin;
 664                 ItemUpdate(self);
 665         }
 666
 667         if(time >= self.wait)
 668                 Item_Respawn();
 669 }
 670
 671 void Item_ScheduleRespawnIn(entity e, float t)
 672 {
 673         if((e.flags & FL_POWERUP) || (e.weapons & WEPSET_SUPERWEAPONS) || e.classname == "item_armor_large" || e.items == IT_HEALTH)
 674         {
 675                 entity head;
 676                 e.think = Item_RespawnCountdown;
 677                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 678                 e.scheduledrespawntime = e.nextthink + ITEM_RESPAWN_TICKS;
 679                 e.count = 0;
 680                 if(e.weapons & WEPSET_SUPERWEAPONS)
 681                 {
 682                         for(t = e.scheduledrespawntime, head = world; (head = nextent(head)); )
 683                         {
 684                                 if(e == head)
 685                                         continue;
 686                                 if(clienttype(head) == CLIENTTYPE_NOTACLIENT)
 687                                 if(head.weapons & WEPSET_SUPERWEAPONS)
 688                                 if(head.classname != "weapon_info")
 689                                 {
 690                                         if(head.scheduledrespawntime <= time)
 691                                         {
 692                                                 t = 0;
 693                                                 break;
 694                                         }
 695                                         if(head.scheduledrespawntime < t)
 696                                                 t = head.scheduledrespawntime;
 697                                 }
 698                         }
 699                 }
 700                 else
 701                 {
 702                         for(t = e.scheduledrespawntime, head = world; (head = find(head, classname, e.classname)); )
 703                         {
 704                                 // in instagib .classname is "instagib" for every item
 705                                 if(e == head || (g_instagib && e.items != head.items))
 706                                         continue;
 707                                 if(head.scheduledrespawntime <= time)
 708                                 {
 709                                         t = 0;
 710                                         break;
 711                                 }
 712                                 if(head.scheduledrespawntime < t)
 713                                         t = head.scheduledrespawntime;
 714                         }
 715                 }
 716                 Item_ItemsTime_UpdateTime(e, t);
 717                 Item_ItemsTime_GetForAll();
 718         }
 719         else
 720         {
 721                 e.think = Item_RespawnThink;
 722                 e.nextthink = time;
 723                 e.scheduledrespawntime = time + t;
 724                 e.wait = time + t;
 725         }
 726 }
 727
 728 void Item_ScheduleRespawn(entity e)
 729 {
 730         if(e.respawntime > 0)
 731         {
 732                 Item_Show(e, 0);
 733                 Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 734         }
 735         else // if respawntime is -1, this item does not respawn
 736                 Item_Show(e, -1);
 737 }
 738
 739 void Item_ScheduleInitialRespawn(entity e)
 740 {
 741         Item_Show(e, 0);
 742         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 743 }
 744
 745 float Item_GiveAmmoTo(entity item, entity player, .float ammotype, float ammomax, float mode)
 746 {
 747         if (!item.(ammotype))
 748                 return false;
 749
 750         if (item.spawnshieldtime)
 751         {
 752                 if ((player.(ammotype) < ammomax) || item.pickup_anyway)
 753                 {
 754                         player.(ammotype) = bound(player.(ammotype), ammomax, player.(ammotype) + item.(ammotype));
 755                         goto YEAH;
 756                 }
 757         }
 758         else if(g_weapon_stay == 2)
 759         {
 760                 float mi = min(item.(ammotype), ammomax);
 761                 if (player.(ammotype) < mi)
 762                 {
 763                         player.(ammotype) = mi;
 764                         goto YEAH;
 765                 }
 766         }
 767
 768         return false;
 769
 770 :YEAH
 771         switch(mode)
 772         {
 773                 case ITEM_MODE_FUEL:
 774                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + autocvar_g_balance_pause_fuel_rot);
 775                         break;
 776                 case ITEM_MODE_HEALTH:
 777                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + autocvar_g_balance_pause_health_rot);
 778                         break;
 779                 case ITEM_MODE_ARMOR:
 780                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + autocvar_g_balance_pause_armor_rot);
 781                         break;
 782                 default:
 783                         break;
 784         }
 785         return true;
 786 }
 787
 788 float Item_GiveTo(entity item, entity player)
 789 {
 790         float _switchweapon;
 791         float pickedup;
 792         float it;
 793         float i;
 794
 795         // if nothing happens to player, just return without taking the item
 796         pickedup = false;
 797         _switchweapon = false;
 798         // in case the player has autoswitch enabled do the following:
 799         // if the player is using their best weapon before items are given, they
 800         // probably want to switch to an even better weapon after items are given
 801         if (player.autoswitch)
 802         if (player.switchweapon == w_getbestweapon(player))
 803                 _switchweapon = true;
 804
 805         if (!(player.weapons & WepSet_FromWeapon(player.switchweapon)))
 806                 _switchweapon = true;
 807
 808         pickedup |= Item_GiveAmmoTo(item, player, ammo_fuel, g_pickup_fuel_max, ITEM_MODE_FUEL);
 809         pickedup |= Item_GiveAmmoTo(item, player, ammo_shells, g_pickup_shells_max, ITEM_MODE_NONE);
 810         pickedup |= Item_GiveAmmoTo(item, player, ammo_nails, g_pickup_nails_max, ITEM_MODE_NONE);
 811         pickedup |= Item_GiveAmmoTo(item, player, ammo_rockets, g_pickup_rockets_max, ITEM_MODE_NONE);
 812         pickedup |= Item_GiveAmmoTo(item, player, ammo_cells, g_pickup_cells_max, ITEM_MODE_NONE);
 813         pickedup |= Item_GiveAmmoTo(item, player, ammo_plasma, g_pickup_plasma_max, ITEM_MODE_NONE);
 814         pickedup |= Item_GiveAmmoTo(item, player, health, item.max_health, ITEM_MODE_HEALTH);
 815         pickedup |= Item_GiveAmmoTo(item, player, armorvalue, item.max_armorvalue, ITEM_MODE_ARMOR);
 816
 817         if (item.flags & FL_WEAPON)
 818         {
 819                 WepSet it;
 820                 it = item.weapons;
 821                 it &= ~player.weapons;
 822
 823                 if (it || (item.spawnshieldtime && item.pickup_anyway))
 824                 {
 825                         pickedup = true;
 826                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 827                         if(it & WepSet_FromWeapon(i))
 828                         {
 829                                 W_DropEvent(WR_PICKUP, player, i, item);
 830                                 W_GiveWeapon(player, i);
 831                         }
 832                 }
 833         }
 834
 835         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 836         {
 837                 pickedup = true;
 838                 player.items |= it;
 839                 Send_Notification(NOTIF_ONE, player, MSG_INFO, INFO_ITEM_WEAPON_GOT, item.netname);
 840         }
 841
 842         if (item.strength_finished)
 843         {
 844                 pickedup = true;
 845                 player.strength_finished = max(player.strength_finished, time) + item.strength_finished;
 846         }
 847         if (item.invincible_finished)
 848         {
 849                 pickedup = true;
 850                 player.invincible_finished = max(player.invincible_finished, time) + item.invincible_finished;
 851         }
 852         if (item.superweapons_finished)
 853         {
 854                 pickedup = true;
 855                 player.superweapons_finished = max(player.superweapons_finished, time) + item.superweapons_finished;
 856         }
 857
 858 :skip
 859
 860         // always eat teamed entities
 861         if(item.team)
 862                 pickedup = true;
 863
 864         if (!pickedup)
 865                 return 0;
 866
 867         if (_switchweapon)
 868                 if (player.switchweapon != w_getbestweapon(player))
 869                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 870
 871         return 1;
 872 }
 873
 874 void Item_Touch (void)
 875 {
 876         entity e, head;
 877
 878         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 879         if(self.classname == "droppedweapon")
 880         {
 881                 if (ITEM_TOUCH_NEEDKILL())
 882                 {
 883                         remove(self);
 884                         return;
 885                 }
 886         }
 887
 888         if (!IS_PLAYER(other))
 889                 return;
 890         if (other.frozen)
 891                 return;
 892         if (other.deadflag)
 893                 return;
 894         if (self.solid != SOLID_TRIGGER)
 895                 return;
 896         if (self.owner == other)
 897                 return;
 898         if (time < self.item_spawnshieldtime)
 899                 return;
 900
 901         switch(MUTATOR_CALLHOOK(ItemTouch))
 902         {
 903                 case MUT_ITEMTOUCH_RETURN: { return; }
 904                 case MUT_ITEMTOUCH_PICKUP: { goto pickup; }
 905         }
 906
 907         if (self.classname == "droppedweapon")
 908         {
 909                 self.strength_finished = max(0, self.strength_finished - time);
 910                 self.invincible_finished = max(0, self.invincible_finished - time);
 911                 self.superweapons_finished = max(0, self.superweapons_finished - time);
 912         }
 913
 914         if(!Item_GiveTo(self, other))
 915         {
 916                 if (self.classname == "droppedweapon")
 917                 {
 918                         // undo what we did above
 919                         self.strength_finished += time;
 920                         self.invincible_finished += time;
 921                         self.superweapons_finished += time;
 922                 }
 923                 return;
 924         }
 925
 926         :pickup
 927
 928         other.last_pickup = time;
 929
 930         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 931         sound (other, CH_TRIGGER, self.item_pickupsound, VOL_BASE, ATTEN_NORM);
 932
 933         if (self.classname == "droppedweapon")
 934                 remove (self);
 935         else if (!self.spawnshieldtime)
 936                 return;
 937         else
 938         {
 939                 if(self.team)
 940                 {
 941                         RandomSelection_Init();
 942                         for(head = world; (head = findfloat(head, team, self.team)); )
 943                         {
 944                                 if(head.flags & FL_ITEM)
 945                                 {
 946                                         Item_Show(head, -1);
 947                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 948                                 }
 949                         }
 950                         e = RandomSelection_chosen_ent;
 951
 952                 }
 953                 else
 954                         e = self;
 955                 Item_ScheduleRespawn(e);
 956         }
 957 }
 958
 959 void Item_Reset()
 960 {
 961         Item_Show(self, !self.state);
 962         setorigin (self, self.origin);
 963
 964         if(self.classname != "droppedweapon")
 965         {
 966                 self.think = Item_Think;
 967                 self.nextthink = time;
 968
 969                 if(self.waypointsprite_attached)
 970                         WaypointSprite_Kill(self.waypointsprite_attached);
 971
 972                 if((self.flags & FL_POWERUP) || (self.weapons & WEPSET_SUPERWEAPONS)) // do not spawn powerups initially!
 973                         Item_ScheduleInitialRespawn(self);
 974         }
 975 }
 976
 977 void Item_FindTeam()
 978 {
 979         entity head, e;
 980
 981         if(self.effects & EF_NODRAW)
 982         {
 983                 // marker for item team search
 984                 dprint("Initializing item team ", ftos(self.team), "\n");
 985                 RandomSelection_Init();
 986                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 987                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 988                 e = RandomSelection_chosen_ent;
 989                 e.state = 0;
 990                 Item_Show(e, 1);
 991
 992                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 993                 {
 994                         if(head != e)
 995                         {
 996                                 // make it a non-spawned item
 997                                 Item_Show(head, -1);
 998                                 head.state = 1; // state 1 = initially hidden item
 999                         }
1000                         head.effects &= ~EF_NODRAW;
1001                 }
1002
1003                 Item_Reset();
1004         }
1005 }
1006
1007 // Savage: used for item garbage-collection
1008 // TODO: perhaps nice special effect?
1009 void RemoveItem(void)
1010 {
1011         remove(self);
1012 }
1013
1014 // pickup evaluation functions
1015 // these functions decide how desirable an item is to the bots
1016
1017 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;}
1018
1019 float weapon_pickupevalfunc(entity player, entity item)
1020 {
1021         float c;
1022
1023         // See if I have it already
1024         if(item.weapons & ~player.weapons)
1025         {
1026                 // If I can pick it up
1027                 if(!item.spawnshieldtime)
1028                         c = 0;
1029                 else if(player.ammo_cells || player.ammo_shells || player.ammo_plasma || player.ammo_nails || player.ammo_rockets)
1030                 {
1031                         // Skilled bots will grab more
1032                         c = bound(0, skill / 10, 1) * 0.5;
1033                 }
1034                 else
1035                         c = 0;
1036         }
1037         else
1038                 c = 1;
1039
1040         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
1041         if( bot_custom_weapon && c )
1042         {
1043                 // Find the highest position on any range
1044                 int position = -1;
1045                 for (int j = 0; j < WEP_LAST ; ++j){
1046                         if(
1047                                         bot_weapons_far[j] == item.weapon ||
1048                                         bot_weapons_mid[j] == item.weapon ||
1049                                         bot_weapons_close[j] == item.weapon
1050                           )
1051                         {
1052                                 position = j;
1053                                 break;
1054                         }
1055                 }
1056
1057                 // Rate it
1058                 if (position >= 0 )
1059                 {
1060                         position = WEP_LAST - position;
1061                         // item.bot_pickupbasevalue is overwritten here
1062                         return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
1063                 }
1064         }
1065
1066         return item.bot_pickupbasevalue * c;
1067 }
1068
1069 float commodity_pickupevalfunc(entity player, entity item)
1070 {
1071         float c, i;
1072         float need_shells = false, need_nails = false, need_rockets = false, need_cells = false, need_plasma = false, need_fuel = false;
1073         entity wi;
1074         c = 0;
1075
1076         // Detect needed ammo
1077         for(i = WEP_FIRST; i <= WEP_LAST ; ++i)
1078         {
1079                 wi = get_weaponinfo(i);
1080
1081                 if (!(player.weapons & WepSet_FromWeapon(i)))
1082                         continue;
1083
1084                 if(wi.items & IT_SHELLS)
1085                         need_shells = true;
1086                 else if(wi.items & IT_NAILS)
1087                         need_nails = true;
1088                 else if(wi.items & IT_ROCKETS)
1089                         need_rockets = true;
1090                 else if(wi.items & IT_CELLS)
1091                         need_cells = true;
1092                 else if(wi.items & IT_PLASMA)
1093                         need_plasma = true;
1094                 else if(wi.items & IT_FUEL)
1095                         need_fuel = true;
1096         }
1097
1098         // TODO: figure out if the player even has the weapon this ammo is for?
1099         // may not affect strategy much though...
1100         // find out how much more ammo/armor/health the player can hold
1101         if (need_shells)
1102         if (item.ammo_shells)
1103         if (player.ammo_shells < g_pickup_shells_max)
1104                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
1105         if (need_nails)
1106         if (item.ammo_nails)
1107         if (player.ammo_nails < g_pickup_nails_max)
1108                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
1109         if (need_rockets)
1110         if (item.ammo_rockets)
1111         if (player.ammo_rockets < g_pickup_rockets_max)
1112                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
1113         if (need_cells)
1114         if (item.ammo_cells)
1115         if (player.ammo_cells < g_pickup_cells_max)
1116                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
1117         if (need_plasma)
1118         if (item.ammo_plasma)
1119         if (player.ammo_plasma < g_pickup_plasma_max)
1120                 c = c + max(0, 1 - player.ammo_plasma / g_pickup_plasma_max);
1121         if (need_fuel)
1122         if (item.ammo_fuel)
1123         if (player.ammo_fuel < g_pickup_fuel_max)
1124                 c = c + max(0, 1 - player.ammo_fuel / g_pickup_fuel_max);
1125         if (item.armorvalue)
1126         if (player.armorvalue < item.max_armorvalue)
1127                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
1128         if (item.health)
1129         if (player.health < item.max_health)
1130                 c = c + max(0, 1 - player.health / item.max_health);
1131
1132         return item.bot_pickupbasevalue * c;
1133 }
1134
1135 void Item_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
1136 {
1137         if(ITEM_DAMAGE_NEEDKILL(deathtype))
1138                 RemoveItem();
1139 }
1140
1141 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
1142 {
1143         startitem_failed = false;
1144
1145         if(self.model == "")
1146                 self.model = itemmodel;
1147
1148         if(self.model == "")
1149     {
1150         error(strcat("^1Tried to spawn ", itemname, " with no model!\n"));
1151         return;
1152     }
1153
1154         if(self.item_pickupsound == "")
1155                 self.item_pickupsound = pickupsound;
1156
1157         if(!self.respawntime) // both need to be set
1158         {
1159                 self.respawntime = defaultrespawntime;
1160                 self.respawntimejitter = defaultrespawntimejitter;
1161         }
1162
1163         self.items = itemid;
1164         self.weapon = weaponid;
1165
1166         if(weaponid)
1167                 self.weapons = WepSet_FromWeapon(weaponid);
1168
1169         self.flags = FL_ITEM | itemflags;
1170
1171         if(MUTATOR_CALLHOOK(FilterItem)) // error means we do not want the item
1172         {
1173                 startitem_failed = true;
1174                 remove(self);
1175                 return;
1176         }
1177
1178         // is it a dropped weapon?
1179         if (self.classname == "droppedweapon")
1180         {
1181                 self.reset = SUB_Remove;
1182                 // it's a dropped weapon
1183                 self.movetype = MOVETYPE_TOSS;
1184
1185                 // Savage: remove thrown items after a certain period of time ("garbage collection")
1186                 self.think = RemoveItem;
1187                 self.nextthink = time + 20;
1188
1189                 self.takedamage = DAMAGE_YES;
1190                 self.event_damage = Item_Damage;
1191
1192                 if(self.strength_finished || self.invincible_finished || self.superweapons_finished)
1193                 /*
1194                 if(self.items == 0)
1195                 if(!(self.weapons & ~WEPSET_SUPERWEAPONS)) // only superweapons
1196                 if(self.ammo_nails == 0)
1197                 if(self.ammo_cells == 0)
1198                 if(self.ammo_rockets == 0)
1199                 if(self.ammo_shells == 0)
1200                 if(self.ammo_fuel == 0)
1201                 if(self.health == 0)
1202                 if(self.armorvalue == 0)
1203                 */
1204                 {
1205                         // if item is worthless after a timer, have it expire then
1206                         self.nextthink = max(self.strength_finished, self.invincible_finished, self.superweapons_finished);
1207                 }
1208
1209                 // don't drop if in a NODROP zone (such as lava)
1210                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
1211                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
1212                 {
1213                         startitem_failed = true;
1214                         remove(self);
1215                         return;
1216                 }
1217         }
1218         else
1219         {
1220                 if(!have_pickup_item())
1221                 {
1222                         startitem_failed = true;
1223                         remove (self);
1224                         return;
1225                 }
1226
1227                 self.reset = Item_Reset;
1228                 // it's a level item
1229                 if(self.spawnflags & 1)
1230                         self.noalign = 1;
1231                 if (self.noalign)
1232                         self.movetype = MOVETYPE_NONE;
1233                 else
1234                         self.movetype = MOVETYPE_TOSS;
1235                 // do item filtering according to game mode and other things
1236                 if (!self.noalign)
1237                 {
1238                         // first nudge it off the floor a little bit to avoid math errors
1239                         setorigin(self, self.origin + '0 0 1');
1240                         // set item size before we spawn a spawnfunc_waypoint
1241                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1242                                 setsize (self, '-16 -16 0', '16 16 48');
1243                         else
1244                                 setsize (self, '-16 -16 0', '16 16 32');
1245
1246                         // note droptofloor returns false if stuck/or would fall too far
1247                         droptofloor();
1248                         waypoint_spawnforitem(self);
1249                 }
1250
1251                 /*
1252                  * can't do it that way, as it would break maps
1253                  * TODO make a target_give like entity another way, that perhaps has
1254                  * the weapon name in a key
1255                 if(self.targetname)
1256                 {
1257                         // target_give not yet supported; maybe later
1258                         print("removed targeted ", self.classname, "\n");
1259                         startitem_failed = true;
1260                         remove (self);
1261                         return;
1262                 }
1263                 */
1264
1265                 if(autocvar_spawn_debug >= 2)
1266                 {
1267                         entity otheritem;
1268                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
1269                         {
1270                             // why not flags & fl_item?
1271                                 if(otheritem.is_item)
1272                                 {
1273                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
1274                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
1275                                         error("Mapper sucks.");
1276                                 }
1277                         }
1278                         self.is_item = true;
1279                 }
1280
1281                 weaponsInMap |= WepSet_FromWeapon(weaponid);
1282
1283                 precache_model (self.model);
1284                 precache_sound (self.item_pickupsound);
1285
1286                 precache_sound ("misc/itemrespawncountdown.wav");
1287                 if(itemid == IT_STRENGTH)
1288                         precache_sound ("misc/strength_respawn.wav");
1289                 else if(itemid == IT_INVINCIBLE)
1290                         precache_sound ("misc/shield_respawn.wav");
1291                 else
1292                         precache_sound ("misc/itemrespawn.wav");
1293
1294                 if((itemflags & (FL_POWERUP | FL_WEAPON)) || (itemid & (IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)))
1295                         self.target = "###item###"; // for finding the nearest item using find()
1296
1297                 Item_ItemsTime_UpdateTime(self, 0);
1298         }
1299
1300         self.bot_pickup = true;
1301         self.bot_pickupevalfunc = pickupevalfunc;
1302         self.bot_pickupbasevalue = pickupbasevalue;
1303         self.mdl = self.model;
1304         self.netname = itemname;
1305         self.touch = Item_Touch;
1306         setmodel(self, "null"); // precision set below
1307         //self.effects |= EF_LOWPRECISION;
1308
1309         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
1310     {
1311         self.pos1 = '-16 -16 0';
1312         self.pos2 = '16 16 48';
1313     }
1314         else
1315     {
1316         self.pos1 = '-16 -16 0';
1317         self.pos2 = '16 16 32';
1318     }
1319     setsize (self, self.pos1, self.pos2);
1320
1321     if(itemflags & FL_POWERUP)
1322         self.ItemStatus |= ITS_ANIMATE1;
1323
1324         if(self.armorvalue || self.health)
1325         self.ItemStatus |= ITS_ANIMATE2;
1326
1327         if(itemflags & FL_WEAPON)
1328         {
1329                 if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
1330             self.colormap = 1024; // color shirt=0 pants=0 grey
1331         else
1332             self.gravity = 1;
1333
1334                 self.ItemStatus |= ITS_ANIMATE1;
1335                 self.ItemStatus |= ISF_COLORMAP;
1336         }
1337
1338         self.state = 0;
1339         if(self.team) // broken, no idea why.
1340         {
1341                 if(!self.cnt)
1342                         self.cnt = 1; // item probability weight
1343
1344                 self.effects |= EF_NODRAW; // marker for item team search
1345                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
1346         }
1347         else
1348                 Item_Reset();
1349
1350     Net_LinkEntity(self, false, 0, ItemSend);
1351
1352         self.SendFlags |= ISF_SIZE;
1353         if(self.angles)
1354                 self.SendFlags |= ISF_ANGLES;
1355
1356         // call this hook after everything else has been done
1357         if(MUTATOR_CALLHOOK(Item_Spawn))
1358         {
1359                 startitem_failed = true;
1360                 remove(self);
1361                 return;
1362         }
1363 }
1364 void spawnfunc_item_rockets (void) {
1365         if(!self.ammo_rockets)
1366                 self.ammo_rockets = g_pickup_rockets;
1367         if(!self.pickup_anyway)
1368                 self.pickup_anyway = g_pickup_ammo_anyway;
1369         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1370 }
1371
1372 void spawnfunc_item_bullets (void) {
1373         if(!weaponswapping)
1374         if(autocvar_sv_q3acompat_machineshotgunswap)
1375         if(self.classname != "droppedweapon")
1376         {
1377                 weaponswapping = true;
1378                 spawnfunc_item_shells();
1379                 weaponswapping = false;
1380                 return;
1381         }
1382
1383         if(!self.ammo_nails)
1384                 self.ammo_nails = g_pickup_nails;
1385         if(!self.pickup_anyway)
1386                 self.pickup_anyway = g_pickup_ammo_anyway;
1387         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1388 }
1389
1390 void spawnfunc_item_cells (void) {
1391         if(!self.ammo_cells)
1392                 self.ammo_cells = g_pickup_cells;
1393         if(!self.pickup_anyway)
1394                 self.pickup_anyway = g_pickup_ammo_anyway;
1395         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1396 }
1397
1398 void spawnfunc_item_plasma()
1399 {
1400         if(!self.ammo_plasma)
1401                 self.ammo_plasma = g_pickup_plasma;
1402         if(!self.pickup_anyway)
1403                 self.pickup_anyway = g_pickup_ammo_anyway;
1404         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "plasma", IT_PLASMA, 0, 0, commodity_pickupevalfunc, 2000);
1405 }
1406
1407 void spawnfunc_item_shells (void) {
1408         if(!weaponswapping)
1409         if(autocvar_sv_q3acompat_machineshotgunswap)
1410         if(self.classname != "droppedweapon")
1411         {
1412                 weaponswapping = true;
1413                 spawnfunc_item_bullets();
1414                 weaponswapping = false;
1415                 return;
1416         }
1417
1418         if(!self.ammo_shells)
1419                 self.ammo_shells = g_pickup_shells;
1420         if(!self.pickup_anyway)
1421                 self.pickup_anyway = g_pickup_ammo_anyway;
1422         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1423 }
1424
1425 void spawnfunc_item_armor_small (void) {
1426         if(!self.armorvalue)
1427                 self.armorvalue = g_pickup_armorsmall;
1428         if(!self.max_armorvalue)
1429                 self.max_armorvalue = g_pickup_armorsmall_max;
1430         if(!self.pickup_anyway)
1431                 self.pickup_anyway = g_pickup_armorsmall_anyway;
1432         StartItem ("models/items/item_armor_small.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1433 }
1434
1435 void spawnfunc_item_armor_medium (void) {
1436         if(!self.armorvalue)
1437                 self.armorvalue = g_pickup_armormedium;
1438         if(!self.max_armorvalue)
1439                 self.max_armorvalue = g_pickup_armormedium_max;
1440         if(!self.pickup_anyway)
1441                 self.pickup_anyway = g_pickup_armormedium_anyway;
1442         StartItem ("models/items/item_armor_medium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1443 }
1444
1445 void spawnfunc_item_armor_big (void) {
1446         if(!self.armorvalue)
1447                 self.armorvalue = g_pickup_armorbig;
1448         if(!self.max_armorvalue)
1449                 self.max_armorvalue = g_pickup_armorbig_max;
1450         if(!self.pickup_anyway)
1451                 self.pickup_anyway = g_pickup_armorbig_anyway;
1452         StartItem ("models/items/item_armor_big.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1453 }
1454
1455 void spawnfunc_item_armor_large (void) {
1456         if(!self.armorvalue)
1457                 self.armorvalue = g_pickup_armorlarge;
1458         if(!self.max_armorvalue)
1459                 self.max_armorvalue = g_pickup_armorlarge_max;
1460         if(!self.pickup_anyway)
1461                 self.pickup_anyway = g_pickup_armorlarge_anyway;
1462         StartItem ("models/items/item_armor_large.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1463 }
1464
1465 void spawnfunc_item_health_small (void) {
1466         if(!self.max_health)
1467                 self.max_health = g_pickup_healthsmall_max;
1468         if(!self.health)
1469                 self.health = g_pickup_healthsmall;
1470         if(!self.pickup_anyway)
1471                 self.pickup_anyway = g_pickup_healthsmall_anyway;
1472         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1473 }
1474
1475 void spawnfunc_item_health_medium (void) {
1476         if(!self.max_health)
1477                 self.max_health = g_pickup_healthmedium_max;
1478         if(!self.health)
1479                 self.health = g_pickup_healthmedium;
1480         if(!self.pickup_anyway)
1481                 self.pickup_anyway = g_pickup_healthmedium_anyway;
1482         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1483 }
1484
1485 void spawnfunc_item_health_large (void) {
1486         if(!self.max_health)
1487                 self.max_health = g_pickup_healthlarge_max;
1488         if(!self.health)
1489                 self.health = g_pickup_healthlarge;
1490         if(!self.pickup_anyway)
1491                 self.pickup_anyway = g_pickup_healthlarge_anyway;
1492         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1493 }
1494
1495 void spawnfunc_item_health_mega (void) {
1496                 if(!self.max_health)
1497                         self.max_health = g_pickup_healthmega_max;
1498                 if(!self.health)
1499                         self.health = g_pickup_healthmega;
1500                 if(!self.pickup_anyway)
1501                         self.pickup_anyway = g_pickup_healthmega_anyway;
1502                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1503 }
1504
1505 // support old misnamed entities
1506 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Xonotic maps it is an armor shard
1507 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1508 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1509 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1510 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1511
1512 void spawnfunc_item_strength (void) {
1513                 precache_sound("weapons/strength_fire.wav");
1514                 if(!self.strength_finished)
1515                         self.strength_finished = autocvar_g_balance_powerup_strength_time;
1516                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1517 }
1518
1519 void spawnfunc_item_invincible (void) {
1520                 if(!self.invincible_finished)
1521                         self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1522                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1523 }
1524
1525 // compatibility:
1526 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1527
1528 void target_items_use (void)
1529 {
1530         if(activator.classname == "droppedweapon")
1531         {
1532                 EXACTTRIGGER_TOUCH;
1533                 remove(activator);
1534                 return;
1535         }
1536
1537         if (!IS_PLAYER(activator))
1538                 return;
1539         if(activator.deadflag != DEAD_NO)
1540                 return;
1541         EXACTTRIGGER_TOUCH;
1542
1543         entity e;
1544         for(e = world; (e = find(e, classname, "droppedweapon")); )
1545                 if(e.enemy == activator)
1546                         remove(e);
1547
1548         if(GiveItems(activator, 0, tokenize_console(self.netname)))
1549                 centerprint(activator, self.message);
1550 }
1551
1552 void spawnfunc_target_items (void)
1553 {
1554         float n, i, j;
1555         entity e;
1556         string s;
1557
1558         self.use = target_items_use;
1559         if(!self.strength_finished)
1560                 self.strength_finished = autocvar_g_balance_powerup_strength_time;
1561         if(!self.invincible_finished)
1562                 self.invincible_finished = autocvar_g_balance_powerup_invincible_time;
1563         if(!self.superweapons_finished)
1564                 self.superweapons_finished = autocvar_g_balance_superweapons_time;
1565
1566         precache_sound("misc/itempickup.wav");
1567         precache_sound("misc/megahealth.wav");
1568         precache_sound("misc/armor25.wav");
1569         precache_sound("misc/powerup.wav");
1570         precache_sound("misc/poweroff.wav");
1571         precache_sound("weapons/weaponpickup.wav");
1572
1573         n = tokenize_console(self.netname);
1574         if(argv(0) == "give")
1575         {
1576                 self.netname = substring(self.netname, argv_start_index(1), argv_end_index(-1) - argv_start_index(1));
1577         }
1578         else
1579         {
1580                 for(i = 0; i < n; ++i)
1581                 {
1582                         if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1583                         else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1584                         else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1585                         else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1586                         else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1587                         else if(argv(i) == "superweapons")           self.items |= IT_SUPERWEAPON;
1588                         else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1589                         else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1590                         else
1591                         {
1592                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1593                                 {
1594                                         e = get_weaponinfo(j);
1595                                         s = W_UndeprecateName(argv(i));
1596                                         if(s == e.netname)
1597                                         {
1598                                                 self.weapons |= WepSet_FromWeapon(j);
1599                                                 if(self.spawnflags == 0 || self.spawnflags == 2)
1600                                                         WEP_ACTION(e.weapon, WR_INIT);
1601                                                 break;
1602                                         }
1603                                 }
1604                                 if(j > WEP_LAST)
1605                                         print("target_items: invalid item ", argv(i), "\n");
1606                         }
1607                 }
1608
1609                 string itemprefix, valueprefix;
1610                 if(self.spawnflags == 0)
1611                 {
1612                         itemprefix = "";
1613                         valueprefix = "";
1614                 }
1615                 else if(self.spawnflags == 1)
1616                 {
1617                         itemprefix = "max ";
1618                         valueprefix = "max ";
1619                 }
1620                 else if(self.spawnflags == 2)
1621                 {
1622                         itemprefix = "min ";
1623                         valueprefix = "min ";
1624                 }
1625                 else if(self.spawnflags == 4)
1626                 {
1627                         itemprefix = "minus ";
1628                         valueprefix = "max ";
1629                 }
1630                 else
1631                 {
1632                         error("invalid spawnflags");
1633                         itemprefix = valueprefix = string_null;
1634                 }
1635
1636                 self.netname = "";
1637                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_WEAPON_AMMO), "unlimited_weapon_ammo");
1638                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_UNLIMITED_SUPERWEAPONS), "unlimited_superweapons");
1639                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.strength_finished * !!(self.items & IT_STRENGTH), "strength");
1640                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.invincible_finished * !!(self.items & IT_INVINCIBLE), "invincible");
1641                 self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, self.superweapons_finished * !!(self.items & IT_SUPERWEAPON), "superweapons");
1642                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_JETPACK), "jetpack");
1643                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.items & IT_FUEL_REGEN), "fuel_regen");
1644                 if(self.ammo_shells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_shells), "shells");
1645                 if(self.ammo_nails != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_nails), "nails");
1646                 if(self.ammo_rockets != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_rockets), "rockets");
1647                 if(self.ammo_cells != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_cells), "cells");
1648                 if(self.ammo_plasma != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_plasma), "plasma");
1649                 if(self.ammo_fuel != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.ammo_fuel), "fuel");
1650                 if(self.health != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "health");
1651                 if(self.armorvalue != 0) self.netname = sprintf("%s %s%d %s", self.netname, valueprefix, max(0, self.health), "armor");
1652                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1653                 {
1654                         e = get_weaponinfo(j);
1655                         if(e.weapon)
1656                                 self.netname = sprintf("%s %s%d %s", self.netname, itemprefix, !!(self.weapons & WepSet_FromWeapon(j)), e.netname);
1657                 }
1658         }
1659         self.netname = strzone(self.netname);
1660         //print(self.netname, "\n");
1661
1662         n = tokenize_console(self.netname);
1663         for(i = 0; i < n; ++i)
1664         {
1665                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1666                 {
1667                         e = get_weaponinfo(j);
1668                         if(argv(i) == e.netname)
1669                         {
1670                                 WEP_ACTION(e.weapon, WR_INIT);
1671                                 break;
1672                         }
1673                 }
1674         }
1675 }
1676
1677 void spawnfunc_item_fuel(void)
1678 {
1679         if(!self.ammo_fuel)
1680                 self.ammo_fuel = g_pickup_fuel;
1681         if(!self.pickup_anyway)
1682                 self.pickup_anyway = g_pickup_ammo_anyway;
1683         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1684 }
1685
1686 void spawnfunc_item_fuel_regen(void)
1687 {
1688         if(start_items & IT_FUEL_REGEN)
1689         {
1690                 spawnfunc_item_fuel();
1691                 return;
1692         }
1693         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1694 }
1695
1696 void spawnfunc_item_jetpack(void)
1697 {
1698         if(!self.ammo_fuel)
1699                 self.ammo_fuel = g_pickup_fuel_jetpack;
1700         if(start_items & IT_JETPACK)
1701         {
1702                 spawnfunc_item_fuel();
1703                 return;
1704         }
1705         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1706 }
1707
1708 float GiveWeapon(entity e, float wpn, float op, float val)
1709 {
1710         WepSet v0, v1;
1711         v0 = (e.weapons & WepSet_FromWeapon(wpn));
1712         switch(op)
1713         {
1714                 case OP_SET:
1715                         if(val > 0)
1716                                 e.weapons |= WepSet_FromWeapon(wpn);
1717                         else
1718                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1719                         break;
1720                 case OP_MIN:
1721                 case OP_PLUS:
1722                         if(val > 0)
1723                                 e.weapons |= WepSet_FromWeapon(wpn);
1724                         break;
1725                 case OP_MAX:
1726                         if(val <= 0)
1727                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1728                         break;
1729                 case OP_MINUS:
1730                         if(val > 0)
1731                                 e.weapons &= ~WepSet_FromWeapon(wpn);
1732                         break;
1733         }
1734         v1 = (e.weapons & WepSet_FromWeapon(wpn));
1735         return (v0 != v1);
1736 }
1737
1738 float GiveBit(entity e, .float fld, float bit, float op, float val)
1739 {
1740         float v0, v1;
1741         v0 = (e.(fld) & bit);
1742         switch(op)
1743         {
1744                 case OP_SET:
1745                         if(val > 0)
1746                                 e.(fld) |= bit;
1747                         else
1748                                 e.(fld) &= ~bit;
1749                         break;
1750                 case OP_MIN:
1751                 case OP_PLUS:
1752                         if(val > 0)
1753                                 e.(fld) |= bit;
1754                         break;
1755                 case OP_MAX:
1756                         if(val <= 0)
1757                                 e.(fld) &= ~bit;
1758                         break;
1759                 case OP_MINUS:
1760                         if(val > 0)
1761                                 e.(fld) &= ~bit;
1762                         break;
1763         }
1764         v1 = (e.(fld) & bit);
1765         return (v0 != v1);
1766 }
1767
1768 float GiveValue(entity e, .float fld, float op, float val)
1769 {
1770         float v0, v1;
1771         v0 = e.(fld);
1772         switch(op)
1773         {
1774                 case OP_SET:
1775                         e.(fld) = val;
1776                         break;
1777                 case OP_MIN:
1778                         e.(fld) = max(e.(fld), val); // min 100 cells = at least 100 cells
1779                         break;
1780                 case OP_MAX:
1781                         e.(fld) = min(e.(fld), val);
1782                         break;
1783                 case OP_PLUS:
1784                         e.(fld) += val;
1785                         break;
1786                 case OP_MINUS:
1787                         e.(fld) -= val;
1788                         break;
1789         }
1790         v1 = e.(fld);
1791         return (v0 != v1);
1792 }
1793
1794 void GiveSound(entity e, float v0, float v1, float t, string snd_incr, string snd_decr)
1795 {
1796         if(v1 == v0)
1797                 return;
1798         if(v1 <= v0 - t)
1799         {
1800                 if(snd_decr != "")
1801                         sound (e, CH_TRIGGER, snd_decr, VOL_BASE, ATTEN_NORM);
1802         }
1803         else if(v0 >= v0 + t)
1804         {
1805                 if(snd_incr != "")
1806                         sound (e, CH_TRIGGER, snd_incr, VOL_BASE, ATTEN_NORM);
1807         }
1808 }
1809
1810 void GiveRot(entity e, float v0, float v1, .float rotfield, float rottime, .float regenfield, float regentime)
1811 {
1812         if(v0 < v1)
1813                 e.(rotfield) = max(e.(rotfield), time + rottime);
1814         else if(v0 > v1)
1815                 e.(regenfield) = max(e.(regenfield), time + regentime);
1816 }
1817 float GiveItems(entity e, float beginarg, float endarg)
1818 {
1819         float got, i, j, val, op;
1820         float _switchweapon;
1821         entity wi;
1822         string cmd;
1823
1824         val = 999;
1825         op = OP_SET;
1826
1827         got = 0;
1828
1829         _switchweapon = false;
1830         if (e.autoswitch)
1831                 if (e.switchweapon == w_getbestweapon(e))
1832                         _switchweapon = true;
1833
1834         e.strength_finished = max(0, e.strength_finished - time);
1835         e.invincible_finished = max(0, e.invincible_finished - time);
1836         e.superweapons_finished = max(0, e.superweapons_finished - time);
1837
1838         PREGIVE(e, items);
1839         PREGIVE_WEAPONS(e);
1840         PREGIVE(e, strength_finished);
1841         PREGIVE(e, invincible_finished);
1842         PREGIVE(e, superweapons_finished);
1843         PREGIVE(e, ammo_nails);
1844         PREGIVE(e, ammo_cells);
1845         PREGIVE(e, ammo_plasma);
1846         PREGIVE(e, ammo_shells);
1847         PREGIVE(e, ammo_rockets);
1848         PREGIVE(e, ammo_fuel);
1849         PREGIVE(e, armorvalue);
1850         PREGIVE(e, health);
1851
1852         for(i = beginarg; i < endarg; ++i)
1853         {
1854                 cmd = argv(i);
1855
1856                 if(cmd == "0" || stof(cmd))
1857                 {
1858                         val = stof(cmd);
1859                         continue;
1860                 }
1861                 switch(cmd)
1862                 {
1863                         case "no":
1864                                 op = OP_MAX;
1865                                 val = 0;
1866                                 continue;
1867                         case "max":
1868                                 op = OP_MAX;
1869                                 continue;
1870                         case "min":
1871                                 op = OP_MIN;
1872                                 continue;
1873                         case "plus":
1874                                 op = OP_PLUS;
1875                                 continue;
1876                         case "minus":
1877                                 op = OP_MINUS;
1878                                 continue;
1879                         case "ALL":
1880                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1881                                 got += GiveValue(e, strength_finished, op, val);
1882                                 got += GiveValue(e, invincible_finished, op, val);
1883                                 got += GiveValue(e, superweapons_finished, op, val);
1884                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1885                         case "all":
1886                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1887                                 got += GiveValue(e, health, op, val);
1888                                 got += GiveValue(e, armorvalue, op, val);
1889                         case "allweapons":
1890                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1891                                 {
1892                                         wi = get_weaponinfo(j);
1893                                         if(wi.weapon)
1894                                                 if (!(wi.spawnflags & WEP_FLAG_MUTATORBLOCKED))
1895                                                         got += GiveWeapon(e, j, op, val);
1896                                 }
1897                         case "allammo":
1898                                 got += GiveValue(e, ammo_cells, op, val);
1899                                 got += GiveValue(e, ammo_plasma, op, val);
1900                                 got += GiveValue(e, ammo_shells, op, val);
1901                                 got += GiveValue(e, ammo_nails, op, val);
1902                                 got += GiveValue(e, ammo_rockets, op, val);
1903                                 got += GiveValue(e, ammo_fuel, op, val);
1904                                 break;
1905                         case "unlimited_ammo":
1906                                 got += GiveBit(e, items, IT_UNLIMITED_AMMO, op, val);
1907                                 break;
1908                         case "unlimited_weapon_ammo":
1909                                 got += GiveBit(e, items, IT_UNLIMITED_WEAPON_AMMO, op, val);
1910                                 break;
1911                         case "unlimited_superweapons":
1912                                 got += GiveBit(e, items, IT_UNLIMITED_SUPERWEAPONS, op, val);
1913                                 break;
1914                         case "jetpack":
1915                                 got += GiveBit(e, items, IT_JETPACK, op, val);
1916                                 break;
1917                         case "fuel_regen":
1918                                 got += GiveBit(e, items, IT_FUEL_REGEN, op, val);
1919                                 break;
1920                         case "strength":
1921                                 got += GiveValue(e, strength_finished, op, val);
1922                                 break;
1923                         case "invincible":
1924                                 got += GiveValue(e, invincible_finished, op, val);
1925                                 break;
1926                         case "superweapons":
1927                                 got += GiveValue(e, superweapons_finished, op, val);
1928                                 break;
1929                         case "cells":
1930                                 got += GiveValue(e, ammo_cells, op, val);
1931                                 break;
1932                         case "plasma":
1933                                 got += GiveValue(e, ammo_plasma, op, val);
1934                                 break;
1935                         case "shells":
1936                                 got += GiveValue(e, ammo_shells, op, val);
1937                                 break;
1938                         case "nails":
1939                         case "bullets":
1940                                 got += GiveValue(e, ammo_nails, op, val);
1941                                 break;
1942                         case "rockets":
1943                                 got += GiveValue(e, ammo_rockets, op, val);
1944                                 break;
1945                         case "health":
1946                                 got += GiveValue(e, health, op, val);
1947                                 break;
1948                         case "armor":
1949                                 got += GiveValue(e, armorvalue, op, val);
1950                                 break;
1951                         case "fuel":
1952                                 got += GiveValue(e, ammo_fuel, op, val);
1953                                 break;
1954                         default:
1955                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1956                                 {
1957                                         wi = get_weaponinfo(j);
1958                                         if(cmd == wi.netname)
1959                                         {
1960                                                 got += GiveWeapon(e, j, op, val);
1961                                                 break;
1962                                         }
1963                                 }
1964                                 if(j > WEP_LAST)
1965                                         print("give: invalid item ", cmd, "\n");
1966                                 break;
1967                 }
1968                 val = 999;
1969                 op = OP_SET;
1970         }
1971
1972         POSTGIVE_BIT(e, items, IT_FUEL_REGEN, "misc/itempickup.wav", string_null);
1973         POSTGIVE_BIT(e, items, IT_UNLIMITED_SUPERWEAPONS, "misc/powerup.wav", "misc/poweroff.wav");
1974         POSTGIVE_BIT(e, items, IT_UNLIMITED_WEAPON_AMMO, "misc/powerup.wav", "misc/poweroff.wav");
1975         POSTGIVE_BIT(e, items, IT_JETPACK, "misc/itempickup.wav", string_null);
1976         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1977         {
1978                 wi = get_weaponinfo(j);
1979                 if(wi.weapon)
1980                 {
1981                         POSTGIVE_WEAPON(e, j, "weapons/weaponpickup.wav", string_null);
1982                         if (!(save_weapons & WepSet_FromWeapon(j)))
1983                                 if(e.weapons & WepSet_FromWeapon(j))
1984                                         WEP_ACTION(wi.weapon, WR_INIT);
1985                 }
1986         }
1987         POSTGIVE_VALUE(e, strength_finished, 1, "misc/powerup.wav", "misc/poweroff.wav");
1988         POSTGIVE_VALUE(e, invincible_finished, 1, "misc/powerup_shield.wav", "misc/poweroff.wav");
1989         POSTGIVE_VALUE(e, ammo_nails, 0, "misc/itempickup.wav", string_null);
1990         POSTGIVE_VALUE(e, ammo_cells, 0, "misc/itempickup.wav", string_null);
1991         POSTGIVE_VALUE(e, ammo_plasma, 0, "misc/itempickup.wav", string_null);
1992         POSTGIVE_VALUE(e, ammo_shells, 0, "misc/itempickup.wav", string_null);
1993         POSTGIVE_VALUE(e, ammo_rockets, 0, "misc/itempickup.wav", string_null);
1994         POSTGIVE_VALUE_ROT(e, ammo_fuel, 1, pauserotfuel_finished, autocvar_g_balance_pause_fuel_rot, pauseregen_finished, autocvar_g_balance_pause_fuel_regen, "misc/itempickup.wav", string_null);
1995         POSTGIVE_VALUE_ROT(e, armorvalue, 1, pauserotarmor_finished, autocvar_g_balance_pause_armor_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/armor25.wav", string_null);
1996         POSTGIVE_VALUE_ROT(e, health, 1, pauserothealth_finished, autocvar_g_balance_pause_health_rot, pauseregen_finished, autocvar_g_balance_pause_health_regen, "misc/megahealth.wav", string_null);
1997
1998         if(e.superweapons_finished <= 0)
1999                 if(self.weapons & WEPSET_SUPERWEAPONS)
2000                         e.superweapons_finished = autocvar_g_balance_superweapons_time;
2001
2002         if(e.strength_finished <= 0)
2003                 e.strength_finished = 0;
2004         else
2005                 e.strength_finished += time;
2006         if(e.invincible_finished <= 0)
2007                 e.invincible_finished = 0;
2008         else
2009                 e.invincible_finished += time;
2010         if(e.superweapons_finished <= 0)
2011                 e.superweapons_finished = 0;
2012         else
2013                 e.superweapons_finished += time;
2014
2015         if (!(e.weapons & WepSet_FromWeapon(e.switchweapon)))
2016                 _switchweapon = true;
2017         if(_switchweapon)
2018                 W_SwitchWeapon_Force(e, w_getbestweapon(e));
2019
2020         return got;
2021 }
2022 #endif